qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107                 if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir)
 127                 zoomin_effect = 0;
 128
 129         if(zoomin_effect || camera_active)
 130         {
 131                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 132         }
 133         else
 134         {
 135                 if(zoomspeed < 0) // instant zoom
 136                 {
 137                         if(zoomdir)
 138                                 current_viewzoom = 1 / zoomfactor;
 139                         else
 140                                 current_viewzoom = 1;
 141                 }
 142                 else
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 146                         else
 147                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 148                 }
 149         }
 150
 151         if(almost_equals(current_viewzoom, 1))
 152                 current_zoomfraction = 0;
 153         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 154                 current_zoomfraction = 1;
 155         else
 156                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 157
 158         if(zoomsensitivity < 1)
 159                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 160         else
 161                 setsensitivityscale(1);
 162
 163         makevectors(view_angles);
 164
 165         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 v = pmove_vel;
 168                 if(csqcplayer)
 169                         v = csqcplayer.velocity;
 170
 171                 switch(autocvar_cl_velocityzoom_type)
 172                 {
 173                         case 3: curspeed = max(0, v_forward * v); break;
 174                         case 2: curspeed = (v_forward * v); break;
 175                         case 1: default: curspeed = vlen(v); break;
 176                 }
 177
 178                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 179                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 180                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 181
 182                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 183         }
 184         else
 185                 velocityzoom = 1;
 186
 187         float frustumx, frustumy, fovx, fovy;
 188         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 189         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 190         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 191         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 192
 193         return '1 0 0' * fovx + '0 1 0' * fovy;
 194 }
 195
 196 // this function must match W_SetupShot!
 197 float zoomscript_caught;
 198
 199 vector wcross_origin;
 200 float wcross_scale_prev, wcross_alpha_prev;
 201 vector wcross_color_prev;
 202 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 203 vector wcross_color_goal_prev;
 204 float wcross_changedonetime;
 205
 206 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 207 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 208 float wcross_name_changestarttime, wcross_name_changedonetime;
 209 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 210 entity trueaim;
 211 entity trueaim_rifle;
 212
 213 #define SHOTTYPE_HITTEAM 1
 214 #define SHOTTYPE_HITOBSTRUCTION 2
 215 #define SHOTTYPE_HITWORLD 3
 216 #define SHOTTYPE_HITENEMY 4
 217
 218 void TrueAim_Init()
 219 {
 220         trueaim = spawn();
 221         trueaim.classname = "trueaim";
 222         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 223         trueaim_rifle = spawn();
 224         trueaim_rifle.classname = "trueaim_rifle";
 225         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 226 }
 227
 228 float EnemyHitCheck()
 229 {
 230         float t, n;
 231         wcross_origin = project_3d_to_2d(trace_endpos);
 232         wcross_origin_z = 0;
 233         if(trace_ent)
 234                 n = trace_ent.entnum;
 235         else
 236                 n = trace_networkentity;
 237         if(n < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(n > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(n - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == COLOR_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float CAMERA_FREE = 1;
 344 float CAMERA_CHASE = 2;
 345 float reticle_type;
 346 string NextFrameCommand;
 347 void CSQC_SPIDER_HUD();
 348 void CSQC_RAPTOR_HUD();
 349
 350 vector freeze_org, freeze_ang;
 351 entity nightvision_noise, nightvision_noise2;
 352
 353 #define MAX_TIME_DIFF 5
 354 float pickup_crosshair_time, pickup_crosshair_size;
 355 float hit_time, typehit_time;
 356 float nextsound_hit_time, nextsound_typehit_time;
 357 float hitindication_crosshair_time, hitindication_crosshair_size;
 358 float use_nex_chargepool;
 359
 360 float myhealth, myhealth_prev;
 361 float myhealth_flash;
 362
 363 float old_blurradius, old_bluralpha;
 364 float old_sharpen_intensity;
 365
 366 vector myhealth_gentlergb;
 367
 368 float contentavgalpha, liquidalpha_prev;
 369 vector liquidcolor_prev;
 370
 371 float eventchase_current_distance;
 372
 373 vector damage_blurpostprocess, content_blurpostprocess;
 374
 375 float checkfail[16];
 376
 377 #define BUTTON_3 4
 378 #define BUTTON_4 8
 379 float cl_notice_run();
 380 void CSQC_UpdateView(float w, float h)
 381 {
 382         entity e;
 383         float fov;
 384         float f, i, j;
 385         vector v;
 386         vector vf_size, vf_min;
 387         float a;
 388
 389         execute_next_frame();
 390
 391         ++framecount;
 392
 393         hud = getstati(STAT_HUD);
 394
 395         if(autocvar__hud_showbinds_reload) // menu can set this one
 396         {
 397                 db_close(binddb);
 398                 binddb = db_create();
 399                 cvar_set("_hud_showbinds_reload", "0");
 400         }
 401
 402         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 403                 view_quality = getproperty(VF_MINFPS_QUALITY);
 404         else
 405                 view_quality = 1;
 406
 407         button_attack2 = (input_buttons & BUTTON_3);
 408         button_zoom = (input_buttons & BUTTON_4);
 409
 410         // FIXME do we need this hack?
 411         if(isdemo())
 412         {
 413                 // in demos, input_buttons do not work
 414                 button_zoom = (autocvar__togglezoom == "-");
 415         }
 416
 417 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 418         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 419         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 420         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 421         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 422         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 423         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 424         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 425
 426         vf_size = getpropertyvec(VF_SIZE);
 427         vf_min = getpropertyvec(VF_MIN);
 428         vid_width = vf_size_x;
 429         vid_height = vf_size_y;
 430
 431         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 432         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 433
 434         WaypointSprite_Load();
 435
 436         CSQCPlayer_SetCamera();
 437
 438 #ifdef COMPAT_XON050_ENGINE
 439         if(spectatee_status)
 440                 myteam = GetPlayerColor(spectatee_status - 1);
 441         else
 442 #endif
 443                 myteam = GetPlayerColor(player_localentnum - 1);
 444
 445         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 446
 447         // event chase camera
 448         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 449         {
 450                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 451                 {
 452                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 453                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 454
 455                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 456                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 457                         if(!autocvar_chase_active)
 458                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 459
 460                         // make the camera smooth back
 461                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 462                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 463                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 464                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 465
 466                         vector eventchase_target_origin;
 467                         makevectors(view_angles);
 468                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 469                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 470                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 471                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 472                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 473                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 474                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 475
 476                         setproperty(VF_ORIGIN, trace_endpos);
 477                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 478                 }
 479                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 480                 {
 481                         cvar_set("chase_active", "0");
 482                         eventchase_current_distance = 0; // start from 0 next time
 483                 }
 484         }
 485         // workaround for camera stuck between player's legs when using chase_active 1
 486         // because the engine stops updating the chase_active camera when the game ends
 487         else if(intermission)
 488         {
 489                 cvar_settemp("chase_active", "-1");
 490                 eventchase_current_distance = 0;
 491         }
 492
 493         // do lockview after event chase camera so that it still applies whenever necessary.
 494         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 495         {
 496                 setproperty(VF_ORIGIN, freeze_org);
 497                 setproperty(VF_ANGLES, freeze_ang);
 498         }
 499         else
 500         {
 501                 freeze_org = getpropertyvec(VF_ORIGIN);
 502                 freeze_ang = getpropertyvec(VF_ANGLES);
 503         }
 504
 505         WarpZone_FixView();
 506         //WarpZone_FixPMove();
 507
 508         // Render the Scene
 509         view_origin = getpropertyvec(VF_ORIGIN);
 510         view_angles = getpropertyvec(VF_ANGLES);
 511         makevectors(view_angles);
 512         view_forward = v_forward;
 513         view_right = v_right;
 514         view_up = v_up;
 515
 516 #ifdef BLURTEST
 517         if(time > blurtest_time0 && time < blurtest_time1)
 518         {
 519                 float r, t;
 520
 521                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 522                 r = t * blurtest_radius;
 523                 f = 1 / pow(t, blurtest_power) - 1;
 524
 525                 cvar_set("r_glsl_postprocess", "1");
 526                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 527         }
 528         else
 529         {
 530                 cvar_set("r_glsl_postprocess", "0");
 531                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 532         }
 533 #endif
 534
 535         TargetMusic_Advance();
 536         Fog_Force();
 537
 538         if(drawtime == 0)
 539                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 540         else
 541                 drawframetime = bound(0.000001, time - drawtime, 1);
 542         drawtime = time;
 543
 544         // watch for gametype changes here...
 545         // in ParseStuffCMD the cmd isn't executed yet :/
 546         // might even be better to add the gametype to TE_CSQC_INIT...?
 547         if(!postinit)
 548                 PostInit();
 549
 550         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 551         {
 552                 if(calledhooks & HOOK_START)
 553                 {
 554                         localcmd("\ncl_hook_gameend\n");
 555                         calledhooks |= HOOK_END;
 556                 }
 557         }
 558
 559         Announcer();
 560
 561         fov = autocvar_fov;
 562         if(fov <= 59.5)
 563         {
 564                 if(!zoomscript_caught)
 565                 {
 566                         localcmd("+button9\n");
 567                         zoomscript_caught = 1;
 568                 }
 569         }
 570         else
 571         {
 572                 if(zoomscript_caught)
 573                 {
 574                         localcmd("-button9\n");
 575                         zoomscript_caught = 0;
 576                 }
 577         }
 578
 579         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 580
 581         // next WANTED weapon (for HUD)
 582         switchweapon = getstati(STAT_SWITCHWEAPON);
 583
 584         // currently switching-to weapon (for crosshair)
 585         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 586
 587         // actually active weapon (for zoom)
 588         activeweapon = getstati(STAT_ACTIVEWEAPON);
 589
 590         f = (serverflags & SERVERFLAG_TEAMPLAY);
 591         if(f != teamplay)
 592         {
 593                 teamplay = f;
 594                 HUD_InitScores();
 595         }
 596
 597         if(last_switchweapon != switchweapon) {
 598                 weapontime = time;
 599                 last_switchweapon = switchweapon;
 600         }
 601         if(last_activeweapon != activeweapon) {
 602                 last_activeweapon = activeweapon;
 603
 604                 e = get_weaponinfo(activeweapon);
 605                 if(e.netname != "")
 606                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 607                 else
 608                         localcmd("\ncl_hook_activeweapon none\n");
 609         }
 610
 611         // ALWAYS Clear Current Scene First
 612         clearscene();
 613 #ifdef WORKAROUND_XON010
 614         if(checkextension("DP_CSQC_ROTATEMOVES"))
 615         {
 616 #endif
 617         setproperty(VF_ORIGIN, view_origin);
 618         setproperty(VF_ANGLES, view_angles);
 619 #ifdef WORKAROUND_XON010
 620         }
 621 #endif
 622
 623         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 624         setproperty(VF_SIZE, vf_size);
 625         setproperty(VF_MIN, vf_min);
 626
 627         // Assign Standard Viewflags
 628         // Draw the World (and sky)
 629         setproperty(VF_DRAWWORLD, 1);
 630
 631         // Set the console size vars
 632         vid_conwidth = autocvar_vid_conwidth;
 633         vid_conheight = autocvar_vid_conheight;
 634         vid_pixelheight = autocvar_vid_pixelheight;
 635
 636         setproperty(VF_FOV, GetCurrentFov(fov));
 637
 638         // Camera for demo playback
 639         if(camera_active)
 640         {
 641                 if(autocvar_camera_enable)
 642                         CSQC_Demo_Camera();
 643                 else
 644                 {
 645                         cvar_set("chase_active", ftos(chase_active_backup));
 646                         cvar_set("cl_demo_mousegrab", "0");
 647                         camera_active = FALSE;
 648                 }
 649         }
 650 #ifdef CAMERATEST
 651         else if(autocvar_camera_enable)
 652 #else
 653         else if(autocvar_camera_enable && isdemo())
 654 #endif
 655         {
 656                 // Enable required Darkplaces cvars
 657                 chase_active_backup = autocvar_chase_active;
 658                 cvar_set("chase_active", "2");
 659                 cvar_set("cl_demo_mousegrab", "1");
 660                 camera_active = TRUE;
 661                 camera_mode = FALSE;
 662         }
 663
 664         // Draw the Crosshair
 665         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 666
 667         // Draw the Engine Status Bar (the default Quake HUD)
 668         setproperty(VF_DRAWENGINESBAR, 0);
 669
 670         // Update the mouse position
 671         /*
 672            mousepos_x = vid_conwidth;
 673            mousepos_y = vid_conheight;
 674            mousepos = mousepos*0.5 + getmousepos();
 675          */
 676
 677         e = self;
 678         for(self = world; (self = nextent(self)); )
 679                 if(self.draw)
 680                         self.draw();
 681         self = e;
 682
 683         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 684         renderscene();
 685
 686         // now switch to 2D drawing mode by calling a 2D drawing function
 687         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 688         // next R_RenderScene call
 689         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 690
 691         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 692         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 693         {
 694                 // apply night vision effect
 695                 vector tc_00, tc_01, tc_10, tc_11;
 696                 vector rgb;
 697                 rgb_x = 0; // fteqcc sucks
 698                 rgb_y = 0; // fteqcc sucks
 699                 rgb_z = 0; // fteqcc sucks
 700
 701                 if(!nightvision_noise)
 702                 {
 703                         nightvision_noise = spawn();
 704                         nightvision_noise.classname = "nightvision_noise";
 705                 }
 706                 if(!nightvision_noise2)
 707                 {
 708                         nightvision_noise2 = spawn();
 709                         nightvision_noise2.classname = "nightvision_noise2";
 710                 }
 711
 712                 // color tint in yellow
 713                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 714
 715                 // draw BG
 716                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 717                 rgb = '1 1 1';
 718                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 719                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 720                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 721                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 722                 tc_11 = tc_01 + tc_10 - tc_00;
 723                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 724                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 725                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 726                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 727                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 728                 R_EndPolygon();
 729
 730                 // draw FG
 731                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 732                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 733                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 734                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 735                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 736                 tc_11 = tc_01 + tc_10 - tc_00;
 737                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 738                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 739                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 740                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 741                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 742                 R_EndPolygon();
 743         }
 744
 745         // Draw the aiming reticle for weapons that use it
 746         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 747         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 748         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 749         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 750                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 751         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 752                 reticle_type = 2; // nex zoom
 753         else if(button_zoom || zoomscript_caught)
 754                 reticle_type = 1; // normal zoom
 755         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 756                 reticle_type = 2; // nex zoom
 757
 758         if(reticle_type && autocvar_cl_reticle)
 759         {
 760                 if(autocvar_cl_reticle_stretch)
 761                 {
 762                         reticle_size_x = vid_conwidth;
 763                         reticle_size_y = vid_conheight;
 764                         reticle_pos_x = 0;
 765                         reticle_pos_y = 0;
 766                 }
 767                 else
 768                 {
 769                         reticle_size_x = max(vid_conwidth, vid_conheight);
 770                         reticle_size_y = max(vid_conwidth, vid_conheight);
 771                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 772                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 773                 }
 774
 775                 f = current_zoomfraction;
 776                 if(zoomscript_caught)
 777                         f = 1;
 778                 if(autocvar_cl_reticle_item_normal)
 779                 {
 780                         if(reticle_type == 1 && f)
 781                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 782                 }
 783                 if(autocvar_cl_reticle_item_nex)
 784                 {
 785                         if(reticle_type == 2 && f)
 786                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 787                 }
 788         }
 789
 790
 791         // improved polyblend
 792         if(autocvar_hud_contents)
 793         {
 794                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 795                 vector liquidcolor;
 796
 797                 switch(pointcontents(view_origin))
 798                 {
 799                         case CONTENT_WATER:
 800                                 liquidalpha = autocvar_hud_contents_water_alpha;
 801                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 802                                 incontent = 1;
 803                                 break;
 804
 805                         case CONTENT_LAVA:
 806                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 807                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 808                                 incontent = 1;
 809                                 break;
 810
 811                         case CONTENT_SLIME:
 812                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 813                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 814                                 incontent = 1;
 815                                 break;
 816
 817                         default:
 818                                 liquidalpha = 0;
 819                                 liquidcolor = '0 0 0';
 820                                 incontent = 0;
 821                                 break;
 822                 }
 823
 824                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 825                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 826                         contentfadetime = autocvar_hud_contents_fadeintime;
 827                         liquidalpha_prev = liquidalpha;
 828                         liquidcolor_prev = liquidcolor;
 829                 }
 830                 else
 831                         contentfadetime = autocvar_hud_contents_fadeouttime;
 832
 833                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 834                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 835
 836                 if(contentavgalpha)
 837                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 838
 839                 if(autocvar_hud_postprocessing)
 840                 {
 841                         if(autocvar_hud_contents_blur && contentavgalpha)
 842                         {
 843                                 content_blurpostprocess_x = 1;
 844                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 845                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 846                         }
 847                         else
 848                         {
 849                                 content_blurpostprocess_x = 0;
 850                                 content_blurpostprocess_y = 0;
 851                                 content_blurpostprocess_z = 0;
 852                         }
 853                 }
 854         }
 855
 856         if(autocvar_hud_damage)
 857         {
 858                 splash_size_x = max(vid_conwidth, vid_conheight);
 859                 splash_size_y = max(vid_conwidth, vid_conheight);
 860                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 861                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 862
 863                 float myhealth_flash_temp;
 864                 myhealth = getstati(STAT_HEALTH);
 865
 866                 // fade out
 867                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 868                 // add new damage
 869                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 870
 871                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 872                 pain_threshold = autocvar_hud_damage_pain_threshold;
 873                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 874                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 875
 876                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 877                 {
 878                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 879                 }
 880
 881                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 882
 883                 if(myhealth_prev < 1)
 884                 {
 885                         if(myhealth >= 1)
 886                         {
 887                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 888                                 myhealth_flash_temp = 0;
 889                         }
 890                         else
 891                         {
 892                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 893                         }
 894                 }
 895
 896                 if(spectatee_status == -1 || intermission)
 897                 {
 898                         myhealth_flash = 0; // observing, or match ended
 899                         myhealth_flash_temp = 0;
 900                 }
 901
 902                 myhealth_prev = myhealth;
 903
 904                 // IDEA: change damage color/picture based on player model for robot/alien species?
 905                 // pro: matches model better
 906                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 907                 // maybe different reddish pics?
 908                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 909                 {
 910                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 911                         {
 912                                 if(autocvar_cl_gentle_damage == 2)
 913                                 {
 914                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 915                                         {
 916                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 917                                         }
 918                                 }
 919                                 else
 920                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 921
 922                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 923                         }
 924                         else
 925                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 926                 }
 927
 928                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 929                 {
 930                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 931                         {
 932                                 damage_blurpostprocess_x = 1;
 933                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 934                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 935                         }
 936                         else
 937                         {
 938                                 damage_blurpostprocess_x = 0;
 939                                 damage_blurpostprocess_y = 0;
 940                                 damage_blurpostprocess_z = 0;
 941                         }
 942                 }
 943         }
 944
 945         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 946         float e2 = (autocvar_hud_powerup != 0);
 947         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 948         {
 949                 // enable or disable rendering types if they are used or not
 950                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 951                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 952
 953                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 954                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 955                 {
 956                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 957                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 958                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 959                         {
 960                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 961                                 old_blurradius = blurradius;
 962                                 old_bluralpha = bluralpha;
 963                         }
 964                 }
 965                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 966                 {
 967                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 968                         old_blurradius = 0;
 969                         old_bluralpha = 0;
 970                 }
 971
 972                 // edge detection postprocess handling done second (used by hud_powerup)
 973                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 974                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 975                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 976
 977                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 978
 979                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 980                 {
 981                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 982                         {
 983                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 984                                 old_sharpen_intensity = sharpen_intensity;
 985                         }
 986                 }
 987                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 988                 {
 989                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 990                         old_sharpen_intensity = 0;
 991                 }
 992
 993                 if(cvar("r_glsl_postprocess") == 0)
 994                         cvar_set("r_glsl_postprocess", "2");
 995         }
 996         else if(cvar("r_glsl_postprocess") == 2)
 997                 cvar_set("r_glsl_postprocess", "0");
 998
 999         if(menu_visible)
1000                 menu_show();
1001
1002         /*if(gametype == MAPINFO_TYPE_CTF)
1003           {
1004           ctf_view();
1005           } else */
1006
1007         // draw 2D entities
1008         e = self;
1009         for(self = world; (self = nextent(self)); )
1010                 if(self.draw2d)
1011                         self.draw2d();
1012         self = e;
1013         Draw_ShowNames_All();
1014
1015         scoreboard_active = HUD_WouldDrawScoreboard();
1016
1017         hit_time = getstatf(STAT_HIT_TIME);
1018         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1019         {
1020                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1021                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1022
1023                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1024         }
1025         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1026         if(typehit_time > nextsound_typehit_time)
1027         {
1028                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1029                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1030
1031                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1032         }
1033
1034         //else
1035         {
1036                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1037                 {
1038                         if(getstati(STAT_FROZEN))
1039                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1040                         if(getstatf(STAT_REVIVE_PROGRESS))
1041                         {
1042                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1043                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1044                         }
1045                 }
1046
1047                 if(autocvar_r_letterbox == 0)
1048                         if(autocvar_viewsize < 120)
1049                                 CSQC_common_hud();
1050
1051                 // crosshair goes VERY LAST
1052                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1053                 {
1054                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1055                                 return;
1056
1057                         string wcross_style;
1058                         float wcross_alpha, wcross_resolution;
1059                         wcross_style = autocvar_crosshair;
1060                         if (wcross_style == "0")
1061                                 return;
1062                         wcross_resolution = autocvar_crosshair_size;
1063                         if (wcross_resolution == 0)
1064                                 return;
1065                         wcross_alpha = autocvar_crosshair_alpha;
1066                         if (wcross_alpha == 0)
1067                                 return;
1068
1069                         // TrueAim check
1070                         float shottype;
1071
1072                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1073                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1074                         wcross_origin_z = 0;
1075                         if(autocvar_crosshair_hittest)
1076                         {
1077                                 vector wcross_oldorigin;
1078                                 wcross_oldorigin = wcross_origin;
1079                                 shottype = TrueAimCheck();
1080                                 if(shottype == SHOTTYPE_HITWORLD)
1081                                 {
1082                                         v = wcross_origin - wcross_oldorigin;
1083                                         v_x /= vid_conwidth;
1084                                         v_y /= vid_conheight;
1085                                         if(vlen(v) > 0.01)
1086                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1087                                 }
1088                                 if(!autocvar_crosshair_hittest_showimpact)
1089                                         wcross_origin = wcross_oldorigin;
1090                         }
1091                         else
1092                                 shottype = SHOTTYPE_HITWORLD;
1093
1094                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1095                         string wcross_wep = "", wcross_name;
1096                         float wcross_scale, wcross_blur;
1097
1098                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1099                                 e = get_weaponinfo(switchingweapon);
1100                                 if (e && e.netname != "")
1101                                 {
1102                                         wcross_wep = e.netname;
1103                                         if(autocvar_crosshair_per_weapon)
1104                                         {
1105                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1106                                                 if (wcross_resolution == 0)
1107                                                         return;
1108                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1109                                                 if (wcross_alpha == 0)
1110                                                         return;
1111
1112                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1113                                                 if(wcross_style == "" || wcross_style == "0")
1114                                                         wcross_style = wcross_wep;
1115                                         }
1116                                 }
1117                         }
1118                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1119                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1120                         else if(autocvar_crosshair_color_by_health)
1121                         {
1122                                 float x = getstati(STAT_HEALTH);
1123
1124                                 //x = red
1125                                 //y = green
1126                                 //z = blue
1127
1128                                 wcross_color_z = 0;
1129
1130                                 if(x > 200)
1131                                 {
1132                                         wcross_color_x = 0;
1133                                         wcross_color_y = 1;
1134                                 }
1135                                 else if(x > 150)
1136                                 {
1137                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1138                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1139                                 }
1140                                 else if(x > 100)
1141                                 {
1142                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1143                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1144                                         wcross_color_z = 1 - (x-100)*0.02;
1145                                 }
1146                                 else if(x > 50)
1147                                 {
1148                                         wcross_color_x = 1;
1149                                         wcross_color_y = 1;
1150                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1151                                 }
1152                                 else if(x > 20)
1153                                 {
1154                                         wcross_color_x = 1;
1155                                         wcross_color_y = (x-20)*90/27/100;
1156                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1157                                 }
1158                                 else
1159                                 {
1160                                         wcross_color_x = 1;
1161                                         wcross_color_y = 0;
1162                                 }
1163                         }
1164                         else
1165                                 wcross_color = stov(autocvar_crosshair_color);
1166
1167                         wcross_name = strcat("gfx/crosshair", wcross_style);
1168
1169                         if(autocvar_crosshair_effect_scalefade)
1170                         {
1171                                 wcross_scale = wcross_resolution;
1172                                 wcross_resolution = 1;
1173                         }
1174                         else
1175                         {
1176                                 wcross_scale = 1;
1177                         }
1178
1179                         if(autocvar_crosshair_pickup)
1180                         {
1181                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1182
1183                                 if(pickup_crosshair_time < stat_pickup_time)
1184                                 {
1185                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1186                                                 pickup_crosshair_size = 1;
1187
1188                                         pickup_crosshair_time = stat_pickup_time;
1189                                 }
1190
1191                                 if(pickup_crosshair_size > 0)
1192                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1193                                 else
1194                                         pickup_crosshair_size = 0;
1195
1196                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1197                         }
1198
1199                         if(autocvar_crosshair_hitindication)
1200                         {
1201                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1202
1203                                 if(hitindication_crosshair_time < hit_time)
1204                                 {
1205                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1206                                                 hitindication_crosshair_size = 1;
1207
1208                                         hitindication_crosshair_time = hit_time;
1209                                 }
1210
1211                                 if(hitindication_crosshair_size > 0)
1212                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1213                                 else
1214                                         hitindication_crosshair_size = 0;
1215
1216                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1217                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1218                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1219                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1220                         }
1221
1222                         if(shottype == SHOTTYPE_HITENEMY)
1223                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1224                         if(shottype == SHOTTYPE_HITTEAM)
1225                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1226
1227                         f = autocvar_crosshair_effect_speed;
1228                         if(f < 0)
1229                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1230                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1231                         {
1232                                 wcross_changedonetime = time + f;
1233                         }
1234                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1235                         {
1236                                 wcross_name_changestarttime = time;
1237                                 wcross_name_changedonetime = time + f;
1238                                 if(wcross_name_goal_prev_prev)
1239                                         strunzone(wcross_name_goal_prev_prev);
1240                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1241                                 wcross_name_goal_prev = strzone(wcross_name);
1242                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1243                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1244                                 wcross_resolution_goal_prev = wcross_resolution;
1245                         }
1246
1247                         wcross_scale_goal_prev = wcross_scale;
1248                         wcross_alpha_goal_prev = wcross_alpha;
1249                         wcross_color_goal_prev = wcross_color;
1250
1251                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1252                         {
1253                                 wcross_blur = 1;
1254                                 wcross_alpha *= 0.75;
1255                         }
1256                         else
1257                                 wcross_blur = 0;
1258                         // *_prev is at time-frametime
1259                         // * is at wcross_changedonetime+f
1260                         // what do we have at time?
1261                         if(time < wcross_changedonetime)
1262                         {
1263                                 f = frametime / (wcross_changedonetime - time + frametime);
1264                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1265                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1266                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1267                         }
1268
1269                         wcross_scale_prev = wcross_scale;
1270                         wcross_alpha_prev = wcross_alpha;
1271                         wcross_color_prev = wcross_color;
1272
1273                         wcross_scale *= 1 - autocvar__menu_alpha;
1274                         wcross_alpha *= 1 - autocvar__menu_alpha;
1275                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1276
1277                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1278                         {
1279                                 // crosshair rings for weapon stats
1280                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1281                                 {
1282                                         // declarations and stats
1283                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1284                                         string ring_image = string_null, ring_inner_image = string_null;
1285                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1286
1287                                         ring_scale = autocvar_crosshair_ring_size;
1288
1289                                         float weapon_clipload, weapon_clipsize;
1290                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1291                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1292
1293                                         float nex_charge, nex_chargepool;
1294                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1295                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1296
1297                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1298                                                 nex_charge_movingavg = nex_charge;
1299
1300
1301                                         // handle the values
1302                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1303                                         {
1304                                                 if (nex_chargepool || use_nex_chargepool) {
1305                                                         use_nex_chargepool = 1;
1306                                                         ring_inner_value = nex_chargepool;
1307                                                 } else {
1308                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1309                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1310                                                 }
1311
1312                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1313                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1314                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1315
1316                                                 // draw the outer ring to show the current charge of the weapon
1317                                                 ring_value = nex_charge;
1318                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1319                                                 ring_rgb = wcross_color;
1320                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1321                                         }
1322                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1323                                         {
1324                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1325                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1326                                                 ring_rgb = wcross_color;
1327                                                 ring_image = "gfx/crosshair_ring.tga";
1328                                         }
1329                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1330                                         {
1331                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1332                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1333                                                 ring_rgb = wcross_color;
1334                                                 ring_image = "gfx/crosshair_ring.tga";
1335                                         }
1336
1337                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1338                                         {
1339                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1340                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1341                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1342                                                 ring_rgb = wcross_color;
1343
1344                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1345                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1346                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1347                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1348                                                 else
1349                                                         ring_image = "gfx/crosshair_ring.tga";
1350                                         }
1351
1352                                         // if in weapon switch animation, fade ring out/in
1353                                         if(g_weaponswitchdelay > 0)
1354                                         {
1355                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1356                                                 if(f > 0 && f < 2)
1357                                                         ring_alpha *= fabs(1 - f);
1358                                         }
1359
1360                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1361                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1362
1363                                         if (ring_value)
1364                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1365                                 }
1366
1367 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1368                                 do \
1369                                 { \
1370                                         if(wcross_blur > 0) \
1371                                         { \
1372                                                 for(i = -2; i <= 2; ++i) \
1373                                                 for(j = -2; j <= 2; ++j) \
1374                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1375                                         } \
1376                                         else \
1377                                         { \
1378                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1379                                         } \
1380                                 } \
1381                                 while(0)
1382
1383 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1384                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1385
1386 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1387                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1388
1389                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1390                                 {
1391                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1392                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1393                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1394                                         f = 1 - f;
1395                                 }
1396                                 else
1397                                 {
1398                                         f = 1;
1399                                 }
1400                                 wcross_name_alpha_goal_prev = f;
1401
1402                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1403                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1404
1405                                 if(autocvar_crosshair_dot)
1406                                 {
1407                                         vector wcross_color_old;
1408                                         wcross_color_old = wcross_color;
1409
1410                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1411                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1412
1413                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1414                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1415                                         wcross_color = wcross_color_old;
1416                                 }
1417                         }
1418                 }
1419                 else
1420                 {
1421                         wcross_scale_prev = 0;
1422                         wcross_alpha_prev = 0;
1423                         wcross_scale_goal_prev = 0;
1424                         wcross_alpha_goal_prev = 0;
1425                         wcross_changedonetime = 0;
1426                         if(wcross_name_goal_prev)
1427                                 strunzone(wcross_name_goal_prev);
1428                         wcross_name_goal_prev = string_null;
1429                         if(wcross_name_goal_prev_prev)
1430                                 strunzone(wcross_name_goal_prev_prev);
1431                         wcross_name_goal_prev_prev = string_null;
1432                         wcross_name_changestarttime = 0;
1433                         wcross_name_changedonetime = 0;
1434                         wcross_name_alpha_goal_prev = 0;
1435                         wcross_name_alpha_goal_prev_prev = 0;
1436                         wcross_resolution_goal_prev = 0;
1437                         wcross_resolution_goal_prev_prev = 0;
1438                 }
1439         }
1440
1441         if(NextFrameCommand)
1442         {
1443                 localcmd("\n", NextFrameCommand, "\n");
1444                 NextFrameCommand = string_null;
1445         }
1446
1447         // we must do this check AFTER a frame was rendered, or it won't work
1448         if(cs_project_is_b0rked == 0)
1449         {
1450                 string w0, h0;
1451                 w0 = ftos(autocvar_vid_conwidth);
1452                 h0 = ftos(autocvar_vid_conheight);
1453                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1454                 //setproperty(VF_FOV, '90 90 0');
1455                 setproperty(VF_ORIGIN, '0 0 0');
1456                 setproperty(VF_ANGLES, '0 0 0');
1457                 setproperty(VF_PERSPECTIVE, 1);
1458                 makevectors('0 0 0');
1459                 vector v1, v2;
1460                 cvar_set("vid_conwidth", "800");
1461                 cvar_set("vid_conheight", "600");
1462                 v1 = cs_project(v_forward);
1463                 cvar_set("vid_conwidth", "640");
1464                 cvar_set("vid_conheight", "480");
1465                 v2 = cs_project(v_forward);
1466                 if(v1 == v2)
1467                         cs_project_is_b0rked = 1;
1468                 else
1469                         cs_project_is_b0rked = -1;
1470                 cvar_set("vid_conwidth", w0);
1471                 cvar_set("vid_conheight", h0);
1472         }
1473
1474         if(autocvar__hud_configure)
1475                 HUD_Panel_Mouse();
1476
1477     if(hud && !intermission)
1478     {
1479         if(hud == HUD_SPIDERBOT)
1480             CSQC_SPIDER_HUD();
1481         else if(hud == HUD_WAKIZASHI)
1482             CSQC_WAKIZASHI_HUD();
1483         else if(hud == HUD_RAPTOR)
1484             CSQC_RAPTOR_HUD();
1485         else if(hud == HUD_BUMBLEBEE)
1486             CSQC_BUMBLE_HUD();
1487         else if(hud == HUD_BUMBLEBEE_GUN)
1488             CSQC_BUMBLE_GUN_HUD();
1489     }
1490
1491         cl_notice_run();
1492
1493         // let's reset the view back to normal for the end
1494         setproperty(VF_MIN, '0 0 0');
1495         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1496 }
1497
1498
1499 void CSQC_common_hud(void)
1500 {
1501     // do some accuracy var caching
1502     float i;
1503     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1504     {
1505         if(autocvar_accuracy_color_levels != acc_color_levels)
1506         {
1507             if(acc_color_levels)
1508                 strunzone(acc_color_levels);
1509             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1510             acc_levels = tokenize_console(acc_color_levels);
1511             if (acc_levels > MAX_ACCURACY_LEVELS)
1512                 acc_levels = MAX_ACCURACY_LEVELS;
1513
1514             for (i = 0; i < acc_levels; ++i)
1515                 acc_lev[i] = stof(argv(i)) / 100.0;
1516         }
1517         // let know that acc_col[] needs to be loaded
1518         acc_col[0] = '-1 0 0';
1519     }
1520
1521     HUD_Main(); // always run these functions for alpha checks
1522     HUD_DrawScoreboard();
1523
1524     if (scoreboard_active) // scoreboard/accuracy
1525         HUD_Reset();
1526     else if (intermission == 2) // map voting screen
1527     {
1528         HUD_FinaleOverlay();
1529         HUD_Reset();
1530     }
1531         /*
1532         switch(hud)
1533         {
1534                 case HUD_SPIDERBOT:
1535                         CSQC_SPIDER_HUD();
1536                         break;
1537
1538                 case HUD_WAKIZASHI:
1539                         CSQC_WAKIZASHI_HUD();
1540                         break;
1541
1542         case HUD_BUMBLEBEE:
1543             CSQC_BUMBLE_HUD();
1544             break;
1545         }
1546         */
1547 }
1548
1549
1550 // following vectors must be global to allow seamless switching between camera modes
1551 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1552 void CSQC_Demo_Camera()
1553 {
1554         float speed, attenuation, dimensions;
1555         vector tmp, delta;
1556
1557         if( autocvar_camera_reset || !camera_mode )
1558         {
1559                 camera_offset = '0 0 0';
1560                 current_angles = '0 0 0';
1561                 camera_direction = '0 0 0';
1562                 camera_offset_z += 30;
1563                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1564                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1565                 current_origin = view_origin;
1566                 current_camera_offset  = camera_offset;
1567                 cvar_set("camera_reset", "0");
1568                 camera_mode = CAMERA_CHASE;
1569         }
1570
1571         // Camera angles
1572         if( camera_roll )
1573                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1574
1575         if(autocvar_camera_look_player)
1576         {
1577                 vector dir;
1578                 float n;
1579
1580                 dir = normalize(view_origin - current_position);
1581                 n = mouse_angles_z;
1582                 mouse_angles = vectoangles(dir);
1583                 mouse_angles_x = mouse_angles_x * -1;
1584                 mouse_angles_z = n;
1585         }
1586         else
1587         {
1588                 tmp = getmousepos() * 0.1;
1589                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1590                 {
1591                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1592                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1593                 }
1594         }
1595
1596         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1597         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1598         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1599         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1600
1601         // Fix difference when angles don't have the same sign
1602         delta = '0 0 0';
1603         if(mouse_angles_y < -60 && current_angles_y > 60)
1604                 delta = '0 360 0';
1605         if(mouse_angles_y > 60 && current_angles_y < -60)
1606                 delta = '0 -360 0';
1607
1608         if(autocvar_camera_look_player)
1609                 attenuation = autocvar_camera_look_attenuation;
1610         else
1611                 attenuation = autocvar_camera_speed_attenuation;
1612
1613         attenuation = 1 / max(1, attenuation);
1614         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1615
1616         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1617         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1618         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1619         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1620
1621         // Camera position
1622         tmp = '0 0 0';
1623         dimensions = 0;
1624
1625         if( camera_direction_x )
1626         {
1627                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1628                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1629                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1630                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1631                 ++dimensions;
1632         }
1633
1634         if( camera_direction_y )
1635         {
1636                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1637                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1638                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1639                 ++dimensions;
1640         }
1641
1642         if( camera_direction_z )
1643         {
1644                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1645                 ++dimensions;
1646         }
1647
1648         if(autocvar_camera_free)
1649                 speed = autocvar_camera_speed_free;
1650         else
1651                 speed = autocvar_camera_speed_chase;
1652
1653         if(dimensions)
1654         {
1655                 speed = speed * sqrt(1 / dimensions);
1656                 camera_offset += tmp * speed;
1657         }
1658
1659         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1660
1661         // Camera modes
1662         if( autocvar_camera_free )
1663         {
1664                 if ( camera_mode == CAMERA_CHASE )
1665                 {
1666                         current_camera_offset = current_origin + current_camera_offset;
1667                         camera_offset = current_origin + camera_offset;
1668                 }
1669
1670                 camera_mode = CAMERA_FREE;
1671                 current_position = current_camera_offset;
1672         }
1673         else
1674         {
1675                 if ( camera_mode == CAMERA_FREE )
1676                 {
1677                         current_origin = view_origin;
1678                         camera_offset = camera_offset - current_origin;
1679                         current_camera_offset = current_camera_offset - current_origin;
1680                 }
1681
1682                 camera_mode = CAMERA_CHASE;
1683
1684                 if(autocvar_camera_chase_smoothly)
1685                         current_origin += (view_origin - current_origin) * attenuation;
1686                 else
1687                         current_origin = view_origin;
1688
1689                 current_position = current_origin + current_camera_offset;
1690         }
1691
1692         setproperty(VF_ANGLES, current_angles);
1693         setproperty(VF_ORIGIN, current_position);
1694 }