qcsrc/client/command/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/generic.qh"
   7 #include "../../common/command/shared_defs.qh"
   8
   9 void DrawDebugModel()
  10 {
  11         if(time - floor(time) > 0.5)
  12         {
  13                 PolyDrawModel(self);
  14                 self.drawmask = 0;
  15         }
  16         else
  17         {
  18                 self.renderflags = 0;
  19                 self.drawmask = MASK_NORMAL;
  20         }
  21 }
  22
  23
  24 // =======================
  25 //  Command Sub-Functions
  26 // =======================
  27
  28 void LocalCommand_blurtest(int request)
  29 {
  30         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  31         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  32
  33         #ifdef BLURTEST
  34         switch(request)
  35         {
  36                 case CMD_REQUEST_COMMAND:
  37                 {
  38                         blurtest_time0 = time;
  39                         blurtest_time1 = time + stof(argv(1));
  40                         blurtest_radius = stof(argv(2));
  41                         blurtest_power = stof(argv(3));
  42                         print("Enabled blurtest\n");
  43                         return;
  44                 }
  45
  46                 default:
  47                 case CMD_REQUEST_USAGE:
  48                 {
  49                         print("\nUsage:^3 cl_cmd blurtest\n");
  50                         print("  No arguments required.\n");
  51                         return;
  52                 }
  53         }
  54         #else
  55         if(request)
  56         {
  57                 print("Blurtest is not enabled on this client.\n");
  58                 return;
  59         }
  60         #endif
  61 }
  62
  63 void LocalCommand_boxparticles(int request, int argc)
  64 {
  65         switch(request)
  66         {
  67                 case CMD_REQUEST_COMMAND:
  68                 {
  69                         if (argc == 9)
  70                         {
  71                                 int effect = particleeffectnum(argv(1));
  72                                 if (effect >= 0)
  73                                 {
  74                                         int index = stoi(argv(2));
  75                                         entity own;
  76                                         if(index <= 0)
  77                                                 own = entitybyindex(-index);
  78                                         else
  79                                                 own = findfloat(world, entnum, index);
  80                                         vector org_from = stov(argv(3));
  81                                         vector org_to = stov(argv(4));
  82                                         vector dir_from = stov(argv(5));
  83                                         vector dir_to = stov(argv(6));
  84                                         int countmultiplier = stoi(argv(7));
  85                                         int flags = stoi(argv(8));
  86                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
  87                                         return;
  88                                 }
  89                         }
  90                 }
  91
  92                 default:
  93                         print("Incorrect parameters for ^2boxparticles^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         print("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
  97                         print("  'effectname' is the name of a particle effect in effectinfo.txt\n");
  98                         print("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
  99                         print("  'org_from' is the starting origin of the box\n");
 100                         print("  'org_to' is the ending origin of the box\n");
 101                         print("  'dir_from' is the minimum velocity\n");
 102                         print("  'dir_to' is the maximum velocity\n");
 103                         print("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 104                         print("  'flags' can contain:\n");
 105                         print("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 106                         print("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 107                         print("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 108                         print("    128 to draw a trail, not a box\n");
 109                         return;
 110                 }
 111         }
 112 }
 113
 114 void LocalCommand_create_scrshot_ent(int request)
 115 {
 116         switch(request)
 117         {
 118                 case CMD_REQUEST_COMMAND:
 119                 {
 120                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 121                         int fh = fopen(filename, FILE_WRITE);
 122
 123                         if(fh >= 0)
 124                         {
 125                                 fputs(fh, "{\n");
 126                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 127                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 128                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 129                                 fputs(fh, "}\n");
 130
 131                                 print("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 132
 133                                 fclose(fh);
 134                         }
 135                         else
 136                         {
 137                                 print("^1Error: ^7Could not dump to file!\n");
 138                         }
 139                         return;
 140                 }
 141
 142                 default:
 143                 case CMD_REQUEST_USAGE:
 144                 {
 145                         print("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 146                         print("  No arguments required.\n");
 147                         return;
 148                 }
 149         }
 150 }
 151
 152 void LocalCommand_debugmodel(int request, int argc)
 153 {
 154         switch(request)
 155         {
 156                 case CMD_REQUEST_COMMAND:
 157                 {
 158                         string modelname = argv(1);
 159                         entity debugmodel_entity;
 160
 161                         debugmodel_entity = spawn();
 162                         precache_model(modelname);
 163                         setmodel(debugmodel_entity, modelname);
 164                         setorigin(debugmodel_entity, view_origin);
 165                         debugmodel_entity.angles = view_angles;
 166                         debugmodel_entity.draw = DrawDebugModel;
 167                         debugmodel_entity.classname = "debugmodel";
 168
 169                         return;
 170                 }
 171
 172                 default:
 173                 case CMD_REQUEST_USAGE:
 174                 {
 175                         print("\nUsage:^3 cl_cmd debugmodel model\n");
 176                         print("  Where 'model' is a string of the model name to use for the debug model.\n");
 177                         return;
 178                 }
 179         }
 180 }
 181
 182 void LocalCommand_handlevote(int request, int argc)
 183 {
 184         switch(request)
 185         {
 186                 case CMD_REQUEST_COMMAND:
 187                 {
 188                         int vote_selection;
 189                         string vote_string;
 190
 191                         if(InterpretBoolean(argv(1)))
 192                         {
 193                                 vote_selection = 2;
 194                                 vote_string = "yes";
 195                         }
 196                         else
 197                         {
 198                                 vote_selection = 1;
 199                                 vote_string = "no";
 200                         }
 201
 202                         if(vote_selection)
 203                         {
 204                                 if(uid2name_dialog) // handled by "uid2name" option
 205                                 {
 206                                         vote_active = 0;
 207                                         vote_prev = 0;
 208                                         vote_change = -9999;
 209                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 210                                         uid2name_dialog = 0;
 211                                 }
 212                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 213
 214                                 return;
 215                         }
 216                 }
 217
 218                 default:
 219                         print("Incorrect parameters for ^2handlevote^7\n");
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         print("\nUsage:^3 cl_cmd handlevote vote\n");
 223                         print("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void LocalCommand_hud(int request, int argc)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         switch(argv(1))
 236                         {
 237                                 case "configure":
 238                                 {
 239                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 240                                         return;
 241                                 }
 242
 243                                 case "save":
 244                                 {
 245                                         if(argv(2))
 246                                         {
 247                                                 HUD_Panel_ExportCfg(argv(2));
 248                                                 return;
 249                                         }
 250                                         else
 251                                         {
 252                                                 break; // go to usage, we're missing the paramater needed here.
 253                                         }
 254                                 }
 255
 256                                 case "scoreboard_columns_set":
 257                                 {
 258                                         Cmd_HUD_SetFields(argc);
 259                                         return;
 260                                 }
 261
 262                                 case "scoreboard_columns_help":
 263                                 {
 264                                         Cmd_HUD_Help();
 265                                         return;
 266                                 }
 267
 268                                 case "radar":
 269                                 {
 270                                         if(argv(2))
 271                                                 hud_panel_radar_maximized = InterpretBoolean(argv(2));
 272                                         else
 273                                                 hud_panel_radar_maximized = !hud_panel_radar_maximized;
 274                                         return;
 275                                 }
 276                         }
 277                 }
 278
 279                 default:
 280                         print("Incorrect parameters for ^2hud^7\n");
 281                 case CMD_REQUEST_USAGE:
 282                 {
 283                         print("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 284                         print("  Where 'action' is the command to complete,\n");
 285                         print("  'configname' is the name to save to for \"save\" action,\n");
 286                         print("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 287                         print("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 288                         print("  Full list of commands here: \"configure, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 289                         return;
 290                 }
 291         }
 292 }
 293
 294 void LocalCommand_localprint(int request, int argc)
 295 {
 296         switch(request)
 297         {
 298                 case CMD_REQUEST_COMMAND:
 299                 {
 300                         if(argv(1))
 301                         {
 302                                 centerprint_hud(argv(1));
 303                                 return;
 304                         }
 305                 }
 306
 307                 default:
 308                         print("Incorrect parameters for ^2localprint^7\n");
 309                 case CMD_REQUEST_USAGE:
 310                 {
 311                         print("\nUsage:^3 cl_cmd localprint \"message\"\n");
 312                         print("  'message' is the centerprint message to send to yourself.\n");
 313                         return;
 314                 }
 315         }
 316 }
 317
 318 void LocalCommand_mv_download(int request, int argc)
 319 {
 320         switch(request)
 321         {
 322                 case CMD_REQUEST_COMMAND:
 323                 {
 324                         if(argv(1))
 325                         {
 326                                 Cmd_MapVote_MapDownload(argc);
 327                                 return;
 328                         }
 329                 }
 330
 331                 default:
 332                         print("Incorrect parameters for ^2mv_download^7\n");
 333                 case CMD_REQUEST_USAGE:
 334                 {
 335                         print("\nUsage:^3 cl_cmd mv_download mapid\n");
 336                         print("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 337                         return;
 338                 }
 339         }
 340 }
 341
 342 void LocalCommand_sendcvar(int request, int argc)
 343 {
 344         switch(request)
 345         {
 346                 case CMD_REQUEST_COMMAND:
 347                 {
 348                         if(argv(1))
 349                         {
 350                                 // W_FixWeaponOrder will trash argv, so save what we need.
 351                                 string thiscvar = strzone(argv(1));
 352                                 string s = cvar_string(thiscvar);
 353
 354                                 if(thiscvar == "cl_weaponpriority")
 355                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 356                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 357                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 358
 359                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 360                                 strunzone(thiscvar);
 361                                 return;
 362                         }
 363                 }
 364
 365                 default:
 366                         print("Incorrect parameters for ^2sendcvar^7\n");
 367                 case CMD_REQUEST_USAGE:
 368                 {
 369                         print("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 370                         print("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 371                         return;
 372                 }
 373         }
 374 }
 375
 376 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 377 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 378 void LocalCommand_(int request)
 379 {
 380         switch(request)
 381         {
 382                 case CMD_REQUEST_COMMAND:
 383                 {
 384
 385                         return;
 386                 }
 387
 388                 default:
 389                 case CMD_REQUEST_USAGE:
 390                 {
 391                         print("\nUsage:^3 cl_cmd \n");
 392                         print("  No arguments required.\n");
 393                         return;
 394                 }
 395         }
 396 }
 397 */
 398
 399
 400 // ==================================
 401 //  Macro system for client commands
 402 // ==================================
 403
 404 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 405 #define CLIENT_COMMANDS(request,arguments) \
 406         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 407         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 408         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 409         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 410         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 411         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 412         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 413         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 414         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 415         /* nothing */
 416
 417 void LocalCommand_macro_help()
 418 {
 419         #define CLIENT_COMMAND(name,function,description) \
 420                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 421
 422         CLIENT_COMMANDS(0, 0);
 423         #undef CLIENT_COMMAND
 424
 425         return;
 426 }
 427
 428 bool LocalCommand_macro_command(int argc)
 429 {
 430         #define CLIENT_COMMAND(name,function,description) \
 431                 { if(name == strtolower(argv(0))) { function; return true; } }
 432
 433         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 434         #undef CLIENT_COMMAND
 435
 436         return false;
 437 }
 438
 439 bool LocalCommand_macro_usage(int argc)
 440 {
 441         #define CLIENT_COMMAND(name,function,description) \
 442                 { if(name == strtolower(argv(1))) { function; return true; } }
 443
 444         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 445         #undef CLIENT_COMMAND
 446
 447         return false;
 448 }
 449
 450 void LocalCommand_macro_write_aliases(int fh)
 451 {
 452         #define CLIENT_COMMAND(name,function,description) \
 453                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 454
 455         CLIENT_COMMANDS(0, 0);
 456         #undef CLIENT_COMMAND
 457
 458         return;
 459 }
 460
 461
 462 // =========================================
 463 //  Main Function Called By Engine (cl_cmd)
 464 // =========================================
 465 // If this function exists, client code handles gamecommand instead of the engine code.
 466
 467 void GameCommand(string command)
 468 {
 469         int argc = tokenize_console(command);
 470
 471         // Guide for working with argc arguments by example:
 472         // argc:   1    - 2      - 3     - 4
 473         // argv:   0    - 1      - 2     - 3
 474         // cmd     vote - master - login - password
 475
 476         if(strtolower(argv(0)) == "help")
 477         {
 478                 if(argc == 1)
 479                 {
 480                         print("\nClient console commands:\n");
 481                         LocalCommand_macro_help();
 482
 483                         print("\nGeneric commands shared by all programs:\n");
 484                         GenericCommand_macro_help();
 485
 486                         print("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 487                         print("For help about a specific command, type cl_cmd help COMMAND\n");
 488
 489                         return;
 490                 }
 491                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 492                 {
 493                         return;
 494                 }
 495                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 496                 {
 497                         return;
 498                 }
 499         }
 500         else if(GenericCommand(command))
 501         {
 502                 return; // handled by common/command/generic.qc
 503         }
 504         else if(LocalCommand_macro_command(argc)) // continue as usual and scan for normal commands
 505         {
 506                 return; // handled by one of the above LocalCommand_* functions
 507         }
 508
 509         // nothing above caught the command, must be invalid
 510         print(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 511
 512         return;
 513 }
 514
 515
 516 // ===================================
 517 //  Macro system for console commands
 518 // ===================================
 519
 520 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 521 // Please add client commands to the function above this, as this is only for special reasons.
 522 #define CONSOLE_COMMANDS_NORMAL() \
 523         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 524         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 525         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 526         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 527         /* nothing */
 528
 529 #define CONSOLE_COMMANDS_MOVEMENT() \
 530         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 531         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 532         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 533         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 534         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 535         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 536         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 537         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 538         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 539         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 540         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 541         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 542         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 543         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 544         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 545         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 546         /* nothing */
 547
 548 void ConsoleCommand_macro_init()
 549 {
 550         // first init normal commands
 551         #define CONSOLE_COMMAND(name,execution) \
 552                 { registercommand(name); }
 553
 554         CONSOLE_COMMANDS_NORMAL();
 555         #undef CONSOLE_COMMAND
 556
 557         // then init movement commands
 558         #ifndef CAMERATEST
 559         if(isdemo())
 560         {
 561         #endif
 562                 #define CONSOLE_COMMAND(name,execution) \
 563                         { registercommand(name); }
 564
 565                 CONSOLE_COMMANDS_MOVEMENT();
 566                 #undef CONSOLE_COMMAND
 567         #ifndef CAMERATEST
 568         }
 569         #endif
 570
 571         return;
 572 }
 573
 574 bool ConsoleCommand_macro_normal(int argc)
 575 {
 576         #define CONSOLE_COMMAND(name,execution) \
 577                 { if(name == strtolower(argv(0))) { { execution } return true; } }
 578
 579         CONSOLE_COMMANDS_NORMAL();
 580         #undef CONSOLE_COMMAND
 581
 582         return false;
 583 }
 584
 585 bool ConsoleCommand_macro_movement(int argc)
 586 {
 587         if(camera_active)
 588         {
 589                 #define CONSOLE_COMMAND(name,execution) \
 590                         { if(name == strtolower(argv(0))) { { execution } return true; } }
 591
 592                 CONSOLE_COMMANDS_MOVEMENT();
 593                 #undef CONSOLE_COMMAND
 594         }
 595
 596         return false;
 597 }
 598
 599
 600 // ======================================================
 601 //  Main Function Called By Engine (registered commands)
 602 // ======================================================
 603 // Used to parse commands in the console that have been registered with the "registercommand" function
 604
 605 bool CSQC_ConsoleCommand(string command)
 606 {
 607         int argc = tokenize_console(command);
 608
 609         if(ConsoleCommand_macro_normal(argc))
 610         {
 611                 return true;
 612         }
 613         else if(ConsoleCommand_macro_movement(argc))
 614         {
 615                 return true;
 616         }
 617
 618         // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 619
 620         return false;
 621 }