qcsrc/client/command/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/generic.qh"
   7 #include "../../common/command/shared_defs.qh"
   8
   9 void DrawDebugModel()
  10 {
  11         if(time - floor(time) > 0.5)
  12         {
  13                 PolyDrawModel(self);
  14                 self.drawmask = 0;
  15         }
  16         else
  17         {
  18                 self.renderflags = 0;
  19                 self.drawmask = MASK_NORMAL;
  20         }
  21 }
  22
  23
  24 // =======================
  25 //  Command Sub-Functions
  26 // =======================
  27
  28 void LocalCommand_blurtest(int request)
  29 {
  30         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  31         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  32
  33         #ifdef BLURTEST
  34         switch(request)
  35         {
  36                 case CMD_REQUEST_COMMAND:
  37                 {
  38                         blurtest_time0 = time;
  39                         blurtest_time1 = time + stof(argv(1));
  40                         blurtest_radius = stof(argv(2));
  41                         blurtest_power = stof(argv(3));
  42                         print("Enabled blurtest\n");
  43                         return;
  44                 }
  45
  46                 default:
  47                 case CMD_REQUEST_USAGE:
  48                 {
  49                         print("\nUsage:^3 cl_cmd blurtest\n");
  50                         print("  No arguments required.\n");
  51                         return;
  52                 }
  53         }
  54         #else
  55         if(request)
  56         {
  57                 print("Blurtest is not enabled on this client.\n");
  58                 return;
  59         }
  60         #endif
  61 }
  62
  63 void LocalCommand_boxparticles(int request, int argc)
  64 {
  65         switch(request)
  66         {
  67                 case CMD_REQUEST_COMMAND:
  68                 {
  69                         if (argc == 9)
  70                         {
  71                                 int effect = particleeffectnum(argv(1));
  72                                 if (effect >= 0)
  73                                 {
  74                                         int index = stoi(argv(2));
  75                                         entity own;
  76                                         if(index <= 0)
  77                                                 own = entitybyindex(-index);
  78                                         else
  79                                                 own = findfloat(world, entnum, index);
  80                                         vector org_from = stov(argv(3));
  81                                         vector org_to = stov(argv(4));
  82                                         vector dir_from = stov(argv(5));
  83                                         vector dir_to = stov(argv(6));
  84                                         int countmultiplier = stoi(argv(7));
  85                                         int flags = stoi(argv(8));
  86                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
  87                                         return;
  88                                 }
  89                         }
  90                 }
  91
  92                 default:
  93                         print("Incorrect parameters for ^2boxparticles^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         print("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
  97                         print("  'effectname' is the name of a particle effect in effectinfo.txt\n");
  98                         print("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
  99                         print("  'org_from' is the starting origin of the box\n");
 100                         print("  'org_to' is the ending origin of the box\n");
 101                         print("  'dir_from' is the minimum velocity\n");
 102                         print("  'dir_to' is the maximum velocity\n");
 103                         print("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 104                         print("  'flags' can contain:\n");
 105                         print("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 106                         print("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 107                         print("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 108                         print("    128 to draw a trail, not a box\n");
 109                         return;
 110                 }
 111         }
 112 }
 113
 114 void LocalCommand_create_scrshot_ent(int request)
 115 {
 116         switch(request)
 117         {
 118                 case CMD_REQUEST_COMMAND:
 119                 {
 120                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 121                         int fh = fopen(filename, FILE_WRITE);
 122
 123                         if(fh >= 0)
 124                         {
 125                                 fputs(fh, "{\n");
 126                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 127                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 128                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 129                                 fputs(fh, "}\n");
 130
 131                                 print("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 132
 133                                 fclose(fh);
 134                         }
 135                         else
 136                         {
 137                                 print("^1Error: ^7Could not dump to file!\n");
 138                         }
 139                         return;
 140                 }
 141
 142                 default:
 143                 case CMD_REQUEST_USAGE:
 144                 {
 145                         print("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 146                         print("  No arguments required.\n");
 147                         return;
 148                 }
 149         }
 150 }
 151
 152 void LocalCommand_debugmodel(int request, int argc)
 153 {
 154         switch(request)
 155         {
 156                 case CMD_REQUEST_COMMAND:
 157                 {
 158                         string modelname = argv(1);
 159                         entity debugmodel_entity;
 160
 161                         debugmodel_entity = spawn();
 162                         precache_model(modelname);
 163                         setmodel(debugmodel_entity, modelname);
 164                         setorigin(debugmodel_entity, view_origin);
 165                         debugmodel_entity.angles = view_angles;
 166                         debugmodel_entity.draw = DrawDebugModel;
 167                         debugmodel_entity.classname = "debugmodel";
 168
 169                         return;
 170                 }
 171
 172                 default:
 173                 case CMD_REQUEST_USAGE:
 174                 {
 175                         print("\nUsage:^3 cl_cmd debugmodel model\n");
 176                         print("  Where 'model' is a string of the model name to use for the debug model.\n");
 177                         return;
 178                 }
 179         }
 180 }
 181
 182 void LocalCommand_handlevote(int request, int argc)
 183 {
 184         switch(request)
 185         {
 186                 case CMD_REQUEST_COMMAND:
 187                 {
 188                         int vote_selection;
 189                         string vote_string;
 190
 191                         if(InterpretBoolean(argv(1)))
 192                         {
 193                                 vote_selection = 2;
 194                                 vote_string = "yes";
 195                         }
 196                         else
 197                         {
 198                                 vote_selection = 1;
 199                                 vote_string = "no";
 200                         }
 201
 202                         if(vote_selection)
 203                         {
 204                                 if(uid2name_dialog) // handled by "uid2name" option
 205                                 {
 206                                         vote_active = 0;
 207                                         vote_prev = 0;
 208                                         vote_change = -9999;
 209                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 210                                         uid2name_dialog = 0;
 211                                 }
 212                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 213
 214                                 return;
 215                         }
 216                 }
 217
 218                 default:
 219                         print("Incorrect parameters for ^2handlevote^7\n");
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         print("\nUsage:^3 cl_cmd handlevote vote\n");
 223                         print("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void LocalCommand_hud(int request, int argc)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         switch(argv(1))
 236                         {
 237                                 case "configure":
 238                                 {
 239                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 240                                         return;
 241                                 }
 242
 243                                 case "minigame":
 244                                 {
 245                                         if(HUD_MinigameMenu_IsOpened())
 246                                                 HUD_MinigameMenu_Close();
 247                                         else
 248                                                 HUD_MinigameMenu_Open();
 249                                         return;
 250                                 }
 251
 252                                 case "save":
 253                                 {
 254                                         if(argv(2))
 255                                         {
 256                                                 HUD_Panel_ExportCfg(argv(2));
 257                                                 return;
 258                                         }
 259                                         else
 260                                         {
 261                                                 break; // go to usage, we're missing the paramater needed here.
 262                                         }
 263                                 }
 264
 265                                 case "scoreboard_columns_set":
 266                                 {
 267                                         Cmd_HUD_SetFields(argc);
 268                                         return;
 269                                 }
 270
 271                                 case "scoreboard_columns_help":
 272                                 {
 273                                         Cmd_HUD_Help();
 274                                         return;
 275                                 }
 276
 277                                 case "radar":
 278                                 {
 279                                         if(argv(2))
 280                                                 hud_panel_radar_maximized = InterpretBoolean(argv(2));
 281                                         else
 282                                                 hud_panel_radar_maximized = !hud_panel_radar_maximized;
 283                                         return;
 284                                 }
 285                         }
 286                 }
 287
 288                 default:
 289                         print("Incorrect parameters for ^2hud^7\n");
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         print("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 293                         print("  Where 'action' is the command to complete,\n");
 294                         print("  'configname' is the name to save to for \"save\" action,\n");
 295                         print("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 296                         print("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 297                         print("  Full list of commands here: \"configure, minigame, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 298                         return;
 299                 }
 300         }
 301 }
 302
 303 void LocalCommand_localprint(int request, int argc)
 304 {
 305         switch(request)
 306         {
 307                 case CMD_REQUEST_COMMAND:
 308                 {
 309                         if(argv(1))
 310                         {
 311                                 centerprint_hud(argv(1));
 312                                 return;
 313                         }
 314                 }
 315
 316                 default:
 317                         print("Incorrect parameters for ^2localprint^7\n");
 318                 case CMD_REQUEST_USAGE:
 319                 {
 320                         print("\nUsage:^3 cl_cmd localprint \"message\"\n");
 321                         print("  'message' is the centerprint message to send to yourself.\n");
 322                         return;
 323                 }
 324         }
 325 }
 326
 327 void LocalCommand_mv_download(int request, int argc)
 328 {
 329         switch(request)
 330         {
 331                 case CMD_REQUEST_COMMAND:
 332                 {
 333                         if(argv(1))
 334                         {
 335                                 Cmd_MapVote_MapDownload(argc);
 336                                 return;
 337                         }
 338                 }
 339
 340                 default:
 341                         print("Incorrect parameters for ^2mv_download^7\n");
 342                 case CMD_REQUEST_USAGE:
 343                 {
 344                         print("\nUsage:^3 cl_cmd mv_download mapid\n");
 345                         print("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 346                         return;
 347                 }
 348         }
 349 }
 350
 351 void LocalCommand_sendcvar(int request, int argc)
 352 {
 353         switch(request)
 354         {
 355                 case CMD_REQUEST_COMMAND:
 356                 {
 357                         if(argv(1))
 358                         {
 359                                 // W_FixWeaponOrder will trash argv, so save what we need.
 360                                 string thiscvar = strzone(argv(1));
 361                                 string s = cvar_string(thiscvar);
 362
 363                                 if(thiscvar == "cl_weaponpriority")
 364                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 365                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 366                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 367
 368                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 369                                 strunzone(thiscvar);
 370                                 return;
 371                         }
 372                 }
 373
 374                 default:
 375                         print("Incorrect parameters for ^2sendcvar^7\n");
 376                 case CMD_REQUEST_USAGE:
 377                 {
 378                         print("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 379                         print("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 380                         return;
 381                 }
 382         }
 383 }
 384
 385 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 386 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 387 void LocalCommand_(int request)
 388 {
 389         switch(request)
 390         {
 391                 case CMD_REQUEST_COMMAND:
 392                 {
 393
 394                         return;
 395                 }
 396
 397                 default:
 398                 case CMD_REQUEST_USAGE:
 399                 {
 400                         print("\nUsage:^3 cl_cmd \n");
 401                         print("  No arguments required.\n");
 402                         return;
 403                 }
 404         }
 405 }
 406 */
 407
 408
 409 // ==================================
 410 //  Macro system for client commands
 411 // ==================================
 412
 413 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 414 #define CLIENT_COMMANDS(request,arguments) \
 415         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 416         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 417         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 418         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 419         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 420         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 421         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 422         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 423         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 424         /* nothing */
 425
 426 void LocalCommand_macro_help()
 427 {
 428         #define CLIENT_COMMAND(name,function,description) \
 429                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 430
 431         CLIENT_COMMANDS(0, 0);
 432         #undef CLIENT_COMMAND
 433
 434         return;
 435 }
 436
 437 bool LocalCommand_macro_command(int argc)
 438 {
 439         #define CLIENT_COMMAND(name,function,description) \
 440                 { if(name == strtolower(argv(0))) { function; return true; } }
 441
 442         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 443         #undef CLIENT_COMMAND
 444
 445         return false;
 446 }
 447
 448 bool LocalCommand_macro_usage(int argc)
 449 {
 450         #define CLIENT_COMMAND(name,function,description) \
 451                 { if(name == strtolower(argv(1))) { function; return true; } }
 452
 453         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 454         #undef CLIENT_COMMAND
 455
 456         return false;
 457 }
 458
 459 void LocalCommand_macro_write_aliases(int fh)
 460 {
 461         #define CLIENT_COMMAND(name,function,description) \
 462                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 463
 464         CLIENT_COMMANDS(0, 0);
 465         #undef CLIENT_COMMAND
 466
 467         return;
 468 }
 469
 470
 471 // =========================================
 472 //  Main Function Called By Engine (cl_cmd)
 473 // =========================================
 474 // If this function exists, client code handles gamecommand instead of the engine code.
 475
 476 void GameCommand(string command)
 477 {
 478         int argc = tokenize_console(command);
 479
 480         // Guide for working with argc arguments by example:
 481         // argc:   1    - 2      - 3     - 4
 482         // argv:   0    - 1      - 2     - 3
 483         // cmd     vote - master - login - password
 484
 485         if(strtolower(argv(0)) == "help")
 486         {
 487                 if(argc == 1)
 488                 {
 489                         print("\nClient console commands:\n");
 490                         LocalCommand_macro_help();
 491
 492                         print("\nGeneric commands shared by all programs:\n");
 493                         GenericCommand_macro_help();
 494
 495                         print("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 496                         print("For help about a specific command, type cl_cmd help COMMAND\n");
 497
 498                         return;
 499                 }
 500                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 501                 {
 502                         return;
 503                 }
 504                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 505                 {
 506                         return;
 507                 }
 508         }
 509         else if(GenericCommand(command))
 510         {
 511                 return; // handled by common/command/generic.qc
 512         }
 513         else if(LocalCommand_macro_command(argc)) // continue as usual and scan for normal commands
 514         {
 515                 return; // handled by one of the above LocalCommand_* functions
 516         }
 517
 518         // nothing above caught the command, must be invalid
 519         print(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 520
 521         return;
 522 }
 523
 524
 525 // ===================================
 526 //  Macro system for console commands
 527 // ===================================
 528
 529 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 530 // Please add client commands to the function above this, as this is only for special reasons.
 531 #define CONSOLE_COMMANDS_NORMAL() \
 532         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 533         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 534         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 535         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 536         /* nothing */
 537
 538 #define CONSOLE_COMMANDS_MOVEMENT() \
 539         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 540         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 541         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 542         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 543         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 544         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 545         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 546         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 547         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 548         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 549         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 550         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 551         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 552         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 553         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 554         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 555         /* nothing */
 556
 557 void ConsoleCommand_macro_init()
 558 {
 559         // first init normal commands
 560         #define CONSOLE_COMMAND(name,execution) \
 561                 { registercommand(name); }
 562
 563         CONSOLE_COMMANDS_NORMAL();
 564         #undef CONSOLE_COMMAND
 565
 566         // then init movement commands
 567         #ifndef CAMERATEST
 568         if(isdemo())
 569         {
 570         #endif
 571                 #define CONSOLE_COMMAND(name,execution) \
 572                         { registercommand(name); }
 573
 574                 CONSOLE_COMMANDS_MOVEMENT();
 575                 #undef CONSOLE_COMMAND
 576         #ifndef CAMERATEST
 577         }
 578         #endif
 579
 580         return;
 581 }
 582
 583 bool ConsoleCommand_macro_normal(int argc)
 584 {
 585         #define CONSOLE_COMMAND(name,execution) \
 586                 { if(name == strtolower(argv(0))) { { execution } return true; } }
 587
 588         CONSOLE_COMMANDS_NORMAL();
 589         #undef CONSOLE_COMMAND
 590
 591         return false;
 592 }
 593
 594 bool ConsoleCommand_macro_movement(int argc)
 595 {
 596         if(camera_active)
 597         {
 598                 #define CONSOLE_COMMAND(name,execution) \
 599                         { if(name == strtolower(argv(0))) { { execution } return true; } }
 600
 601                 CONSOLE_COMMANDS_MOVEMENT();
 602                 #undef CONSOLE_COMMAND
 603         }
 604
 605         return false;
 606 }
 607
 608
 609 // ======================================================
 610 //  Main Function Called By Engine (registered commands)
 611 // ======================================================
 612 // Used to parse commands in the console that have been registered with the "registercommand" function
 613
 614 bool CSQC_ConsoleCommand(string command)
 615 {
 616         int argc = tokenize_console(command);
 617
 618         if(ConsoleCommand_macro_normal(argc))
 619         {
 620                 return true;
 621         }
 622         else if(ConsoleCommand_macro_movement(argc))
 623         {
 624                 return true;
 625         }
 626
 627         // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 628
 629         return false;
 630 }