qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107                 if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir)
 127                 zoomin_effect = 0;
 128
 129         if(zoomin_effect || camera_active)
 130         {
 131                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 132         }
 133         else
 134         {
 135                 if(zoomspeed < 0) // instant zoom
 136                 {
 137                         if(zoomdir)
 138                                 current_viewzoom = 1 / zoomfactor;
 139                         else
 140                                 current_viewzoom = 1;
 141                 }
 142                 else
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 146                         else
 147                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 148                 }
 149         }
 150
 151         if(almost_equals(current_viewzoom, 1))
 152                 current_zoomfraction = 0;
 153         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 154                 current_zoomfraction = 1;
 155         else
 156                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 157
 158         if(zoomsensitivity < 1)
 159                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 160         else
 161                 setsensitivityscale(1);
 162
 163         makevectors(view_angles);
 164
 165         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 v = pmove_vel;
 168                 if(csqcplayer)
 169                         v = csqcplayer.velocity;
 170
 171                 switch(autocvar_cl_velocityzoom_type)
 172                 {
 173                         case 3: curspeed = max(0, v_forward * v); break;
 174                         case 2: curspeed = (v_forward * v); break;
 175                         case 1: default: curspeed = vlen(v); break;
 176                 }
 177
 178                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 179                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 180                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 181
 182                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 183         }
 184         else
 185                 velocityzoom = 1;
 186
 187         float frustumx, frustumy, fovx, fovy;
 188         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 189         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 190         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 191         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 192
 193         return '1 0 0' * fovx + '0 1 0' * fovy;
 194 }
 195
 196 // this function must match W_SetupShot!
 197 float zoomscript_caught;
 198
 199 vector wcross_origin;
 200 float wcross_scale_prev, wcross_alpha_prev;
 201 vector wcross_color_prev;
 202 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 203 vector wcross_color_goal_prev;
 204 float wcross_changedonetime;
 205
 206 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 207 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 208 float wcross_name_changestarttime, wcross_name_changedonetime;
 209 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 210 entity trueaim;
 211 entity trueaim_rifle;
 212
 213 #define SHOTTYPE_HITTEAM 1
 214 #define SHOTTYPE_HITOBSTRUCTION 2
 215 #define SHOTTYPE_HITWORLD 3
 216 #define SHOTTYPE_HITENEMY 4
 217
 218 void TrueAim_Init()
 219 {
 220         trueaim = spawn();
 221         trueaim.classname = "trueaim";
 222         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 223         trueaim_rifle = spawn();
 224         trueaim_rifle.classname = "trueaim_rifle";
 225         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 226 }
 227
 228 float EnemyHitCheck()
 229 {
 230         float t, n;
 231         wcross_origin = project_3d_to_2d(trace_endpos);
 232         wcross_origin_z = 0;
 233         if(trace_ent)
 234                 n = trace_ent.entnum;
 235         else
 236                 n = trace_networkentity;
 237         if(n < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(n > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(n - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == FL_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float CAMERA_FREE = 1;
 344 float CAMERA_CHASE = 2;
 345 float reticle_type;
 346 string NextFrameCommand;
 347 void CSQC_SPIDER_HUD();
 348 void CSQC_RAPTOR_HUD();
 349
 350 vector freeze_org, freeze_ang;
 351 entity nightvision_noise, nightvision_noise2;
 352
 353 #define MAX_TIME_DIFF 5
 354 float pickup_crosshair_time, pickup_crosshair_size;
 355 float hit_time, typehit_time;
 356 float nextsound_hit_time, nextsound_typehit_time;
 357 float hitindication_crosshair_time, hitindication_crosshair_size;
 358 float use_nex_chargepool;
 359
 360 float myhealth, myhealth_prev;
 361 float myhealth_flash;
 362
 363 float old_blurradius, old_bluralpha;
 364 float old_sharpen_intensity;
 365
 366 vector myhealth_gentlergb;
 367
 368 float contentavgalpha, liquidalpha_prev;
 369 vector liquidcolor_prev;
 370
 371 float eventchase_current_distance;
 372
 373 vector damage_blurpostprocess, content_blurpostprocess;
 374
 375 float checkfail[16];
 376
 377 #define BUTTON_3 4
 378 #define BUTTON_4 8
 379 float cl_notice_run();
 380 void CSQC_UpdateView(float w, float h)
 381 {
 382         entity e;
 383         float fov;
 384         float f, i, j;
 385         vector v;
 386         vector vf_size, vf_min;
 387         float a;
 388
 389         execute_next_frame();
 390
 391         ++framecount;
 392
 393         hud = getstati(STAT_HUD);
 394
 395         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 396                 view_quality = getproperty(VF_MINFPS_QUALITY);
 397         else
 398                 view_quality = 1;
 399
 400         button_attack2 = (input_buttons & BUTTON_3);
 401         button_zoom = (input_buttons & BUTTON_4);
 402
 403         // FIXME do we need this hack?
 404         if(isdemo())
 405         {
 406                 // in demos, input_buttons do not work
 407                 button_zoom = (autocvar__togglezoom == "-");
 408         }
 409
 410 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 411         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 412         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 413         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 414         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 415         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 416         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 417         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 418
 419         vf_size = getpropertyvec(VF_SIZE);
 420         vf_min = getpropertyvec(VF_MIN);
 421         vid_width = vf_size_x;
 422         vid_height = vf_size_y;
 423
 424         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 425         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 426
 427         WaypointSprite_Load();
 428
 429         CSQCPlayer_SetCamera();
 430
 431 #ifdef COMPAT_XON050_ENGINE
 432         if(spectatee_status)
 433                 myteam = GetPlayerColor(spectatee_status - 1);
 434         else
 435 #endif
 436                 myteam = GetPlayerColor(player_localentnum - 1);
 437
 438         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 439
 440         // event chase camera
 441         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 442         {
 443                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 444                 {
 445                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 446                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 447
 448                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 449                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 450                         if(!autocvar_chase_active)
 451                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 452
 453                         // make the camera smooth back
 454                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 455                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 456                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 457                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 458
 459                         vector eventchase_target_origin;
 460                         makevectors(view_angles);
 461                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 462                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 463                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 464                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 465                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 466                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 467                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 468
 469                         setproperty(VF_ORIGIN, trace_endpos);
 470                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 471                 }
 472                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 473                 {
 474                         cvar_set("chase_active", "0");
 475                         eventchase_current_distance = 0; // start from 0 next time
 476                 }
 477         }
 478         // workaround for camera stuck between player's legs when using chase_active 1
 479         // because the engine stops updating the chase_active camera when the game ends
 480         else if(intermission)
 481         {
 482                 cvar_settemp("chase_active", "-1");
 483                 eventchase_current_distance = 0;
 484         }
 485
 486         // do lockview after event chase camera so that it still applies whenever necessary.
 487         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 488         {
 489                 setproperty(VF_ORIGIN, freeze_org);
 490                 setproperty(VF_ANGLES, freeze_ang);
 491         }
 492         else
 493         {
 494                 freeze_org = getpropertyvec(VF_ORIGIN);
 495                 freeze_ang = getpropertyvec(VF_ANGLES);
 496         }
 497
 498         WarpZone_FixView();
 499         //WarpZone_FixPMove();
 500
 501         // Render the Scene
 502         view_origin = getpropertyvec(VF_ORIGIN);
 503         view_angles = getpropertyvec(VF_ANGLES);
 504         makevectors(view_angles);
 505         view_forward = v_forward;
 506         view_right = v_right;
 507         view_up = v_up;
 508
 509 #ifdef BLURTEST
 510         if(time > blurtest_time0 && time < blurtest_time1)
 511         {
 512                 float r, t;
 513
 514                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 515                 r = t * blurtest_radius;
 516                 f = 1 / pow(t, blurtest_power) - 1;
 517
 518                 cvar_set("r_glsl_postprocess", "1");
 519                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 520         }
 521         else
 522         {
 523                 cvar_set("r_glsl_postprocess", "0");
 524                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 525         }
 526 #endif
 527
 528         TargetMusic_Advance();
 529         Fog_Force();
 530
 531         if(drawtime == 0)
 532                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 533         else
 534                 drawframetime = bound(0.000001, time - drawtime, 1);
 535         drawtime = time;
 536
 537         // watch for gametype changes here...
 538         // in ParseStuffCMD the cmd isn't executed yet :/
 539         // might even be better to add the gametype to TE_CSQC_INIT...?
 540         if(!postinit)
 541                 PostInit();
 542
 543         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 544         {
 545                 if(calledhooks & HOOK_START)
 546                 {
 547                         localcmd("\ncl_hook_gameend\n");
 548                         calledhooks |= HOOK_END;
 549                 }
 550         }
 551
 552         Announcer();
 553
 554         fov = autocvar_fov;
 555         if(fov <= 59.5)
 556         {
 557                 if(!zoomscript_caught)
 558                 {
 559                         localcmd("+button9\n");
 560                         zoomscript_caught = 1;
 561                 }
 562         }
 563         else
 564         {
 565                 if(zoomscript_caught)
 566                 {
 567                         localcmd("-button9\n");
 568                         zoomscript_caught = 0;
 569                 }
 570         }
 571
 572         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 573
 574         // next WANTED weapon (for HUD)
 575         switchweapon = getstati(STAT_SWITCHWEAPON);
 576
 577         // currently switching-to weapon (for crosshair)
 578         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 579
 580         // actually active weapon (for zoom)
 581         activeweapon = getstati(STAT_ACTIVEWEAPON);
 582
 583         f = (serverflags & SERVERFLAG_TEAMPLAY);
 584         if(f != teamplay)
 585         {
 586                 teamplay = f;
 587                 HUD_InitScores();
 588         }
 589
 590         if(last_switchweapon != switchweapon) {
 591                 weapontime = time;
 592                 last_switchweapon = switchweapon;
 593         }
 594         if(last_activeweapon != activeweapon) {
 595                 last_activeweapon = activeweapon;
 596
 597                 e = get_weaponinfo(activeweapon);
 598                 if(e.netname != "")
 599                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 600                 else
 601                         localcmd("\ncl_hook_activeweapon none\n");
 602         }
 603
 604         // ALWAYS Clear Current Scene First
 605         clearscene();
 606 #ifdef WORKAROUND_XON010
 607         if(checkextension("DP_CSQC_ROTATEMOVES"))
 608         {
 609 #endif
 610         setproperty(VF_ORIGIN, view_origin);
 611         setproperty(VF_ANGLES, view_angles);
 612 #ifdef WORKAROUND_XON010
 613         }
 614 #endif
 615
 616         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 617         setproperty(VF_SIZE, vf_size);
 618         setproperty(VF_MIN, vf_min);
 619
 620         // Assign Standard Viewflags
 621         // Draw the World (and sky)
 622         setproperty(VF_DRAWWORLD, 1);
 623
 624         // Set the console size vars
 625         vid_conwidth = autocvar_vid_conwidth;
 626         vid_conheight = autocvar_vid_conheight;
 627         vid_pixelheight = autocvar_vid_pixelheight;
 628
 629         setproperty(VF_FOV, GetCurrentFov(fov));
 630
 631         // Camera for demo playback
 632         if(camera_active)
 633         {
 634                 if(autocvar_camera_enable)
 635                         CSQC_Demo_Camera();
 636                 else
 637                 {
 638                         cvar_set("chase_active", ftos(chase_active_backup));
 639                         cvar_set("cl_demo_mousegrab", "0");
 640                         camera_active = FALSE;
 641                 }
 642         }
 643 #ifdef CAMERATEST
 644         else if(autocvar_camera_enable)
 645 #else
 646         else if(autocvar_camera_enable && isdemo())
 647 #endif
 648         {
 649                 // Enable required Darkplaces cvars
 650                 chase_active_backup = autocvar_chase_active;
 651                 cvar_set("chase_active", "2");
 652                 cvar_set("cl_demo_mousegrab", "1");
 653                 camera_active = TRUE;
 654                 camera_mode = FALSE;
 655         }
 656
 657         // Draw the Crosshair
 658         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 659
 660         // Draw the Engine Status Bar (the default Quake HUD)
 661         setproperty(VF_DRAWENGINESBAR, 0);
 662
 663         // Update the mouse position
 664         /*
 665            mousepos_x = vid_conwidth;
 666            mousepos_y = vid_conheight;
 667            mousepos = mousepos*0.5 + getmousepos();
 668          */
 669
 670         e = self;
 671         for(self = world; (self = nextent(self)); )
 672                 if(self.draw)
 673                         self.draw();
 674         self = e;
 675
 676         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 677         renderscene();
 678
 679         // now switch to 2D drawing mode by calling a 2D drawing function
 680         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 681         // next R_RenderScene call
 682         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 683
 684         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 685         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 686         {
 687                 // apply night vision effect
 688                 vector tc_00, tc_01, tc_10, tc_11;
 689                 vector rgb;
 690                 rgb_x = 0; // fteqcc sucks
 691                 rgb_y = 0; // fteqcc sucks
 692                 rgb_z = 0; // fteqcc sucks
 693
 694                 if(!nightvision_noise)
 695                 {
 696                         nightvision_noise = spawn();
 697                         nightvision_noise.classname = "nightvision_noise";
 698                 }
 699                 if(!nightvision_noise2)
 700                 {
 701                         nightvision_noise2 = spawn();
 702                         nightvision_noise2.classname = "nightvision_noise2";
 703                 }
 704
 705                 // color tint in yellow
 706                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 707
 708                 // draw BG
 709                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 710                 rgb = '1 1 1';
 711                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 712                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 713                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 714                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 715                 tc_11 = tc_01 + tc_10 - tc_00;
 716                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 717                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 718                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 719                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 720                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 721                 R_EndPolygon();
 722
 723                 // draw FG
 724                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 725                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 726                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 727                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 728                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 729                 tc_11 = tc_01 + tc_10 - tc_00;
 730                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 731                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 732                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 733                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 734                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 735                 R_EndPolygon();
 736         }
 737
 738         // Draw the aiming reticle for weapons that use it
 739         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 740         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 741         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 742         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 743                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 744         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 745                 reticle_type = 2; // nex zoom
 746         else if(button_zoom || zoomscript_caught)
 747                 reticle_type = 1; // normal zoom
 748         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 749                 reticle_type = 2; // nex zoom
 750
 751         if(reticle_type && autocvar_cl_reticle)
 752         {
 753                 if(autocvar_cl_reticle_stretch)
 754                 {
 755                         reticle_size_x = vid_conwidth;
 756                         reticle_size_y = vid_conheight;
 757                         reticle_pos_x = 0;
 758                         reticle_pos_y = 0;
 759                 }
 760                 else
 761                 {
 762                         reticle_size_x = max(vid_conwidth, vid_conheight);
 763                         reticle_size_y = max(vid_conwidth, vid_conheight);
 764                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 765                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 766                 }
 767
 768                 f = current_zoomfraction;
 769                 if(zoomscript_caught)
 770                         f = 1;
 771                 if(autocvar_cl_reticle_item_normal)
 772                 {
 773                         if(reticle_type == 1 && f)
 774                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 775                 }
 776                 if(autocvar_cl_reticle_item_nex)
 777                 {
 778                         if(reticle_type == 2 && f)
 779                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 780                 }
 781         }
 782
 783
 784         // improved polyblend
 785         if(autocvar_hud_contents)
 786         {
 787                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 788                 vector liquidcolor;
 789
 790                 switch(pointcontents(view_origin))
 791                 {
 792                         case CONTENT_WATER:
 793                                 liquidalpha = autocvar_hud_contents_water_alpha;
 794                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 795                                 incontent = 1;
 796                                 break;
 797
 798                         case CONTENT_LAVA:
 799                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 800                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 801                                 incontent = 1;
 802                                 break;
 803
 804                         case CONTENT_SLIME:
 805                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 806                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 807                                 incontent = 1;
 808                                 break;
 809
 810                         default:
 811                                 liquidalpha = 0;
 812                                 liquidcolor = '0 0 0';
 813                                 incontent = 0;
 814                                 break;
 815                 }
 816
 817                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 818                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 819                         contentfadetime = autocvar_hud_contents_fadeintime;
 820                         liquidalpha_prev = liquidalpha;
 821                         liquidcolor_prev = liquidcolor;
 822                 }
 823                 else
 824                         contentfadetime = autocvar_hud_contents_fadeouttime;
 825
 826                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 827                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 828
 829                 if(contentavgalpha)
 830                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 831
 832                 if(autocvar_hud_postprocessing)
 833                 {
 834                         if(autocvar_hud_contents_blur && contentavgalpha)
 835                         {
 836                                 content_blurpostprocess_x = 1;
 837                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 838                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 839                         }
 840                         else
 841                         {
 842                                 content_blurpostprocess_x = 0;
 843                                 content_blurpostprocess_y = 0;
 844                                 content_blurpostprocess_z = 0;
 845                         }
 846                 }
 847         }
 848
 849         if(autocvar_hud_damage)
 850         {
 851                 splash_size_x = max(vid_conwidth, vid_conheight);
 852                 splash_size_y = max(vid_conwidth, vid_conheight);
 853                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 854                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 855
 856                 float myhealth_flash_temp;
 857                 myhealth = getstati(STAT_HEALTH);
 858
 859                 // fade out
 860                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 861                 // add new damage
 862                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 863
 864                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 865                 pain_threshold = autocvar_hud_damage_pain_threshold;
 866                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 867                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 868
 869                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 870                 {
 871                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 872                 }
 873
 874                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 875
 876                 if(myhealth_prev < 1)
 877                 {
 878                         if(myhealth >= 1)
 879                         {
 880                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 881                                 myhealth_flash_temp = 0;
 882                         }
 883                         else
 884                         {
 885                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 886                         }
 887                 }
 888
 889                 if(spectatee_status == -1 || intermission)
 890                 {
 891                         myhealth_flash = 0; // observing, or match ended
 892                         myhealth_flash_temp = 0;
 893                 }
 894
 895                 myhealth_prev = myhealth;
 896
 897                 // IDEA: change damage color/picture based on player model for robot/alien species?
 898                 // pro: matches model better
 899                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 900                 // maybe different reddish pics?
 901                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 902                 {
 903                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 904                         {
 905                                 if(autocvar_cl_gentle_damage == 2)
 906                                 {
 907                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 908                                         {
 909                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 910                                         }
 911                                 }
 912                                 else
 913                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 914
 915                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 916                         }
 917                         else
 918                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 919                 }
 920
 921                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 922                 {
 923                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 924                         {
 925                                 damage_blurpostprocess_x = 1;
 926                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 927                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 928                         }
 929                         else
 930                         {
 931                                 damage_blurpostprocess_x = 0;
 932                                 damage_blurpostprocess_y = 0;
 933                                 damage_blurpostprocess_z = 0;
 934                         }
 935                 }
 936         }
 937
 938         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 939         float e2 = (autocvar_hud_powerup != 0);
 940         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 941         {
 942                 // enable or disable rendering types if they are used or not
 943                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 944                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 945
 946                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 947                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 948                 {
 949                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 950                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 951                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 952                         {
 953                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 954                                 old_blurradius = blurradius;
 955                                 old_bluralpha = bluralpha;
 956                         }
 957                 }
 958                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 959                 {
 960                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 961                         old_blurradius = 0;
 962                         old_bluralpha = 0;
 963                 }
 964
 965                 // edge detection postprocess handling done second (used by hud_powerup)
 966                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 967                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 968                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 969
 970                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 971
 972                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 973                 {
 974                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 975                         {
 976                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 977                                 old_sharpen_intensity = sharpen_intensity;
 978                         }
 979                 }
 980                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 981                 {
 982                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 983                         old_sharpen_intensity = 0;
 984                 }
 985
 986                 if(cvar("r_glsl_postprocess") == 0)
 987                         cvar_set("r_glsl_postprocess", "2");
 988         }
 989         else if(cvar("r_glsl_postprocess") == 2)
 990                 cvar_set("r_glsl_postprocess", "0");
 991
 992         if(menu_visible)
 993                 menu_show();
 994
 995         /*if(gametype == MAPINFO_TYPE_CTF)
 996           {
 997           ctf_view();
 998           } else */
 999
1000         // draw 2D entities
1001         e = self;
1002         for(self = world; (self = nextent(self)); )
1003                 if(self.draw2d)
1004                         self.draw2d();
1005         self = e;
1006         Draw_ShowNames_All();
1007
1008         scoreboard_active = HUD_WouldDrawScoreboard();
1009
1010         hit_time = getstatf(STAT_HIT_TIME);
1011         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1012         {
1013                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1014                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1015
1016                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1017         }
1018         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1019         if(typehit_time > nextsound_typehit_time)
1020         {
1021                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1022                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1023
1024                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1025         }
1026
1027         //else
1028         {
1029                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1030                 {
1031                         if(getstati(STAT_FROZEN))
1032                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1033                         if(getstatf(STAT_REVIVE_PROGRESS))
1034                         {
1035                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1036                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1037                         }
1038                 }
1039
1040                 if(autocvar_r_letterbox == 0)
1041                         if(autocvar_viewsize < 120)
1042                                 CSQC_common_hud();
1043
1044                 // crosshair goes VERY LAST
1045                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1046                 {
1047                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1048                                 return;
1049
1050                         string wcross_style;
1051                         float wcross_alpha, wcross_resolution;
1052                         wcross_style = autocvar_crosshair;
1053                         if (wcross_style == "0")
1054                                 return;
1055                         wcross_resolution = autocvar_crosshair_size;
1056                         if (wcross_resolution == 0)
1057                                 return;
1058                         wcross_alpha = autocvar_crosshair_alpha;
1059                         if (wcross_alpha == 0)
1060                                 return;
1061
1062                         // TrueAim check
1063                         float shottype;
1064
1065                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1066                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1067                         wcross_origin_z = 0;
1068                         if(autocvar_crosshair_hittest)
1069                         {
1070                                 vector wcross_oldorigin;
1071                                 wcross_oldorigin = wcross_origin;
1072                                 shottype = TrueAimCheck();
1073                                 if(shottype == SHOTTYPE_HITWORLD)
1074                                 {
1075                                         v = wcross_origin - wcross_oldorigin;
1076                                         v_x /= vid_conwidth;
1077                                         v_y /= vid_conheight;
1078                                         if(vlen(v) > 0.01)
1079                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1080                                 }
1081                                 if(!autocvar_crosshair_hittest_showimpact)
1082                                         wcross_origin = wcross_oldorigin;
1083                         }
1084                         else
1085                                 shottype = SHOTTYPE_HITWORLD;
1086
1087                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1088                         string wcross_wep = "", wcross_name;
1089                         float wcross_scale, wcross_blur;
1090
1091                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1092                                 e = get_weaponinfo(switchingweapon);
1093                                 if (e && e.netname != "")
1094                                 {
1095                                         wcross_wep = e.netname;
1096                                         if(autocvar_crosshair_per_weapon)
1097                                         {
1098                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1099                                                 if (wcross_resolution == 0)
1100                                                         return;
1101                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1102                                                 if (wcross_alpha == 0)
1103                                                         return;
1104
1105                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1106                                                 if(wcross_style == "" || wcross_style == "0")
1107                                                         wcross_style = wcross_wep;
1108                                         }
1109                                 }
1110                         }
1111                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1112                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1113                         else if(autocvar_crosshair_color_by_health)
1114                         {
1115                                 float x = getstati(STAT_HEALTH);
1116
1117                                 //x = red
1118                                 //y = green
1119                                 //z = blue
1120
1121                                 wcross_color_z = 0;
1122
1123                                 if(x > 200)
1124                                 {
1125                                         wcross_color_x = 0;
1126                                         wcross_color_y = 1;
1127                                 }
1128                                 else if(x > 150)
1129                                 {
1130                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1131                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1132                                 }
1133                                 else if(x > 100)
1134                                 {
1135                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1136                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1137                                         wcross_color_z = 1 - (x-100)*0.02;
1138                                 }
1139                                 else if(x > 50)
1140                                 {
1141                                         wcross_color_x = 1;
1142                                         wcross_color_y = 1;
1143                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1144                                 }
1145                                 else if(x > 20)
1146                                 {
1147                                         wcross_color_x = 1;
1148                                         wcross_color_y = (x-20)*90/27/100;
1149                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1150                                 }
1151                                 else
1152                                 {
1153                                         wcross_color_x = 1;
1154                                         wcross_color_y = 0;
1155                                 }
1156                         }
1157                         else
1158                                 wcross_color = stov(autocvar_crosshair_color);
1159
1160                         wcross_name = strcat("gfx/crosshair", wcross_style);
1161
1162                         if(autocvar_crosshair_effect_scalefade)
1163                         {
1164                                 wcross_scale = wcross_resolution;
1165                                 wcross_resolution = 1;
1166                         }
1167                         else
1168                         {
1169                                 wcross_scale = 1;
1170                         }
1171
1172                         if(autocvar_crosshair_pickup)
1173                         {
1174                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1175
1176                                 if(pickup_crosshair_time < stat_pickup_time)
1177                                 {
1178                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1179                                                 pickup_crosshair_size = 1;
1180
1181                                         pickup_crosshair_time = stat_pickup_time;
1182                                 }
1183
1184                                 if(pickup_crosshair_size > 0)
1185                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1186                                 else
1187                                         pickup_crosshair_size = 0;
1188
1189                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1190                         }
1191
1192                         if(autocvar_crosshair_hitindication)
1193                         {
1194                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1195
1196                                 if(hitindication_crosshair_time < hit_time)
1197                                 {
1198                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1199                                                 hitindication_crosshair_size = 1;
1200
1201                                         hitindication_crosshair_time = hit_time;
1202                                 }
1203
1204                                 if(hitindication_crosshair_size > 0)
1205                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1206                                 else
1207                                         hitindication_crosshair_size = 0;
1208
1209                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1210                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1211                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1212                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1213                         }
1214
1215                         if(shottype == SHOTTYPE_HITENEMY)
1216                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1217                         if(shottype == SHOTTYPE_HITTEAM)
1218                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1219
1220                         f = autocvar_crosshair_effect_speed;
1221                         if(f < 0)
1222                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1223                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1224                         {
1225                                 wcross_changedonetime = time + f;
1226                         }
1227                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1228                         {
1229                                 wcross_name_changestarttime = time;
1230                                 wcross_name_changedonetime = time + f;
1231                                 if(wcross_name_goal_prev_prev)
1232                                         strunzone(wcross_name_goal_prev_prev);
1233                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1234                                 wcross_name_goal_prev = strzone(wcross_name);
1235                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1236                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1237                                 wcross_resolution_goal_prev = wcross_resolution;
1238                         }
1239
1240                         wcross_scale_goal_prev = wcross_scale;
1241                         wcross_alpha_goal_prev = wcross_alpha;
1242                         wcross_color_goal_prev = wcross_color;
1243
1244                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1245                         {
1246                                 wcross_blur = 1;
1247                                 wcross_alpha *= 0.75;
1248                         }
1249                         else
1250                                 wcross_blur = 0;
1251                         // *_prev is at time-frametime
1252                         // * is at wcross_changedonetime+f
1253                         // what do we have at time?
1254                         if(time < wcross_changedonetime)
1255                         {
1256                                 f = frametime / (wcross_changedonetime - time + frametime);
1257                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1258                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1259                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1260                         }
1261
1262                         wcross_scale_prev = wcross_scale;
1263                         wcross_alpha_prev = wcross_alpha;
1264                         wcross_color_prev = wcross_color;
1265
1266                         wcross_scale *= 1 - autocvar__menu_alpha;
1267                         wcross_alpha *= 1 - autocvar__menu_alpha;
1268                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1269
1270                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1271                         {
1272                                 // crosshair rings for weapon stats
1273                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1274                                 {
1275                                         // declarations and stats
1276                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1277                                         string ring_image = string_null, ring_inner_image = string_null;
1278                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1279
1280                                         ring_scale = autocvar_crosshair_ring_size;
1281
1282                                         float weapon_clipload, weapon_clipsize;
1283                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1284                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1285
1286                                         float nex_charge, nex_chargepool;
1287                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1288                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1289
1290                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1291                                                 nex_charge_movingavg = nex_charge;
1292
1293
1294                                         // handle the values
1295                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1296                                         {
1297                                                 if (nex_chargepool || use_nex_chargepool) {
1298                                                         use_nex_chargepool = 1;
1299                                                         ring_inner_value = nex_chargepool;
1300                                                 } else {
1301                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1302                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1303                                                 }
1304
1305                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1306                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1307                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1308
1309                                                 // draw the outer ring to show the current charge of the weapon
1310                                                 ring_value = nex_charge;
1311                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1312                                                 ring_rgb = wcross_color;
1313                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1314                                         }
1315                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1316                                         {
1317                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1318                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1319                                                 ring_rgb = wcross_color;
1320                                                 ring_image = "gfx/crosshair_ring.tga";
1321                                         }
1322                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1323                                         {
1324                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1325                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1326                                                 ring_rgb = wcross_color;
1327                                                 ring_image = "gfx/crosshair_ring.tga";
1328                                         }
1329
1330                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1331                                         {
1332                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1333                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1334                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1335                                                 ring_rgb = wcross_color;
1336
1337                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1338                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1339                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1340                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1341                                                 else
1342                                                         ring_image = "gfx/crosshair_ring.tga";
1343                                         }
1344
1345                                         // if in weapon switch animation, fade ring out/in
1346                                         if(g_weaponswitchdelay > 0)
1347                                         {
1348                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1349                                                 if(f > 0 && f < 2)
1350                                                         ring_alpha *= fabs(1 - f);
1351                                         }
1352
1353                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1354                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1355
1356                                         if (ring_value)
1357                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1358                                 }
1359
1360 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1361                                 do \
1362                                 { \
1363                                         if(wcross_blur > 0) \
1364                                         { \
1365                                                 for(i = -2; i <= 2; ++i) \
1366                                                 for(j = -2; j <= 2; ++j) \
1367                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1368                                         } \
1369                                         else \
1370                                         { \
1371                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1372                                         } \
1373                                 } \
1374                                 while(0)
1375
1376 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1377                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1378
1379 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1380                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1381
1382                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1383                                 {
1384                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1385                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1386                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1387                                         f = 1 - f;
1388                                 }
1389                                 else
1390                                 {
1391                                         f = 1;
1392                                 }
1393                                 wcross_name_alpha_goal_prev = f;
1394
1395                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1396                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1397
1398                                 if(autocvar_crosshair_dot)
1399                                 {
1400                                         vector wcross_color_old;
1401                                         wcross_color_old = wcross_color;
1402
1403                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1404                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1405
1406                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1407                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1408                                         wcross_color = wcross_color_old;
1409                                 }
1410                         }
1411                 }
1412                 else
1413                 {
1414                         wcross_scale_prev = 0;
1415                         wcross_alpha_prev = 0;
1416                         wcross_scale_goal_prev = 0;
1417                         wcross_alpha_goal_prev = 0;
1418                         wcross_changedonetime = 0;
1419                         if(wcross_name_goal_prev)
1420                                 strunzone(wcross_name_goal_prev);
1421                         wcross_name_goal_prev = string_null;
1422                         if(wcross_name_goal_prev_prev)
1423                                 strunzone(wcross_name_goal_prev_prev);
1424                         wcross_name_goal_prev_prev = string_null;
1425                         wcross_name_changestarttime = 0;
1426                         wcross_name_changedonetime = 0;
1427                         wcross_name_alpha_goal_prev = 0;
1428                         wcross_name_alpha_goal_prev_prev = 0;
1429                         wcross_resolution_goal_prev = 0;
1430                         wcross_resolution_goal_prev_prev = 0;
1431                 }
1432         }
1433
1434         if(NextFrameCommand)
1435         {
1436                 localcmd("\n", NextFrameCommand, "\n");
1437                 NextFrameCommand = string_null;
1438         }
1439
1440         // we must do this check AFTER a frame was rendered, or it won't work
1441         if(cs_project_is_b0rked == 0)
1442         {
1443                 string w0, h0;
1444                 w0 = ftos(autocvar_vid_conwidth);
1445                 h0 = ftos(autocvar_vid_conheight);
1446                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1447                 //setproperty(VF_FOV, '90 90 0');
1448                 setproperty(VF_ORIGIN, '0 0 0');
1449                 setproperty(VF_ANGLES, '0 0 0');
1450                 setproperty(VF_PERSPECTIVE, 1);
1451                 makevectors('0 0 0');
1452                 vector v1, v2;
1453                 cvar_set("vid_conwidth", "800");
1454                 cvar_set("vid_conheight", "600");
1455                 v1 = cs_project(v_forward);
1456                 cvar_set("vid_conwidth", "640");
1457                 cvar_set("vid_conheight", "480");
1458                 v2 = cs_project(v_forward);
1459                 if(v1 == v2)
1460                         cs_project_is_b0rked = 1;
1461                 else
1462                         cs_project_is_b0rked = -1;
1463                 cvar_set("vid_conwidth", w0);
1464                 cvar_set("vid_conheight", h0);
1465         }
1466
1467         if(autocvar__hud_configure)
1468                 HUD_Panel_Mouse();
1469
1470     if(hud && !intermission)
1471     {
1472         if(hud == HUD_SPIDERBOT)
1473             CSQC_SPIDER_HUD();
1474         else if(hud == HUD_WAKIZASHI)
1475             CSQC_WAKIZASHI_HUD();
1476         else if(hud == HUD_RAPTOR)
1477             CSQC_RAPTOR_HUD();
1478         else if(hud == HUD_BUMBLEBEE)
1479             CSQC_BUMBLE_HUD();
1480         else if(hud == HUD_BUMBLEBEE_GUN)
1481             CSQC_BUMBLE_GUN_HUD();
1482     }
1483
1484         cl_notice_run();
1485
1486         // let's reset the view back to normal for the end
1487         setproperty(VF_MIN, '0 0 0');
1488         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1489 }
1490
1491
1492 void CSQC_common_hud(void)
1493 {
1494     // do some accuracy var caching
1495     float i;
1496     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1497     {
1498         if(autocvar_accuracy_color_levels != acc_color_levels)
1499         {
1500             if(acc_color_levels)
1501                 strunzone(acc_color_levels);
1502             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1503             acc_levels = tokenize_console(acc_color_levels);
1504             if (acc_levels > MAX_ACCURACY_LEVELS)
1505                 acc_levels = MAX_ACCURACY_LEVELS;
1506
1507             for (i = 0; i < acc_levels; ++i)
1508                 acc_lev[i] = stof(argv(i)) / 100.0;
1509         }
1510         // let know that acc_col[] needs to be loaded
1511         acc_col[0] = '-1 0 0';
1512     }
1513
1514     HUD_Main(); // always run these functions for alpha checks
1515     HUD_DrawScoreboard();
1516
1517     if (scoreboard_active) // scoreboard/accuracy
1518         HUD_Reset();
1519     else if (intermission == 2) // map voting screen
1520     {
1521         HUD_FinaleOverlay();
1522         HUD_Reset();
1523     }
1524         /*
1525         switch(hud)
1526         {
1527                 case HUD_SPIDERBOT:
1528                         CSQC_SPIDER_HUD();
1529                         break;
1530
1531                 case HUD_WAKIZASHI:
1532                         CSQC_WAKIZASHI_HUD();
1533                         break;
1534
1535         case HUD_BUMBLEBEE:
1536             CSQC_BUMBLE_HUD();
1537             break;
1538         }
1539         */
1540 }
1541
1542
1543 // following vectors must be global to allow seamless switching between camera modes
1544 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1545 void CSQC_Demo_Camera()
1546 {
1547         float speed, attenuation, dimensions;
1548         vector tmp, delta;
1549
1550         if( autocvar_camera_reset || !camera_mode )
1551         {
1552                 camera_offset = '0 0 0';
1553                 current_angles = '0 0 0';
1554                 camera_direction = '0 0 0';
1555                 camera_offset_z += 30;
1556                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1557                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1558                 current_origin = view_origin;
1559                 current_camera_offset  = camera_offset;
1560                 cvar_set("camera_reset", "0");
1561                 camera_mode = CAMERA_CHASE;
1562         }
1563
1564         // Camera angles
1565         if( camera_roll )
1566                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1567
1568         if(autocvar_camera_look_player)
1569         {
1570                 vector dir;
1571                 float n;
1572
1573                 dir = normalize(view_origin - current_position);
1574                 n = mouse_angles_z;
1575                 mouse_angles = vectoangles(dir);
1576                 mouse_angles_x = mouse_angles_x * -1;
1577                 mouse_angles_z = n;
1578         }
1579         else
1580         {
1581                 tmp = getmousepos() * 0.1;
1582                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1583                 {
1584                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1585                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1586                 }
1587         }
1588
1589         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1590         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1591         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1592         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1593
1594         // Fix difference when angles don't have the same sign
1595         delta = '0 0 0';
1596         if(mouse_angles_y < -60 && current_angles_y > 60)
1597                 delta = '0 360 0';
1598         if(mouse_angles_y > 60 && current_angles_y < -60)
1599                 delta = '0 -360 0';
1600
1601         if(autocvar_camera_look_player)
1602                 attenuation = autocvar_camera_look_attenuation;
1603         else
1604                 attenuation = autocvar_camera_speed_attenuation;
1605
1606         attenuation = 1 / max(1, attenuation);
1607         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1608
1609         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1610         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1611         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1612         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1613
1614         // Camera position
1615         tmp = '0 0 0';
1616         dimensions = 0;
1617
1618         if( camera_direction_x )
1619         {
1620                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1621                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1622                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1623                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1624                 ++dimensions;
1625         }
1626
1627         if( camera_direction_y )
1628         {
1629                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1630                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1631                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1632                 ++dimensions;
1633         }
1634
1635         if( camera_direction_z )
1636         {
1637                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1638                 ++dimensions;
1639         }
1640
1641         if(autocvar_camera_free)
1642                 speed = autocvar_camera_speed_free;
1643         else
1644                 speed = autocvar_camera_speed_chase;
1645
1646         if(dimensions)
1647         {
1648                 speed = speed * sqrt(1 / dimensions);
1649                 camera_offset += tmp * speed;
1650         }
1651
1652         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1653
1654         // Camera modes
1655         if( autocvar_camera_free )
1656         {
1657                 if ( camera_mode == CAMERA_CHASE )
1658                 {
1659                         current_camera_offset = current_origin + current_camera_offset;
1660                         camera_offset = current_origin + camera_offset;
1661                 }
1662
1663                 camera_mode = CAMERA_FREE;
1664                 current_position = current_camera_offset;
1665         }
1666         else
1667         {
1668                 if ( camera_mode == CAMERA_FREE )
1669                 {
1670                         current_origin = view_origin;
1671                         camera_offset = camera_offset - current_origin;
1672                         current_camera_offset = current_camera_offset - current_origin;
1673                 }
1674
1675                 camera_mode = CAMERA_CHASE;
1676
1677                 if(autocvar_camera_chase_smoothly)
1678                         current_origin += (view_origin - current_origin) * attenuation;
1679                 else
1680                         current_origin = view_origin;
1681
1682                 current_position = current_origin + current_camera_offset;
1683         }
1684
1685         setproperty(VF_ANGLES, current_angles);
1686         setproperty(VF_ORIGIN, current_position);
1687 }