qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float reticle_type;
 331 string NextFrameCommand;
 332 void CSQC_SPIDER_HUD();
 333 void CSQC_RAPTOR_HUD();
 334
 335 vector freeze_org, freeze_ang;
 336 entity nightvision_noise, nightvision_noise2;
 337
 338 #define MAX_TIME_DIFF 5
 339 float pickup_crosshair_time, pickup_crosshair_size;
 340 float hit_time, typehit_time;
 341 float nextsound_hit_time, nextsound_typehit_time;
 342 float hitindication_crosshair_time, hitindication_crosshair_size;
 343 float use_nex_chargepool;
 344
 345 float myhealth, myhealth_prev;
 346 float myhealth_flash;
 347
 348 float old_blurradius, old_bluralpha;
 349 float old_sharpen_intensity;
 350
 351 vector myhealth_gentlergb;
 352
 353 float contentavgalpha, liquidalpha_prev;
 354 vector liquidcolor_prev;
 355
 356 float eventchase_current_distance;
 357
 358 vector damage_blurpostprocess, content_blurpostprocess;
 359
 360 float checkfail[16];
 361
 362 void CSQC_UpdateView(float w, float h)
 363 {
 364         entity e;
 365         float fov;
 366         float f, i, j;
 367         vector v;
 368         vector vf_size, vf_min;
 369         float a;
 370         hud = getstati(STAT_HUD);
 371
 372         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 373                 view_quality = R_SetView(VF_MINFPS_QUALITY);
 374         else
 375                 view_quality = 1;
 376
 377         button_attack2 = (input_buttons & BUTTON_3);
 378         button_zoom = (input_buttons & BUTTON_4);
 379
 380         // FIXME do we need this hack?
 381         if(isdemo())
 382         {
 383                 // in demos, input_buttons do not work
 384                 button_zoom = (autocvar__togglezoom == "-");
 385         }
 386
 387 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 388         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 389         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 390         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 391         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 392         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 393         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 394         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 395
 396         vf_size = R_SetView3fv(VF_SIZE);
 397         vf_min = R_SetView3fv(VF_MIN);
 398         vid_width = vf_size_x;
 399         vid_height = vf_size_y;
 400
 401         vector reticle_pos, reticle_size;
 402         vector splash_pos, splash_size;
 403
 404         WaypointSprite_Load();
 405
 406         CSQCPlayer_SetCamera();
 407
 408         if(spectatee_status)
 409                 myteam = GetPlayerColor(spectatee_status - 1);
 410         else
 411                 myteam = GetPlayerColor(player_localentnum - 1);
 412
 413         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 414
 415         // event chase camera
 416         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 417         {
 418                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 419                 {
 420                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 421                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 422
 423                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 424                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 425                         if(!autocvar_chase_active)
 426                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 427
 428                         // make the camera smooth back
 429                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 430                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 431                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 432                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 433
 434                         vector eventchase_target_origin;
 435                         makevectors(view_angles);
 436                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 437                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 438                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 439                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 440                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 441                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 442                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 443
 444                         R_SetView(VF_ORIGIN, trace_endpos);
 445                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 446                 }
 447                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 448                 {
 449                         cvar_set("chase_active", "0");
 450                         eventchase_current_distance = 0; // start from 0 next time
 451                 }
 452         }
 453
 454         // do lockview after event chase camera so that it still applies whenever necessary.
 455         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 456         {
 457                 R_SetView(VF_ORIGIN, freeze_org);
 458                 R_SetView(VF_ANGLES, freeze_ang);
 459         }
 460         else
 461         {
 462                 freeze_org = R_SetView3fv(VF_ORIGIN);
 463                 freeze_ang = R_SetView3fv(VF_ANGLES);
 464         }
 465
 466         WarpZone_FixView();
 467         //WarpZone_FixPMove();
 468
 469         // Render the Scene
 470         view_origin = R_SetView3fv(VF_ORIGIN);
 471         view_angles = R_SetView3fv(VF_ANGLES);
 472         makevectors(view_angles);
 473         view_forward = v_forward;
 474         view_right = v_right;
 475         view_up = v_up;
 476
 477 #ifdef BLURTEST
 478         if(time > blurtest_time0 && time < blurtest_time1)
 479         {
 480                 float r, t;
 481
 482                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 483                 r = t * blurtest_radius;
 484                 f = 1 / pow(t, blurtest_power) - 1;
 485
 486                 cvar_set("r_glsl_postprocess", "1");
 487                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 488         }
 489         else
 490         {
 491                 cvar_set("r_glsl_postprocess", "0");
 492                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 493         }
 494 #endif
 495
 496         TargetMusic_Advance();
 497         Fog_Force();
 498
 499         if(drawtime == 0)
 500                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 501         else
 502                 drawframetime = bound(0.000001, time - drawtime, 1);
 503         drawtime = time;
 504
 505         // watch for gametype changes here...
 506         // in ParseStuffCMD the cmd isn't executed yet :/
 507         // might even be better to add the gametype to TE_CSQC_INIT...?
 508         if(!postinit)
 509                 PostInit();
 510
 511         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 512         {
 513                 if(calledhooks & HOOK_START)
 514                 {
 515                         localcmd("\ncl_hook_gameend\n");
 516                         calledhooks |= HOOK_END;
 517                 }
 518         }
 519
 520   Announcer();
 521
 522         fov = autocvar_fov;
 523         if(fov <= 59.5)
 524         {
 525                 if(!zoomscript_caught)
 526                 {
 527                         localcmd("+button9\n");
 528                         zoomscript_caught = 1;
 529                 }
 530         }
 531         else
 532         {
 533                 if(zoomscript_caught)
 534                 {
 535                         localcmd("-button9\n");
 536                         zoomscript_caught = 0;
 537                 }
 538         }
 539
 540         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 541
 542         // next WANTED weapon (for HUD)
 543         switchweapon = getstati(STAT_SWITCHWEAPON);
 544
 545         // currently switching-to weapon (for crosshair)
 546         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 547
 548         // actually active weapon (for zoom)
 549         activeweapon = getstati(STAT_ACTIVEWEAPON);
 550
 551         f = (serverflags & SERVERFLAG_TEAMPLAY);
 552         if(f != teamplay)
 553         {
 554                 teamplay = f;
 555                 HUD_InitScores();
 556         }
 557
 558         if(last_switchweapon != switchweapon) {
 559                 weapontime = time;
 560                 last_switchweapon = switchweapon;
 561         }
 562         if(last_activeweapon != activeweapon) {
 563                 last_activeweapon = activeweapon;
 564
 565                 e = get_weaponinfo(activeweapon);
 566                 if(e.netname != "")
 567                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 568                 else
 569                         localcmd("\ncl_hook_activeweapon none\n");
 570         }
 571
 572         // ALWAYS Clear Current Scene First
 573         R_ClearScene();
 574 #ifdef WORKAROUND_XON010
 575         if(checkextension("DP_CSQC_ROTATEMOVES"))
 576         {
 577 #endif
 578         R_SetView(VF_ORIGIN, view_origin);
 579         R_SetView(VF_ANGLES, view_angles);
 580 #ifdef WORKAROUND_XON010
 581         }
 582 #endif
 583
 584         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 585         R_SetView(VF_SIZE, vf_size);
 586         R_SetView(VF_MIN, vf_min);
 587
 588         // Assign Standard Viewflags
 589         // Draw the World (and sky)
 590         R_SetView(VF_DRAWWORLD, 1);
 591
 592         // Set the console size vars
 593         vid_conwidth = autocvar_vid_conwidth;
 594         vid_conheight = autocvar_vid_conheight;
 595         vid_pixelheight = autocvar_vid_pixelheight;
 596
 597         R_SetView(VF_FOV, GetCurrentFov(fov));
 598
 599         // Camera for demo playback
 600         if(camera_active)
 601         {
 602                 if(autocvar_camera_enable)
 603                         CSQC_Demo_Camera();
 604                 else
 605                 {
 606                         cvar_set("chase_active", ftos(chase_active_backup));
 607                         cvar_set("cl_demo_mousegrab", "0");
 608                         camera_active = FALSE;
 609                 }
 610         }
 611 #ifdef CAMERATEST
 612         else if(autocvar_camera_enable)
 613 #else
 614         else if(autocvar_camera_enable && isdemo())
 615 #endif
 616         {
 617                 // Enable required Darkplaces cvars
 618                 chase_active_backup = autocvar_chase_active;
 619                 cvar_set("chase_active", "2");
 620                 cvar_set("cl_demo_mousegrab", "1");
 621                 camera_active = TRUE;
 622                 camera_mode = FALSE;
 623         }
 624
 625         // Draw the Crosshair
 626         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 627
 628         // Draw the Engine Status Bar (the default Quake HUD)
 629         R_SetView(VF_DRAWENGINEHUD, 0);
 630
 631         // Update the mouse position
 632         /*
 633            mousepos_x = vid_conwidth;
 634            mousepos_y = vid_conheight;
 635            mousepos = mousepos*0.5 + getmousepos();
 636          */
 637
 638         e = self;
 639         for(self = world; (self = nextent(self)); )
 640                 if(self.draw)
 641                         self.draw();
 642         self = e;
 643
 644         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 645         R_RenderScene();
 646
 647         // now switch to 2D drawing mode by calling a 2D drawing function
 648         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 649         // next R_RenderScene call
 650         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 651
 652         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 653         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 654         {
 655                 // apply night vision effect
 656                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 657
 658                 if(!nightvision_noise)
 659                 {
 660                         nightvision_noise = spawn();
 661                         nightvision_noise.classname = "nightvision_noise";
 662                 }
 663                 if(!nightvision_noise2)
 664                 {
 665                         nightvision_noise2 = spawn();
 666                         nightvision_noise2.classname = "nightvision_noise2";
 667                 }
 668
 669                 // color tint in yellow
 670                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 671
 672                 // draw BG
 673                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 674                 rgb = '1 1 1';
 675                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 676                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 677                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 678                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 679                 tc_11 = tc_01 + tc_10 - tc_00;
 680                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 681                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 682                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 683                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 684                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 685                 R_EndPolygon();
 686
 687                 // draw FG
 688                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 689                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 690                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 691                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 692                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 693                 tc_11 = tc_01 + tc_10 - tc_00;
 694                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 695                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 696                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 697                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 698                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 699                 R_EndPolygon();
 700         }
 701
 702         // Draw the aiming reticle for weapons that use it
 703         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 704         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 705         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 706         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 707                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 708         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 709                 reticle_type = 2; // nex zoom
 710         else if(button_zoom || zoomscript_caught)
 711                 reticle_type = 1; // normal zoom
 712         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 713                 reticle_type = 2; // nex zoom
 714
 715         if(reticle_type && autocvar_cl_reticle)
 716         {
 717                 if(autocvar_cl_reticle_stretch)
 718                 {
 719                         reticle_size_x = vid_conwidth;
 720                         reticle_size_y = vid_conheight;
 721                         reticle_pos_x = 0;
 722                         reticle_pos_y = 0;
 723                 }
 724                 else
 725                 {
 726                         reticle_size_x = max(vid_conwidth, vid_conheight);
 727                         reticle_size_y = max(vid_conwidth, vid_conheight);
 728                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 729                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 730                 }
 731
 732                 f = current_zoomfraction;
 733                 if(zoomscript_caught)
 734                         f = 1;
 735                 if(autocvar_cl_reticle_item_normal)
 736                 {
 737                         if(reticle_type == 1 && f)
 738                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 739                 }
 740                 if(autocvar_cl_reticle_item_nex)
 741                 {
 742                         if(reticle_type == 2 && f)
 743                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 744                 }
 745         }
 746
 747
 748         // improved polyblend
 749         vector rgb;
 750         if(autocvar_hud_contents)
 751         {
 752                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 753                 vector liquidcolor;
 754
 755                 switch(pointcontents(view_origin))
 756                 {
 757                         case CONTENT_WATER:
 758                                 liquidalpha = autocvar_hud_contents_water_alpha;
 759                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 760                                 incontent = 1;
 761                                 break;
 762
 763                         case CONTENT_LAVA:
 764                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 765                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 766                                 incontent = 1;
 767                                 break;
 768
 769                         case CONTENT_SLIME:
 770                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 771                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 772                                 incontent = 1;
 773                                 break;
 774
 775                         default:
 776                                 liquidalpha = 0;
 777                                 liquidcolor = '0 0 0';
 778                                 incontent = 0;
 779                                 break;
 780                 }
 781
 782                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 783                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 784                         contentfadetime = autocvar_hud_contents_fadeintime;
 785                         liquidalpha_prev = liquidalpha;
 786                         liquidcolor_prev = liquidcolor;
 787                 }
 788                 else
 789                         contentfadetime = autocvar_hud_contents_fadeouttime;
 790
 791                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 792                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 793
 794                 if(contentavgalpha)
 795                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 796
 797                 if(autocvar_hud_postprocessing)
 798                 {
 799                         if(autocvar_hud_contents_blur && contentavgalpha)
 800                         {
 801                                 content_blurpostprocess_x = 1;
 802                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 803                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 804                         }
 805                         else
 806                         {
 807                                 content_blurpostprocess_x = 0;
 808                                 content_blurpostprocess_y = 0;
 809                                 content_blurpostprocess_z = 0;
 810                         }
 811                 }
 812         }
 813
 814         if(autocvar_hud_damage)
 815         {
 816                 splash_size_x = max(vid_conwidth, vid_conheight);
 817                 splash_size_y = max(vid_conwidth, vid_conheight);
 818                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 819                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 820
 821                 float myhealth_flash_temp;
 822                 myhealth = getstati(STAT_HEALTH);
 823
 824                 // fade out
 825                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 826                 // add new damage
 827                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 828
 829                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 830                 pain_threshold = autocvar_hud_damage_pain_threshold;
 831                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 832                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 833
 834                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 835                 {
 836                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 837                 }
 838
 839                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 840
 841                 if(myhealth_prev < 1)
 842                 {
 843                         if(myhealth >= 1)
 844                         {
 845                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 846                                 myhealth_flash_temp = 0;
 847                         }
 848                         else
 849                         {
 850                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 851                         }
 852                 }
 853
 854                 if(spectatee_status == -1 || intermission)
 855                 {
 856                         myhealth_flash = 0; // observing, or match ended
 857                         myhealth_flash_temp = 0;
 858                 }
 859
 860                 myhealth_prev = myhealth;
 861
 862                 // IDEA: change damage color/picture based on player model for robot/alien species?
 863                 // pro: matches model better
 864                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 865                 // maybe different reddish pics?
 866                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 867                 {
 868                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 869                         {
 870                                 if(autocvar_cl_gentle_damage == 2)
 871                                 {
 872                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 873                                         {
 874                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 875                                         }
 876                                 }
 877                                 else
 878                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 879
 880                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 881                         }
 882                         else
 883                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 884                 }
 885
 886                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 887                 {
 888                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 889                         {
 890                                 damage_blurpostprocess_x = 1;
 891                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 892                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 893                         }
 894                         else
 895                         {
 896                                 damage_blurpostprocess_x = 0;
 897                                 damage_blurpostprocess_y = 0;
 898                                 damage_blurpostprocess_z = 0;
 899                         }
 900                 }
 901         }
 902
 903         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 904         {
 905                 // enable or disable rendering types if they are used or not
 906                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 907                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 908
 909                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 910                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 911                 {
 912                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 913                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 914                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 915                         {
 916                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 917                                 old_blurradius = blurradius;
 918                                 old_bluralpha = bluralpha;
 919                         }
 920                 }
 921                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 922                 {
 923                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 924                         old_blurradius = 0;
 925                         old_bluralpha = 0;
 926                 }
 927
 928                 // edge detection postprocess handling done second (used by hud_powerup)
 929                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 930                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 931                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 932
 933                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 934
 935                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 936                 {
 937                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 938                         {
 939                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 940                                 old_sharpen_intensity = sharpen_intensity;
 941                         }
 942                 }
 943                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 944                 {
 945                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 946                         old_sharpen_intensity = 0;
 947                 }
 948         }
 949
 950         if(menu_visible)
 951                 menu_show();
 952
 953         /*if(gametype == GAME_CTF)
 954           {
 955           ctf_view();
 956           } else */
 957
 958         // draw 2D entities
 959         e = self;
 960         for(self = world; (self = nextent(self)); )
 961                 if(self.draw2d)
 962                         self.draw2d();
 963         self = e;
 964         Draw_ShowNames_All();
 965
 966         scoreboard_active = HUD_WouldDrawScoreboard();
 967
 968         hit_time = getstatf(STAT_HIT_TIME);
 969         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 970         {
 971                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 972                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 973
 974                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 975         }
 976         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 977         if(typehit_time > nextsound_typehit_time)
 978         {
 979                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 980                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 981
 982                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 983         }
 984
 985         //else
 986         {
 987                 if(gametype == GAME_FREEZETAG)
 988                 {
 989                         if(getstati(STAT_FROZEN))
 990                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 991                         if(getstatf(STAT_REVIVE_PROGRESS))
 992                         {
 993                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 994                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 995                         }
 996                 }
 997
 998                 if(autocvar_r_letterbox == 0)
 999                         if(autocvar_viewsize < 120)
1000                                 CSQC_common_hud();
1001
1002                 // crosshair goes VERY LAST
1003                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1004                         string wcross_style;
1005                         float wcross_alpha, wcross_resolution;
1006                         wcross_style = autocvar_crosshair;
1007                         if (wcross_style == "0")
1008                                 return;
1009                         wcross_resolution = autocvar_crosshair_size;
1010                         if (wcross_resolution == 0)
1011                                 return;
1012                         wcross_alpha = autocvar_crosshair_alpha;
1013                         if (wcross_alpha == 0)
1014                                 return;
1015
1016                         // TrueAim check
1017                         float shottype;
1018
1019                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1020                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1021                         wcross_origin_z = 0;
1022                         if(autocvar_crosshair_hittest)
1023                         {
1024                                 vector wcross_oldorigin;
1025                                 wcross_oldorigin = wcross_origin;
1026                                 shottype = TrueAimCheck();
1027                                 if(shottype == SHOTTYPE_HITWORLD)
1028                                 {
1029                                         v = wcross_origin - wcross_oldorigin;
1030                                         v_x /= vid_conwidth;
1031                                         v_y /= vid_conheight;
1032                                         if(vlen(v) > 0.01)
1033                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1034                                 }
1035                                 if(!autocvar_crosshair_hittest_showimpact)
1036                                         wcross_origin = wcross_oldorigin;
1037                         }
1038                         else
1039                                 shottype = SHOTTYPE_HITWORLD;
1040
1041                         vector wcross_color, wcross_size;
1042                         string wcross_wep, wcross_name;
1043                         float wcross_scale, wcross_blur;
1044
1045                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1046                                 e = get_weaponinfo(switchingweapon);
1047                                 if (e && e.netname != "")
1048                                 {
1049                                         wcross_wep = e.netname;
1050                                         if(autocvar_crosshair_per_weapon)
1051                                         {
1052                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1053                                                 if (wcross_resolution == 0)
1054                                                         return;
1055                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1056                                                 if (wcross_alpha == 0)
1057                                                         return;
1058
1059                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1060                                                 if(wcross_style == "" || wcross_style == "0")
1061                                                         wcross_style = wcross_wep;
1062                                         }
1063                                 }
1064                         }
1065                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1066                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1067                         else if(autocvar_crosshair_color_by_health)
1068                         {
1069                                 float x = getstati(STAT_HEALTH);
1070
1071                                 //x = red
1072                                 //y = green
1073                                 //z = blue
1074
1075                                 wcross_color_z = 0;
1076
1077                                 if(x > 200)
1078                                 {
1079                                         wcross_color_x = 0;
1080                                         wcross_color_y = 1;
1081                                 }
1082                                 else if(x > 150)
1083                                 {
1084                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1085                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1086                                 }
1087                                 else if(x > 100)
1088                                 {
1089                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1090                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1091                                         wcross_color_z = 1 - (x-100)*0.02;
1092                                 }
1093                                 else if(x > 50)
1094                                 {
1095                                         wcross_color_x = 1;
1096                                         wcross_color_y = 1;
1097                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1098                                 }
1099                                 else if(x > 20)
1100                                 {
1101                                         wcross_color_x = 1;
1102                                         wcross_color_y = (x-20)*90/27/100;
1103                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1104                                 }
1105                                 else
1106                                 {
1107                                         wcross_color_x = 1;
1108                                         wcross_color_y = 0;
1109                                 }
1110                         }
1111                         else
1112                                 wcross_color = stov(autocvar_crosshair_color);
1113
1114                         wcross_name = strcat("gfx/crosshair", wcross_style);
1115
1116                         if(autocvar_crosshair_effect_scalefade)
1117                         {
1118                                 wcross_scale = wcross_resolution;
1119                                 wcross_resolution = 1;
1120                         }
1121                         else
1122                         {
1123                                 wcross_scale = 1;
1124                         }
1125
1126                         if(autocvar_crosshair_pickup)
1127                         {
1128                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1129
1130                                 if(pickup_crosshair_time < stat_pickup_time)
1131                                 {
1132                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1133                                                 pickup_crosshair_size = 1;
1134
1135                                         pickup_crosshair_time = stat_pickup_time;
1136                                 }
1137
1138                                 if(pickup_crosshair_size > 0)
1139                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1140                                 else
1141                                         pickup_crosshair_size = 0;
1142
1143                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1144                         }
1145
1146                         if(autocvar_crosshair_hitindication)
1147                         {
1148                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1149                                 if(hitindication_crosshair_time < hit_time)
1150                                 {
1151                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1152                                                 hitindication_crosshair_size = 1;
1153
1154                                         hitindication_crosshair_time = hit_time;
1155                                 }
1156
1157                                 if(hitindication_crosshair_size > 0)
1158                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1159                                 else
1160                                         hitindication_crosshair_size = 0;
1161
1162                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1163                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1164                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1165                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1166                         }
1167
1168                         if(shottype == SHOTTYPE_HITENEMY)
1169                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1170                         if(shottype == SHOTTYPE_HITTEAM)
1171                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1172
1173                         f = autocvar_crosshair_effect_speed;
1174                         if(f < 0)
1175                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1176                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1177                         {
1178                                 wcross_changedonetime = time + f;
1179                         }
1180                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1181                         {
1182                                 wcross_name_changestarttime = time;
1183                                 wcross_name_changedonetime = time + f;
1184                                 if(wcross_name_goal_prev_prev)
1185                                         strunzone(wcross_name_goal_prev_prev);
1186                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1187                                 wcross_name_goal_prev = strzone(wcross_name);
1188                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1189                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1190                                 wcross_resolution_goal_prev = wcross_resolution;
1191                         }
1192
1193                         wcross_scale_goal_prev = wcross_scale;
1194                         wcross_alpha_goal_prev = wcross_alpha;
1195                         wcross_color_goal_prev = wcross_color;
1196
1197                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1198                         {
1199                                 wcross_blur = 1;
1200                                 wcross_alpha *= 0.75;
1201                         }
1202                         else
1203                                 wcross_blur = 0;
1204                         // *_prev is at time-frametime
1205                         // * is at wcross_changedonetime+f
1206                         // what do we have at time?
1207                         if(time < wcross_changedonetime)
1208                         {
1209                                 f = frametime / (wcross_changedonetime - time + frametime);
1210                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1211                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1212                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1213                         }
1214
1215                         wcross_scale_prev = wcross_scale;
1216                         wcross_alpha_prev = wcross_alpha;
1217                         wcross_color_prev = wcross_color;
1218
1219                         wcross_scale *= 1 - autocvar__menu_alpha;
1220                         wcross_alpha *= 1 - autocvar__menu_alpha;
1221                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1222
1223                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1224                         {
1225                                 // crosshair rings for weapon stats
1226                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1227                                 {
1228                                         // declarations and stats
1229                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1230                                         string ring_image, ring_inner_image;
1231                                         vector ring_rgb, ring_inner_rgb;
1232
1233                                         ring_scale = autocvar_crosshair_ring_size;
1234
1235                                         float weapon_clipload, weapon_clipsize;
1236                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1237                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1238
1239                                         float nex_charge, nex_chargepool;
1240                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1241                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1242
1243                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1244                                                 nex_charge_movingavg = nex_charge;
1245
1246
1247                                         // handle the values
1248                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1249                                         {
1250                                                 if (nex_chargepool || use_nex_chargepool) {
1251                                                         use_nex_chargepool = 1;
1252                                                         ring_inner_value = nex_chargepool;
1253                                                 } else {
1254                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1255                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1256                                                 }
1257
1258                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1259                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1260                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1261
1262                                                 // draw the outer ring to show the current charge of the weapon
1263                                                 ring_value = nex_charge;
1264                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1265                                                 ring_rgb = wcross_color;
1266                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1267                                         }
1268                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1269                                         {
1270                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1271                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1272                                                 ring_rgb = wcross_color;
1273                                                 ring_image = "gfx/crosshair_ring.tga";
1274                                         }
1275                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1276                                         {
1277                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1278                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1279                                                 ring_rgb = wcross_color;
1280                                                 ring_image = "gfx/crosshair_ring.tga";
1281                                         }
1282
1283                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1284                                         {
1285                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1286                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1287                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1288                                                 ring_rgb = wcross_color;
1289
1290                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1291                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1292                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1293                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1294                                                 else
1295                                                         ring_image = "gfx/crosshair_ring.tga";
1296                                         }
1297
1298                                         // if in weapon switch animation, fade ring out/in
1299                                         if(g_weaponswitchdelay > 0)
1300                                         {
1301                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1302                                                 if(f > 0 && f < 2)
1303                                                         ring_alpha *= fabs(1 - f);
1304                                         }
1305
1306                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1307                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1308
1309                                         if (ring_value)
1310                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1311                                 }
1312
1313 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1314                                 do \
1315                                 { \
1316                                         if(wcross_blur > 0) \
1317                                         { \
1318                                                 for(i = -2; i <= 2; ++i) \
1319                                                 for(j = -2; j <= 2; ++j) \
1320                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1321                                         } \
1322                                         else \
1323                                         { \
1324                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1325                                         } \
1326                                 } \
1327                                 while(0)
1328
1329 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1330                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1331
1332 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1333                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1334
1335                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1336                                 {
1337                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1338                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1339                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1340                                         f = 1 - f;
1341                                 }
1342                                 else
1343                                 {
1344                                         f = 1;
1345                                 }
1346                                 wcross_name_alpha_goal_prev = f;
1347
1348                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1349                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1350
1351                                 if(autocvar_crosshair_dot)
1352                                 {
1353                                         vector wcross_color_old;
1354                                         wcross_color_old = wcross_color;
1355                                         if(autocvar_crosshair_dot_color != "0")
1356                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1357                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1358                                         // FIXME why don't we use wcross_alpha here?
1359                                         wcross_color = wcross_color_old;
1360                                 }
1361                         }
1362                 }
1363                 else
1364                 {
1365                         wcross_scale_prev = 0;
1366                         wcross_alpha_prev = 0;
1367                         wcross_scale_goal_prev = 0;
1368                         wcross_alpha_goal_prev = 0;
1369                         wcross_changedonetime = 0;
1370                         if(wcross_name_goal_prev)
1371                                 strunzone(wcross_name_goal_prev);
1372                         wcross_name_goal_prev = string_null;
1373                         if(wcross_name_goal_prev_prev)
1374                                 strunzone(wcross_name_goal_prev_prev);
1375                         wcross_name_goal_prev_prev = string_null;
1376                         wcross_name_changestarttime = 0;
1377                         wcross_name_changedonetime = 0;
1378                         wcross_name_alpha_goal_prev = 0;
1379                         wcross_name_alpha_goal_prev_prev = 0;
1380                         wcross_resolution_goal_prev = 0;
1381                         wcross_resolution_goal_prev_prev = 0;
1382                 }
1383         }
1384
1385         if(NextFrameCommand)
1386         {
1387                 localcmd("\n", NextFrameCommand, "\n");
1388                 NextFrameCommand = string_null;
1389         }
1390
1391         // we must do this check AFTER a frame was rendered, or it won't work
1392         if(cs_project_is_b0rked == 0)
1393         {
1394                 string w0, h0;
1395                 w0 = ftos(autocvar_vid_conwidth);
1396                 h0 = ftos(autocvar_vid_conheight);
1397                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1398                 //R_SetView(VF_FOV, '90 90 0');
1399                 R_SetView(VF_ORIGIN, '0 0 0');
1400                 R_SetView(VF_ANGLES, '0 0 0');
1401                 R_SetView(VF_PERSPECTIVE, 1);
1402                 makevectors('0 0 0');
1403                 vector v1, v2;
1404                 cvar_set("vid_conwidth", "800");
1405                 cvar_set("vid_conheight", "600");
1406                 v1 = cs_project(v_forward);
1407                 cvar_set("vid_conwidth", "640");
1408                 cvar_set("vid_conheight", "480");
1409                 v2 = cs_project(v_forward);
1410                 if(v1 == v2)
1411                         cs_project_is_b0rked = 1;
1412                 else
1413                         cs_project_is_b0rked = -1;
1414                 cvar_set("vid_conwidth", w0);
1415                 cvar_set("vid_conheight", h0);
1416         }
1417
1418         if(autocvar__hud_configure)
1419                 HUD_Panel_Mouse();
1420
1421     if(hud && !intermission)
1422     {
1423         if(hud == HUD_SPIDERBOT)
1424             CSQC_SPIDER_HUD();
1425         else if(hud == HUD_WAKIZASHI)
1426             CSQC_WAKIZASHI_HUD();
1427         else if(hud == HUD_RAPTOR)
1428             CSQC_RAPTOR_HUD();
1429         else if(hud == HUD_BUMBLEBEE)
1430             CSQC_BUMBLE_HUD();
1431     }
1432         // let's reset the view back to normal for the end
1433         R_SetView(VF_MIN, '0 0 0');
1434         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1435 }
1436
1437
1438 void CSQC_common_hud(void)
1439 {
1440     // do some accuracy var caching
1441     float i;
1442     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1443     {
1444         if(autocvar_accuracy_color_levels != acc_color_levels)
1445         {
1446             if(acc_color_levels)
1447                 strunzone(acc_color_levels);
1448             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1449             acc_levels = tokenize_console(acc_color_levels);
1450             if (acc_levels > MAX_ACCURACY_LEVELS)
1451                 acc_levels = MAX_ACCURACY_LEVELS;
1452
1453             for (i = 0; i < acc_levels; ++i)
1454                 acc_lev[i] = stof(argv(i)) / 100.0;
1455         }
1456         // let know that acc_col[] needs to be loaded
1457         acc_col_x[0] = -1;
1458     }
1459
1460     HUD_Main(); // always run these functions for alpha checks
1461     HUD_DrawScoreboard();
1462
1463     if (scoreboard_active) // scoreboard/accuracy
1464         HUD_Reset();
1465     else if (intermission == 2) // map voting screen
1466     {
1467         HUD_FinaleOverlay();
1468         HUD_Reset();
1469     }
1470         /*
1471         switch(hud)
1472         {
1473                 case HUD_SPIDERBOT:
1474                         CSQC_SPIDER_HUD();
1475                         break;
1476
1477                 case HUD_WAKIZASHI:
1478                         CSQC_WAKIZASHI_HUD();
1479                         break;
1480
1481         case HUD_BUMBLEBEE:
1482             CSQC_BUMBLE_HUD();
1483             break;
1484         }
1485         */
1486 }
1487
1488
1489 // following vectors must be global to allow seamless switching between camera modes
1490 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1491 void CSQC_Demo_Camera()
1492 {
1493         float speed, attenuation, dimensions;
1494         vector tmp, delta;
1495
1496         if( autocvar_camera_reset || !camera_mode )
1497         {
1498                 camera_offset = '0 0 0';
1499                 current_angles = '0 0 0';
1500                 camera_direction = '0 0 0';
1501                 camera_offset_z += 30;
1502                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1503                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1504                 current_origin = view_origin;
1505                 current_camera_offset  = camera_offset;
1506                 cvar_set("camera_reset", "0");
1507                 camera_mode = CAMERA_CHASE;
1508         }
1509
1510         // Camera angles
1511         if( camera_roll )
1512                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1513
1514         if(autocvar_camera_look_player)
1515         {
1516                 vector dir;
1517                 float n;
1518
1519                 dir = normalize(view_origin - current_position);
1520                 n = mouse_angles_z;
1521                 mouse_angles = vectoangles(dir);
1522                 mouse_angles_x = mouse_angles_x * -1;
1523                 mouse_angles_z = n;
1524         }
1525         else
1526         {
1527                 tmp = getmousepos() * 0.1;
1528                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1529                 {
1530                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1531                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1532                 }
1533         }
1534
1535         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1536         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1537         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1538         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1539
1540         // Fix difference when angles don't have the same sign
1541         delta = '0 0 0';
1542         if(mouse_angles_y < -60 && current_angles_y > 60)
1543                 delta = '0 360 0';
1544         if(mouse_angles_y > 60 && current_angles_y < -60)
1545                 delta = '0 -360 0';
1546
1547         if(autocvar_camera_look_player)
1548                 attenuation = autocvar_camera_look_attenuation;
1549         else
1550                 attenuation = autocvar_camera_speed_attenuation;
1551
1552         attenuation = 1 / max(1, attenuation);
1553         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1554
1555         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1556         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1557         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1558         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1559
1560         // Camera position
1561         tmp = '0 0 0';
1562         dimensions = 0;
1563
1564         if( camera_direction_x )
1565         {
1566                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1567                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1568                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1569                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1570                 ++dimensions;
1571         }
1572
1573         if( camera_direction_y )
1574         {
1575                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1576                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1577                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1578                 ++dimensions;
1579         }
1580
1581         if( camera_direction_z )
1582         {
1583                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1584                 ++dimensions;
1585         }
1586
1587         if(autocvar_camera_free)
1588                 speed = autocvar_camera_speed_free;
1589         else
1590                 speed = autocvar_camera_speed_chase;
1591
1592         if(dimensions)
1593         {
1594                 speed = speed * sqrt(1 / dimensions);
1595                 camera_offset += tmp * speed;
1596         }
1597
1598         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1599
1600         // Camera modes
1601         if( autocvar_camera_free )
1602         {
1603                 if ( camera_mode == CAMERA_CHASE )
1604                 {
1605                         current_camera_offset = current_origin + current_camera_offset;
1606                         camera_offset = current_origin + camera_offset;
1607                 }
1608
1609                 camera_mode = CAMERA_FREE;
1610                 current_position = current_camera_offset;
1611         }
1612         else
1613         {
1614                 if ( camera_mode == CAMERA_FREE )
1615                 {
1616                         current_origin = view_origin;
1617                         camera_offset = camera_offset - current_origin;
1618                         current_camera_offset = current_camera_offset - current_origin;
1619                 }
1620
1621                 camera_mode = CAMERA_CHASE;
1622
1623                 if(autocvar_camera_chase_smoothly)
1624                         current_origin += (view_origin - current_origin) * attenuation;
1625                 else
1626                         current_origin = view_origin;
1627
1628                 current_position = current_origin + current_camera_offset;
1629         }
1630
1631         R_SetView(VF_ANGLES, current_angles);
1632         R_SetView(VF_ORIGIN, current_position);
1633 }