qcsrc/client/announcer.qc

   1 float previous_announcement_time;
   2 float previous_game_starttime;
   3 string previous_announcement;
   4
   5 // remaining maptime announcer sounds, true when sound was already played
   6 float announcer_1min;
   7 float announcer_5min;
   8
   9 void Announcer_Play(string announcement)
  10 {
  11         if((announcement != previous_announcement) || (time >= (previous_announcement_time + autocvar_cl_announcer_antispam)))
  12         {
  13                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", announcement, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  14
  15                 if(previous_announcement) { strunzone(previous_announcement); }
  16
  17                 previous_announcement = strzone(announcement);
  18                 previous_announcement_time = time;
  19         }
  20 }
  21
  22 void Announcer_Countdown()
  23 {
  24         float starttime = getstatf(STAT_GAMESTARTTIME);
  25         float roundstarttime = getstatf(STAT_ROUNDSTARTTIME);
  26         if(starttime <= time) // game start time has passed
  27                 announcer_5min = announcer_1min = FALSE; // reset maptime announcers now as well
  28         if(roundstarttime == -1)
  29         {
  30                 // stop countdown immediately
  31                 centerprint_generic(CPID_GAME_STARTING, "", 1, 0);
  32                 remove(self);
  33                 return;
  34         }
  35         if(roundstarttime >= starttime)
  36                 starttime = roundstarttime;
  37
  38         float countdown = (starttime - time);
  39         float countdown_rounded = floor(0.5 + countdown);
  40
  41         if(countdown <= 0) // countdown has finished, starttime is now
  42         {
  43                 if (!spectatee_status)
  44                         centerprint_generic(CPID_GAME_STARTING, _("^1Begin!"), 1, 0);
  45
  46                 Announcer_Play("begin");
  47                 remove(self);
  48                 return;
  49         }
  50         else // countdown is still going
  51         {
  52                 if (!spectatee_status)
  53                 {
  54                         if(roundstarttime == starttime)
  55                                 centerprint_generic(CPID_GAME_STARTING, _("^1Round starts in %d seconds"), 1, countdown_rounded);
  56                         else
  57                                 centerprint_generic(CPID_GAME_STARTING, _("^1Game starts in %d seconds"), 1, countdown_rounded);
  58                 }
  59
  60                 if(countdown_rounded <= 3 && countdown_rounded >= 1)
  61                         Announcer_Play(ftos(countdown_rounded));
  62
  63                 self.nextthink = (starttime - (countdown - 1));
  64         }
  65 }
  66
  67 /**
  68  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  69  *
  70  * TODO: Use a better solution where a common shared entitiy is used that contains
  71  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  72  * and STAT_FRAGLIMIT to be auto-sent)
  73  */
  74 void Announcer_Gamestart()
  75 {
  76         float startTime = getstatf(STAT_GAMESTARTTIME);
  77         float roundstarttime = getstatf(STAT_ROUNDSTARTTIME);
  78         if(roundstarttime > startTime)
  79                 startTime = roundstarttime;
  80
  81         if(previous_game_starttime != startTime)
  82         {
  83                 if((time + 5.0) < startTime) // if connecting to server while restart was active don't always play prepareforbattle
  84                         Announcer_Play("prepareforbattle");
  85
  86                 if(time < startTime)
  87                 {
  88                         entity e;
  89                         e = spawn();
  90                         e.think = Announcer_Countdown;
  91                         e.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
  92                 }
  93         }
  94
  95         previous_game_starttime = startTime;
  96 }
  97
  98
  99 // Plays the 1 minute or 5 minutes (of maptime) remaining sound, if client wants it
 100 void Announcer_Time()
 101 {
 102         float timelimit = getstatf(STAT_TIMELIMIT);
 103         float timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
 104         float warmup_timeleft = 0;
 105
 106         if(warmup_stage)
 107                 if(autocvar_g_warmup_limit > 0)
 108                         warmup_timeleft = max(0, autocvar_g_warmup_limit + getstatf(STAT_GAMESTARTTIME) - time);
 109
 110         // 5 minute check
 111         if(autocvar_cl_announcer_maptime >= 2)
 112         {
 113                 // make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
 114                 if(announcer_5min)
 115                 {
 116                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 300)
 117                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 300))
 118                                         announcer_5min = FALSE;
 119                 }
 120                 else
 121                 {
 122                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299)
 123                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 300 && warmup_timeleft > 299))
 124                         {
 125                                 //if we're in warmup mode, check whether there's a warmup timelimit
 126                                 if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 127                                 {
 128                                         announcer_5min = TRUE;
 129                                         Announcer_Play("5minutesremain");
 130                                 }
 131                         }
 132                 }
 133         }
 134
 135         // 1 minute check
 136         if((autocvar_cl_announcer_maptime == 1) || (autocvar_cl_announcer_maptime == 3))
 137         {
 138                 if (announcer_1min)
 139                 {
 140                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 60)
 141                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 60))
 142                                         announcer_1min = FALSE;
 143                 }
 144                 else if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 60)
 145                         || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 60))
 146                 {
 147                         // if we're in warmup mode, check whether there's a warmup timelimit
 148                         if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 149                         {
 150                                 announcer_1min = TRUE;
 151                                 Announcer_Play("1minuteremains");
 152                         }
 153                 }
 154         }
 155 }
 156
 157 void Announcer()
 158 {
 159         Announcer_Gamestart();
 160         Announcer_Time();
 161 }
 162
 163 void Announcer_Precache ()
 164 {
 165         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 166         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 167
 168         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 169         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 170         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 171         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 172         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 173         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 174         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 175         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 176         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 177         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 178         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 179         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 180         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 181         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
 182         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 183
 184         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 187         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 188         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 189         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 190         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 191
 192         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 193         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 194         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 195         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 196         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 197         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 198         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 199         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 200         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 201         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 202
 203         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 204         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 205
 206         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 207         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 208         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 209 }