qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon) // WEAPONTODO
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_MORTAR: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_VORTEX:
 291                 case WEP_VAPORIZER:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_DEVASTATOR: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string reticle_image;
 369 string NextFrameCommand;
 370 void CSQC_SPIDER_HUD();
 371 void CSQC_RAPTOR_HUD();
 372
 373 vector freeze_org, freeze_ang;
 374 entity nightvision_noise, nightvision_noise2;
 375
 376 #define MAX_TIME_DIFF 5
 377 float pickup_crosshair_time, pickup_crosshair_size;
 378 float hit_time, typehit_time;
 379 float nextsound_hit_time, nextsound_typehit_time;
 380 float hitindication_crosshair_time, hitindication_crosshair_size;
 381 float use_vortex_chargepool;
 382
 383 float myhealth, myhealth_prev;
 384 float myhealth_flash;
 385
 386 float old_blurradius, old_bluralpha;
 387 float old_sharpen_intensity;
 388
 389 vector myhealth_gentlergb;
 390
 391 float contentavgalpha, liquidalpha_prev;
 392 vector liquidcolor_prev;
 393
 394 float eventchase_current_distance;
 395
 396 vector damage_blurpostprocess, content_blurpostprocess;
 397
 398 float checkfail[16];
 399
 400 float rainbow_last_flicker;
 401 vector rainbow_prev_color;
 402
 403 #define BUTTON_3 4
 404 #define BUTTON_4 8
 405 float cl_notice_run();
 406 float prev_myteam;
 407 void CSQC_UpdateView(float w, float h)
 408 {
 409         entity e;
 410         float fov;
 411         float f, i, j;
 412         vector v;
 413         vector vf_size, vf_min;
 414         float a;
 415
 416         execute_next_frame();
 417
 418         ++framecount;
 419
 420         hud = getstati(STAT_HUD);
 421
 422         if(autocvar__hud_showbinds_reload) // menu can set this one
 423         {
 424                 db_close(binddb);
 425                 binddb = db_create();
 426                 cvar_set("_hud_showbinds_reload", "0");
 427         }
 428
 429         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 430                 view_quality = getproperty(VF_MINFPS_QUALITY);
 431         else
 432                 view_quality = 1;
 433
 434         button_attack2 = (input_buttons & BUTTON_3);
 435         button_zoom = (input_buttons & BUTTON_4);
 436
 437 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 438         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 439         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 440         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 441         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 442         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 443         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 444         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 445
 446         vf_size = getpropertyvec(VF_SIZE);
 447         vf_min = getpropertyvec(VF_MIN);
 448         vid_width = vf_size_x;
 449         vid_height = vf_size_y;
 450
 451         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 452         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 453
 454         WaypointSprite_Load();
 455
 456         CSQCPlayer_SetCamera();
 457
 458 #ifdef COMPAT_XON050_ENGINE
 459         if(spectatee_status)
 460                 myteam = GetPlayerColor(spectatee_status - 1);
 461         else
 462 #endif
 463                 myteam = GetPlayerColor(player_localentnum - 1);
 464
 465         if(myteam != prev_myteam)
 466         {
 467                 myteamcolors = colormapPaletteColor(myteam, 1);
 468                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 469                         hud_panel[i].update_time = time;
 470                 prev_myteam = myteam;
 471         }
 472
 473         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 474
 475         float is_dead = (getstati(STAT_HEALTH) <= 0);
 476
 477         // FIXME do we need this hack?
 478         if(isdemo())
 479         {
 480                 // in demos, input_buttons do not work
 481                 button_zoom = (autocvar__togglezoom == "-");
 482         }
 483         else if(button_zoom
 484                 && autocvar_cl_unpress_zoom_on_death
 485                 && (spectatee_status >= 0)
 486                 && (is_dead || intermission))
 487         {
 488                 // no zoom while dead or in intermission please
 489                 localcmd("-zoom\n");
 490                 button_zoom = FALSE;
 491         }
 492
 493         // event chase camera
 494         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 495         {
 496                 WepSet weapons_stat = WepSet_GetFromStat();
 497                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview || (autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(weapons_stat & WepSet_FromWeapon(WEP_PORTO))))
 498                 {
 499                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 500                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 501
 502                         // detect maximum viewoffset and use it
 503                         if(autocvar_cl_eventchase_viewoffset)
 504                         {
 505                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 506                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 507                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 508                         }
 509
 510                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 511                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 512                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 513                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 514
 515                         // make the camera smooth back
 516                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 517                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 518                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 519                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 520
 521                         makevectors(view_angles);
 522
 523                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 524                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 525
 526                         // If the boxtrace fails, revert back to line tracing.
 527                         if(trace_startsolid)
 528                         {
 529                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 530                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 531                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 532                         }
 533                         else { setproperty(VF_ORIGIN, trace_endpos); }
 534
 535                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 536                 }
 537                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 538                 {
 539                         cvar_set("chase_active", "0");
 540                         eventchase_current_distance = 0; // start from 0 next time
 541                 }
 542         }
 543         // workaround for camera stuck between player's legs when using chase_active 1
 544         // because the engine stops updating the chase_active camera when the game ends
 545         else if(intermission)
 546         {
 547                 cvar_settemp("chase_active", "-1");
 548                 eventchase_current_distance = 0;
 549         }
 550
 551         // do lockview after event chase camera so that it still applies whenever necessary.
 552         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 553         {
 554                 setproperty(VF_ORIGIN, freeze_org);
 555                 setproperty(VF_ANGLES, freeze_ang);
 556         }
 557         else
 558         {
 559                 freeze_org = getpropertyvec(VF_ORIGIN);
 560                 freeze_ang = getpropertyvec(VF_ANGLES);
 561         }
 562
 563         WarpZone_FixView();
 564         //WarpZone_FixPMove();
 565
 566         vector ov_org = '0 0 0';
 567         vector ov_mid = '0 0 0';
 568         vector ov_worldmin = '0 0 0';
 569         vector ov_worldmax = '0 0 0';
 570         if(autocvar_cl_orthoview)
 571         {
 572                 ov_worldmin = mi_picmin;
 573                 ov_worldmax = mi_picmax;
 574
 575                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 576                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 577                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 578
 579                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 580                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 581
 582                 float ov_nearest = vlen(ov_org - vec3(
 583                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 584                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 585                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 586                 ));
 587
 588                 float ov_furthest = 0;
 589                 float dist = 0;
 590
 591                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 592                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 593                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 594                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 595                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 596                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 597                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 598                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 599
 600                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 601                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 602                 cvar_settemp("r_farclip_world", "0");
 603                 cvar_settemp("r_novis", "1");
 604                 cvar_settemp("r_useportalculling", "0");
 605                 cvar_settemp("r_useinfinitefarclip", "0");
 606
 607                 setproperty(VF_ORIGIN, ov_org);
 608                 setproperty(VF_ANGLES, '90 0 0');
 609
 610                 #if 0
 611                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 612                         vtos(ov_org),
 613                         vtos(getpropertyvec(VF_ANGLES)),
 614                         ov_distance,
 615                         ov_nearest,
 616                         ov_furthest);
 617                 #endif
 618         }
 619
 620         // Render the Scene
 621         view_origin = getpropertyvec(VF_ORIGIN);
 622         view_angles = getpropertyvec(VF_ANGLES);
 623         makevectors(view_angles);
 624         view_forward = v_forward;
 625         view_right = v_right;
 626         view_up = v_up;
 627
 628 #ifdef BLURTEST
 629         if(time > blurtest_time0 && time < blurtest_time1)
 630         {
 631                 float r, t;
 632
 633                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 634                 r = t * blurtest_radius;
 635                 f = 1 / pow(t, blurtest_power) - 1;
 636
 637                 cvar_set("r_glsl_postprocess", "1");
 638                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 639         }
 640         else
 641         {
 642                 cvar_set("r_glsl_postprocess", "0");
 643                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 644         }
 645 #endif
 646
 647         TargetMusic_Advance();
 648         Fog_Force();
 649
 650         if(drawtime == 0)
 651                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 652         else
 653                 drawframetime = bound(0.000001, time - drawtime, 1);
 654         drawtime = time;
 655
 656         // watch for gametype changes here...
 657         // in ParseStuffCMD the cmd isn't executed yet :/
 658         // might even be better to add the gametype to TE_CSQC_INIT...?
 659         if(!postinit)
 660                 PostInit();
 661
 662         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 663         {
 664                 if(calledhooks & HOOK_START)
 665                 {
 666                         localcmd("\ncl_hook_gameend\n");
 667                         calledhooks |= HOOK_END;
 668                 }
 669         }
 670
 671         Announcer();
 672
 673         fov = autocvar_fov;
 674         if(fov <= 59.5)
 675         {
 676                 if(!zoomscript_caught)
 677                 {
 678                         localcmd("+button9\n");
 679                         zoomscript_caught = 1;
 680                 }
 681         }
 682         else
 683         {
 684                 if(zoomscript_caught)
 685                 {
 686                         localcmd("-button9\n");
 687                         zoomscript_caught = 0;
 688                 }
 689         }
 690
 691         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 692
 693         // next WANTED weapon (for HUD)
 694         switchweapon = getstati(STAT_SWITCHWEAPON);
 695
 696         // currently switching-to weapon (for crosshair)
 697         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 698
 699         // actually active weapon (for zoom)
 700         activeweapon = getstati(STAT_ACTIVEWEAPON);
 701
 702         f = (serverflags & SERVERFLAG_TEAMPLAY);
 703         if(f != teamplay)
 704         {
 705                 teamplay = f;
 706                 HUD_InitScores();
 707         }
 708
 709         if(last_switchweapon != switchweapon)
 710         {
 711                 weapontime = time;
 712                 last_switchweapon = switchweapon;
 713                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 714                 {
 715                         localcmd("-zoom\n");
 716                         button_zoom = FALSE;
 717                 }
 718                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 719                 {
 720                         localcmd("-fire\n");
 721                         localcmd("-fire2\n");
 722                         button_attack2 = FALSE;
 723                 }
 724         }
 725         if(last_activeweapon != activeweapon)
 726         {
 727                 last_activeweapon = activeweapon;
 728
 729                 e = get_weaponinfo(activeweapon);
 730                 if(e.netname != "")
 731                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 732                 else
 733                         localcmd("\ncl_hook_activeweapon none\n");
 734         }
 735
 736         // ALWAYS Clear Current Scene First
 737         clearscene();
 738 #ifdef WORKAROUND_XON010
 739         if(checkextension("DP_CSQC_ROTATEMOVES"))
 740         {
 741 #endif
 742         setproperty(VF_ORIGIN, view_origin);
 743         setproperty(VF_ANGLES, view_angles);
 744 #ifdef WORKAROUND_XON010
 745         }
 746 #endif
 747
 748         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 749         setproperty(VF_SIZE, vf_size);
 750         setproperty(VF_MIN, vf_min);
 751
 752         // Assign Standard Viewflags
 753         // Draw the World (and sky)
 754         setproperty(VF_DRAWWORLD, 1);
 755
 756         // Set the console size vars
 757         vid_conwidth = autocvar_vid_conwidth;
 758         vid_conheight = autocvar_vid_conheight;
 759         vid_pixelheight = autocvar_vid_pixelheight;
 760
 761         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 762         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 763
 764         // Camera for demo playback
 765         if(camera_active)
 766         {
 767                 if(autocvar_camera_enable)
 768                         CSQC_Demo_Camera();
 769                 else
 770                 {
 771                         cvar_set("chase_active", ftos(chase_active_backup));
 772                         cvar_set("cl_demo_mousegrab", "0");
 773                         camera_active = FALSE;
 774                 }
 775         }
 776 #ifdef CAMERATEST
 777         else if(autocvar_camera_enable)
 778 #else
 779         else if(autocvar_camera_enable && isdemo())
 780 #endif
 781         {
 782                 // Enable required Darkplaces cvars
 783                 chase_active_backup = autocvar_chase_active;
 784                 cvar_set("chase_active", "2");
 785                 cvar_set("cl_demo_mousegrab", "1");
 786                 camera_active = TRUE;
 787                 camera_mode = FALSE;
 788         }
 789
 790         // Draw the Crosshair
 791         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 792
 793         // Draw the Engine Status Bar (the default Quake HUD)
 794         setproperty(VF_DRAWENGINESBAR, 0);
 795
 796         // Update the mouse position
 797         /*
 798            mousepos_x = vid_conwidth;
 799            mousepos_y = vid_conheight;
 800            mousepos = mousepos*0.5 + getmousepos();
 801          */
 802
 803         e = self;
 804         for(self = world; (self = nextent(self)); )
 805                 if(self.draw)
 806                         self.draw();
 807         self = e;
 808
 809         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 810         renderscene();
 811
 812         // now switch to 2D drawing mode by calling a 2D drawing function
 813         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 814         // next R_RenderScene call
 815         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 816
 817         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 818         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 819         {
 820                 // apply night vision effect
 821                 vector tc_00, tc_01, tc_10, tc_11;
 822                 vector rgb;
 823                 rgb_x = 0; // fteqcc sucks
 824                 rgb_y = 0; // fteqcc sucks
 825                 rgb_z = 0; // fteqcc sucks
 826
 827                 if(!nightvision_noise)
 828                 {
 829                         nightvision_noise = spawn();
 830                         nightvision_noise.classname = "nightvision_noise";
 831                 }
 832                 if(!nightvision_noise2)
 833                 {
 834                         nightvision_noise2 = spawn();
 835                         nightvision_noise2.classname = "nightvision_noise2";
 836                 }
 837
 838                 // color tint in yellow
 839                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 840
 841                 // draw BG
 842                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 843                 rgb = '1 1 1';
 844                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 845                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 846                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 847                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 848                 tc_11 = tc_01 + tc_10 - tc_00;
 849                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 850                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 851                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 852                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 853                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 854                 R_EndPolygon();
 855
 856                 // draw FG
 857                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 858                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 859                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 860                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 861                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 862                 tc_11 = tc_01 + tc_10 - tc_00;
 863                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 864                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 865                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 866                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 867                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 868                 R_EndPolygon();
 869         }
 870
 871         if(autocvar_cl_reticle)
 872         {
 873                 // Draw the aiming reticle for weapons that use it
 874                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 875                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 876                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
 877                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
 878                 {
 879                         // no zoom reticle while dead
 880                         reticle_type = 0;
 881                 }
 882                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
 883                 {
 884                         if(reticle_image != "") { reticle_type = 2; }
 885                         else { reticle_type = 0; }
 886                 }
 887                 else if(button_zoom || zoomscript_caught)
 888                 {
 889                         // normal zoom
 890                         reticle_type = 1;
 891                 }
 892
 893                 if(reticle_type)
 894                 {
 895                         if(autocvar_cl_reticle_stretch)
 896                         {
 897                                 reticle_size_x = vid_conwidth;
 898                                 reticle_size_y = vid_conheight;
 899                                 reticle_pos_x = 0;
 900                                 reticle_pos_y = 0;
 901                         }
 902                         else
 903                         {
 904                                 reticle_size_x = max(vid_conwidth, vid_conheight);
 905                                 reticle_size_y = max(vid_conwidth, vid_conheight);
 906                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 907                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 908                         }
 909
 910                         if(zoomscript_caught)
 911                                 f = 1;
 912                         else
 913                                 f = current_zoomfraction;
 914
 915                         if(f)
 916                         {
 917                                 switch(reticle_type)
 918                                 {
 919                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 920                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 921                                 }
 922                         }
 923                 }
 924         }
 925         else
 926         {
 927                 if(reticle_type != 0) { reticle_type = 0; }
 928         }
 929
 930
 931         // improved polyblend
 932         if(autocvar_hud_contents)
 933         {
 934                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 935                 vector liquidcolor;
 936
 937                 switch(pointcontents(view_origin))
 938                 {
 939                         case CONTENT_WATER:
 940                                 liquidalpha = autocvar_hud_contents_water_alpha;
 941                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 942                                 incontent = 1;
 943                                 break;
 944
 945                         case CONTENT_LAVA:
 946                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 947                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 948                                 incontent = 1;
 949                                 break;
 950
 951                         case CONTENT_SLIME:
 952                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 953                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 954                                 incontent = 1;
 955                                 break;
 956
 957                         default:
 958                                 liquidalpha = 0;
 959                                 liquidcolor = '0 0 0';
 960                                 incontent = 0;
 961                                 break;
 962                 }
 963
 964                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 965                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 966                         contentfadetime = autocvar_hud_contents_fadeintime;
 967                         liquidalpha_prev = liquidalpha;
 968                         liquidcolor_prev = liquidcolor;
 969                 }
 970                 else
 971                         contentfadetime = autocvar_hud_contents_fadeouttime;
 972
 973                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 974                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 975
 976                 if(contentavgalpha)
 977                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 978
 979                 if(autocvar_hud_postprocessing)
 980                 {
 981                         if(autocvar_hud_contents_blur && contentavgalpha)
 982                         {
 983                                 content_blurpostprocess_x = 1;
 984                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 985                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 986                         }
 987                         else
 988                         {
 989                                 content_blurpostprocess_x = 0;
 990                                 content_blurpostprocess_y = 0;
 991                                 content_blurpostprocess_z = 0;
 992                         }
 993                 }
 994         }
 995
 996         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 997         {
 998                 splash_size_x = max(vid_conwidth, vid_conheight);
 999                 splash_size_y = max(vid_conwidth, vid_conheight);
1000                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1001                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1002
1003                 float myhealth_flash_temp;
1004                 myhealth = getstati(STAT_HEALTH);
1005
1006                 // fade out
1007                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1008                 // add new damage
1009                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1010
1011                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1012                 pain_threshold = autocvar_hud_damage_pain_threshold;
1013                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1014                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1015
1016                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1017                 {
1018                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1019                 }
1020
1021                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1022
1023                 if(myhealth_prev < 1)
1024                 {
1025                         if(myhealth >= 1)
1026                         {
1027                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1028                                 myhealth_flash_temp = 0;
1029                         }
1030                         else
1031                         {
1032                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1033                         }
1034                 }
1035
1036                 if(spectatee_status == -1 || intermission)
1037                 {
1038                         myhealth_flash = 0; // observing, or match ended
1039                         myhealth_flash_temp = 0;
1040                 }
1041
1042                 myhealth_prev = myhealth;
1043
1044                 // IDEA: change damage color/picture based on player model for robot/alien species?
1045                 // pro: matches model better
1046                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1047                 // maybe different reddish pics?
1048                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1049                 {
1050                         if(autocvar_cl_gentle_damage == 2)
1051                         {
1052                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1053                                 {
1054                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1055                                 }
1056                         }
1057                         else
1058                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1059
1060                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1061                 }
1062                 else
1063                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1064
1065                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1066                 {
1067                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1068                         {
1069                                 damage_blurpostprocess_x = 1;
1070                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1071                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1072                         }
1073                         else
1074                         {
1075                                 damage_blurpostprocess_x = 0;
1076                                 damage_blurpostprocess_y = 0;
1077                                 damage_blurpostprocess_z = 0;
1078                         }
1079                 }
1080         }
1081
1082         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1083         float e2 = (autocvar_hud_powerup != 0);
1084         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1085         {
1086                 // enable or disable rendering types if they are used or not
1087                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1088                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1089
1090                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1091                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1092                 {
1093                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1094                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1095                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1096                         {
1097                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1098                                 old_blurradius = blurradius;
1099                                 old_bluralpha = bluralpha;
1100                         }
1101                 }
1102                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1103                 {
1104                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1105                         old_blurradius = 0;
1106                         old_bluralpha = 0;
1107                 }
1108
1109                 // edge detection postprocess handling done second (used by hud_powerup)
1110                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1111                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1112                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1113
1114                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1115
1116                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1117                 {
1118                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1119                         {
1120                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1121                                 old_sharpen_intensity = sharpen_intensity;
1122                         }
1123                 }
1124                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1125                 {
1126                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1127                         old_sharpen_intensity = 0;
1128                 }
1129
1130                 if(cvar("r_glsl_postprocess") == 0)
1131                         cvar_set("r_glsl_postprocess", "2");
1132         }
1133         else if(cvar("r_glsl_postprocess") == 2)
1134                 cvar_set("r_glsl_postprocess", "0");
1135
1136         if(menu_visible)
1137                 menu_show();
1138
1139         /*if(gametype == MAPINFO_TYPE_CTF)
1140           {
1141           ctf_view();
1142           } else */
1143
1144         // draw 2D entities
1145         e = self;
1146         for(self = world; (self = nextent(self)); )
1147                 if(self.draw2d)
1148                         self.draw2d();
1149         self = e;
1150         Draw_ShowNames_All();
1151
1152         scoreboard_active = HUD_WouldDrawScoreboard();
1153
1154         hit_time = getstatf(STAT_HIT_TIME);
1155         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1156         {
1157                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1158                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1159
1160                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1161         }
1162         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1163         if(typehit_time > nextsound_typehit_time)
1164         {
1165                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1166                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1167
1168                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1169         }
1170
1171         //else
1172         {
1173                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1174                 {
1175                         if(getstati(STAT_FROZEN))
1176                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1177                         if(getstatf(STAT_REVIVE_PROGRESS))
1178                         {
1179                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1180                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1181                         }
1182                 }
1183
1184                 if(autocvar_r_letterbox == 0)
1185                         if(autocvar_viewsize < 120)
1186                                 CSQC_common_hud();
1187
1188                 // crosshair goes VERY LAST
1189                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1190                 {
1191                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1192                                 return;
1193
1194                         string wcross_style;
1195                         float wcross_alpha, wcross_resolution;
1196                         wcross_style = autocvar_crosshair;
1197                         if (wcross_style == "0")
1198                                 return;
1199                         wcross_resolution = autocvar_crosshair_size;
1200                         if (wcross_resolution == 0)
1201                                 return;
1202                         wcross_alpha = autocvar_crosshair_alpha;
1203                         if (wcross_alpha == 0)
1204                                 return;
1205
1206                         // TrueAim check
1207                         float shottype;
1208
1209                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1210                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1211                         wcross_origin_z = 0;
1212                         if(autocvar_crosshair_hittest)
1213                         {
1214                                 vector wcross_oldorigin;
1215                                 wcross_oldorigin = wcross_origin;
1216                                 shottype = TrueAimCheck();
1217                                 if(shottype == SHOTTYPE_HITWORLD)
1218                                 {
1219                                         v = wcross_origin - wcross_oldorigin;
1220                                         v_x /= vid_conwidth;
1221                                         v_y /= vid_conheight;
1222                                         if(vlen(v) > 0.01)
1223                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1224                                 }
1225                                 if(!autocvar_crosshair_hittest_showimpact)
1226                                         wcross_origin = wcross_oldorigin;
1227                         }
1228                         else
1229                                 shottype = SHOTTYPE_HITWORLD;
1230
1231                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1232                         string wcross_name = "";
1233                         float wcross_scale, wcross_blur;
1234
1235                         if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1236                         {
1237                                 e = get_weaponinfo(switchingweapon);
1238                                 if(e)
1239                                 {
1240                                         if(autocvar_crosshair_per_weapon)
1241                                         {
1242                                                 // WEAPONTODO: access these through some general settings (with non-balance config settings)
1243                                                 //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1244                                                 //if (wcross_resolution == 0)
1245                                                         //return;
1246
1247                                                 //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1248                                                 wcross_resolution *= e.w_crosshair_size;
1249                                                 wcross_name = e.w_crosshair;
1250                                         }
1251                                 }
1252                         }
1253
1254                         if(wcross_name == "")
1255                                 wcross_name = strcat("gfx/crosshair", wcross_style);
1256
1257                         // MAIN CROSSHAIR COLOR DECISION
1258                         switch(autocvar_crosshair_color_special)
1259                         {
1260                                 case 1: // crosshair_color_per_weapon
1261                                 {
1262                                         if(e)
1263                                         {
1264                                                 wcross_color = e.wpcolor;
1265                                                 break;
1266                                         }
1267                                         else { goto normalcolor; }
1268                                 }
1269
1270                                 case 2: // crosshair_color_by_health
1271                                 {
1272                                         float x = getstati(STAT_HEALTH);
1273
1274                                         //x = red
1275                                         //y = green
1276                                         //z = blue
1277
1278                                         wcross_color_z = 0;
1279
1280                                         if(x > 200)
1281                                         {
1282                                                 wcross_color_x = 0;
1283                                                 wcross_color_y = 1;
1284                                         }
1285                                         else if(x > 150)
1286                                         {
1287                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1288                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1289                                         }
1290                                         else if(x > 100)
1291                                         {
1292                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1293                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1294                                                 wcross_color_z = 1 - (x-100)*0.02;
1295                                         }
1296                                         else if(x > 50)
1297                                         {
1298                                                 wcross_color_x = 1;
1299                                                 wcross_color_y = 1;
1300                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1301                                         }
1302                                         else if(x > 20)
1303                                         {
1304                                                 wcross_color_x = 1;
1305                                                 wcross_color_y = (x-20)*90/27/100;
1306                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1307                                         }
1308                                         else
1309                                         {
1310                                                 wcross_color_x = 1;
1311                                                 wcross_color_y = 0;
1312                                         }
1313                                         break;
1314                                 }
1315
1316                                 case 3: // crosshair_color_rainbow
1317                                 {
1318                                         if(time >= rainbow_last_flicker)
1319                                         {
1320                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1321                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1322                                         }
1323                                         wcross_color = rainbow_prev_color;
1324                                         break;
1325                                 }
1326                                 :normalcolor
1327                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1328                         }
1329
1330                         if(autocvar_crosshair_effect_scalefade)
1331                         {
1332                                 wcross_scale = wcross_resolution;
1333                                 wcross_resolution = 1;
1334                         }
1335                         else
1336                         {
1337                                 wcross_scale = 1;
1338                         }
1339
1340                         if(autocvar_crosshair_pickup)
1341                         {
1342                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1343
1344                                 if(pickup_crosshair_time < stat_pickup_time)
1345                                 {
1346                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1347                                                 pickup_crosshair_size = 1;
1348
1349                                         pickup_crosshair_time = stat_pickup_time;
1350                                 }
1351
1352                                 if(pickup_crosshair_size > 0)
1353                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1354                                 else
1355                                         pickup_crosshair_size = 0;
1356
1357                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1358                         }
1359
1360                         if(autocvar_crosshair_hitindication)
1361                         {
1362                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1363
1364                                 if(hitindication_crosshair_time < hit_time)
1365                                 {
1366                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1367                                                 hitindication_crosshair_size = 1;
1368
1369                                         hitindication_crosshair_time = hit_time;
1370                                 }
1371
1372                                 if(hitindication_crosshair_size > 0)
1373                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1374                                 else
1375                                         hitindication_crosshair_size = 0;
1376
1377                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1378                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1379                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1380                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1381                         }
1382
1383                         if(shottype == SHOTTYPE_HITENEMY)
1384                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1385                         if(shottype == SHOTTYPE_HITTEAM)
1386                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1387
1388                         f = fabs(autocvar_crosshair_effect_time);
1389                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1390                         {
1391                                 wcross_changedonetime = time + f;
1392                         }
1393                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1394                         {
1395                                 wcross_name_changestarttime = time;
1396                                 wcross_name_changedonetime = time + f;
1397                                 if(wcross_name_goal_prev_prev)
1398                                         strunzone(wcross_name_goal_prev_prev);
1399                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1400                                 wcross_name_goal_prev = strzone(wcross_name);
1401                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1402                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1403                                 wcross_resolution_goal_prev = wcross_resolution;
1404                         }
1405
1406                         wcross_scale_goal_prev = wcross_scale;
1407                         wcross_alpha_goal_prev = wcross_alpha;
1408                         wcross_color_goal_prev = wcross_color;
1409
1410                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1411                         {
1412                                 wcross_blur = 1;
1413                                 wcross_alpha *= 0.75;
1414                         }
1415                         else
1416                                 wcross_blur = 0;
1417                         // *_prev is at time-frametime
1418                         // * is at wcross_changedonetime+f
1419                         // what do we have at time?
1420                         if(time < wcross_changedonetime)
1421                         {
1422                                 f = frametime / (wcross_changedonetime - time + frametime);
1423                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1424                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1425                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1426                         }
1427
1428                         wcross_scale_prev = wcross_scale;
1429                         wcross_alpha_prev = wcross_alpha;
1430                         wcross_color_prev = wcross_color;
1431
1432                         wcross_scale *= 1 - autocvar__menu_alpha;
1433                         wcross_alpha *= 1 - autocvar__menu_alpha;
1434                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1435
1436                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1437                         {
1438                                 // crosshair rings for weapon stats
1439                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1440                                 {
1441                                         // declarations and stats
1442                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1443                                         string ring_image = string_null, ring_inner_image = string_null;
1444                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1445
1446                                         ring_scale = autocvar_crosshair_ring_size;
1447
1448                                         float weapon_clipload, weapon_clipsize;
1449                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1450                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1451
1452                                         float vortex_charge, vortex_chargepool;
1453                                         vortex_charge = getstatf(STAT_VORTEX_CHARGE);
1454                                         vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
1455
1456                                         if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1457                                                 vortex_charge_movingavg = vortex_charge;
1458
1459
1460                                         // handle the values
1461                                         if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1462                                         {
1463                                                 if (vortex_chargepool || use_vortex_chargepool) {
1464                                                         use_vortex_chargepool = 1;
1465                                                         ring_inner_value = vortex_chargepool;
1466                                                 } else {
1467                                                         vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1468                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1469                                                 }
1470
1471                                                 ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1472                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1473                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1474
1475                                                 // draw the outer ring to show the current charge of the weapon
1476                                                 ring_value = vortex_charge;
1477                                                 ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1478                                                 ring_rgb = wcross_color;
1479                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1480                                         }
1481                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1482                                         {
1483                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1484                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1485                                                 ring_rgb = wcross_color;
1486                                                 ring_image = "gfx/crosshair_ring.tga";
1487                                         }
1488                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1489                                         {
1490                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1491                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1492                                                 ring_rgb = wcross_color;
1493                                                 ring_image = "gfx/crosshair_ring.tga";
1494                                         }
1495
1496                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1497                                         {
1498                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1499                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1500                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1501                                                 ring_rgb = wcross_color;
1502
1503                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1504                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1505                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1506                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1507                                                 else
1508                                                         ring_image = "gfx/crosshair_ring.tga";
1509                                         }
1510
1511                                         // if in weapon switch animation, fade ring out/in
1512                                         if(autocvar_crosshair_effect_time > 0)
1513                                         {
1514                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1515                                                 if (!(f < 1))
1516                                                 {
1517                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1518                                                 }
1519
1520                                                 if(wcross_ring_prev)
1521                                                 {
1522                                                         if(f < 1)
1523                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1524                                                 }
1525                                                 else
1526                                                 {
1527                                                         if(f < 1)
1528                                                                 ring_alpha *= bound(0, f, 1);
1529                                                 }
1530                                         }
1531
1532                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1533                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1534
1535                                         if (ring_value)
1536                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1537                                 }
1538
1539 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1540                                 do \
1541                                 { \
1542                                         if(wcross_blur > 0) \
1543                                         { \
1544                                                 for(i = -2; i <= 2; ++i) \
1545                                                 for(j = -2; j <= 2; ++j) \
1546                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1547                                         } \
1548                                         else \
1549                                         { \
1550                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1551                                         } \
1552                                 } \
1553                                 while(0)
1554
1555 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1556                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1557
1558 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1559                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1560
1561                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1562                                 {
1563                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1564                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1565                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1566                                         f = 1 - f;
1567                                 }
1568                                 else
1569                                 {
1570                                         f = 1;
1571                                 }
1572                                 wcross_name_alpha_goal_prev = f;
1573
1574                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1575                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1576
1577                                 if(autocvar_crosshair_dot)
1578                                 {
1579                                         vector wcross_color_old;
1580                                         wcross_color_old = wcross_color;
1581
1582                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1583                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1584
1585                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1586                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1587                                         wcross_color = wcross_color_old;
1588                                 }
1589                         }
1590                 }
1591                 else
1592                 {
1593                         wcross_scale_prev = 0;
1594                         wcross_alpha_prev = 0;
1595                         wcross_scale_goal_prev = 0;
1596                         wcross_alpha_goal_prev = 0;
1597                         wcross_changedonetime = 0;
1598                         if(wcross_name_goal_prev)
1599                                 strunzone(wcross_name_goal_prev);
1600                         wcross_name_goal_prev = string_null;
1601                         if(wcross_name_goal_prev_prev)
1602                                 strunzone(wcross_name_goal_prev_prev);
1603                         wcross_name_goal_prev_prev = string_null;
1604                         wcross_name_changestarttime = 0;
1605                         wcross_name_changedonetime = 0;
1606                         wcross_name_alpha_goal_prev = 0;
1607                         wcross_name_alpha_goal_prev_prev = 0;
1608                         wcross_resolution_goal_prev = 0;
1609                         wcross_resolution_goal_prev_prev = 0;
1610                 }
1611         }
1612
1613         if(NextFrameCommand)
1614         {
1615                 localcmd("\n", NextFrameCommand, "\n");
1616                 NextFrameCommand = string_null;
1617         }
1618
1619         // we must do this check AFTER a frame was rendered, or it won't work
1620         if(cs_project_is_b0rked == 0)
1621         {
1622                 string w0, h0;
1623                 w0 = ftos(autocvar_vid_conwidth);
1624                 h0 = ftos(autocvar_vid_conheight);
1625                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1626                 //setproperty(VF_FOV, '90 90 0');
1627                 setproperty(VF_ORIGIN, '0 0 0');
1628                 setproperty(VF_ANGLES, '0 0 0');
1629                 setproperty(VF_PERSPECTIVE, 1);
1630                 makevectors('0 0 0');
1631                 vector v1, v2;
1632                 cvar_set("vid_conwidth", "800");
1633                 cvar_set("vid_conheight", "600");
1634                 v1 = cs_project(v_forward);
1635                 cvar_set("vid_conwidth", "640");
1636                 cvar_set("vid_conheight", "480");
1637                 v2 = cs_project(v_forward);
1638                 if(v1 == v2)
1639                         cs_project_is_b0rked = 1;
1640                 else
1641                         cs_project_is_b0rked = -1;
1642                 cvar_set("vid_conwidth", w0);
1643                 cvar_set("vid_conheight", h0);
1644         }
1645
1646         if(autocvar__hud_configure)
1647                 HUD_Panel_Mouse();
1648
1649     if(hud && !intermission)
1650     {
1651         if(hud == HUD_SPIDERBOT)
1652             CSQC_SPIDER_HUD();
1653         else if(hud == HUD_WAKIZASHI)
1654             CSQC_WAKIZASHI_HUD();
1655         else if(hud == HUD_RAPTOR)
1656             CSQC_RAPTOR_HUD();
1657         else if(hud == HUD_BUMBLEBEE)
1658             CSQC_BUMBLE_HUD();
1659         else if(hud == HUD_BUMBLEBEE_GUN)
1660             CSQC_BUMBLE_GUN_HUD();
1661     }
1662
1663         cl_notice_run();
1664
1665         // let's reset the view back to normal for the end
1666         setproperty(VF_MIN, '0 0 0');
1667         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1668 }
1669
1670
1671 void CSQC_common_hud(void)
1672 {
1673         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1674                 Accuracy_LoadLevels();
1675
1676         HUD_Main(); // always run these functions for alpha checks
1677         HUD_DrawScoreboard();
1678
1679         if (scoreboard_active) // scoreboard/accuracy
1680                 HUD_Reset();
1681         else if (intermission == 2) // map voting screen
1682         {
1683                 MapVote_Draw();
1684                 HUD_Reset();
1685         }
1686 }
1687
1688
1689 // following vectors must be global to allow seamless switching between camera modes
1690 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1691 void CSQC_Demo_Camera()
1692 {
1693         float speed, attenuation, dimensions;
1694         vector tmp, delta;
1695
1696         if( autocvar_camera_reset || !camera_mode )
1697         {
1698                 camera_offset = '0 0 0';
1699                 current_angles = '0 0 0';
1700                 camera_direction = '0 0 0';
1701                 camera_offset_z += 30;
1702                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1703                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1704                 current_origin = view_origin;
1705                 current_camera_offset  = camera_offset;
1706                 cvar_set("camera_reset", "0");
1707                 camera_mode = CAMERA_CHASE;
1708         }
1709
1710         // Camera angles
1711         if( camera_roll )
1712                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1713
1714         if(autocvar_camera_look_player)
1715         {
1716                 vector dir;
1717                 float n;
1718
1719                 dir = normalize(view_origin - current_position);
1720                 n = mouse_angles_z;
1721                 mouse_angles = vectoangles(dir);
1722                 mouse_angles_x = mouse_angles_x * -1;
1723                 mouse_angles_z = n;
1724         }
1725         else
1726         {
1727                 tmp = getmousepos() * 0.1;
1728                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1729                 {
1730                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1731                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1732                 }
1733         }
1734
1735         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1736         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1737         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1738         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1739
1740         // Fix difference when angles don't have the same sign
1741         delta = '0 0 0';
1742         if(mouse_angles_y < -60 && current_angles_y > 60)
1743                 delta = '0 360 0';
1744         if(mouse_angles_y > 60 && current_angles_y < -60)
1745                 delta = '0 -360 0';
1746
1747         if(autocvar_camera_look_player)
1748                 attenuation = autocvar_camera_look_attenuation;
1749         else
1750                 attenuation = autocvar_camera_speed_attenuation;
1751
1752         attenuation = 1 / max(1, attenuation);
1753         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1754
1755         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1756         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1757         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1758         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1759
1760         // Camera position
1761         tmp = '0 0 0';
1762         dimensions = 0;
1763
1764         if( camera_direction_x )
1765         {
1766                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1767                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1768                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1769                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1770                 ++dimensions;
1771         }
1772
1773         if( camera_direction_y )
1774         {
1775                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1776                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1777                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1778                 ++dimensions;
1779         }
1780
1781         if( camera_direction_z )
1782         {
1783                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1784                 ++dimensions;
1785         }
1786
1787         if(autocvar_camera_free)
1788                 speed = autocvar_camera_speed_free;
1789         else
1790                 speed = autocvar_camera_speed_chase;
1791
1792         if(dimensions)
1793         {
1794                 speed = speed * sqrt(1 / dimensions);
1795                 camera_offset += tmp * speed;
1796         }
1797
1798         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1799
1800         // Camera modes
1801         if( autocvar_camera_free )
1802         {
1803                 if ( camera_mode == CAMERA_CHASE )
1804                 {
1805                         current_camera_offset = current_origin + current_camera_offset;
1806                         camera_offset = current_origin + camera_offset;
1807                 }
1808
1809                 camera_mode = CAMERA_FREE;
1810                 current_position = current_camera_offset;
1811         }
1812         else
1813         {
1814                 if ( camera_mode == CAMERA_FREE )
1815                 {
1816                         current_origin = view_origin;
1817                         camera_offset = camera_offset - current_origin;
1818                         current_camera_offset = current_camera_offset - current_origin;
1819                 }
1820
1821                 camera_mode = CAMERA_CHASE;
1822
1823                 if(autocvar_camera_chase_smoothly)
1824                         current_origin += (view_origin - current_origin) * attenuation;
1825                 else
1826                         current_origin = view_origin;
1827
1828                 current_position = current_origin + current_camera_offset;
1829         }
1830
1831         setproperty(VF_ANGLES, current_angles);
1832         setproperty(VF_ORIGIN, current_position);
1833 }