qcsrc/client/casings.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qc"
   3         #include "Defs.qc"
   4         #include "../common/constants.qh"
   5         #include "../common/util.qh"
   6         #include "autocvars.qh"
   7         #include "movetypes.qh"
   8         #include "prandom.qh"
   9         #include "main.qh"
  10         #include "../csqcmodellib/cl_model.qh"
  11 #elif defined(MENUQC)
  12 #elif defined(SVQC)
  13 #endif
  14
  15
  16 .bool silent;
  17
  18 void Casing_Delete()
  19 {
  20     remove(self);
  21 }
  22
  23 void Casing_Draw()
  24 {
  25         if(self.move_flags & FL_ONGROUND)
  26         {
  27                 self.move_angles_x = 0;
  28                 self.move_angles_z = 0;
  29                 self.flags &= ~FL_ONGROUND;
  30         }
  31
  32         Movetype_Physics_MatchTicrate(autocvar_cl_casings_ticrate, autocvar_cl_casings_sloppy);
  33         if(wasfreed(self))
  34                 return; // deleted by touch function
  35
  36         self.renderflags = 0;
  37         self.alpha = bound(0, self.cnt - time, 1);
  38
  39         if(self.alpha < ALPHA_MIN_VISIBLE)
  40         {
  41                 Casing_Delete();
  42                 self.drawmask = 0;
  43         }
  44 }
  45
  46 void Casing_Touch()
  47 {
  48         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  49         {
  50                 Casing_Delete();
  51                 return;
  52         }
  53
  54         if(!self.silent)
  55         if(!trace_ent || trace_ent.solid == SOLID_BSP)
  56         {
  57                 if(vlen(self.velocity) > 50)
  58                 {
  59                         if(time >= self.nextthink)
  60                         {
  61                                 string s;
  62                                 int f = floor(prandom() * 3) + 1;
  63
  64                                 switch(self.state)
  65                                 {
  66                                         case 1:
  67                                                 s = strcat("weapons/casings", itos(f), ".wav");
  68                                                 break;
  69                                         default:
  70                                                 s = strcat("weapons/brass", itos(f), ".wav");
  71                                                 break;
  72                                 }
  73
  74                                 sound (self, CH_SHOTS, s, VOL_BASE, ATTEN_LARGE);
  75                         }
  76                 }
  77         }
  78
  79         self.nextthink = time + 0.2;
  80 }
  81
  82 void Casing_Damage(float thisdmg, int hittype, vector org, vector thisforce)
  83 {
  84         if(thisforce.z < 0)
  85                 thisforce_z = 0;
  86         self.move_velocity = self.move_velocity + thisforce + '0 0 100';
  87         self.move_flags &= ~FL_ONGROUND;
  88 }
  89
  90 void Ent_Casing(float isNew)
  91 {
  92         entity casing;
  93
  94         casing = RubbleNew("casing");
  95         casing.state = ReadByte();
  96         casing.silent = (casing.state & 0x80);
  97         casing.state = (casing.state & 0x7F);
  98         casing.origin_x = ReadCoord();
  99         casing.origin_y = ReadCoord();
 100         casing.origin_z = ReadCoord();
 101         setorigin(casing, casing.origin);
 102         casing.velocity = decompressShortVector(ReadShort());
 103         casing.angles_x = ReadByte() * 360 / 256;
 104         casing.angles_y = ReadByte() * 360 / 256;
 105         casing.angles_z = ReadByte() * 360 / 256;
 106         casing.drawmask = MASK_NORMAL;
 107
 108         if(autocvar_cl_casings && isNew) {
 109                 casing.draw = Casing_Draw;
 110                 casing.move_origin = casing.origin;
 111                 casing.move_velocity = casing.velocity + 2 * prandomvec();
 112                 casing.move_angles = casing.angles;
 113                 casing.move_avelocity = '0 250 0' + 100 * prandomvec();
 114                 casing.move_movetype = MOVETYPE_BOUNCE;
 115                 casing.move_touch = Casing_Touch;
 116                 casing.move_time = time;
 117                 casing.event_damage = Casing_Damage;
 118                 casing.solid = SOLID_TRIGGER;
 119
 120                 switch(casing.state)
 121                 {
 122                         case 1:
 123                                 setmodel(casing, "models/casing_shell.mdl");
 124                                 casing.cnt = time + autocvar_cl_casings_shell_time;
 125                                 break;
 126                         default:
 127                                 setmodel(casing, "models/casing_bronze.iqm");
 128                                 casing.cnt = time + autocvar_cl_casings_bronze_time;
 129                                 break;
 130                 }
 131
 132                 setsize(casing, '0 0 -1', '0 0 -1');
 133
 134                 RubbleLimit("casing", autocvar_cl_casings_maxcount, Casing_Delete);
 135         }
 136         else
 137         {
 138                 entity oldself = self;
 139                 self = casing;
 140                 Casing_Delete(); // yes, this IS stupid, but I don't need to duplicate all the read* stuff then
 141                 self = oldself;
 142         }
 143 }
 144
 145 void Casings_Precache()
 146 {
 147         precache_model("models/casing_shell.mdl");
 148         precache_model("models/casing_bronze.iqm");
 149         precache_sound("weapons/brass1.wav");
 150         precache_sound("weapons/brass2.wav");
 151         precache_sound("weapons/brass3.wav");
 152         precache_sound("weapons/casings1.wav");
 153         precache_sound("weapons/casings2.wav");
 154         precache_sound("weapons/casings3.wav");
 155 }