qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float CAMERA_FREE = 1;
 331 float CAMERA_CHASE = 2;
 332 float reticle_type;
 333 string NextFrameCommand;
 334 void CSQC_SPIDER_HUD();
 335 void CSQC_RAPTOR_HUD();
 336
 337 vector freeze_org, freeze_ang;
 338 entity nightvision_noise, nightvision_noise2;
 339
 340 #define MAX_TIME_DIFF 5
 341 float pickup_crosshair_time, pickup_crosshair_size;
 342 float hit_time, typehit_time;
 343 float nextsound_hit_time, nextsound_typehit_time;
 344 float hitindication_crosshair_time, hitindication_crosshair_size;
 345 float use_nex_chargepool;
 346
 347 float myhealth, myhealth_prev;
 348 float myhealth_flash;
 349
 350 float old_blurradius, old_bluralpha;
 351 float old_sharpen_intensity;
 352
 353 vector myhealth_gentlergb;
 354
 355 float contentavgalpha, liquidalpha_prev;
 356 vector liquidcolor_prev;
 357
 358 float eventchase_current_distance;
 359
 360 vector damage_blurpostprocess, content_blurpostprocess;
 361
 362 float checkfail[16];
 363
 364 #define BUTTON_3 4
 365 #define BUTTON_4 8
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v;
 372         vector vf_size, vf_min;
 373         float a;
 374
 375         execute_next_frame();
 376
 377         ++framecount;
 378
 379         hud = getstati(STAT_HUD);
 380
 381         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 382                 view_quality = getproperty(VF_MINFPS_QUALITY);
 383         else
 384                 view_quality = 1;
 385
 386         button_attack2 = (input_buttons & BUTTON_3);
 387         button_zoom = (input_buttons & BUTTON_4);
 388
 389         // FIXME do we need this hack?
 390         if(isdemo())
 391         {
 392                 // in demos, input_buttons do not work
 393                 button_zoom = (autocvar__togglezoom == "-");
 394         }
 395
 396 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 397         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 398         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 399         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 400         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 401         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 402         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 403         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 404
 405         vf_size = getpropertyvec(VF_SIZE);
 406         vf_min = getpropertyvec(VF_MIN);
 407         vid_width = vf_size_x;
 408         vid_height = vf_size_y;
 409
 410         vector reticle_pos, reticle_size;
 411         vector splash_pos, splash_size;
 412
 413         WaypointSprite_Load();
 414
 415         CSQCPlayer_SetCamera();
 416
 417 #ifdef COMPAT_XON050_ENGINE
 418         if(spectatee_status)
 419                 myteam = GetPlayerColor(spectatee_status - 1);
 420         else
 421 #endif
 422                 myteam = GetPlayerColor(player_localentnum - 1);
 423
 424         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 425
 426         // event chase camera
 427         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 428         {
 429                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 430                 {
 431                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 432                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 433
 434                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 435                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 436                         if(!autocvar_chase_active)
 437                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 438
 439                         // make the camera smooth back
 440                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 441                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 442                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 443                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 444
 445                         vector eventchase_target_origin;
 446                         makevectors(view_angles);
 447                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 448                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 449                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 450                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 451                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 452                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 453                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 454
 455                         setproperty(VF_ORIGIN, trace_endpos);
 456                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 457                 }
 458                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 459                 {
 460                         cvar_set("chase_active", "0");
 461                         eventchase_current_distance = 0; // start from 0 next time
 462                 }
 463         }
 464
 465         // do lockview after event chase camera so that it still applies whenever necessary.
 466         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 467         {
 468                 setproperty(VF_ORIGIN, freeze_org);
 469                 setproperty(VF_ANGLES, freeze_ang);
 470         }
 471         else
 472         {
 473                 freeze_org = getpropertyvec(VF_ORIGIN);
 474                 freeze_ang = getpropertyvec(VF_ANGLES);
 475         }
 476
 477         WarpZone_FixView();
 478         //WarpZone_FixPMove();
 479
 480         // Render the Scene
 481         view_origin = getpropertyvec(VF_ORIGIN);
 482         view_angles = getpropertyvec(VF_ANGLES);
 483         makevectors(view_angles);
 484         view_forward = v_forward;
 485         view_right = v_right;
 486         view_up = v_up;
 487
 488 #ifdef BLURTEST
 489         if(time > blurtest_time0 && time < blurtest_time1)
 490         {
 491                 float r, t;
 492
 493                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 494                 r = t * blurtest_radius;
 495                 f = 1 / pow(t, blurtest_power) - 1;
 496
 497                 cvar_set("r_glsl_postprocess", "1");
 498                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 499         }
 500         else
 501         {
 502                 cvar_set("r_glsl_postprocess", "0");
 503                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 504         }
 505 #endif
 506
 507         TargetMusic_Advance();
 508         Fog_Force();
 509
 510         if(drawtime == 0)
 511                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 512         else
 513                 drawframetime = bound(0.000001, time - drawtime, 1);
 514         drawtime = time;
 515
 516         // watch for gametype changes here...
 517         // in ParseStuffCMD the cmd isn't executed yet :/
 518         // might even be better to add the gametype to TE_CSQC_INIT...?
 519         if(!postinit)
 520                 PostInit();
 521
 522         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 523         {
 524                 if(calledhooks & HOOK_START)
 525                 {
 526                         localcmd("\ncl_hook_gameend\n");
 527                         calledhooks |= HOOK_END;
 528                 }
 529         }
 530
 531   Announcer();
 532
 533         fov = autocvar_fov;
 534         if(fov <= 59.5)
 535         {
 536                 if(!zoomscript_caught)
 537                 {
 538                         localcmd("+button9\n");
 539                         zoomscript_caught = 1;
 540                 }
 541         }
 542         else
 543         {
 544                 if(zoomscript_caught)
 545                 {
 546                         localcmd("-button9\n");
 547                         zoomscript_caught = 0;
 548                 }
 549         }
 550
 551         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 552
 553         // next WANTED weapon (for HUD)
 554         switchweapon = getstati(STAT_SWITCHWEAPON);
 555
 556         // currently switching-to weapon (for crosshair)
 557         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 558
 559         // actually active weapon (for zoom)
 560         activeweapon = getstati(STAT_ACTIVEWEAPON);
 561
 562         f = (serverflags & SERVERFLAG_TEAMPLAY);
 563         if(f != teamplay)
 564         {
 565                 teamplay = f;
 566                 HUD_InitScores();
 567         }
 568
 569         if(last_switchweapon != switchweapon) {
 570                 weapontime = time;
 571                 last_switchweapon = switchweapon;
 572         }
 573         if(last_activeweapon != activeweapon) {
 574                 last_activeweapon = activeweapon;
 575
 576                 e = get_weaponinfo(activeweapon);
 577                 if(e.netname != "")
 578                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 579                 else
 580                         localcmd("\ncl_hook_activeweapon none\n");
 581         }
 582
 583         // ALWAYS Clear Current Scene First
 584         clearscene();
 585 #ifdef WORKAROUND_XON010
 586         if(checkextension("DP_CSQC_ROTATEMOVES"))
 587         {
 588 #endif
 589         setproperty(VF_ORIGIN, view_origin);
 590         setproperty(VF_ANGLES, view_angles);
 591 #ifdef WORKAROUND_XON010
 592         }
 593 #endif
 594
 595         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 596         setproperty(VF_SIZE, vf_size);
 597         setproperty(VF_MIN, vf_min);
 598
 599         // Assign Standard Viewflags
 600         // Draw the World (and sky)
 601         setproperty(VF_DRAWWORLD, 1);
 602
 603         // Set the console size vars
 604         vid_conwidth = autocvar_vid_conwidth;
 605         vid_conheight = autocvar_vid_conheight;
 606         vid_pixelheight = autocvar_vid_pixelheight;
 607
 608         setproperty(VF_FOV, GetCurrentFov(fov));
 609
 610         // Camera for demo playback
 611         if(camera_active)
 612         {
 613                 if(autocvar_camera_enable)
 614                         CSQC_Demo_Camera();
 615                 else
 616                 {
 617                         cvar_set("chase_active", ftos(chase_active_backup));
 618                         cvar_set("cl_demo_mousegrab", "0");
 619                         camera_active = FALSE;
 620                 }
 621         }
 622 #ifdef CAMERATEST
 623         else if(autocvar_camera_enable)
 624 #else
 625         else if(autocvar_camera_enable && isdemo())
 626 #endif
 627         {
 628                 // Enable required Darkplaces cvars
 629                 chase_active_backup = autocvar_chase_active;
 630                 cvar_set("chase_active", "2");
 631                 cvar_set("cl_demo_mousegrab", "1");
 632                 camera_active = TRUE;
 633                 camera_mode = FALSE;
 634         }
 635
 636         // Draw the Crosshair
 637         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 638
 639         // Draw the Engine Status Bar (the default Quake HUD)
 640         setproperty(VF_DRAWENGINESBAR, 0);
 641
 642         // Update the mouse position
 643         /*
 644            mousepos_x = vid_conwidth;
 645            mousepos_y = vid_conheight;
 646            mousepos = mousepos*0.5 + getmousepos();
 647          */
 648
 649         e = self;
 650         for(self = world; (self = nextent(self)); )
 651                 if(self.draw)
 652                         self.draw();
 653         self = e;
 654
 655         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 656         renderscene();
 657
 658         // now switch to 2D drawing mode by calling a 2D drawing function
 659         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 660         // next R_RenderScene call
 661         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 662
 663         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 664         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 665         {
 666                 // apply night vision effect
 667                 vector tc_00, tc_01, tc_10, tc_11;
 668                 vector rgb;
 669                 rgb_x = 0; // fteqcc sucks
 670                 rgb_y = 0; // fteqcc sucks
 671                 rgb_z = 0; // fteqcc sucks
 672
 673                 if(!nightvision_noise)
 674                 {
 675                         nightvision_noise = spawn();
 676                         nightvision_noise.classname = "nightvision_noise";
 677                 }
 678                 if(!nightvision_noise2)
 679                 {
 680                         nightvision_noise2 = spawn();
 681                         nightvision_noise2.classname = "nightvision_noise2";
 682                 }
 683
 684                 // color tint in yellow
 685                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 686
 687                 // draw BG
 688                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 689                 rgb = '1 1 1';
 690                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 691                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 692                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 693                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 694                 tc_11 = tc_01 + tc_10 - tc_00;
 695                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 696                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 697                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 698                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 699                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 700                 R_EndPolygon();
 701
 702                 // draw FG
 703                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 704                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 705                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 706                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 707                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 708                 tc_11 = tc_01 + tc_10 - tc_00;
 709                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 710                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 711                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 712                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 713                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 714                 R_EndPolygon();
 715         }
 716
 717         // Draw the aiming reticle for weapons that use it
 718         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 719         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 720         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 721         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 722                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 723         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 724                 reticle_type = 2; // nex zoom
 725         else if(button_zoom || zoomscript_caught)
 726                 reticle_type = 1; // normal zoom
 727         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 728                 reticle_type = 2; // nex zoom
 729
 730         if(reticle_type && autocvar_cl_reticle)
 731         {
 732                 if(autocvar_cl_reticle_stretch)
 733                 {
 734                         reticle_size_x = vid_conwidth;
 735                         reticle_size_y = vid_conheight;
 736                         reticle_pos_x = 0;
 737                         reticle_pos_y = 0;
 738                 }
 739                 else
 740                 {
 741                         reticle_size_x = max(vid_conwidth, vid_conheight);
 742                         reticle_size_y = max(vid_conwidth, vid_conheight);
 743                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 744                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 745                 }
 746
 747                 f = current_zoomfraction;
 748                 if(zoomscript_caught)
 749                         f = 1;
 750                 if(autocvar_cl_reticle_item_normal)
 751                 {
 752                         if(reticle_type == 1 && f)
 753                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 754                 }
 755                 if(autocvar_cl_reticle_item_nex)
 756                 {
 757                         if(reticle_type == 2 && f)
 758                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 759                 }
 760         }
 761
 762
 763         // improved polyblend
 764         vector rgb;
 765         if(autocvar_hud_contents)
 766         {
 767                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 768                 vector liquidcolor;
 769
 770                 switch(pointcontents(view_origin))
 771                 {
 772                         case CONTENT_WATER:
 773                                 liquidalpha = autocvar_hud_contents_water_alpha;
 774                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 775                                 incontent = 1;
 776                                 break;
 777
 778                         case CONTENT_LAVA:
 779                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 780                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 781                                 incontent = 1;
 782                                 break;
 783
 784                         case CONTENT_SLIME:
 785                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 786                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 787                                 incontent = 1;
 788                                 break;
 789
 790                         default:
 791                                 liquidalpha = 0;
 792                                 liquidcolor = '0 0 0';
 793                                 incontent = 0;
 794                                 break;
 795                 }
 796
 797                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 798                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 799                         contentfadetime = autocvar_hud_contents_fadeintime;
 800                         liquidalpha_prev = liquidalpha;
 801                         liquidcolor_prev = liquidcolor;
 802                 }
 803                 else
 804                         contentfadetime = autocvar_hud_contents_fadeouttime;
 805
 806                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 807                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 808
 809                 if(contentavgalpha)
 810                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 811
 812                 if(autocvar_hud_postprocessing)
 813                 {
 814                         if(autocvar_hud_contents_blur && contentavgalpha)
 815                         {
 816                                 content_blurpostprocess_x = 1;
 817                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 818                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 819                         }
 820                         else
 821                         {
 822                                 content_blurpostprocess_x = 0;
 823                                 content_blurpostprocess_y = 0;
 824                                 content_blurpostprocess_z = 0;
 825                         }
 826                 }
 827         }
 828
 829         if(autocvar_hud_damage)
 830         {
 831                 splash_size_x = max(vid_conwidth, vid_conheight);
 832                 splash_size_y = max(vid_conwidth, vid_conheight);
 833                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 834                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 835
 836                 float myhealth_flash_temp;
 837                 myhealth = getstati(STAT_HEALTH);
 838
 839                 // fade out
 840                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 841                 // add new damage
 842                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 843
 844                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 845                 pain_threshold = autocvar_hud_damage_pain_threshold;
 846                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 847                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 848
 849                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 850                 {
 851                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 852                 }
 853
 854                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 855
 856                 if(myhealth_prev < 1)
 857                 {
 858                         if(myhealth >= 1)
 859                         {
 860                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 861                                 myhealth_flash_temp = 0;
 862                         }
 863                         else
 864                         {
 865                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 866                         }
 867                 }
 868
 869                 if(spectatee_status == -1 || intermission)
 870                 {
 871                         myhealth_flash = 0; // observing, or match ended
 872                         myhealth_flash_temp = 0;
 873                 }
 874
 875                 myhealth_prev = myhealth;
 876
 877                 // IDEA: change damage color/picture based on player model for robot/alien species?
 878                 // pro: matches model better
 879                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 880                 // maybe different reddish pics?
 881                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 882                 {
 883                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 884                         {
 885                                 if(autocvar_cl_gentle_damage == 2)
 886                                 {
 887                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 888                                         {
 889                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 890                                         }
 891                                 }
 892                                 else
 893                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 894
 895                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 896                         }
 897                         else
 898                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 899                 }
 900
 901                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 902                 {
 903                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 904                         {
 905                                 damage_blurpostprocess_x = 1;
 906                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 907                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 908                         }
 909                         else
 910                         {
 911                                 damage_blurpostprocess_x = 0;
 912                                 damage_blurpostprocess_y = 0;
 913                                 damage_blurpostprocess_z = 0;
 914                         }
 915                 }
 916         }
 917
 918         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 919         {
 920                 // enable or disable rendering types if they are used or not
 921                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 922                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 923
 924                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 925                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 926                 {
 927                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 928                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 929                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 930                         {
 931                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 932                                 old_blurradius = blurradius;
 933                                 old_bluralpha = bluralpha;
 934                         }
 935                 }
 936                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 937                 {
 938                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 939                         old_blurradius = 0;
 940                         old_bluralpha = 0;
 941                 }
 942
 943                 // edge detection postprocess handling done second (used by hud_powerup)
 944                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 945                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 946                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 947
 948                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 949
 950                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 951                 {
 952                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 953                         {
 954                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 955                                 old_sharpen_intensity = sharpen_intensity;
 956                         }
 957                 }
 958                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 959                 {
 960                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 961                         old_sharpen_intensity = 0;
 962                 }
 963         }
 964
 965         if(menu_visible)
 966                 menu_show();
 967
 968         /*if(gametype == MAPINFO_TYPE_CTF)
 969           {
 970           ctf_view();
 971           } else */
 972
 973         // draw 2D entities
 974         e = self;
 975         for(self = world; (self = nextent(self)); )
 976                 if(self.draw2d)
 977                         self.draw2d();
 978         self = e;
 979         Draw_ShowNames_All();
 980
 981         scoreboard_active = HUD_WouldDrawScoreboard();
 982
 983         hit_time = getstatf(STAT_HIT_TIME);
 984         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 985         {
 986                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 987                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 988
 989                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 990         }
 991         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 992         if(typehit_time > nextsound_typehit_time)
 993         {
 994                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 995                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 996
 997                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 998         }
 999
1000         //else
1001         {
1002                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1003                 {
1004                         if(getstati(STAT_FROZEN))
1005                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1006                         if(getstatf(STAT_REVIVE_PROGRESS))
1007                         {
1008                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1009                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1010                         }
1011                 }
1012
1013                 if(autocvar_r_letterbox == 0)
1014                         if(autocvar_viewsize < 120)
1015                                 CSQC_common_hud();
1016
1017                 // crosshair goes VERY LAST
1018                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1019                 {
1020                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1021                                 return;
1022
1023                         string wcross_style;
1024                         float wcross_alpha, wcross_resolution;
1025                         wcross_style = autocvar_crosshair;
1026                         if (wcross_style == "0")
1027                                 return;
1028                         wcross_resolution = autocvar_crosshair_size;
1029                         if (wcross_resolution == 0)
1030                                 return;
1031                         wcross_alpha = autocvar_crosshair_alpha;
1032                         if (wcross_alpha == 0)
1033                                 return;
1034
1035                         // TrueAim check
1036                         float shottype;
1037
1038                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1039                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1040                         wcross_origin_z = 0;
1041                         if(autocvar_crosshair_hittest)
1042                         {
1043                                 vector wcross_oldorigin;
1044                                 wcross_oldorigin = wcross_origin;
1045                                 shottype = TrueAimCheck();
1046                                 if(shottype == SHOTTYPE_HITWORLD)
1047                                 {
1048                                         v = wcross_origin - wcross_oldorigin;
1049                                         v_x /= vid_conwidth;
1050                                         v_y /= vid_conheight;
1051                                         if(vlen(v) > 0.01)
1052                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1053                                 }
1054                                 if(!autocvar_crosshair_hittest_showimpact)
1055                                         wcross_origin = wcross_oldorigin;
1056                         }
1057                         else
1058                                 shottype = SHOTTYPE_HITWORLD;
1059
1060                         vector wcross_color, wcross_size;
1061                         string wcross_wep, wcross_name;
1062                         float wcross_scale, wcross_blur;
1063
1064                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1065                                 e = get_weaponinfo(switchingweapon);
1066                                 if (e && e.netname != "")
1067                                 {
1068                                         wcross_wep = e.netname;
1069                                         if(autocvar_crosshair_per_weapon)
1070                                         {
1071                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1072                                                 if (wcross_resolution == 0)
1073                                                         return;
1074                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1075                                                 if (wcross_alpha == 0)
1076                                                         return;
1077
1078                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1079                                                 if(wcross_style == "" || wcross_style == "0")
1080                                                         wcross_style = wcross_wep;
1081                                         }
1082                                 }
1083                         }
1084                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1085                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1086                         else if(autocvar_crosshair_color_by_health)
1087                         {
1088                                 float x = getstati(STAT_HEALTH);
1089
1090                                 //x = red
1091                                 //y = green
1092                                 //z = blue
1093
1094                                 wcross_color_z = 0;
1095
1096                                 if(x > 200)
1097                                 {
1098                                         wcross_color_x = 0;
1099                                         wcross_color_y = 1;
1100                                 }
1101                                 else if(x > 150)
1102                                 {
1103                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1104                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1105                                 }
1106                                 else if(x > 100)
1107                                 {
1108                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1109                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1110                                         wcross_color_z = 1 - (x-100)*0.02;
1111                                 }
1112                                 else if(x > 50)
1113                                 {
1114                                         wcross_color_x = 1;
1115                                         wcross_color_y = 1;
1116                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1117                                 }
1118                                 else if(x > 20)
1119                                 {
1120                                         wcross_color_x = 1;
1121                                         wcross_color_y = (x-20)*90/27/100;
1122                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1123                                 }
1124                                 else
1125                                 {
1126                                         wcross_color_x = 1;
1127                                         wcross_color_y = 0;
1128                                 }
1129                         }
1130                         else
1131                                 wcross_color = stov(autocvar_crosshair_color);
1132
1133                         wcross_name = strcat("gfx/crosshair", wcross_style);
1134
1135                         if(autocvar_crosshair_effect_scalefade)
1136                         {
1137                                 wcross_scale = wcross_resolution;
1138                                 wcross_resolution = 1;
1139                         }
1140                         else
1141                         {
1142                                 wcross_scale = 1;
1143                         }
1144
1145                         if(autocvar_crosshair_pickup)
1146                         {
1147                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1148
1149                                 if(pickup_crosshair_time < stat_pickup_time)
1150                                 {
1151                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1152                                                 pickup_crosshair_size = 1;
1153
1154                                         pickup_crosshair_time = stat_pickup_time;
1155                                 }
1156
1157                                 if(pickup_crosshair_size > 0)
1158                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1159                                 else
1160                                         pickup_crosshair_size = 0;
1161
1162                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1163                         }
1164
1165                         if(autocvar_crosshair_hitindication)
1166                         {
1167                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1168                                 if(hitindication_crosshair_time < hit_time)
1169                                 {
1170                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1171                                                 hitindication_crosshair_size = 1;
1172
1173                                         hitindication_crosshair_time = hit_time;
1174                                 }
1175
1176                                 if(hitindication_crosshair_size > 0)
1177                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1178                                 else
1179                                         hitindication_crosshair_size = 0;
1180
1181                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1182                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1183                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1184                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1185                         }
1186
1187                         if(shottype == SHOTTYPE_HITENEMY)
1188                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1189                         if(shottype == SHOTTYPE_HITTEAM)
1190                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1191
1192                         f = autocvar_crosshair_effect_speed;
1193                         if(f < 0)
1194                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1195                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1196                         {
1197                                 wcross_changedonetime = time + f;
1198                         }
1199                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1200                         {
1201                                 wcross_name_changestarttime = time;
1202                                 wcross_name_changedonetime = time + f;
1203                                 if(wcross_name_goal_prev_prev)
1204                                         strunzone(wcross_name_goal_prev_prev);
1205                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1206                                 wcross_name_goal_prev = strzone(wcross_name);
1207                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1208                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1209                                 wcross_resolution_goal_prev = wcross_resolution;
1210                         }
1211
1212                         wcross_scale_goal_prev = wcross_scale;
1213                         wcross_alpha_goal_prev = wcross_alpha;
1214                         wcross_color_goal_prev = wcross_color;
1215
1216                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1217                         {
1218                                 wcross_blur = 1;
1219                                 wcross_alpha *= 0.75;
1220                         }
1221                         else
1222                                 wcross_blur = 0;
1223                         // *_prev is at time-frametime
1224                         // * is at wcross_changedonetime+f
1225                         // what do we have at time?
1226                         if(time < wcross_changedonetime)
1227                         {
1228                                 f = frametime / (wcross_changedonetime - time + frametime);
1229                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1230                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1231                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1232                         }
1233
1234                         wcross_scale_prev = wcross_scale;
1235                         wcross_alpha_prev = wcross_alpha;
1236                         wcross_color_prev = wcross_color;
1237
1238                         wcross_scale *= 1 - autocvar__menu_alpha;
1239                         wcross_alpha *= 1 - autocvar__menu_alpha;
1240                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1241
1242                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1243                         {
1244                                 // crosshair rings for weapon stats
1245                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1246                                 {
1247                                         // declarations and stats
1248                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1249                                         string ring_image, ring_inner_image;
1250                                         vector ring_rgb, ring_inner_rgb;
1251
1252                                         ring_scale = autocvar_crosshair_ring_size;
1253
1254                                         float weapon_clipload, weapon_clipsize;
1255                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1256                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1257
1258                                         float nex_charge, nex_chargepool;
1259                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1260                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1261
1262                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1263                                                 nex_charge_movingavg = nex_charge;
1264
1265
1266                                         // handle the values
1267                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1268                                         {
1269                                                 if (nex_chargepool || use_nex_chargepool) {
1270                                                         use_nex_chargepool = 1;
1271                                                         ring_inner_value = nex_chargepool;
1272                                                 } else {
1273                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1274                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1275                                                 }
1276
1277                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1278                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1279                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1280
1281                                                 // draw the outer ring to show the current charge of the weapon
1282                                                 ring_value = nex_charge;
1283                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1284                                                 ring_rgb = wcross_color;
1285                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1286                                         }
1287                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1288                                         {
1289                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1290                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1291                                                 ring_rgb = wcross_color;
1292                                                 ring_image = "gfx/crosshair_ring.tga";
1293                                         }
1294                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1295                                         {
1296                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1297                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1298                                                 ring_rgb = wcross_color;
1299                                                 ring_image = "gfx/crosshair_ring.tga";
1300                                         }
1301
1302                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1303                                         {
1304                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1305                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1306                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1307                                                 ring_rgb = wcross_color;
1308
1309                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1310                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1311                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1312                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1313                                                 else
1314                                                         ring_image = "gfx/crosshair_ring.tga";
1315                                         }
1316
1317                                         // if in weapon switch animation, fade ring out/in
1318                                         if(g_weaponswitchdelay > 0)
1319                                         {
1320                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1321                                                 if(f > 0 && f < 2)
1322                                                         ring_alpha *= fabs(1 - f);
1323                                         }
1324
1325                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1326                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1327
1328                                         if (ring_value)
1329                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1330                                 }
1331
1332 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1333                                 do \
1334                                 { \
1335                                         if(wcross_blur > 0) \
1336                                         { \
1337                                                 for(i = -2; i <= 2; ++i) \
1338                                                 for(j = -2; j <= 2; ++j) \
1339                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1340                                         } \
1341                                         else \
1342                                         { \
1343                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1344                                         } \
1345                                 } \
1346                                 while(0)
1347
1348 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1349                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1350
1351 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1352                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1353
1354                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1355                                 {
1356                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1357                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1358                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1359                                         f = 1 - f;
1360                                 }
1361                                 else
1362                                 {
1363                                         f = 1;
1364                                 }
1365                                 wcross_name_alpha_goal_prev = f;
1366
1367                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1368                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1369
1370                                 if(autocvar_crosshair_dot)
1371                                 {
1372                                         vector wcross_color_old;
1373                                         wcross_color_old = wcross_color;
1374                                         if(autocvar_crosshair_dot_color != "0")
1375                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1376                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1377                                         // FIXME why don't we use wcross_alpha here?
1378                                         wcross_color = wcross_color_old;
1379                                 }
1380                         }
1381                 }
1382                 else
1383                 {
1384                         wcross_scale_prev = 0;
1385                         wcross_alpha_prev = 0;
1386                         wcross_scale_goal_prev = 0;
1387                         wcross_alpha_goal_prev = 0;
1388                         wcross_changedonetime = 0;
1389                         if(wcross_name_goal_prev)
1390                                 strunzone(wcross_name_goal_prev);
1391                         wcross_name_goal_prev = string_null;
1392                         if(wcross_name_goal_prev_prev)
1393                                 strunzone(wcross_name_goal_prev_prev);
1394                         wcross_name_goal_prev_prev = string_null;
1395                         wcross_name_changestarttime = 0;
1396                         wcross_name_changedonetime = 0;
1397                         wcross_name_alpha_goal_prev = 0;
1398                         wcross_name_alpha_goal_prev_prev = 0;
1399                         wcross_resolution_goal_prev = 0;
1400                         wcross_resolution_goal_prev_prev = 0;
1401                 }
1402         }
1403
1404         if(NextFrameCommand)
1405         {
1406                 localcmd("\n", NextFrameCommand, "\n");
1407                 NextFrameCommand = string_null;
1408         }
1409
1410         // we must do this check AFTER a frame was rendered, or it won't work
1411         if(cs_project_is_b0rked == 0)
1412         {
1413                 string w0, h0;
1414                 w0 = ftos(autocvar_vid_conwidth);
1415                 h0 = ftos(autocvar_vid_conheight);
1416                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1417                 //setproperty(VF_FOV, '90 90 0');
1418                 setproperty(VF_ORIGIN, '0 0 0');
1419                 setproperty(VF_ANGLES, '0 0 0');
1420                 setproperty(VF_PERSPECTIVE, 1);
1421                 makevectors('0 0 0');
1422                 vector v1, v2;
1423                 cvar_set("vid_conwidth", "800");
1424                 cvar_set("vid_conheight", "600");
1425                 v1 = cs_project(v_forward);
1426                 cvar_set("vid_conwidth", "640");
1427                 cvar_set("vid_conheight", "480");
1428                 v2 = cs_project(v_forward);
1429                 if(v1 == v2)
1430                         cs_project_is_b0rked = 1;
1431                 else
1432                         cs_project_is_b0rked = -1;
1433                 cvar_set("vid_conwidth", w0);
1434                 cvar_set("vid_conheight", h0);
1435         }
1436
1437         if(autocvar__hud_configure)
1438                 HUD_Panel_Mouse();
1439
1440     if(hud && !intermission)
1441     {
1442         if(hud == HUD_SPIDERBOT)
1443             CSQC_SPIDER_HUD();
1444         else if(hud == HUD_WAKIZASHI)
1445             CSQC_WAKIZASHI_HUD();
1446         else if(hud == HUD_RAPTOR)
1447             CSQC_RAPTOR_HUD();
1448         else if(hud == HUD_BUMBLEBEE)
1449             CSQC_BUMBLE_HUD();
1450     }
1451         // let's reset the view back to normal for the end
1452         setproperty(VF_MIN, '0 0 0');
1453         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1454 }
1455
1456
1457 void CSQC_common_hud(void)
1458 {
1459     // do some accuracy var caching
1460     float i;
1461     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1462     {
1463         if(autocvar_accuracy_color_levels != acc_color_levels)
1464         {
1465             if(acc_color_levels)
1466                 strunzone(acc_color_levels);
1467             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1468             acc_levels = tokenize_console(acc_color_levels);
1469             if (acc_levels > MAX_ACCURACY_LEVELS)
1470                 acc_levels = MAX_ACCURACY_LEVELS;
1471
1472             for (i = 0; i < acc_levels; ++i)
1473                 acc_lev[i] = stof(argv(i)) / 100.0;
1474         }
1475         // let know that acc_col[] needs to be loaded
1476         acc_col_x[0] = -1;
1477     }
1478
1479     HUD_Main(); // always run these functions for alpha checks
1480     HUD_DrawScoreboard();
1481
1482     if (scoreboard_active) // scoreboard/accuracy
1483         HUD_Reset();
1484     else if (intermission == 2) // map voting screen
1485     {
1486         HUD_FinaleOverlay();
1487         HUD_Reset();
1488     }
1489         /*
1490         switch(hud)
1491         {
1492                 case HUD_SPIDERBOT:
1493                         CSQC_SPIDER_HUD();
1494                         break;
1495
1496                 case HUD_WAKIZASHI:
1497                         CSQC_WAKIZASHI_HUD();
1498                         break;
1499
1500         case HUD_BUMBLEBEE:
1501             CSQC_BUMBLE_HUD();
1502             break;
1503         }
1504         */
1505 }
1506
1507
1508 // following vectors must be global to allow seamless switching between camera modes
1509 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1510 void CSQC_Demo_Camera()
1511 {
1512         float speed, attenuation, dimensions;
1513         vector tmp, delta;
1514
1515         if( autocvar_camera_reset || !camera_mode )
1516         {
1517                 camera_offset = '0 0 0';
1518                 current_angles = '0 0 0';
1519                 camera_direction = '0 0 0';
1520                 camera_offset_z += 30;
1521                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1522                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1523                 current_origin = view_origin;
1524                 current_camera_offset  = camera_offset;
1525                 cvar_set("camera_reset", "0");
1526                 camera_mode = CAMERA_CHASE;
1527         }
1528
1529         // Camera angles
1530         if( camera_roll )
1531                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1532
1533         if(autocvar_camera_look_player)
1534         {
1535                 vector dir;
1536                 float n;
1537
1538                 dir = normalize(view_origin - current_position);
1539                 n = mouse_angles_z;
1540                 mouse_angles = vectoangles(dir);
1541                 mouse_angles_x = mouse_angles_x * -1;
1542                 mouse_angles_z = n;
1543         }
1544         else
1545         {
1546                 tmp = getmousepos() * 0.1;
1547                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1548                 {
1549                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1550                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1551                 }
1552         }
1553
1554         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1555         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1556         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1557         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1558
1559         // Fix difference when angles don't have the same sign
1560         delta = '0 0 0';
1561         if(mouse_angles_y < -60 && current_angles_y > 60)
1562                 delta = '0 360 0';
1563         if(mouse_angles_y > 60 && current_angles_y < -60)
1564                 delta = '0 -360 0';
1565
1566         if(autocvar_camera_look_player)
1567                 attenuation = autocvar_camera_look_attenuation;
1568         else
1569                 attenuation = autocvar_camera_speed_attenuation;
1570
1571         attenuation = 1 / max(1, attenuation);
1572         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1573
1574         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1575         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1576         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1577         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1578
1579         // Camera position
1580         tmp = '0 0 0';
1581         dimensions = 0;
1582
1583         if( camera_direction_x )
1584         {
1585                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1586                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1587                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1588                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1589                 ++dimensions;
1590         }
1591
1592         if( camera_direction_y )
1593         {
1594                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1595                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1596                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1597                 ++dimensions;
1598         }
1599
1600         if( camera_direction_z )
1601         {
1602                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1603                 ++dimensions;
1604         }
1605
1606         if(autocvar_camera_free)
1607                 speed = autocvar_camera_speed_free;
1608         else
1609                 speed = autocvar_camera_speed_chase;
1610
1611         if(dimensions)
1612         {
1613                 speed = speed * sqrt(1 / dimensions);
1614                 camera_offset += tmp * speed;
1615         }
1616
1617         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1618
1619         // Camera modes
1620         if( autocvar_camera_free )
1621         {
1622                 if ( camera_mode == CAMERA_CHASE )
1623                 {
1624                         current_camera_offset = current_origin + current_camera_offset;
1625                         camera_offset = current_origin + camera_offset;
1626                 }
1627
1628                 camera_mode = CAMERA_FREE;
1629                 current_position = current_camera_offset;
1630         }
1631         else
1632         {
1633                 if ( camera_mode == CAMERA_FREE )
1634                 {
1635                         current_origin = view_origin;
1636                         camera_offset = camera_offset - current_origin;
1637                         current_camera_offset = current_camera_offset - current_origin;
1638                 }
1639
1640                 camera_mode = CAMERA_CHASE;
1641
1642                 if(autocvar_camera_chase_smoothly)
1643                         current_origin += (view_origin - current_origin) * attenuation;
1644                 else
1645                         current_origin = view_origin;
1646
1647                 current_position = current_origin + current_camera_offset;
1648         }
1649
1650         setproperty(VF_ANGLES, current_angles);
1651         setproperty(VF_ORIGIN, current_position);
1652 }