qcsrc/client/casings.qc

   1 .float silent;
   2
   3 void Casing_Delete()
   4 {
   5     remove(self);
   6 }
   7
   8 void Casing_Draw()
   9 {
  10         if(self.move_flags & FL_ONGROUND)
  11         {
  12                 self.move_angles_x = 0;
  13                 self.move_angles_z = 0;
  14                 self.flags &~= FL_ONGROUND;
  15         }
  16
  17         Movetype_Physics_MatchTicrate(autocvar_cl_casings_ticrate, autocvar_cl_casings_sloppy);
  18         if(wasfreed(self))
  19                 return; // deleted by touch function
  20
  21         self.renderflags = 0;
  22         self.alpha = bound(0, self.cnt - time, 1);
  23
  24         if(self.alpha < ALPHA_MIN_VISIBLE)
  25         {
  26                 Casing_Delete();
  27                 self.drawmask = 0;
  28         }
  29 }
  30
  31 void Casing_Touch()
  32 {
  33         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  34         {
  35                 Casing_Delete();
  36                 return;
  37         }
  38
  39         if(!self.silent)
  40         if(!trace_ent || trace_ent.solid == SOLID_BSP)
  41         {
  42                 if(vlen(self.velocity) > 50)
  43                 {
  44                         if(time >= self.nextthink)
  45                         {
  46                                 string s;
  47                                 float f;
  48
  49                                 f = floor(prandom() * 3) + 1;
  50                                 switch(self.state)
  51                                 {
  52                                         case 1:
  53                                                 s = strcat("weapons/casings", ftos(f), ".wav");
  54                                                 break;
  55                                         default:
  56                                                 s = strcat("weapons/brass", ftos(f), ".wav");
  57                                                 break;
  58                                 }
  59
  60                                 sound (self, CH_SHOTS, s, VOL_BASE, ATTN_LARGE);
  61                         }
  62                 }
  63         }
  64
  65         self.nextthink = time + 0.2;
  66 }
  67
  68 void Casing_Damage(float thisdmg, float hittype, vector org, vector thisforce)
  69 {
  70         if(thisforce_z < 0)
  71                 thisforce_z = 0;
  72         self.move_velocity = self.move_velocity + thisforce + '0 0 100';
  73         self.move_flags &~= FL_ONGROUND;
  74 }
  75
  76 void Ent_Casing(float isNew)
  77 {
  78         entity casing;
  79
  80         casing = RubbleNew("casing");
  81         casing.state = ReadByte();
  82         casing.silent = (casing.state & 0x80);
  83         casing.state = (casing.state & 0x7F);
  84         casing.origin_x = ReadCoord();
  85         casing.origin_y = ReadCoord();
  86         casing.origin_z = ReadCoord();
  87         casing.velocity = decompressShortVector(ReadShort());
  88         casing.angles_x = ReadByte() * 360 / 256;
  89         casing.angles_y = ReadByte() * 360 / 256;
  90         casing.angles_z = ReadByte() * 360 / 256;
  91         casing.drawmask = MASK_NORMAL;
  92
  93         if(autocvar_cl_casings && isNew) {
  94                 casing.draw = Casing_Draw;
  95                 casing.move_origin = casing.origin;
  96                 casing.move_velocity = casing.velocity + 2 * prandomvec();
  97                 casing.move_angles = casing.angles;
  98                 casing.move_avelocity = '0 250 0' + 100 * prandomvec();
  99                 casing.move_movetype = MOVETYPE_BOUNCE;
 100                 casing.move_touch = Casing_Touch;
 101                 casing.move_time = time;
 102                 casing.event_damage = Casing_Damage;
 103                 casing.solid = SOLID_TRIGGER;
 104
 105                 switch(casing.state)
 106                 {
 107                         case 1:
 108                                 setmodel(casing, "models/casing_shell.mdl");
 109                                 casing.cnt = time + autocvar_cl_casings_shell_time;
 110                                 break;
 111                         default:
 112                                 setmodel(casing, "models/casing_bronze.iqm");
 113                                 casing.cnt = time + autocvar_cl_casings_bronze_time;
 114                                 break;
 115                 }
 116
 117                 setsize(casing, '0 0 -1', '0 0 -1');
 118
 119                 RubbleLimit("casing", autocvar_cl_casings_maxcount, Casing_Delete);
 120         }
 121         else
 122         {
 123                 entity oldself = self;
 124                 self = casing;
 125                 Casing_Delete(); // yes, this IS stupid, but I don't need to duplicate all the read* stuff then
 126                 self = oldself;
 127         }
 128 }
 129
 130 void Casings_Precache()
 131 {
 132         precache_model("models/casing_shell.mdl");
 133         precache_model("models/casing_bronze.iqm");
 134         precache_sound("weapons/brass1.wav");
 135         precache_sound("weapons/brass2.wav");
 136         precache_sound("weapons/brass3.wav");
 137         precache_sound("weapons/casings1.wav");
 138         precache_sound("weapons/casings2.wav");
 139         precache_sound("weapons/casings3.wav");
 140 }