qcsrc/client/commands/cl_cmd.qc

   1 #include "cl_cmd.qh"
   2 // ==============================================
   3 //  CSQC client commands code, written by Samual
   4 //  Last updated: December 28th, 2011
   5 // ==============================================
   6
   7 #include <common/command/command.qh>
   8 #include "cl_cmd.qh"
   9
  10 #include "../autocvars.qh"
  11 #include "../defs.qh"
  12 #include <client/hud/all.qh>
  13 #include "../main.qh"
  14 #include "../mapvoting.qh"
  15 #include "../miscfunctions.qh"
  16
  17 #include "../mutators/events.qh"
  18
  19 #include <common/mapinfo.qh>
  20
  21 #include <common/command/generic.qh>
  22
  23 void DrawDebugModel(entity this)
  24 {
  25         if (time - floor(time) > 0.5)
  26         {
  27                 PolyDrawModel(this);
  28                 this.drawmask = 0;
  29         }
  30         else
  31         {
  32                 this.renderflags = 0;
  33                 this.drawmask = MASK_NORMAL;
  34         }
  35 }
  36
  37
  38 // =======================
  39 //  Command Sub-Functions
  40 // =======================
  41
  42 void LocalCommand_blurtest(int request)
  43 {
  44     TC(int, request);
  45         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  46         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  47
  48         #ifdef BLURTEST
  49         switch (request)
  50         {
  51                 case CMD_REQUEST_COMMAND:
  52                 {
  53                         blurtest_time0 = time;
  54                         blurtest_time1 = time + stof(argv(1));
  55                         blurtest_radius = stof(argv(2));
  56                         blurtest_power = stof(argv(3));
  57                         LOG_INFO("Enabled blurtest\n");
  58                         return;
  59                 }
  60
  61                 default:
  62                 case CMD_REQUEST_USAGE:
  63                 {
  64                         LOG_INFO("\nUsage:^3 cl_cmd blurtest\n");
  65                         LOG_INFO("  No arguments required.\n");
  66                         return;
  67                 }
  68         }
  69         #else
  70         if (request)
  71         {
  72                 LOG_INFO("Blurtest is not enabled on this client.\n");
  73                 return;
  74         }
  75         #endif
  76 }
  77
  78 void LocalCommand_boxparticles(int request, int argc)
  79 {
  80     TC(int, request); TC(int, argc);
  81         switch (request)
  82         {
  83                 case CMD_REQUEST_COMMAND:
  84                 {
  85                         if (argc == 9)
  86                         {
  87                                 int effect = _particleeffectnum(argv(1));
  88                                 if (effect >= 0)
  89                                 {
  90                                         int index = stoi(argv(2));
  91                                         entity own;
  92                                         if (index <= 0)
  93                                                 own = entitybyindex(-index);
  94                                         else
  95                                                 own = findfloat(world, entnum, index);
  96                                         vector org_from = stov(argv(3));
  97                                         vector org_to = stov(argv(4));
  98                                         vector dir_from = stov(argv(5));
  99                                         vector dir_to = stov(argv(6));
 100                                         int countmultiplier = stoi(argv(7));
 101                                         int flags = stoi(argv(8));
 102                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
 103                                         return;
 104                                 }
 105                         }
 106                 }
 107
 108                 default:
 109                 {
 110                         LOG_INFO("Incorrect parameters for ^2boxparticles^7\n");
 111                 }
 112                 case CMD_REQUEST_USAGE:
 113                 {
 114                         LOG_INFO("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
 115                         LOG_INFO("  'effectname' is the name of a particle effect in effectinfo.txt\n");
 116                         LOG_INFO("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
 117                         LOG_INFO("  'org_from' is the starting origin of the box\n");
 118                         LOG_INFO("  'org_to' is the ending origin of the box\n");
 119                         LOG_INFO("  'dir_from' is the minimum velocity\n");
 120                         LOG_INFO("  'dir_to' is the maximum velocity\n");
 121                         LOG_INFO("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 122                         LOG_INFO("  'flags' can contain:\n");
 123                         LOG_INFO("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 124                         LOG_INFO("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 125                         LOG_INFO("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 126                         LOG_INFO("    128 to draw a trail, not a box\n");
 127                         return;
 128                 }
 129         }
 130 }
 131
 132 void LocalCommand_create_scrshot_ent(int request)
 133 {
 134     TC(int, request);
 135         switch (request)
 136         {
 137                 case CMD_REQUEST_COMMAND:
 138                 {
 139                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 140                         int fh = fopen(filename, FILE_WRITE);
 141
 142                         if (fh >= 0)
 143                         {
 144                                 fputs(fh, "{\n");
 145                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 146                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 147                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 148                                 fputs(fh, "}\n");
 149
 150                                 LOG_INFO("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 151
 152                                 fclose(fh);
 153                         }
 154                         else
 155                         {
 156                                 LOG_INFO("^1Error: ^7Could not dump to file!\n");
 157                         }
 158                         return;
 159                 }
 160
 161                 default:
 162                 case CMD_REQUEST_USAGE:
 163                 {
 164                         LOG_INFO("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 165                         LOG_INFO("  No arguments required.\n");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void LocalCommand_debugmodel(int request, int argc)
 172 {
 173     TC(int, request); TC(int, argc);
 174         switch (request)
 175         {
 176                 case CMD_REQUEST_COMMAND:
 177                 {
 178                         string modelname = argv(1);
 179
 180                         entity debugmodel_entity = new(debugmodel);
 181                         precache_model(modelname);
 182                         _setmodel(debugmodel_entity, modelname);
 183                         setorigin(debugmodel_entity, view_origin);
 184                         debugmodel_entity.angles = view_angles;
 185                         debugmodel_entity.draw = DrawDebugModel;
 186
 187                         return;
 188                 }
 189
 190                 default:
 191                 case CMD_REQUEST_USAGE:
 192                 {
 193                         LOG_INFO("\nUsage:^3 cl_cmd debugmodel model\n");
 194                         LOG_INFO("  Where 'model' is a string of the model name to use for the debug model.\n");
 195                         return;
 196                 }
 197         }
 198 }
 199
 200 void LocalCommand_handlevote(int request, int argc)
 201 {
 202     TC(int, request); TC(int, argc);
 203         switch (request)
 204         {
 205                 case CMD_REQUEST_COMMAND:
 206                 {
 207                         int vote_selection;
 208                         string vote_string;
 209
 210                         if (InterpretBoolean(argv(1)))
 211                         {
 212                                 vote_selection = 2;
 213                                 vote_string = "yes";
 214                         }
 215                         else
 216                         {
 217                                 vote_selection = 1;
 218                                 vote_string = "no";
 219                         }
 220
 221                         if (vote_selection)
 222                         {
 223                                 if (uid2name_dialog)  // handled by "uid2name" option
 224                                 {
 225                                         vote_active = 0;
 226                                         vote_prev = 0;
 227                                         vote_change = -9999;
 228                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 229                                         uid2name_dialog = 0;
 230                                 }
 231                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 232
 233                                 return;
 234                         }
 235                 }
 236
 237                 default:
 238                 {
 239                         LOG_INFO("Incorrect parameters for ^2handlevote^7\n");
 240                 }
 241                 case CMD_REQUEST_USAGE:
 242                 {
 243                         LOG_INFO("\nUsage:^3 cl_cmd handlevote vote\n");
 244                         LOG_INFO("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 245                         return;
 246                 }
 247         }
 248 }
 249
 250 bool QuickMenu_IsOpened();
 251 void QuickMenu_Close();
 252 bool QuickMenu_Open(string mode, string submenu);
 253
 254 bool HUD_MinigameMenu_IsOpened();
 255 void HUD_MinigameMenu_Close();
 256 void HUD_MinigameMenu_Open();
 257
 258 void HUD_Radar_Show_Maximized(bool doshow, bool clickable);
 259
 260 void LocalCommand_hud(int request, int argc)
 261 {
 262     TC(int, request); TC(int, argc);
 263         switch (request)
 264         {
 265                 case CMD_REQUEST_COMMAND:
 266                 {
 267                         if(MUTATOR_CALLHOOK(HUD_Command, argc))
 268                                 return;
 269
 270                         switch (argv(1))
 271                         {
 272                                 case "configure":
 273                                 {
 274                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 275                                         return;
 276                                 }
 277
 278                                 case "quickmenu":
 279                                 {
 280                                         if (argv(2) == "help")
 281                                         {
 282                                                 LOG_INFO(" quickmenu [[default | file | \"\"] submenu]\n");
 283                                                 LOG_INFO("Called without options (or with \"\") loads either the default quickmenu or a quickmenu file if hud_panel_quickmenu_file is set to a valid filename.\n");
 284                                                 LOG_INFO("A submenu name can be given to open the quickmenu directly in a submenu; it requires to specify 'default', 'file' or '\"\"' option.\n");
 285                                                 return;
 286                                         }
 287                                         if (QuickMenu_IsOpened())
 288                                                 QuickMenu_Close();
 289                                         else
 290                                                 QuickMenu_Open(argv(2), argv(3));  // mode, submenu
 291                                         return;
 292                                 }
 293
 294                                 case "save":
 295                                 {
 296                                         if (argv(2))
 297                                         {
 298                                                 HUD_Panel_ExportCfg(argv(2));
 299                                                 return;
 300                                         }
 301                                         else
 302                                         {
 303                                                 break;  // go to usage, we're missing the paramater needed here.
 304                                         }
 305                                 }
 306
 307                                 case "scoreboard_columns_set":
 308                                 {
 309                                         Cmd_HUD_SetFields(argc);
 310                                         return;
 311                                 }
 312
 313                                 case "scoreboard_columns_help":
 314                                 {
 315                                         Cmd_HUD_Help();
 316                                         return;
 317                                 }
 318
 319                                 case "radar":
 320                                 {
 321                                         if (argv(2))
 322                                                 HUD_Radar_Show_Maximized(InterpretBoolean(argv(2)), 0);
 323                                         else
 324                                                 HUD_Radar_Show_Maximized(!hud_panel_radar_maximized, 0);
 325                                         return;
 326                                 }
 327
 328                                 case "clickradar":
 329                                 {
 330                                         HUD_Radar_Show_Maximized(!hud_panel_radar_mouse, 1);
 331                                         return;
 332                                 }
 333                         }
 334                 }
 335
 336                 default:
 337                 {
 338                         LOG_INFO("Incorrect parameters for ^2hud^7\n");
 339                 }
 340                 case CMD_REQUEST_USAGE:
 341                 {
 342                         LOG_INFO("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 343                         LOG_INFO("  Where 'action' is the command to complete,\n");
 344                         LOG_INFO("  'configname' is the name to save to for \"save\" action,\n");
 345                         LOG_INFO("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 346                         LOG_INFO("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 347                         LOG_INFO("  Full list of commands here: \"configure, quickmenu, minigame, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 348                         return;
 349                 }
 350         }
 351 }
 352
 353 void LocalCommand_localprint(int request, int argc)
 354 {
 355     TC(int, request); TC(int, argc);
 356         switch (request)
 357         {
 358                 case CMD_REQUEST_COMMAND:
 359                 {
 360                         if (argv(1))
 361                         {
 362                                 centerprint_hud(argv(1));
 363                                 return;
 364                         }
 365                 }
 366
 367                 default:
 368                 {
 369                         LOG_INFO("Incorrect parameters for ^2localprint^7\n");
 370                 }
 371                 case CMD_REQUEST_USAGE:
 372                 {
 373                         LOG_INFO("\nUsage:^3 cl_cmd localprint \"message\"\n");
 374                         LOG_INFO("  'message' is the centerprint message to send to yourself.\n");
 375                         return;
 376                 }
 377         }
 378 }
 379
 380 void LocalCommand_mv_download(int request, int argc)
 381 {
 382     TC(int, request); TC(int, argc);
 383         switch (request)
 384         {
 385                 case CMD_REQUEST_COMMAND:
 386                 {
 387                         if (argv(1))
 388                         {
 389                                 Cmd_MapVote_MapDownload(argc);
 390                                 return;
 391                         }
 392                 }
 393
 394                 default:
 395                 {
 396                         LOG_INFO("Incorrect parameters for ^2mv_download^7\n");
 397                 }
 398                 case CMD_REQUEST_USAGE:
 399                 {
 400                         LOG_INFO("\nUsage:^3 cl_cmd mv_download mapid\n");
 401                         LOG_INFO("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 402                         return;
 403                 }
 404         }
 405 }
 406
 407 void LocalCommand_sendcvar(int request, int argc)
 408 {
 409     TC(int, request); TC(int, argc);
 410         switch (request)
 411         {
 412                 case CMD_REQUEST_COMMAND:
 413                 {
 414                         if (argv(1))
 415                         {
 416                                 // W_FixWeaponOrder will trash argv, so save what we need.
 417                                 string thiscvar = strzone(argv(1));
 418                                 string s = cvar_string(thiscvar);
 419
 420                                 if (thiscvar == "cl_weaponpriority")
 421                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 422                                 else if (substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 423                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 424
 425                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 426                                 strunzone(thiscvar);
 427                                 return;
 428                         }
 429                 }
 430
 431                 default:
 432                 {
 433                         LOG_INFO("Incorrect parameters for ^2sendcvar^7\n");
 434                 }
 435                 case CMD_REQUEST_USAGE:
 436                 {
 437                         LOG_INFO("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 438                         LOG_INFO("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 439                         return;
 440                 }
 441         }
 442 }
 443
 444 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 445 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 446 void LocalCommand_(int request)
 447 {
 448     switch(request)
 449     {
 450         case CMD_REQUEST_COMMAND:
 451         {
 452
 453             return;
 454         }
 455
 456         default:
 457         case CMD_REQUEST_USAGE:
 458         {
 459             print("\nUsage:^3 cl_cmd \n");
 460             print("  No arguments required.\n");
 461             return;
 462         }
 463     }
 464 }
 465 */
 466
 467
 468 // ==================================
 469 //  Macro system for client commands
 470 // ==================================
 471
 472 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 473 CLIENT_COMMAND(blurtest, "Feature for testing blur postprocessing") { LocalCommand_blurtest(request); }
 474 CLIENT_COMMAND(boxparticles, "Spawn particles manually") { LocalCommand_boxparticles(request, arguments); }
 475 CLIENT_COMMAND(create_scrshot_ent, "Create an entity at this location for automatic screenshots") { LocalCommand_create_scrshot_ent(request); }
 476 CLIENT_COMMAND(debugmodel, "Spawn a debug model manually") { LocalCommand_debugmodel(request, arguments); }
 477 CLIENT_COMMAND(handlevote, "System to handle selecting a vote or option") { LocalCommand_handlevote(request, arguments); }
 478 CLIENT_COMMAND(hud, "Commands regarding/controlling the HUD system") { LocalCommand_hud(request, arguments); }
 479 CLIENT_COMMAND(localprint, "Create your own centerprint sent to yourself") { LocalCommand_localprint(request, arguments); }
 480 CLIENT_COMMAND(mv_download, "Retrieve mapshot picture from the server") { LocalCommand_mv_download(request, arguments); }
 481 CLIENT_COMMAND(sendcvar, "Send a cvar to the server (like weaponpriority)") { LocalCommand_sendcvar(request, arguments); }
 482
 483 void LocalCommand_macro_help()
 484 {
 485         FOREACH(CLIENT_COMMANDS, true, LOG_INFOF("  ^2%s^7: %s\n", it.m_name, it.m_description));
 486 }
 487
 488 bool LocalCommand_macro_command(int argc, string command)
 489 {
 490         string c = strtolower(argv(0));
 491         FOREACH(CLIENT_COMMANDS, it.m_name == c, {
 492                 it.m_invokecmd(CMD_REQUEST_COMMAND, NULL, argc, command);
 493                 return true;
 494         });
 495         return false;
 496 }
 497
 498 bool LocalCommand_macro_usage(int argc)
 499 {
 500         string c = strtolower(argv(1));
 501         FOREACH(CLIENT_COMMANDS, it.m_name == c, {
 502                 it.m_invokecmd(CMD_REQUEST_USAGE, NULL, argc, "");
 503                 return true;
 504         });
 505         return false;
 506 }
 507
 508 void LocalCommand_macro_write_aliases(int fh)
 509 {
 510         FOREACH(CLIENT_COMMANDS, true, CMD_Write_Alias("qc_cmd_cl", it.m_name, it.m_description));
 511 }
 512
 513
 514 // =========================================
 515 //  Main Function Called By Engine (cl_cmd)
 516 // =========================================
 517 // If this function exists, client code handles gamecommand instead of the engine code.
 518
 519 void GameCommand(string command)
 520 {
 521         int argc = tokenize_console(command);
 522
 523         // Guide for working with argc arguments by example:
 524         // argc:   1    - 2      - 3     - 4
 525         // argv:   0    - 1      - 2     - 3
 526         // cmd     vote - master - login - password
 527         string s = strtolower(argv(0));
 528         if (s == "help")
 529         {
 530                 if (argc == 1)
 531                 {
 532                         LOG_INFO("\nClient console commands:\n");
 533                         LocalCommand_macro_help();
 534
 535                         LOG_INFO("\nGeneric commands shared by all programs:\n");
 536                         GenericCommand_macro_help();
 537
 538                         LOG_INFO("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 539                         LOG_INFO("For help about a specific command, type cl_cmd help COMMAND\n");
 540
 541                         return;
 542                 }
 543                 else if (GenericCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
 544                 {
 545                         return;
 546                 }
 547                 else if (LocalCommand_macro_usage(argc))  // now try for normal commands too
 548                 {
 549                         return;
 550                 }
 551         }
 552         // continue as usual and scan for normal commands
 553         if (GenericCommand(command)                                    // handled by common/command/generic.qc
 554             || LocalCommand_macro_command(argc, command)               // handled by one of the above LocalCommand_* functions
 555             || MUTATOR_CALLHOOK(CSQC_ConsoleCommand, s, argc, command) // handled by a mutator
 556            ) return;
 557
 558         // nothing above caught the command, must be invalid
 559         LOG_INFO(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 560 }
 561
 562
 563 // ===================================
 564 //  Macro system for console commands
 565 // ===================================
 566
 567 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 568 // Please add client commands to the function above this, as this is only for special reasons.
 569 #define CONSOLE_COMMANDS_NORMAL() \
 570         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 571         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 572         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 573         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 574         /* nothing */
 575
 576 #define CONSOLE_COMMANDS_MOVEMENT() \
 577         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 578         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 579         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 580         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 581         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 582         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 583         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 584         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 585         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 586         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 587         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 588         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 589         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 590         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 591         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 592         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 593         /* nothing */
 594
 595 void ConsoleCommand_macro_init()
 596 {
 597         // first init normal commands
 598         #define CONSOLE_COMMAND(name, execution) \
 599                 { registercommand(name); }
 600
 601         CONSOLE_COMMANDS_NORMAL();
 602         #undef CONSOLE_COMMAND
 603
 604         // then init movement commands
 605         #ifndef CAMERATEST
 606         if (isdemo())
 607         {
 608         #endif
 609         #define CONSOLE_COMMAND(name, execution) \
 610                 registercommand(name);
 611
 612         CONSOLE_COMMANDS_MOVEMENT();
 613                 #undef CONSOLE_COMMAND
 614         #ifndef CAMERATEST
 615 }
 616         #endif
 617 }
 618
 619 bool ConsoleCommand_macro_normal(string s, int argc)
 620 {
 621         #define CONSOLE_COMMAND(name, execution) \
 622                 { if (name == s) { { execution } return true; } }
 623
 624         CONSOLE_COMMANDS_NORMAL();
 625         #undef CONSOLE_COMMAND
 626
 627         return false;
 628 }
 629
 630 bool ConsoleCommand_macro_movement(string s, int argc)
 631 {
 632         if (camera_active)
 633         {
 634                 #define CONSOLE_COMMAND(name, execution) \
 635                         { if (name == s) { { execution } return true; } }
 636
 637                 CONSOLE_COMMANDS_MOVEMENT();
 638                 #undef CONSOLE_COMMAND
 639         }
 640
 641         return false;
 642 }
 643
 644
 645 // ======================================================
 646 //  Main Function Called By Engine (registered commands)
 647 // ======================================================
 648 // Used to parse commands in the console that have been registered with the "registercommand" function
 649
 650 bool CSQC_ConsoleCommand(string command)
 651 {
 652         int argc = tokenize_console(command);
 653         string s = strtolower(argv(0));
 654         // Return value should be true if CSQC handled the command, otherwise return false to have the engine handle it.
 655         return ConsoleCommand_macro_normal(s, argc)
 656                || ConsoleCommand_macro_movement(s, argc)
 657         ;
 658 }