qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float reticle_type;
 331 string NextFrameCommand;
 332 void CSQC_SPIDER_HUD();
 333 void CSQC_RAPTOR_HUD();
 334
 335 vector freeze_org, freeze_ang;
 336 entity nightvision_noise, nightvision_noise2;
 337
 338 #define MAX_TIME_DIFF 5
 339 float pickup_crosshair_time, pickup_crosshair_size;
 340 float hit_time, typehit_time;
 341 float nextsound_hit_time, nextsound_typehit_time;
 342 float hitindication_crosshair_time, hitindication_crosshair_size;
 343 float use_nex_chargepool;
 344
 345 float myhealth, myhealth_prev;
 346 float myhealth_flash;
 347
 348 float old_blurradius, old_bluralpha;
 349 float old_sharpen_intensity;
 350
 351 vector myhealth_gentlergb;
 352
 353 float contentavgalpha, liquidalpha_prev;
 354 vector liquidcolor_prev;
 355
 356 float eventchase_current_distance;
 357
 358 vector damage_blurpostprocess, content_blurpostprocess;
 359
 360 float checkfail[16];
 361
 362 void CSQC_UpdateView(float w, float h)
 363 {
 364         entity e;
 365         float fov;
 366         float f, i, j;
 367         vector v;
 368         vector vf_size, vf_min;
 369         float a;
 370         hud = getstati(STAT_HUD);
 371
 372         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 373                 view_quality = R_SetView(VF_MINFPS_QUALITY);
 374         else
 375                 view_quality = 1;
 376
 377         button_attack2 = (input_buttons & BUTTON_3);
 378         button_zoom = (input_buttons & BUTTON_4);
 379
 380         // FIXME do we need this hack?
 381         if(isdemo())
 382         {
 383                 // in demos, input_buttons do not work
 384                 button_zoom = (autocvar__togglezoom == "-");
 385         }
 386
 387 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 388         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 389         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 390         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 391         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 392         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 393         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 394         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 395
 396         vf_size = R_SetView3fv(VF_SIZE);
 397         vf_min = R_SetView3fv(VF_MIN);
 398         vid_width = vf_size_x;
 399         vid_height = vf_size_y;
 400
 401         vector reticle_pos, reticle_size;
 402         vector splash_pos, splash_size;
 403
 404         WaypointSprite_Load();
 405
 406         if(spectatee_status)
 407                 myteam = GetPlayerColor(spectatee_status - 1);
 408         else
 409                 myteam = GetPlayerColor(player_localentnum - 1);
 410
 411         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 412
 413         // event chase camera
 414         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 415         {
 416                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 417                 {
 418                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 419                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 420
 421                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 422                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 423                         if(!autocvar_chase_active)
 424                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 425
 426                         // make the camera smooth back
 427                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 428                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 429                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 430                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 431
 432                         vector eventchase_target_origin;
 433                         makevectors(view_angles);
 434                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 435                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 436                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 437                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 438                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 439                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 440                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 441
 442                         R_SetView(VF_ORIGIN, trace_endpos);
 443                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 444                 }
 445                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 446                 {
 447                         cvar_set("chase_active", "0");
 448                         eventchase_current_distance = 0; // start from 0 next time
 449                 }
 450         }
 451
 452         // do lockview after event chase camera so that it still applies whenever necessary.
 453         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 454         {
 455                 R_SetView(VF_ORIGIN, freeze_org);
 456                 R_SetView(VF_ANGLES, freeze_ang);
 457         }
 458         else
 459         {
 460                 freeze_org = R_SetView3fv(VF_ORIGIN);
 461                 freeze_ang = R_SetView3fv(VF_ANGLES);
 462         }
 463
 464         WarpZone_FixView();
 465         //WarpZone_FixPMove();
 466
 467         // Render the Scene
 468         view_origin = R_SetView3fv(VF_ORIGIN);
 469         view_angles = R_SetView3fv(VF_ANGLES);
 470         makevectors(view_angles);
 471         view_forward = v_forward;
 472         view_right = v_right;
 473         view_up = v_up;
 474
 475 #ifdef BLURTEST
 476         if(time > blurtest_time0 && time < blurtest_time1)
 477         {
 478                 float r, t;
 479
 480                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 481                 r = t * blurtest_radius;
 482                 f = 1 / pow(t, blurtest_power) - 1;
 483
 484                 cvar_set("r_glsl_postprocess", "1");
 485                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 486         }
 487         else
 488         {
 489                 cvar_set("r_glsl_postprocess", "0");
 490                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 491         }
 492 #endif
 493
 494         TargetMusic_Advance();
 495         Fog_Force();
 496
 497         if(drawtime == 0)
 498                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 499         else
 500                 drawframetime = bound(0.000001, time - drawtime, 1);
 501         drawtime = time;
 502
 503         // watch for gametype changes here...
 504         // in ParseStuffCMD the cmd isn't executed yet :/
 505         // might even be better to add the gametype to TE_CSQC_INIT...?
 506         if(!postinit)
 507                 PostInit();
 508
 509         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 510         {
 511                 if(calledhooks & HOOK_START)
 512                 {
 513                         localcmd("\ncl_hook_gameend\n");
 514                         calledhooks |= HOOK_END;
 515                 }
 516         }
 517
 518   Announcer();
 519
 520         fov = autocvar_fov;
 521         if(fov <= 59.5)
 522         {
 523                 if(!zoomscript_caught)
 524                 {
 525                         localcmd("+button9\n");
 526                         zoomscript_caught = 1;
 527                 }
 528         }
 529         else
 530         {
 531                 if(zoomscript_caught)
 532                 {
 533                         localcmd("-button9\n");
 534                         zoomscript_caught = 0;
 535                 }
 536         }
 537
 538         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 539
 540         // next WANTED weapon (for HUD)
 541         switchweapon = getstati(STAT_SWITCHWEAPON);
 542
 543         // currently switching-to weapon (for crosshair)
 544         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 545
 546         // actually active weapon (for zoom)
 547         activeweapon = getstati(STAT_ACTIVEWEAPON);
 548
 549         f = (serverflags & SERVERFLAG_TEAMPLAY);
 550         if(f != teamplay)
 551         {
 552                 teamplay = f;
 553                 HUD_InitScores();
 554         }
 555
 556         if(last_switchweapon != switchweapon) {
 557                 weapontime = time;
 558                 last_switchweapon = switchweapon;
 559         }
 560         if(last_activeweapon != activeweapon) {
 561                 last_activeweapon = activeweapon;
 562
 563                 e = get_weaponinfo(activeweapon);
 564                 if(e.netname != "")
 565                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 566                 else
 567                         localcmd("\ncl_hook_activeweapon none\n");
 568         }
 569
 570         // ALWAYS Clear Current Scene First
 571         R_ClearScene();
 572 #ifdef WORKAROUND_XON010
 573         if(checkextension("DP_CSQC_ROTATEMOVES"))
 574         {
 575 #endif
 576         R_SetView(VF_ORIGIN, view_origin);
 577         R_SetView(VF_ANGLES, view_angles);
 578 #ifdef WORKAROUND_XON010
 579         }
 580 #endif
 581
 582         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 583         R_SetView(VF_SIZE, vf_size);
 584         R_SetView(VF_MIN, vf_min);
 585
 586         // Assign Standard Viewflags
 587         // Draw the World (and sky)
 588         R_SetView(VF_DRAWWORLD, 1);
 589
 590         // Set the console size vars
 591         vid_conwidth = autocvar_vid_conwidth;
 592         vid_conheight = autocvar_vid_conheight;
 593         vid_pixelheight = autocvar_vid_pixelheight;
 594
 595         R_SetView(VF_FOV, GetCurrentFov(fov));
 596
 597         // Camera for demo playback
 598         if(camera_active)
 599         {
 600                 if(autocvar_camera_enable)
 601                         CSQC_Demo_Camera();
 602                 else
 603                 {
 604                         cvar_set("chase_active", ftos(chase_active_backup));
 605                         cvar_set("cl_demo_mousegrab", "0");
 606                         camera_active = FALSE;
 607                 }
 608         }
 609 #ifdef CAMERATEST
 610         else if(autocvar_camera_enable)
 611 #else
 612         else if(autocvar_camera_enable && isdemo())
 613 #endif
 614         {
 615                 // Enable required Darkplaces cvars
 616                 chase_active_backup = autocvar_chase_active;
 617                 cvar_set("chase_active", "2");
 618                 cvar_set("cl_demo_mousegrab", "1");
 619                 camera_active = TRUE;
 620                 camera_mode = FALSE;
 621         }
 622
 623         // Draw the Crosshair
 624         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 625
 626         // Draw the Engine Status Bar (the default Quake HUD)
 627         R_SetView(VF_DRAWENGINEHUD, 0);
 628
 629         // Update the mouse position
 630         /*
 631            mousepos_x = vid_conwidth;
 632            mousepos_y = vid_conheight;
 633            mousepos = mousepos*0.5 + getmousepos();
 634          */
 635
 636         e = self;
 637         for(self = world; (self = nextent(self)); )
 638                 if(self.draw)
 639                         self.draw();
 640         self = e;
 641
 642         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 643         R_RenderScene();
 644
 645         // now switch to 2D drawing mode by calling a 2D drawing function
 646         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 647         // next R_RenderScene call
 648         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 649
 650         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 651         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 652         {
 653                 // apply night vision effect
 654                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 655
 656                 if(!nightvision_noise)
 657                 {
 658                         nightvision_noise = spawn();
 659                         nightvision_noise.classname = "nightvision_noise";
 660                 }
 661                 if(!nightvision_noise2)
 662                 {
 663                         nightvision_noise2 = spawn();
 664                         nightvision_noise2.classname = "nightvision_noise2";
 665                 }
 666
 667                 // color tint in yellow
 668                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 669
 670                 // draw BG
 671                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 672                 rgb = '1 1 1';
 673                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 674                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 675                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 676                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 677                 tc_11 = tc_01 + tc_10 - tc_00;
 678                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 679                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 680                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 681                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 682                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 683                 R_EndPolygon();
 684
 685                 // draw FG
 686                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 687                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 688                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 689                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 690                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 691                 tc_11 = tc_01 + tc_10 - tc_00;
 692                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 693                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 694                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 695                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 696                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 697                 R_EndPolygon();
 698         }
 699
 700         // Draw the aiming reticle for weapons that use it
 701         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 702         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 703         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 704         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 705                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 706         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 707                 reticle_type = 2; // nex zoom
 708         else if(button_zoom || zoomscript_caught)
 709                 reticle_type = 1; // normal zoom
 710         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 711                 reticle_type = 2; // nex zoom
 712
 713         if(reticle_type && autocvar_cl_reticle)
 714         {
 715                 if(autocvar_cl_reticle_stretch)
 716                 {
 717                         reticle_size_x = vid_conwidth;
 718                         reticle_size_y = vid_conheight;
 719                         reticle_pos_x = 0;
 720                         reticle_pos_y = 0;
 721                 }
 722                 else
 723                 {
 724                         reticle_size_x = max(vid_conwidth, vid_conheight);
 725                         reticle_size_y = max(vid_conwidth, vid_conheight);
 726                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 727                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 728                 }
 729
 730                 f = current_zoomfraction;
 731                 if(zoomscript_caught)
 732                         f = 1;
 733                 if(autocvar_cl_reticle_item_normal)
 734                 {
 735                         if(reticle_type == 1 && f)
 736                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 737                 }
 738                 if(autocvar_cl_reticle_item_nex)
 739                 {
 740                         if(reticle_type == 2 && f)
 741                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 742                 }
 743         }
 744
 745
 746         // improved polyblend
 747         vector rgb;
 748         if(autocvar_hud_contents)
 749         {
 750                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 751                 vector liquidcolor;
 752
 753                 switch(pointcontents(view_origin))
 754                 {
 755                         case CONTENT_WATER:
 756                                 liquidalpha = autocvar_hud_contents_water_alpha;
 757                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 758                                 incontent = 1;
 759                                 break;
 760
 761                         case CONTENT_LAVA:
 762                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 763                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 764                                 incontent = 1;
 765                                 break;
 766
 767                         case CONTENT_SLIME:
 768                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 769                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 770                                 incontent = 1;
 771                                 break;
 772
 773                         default:
 774                                 liquidalpha = 0;
 775                                 liquidcolor = '0 0 0';
 776                                 incontent = 0;
 777                                 break;
 778                 }
 779
 780                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 781                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 782                         contentfadetime = autocvar_hud_contents_fadeintime;
 783                         liquidalpha_prev = liquidalpha;
 784                         liquidcolor_prev = liquidcolor;
 785                 }
 786                 else
 787                         contentfadetime = autocvar_hud_contents_fadeouttime;
 788
 789                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 790                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 791
 792                 if(contentavgalpha)
 793                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 794
 795                 if(autocvar_hud_postprocessing)
 796                 {
 797                         if(autocvar_hud_contents_blur && contentavgalpha)
 798                         {
 799                                 content_blurpostprocess_x = 1;
 800                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 801                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 802                         }
 803                         else
 804                         {
 805                                 content_blurpostprocess_x = 0;
 806                                 content_blurpostprocess_y = 0;
 807                                 content_blurpostprocess_z = 0;
 808                         }
 809                 }
 810         }
 811
 812         if(autocvar_hud_damage)
 813         {
 814                 splash_size_x = max(vid_conwidth, vid_conheight);
 815                 splash_size_y = max(vid_conwidth, vid_conheight);
 816                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 817                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 818
 819                 float myhealth_flash_temp;
 820                 myhealth = getstati(STAT_HEALTH);
 821
 822                 // fade out
 823                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 824                 // add new damage
 825                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 826
 827                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 828                 pain_threshold = autocvar_hud_damage_pain_threshold;
 829                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 830                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 831
 832                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 833                 {
 834                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 835                 }
 836
 837                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 838
 839                 if(myhealth_prev < 1)
 840                 {
 841                         if(myhealth >= 1)
 842                         {
 843                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 844                                 myhealth_flash_temp = 0;
 845                         }
 846                         else
 847                         {
 848                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 849                         }
 850                 }
 851
 852                 if(spectatee_status == -1 || intermission)
 853                 {
 854                         myhealth_flash = 0; // observing, or match ended
 855                         myhealth_flash_temp = 0;
 856                 }
 857
 858                 myhealth_prev = myhealth;
 859
 860                 // IDEA: change damage color/picture based on player model for robot/alien species?
 861                 // pro: matches model better
 862                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 863                 // maybe different reddish pics?
 864                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 865                 {
 866                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 867                         {
 868                                 if(autocvar_cl_gentle_damage == 2)
 869                                 {
 870                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 871                                         {
 872                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 873                                         }
 874                                 }
 875                                 else
 876                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 877
 878                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 879                         }
 880                         else
 881                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 882                 }
 883
 884                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 885                 {
 886                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 887                         {
 888                                 damage_blurpostprocess_x = 1;
 889                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 890                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 891                         }
 892                         else
 893                         {
 894                                 damage_blurpostprocess_x = 0;
 895                                 damage_blurpostprocess_y = 0;
 896                                 damage_blurpostprocess_z = 0;
 897                         }
 898                 }
 899         }
 900
 901         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 902         {
 903                 // enable or disable rendering types if they are used or not
 904                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 905                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 906
 907                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 908                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 909                 {
 910                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 911                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 912                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 913                         {
 914                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 915                                 old_blurradius = blurradius;
 916                                 old_bluralpha = bluralpha;
 917                         }
 918                 }
 919                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 920                 {
 921                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 922                         old_blurradius = 0;
 923                         old_bluralpha = 0;
 924                 }
 925
 926                 // edge detection postprocess handling done second (used by hud_powerup)
 927                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 928                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 929                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 930
 931                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 932
 933                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 934                 {
 935                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 936                         {
 937                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 938                                 old_sharpen_intensity = sharpen_intensity;
 939                         }
 940                 }
 941                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 942                 {
 943                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 944                         old_sharpen_intensity = 0;
 945                 }
 946         }
 947
 948         if(menu_visible)
 949                 menu_show();
 950
 951         /*if(gametype == GAME_CTF)
 952           {
 953           ctf_view();
 954           } else */
 955
 956         // draw 2D entities
 957         e = self;
 958         for(self = world; (self = nextent(self)); )
 959                 if(self.draw2d)
 960                         self.draw2d();
 961         self = e;
 962         Draw_ShowNames_All();
 963
 964         scoreboard_active = HUD_WouldDrawScoreboard();
 965
 966         hit_time = getstatf(STAT_HIT_TIME);
 967         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 968         {
 969                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 970                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 971
 972                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 973         }
 974         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 975         if(typehit_time > nextsound_typehit_time)
 976         {
 977                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 978                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 979
 980                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 981         }
 982
 983         //else
 984         {
 985                 if(gametype == GAME_FREEZETAG)
 986                 {
 987                         if(getstati(STAT_FROZEN))
 988                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 989                         if(getstatf(STAT_REVIVE_PROGRESS))
 990                         {
 991                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 992                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 993                         }
 994                 }
 995
 996                 if(autocvar_r_letterbox == 0)
 997                         if(autocvar_viewsize < 120)
 998                                 CSQC_common_hud();
 999
1000                 // crosshair goes VERY LAST
1001                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1002                         string wcross_style;
1003                         float wcross_alpha, wcross_resolution;
1004                         wcross_style = autocvar_crosshair;
1005                         if (wcross_style == "0")
1006                                 return;
1007                         wcross_resolution = autocvar_crosshair_size;
1008                         if (wcross_resolution == 0)
1009                                 return;
1010                         wcross_alpha = autocvar_crosshair_alpha;
1011                         if (wcross_alpha == 0)
1012                                 return;
1013
1014                         // TrueAim check
1015                         float shottype;
1016
1017                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1018                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1019                         wcross_origin_z = 0;
1020                         if(autocvar_crosshair_hittest)
1021                         {
1022                                 vector wcross_oldorigin;
1023                                 wcross_oldorigin = wcross_origin;
1024                                 shottype = TrueAimCheck();
1025                                 if(shottype == SHOTTYPE_HITWORLD)
1026                                 {
1027                                         v = wcross_origin - wcross_oldorigin;
1028                                         v_x /= vid_conwidth;
1029                                         v_y /= vid_conheight;
1030                                         if(vlen(v) > 0.01)
1031                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1032                                 }
1033                                 if(!autocvar_crosshair_hittest_showimpact)
1034                                         wcross_origin = wcross_oldorigin;
1035                         }
1036                         else
1037                                 shottype = SHOTTYPE_HITWORLD;
1038
1039                         vector wcross_color, wcross_size;
1040                         string wcross_wep, wcross_name;
1041                         float wcross_scale, wcross_blur;
1042
1043                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1044                                 e = get_weaponinfo(switchingweapon);
1045                                 if (e && e.netname != "")
1046                                 {
1047                                         wcross_wep = e.netname;
1048                                         if(autocvar_crosshair_per_weapon)
1049                                         {
1050                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1051                                                 if (wcross_resolution == 0)
1052                                                         return;
1053                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1054                                                 if (wcross_alpha == 0)
1055                                                         return;
1056
1057                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1058                                                 if(wcross_style == "" || wcross_style == "0")
1059                                                         wcross_style = wcross_wep;
1060                                         }
1061                                 }
1062                         }
1063                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1064                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1065                         else if(autocvar_crosshair_color_by_health)
1066                         {
1067                                 float x = getstati(STAT_HEALTH);
1068
1069                                 //x = red
1070                                 //y = green
1071                                 //z = blue
1072
1073                                 wcross_color_z = 0;
1074
1075                                 if(x > 200)
1076                                 {
1077                                         wcross_color_x = 0;
1078                                         wcross_color_y = 1;
1079                                 }
1080                                 else if(x > 150)
1081                                 {
1082                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1083                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1084                                 }
1085                                 else if(x > 100)
1086                                 {
1087                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1088                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1089                                         wcross_color_z = 1 - (x-100)*0.02;
1090                                 }
1091                                 else if(x > 50)
1092                                 {
1093                                         wcross_color_x = 1;
1094                                         wcross_color_y = 1;
1095                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1096                                 }
1097                                 else if(x > 20)
1098                                 {
1099                                         wcross_color_x = 1;
1100                                         wcross_color_y = (x-20)*90/27/100;
1101                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1102                                 }
1103                                 else
1104                                 {
1105                                         wcross_color_x = 1;
1106                                         wcross_color_y = 0;
1107                                 }
1108                         }
1109                         else
1110                                 wcross_color = stov(autocvar_crosshair_color);
1111
1112                         wcross_name = strcat("gfx/crosshair", wcross_style);
1113
1114                         if(autocvar_crosshair_effect_scalefade)
1115                         {
1116                                 wcross_scale = wcross_resolution;
1117                                 wcross_resolution = 1;
1118                         }
1119                         else
1120                         {
1121                                 wcross_scale = 1;
1122                         }
1123
1124                         if(autocvar_crosshair_pickup)
1125                         {
1126                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1127
1128                                 if(pickup_crosshair_time < stat_pickup_time)
1129                                 {
1130                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1131                                                 pickup_crosshair_size = 1;
1132
1133                                         pickup_crosshair_time = stat_pickup_time;
1134                                 }
1135
1136                                 if(pickup_crosshair_size > 0)
1137                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1138                                 else
1139                                         pickup_crosshair_size = 0;
1140
1141                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1142                         }
1143
1144                         if(autocvar_crosshair_hitindication)
1145                         {
1146                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1147                                 if(hitindication_crosshair_time < hit_time)
1148                                 {
1149                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1150                                                 hitindication_crosshair_size = 1;
1151
1152                                         hitindication_crosshair_time = hit_time;
1153                                 }
1154
1155                                 if(hitindication_crosshair_size > 0)
1156                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1157                                 else
1158                                         hitindication_crosshair_size = 0;
1159
1160                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1161                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1162                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1163                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1164                         }
1165
1166                         if(shottype == SHOTTYPE_HITENEMY)
1167                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1168                         if(shottype == SHOTTYPE_HITTEAM)
1169                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1170
1171                         f = autocvar_crosshair_effect_speed;
1172                         if(f < 0)
1173                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1174                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1175                         {
1176                                 wcross_changedonetime = time + f;
1177                         }
1178                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1179                         {
1180                                 wcross_name_changestarttime = time;
1181                                 wcross_name_changedonetime = time + f;
1182                                 if(wcross_name_goal_prev_prev)
1183                                         strunzone(wcross_name_goal_prev_prev);
1184                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1185                                 wcross_name_goal_prev = strzone(wcross_name);
1186                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1187                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1188                                 wcross_resolution_goal_prev = wcross_resolution;
1189                         }
1190
1191                         wcross_scale_goal_prev = wcross_scale;
1192                         wcross_alpha_goal_prev = wcross_alpha;
1193                         wcross_color_goal_prev = wcross_color;
1194
1195                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1196                         {
1197                                 wcross_blur = 1;
1198                                 wcross_alpha *= 0.75;
1199                         }
1200                         else
1201                                 wcross_blur = 0;
1202                         // *_prev is at time-frametime
1203                         // * is at wcross_changedonetime+f
1204                         // what do we have at time?
1205                         if(time < wcross_changedonetime)
1206                         {
1207                                 f = frametime / (wcross_changedonetime - time + frametime);
1208                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1209                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1210                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1211                         }
1212
1213                         wcross_scale_prev = wcross_scale;
1214                         wcross_alpha_prev = wcross_alpha;
1215                         wcross_color_prev = wcross_color;
1216
1217                         wcross_scale *= 1 - autocvar__menu_alpha;
1218                         wcross_alpha *= 1 - autocvar__menu_alpha;
1219                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1220
1221                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1222                         {
1223                                 // crosshair rings for weapon stats
1224                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1225                                 {
1226                                         // declarations and stats
1227                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1228                                         string ring_image, ring_inner_image;
1229                                         vector ring_rgb, ring_inner_rgb;
1230
1231                                         ring_scale = autocvar_crosshair_ring_size;
1232
1233                                         float weapon_clipload, weapon_clipsize;
1234                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1235                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1236
1237                                         float nex_charge, nex_chargepool;
1238                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1239                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1240
1241                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1242                                                 nex_charge_movingavg = nex_charge;
1243
1244
1245                                         // handle the values
1246                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1247                                         {
1248                                                 if (nex_chargepool || use_nex_chargepool) {
1249                                                         use_nex_chargepool = 1;
1250                                                         ring_inner_value = nex_chargepool;
1251                                                 } else {
1252                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1253                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1254                                                 }
1255
1256                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1257                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1258                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1259
1260                                                 // draw the outer ring to show the current charge of the weapon
1261                                                 ring_value = nex_charge;
1262                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1263                                                 ring_rgb = wcross_color;
1264                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1265                                         }
1266                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1267                                         {
1268                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1269                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1270                                                 ring_rgb = wcross_color;
1271                                                 ring_image = "gfx/crosshair_ring.tga";
1272                                         }
1273                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1274                                         {
1275                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1276                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1277                                                 ring_rgb = wcross_color;
1278                                                 ring_image = "gfx/crosshair_ring.tga";
1279                                         }
1280
1281                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1282                                         {
1283                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1284                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1285                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1286                                                 ring_rgb = wcross_color;
1287
1288                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1289                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1290                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1291                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1292                                                 else
1293                                                         ring_image = "gfx/crosshair_ring.tga";
1294                                         }
1295
1296                                         // if in weapon switch animation, fade ring out/in
1297                                         if(g_weaponswitchdelay > 0)
1298                                         {
1299                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1300                                                 if(f > 0 && f < 2)
1301                                                         ring_alpha *= fabs(1 - f);
1302                                         }
1303
1304                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1305                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1306
1307                                         if (ring_value)
1308                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1309                                 }
1310
1311 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1312                                 do \
1313                                 { \
1314                                         if(wcross_blur > 0) \
1315                                         { \
1316                                                 for(i = -2; i <= 2; ++i) \
1317                                                 for(j = -2; j <= 2; ++j) \
1318                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1319                                         } \
1320                                         else \
1321                                         { \
1322                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1323                                         } \
1324                                 } \
1325                                 while(0)
1326
1327 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1328                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1329
1330 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1331                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1332
1333                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1334                                 {
1335                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1336                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1337                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1338                                         f = 1 - f;
1339                                 }
1340                                 else
1341                                 {
1342                                         f = 1;
1343                                 }
1344                                 wcross_name_alpha_goal_prev = f;
1345
1346                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1347                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1348
1349                                 if(autocvar_crosshair_dot)
1350                                 {
1351                                         vector wcross_color_old;
1352                                         wcross_color_old = wcross_color;
1353                                         if(autocvar_crosshair_dot_color != "0")
1354                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1355                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1356                                         // FIXME why don't we use wcross_alpha here?
1357                                         wcross_color = wcross_color_old;
1358                                 }
1359                         }
1360                 }
1361                 else
1362                 {
1363                         wcross_scale_prev = 0;
1364                         wcross_alpha_prev = 0;
1365                         wcross_scale_goal_prev = 0;
1366                         wcross_alpha_goal_prev = 0;
1367                         wcross_changedonetime = 0;
1368                         if(wcross_name_goal_prev)
1369                                 strunzone(wcross_name_goal_prev);
1370                         wcross_name_goal_prev = string_null;
1371                         if(wcross_name_goal_prev_prev)
1372                                 strunzone(wcross_name_goal_prev_prev);
1373                         wcross_name_goal_prev_prev = string_null;
1374                         wcross_name_changestarttime = 0;
1375                         wcross_name_changedonetime = 0;
1376                         wcross_name_alpha_goal_prev = 0;
1377                         wcross_name_alpha_goal_prev_prev = 0;
1378                         wcross_resolution_goal_prev = 0;
1379                         wcross_resolution_goal_prev_prev = 0;
1380                 }
1381         }
1382
1383         if(NextFrameCommand)
1384         {
1385                 localcmd("\n", NextFrameCommand, "\n");
1386                 NextFrameCommand = string_null;
1387         }
1388
1389         // we must do this check AFTER a frame was rendered, or it won't work
1390         if(cs_project_is_b0rked == 0)
1391         {
1392                 string w0, h0;
1393                 w0 = ftos(autocvar_vid_conwidth);
1394                 h0 = ftos(autocvar_vid_conheight);
1395                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1396                 //R_SetView(VF_FOV, '90 90 0');
1397                 R_SetView(VF_ORIGIN, '0 0 0');
1398                 R_SetView(VF_ANGLES, '0 0 0');
1399                 R_SetView(VF_PERSPECTIVE, 1);
1400                 makevectors('0 0 0');
1401                 vector v1, v2;
1402                 cvar_set("vid_conwidth", "800");
1403                 cvar_set("vid_conheight", "600");
1404                 v1 = cs_project(v_forward);
1405                 cvar_set("vid_conwidth", "640");
1406                 cvar_set("vid_conheight", "480");
1407                 v2 = cs_project(v_forward);
1408                 if(v1 == v2)
1409                         cs_project_is_b0rked = 1;
1410                 else
1411                         cs_project_is_b0rked = -1;
1412                 cvar_set("vid_conwidth", w0);
1413                 cvar_set("vid_conheight", h0);
1414         }
1415
1416         if(autocvar__hud_configure)
1417                 HUD_Panel_Mouse();
1418
1419     if(hud && !intermission)
1420     {
1421         if(hud == HUD_SPIDERBOT)
1422             CSQC_SPIDER_HUD();
1423         else if(hud == HUD_WAKIZASHI)
1424             CSQC_WAKIZASHI_HUD();
1425         else if(hud == HUD_RAPTOR)
1426             CSQC_RAPTOR_HUD();
1427         else if(hud == HUD_BUMBLEBEE)
1428             CSQC_BUMBLE_HUD();
1429     }
1430         // let's reset the view back to normal for the end
1431         R_SetView(VF_MIN, '0 0 0');
1432         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1433 }
1434
1435
1436 void CSQC_common_hud(void)
1437 {
1438     // do some accuracy var caching
1439     float i;
1440     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1441     {
1442         if(autocvar_accuracy_color_levels != acc_color_levels)
1443         {
1444             if(acc_color_levels)
1445                 strunzone(acc_color_levels);
1446             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1447             acc_levels = tokenize_console(acc_color_levels);
1448             if (acc_levels > MAX_ACCURACY_LEVELS)
1449                 acc_levels = MAX_ACCURACY_LEVELS;
1450
1451             for (i = 0; i < acc_levels; ++i)
1452                 acc_lev[i] = stof(argv(i)) / 100.0;
1453         }
1454         // let know that acc_col[] needs to be loaded
1455         acc_col_x[0] = -1;
1456     }
1457
1458     HUD_Main(); // always run these functions for alpha checks
1459     HUD_DrawScoreboard();
1460
1461     if (scoreboard_active) // scoreboard/accuracy
1462         HUD_Reset();
1463     else if (intermission == 2) // map voting screen
1464     {
1465         HUD_FinaleOverlay();
1466         HUD_Reset();
1467     }
1468         /*
1469         switch(hud)
1470         {
1471                 case HUD_SPIDERBOT:
1472                         CSQC_SPIDER_HUD();
1473                         break;
1474
1475                 case HUD_WAKIZASHI:
1476                         CSQC_WAKIZASHI_HUD();
1477                         break;
1478
1479         case HUD_BUMBLEBEE:
1480             CSQC_BUMBLE_HUD();
1481             break;
1482         }
1483         */
1484 }
1485
1486
1487 // following vectors must be global to allow seamless switching between camera modes
1488 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1489 void CSQC_Demo_Camera()
1490 {
1491         float speed, attenuation, dimensions;
1492         vector tmp, delta;
1493
1494         if( autocvar_camera_reset || !camera_mode )
1495         {
1496                 camera_offset = '0 0 0';
1497                 current_angles = '0 0 0';
1498                 camera_direction = '0 0 0';
1499                 camera_offset_z += 30;
1500                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1501                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1502                 current_origin = view_origin;
1503                 current_camera_offset  = camera_offset;
1504                 cvar_set("camera_reset", "0");
1505                 camera_mode = CAMERA_CHASE;
1506         }
1507
1508         // Camera angles
1509         if( camera_roll )
1510                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1511
1512         if(autocvar_camera_look_player)
1513         {
1514                 vector dir;
1515                 float n;
1516
1517                 dir = normalize(view_origin - current_position);
1518                 n = mouse_angles_z;
1519                 mouse_angles = vectoangles(dir);
1520                 mouse_angles_x = mouse_angles_x * -1;
1521                 mouse_angles_z = n;
1522         }
1523         else
1524         {
1525                 tmp = getmousepos() * 0.1;
1526                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1527                 {
1528                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1529                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1530                 }
1531         }
1532
1533         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1534         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1535         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1536         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1537
1538         // Fix difference when angles don't have the same sign
1539         delta = '0 0 0';
1540         if(mouse_angles_y < -60 && current_angles_y > 60)
1541                 delta = '0 360 0';
1542         if(mouse_angles_y > 60 && current_angles_y < -60)
1543                 delta = '0 -360 0';
1544
1545         if(autocvar_camera_look_player)
1546                 attenuation = autocvar_camera_look_attenuation;
1547         else
1548                 attenuation = autocvar_camera_speed_attenuation;
1549
1550         attenuation = 1 / max(1, attenuation);
1551         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1552
1553         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1554         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1555         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1556         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1557
1558         // Camera position
1559         tmp = '0 0 0';
1560         dimensions = 0;
1561
1562         if( camera_direction_x )
1563         {
1564                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1565                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1566                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1567                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1568                 ++dimensions;
1569         }
1570
1571         if( camera_direction_y )
1572         {
1573                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1574                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1575                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1576                 ++dimensions;
1577         }
1578
1579         if( camera_direction_z )
1580         {
1581                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1582                 ++dimensions;
1583         }
1584
1585         if(autocvar_camera_free)
1586                 speed = autocvar_camera_speed_free;
1587         else
1588                 speed = autocvar_camera_speed_chase;
1589
1590         if(dimensions)
1591         {
1592                 speed = speed * sqrt(1 / dimensions);
1593                 camera_offset += tmp * speed;
1594         }
1595
1596         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1597
1598         // Camera modes
1599         if( autocvar_camera_free )
1600         {
1601                 if ( camera_mode == CAMERA_CHASE )
1602                 {
1603                         current_camera_offset = current_origin + current_camera_offset;
1604                         camera_offset = current_origin + camera_offset;
1605                 }
1606
1607                 camera_mode = CAMERA_FREE;
1608                 current_position = current_camera_offset;
1609         }
1610         else
1611         {
1612                 if ( camera_mode == CAMERA_FREE )
1613                 {
1614                         current_origin = view_origin;
1615                         camera_offset = camera_offset - current_origin;
1616                         current_camera_offset = current_camera_offset - current_origin;
1617                 }
1618
1619                 camera_mode = CAMERA_CHASE;
1620
1621                 if(autocvar_camera_chase_smoothly)
1622                         current_origin += (view_origin - current_origin) * attenuation;
1623                 else
1624                         current_origin = view_origin;
1625
1626                 current_position = current_origin + current_camera_offset;
1627         }
1628
1629         R_SetView(VF_ANGLES, current_angles);
1630         R_SetView(VF_ORIGIN, current_position);
1631 }