qcsrc/client/command/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/command.qh"
   7 #include "cl_cmd.qh"
   8
   9 #include "../autocvars.qh"
  10 #include "../defs.qh"
  11 #include "../hud.qh"
  12 #include "../hud_config.qh"
  13 #include "../main.qh"
  14 #include "../mapvoting.qh"
  15 #include "../miscfunctions.qh"
  16
  17 #include "../mutators/events.qh"
  18
  19 #include "../../common/mapinfo.qh"
  20
  21 #include "../../common/command/generic.qh"
  22
  23 void DrawDebugModel()
  24 {
  25         if(time - floor(time) > 0.5)
  26         {
  27                 PolyDrawModel(self);
  28                 self.drawmask = 0;
  29         }
  30         else
  31         {
  32                 self.renderflags = 0;
  33                 self.drawmask = MASK_NORMAL;
  34         }
  35 }
  36
  37
  38 // =======================
  39 //  Command Sub-Functions
  40 // =======================
  41
  42 void LocalCommand_blurtest(int request)
  43 {
  44         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  45         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  46
  47         #ifdef BLURTEST
  48         switch(request)
  49         {
  50                 case CMD_REQUEST_COMMAND:
  51                 {
  52                         blurtest_time0 = time;
  53                         blurtest_time1 = time + stof(argv(1));
  54                         blurtest_radius = stof(argv(2));
  55                         blurtest_power = stof(argv(3));
  56                         print("Enabled blurtest\n");
  57                         return;
  58                 }
  59
  60                 default:
  61                 case CMD_REQUEST_USAGE:
  62                 {
  63                         print("\nUsage:^3 cl_cmd blurtest\n");
  64                         print("  No arguments required.\n");
  65                         return;
  66                 }
  67         }
  68         #else
  69         if(request)
  70         {
  71                 print("Blurtest is not enabled on this client.\n");
  72                 return;
  73         }
  74         #endif
  75 }
  76
  77 void LocalCommand_boxparticles(int request, int argc)
  78 {
  79         switch(request)
  80         {
  81                 case CMD_REQUEST_COMMAND:
  82                 {
  83                         if (argc == 9)
  84                         {
  85                                 int effect = particleeffectnum(argv(1));
  86                                 if (effect >= 0)
  87                                 {
  88                                         int index = stoi(argv(2));
  89                                         entity own;
  90                                         if(index <= 0)
  91                                                 own = entitybyindex(-index);
  92                                         else
  93                                                 own = findfloat(world, entnum, index);
  94                                         vector org_from = stov(argv(3));
  95                                         vector org_to = stov(argv(4));
  96                                         vector dir_from = stov(argv(5));
  97                                         vector dir_to = stov(argv(6));
  98                                         int countmultiplier = stoi(argv(7));
  99                                         int flags = stoi(argv(8));
 100                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
 101                                         return;
 102                                 }
 103                         }
 104                 }
 105
 106                 default:
 107                         print("Incorrect parameters for ^2boxparticles^7\n");
 108                 case CMD_REQUEST_USAGE:
 109                 {
 110                         print("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
 111                         print("  'effectname' is the name of a particle effect in effectinfo.txt\n");
 112                         print("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
 113                         print("  'org_from' is the starting origin of the box\n");
 114                         print("  'org_to' is the ending origin of the box\n");
 115                         print("  'dir_from' is the minimum velocity\n");
 116                         print("  'dir_to' is the maximum velocity\n");
 117                         print("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 118                         print("  'flags' can contain:\n");
 119                         print("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 120                         print("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 121                         print("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 122                         print("    128 to draw a trail, not a box\n");
 123                         return;
 124                 }
 125         }
 126 }
 127
 128 void LocalCommand_create_scrshot_ent(int request)
 129 {
 130         switch(request)
 131         {
 132                 case CMD_REQUEST_COMMAND:
 133                 {
 134                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 135                         int fh = fopen(filename, FILE_WRITE);
 136
 137                         if(fh >= 0)
 138                         {
 139                                 fputs(fh, "{\n");
 140                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 141                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 142                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 143                                 fputs(fh, "}\n");
 144
 145                                 print("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 146
 147                                 fclose(fh);
 148                         }
 149                         else
 150                         {
 151                                 print("^1Error: ^7Could not dump to file!\n");
 152                         }
 153                         return;
 154                 }
 155
 156                 default:
 157                 case CMD_REQUEST_USAGE:
 158                 {
 159                         print("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 160                         print("  No arguments required.\n");
 161                         return;
 162                 }
 163         }
 164 }
 165
 166 void LocalCommand_debugmodel(int request, int argc)
 167 {
 168         switch(request)
 169         {
 170                 case CMD_REQUEST_COMMAND:
 171                 {
 172                         string modelname = argv(1);
 173                         entity debugmodel_entity;
 174
 175                         debugmodel_entity = spawn();
 176                         precache_model(modelname);
 177                         setmodel(debugmodel_entity, modelname);
 178                         setorigin(debugmodel_entity, view_origin);
 179                         debugmodel_entity.angles = view_angles;
 180                         debugmodel_entity.draw = DrawDebugModel;
 181                         debugmodel_entity.classname = "debugmodel";
 182
 183                         return;
 184                 }
 185
 186                 default:
 187                 case CMD_REQUEST_USAGE:
 188                 {
 189                         print("\nUsage:^3 cl_cmd debugmodel model\n");
 190                         print("  Where 'model' is a string of the model name to use for the debug model.\n");
 191                         return;
 192                 }
 193         }
 194 }
 195
 196 void LocalCommand_handlevote(int request, int argc)
 197 {
 198         switch(request)
 199         {
 200                 case CMD_REQUEST_COMMAND:
 201                 {
 202                         int vote_selection;
 203                         string vote_string;
 204
 205                         if(InterpretBoolean(argv(1)))
 206                         {
 207                                 vote_selection = 2;
 208                                 vote_string = "yes";
 209                         }
 210                         else
 211                         {
 212                                 vote_selection = 1;
 213                                 vote_string = "no";
 214                         }
 215
 216                         if(vote_selection)
 217                         {
 218                                 if(uid2name_dialog) // handled by "uid2name" option
 219                                 {
 220                                         vote_active = 0;
 221                                         vote_prev = 0;
 222                                         vote_change = -9999;
 223                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 224                                         uid2name_dialog = 0;
 225                                 }
 226                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 227
 228                                 return;
 229                         }
 230                 }
 231
 232                 default:
 233                         print("Incorrect parameters for ^2handlevote^7\n");
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         print("\nUsage:^3 cl_cmd handlevote vote\n");
 237                         print("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void LocalCommand_hud(int request, int argc)
 244 {
 245         switch(request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         switch(argv(1))
 250                         {
 251                                 case "configure":
 252                                 {
 253                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 254                                         return;
 255                                 }
 256
 257                                 case "minigame":
 258                                 {
 259                                         if(HUD_MinigameMenu_IsOpened())
 260                                                 HUD_MinigameMenu_Close();
 261                                         else
 262                                                 HUD_MinigameMenu_Open();
 263                                         return;
 264                                 }
 265
 266                                 case "save":
 267                                 {
 268                                         if(argv(2))
 269                                         {
 270                                                 HUD_Panel_ExportCfg(argv(2));
 271                                                 return;
 272                                         }
 273                                         else
 274                                         {
 275                                                 break; // go to usage, we're missing the paramater needed here.
 276                                         }
 277                                 }
 278
 279                                 case "scoreboard_columns_set":
 280                                 {
 281                                         Cmd_HUD_SetFields(argc);
 282                                         return;
 283                                 }
 284
 285                                 case "scoreboard_columns_help":
 286                                 {
 287                                         Cmd_HUD_Help();
 288                                         return;
 289                                 }
 290
 291                                 case "radar":
 292                                 {
 293                                         if(argv(2))
 294                                                 HUD_Radar_Show_Maximized(InterpretBoolean(argv(2)),0);
 295                                         else
 296                                                 HUD_Radar_Show_Maximized(!hud_panel_radar_maximized,0);
 297                                         return;
 298                                 }
 299
 300                                 case "clickradar":
 301                                 {
 302                                         HUD_Radar_Show_Maximized(!hud_panel_radar_mouse,1);
 303                                         return;
 304                                 }
 305                         }
 306                 }
 307
 308                 default:
 309                         print("Incorrect parameters for ^2hud^7\n");
 310                 case CMD_REQUEST_USAGE:
 311                 {
 312                         print("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 313                         print("  Where 'action' is the command to complete,\n");
 314                         print("  'configname' is the name to save to for \"save\" action,\n");
 315                         print("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 316                         print("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 317                         print("  Full list of commands here: \"configure, minigame, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 318                         return;
 319                 }
 320         }
 321 }
 322
 323 void LocalCommand_localprint(int request, int argc)
 324 {
 325         switch(request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         if(argv(1))
 330                         {
 331                                 centerprint_hud(argv(1));
 332                                 return;
 333                         }
 334                 }
 335
 336                 default:
 337                         print("Incorrect parameters for ^2localprint^7\n");
 338                 case CMD_REQUEST_USAGE:
 339                 {
 340                         print("\nUsage:^3 cl_cmd localprint \"message\"\n");
 341                         print("  'message' is the centerprint message to send to yourself.\n");
 342                         return;
 343                 }
 344         }
 345 }
 346
 347 void LocalCommand_mv_download(int request, int argc)
 348 {
 349         switch(request)
 350         {
 351                 case CMD_REQUEST_COMMAND:
 352                 {
 353                         if(argv(1))
 354                         {
 355                                 Cmd_MapVote_MapDownload(argc);
 356                                 return;
 357                         }
 358                 }
 359
 360                 default:
 361                         print("Incorrect parameters for ^2mv_download^7\n");
 362                 case CMD_REQUEST_USAGE:
 363                 {
 364                         print("\nUsage:^3 cl_cmd mv_download mapid\n");
 365                         print("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 366                         return;
 367                 }
 368         }
 369 }
 370
 371 void LocalCommand_find(int request, int argc)
 372 {
 373         switch(request)
 374         {
 375                 case CMD_REQUEST_COMMAND:
 376                 {
 377                         entity client;
 378
 379                         for(client = world; (client = find(client, classname, argv(1))); )
 380                                 print(etos(client), "\n");
 381
 382                         return;
 383                 }
 384
 385                 default:
 386                         print("Incorrect parameters for ^2find^7\n");
 387                 case CMD_REQUEST_USAGE:
 388                 {
 389                         print("\nUsage:^3 cl_cmd find classname\n");
 390                         print("  Where 'classname' is the classname to search for.\n");
 391                         return;
 392                 }
 393         }
 394 }
 395
 396 void LocalCommand_sendcvar(int request, int argc)
 397 {
 398         switch(request)
 399         {
 400                 case CMD_REQUEST_COMMAND:
 401                 {
 402                         if(argv(1))
 403                         {
 404                                 // W_FixWeaponOrder will trash argv, so save what we need.
 405                                 string thiscvar = strzone(argv(1));
 406                                 string s = cvar_string(thiscvar);
 407
 408                                 if(thiscvar == "cl_weaponpriority")
 409                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 410                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 411                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 412
 413                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 414                                 strunzone(thiscvar);
 415                                 return;
 416                         }
 417                 }
 418
 419                 default:
 420                         print("Incorrect parameters for ^2sendcvar^7\n");
 421                 case CMD_REQUEST_USAGE:
 422                 {
 423                         print("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 424                         print("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 431 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 432 void LocalCommand_(int request)
 433 {
 434         switch(request)
 435         {
 436                 case CMD_REQUEST_COMMAND:
 437                 {
 438
 439                         return;
 440                 }
 441
 442                 default:
 443                 case CMD_REQUEST_USAGE:
 444                 {
 445                         print("\nUsage:^3 cl_cmd \n");
 446                         print("  No arguments required.\n");
 447                         return;
 448                 }
 449         }
 450 }
 451 */
 452
 453
 454 // ==================================
 455 //  Macro system for client commands
 456 // ==================================
 457
 458 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 459 #define CLIENT_COMMANDS(request,arguments) \
 460         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 461         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 462         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 463         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 464         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 465         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 466         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 467         CLIENT_COMMAND("find", LocalCommand_find(request, arguments), "Search through entities for matching classname") \
 468         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 469         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 470         /* nothing */
 471
 472 void LocalCommand_macro_help()
 473 {
 474         #define CLIENT_COMMAND(name,function,description) \
 475                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 476
 477         CLIENT_COMMANDS(0, 0);
 478         #undef CLIENT_COMMAND
 479
 480         return;
 481 }
 482
 483 bool LocalCommand_macro_command(int argc)
 484 {
 485         #define CLIENT_COMMAND(name,function,description) \
 486                 { if(name == strtolower(argv(0))) { function; return true; } }
 487
 488         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 489         #undef CLIENT_COMMAND
 490
 491         return false;
 492 }
 493
 494 bool LocalCommand_macro_usage(int argc)
 495 {
 496         #define CLIENT_COMMAND(name,function,description) \
 497                 { if(name == strtolower(argv(1))) { function; return true; } }
 498
 499         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 500         #undef CLIENT_COMMAND
 501
 502         return false;
 503 }
 504
 505 void LocalCommand_macro_write_aliases(int fh)
 506 {
 507         #define CLIENT_COMMAND(name,function,description) \
 508                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 509
 510         CLIENT_COMMANDS(0, 0);
 511         #undef CLIENT_COMMAND
 512
 513         return;
 514 }
 515
 516
 517 // =========================================
 518 //  Main Function Called By Engine (cl_cmd)
 519 // =========================================
 520 // If this function exists, client code handles gamecommand instead of the engine code.
 521
 522 void GameCommand(string command)
 523 {
 524         int argc = tokenize_console(command);
 525
 526         // Guide for working with argc arguments by example:
 527         // argc:   1    - 2      - 3     - 4
 528         // argv:   0    - 1      - 2     - 3
 529         // cmd     vote - master - login - password
 530         string s = strtolower(argv(0));
 531         if (s == "help")
 532         {
 533                 if(argc == 1)
 534                 {
 535                         print("\nClient console commands:\n");
 536                         LocalCommand_macro_help();
 537
 538                         print("\nGeneric commands shared by all programs:\n");
 539                         GenericCommand_macro_help();
 540
 541                         print("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 542                         print("For help about a specific command, type cl_cmd help COMMAND\n");
 543
 544                         return;
 545                 }
 546                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 547                 {
 548                         return;
 549                 }
 550                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 551                 {
 552                         return;
 553                 }
 554         }
 555         // continue as usual and scan for normal commands
 556         if (GenericCommand(command)// handled by common/command/generic.qc
 557         || LocalCommand_macro_command(argc) // handled by one of the above LocalCommand_* functions
 558         || MUTATOR_CALLHOOK(CSQC_ConsoleCommand, s, argc, command) // handled by a mutator
 559         ) return;
 560
 561         // nothing above caught the command, must be invalid
 562         print(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 563
 564         return;
 565 }
 566
 567
 568 // ===================================
 569 //  Macro system for console commands
 570 // ===================================
 571
 572 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 573 // Please add client commands to the function above this, as this is only for special reasons.
 574 #define CONSOLE_COMMANDS_NORMAL() \
 575         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 576         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 577         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 578         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 579         /* nothing */
 580
 581 #define CONSOLE_COMMANDS_MOVEMENT() \
 582         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 583         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 584         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 585         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 586         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 587         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 588         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 589         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 590         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 591         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 592         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 593         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 594         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 595         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 596         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 597         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 598         /* nothing */
 599
 600 void ConsoleCommand_macro_init()
 601 {
 602         // first init normal commands
 603         #define CONSOLE_COMMAND(name,execution) \
 604                 { registercommand(name); }
 605
 606         CONSOLE_COMMANDS_NORMAL();
 607         #undef CONSOLE_COMMAND
 608
 609         // then init movement commands
 610         #ifndef CAMERATEST
 611         if(isdemo())
 612         {
 613         #endif
 614                 #define CONSOLE_COMMAND(name,execution) \
 615                         { registercommand(name); }
 616
 617                 CONSOLE_COMMANDS_MOVEMENT();
 618                 #undef CONSOLE_COMMAND
 619         #ifndef CAMERATEST
 620         }
 621         #endif
 622 }
 623
 624 bool ConsoleCommand_macro_normal(string s, int argc)
 625 {
 626         #define CONSOLE_COMMAND(name,execution) \
 627                 { if (name == s) { { execution } return true; } }
 628
 629         CONSOLE_COMMANDS_NORMAL();
 630         #undef CONSOLE_COMMAND
 631
 632         return false;
 633 }
 634
 635 bool ConsoleCommand_macro_movement(string s, int argc)
 636 {
 637         if(camera_active)
 638         {
 639                 #define CONSOLE_COMMAND(name,execution) \
 640                         { if (name == s) { { execution } return true; } }
 641
 642                 CONSOLE_COMMANDS_MOVEMENT();
 643                 #undef CONSOLE_COMMAND
 644         }
 645
 646         return false;
 647 }
 648
 649
 650 // ======================================================
 651 //  Main Function Called By Engine (registered commands)
 652 // ======================================================
 653 // Used to parse commands in the console that have been registered with the "registercommand" function
 654
 655 bool CSQC_ConsoleCommand(string command)
 656 {
 657         int argc = tokenize_console(command);
 658         string s = strtolower(argv(0));
 659         // Return value should be true if CSQC handled the command, otherwise return false to have the engine handle it.
 660         return (ConsoleCommand_macro_normal(s, argc)
 661         || ConsoleCommand_macro_movement(s, argc)
 662         );
 663 }