qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float CAMERA_FREE = 1;
 331 float CAMERA_CHASE = 2;
 332 float reticle_type;
 333 string NextFrameCommand;
 334 void CSQC_SPIDER_HUD();
 335 void CSQC_RAPTOR_HUD();
 336
 337 vector freeze_org, freeze_ang;
 338 entity nightvision_noise, nightvision_noise2;
 339
 340 #define MAX_TIME_DIFF 5
 341 float pickup_crosshair_time, pickup_crosshair_size;
 342 float hit_time, typehit_time;
 343 float nextsound_hit_time, nextsound_typehit_time;
 344 float hitindication_crosshair_time, hitindication_crosshair_size;
 345 float use_nex_chargepool;
 346
 347 float myhealth, myhealth_prev;
 348 float myhealth_flash;
 349
 350 float old_blurradius, old_bluralpha;
 351 float old_sharpen_intensity;
 352
 353 vector myhealth_gentlergb;
 354
 355 float contentavgalpha, liquidalpha_prev;
 356 vector liquidcolor_prev;
 357
 358 float eventchase_current_distance;
 359
 360 vector damage_blurpostprocess, content_blurpostprocess;
 361
 362 float checkfail[16];
 363
 364 #define BUTTON_3 4
 365 #define BUTTON_4 8
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v;
 372         vector vf_size, vf_min;
 373         float a;
 374
 375         ++framecount;
 376
 377         hud = getstati(STAT_HUD);
 378
 379         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 380                 view_quality = getproperty(VF_MINFPS_QUALITY);
 381         else
 382                 view_quality = 1;
 383
 384         button_attack2 = (input_buttons & BUTTON_3);
 385         button_zoom = (input_buttons & BUTTON_4);
 386
 387         // FIXME do we need this hack?
 388         if(isdemo())
 389         {
 390                 // in demos, input_buttons do not work
 391                 button_zoom = (autocvar__togglezoom == "-");
 392         }
 393
 394 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 395         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 396         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 397         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 398         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 399         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 400         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 401         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 402
 403         vf_size = getpropertyvec(VF_SIZE);
 404         vf_min = getpropertyvec(VF_MIN);
 405         vid_width = vf_size_x;
 406         vid_height = vf_size_y;
 407
 408         vector reticle_pos, reticle_size;
 409         vector splash_pos, splash_size;
 410
 411         WaypointSprite_Load();
 412
 413         CSQCPlayer_SetCamera();
 414
 415 #ifdef COMPAT_XON050_ENGINE
 416         if(spectatee_status)
 417                 myteam = GetPlayerColor(spectatee_status - 1);
 418         else
 419 #endif
 420                 myteam = GetPlayerColor(player_localentnum - 1);
 421
 422         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 423
 424         // event chase camera
 425         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 426         {
 427                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 428                 {
 429                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 430                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 431
 432                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 433                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 434                         if(!autocvar_chase_active)
 435                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 436
 437                         // make the camera smooth back
 438                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 439                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 440                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 441                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 442
 443                         vector eventchase_target_origin;
 444                         makevectors(view_angles);
 445                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 446                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 447                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 448                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 449                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 450                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 451                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 452
 453                         setproperty(VF_ORIGIN, trace_endpos);
 454                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 455                 }
 456                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 457                 {
 458                         cvar_set("chase_active", "0");
 459                         eventchase_current_distance = 0; // start from 0 next time
 460                 }
 461         }
 462
 463         // do lockview after event chase camera so that it still applies whenever necessary.
 464         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 465         {
 466                 setproperty(VF_ORIGIN, freeze_org);
 467                 setproperty(VF_ANGLES, freeze_ang);
 468         }
 469         else
 470         {
 471                 freeze_org = getpropertyvec(VF_ORIGIN);
 472                 freeze_ang = getpropertyvec(VF_ANGLES);
 473         }
 474
 475         WarpZone_FixView();
 476         //WarpZone_FixPMove();
 477
 478         // Render the Scene
 479         view_origin = getpropertyvec(VF_ORIGIN);
 480         view_angles = getpropertyvec(VF_ANGLES);
 481         makevectors(view_angles);
 482         view_forward = v_forward;
 483         view_right = v_right;
 484         view_up = v_up;
 485
 486 #ifdef BLURTEST
 487         if(time > blurtest_time0 && time < blurtest_time1)
 488         {
 489                 float r, t;
 490
 491                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 492                 r = t * blurtest_radius;
 493                 f = 1 / pow(t, blurtest_power) - 1;
 494
 495                 cvar_set("r_glsl_postprocess", "1");
 496                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 497         }
 498         else
 499         {
 500                 cvar_set("r_glsl_postprocess", "0");
 501                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 502         }
 503 #endif
 504
 505         TargetMusic_Advance();
 506         Fog_Force();
 507
 508         if(drawtime == 0)
 509                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 510         else
 511                 drawframetime = bound(0.000001, time - drawtime, 1);
 512         drawtime = time;
 513
 514         // watch for gametype changes here...
 515         // in ParseStuffCMD the cmd isn't executed yet :/
 516         // might even be better to add the gametype to TE_CSQC_INIT...?
 517         if(!postinit)
 518                 PostInit();
 519
 520         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 521         {
 522                 if(calledhooks & HOOK_START)
 523                 {
 524                         localcmd("\ncl_hook_gameend\n");
 525                         calledhooks |= HOOK_END;
 526                 }
 527         }
 528
 529   Announcer();
 530
 531         fov = autocvar_fov;
 532         if(fov <= 59.5)
 533         {
 534                 if(!zoomscript_caught)
 535                 {
 536                         localcmd("+button9\n");
 537                         zoomscript_caught = 1;
 538                 }
 539         }
 540         else
 541         {
 542                 if(zoomscript_caught)
 543                 {
 544                         localcmd("-button9\n");
 545                         zoomscript_caught = 0;
 546                 }
 547         }
 548
 549         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 550
 551         // next WANTED weapon (for HUD)
 552         switchweapon = getstati(STAT_SWITCHWEAPON);
 553
 554         // currently switching-to weapon (for crosshair)
 555         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 556
 557         // actually active weapon (for zoom)
 558         activeweapon = getstati(STAT_ACTIVEWEAPON);
 559
 560         f = (serverflags & SERVERFLAG_TEAMPLAY);
 561         if(f != teamplay)
 562         {
 563                 teamplay = f;
 564                 HUD_InitScores();
 565         }
 566
 567         if(last_switchweapon != switchweapon) {
 568                 weapontime = time;
 569                 last_switchweapon = switchweapon;
 570         }
 571         if(last_activeweapon != activeweapon) {
 572                 last_activeweapon = activeweapon;
 573
 574                 e = get_weaponinfo(activeweapon);
 575                 if(e.netname != "")
 576                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 577                 else
 578                         localcmd("\ncl_hook_activeweapon none\n");
 579         }
 580
 581         // ALWAYS Clear Current Scene First
 582         clearscene();
 583 #ifdef WORKAROUND_XON010
 584         if(checkextension("DP_CSQC_ROTATEMOVES"))
 585         {
 586 #endif
 587         setproperty(VF_ORIGIN, view_origin);
 588         setproperty(VF_ANGLES, view_angles);
 589 #ifdef WORKAROUND_XON010
 590         }
 591 #endif
 592
 593         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 594         setproperty(VF_SIZE, vf_size);
 595         setproperty(VF_MIN, vf_min);
 596
 597         // Assign Standard Viewflags
 598         // Draw the World (and sky)
 599         setproperty(VF_DRAWWORLD, 1);
 600
 601         // Set the console size vars
 602         vid_conwidth = autocvar_vid_conwidth;
 603         vid_conheight = autocvar_vid_conheight;
 604         vid_pixelheight = autocvar_vid_pixelheight;
 605
 606         setproperty(VF_FOV, GetCurrentFov(fov));
 607
 608         // Camera for demo playback
 609         if(camera_active)
 610         {
 611                 if(autocvar_camera_enable)
 612                         CSQC_Demo_Camera();
 613                 else
 614                 {
 615                         cvar_set("chase_active", ftos(chase_active_backup));
 616                         cvar_set("cl_demo_mousegrab", "0");
 617                         camera_active = FALSE;
 618                 }
 619         }
 620 #ifdef CAMERATEST
 621         else if(autocvar_camera_enable)
 622 #else
 623         else if(autocvar_camera_enable && isdemo())
 624 #endif
 625         {
 626                 // Enable required Darkplaces cvars
 627                 chase_active_backup = autocvar_chase_active;
 628                 cvar_set("chase_active", "2");
 629                 cvar_set("cl_demo_mousegrab", "1");
 630                 camera_active = TRUE;
 631                 camera_mode = FALSE;
 632         }
 633
 634         // Draw the Crosshair
 635         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 636
 637         // Draw the Engine Status Bar (the default Quake HUD)
 638         setproperty(VF_DRAWENGINESBAR, 0);
 639
 640         // Update the mouse position
 641         /*
 642            mousepos_x = vid_conwidth;
 643            mousepos_y = vid_conheight;
 644            mousepos = mousepos*0.5 + getmousepos();
 645          */
 646
 647         e = self;
 648         for(self = world; (self = nextent(self)); )
 649                 if(self.draw)
 650                         self.draw();
 651         self = e;
 652
 653         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 654         renderscene();
 655
 656         // now switch to 2D drawing mode by calling a 2D drawing function
 657         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 658         // next R_RenderScene call
 659         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 660
 661         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 662         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 663         {
 664                 // apply night vision effect
 665                 vector tc_00, tc_01, tc_10, tc_11;
 666                 vector rgb;
 667                 rgb_x = 0; // fteqcc sucks
 668                 rgb_y = 0; // fteqcc sucks
 669                 rgb_z = 0; // fteqcc sucks
 670
 671                 if(!nightvision_noise)
 672                 {
 673                         nightvision_noise = spawn();
 674                         nightvision_noise.classname = "nightvision_noise";
 675                 }
 676                 if(!nightvision_noise2)
 677                 {
 678                         nightvision_noise2 = spawn();
 679                         nightvision_noise2.classname = "nightvision_noise2";
 680                 }
 681
 682                 // color tint in yellow
 683                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 684
 685                 // draw BG
 686                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 687                 rgb = '1 1 1';
 688                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 689                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 690                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 691                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 692                 tc_11 = tc_01 + tc_10 - tc_00;
 693                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 694                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 695                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 696                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 697                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 698                 R_EndPolygon();
 699
 700                 // draw FG
 701                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 702                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 703                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 704                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 705                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 706                 tc_11 = tc_01 + tc_10 - tc_00;
 707                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 708                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 709                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 710                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 711                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 712                 R_EndPolygon();
 713         }
 714
 715         // Draw the aiming reticle for weapons that use it
 716         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 717         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 718         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 719         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 720                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 721         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 722                 reticle_type = 2; // nex zoom
 723         else if(button_zoom || zoomscript_caught)
 724                 reticle_type = 1; // normal zoom
 725         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 726                 reticle_type = 2; // nex zoom
 727
 728         if(reticle_type && autocvar_cl_reticle)
 729         {
 730                 if(autocvar_cl_reticle_stretch)
 731                 {
 732                         reticle_size_x = vid_conwidth;
 733                         reticle_size_y = vid_conheight;
 734                         reticle_pos_x = 0;
 735                         reticle_pos_y = 0;
 736                 }
 737                 else
 738                 {
 739                         reticle_size_x = max(vid_conwidth, vid_conheight);
 740                         reticle_size_y = max(vid_conwidth, vid_conheight);
 741                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 742                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 743                 }
 744
 745                 f = current_zoomfraction;
 746                 if(zoomscript_caught)
 747                         f = 1;
 748                 if(autocvar_cl_reticle_item_normal)
 749                 {
 750                         if(reticle_type == 1 && f)
 751                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 752                 }
 753                 if(autocvar_cl_reticle_item_nex)
 754                 {
 755                         if(reticle_type == 2 && f)
 756                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 757                 }
 758         }
 759
 760
 761         // improved polyblend
 762         vector rgb;
 763         if(autocvar_hud_contents)
 764         {
 765                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 766                 vector liquidcolor;
 767
 768                 switch(pointcontents(view_origin))
 769                 {
 770                         case CONTENT_WATER:
 771                                 liquidalpha = autocvar_hud_contents_water_alpha;
 772                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 773                                 incontent = 1;
 774                                 break;
 775
 776                         case CONTENT_LAVA:
 777                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 778                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 779                                 incontent = 1;
 780                                 break;
 781
 782                         case CONTENT_SLIME:
 783                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 784                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 785                                 incontent = 1;
 786                                 break;
 787
 788                         default:
 789                                 liquidalpha = 0;
 790                                 liquidcolor = '0 0 0';
 791                                 incontent = 0;
 792                                 break;
 793                 }
 794
 795                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 796                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 797                         contentfadetime = autocvar_hud_contents_fadeintime;
 798                         liquidalpha_prev = liquidalpha;
 799                         liquidcolor_prev = liquidcolor;
 800                 }
 801                 else
 802                         contentfadetime = autocvar_hud_contents_fadeouttime;
 803
 804                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 805                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 806
 807                 if(contentavgalpha)
 808                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 809
 810                 if(autocvar_hud_postprocessing)
 811                 {
 812                         if(autocvar_hud_contents_blur && contentavgalpha)
 813                         {
 814                                 content_blurpostprocess_x = 1;
 815                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 816                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 817                         }
 818                         else
 819                         {
 820                                 content_blurpostprocess_x = 0;
 821                                 content_blurpostprocess_y = 0;
 822                                 content_blurpostprocess_z = 0;
 823                         }
 824                 }
 825         }
 826
 827         if(autocvar_hud_damage)
 828         {
 829                 splash_size_x = max(vid_conwidth, vid_conheight);
 830                 splash_size_y = max(vid_conwidth, vid_conheight);
 831                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 832                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 833
 834                 float myhealth_flash_temp;
 835                 myhealth = getstati(STAT_HEALTH);
 836
 837                 // fade out
 838                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 839                 // add new damage
 840                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 841
 842                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 843                 pain_threshold = autocvar_hud_damage_pain_threshold;
 844                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 845                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 846
 847                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 848                 {
 849                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 850                 }
 851
 852                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 853
 854                 if(myhealth_prev < 1)
 855                 {
 856                         if(myhealth >= 1)
 857                         {
 858                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 859                                 myhealth_flash_temp = 0;
 860                         }
 861                         else
 862                         {
 863                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 864                         }
 865                 }
 866
 867                 if(spectatee_status == -1 || intermission)
 868                 {
 869                         myhealth_flash = 0; // observing, or match ended
 870                         myhealth_flash_temp = 0;
 871                 }
 872
 873                 myhealth_prev = myhealth;
 874
 875                 // IDEA: change damage color/picture based on player model for robot/alien species?
 876                 // pro: matches model better
 877                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 878                 // maybe different reddish pics?
 879                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 880                 {
 881                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 882                         {
 883                                 if(autocvar_cl_gentle_damage == 2)
 884                                 {
 885                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 886                                         {
 887                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 888                                         }
 889                                 }
 890                                 else
 891                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 892
 893                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 894                         }
 895                         else
 896                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 897                 }
 898
 899                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 900                 {
 901                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 902                         {
 903                                 damage_blurpostprocess_x = 1;
 904                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 905                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 906                         }
 907                         else
 908                         {
 909                                 damage_blurpostprocess_x = 0;
 910                                 damage_blurpostprocess_y = 0;
 911                                 damage_blurpostprocess_z = 0;
 912                         }
 913                 }
 914         }
 915
 916         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 917         {
 918                 // enable or disable rendering types if they are used or not
 919                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 920                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 921
 922                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 923                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 924                 {
 925                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 926                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 927                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 928                         {
 929                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 930                                 old_blurradius = blurradius;
 931                                 old_bluralpha = bluralpha;
 932                         }
 933                 }
 934                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 935                 {
 936                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 937                         old_blurradius = 0;
 938                         old_bluralpha = 0;
 939                 }
 940
 941                 // edge detection postprocess handling done second (used by hud_powerup)
 942                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 943                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 944                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 945
 946                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 947
 948                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 949                 {
 950                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 951                         {
 952                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 953                                 old_sharpen_intensity = sharpen_intensity;
 954                         }
 955                 }
 956                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 957                 {
 958                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 959                         old_sharpen_intensity = 0;
 960                 }
 961         }
 962
 963         if(menu_visible)
 964                 menu_show();
 965
 966         /*if(gametype == MAPINFO_TYPE_CTF)
 967           {
 968           ctf_view();
 969           } else */
 970
 971         // draw 2D entities
 972         e = self;
 973         for(self = world; (self = nextent(self)); )
 974                 if(self.draw2d)
 975                         self.draw2d();
 976         self = e;
 977         Draw_ShowNames_All();
 978
 979         scoreboard_active = HUD_WouldDrawScoreboard();
 980
 981         hit_time = getstatf(STAT_HIT_TIME);
 982         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 983         {
 984                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 985                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 986
 987                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 988         }
 989         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 990         if(typehit_time > nextsound_typehit_time)
 991         {
 992                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 993                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 994
 995                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 996         }
 997
 998         //else
 999         {
1000                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1001                 {
1002                         if(getstati(STAT_FROZEN))
1003                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1004                         if(getstatf(STAT_REVIVE_PROGRESS))
1005                         {
1006                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1007                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1008                         }
1009                 }
1010
1011                 if(autocvar_r_letterbox == 0)
1012                         if(autocvar_viewsize < 120)
1013                                 CSQC_common_hud();
1014
1015                 // crosshair goes VERY LAST
1016                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1017                         string wcross_style;
1018                         float wcross_alpha, wcross_resolution;
1019                         wcross_style = autocvar_crosshair;
1020                         if (wcross_style == "0")
1021                                 return;
1022                         wcross_resolution = autocvar_crosshair_size;
1023                         if (wcross_resolution == 0)
1024                                 return;
1025                         wcross_alpha = autocvar_crosshair_alpha;
1026                         if (wcross_alpha == 0)
1027                                 return;
1028
1029                         // TrueAim check
1030                         float shottype;
1031
1032                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1033                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1034                         wcross_origin_z = 0;
1035                         if(autocvar_crosshair_hittest)
1036                         {
1037                                 vector wcross_oldorigin;
1038                                 wcross_oldorigin = wcross_origin;
1039                                 shottype = TrueAimCheck();
1040                                 if(shottype == SHOTTYPE_HITWORLD)
1041                                 {
1042                                         v = wcross_origin - wcross_oldorigin;
1043                                         v_x /= vid_conwidth;
1044                                         v_y /= vid_conheight;
1045                                         if(vlen(v) > 0.01)
1046                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1047                                 }
1048                                 if(!autocvar_crosshair_hittest_showimpact)
1049                                         wcross_origin = wcross_oldorigin;
1050                         }
1051                         else
1052                                 shottype = SHOTTYPE_HITWORLD;
1053
1054                         vector wcross_color, wcross_size;
1055                         string wcross_wep, wcross_name;
1056                         float wcross_scale, wcross_blur;
1057
1058                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1059                                 e = get_weaponinfo(switchingweapon);
1060                                 if (e && e.netname != "")
1061                                 {
1062                                         wcross_wep = e.netname;
1063                                         if(autocvar_crosshair_per_weapon)
1064                                         {
1065                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1066                                                 if (wcross_resolution == 0)
1067                                                         return;
1068                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1069                                                 if (wcross_alpha == 0)
1070                                                         return;
1071
1072                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1073                                                 if(wcross_style == "" || wcross_style == "0")
1074                                                         wcross_style = wcross_wep;
1075                                         }
1076                                 }
1077                         }
1078                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1079                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1080                         else if(autocvar_crosshair_color_by_health)
1081                         {
1082                                 float x = getstati(STAT_HEALTH);
1083
1084                                 //x = red
1085                                 //y = green
1086                                 //z = blue
1087
1088                                 wcross_color_z = 0;
1089
1090                                 if(x > 200)
1091                                 {
1092                                         wcross_color_x = 0;
1093                                         wcross_color_y = 1;
1094                                 }
1095                                 else if(x > 150)
1096                                 {
1097                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1098                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1099                                 }
1100                                 else if(x > 100)
1101                                 {
1102                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1103                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1104                                         wcross_color_z = 1 - (x-100)*0.02;
1105                                 }
1106                                 else if(x > 50)
1107                                 {
1108                                         wcross_color_x = 1;
1109                                         wcross_color_y = 1;
1110                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1111                                 }
1112                                 else if(x > 20)
1113                                 {
1114                                         wcross_color_x = 1;
1115                                         wcross_color_y = (x-20)*90/27/100;
1116                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1117                                 }
1118                                 else
1119                                 {
1120                                         wcross_color_x = 1;
1121                                         wcross_color_y = 0;
1122                                 }
1123                         }
1124                         else
1125                                 wcross_color = stov(autocvar_crosshair_color);
1126
1127                         wcross_name = strcat("gfx/crosshair", wcross_style);
1128
1129                         if(autocvar_crosshair_effect_scalefade)
1130                         {
1131                                 wcross_scale = wcross_resolution;
1132                                 wcross_resolution = 1;
1133                         }
1134                         else
1135                         {
1136                                 wcross_scale = 1;
1137                         }
1138
1139                         if(autocvar_crosshair_pickup)
1140                         {
1141                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1142
1143                                 if(pickup_crosshair_time < stat_pickup_time)
1144                                 {
1145                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1146                                                 pickup_crosshair_size = 1;
1147
1148                                         pickup_crosshair_time = stat_pickup_time;
1149                                 }
1150
1151                                 if(pickup_crosshair_size > 0)
1152                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1153                                 else
1154                                         pickup_crosshair_size = 0;
1155
1156                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1157                         }
1158
1159                         if(autocvar_crosshair_hitindication)
1160                         {
1161                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1162                                 if(hitindication_crosshair_time < hit_time)
1163                                 {
1164                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1165                                                 hitindication_crosshair_size = 1;
1166
1167                                         hitindication_crosshair_time = hit_time;
1168                                 }
1169
1170                                 if(hitindication_crosshair_size > 0)
1171                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1172                                 else
1173                                         hitindication_crosshair_size = 0;
1174
1175                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1176                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1177                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1178                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1179                         }
1180
1181                         if(shottype == SHOTTYPE_HITENEMY)
1182                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1183                         if(shottype == SHOTTYPE_HITTEAM)
1184                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1185
1186                         f = autocvar_crosshair_effect_speed;
1187                         if(f < 0)
1188                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1189                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1190                         {
1191                                 wcross_changedonetime = time + f;
1192                         }
1193                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1194                         {
1195                                 wcross_name_changestarttime = time;
1196                                 wcross_name_changedonetime = time + f;
1197                                 if(wcross_name_goal_prev_prev)
1198                                         strunzone(wcross_name_goal_prev_prev);
1199                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1200                                 wcross_name_goal_prev = strzone(wcross_name);
1201                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1202                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1203                                 wcross_resolution_goal_prev = wcross_resolution;
1204                         }
1205
1206                         wcross_scale_goal_prev = wcross_scale;
1207                         wcross_alpha_goal_prev = wcross_alpha;
1208                         wcross_color_goal_prev = wcross_color;
1209
1210                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1211                         {
1212                                 wcross_blur = 1;
1213                                 wcross_alpha *= 0.75;
1214                         }
1215                         else
1216                                 wcross_blur = 0;
1217                         // *_prev is at time-frametime
1218                         // * is at wcross_changedonetime+f
1219                         // what do we have at time?
1220                         if(time < wcross_changedonetime)
1221                         {
1222                                 f = frametime / (wcross_changedonetime - time + frametime);
1223                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1224                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1225                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1226                         }
1227
1228                         wcross_scale_prev = wcross_scale;
1229                         wcross_alpha_prev = wcross_alpha;
1230                         wcross_color_prev = wcross_color;
1231
1232                         wcross_scale *= 1 - autocvar__menu_alpha;
1233                         wcross_alpha *= 1 - autocvar__menu_alpha;
1234                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1235
1236                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1237                         {
1238                                 // crosshair rings for weapon stats
1239                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1240                                 {
1241                                         // declarations and stats
1242                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1243                                         string ring_image, ring_inner_image;
1244                                         vector ring_rgb, ring_inner_rgb;
1245
1246                                         ring_scale = autocvar_crosshair_ring_size;
1247
1248                                         float weapon_clipload, weapon_clipsize;
1249                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1250                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1251
1252                                         float nex_charge, nex_chargepool;
1253                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1254                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1255
1256                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1257                                                 nex_charge_movingavg = nex_charge;
1258
1259
1260                                         // handle the values
1261                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1262                                         {
1263                                                 if (nex_chargepool || use_nex_chargepool) {
1264                                                         use_nex_chargepool = 1;
1265                                                         ring_inner_value = nex_chargepool;
1266                                                 } else {
1267                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1268                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1269                                                 }
1270
1271                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1272                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1273                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1274
1275                                                 // draw the outer ring to show the current charge of the weapon
1276                                                 ring_value = nex_charge;
1277                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1278                                                 ring_rgb = wcross_color;
1279                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1280                                         }
1281                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1282                                         {
1283                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1284                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1285                                                 ring_rgb = wcross_color;
1286                                                 ring_image = "gfx/crosshair_ring.tga";
1287                                         }
1288                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1289                                         {
1290                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1291                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1292                                                 ring_rgb = wcross_color;
1293                                                 ring_image = "gfx/crosshair_ring.tga";
1294                                         }
1295
1296                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1297                                         {
1298                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1299                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1300                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1301                                                 ring_rgb = wcross_color;
1302
1303                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1304                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1305                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1306                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1307                                                 else
1308                                                         ring_image = "gfx/crosshair_ring.tga";
1309                                         }
1310
1311                                         // if in weapon switch animation, fade ring out/in
1312                                         if(g_weaponswitchdelay > 0)
1313                                         {
1314                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1315                                                 if(f > 0 && f < 2)
1316                                                         ring_alpha *= fabs(1 - f);
1317                                         }
1318
1319                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1320                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1321
1322                                         if (ring_value)
1323                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1324                                 }
1325
1326 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1327                                 do \
1328                                 { \
1329                                         if(wcross_blur > 0) \
1330                                         { \
1331                                                 for(i = -2; i <= 2; ++i) \
1332                                                 for(j = -2; j <= 2; ++j) \
1333                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1334                                         } \
1335                                         else \
1336                                         { \
1337                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1338                                         } \
1339                                 } \
1340                                 while(0)
1341
1342 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1343                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1344
1345 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1346                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1347
1348                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1349                                 {
1350                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1351                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1352                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1353                                         f = 1 - f;
1354                                 }
1355                                 else
1356                                 {
1357                                         f = 1;
1358                                 }
1359                                 wcross_name_alpha_goal_prev = f;
1360
1361                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1362                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1363
1364                                 if(autocvar_crosshair_dot)
1365                                 {
1366                                         vector wcross_color_old;
1367                                         wcross_color_old = wcross_color;
1368                                         if(autocvar_crosshair_dot_color != "0")
1369                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1370                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1371                                         // FIXME why don't we use wcross_alpha here?
1372                                         wcross_color = wcross_color_old;
1373                                 }
1374                         }
1375                 }
1376                 else
1377                 {
1378                         wcross_scale_prev = 0;
1379                         wcross_alpha_prev = 0;
1380                         wcross_scale_goal_prev = 0;
1381                         wcross_alpha_goal_prev = 0;
1382                         wcross_changedonetime = 0;
1383                         if(wcross_name_goal_prev)
1384                                 strunzone(wcross_name_goal_prev);
1385                         wcross_name_goal_prev = string_null;
1386                         if(wcross_name_goal_prev_prev)
1387                                 strunzone(wcross_name_goal_prev_prev);
1388                         wcross_name_goal_prev_prev = string_null;
1389                         wcross_name_changestarttime = 0;
1390                         wcross_name_changedonetime = 0;
1391                         wcross_name_alpha_goal_prev = 0;
1392                         wcross_name_alpha_goal_prev_prev = 0;
1393                         wcross_resolution_goal_prev = 0;
1394                         wcross_resolution_goal_prev_prev = 0;
1395                 }
1396         }
1397
1398         if(NextFrameCommand)
1399         {
1400                 localcmd("\n", NextFrameCommand, "\n");
1401                 NextFrameCommand = string_null;
1402         }
1403
1404         // we must do this check AFTER a frame was rendered, or it won't work
1405         if(cs_project_is_b0rked == 0)
1406         {
1407                 string w0, h0;
1408                 w0 = ftos(autocvar_vid_conwidth);
1409                 h0 = ftos(autocvar_vid_conheight);
1410                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1411                 //setproperty(VF_FOV, '90 90 0');
1412                 setproperty(VF_ORIGIN, '0 0 0');
1413                 setproperty(VF_ANGLES, '0 0 0');
1414                 setproperty(VF_PERSPECTIVE, 1);
1415                 makevectors('0 0 0');
1416                 vector v1, v2;
1417                 cvar_set("vid_conwidth", "800");
1418                 cvar_set("vid_conheight", "600");
1419                 v1 = cs_project(v_forward);
1420                 cvar_set("vid_conwidth", "640");
1421                 cvar_set("vid_conheight", "480");
1422                 v2 = cs_project(v_forward);
1423                 if(v1 == v2)
1424                         cs_project_is_b0rked = 1;
1425                 else
1426                         cs_project_is_b0rked = -1;
1427                 cvar_set("vid_conwidth", w0);
1428                 cvar_set("vid_conheight", h0);
1429         }
1430
1431         if(autocvar__hud_configure)
1432                 HUD_Panel_Mouse();
1433
1434     if(hud && !intermission)
1435     {
1436         if(hud == HUD_SPIDERBOT)
1437             CSQC_SPIDER_HUD();
1438         else if(hud == HUD_WAKIZASHI)
1439             CSQC_WAKIZASHI_HUD();
1440         else if(hud == HUD_RAPTOR)
1441             CSQC_RAPTOR_HUD();
1442         else if(hud == HUD_BUMBLEBEE)
1443             CSQC_BUMBLE_HUD();
1444     }
1445         // let's reset the view back to normal for the end
1446         setproperty(VF_MIN, '0 0 0');
1447         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1448 }
1449
1450
1451 void CSQC_common_hud(void)
1452 {
1453     // do some accuracy var caching
1454     float i;
1455     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1456     {
1457         if(autocvar_accuracy_color_levels != acc_color_levels)
1458         {
1459             if(acc_color_levels)
1460                 strunzone(acc_color_levels);
1461             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1462             acc_levels = tokenize_console(acc_color_levels);
1463             if (acc_levels > MAX_ACCURACY_LEVELS)
1464                 acc_levels = MAX_ACCURACY_LEVELS;
1465
1466             for (i = 0; i < acc_levels; ++i)
1467                 acc_lev[i] = stof(argv(i)) / 100.0;
1468         }
1469         // let know that acc_col[] needs to be loaded
1470         acc_col_x[0] = -1;
1471     }
1472
1473     HUD_Main(); // always run these functions for alpha checks
1474     HUD_DrawScoreboard();
1475
1476     if (scoreboard_active) // scoreboard/accuracy
1477         HUD_Reset();
1478     else if (intermission == 2) // map voting screen
1479     {
1480         HUD_FinaleOverlay();
1481         HUD_Reset();
1482     }
1483         /*
1484         switch(hud)
1485         {
1486                 case HUD_SPIDERBOT:
1487                         CSQC_SPIDER_HUD();
1488                         break;
1489
1490                 case HUD_WAKIZASHI:
1491                         CSQC_WAKIZASHI_HUD();
1492                         break;
1493
1494         case HUD_BUMBLEBEE:
1495             CSQC_BUMBLE_HUD();
1496             break;
1497         }
1498         */
1499 }
1500
1501
1502 // following vectors must be global to allow seamless switching between camera modes
1503 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1504 void CSQC_Demo_Camera()
1505 {
1506         float speed, attenuation, dimensions;
1507         vector tmp, delta;
1508
1509         if( autocvar_camera_reset || !camera_mode )
1510         {
1511                 camera_offset = '0 0 0';
1512                 current_angles = '0 0 0';
1513                 camera_direction = '0 0 0';
1514                 camera_offset_z += 30;
1515                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1516                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1517                 current_origin = view_origin;
1518                 current_camera_offset  = camera_offset;
1519                 cvar_set("camera_reset", "0");
1520                 camera_mode = CAMERA_CHASE;
1521         }
1522
1523         // Camera angles
1524         if( camera_roll )
1525                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1526
1527         if(autocvar_camera_look_player)
1528         {
1529                 vector dir;
1530                 float n;
1531
1532                 dir = normalize(view_origin - current_position);
1533                 n = mouse_angles_z;
1534                 mouse_angles = vectoangles(dir);
1535                 mouse_angles_x = mouse_angles_x * -1;
1536                 mouse_angles_z = n;
1537         }
1538         else
1539         {
1540                 tmp = getmousepos() * 0.1;
1541                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1542                 {
1543                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1544                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1545                 }
1546         }
1547
1548         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1549         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1550         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1551         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1552
1553         // Fix difference when angles don't have the same sign
1554         delta = '0 0 0';
1555         if(mouse_angles_y < -60 && current_angles_y > 60)
1556                 delta = '0 360 0';
1557         if(mouse_angles_y > 60 && current_angles_y < -60)
1558                 delta = '0 -360 0';
1559
1560         if(autocvar_camera_look_player)
1561                 attenuation = autocvar_camera_look_attenuation;
1562         else
1563                 attenuation = autocvar_camera_speed_attenuation;
1564
1565         attenuation = 1 / max(1, attenuation);
1566         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1567
1568         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1569         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1570         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1571         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1572
1573         // Camera position
1574         tmp = '0 0 0';
1575         dimensions = 0;
1576
1577         if( camera_direction_x )
1578         {
1579                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1580                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1581                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1582                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1583                 ++dimensions;
1584         }
1585
1586         if( camera_direction_y )
1587         {
1588                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1589                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1590                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1591                 ++dimensions;
1592         }
1593
1594         if( camera_direction_z )
1595         {
1596                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1597                 ++dimensions;
1598         }
1599
1600         if(autocvar_camera_free)
1601                 speed = autocvar_camera_speed_free;
1602         else
1603                 speed = autocvar_camera_speed_chase;
1604
1605         if(dimensions)
1606         {
1607                 speed = speed * sqrt(1 / dimensions);
1608                 camera_offset += tmp * speed;
1609         }
1610
1611         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1612
1613         // Camera modes
1614         if( autocvar_camera_free )
1615         {
1616                 if ( camera_mode == CAMERA_CHASE )
1617                 {
1618                         current_camera_offset = current_origin + current_camera_offset;
1619                         camera_offset = current_origin + camera_offset;
1620                 }
1621
1622                 camera_mode = CAMERA_FREE;
1623                 current_position = current_camera_offset;
1624         }
1625         else
1626         {
1627                 if ( camera_mode == CAMERA_FREE )
1628                 {
1629                         current_origin = view_origin;
1630                         camera_offset = camera_offset - current_origin;
1631                         current_camera_offset = current_camera_offset - current_origin;
1632                 }
1633
1634                 camera_mode = CAMERA_CHASE;
1635
1636                 if(autocvar_camera_chase_smoothly)
1637                         current_origin += (view_origin - current_origin) * attenuation;
1638                 else
1639                         current_origin = view_origin;
1640
1641                 current_position = current_origin + current_camera_offset;
1642         }
1643
1644         setproperty(VF_ANGLES, current_angles);
1645         setproperty(VF_ORIGIN, current_position);
1646 }