qcsrc/client/command/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/command.qh"
   7 #include "cl_cmd.qh"
   8
   9 #include "../autocvars.qh"
  10 #include "../defs.qh"
  11 #include "../hud.qh"
  12 #include "../hud_config.qh"
  13 #include "../main.qh"
  14 #include "../mapvoting.qh"
  15 #include "../miscfunctions.qh"
  16
  17 #include "../mutators/events.qh"
  18
  19 #include "../../common/mapinfo.qh"
  20
  21 #include "../../common/command/generic.qh"
  22
  23 void DrawDebugModel()
  24 {
  25         if(time - floor(time) > 0.5)
  26         {
  27                 PolyDrawModel(self);
  28                 self.drawmask = 0;
  29         }
  30         else
  31         {
  32                 self.renderflags = 0;
  33                 self.drawmask = MASK_NORMAL;
  34         }
  35 }
  36
  37
  38 // =======================
  39 //  Command Sub-Functions
  40 // =======================
  41
  42 void LocalCommand_blurtest(int request)
  43 {
  44         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  45         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  46
  47         #ifdef BLURTEST
  48         switch(request)
  49         {
  50                 case CMD_REQUEST_COMMAND:
  51                 {
  52                         blurtest_time0 = time;
  53                         blurtest_time1 = time + stof(argv(1));
  54                         blurtest_radius = stof(argv(2));
  55                         blurtest_power = stof(argv(3));
  56                         print("Enabled blurtest\n");
  57                         return;
  58                 }
  59
  60                 default:
  61                 case CMD_REQUEST_USAGE:
  62                 {
  63                         print("\nUsage:^3 cl_cmd blurtest\n");
  64                         print("  No arguments required.\n");
  65                         return;
  66                 }
  67         }
  68         #else
  69         if(request)
  70         {
  71                 print("Blurtest is not enabled on this client.\n");
  72                 return;
  73         }
  74         #endif
  75 }
  76
  77 void LocalCommand_boxparticles(int request, int argc)
  78 {
  79         switch(request)
  80         {
  81                 case CMD_REQUEST_COMMAND:
  82                 {
  83                         if (argc == 9)
  84                         {
  85                                 int effect = particleeffectnum(argv(1));
  86                                 if (effect >= 0)
  87                                 {
  88                                         int index = stoi(argv(2));
  89                                         entity own;
  90                                         if(index <= 0)
  91                                                 own = entitybyindex(-index);
  92                                         else
  93                                                 own = findfloat(world, entnum, index);
  94                                         vector org_from = stov(argv(3));
  95                                         vector org_to = stov(argv(4));
  96                                         vector dir_from = stov(argv(5));
  97                                         vector dir_to = stov(argv(6));
  98                                         int countmultiplier = stoi(argv(7));
  99                                         int flags = stoi(argv(8));
 100                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
 101                                         return;
 102                                 }
 103                         }
 104                 }
 105
 106                 default:
 107                         print("Incorrect parameters for ^2boxparticles^7\n");
 108                 case CMD_REQUEST_USAGE:
 109                 {
 110                         print("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
 111                         print("  'effectname' is the name of a particle effect in effectinfo.txt\n");
 112                         print("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
 113                         print("  'org_from' is the starting origin of the box\n");
 114                         print("  'org_to' is the ending origin of the box\n");
 115                         print("  'dir_from' is the minimum velocity\n");
 116                         print("  'dir_to' is the maximum velocity\n");
 117                         print("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 118                         print("  'flags' can contain:\n");
 119                         print("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 120                         print("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 121                         print("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 122                         print("    128 to draw a trail, not a box\n");
 123                         return;
 124                 }
 125         }
 126 }
 127
 128 void LocalCommand_create_scrshot_ent(int request)
 129 {
 130         switch(request)
 131         {
 132                 case CMD_REQUEST_COMMAND:
 133                 {
 134                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 135                         int fh = fopen(filename, FILE_WRITE);
 136
 137                         if(fh >= 0)
 138                         {
 139                                 fputs(fh, "{\n");
 140                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 141                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 142                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 143                                 fputs(fh, "}\n");
 144
 145                                 print("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 146
 147                                 fclose(fh);
 148                         }
 149                         else
 150                         {
 151                                 print("^1Error: ^7Could not dump to file!\n");
 152                         }
 153                         return;
 154                 }
 155
 156                 default:
 157                 case CMD_REQUEST_USAGE:
 158                 {
 159                         print("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 160                         print("  No arguments required.\n");
 161                         return;
 162                 }
 163         }
 164 }
 165
 166 void LocalCommand_debugmodel(int request, int argc)
 167 {
 168         switch(request)
 169         {
 170                 case CMD_REQUEST_COMMAND:
 171                 {
 172                         string modelname = argv(1);
 173                         entity debugmodel_entity;
 174
 175                         debugmodel_entity = spawn();
 176                         precache_model(modelname);
 177                         setmodel(debugmodel_entity, modelname);
 178                         setorigin(debugmodel_entity, view_origin);
 179                         debugmodel_entity.angles = view_angles;
 180                         debugmodel_entity.draw = DrawDebugModel;
 181                         debugmodel_entity.classname = "debugmodel";
 182
 183                         return;
 184                 }
 185
 186                 default:
 187                 case CMD_REQUEST_USAGE:
 188                 {
 189                         print("\nUsage:^3 cl_cmd debugmodel model\n");
 190                         print("  Where 'model' is a string of the model name to use for the debug model.\n");
 191                         return;
 192                 }
 193         }
 194 }
 195
 196 void LocalCommand_handlevote(int request, int argc)
 197 {
 198         switch(request)
 199         {
 200                 case CMD_REQUEST_COMMAND:
 201                 {
 202                         int vote_selection;
 203                         string vote_string;
 204
 205                         if(InterpretBoolean(argv(1)))
 206                         {
 207                                 vote_selection = 2;
 208                                 vote_string = "yes";
 209                         }
 210                         else
 211                         {
 212                                 vote_selection = 1;
 213                                 vote_string = "no";
 214                         }
 215
 216                         if(vote_selection)
 217                         {
 218                                 if(uid2name_dialog) // handled by "uid2name" option
 219                                 {
 220                                         vote_active = 0;
 221                                         vote_prev = 0;
 222                                         vote_change = -9999;
 223                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 224                                         uid2name_dialog = 0;
 225                                 }
 226                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 227
 228                                 return;
 229                         }
 230                 }
 231
 232                 default:
 233                         print("Incorrect parameters for ^2handlevote^7\n");
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         print("\nUsage:^3 cl_cmd handlevote vote\n");
 237                         print("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void LocalCommand_hud(int request, int argc)
 244 {
 245         switch(request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         switch(argv(1))
 250                         {
 251                                 case "configure":
 252                                 {
 253                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 254                                         return;
 255                                 }
 256
 257                                 case "save":
 258                                 {
 259                                         if(argv(2))
 260                                         {
 261                                                 HUD_Panel_ExportCfg(argv(2));
 262                                                 return;
 263                                         }
 264                                         else
 265                                         {
 266                                                 break; // go to usage, we're missing the paramater needed here.
 267                                         }
 268                                 }
 269
 270                                 case "scoreboard_columns_set":
 271                                 {
 272                                         Cmd_HUD_SetFields(argc);
 273                                         return;
 274                                 }
 275
 276                                 case "scoreboard_columns_help":
 277                                 {
 278                                         Cmd_HUD_Help();
 279                                         return;
 280                                 }
 281
 282                                 case "radar":
 283                                 {
 284                                         if(argv(2))
 285                                                 HUD_Radar_Show_Maximized(InterpretBoolean(argv(2)),0);
 286                                         else
 287                                                 HUD_Radar_Show_Maximized(!hud_panel_radar_maximized,0);
 288                                         return;
 289                                 }
 290
 291                                 case "clickradar":
 292                                 {
 293                                         HUD_Radar_Show_Maximized(!hud_panel_radar_mouse,1);
 294                                         return;
 295                                 }
 296                         }
 297                 }
 298
 299                 default:
 300                         print("Incorrect parameters for ^2hud^7\n");
 301                 case CMD_REQUEST_USAGE:
 302                 {
 303                         print("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 304                         print("  Where 'action' is the command to complete,\n");
 305                         print("  'configname' is the name to save to for \"save\" action,\n");
 306                         print("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 307                         print("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 308                         print("  Full list of commands here: \"configure, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 309                         return;
 310                 }
 311         }
 312 }
 313
 314 void LocalCommand_localprint(int request, int argc)
 315 {
 316         switch(request)
 317         {
 318                 case CMD_REQUEST_COMMAND:
 319                 {
 320                         if(argv(1))
 321                         {
 322                                 centerprint_hud(argv(1));
 323                                 return;
 324                         }
 325                 }
 326
 327                 default:
 328                         print("Incorrect parameters for ^2localprint^7\n");
 329                 case CMD_REQUEST_USAGE:
 330                 {
 331                         print("\nUsage:^3 cl_cmd localprint \"message\"\n");
 332                         print("  'message' is the centerprint message to send to yourself.\n");
 333                         return;
 334                 }
 335         }
 336 }
 337
 338 void LocalCommand_mv_download(int request, int argc)
 339 {
 340         switch(request)
 341         {
 342                 case CMD_REQUEST_COMMAND:
 343                 {
 344                         if(argv(1))
 345                         {
 346                                 Cmd_MapVote_MapDownload(argc);
 347                                 return;
 348                         }
 349                 }
 350
 351                 default:
 352                         print("Incorrect parameters for ^2mv_download^7\n");
 353                 case CMD_REQUEST_USAGE:
 354                 {
 355                         print("\nUsage:^3 cl_cmd mv_download mapid\n");
 356                         print("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 357                         return;
 358                 }
 359         }
 360 }
 361
 362 void LocalCommand_find(int request, int argc)
 363 {
 364         switch(request)
 365         {
 366                 case CMD_REQUEST_COMMAND:
 367                 {
 368                         entity client;
 369
 370                         for(client = world; (client = find(client, classname, argv(1))); )
 371                                 print(etos(client), "\n");
 372
 373                         return;
 374                 }
 375
 376                 default:
 377                         print("Incorrect parameters for ^2find^7\n");
 378                 case CMD_REQUEST_USAGE:
 379                 {
 380                         print("\nUsage:^3 cl_cmd find classname\n");
 381                         print("  Where 'classname' is the classname to search for.\n");
 382                         return;
 383                 }
 384         }
 385 }
 386
 387 void LocalCommand_sendcvar(int request, int argc)
 388 {
 389         switch(request)
 390         {
 391                 case CMD_REQUEST_COMMAND:
 392                 {
 393                         if(argv(1))
 394                         {
 395                                 // W_FixWeaponOrder will trash argv, so save what we need.
 396                                 string thiscvar = strzone(argv(1));
 397                                 string s = cvar_string(thiscvar);
 398
 399                                 if(thiscvar == "cl_weaponpriority")
 400                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 401                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 402                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 403
 404                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 405                                 strunzone(thiscvar);
 406                                 return;
 407                         }
 408                 }
 409
 410                 default:
 411                         print("Incorrect parameters for ^2sendcvar^7\n");
 412                 case CMD_REQUEST_USAGE:
 413                 {
 414                         print("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 415                         print("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 416                         return;
 417                 }
 418         }
 419 }
 420
 421 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 422 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 423 void LocalCommand_(int request)
 424 {
 425         switch(request)
 426         {
 427                 case CMD_REQUEST_COMMAND:
 428                 {
 429
 430                         return;
 431                 }
 432
 433                 default:
 434                 case CMD_REQUEST_USAGE:
 435                 {
 436                         print("\nUsage:^3 cl_cmd \n");
 437                         print("  No arguments required.\n");
 438                         return;
 439                 }
 440         }
 441 }
 442 */
 443
 444
 445 // ==================================
 446 //  Macro system for client commands
 447 // ==================================
 448
 449 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 450 #define CLIENT_COMMANDS(request,arguments) \
 451         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 452         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 453         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 454         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 455         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 456         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 457         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 458         CLIENT_COMMAND("find", LocalCommand_find(request, arguments), "Search through entities for matching classname") \
 459         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 460         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 461         /* nothing */
 462
 463 void LocalCommand_macro_help()
 464 {
 465         #define CLIENT_COMMAND(name,function,description) \
 466                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 467
 468         CLIENT_COMMANDS(0, 0);
 469         #undef CLIENT_COMMAND
 470
 471         return;
 472 }
 473
 474 bool LocalCommand_macro_command(int argc)
 475 {
 476         #define CLIENT_COMMAND(name,function,description) \
 477                 { if(name == strtolower(argv(0))) { function; return true; } }
 478
 479         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 480         #undef CLIENT_COMMAND
 481
 482         return false;
 483 }
 484
 485 bool LocalCommand_macro_usage(int argc)
 486 {
 487         #define CLIENT_COMMAND(name,function,description) \
 488                 { if(name == strtolower(argv(1))) { function; return true; } }
 489
 490         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 491         #undef CLIENT_COMMAND
 492
 493         return false;
 494 }
 495
 496 void LocalCommand_macro_write_aliases(int fh)
 497 {
 498         #define CLIENT_COMMAND(name,function,description) \
 499                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 500
 501         CLIENT_COMMANDS(0, 0);
 502         #undef CLIENT_COMMAND
 503
 504         return;
 505 }
 506
 507
 508 // =========================================
 509 //  Main Function Called By Engine (cl_cmd)
 510 // =========================================
 511 // If this function exists, client code handles gamecommand instead of the engine code.
 512
 513 void GameCommand(string command)
 514 {
 515         int argc = tokenize_console(command);
 516
 517         // Guide for working with argc arguments by example:
 518         // argc:   1    - 2      - 3     - 4
 519         // argv:   0    - 1      - 2     - 3
 520         // cmd     vote - master - login - password
 521         string s = strtolower(argv(0));
 522         if (s == "help")
 523         {
 524                 if(argc == 1)
 525                 {
 526                         print("\nClient console commands:\n");
 527                         LocalCommand_macro_help();
 528
 529                         print("\nGeneric commands shared by all programs:\n");
 530                         GenericCommand_macro_help();
 531
 532                         print("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 533                         print("For help about a specific command, type cl_cmd help COMMAND\n");
 534
 535                         return;
 536                 }
 537                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 538                 {
 539                         return;
 540                 }
 541                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 542                 {
 543                         return;
 544                 }
 545         }
 546         // continue as usual and scan for normal commands
 547         if (GenericCommand(command)// handled by common/command/generic.qc
 548         || LocalCommand_macro_command(argc) // handled by one of the above LocalCommand_* functions
 549         || MUTATOR_CALLHOOK(CSQC_ConsoleCommand, s, argc, command) // handled by a mutator
 550         ) return;
 551
 552         // nothing above caught the command, must be invalid
 553         print(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 554
 555         return;
 556 }
 557
 558
 559 // ===================================
 560 //  Macro system for console commands
 561 // ===================================
 562
 563 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 564 // Please add client commands to the function above this, as this is only for special reasons.
 565 #define CONSOLE_COMMANDS_NORMAL() \
 566         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 567         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 568         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 569         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 570         /* nothing */
 571
 572 #define CONSOLE_COMMANDS_MOVEMENT() \
 573         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 574         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 575         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 576         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 577         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 578         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 579         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 580         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 581         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 582         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 583         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 584         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 585         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 586         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 587         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 588         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 589         /* nothing */
 590
 591 void ConsoleCommand_macro_init()
 592 {
 593         // first init normal commands
 594         #define CONSOLE_COMMAND(name,execution) \
 595                 { registercommand(name); }
 596
 597         CONSOLE_COMMANDS_NORMAL();
 598         #undef CONSOLE_COMMAND
 599
 600         // then init movement commands
 601         #ifndef CAMERATEST
 602         if(isdemo())
 603         {
 604         #endif
 605                 #define CONSOLE_COMMAND(name,execution) \
 606                         { registercommand(name); }
 607
 608                 CONSOLE_COMMANDS_MOVEMENT();
 609                 #undef CONSOLE_COMMAND
 610         #ifndef CAMERATEST
 611         }
 612         #endif
 613 }
 614
 615 bool ConsoleCommand_macro_normal(string s, int argc)
 616 {
 617         #define CONSOLE_COMMAND(name,execution) \
 618                 { if (name == s) { { execution } return true; } }
 619
 620         CONSOLE_COMMANDS_NORMAL();
 621         #undef CONSOLE_COMMAND
 622
 623         return false;
 624 }
 625
 626 bool ConsoleCommand_macro_movement(string s, int argc)
 627 {
 628         if(camera_active)
 629         {
 630                 #define CONSOLE_COMMAND(name,execution) \
 631                         { if (name == s) { { execution } return true; } }
 632
 633                 CONSOLE_COMMANDS_MOVEMENT();
 634                 #undef CONSOLE_COMMAND
 635         }
 636
 637         return false;
 638 }
 639
 640
 641 // ======================================================
 642 //  Main Function Called By Engine (registered commands)
 643 // ======================================================
 644 // Used to parse commands in the console that have been registered with the "registercommand" function
 645
 646 bool CSQC_ConsoleCommand(string command)
 647 {
 648         int argc = tokenize_console(command);
 649         string s = strtolower(argv(0));
 650         // Return value should be true if CSQC handled the command, otherwise return false to have the engine handle it.
 651         return (ConsoleCommand_macro_normal(s, argc)
 652         || ConsoleCommand_macro_movement(s, argc)
 653         );
 654 }