Merge branch 'terencehill/cl_forceplayercolors_3' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / announcer.qc
1 #include "announcer.qh"
2
3 #include <client/mutators/_mod.qh>
4
5 #include <common/notifications/all.qh>
6 #include <common/stats.qh>
7 #include "hud/panel/centerprint.qh"
8
9 bool announcer_1min;
10 bool announcer_5min;
11 string AnnouncerOption()
12 {
13         string ret = autocvar_cl_announcer;
14         MUTATOR_CALLHOOK(AnnouncerOption, ret);
15         ret = M_ARGV(0, string);
16         return ret;
17 }
18
19 entity announcer_countdown;
20
21 void Announcer_Countdown(entity this)
22 {
23         float starttime = STAT(GAMESTARTTIME);
24         float roundstarttime = STAT(ROUNDSTARTTIME);
25         if(roundstarttime == -1)
26         {
27                 Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_ROUNDSTOP);
28                 delete(this);
29                 announcer_countdown = NULL;
30                 return;
31         }
32         if(roundstarttime >= starttime)
33                 starttime = roundstarttime;
34         if(starttime <= time && roundstarttime != starttime) // game start time has passed
35                 announcer_5min = announcer_1min = false; // reset maptime announcers now as well
36
37         float countdown = (starttime - time);
38         float countdown_rounded = floor(0.5 + countdown);
39
40         if(countdown <= 0) // countdown has finished, starttime is now
41         {
42                 Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_BEGIN);
43                 Local_Notification(MSG_MULTI, MULTI_COUNTDOWN_BEGIN);
44                 delete(this);
45                 announcer_countdown = NULL;
46                 return;
47         }
48         else // countdown is still going
49         {
50                 // if concomitant countdown to round start overrides countdown to game start
51                 if(roundstarttime == starttime)
52                 {
53                         Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_ROUNDSTART, countdown_rounded);
54                         Notification annce_num = Announcer_PickNumber(CNT_ROUNDSTART, countdown_rounded);
55                         if(annce_num != NULL)
56                                 Local_Notification(MSG_ANNCE, annce_num);
57                 }
58                 else
59                 {
60                         Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_GAMESTART, countdown_rounded);
61                         Notification annce_num = Announcer_PickNumber(CNT_GAMESTART, countdown_rounded);
62                         if(annce_num != NULL)
63                                 Local_Notification(MSG_ANNCE, annce_num);
64                 }
65
66                 this.nextthink = (starttime - (countdown - 1));
67         }
68 }
69
70 /**
71  * Checks whether the server initiated a map restart (stat_game_starttime changed)
72  *
73  * TODO: Use a better solution where a common shared entitiy is used that contains
74  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
75  * and STAT_FRAGLIMIT to be auto-sent)
76  */
77  float previous_game_starttime;
78 void Announcer_Gamestart()
79 {
80         float startTime = STAT(GAMESTARTTIME);
81         float roundstarttime = STAT(ROUNDSTARTTIME);
82         if(roundstarttime > startTime)
83                 startTime = roundstarttime;
84         if(intermission)
85         {
86                 if(announcer_countdown)
87                 {
88                         centerprint_Kill(ORDINAL(CPID_ROUND));
89                         if(announcer_countdown)
90                         {
91                                 delete(announcer_countdown);
92                                 announcer_countdown = NULL;
93                         }
94                 }
95                 return;
96         }
97
98         if(previous_game_starttime != startTime)
99         {
100                 if(time < startTime)
101                 {
102                         if (!announcer_countdown)
103                         {
104                                 announcer_countdown = new(announcer_countdown);
105                                 setthink(announcer_countdown, Announcer_Countdown);
106                         }
107
108                         if(time + 5.0 < startTime) // if connecting to server while restart was active don't always play prepareforbattle
109                         if(time > announcer_countdown.nextthink) // don't play it again if countdown was already going
110                                 Local_Notification(MSG_ANNCE, ANNCE_PREPARE);
111
112                         announcer_countdown.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
113                 }
114         }
115
116         previous_game_starttime = startTime;
117 }
118
119 #define ANNOUNCER_CHECKMINUTE(minute) MACRO_BEGIN \
120         if(announcer_##minute##min) { \
121                 if(timeleft > minute * 60) \
122                         announcer_##minute##min = false; \
123         } else { \
124                 if(timeleft < minute * 60 && timeleft > minute * 60 - 1) { \
125                         announcer_##minute##min = true; \
126                         Local_Notification(MSG_ANNCE, ANNCE_REMAINING_MIN_##minute); \
127                 } \
128         } \
129 MACRO_END
130
131 void Announcer_Time()
132 {
133         if(intermission)
134                 return;
135
136         float timeleft;
137         if(warmup_stage)
138         {
139                 float warmup_timelimit = STAT(WARMUP_TIMELIMIT);
140                 if(warmup_timelimit > 0)
141                         timeleft = max(0, warmup_timelimit - time);
142                 else
143                         timeleft = 0;
144         }
145         else
146                 timeleft = max(0, STAT(TIMELIMIT) * 60 + STAT(GAMESTARTTIME) - time);
147
148         if(autocvar_cl_announcer_maptime >= 2)
149                 ANNOUNCER_CHECKMINUTE(5);
150
151         if((autocvar_cl_announcer_maptime == 1) || (autocvar_cl_announcer_maptime == 3))
152                 ANNOUNCER_CHECKMINUTE(1);
153 }
154
155 void Announcer()
156 {
157         Announcer_Gamestart();
158         Announcer_Time();
159 }