qcsrc/client/commands/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/command.qh"
   7 #include "cl_cmd.qh"
   8
   9 #include "../autocvars.qh"
  10 #include "../defs.qh"
  11 #include "../hud.qh"
  12 #include "../hud_config.qh"
  13 #include "../main.qh"
  14 #include "../mapvoting.qh"
  15 #include "../miscfunctions.qh"
  16
  17 #include "../mutators/events.qh"
  18
  19 #include "../../common/mapinfo.qh"
  20
  21 #include "../../common/command/generic.qh"
  22
  23 void DrawDebugModel(entity this)
  24 {
  25         if (time - floor(time) > 0.5)
  26         {
  27                 PolyDrawModel(self);
  28                 self.drawmask = 0;
  29         }
  30         else
  31         {
  32                 self.renderflags = 0;
  33                 self.drawmask = MASK_NORMAL;
  34         }
  35 }
  36
  37
  38 // =======================
  39 //  Command Sub-Functions
  40 // =======================
  41
  42 void LocalCommand_blurtest(int request)
  43 {
  44         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  45         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  46
  47         #ifdef BLURTEST
  48         switch (request)
  49         {
  50                 case CMD_REQUEST_COMMAND:
  51                 {
  52                         blurtest_time0 = time;
  53                         blurtest_time1 = time + stof(argv(1));
  54                         blurtest_radius = stof(argv(2));
  55                         blurtest_power = stof(argv(3));
  56                         LOG_INFO("Enabled blurtest\n");
  57                         return;
  58                 }
  59
  60                 default:
  61                 case CMD_REQUEST_USAGE:
  62                 {
  63                         LOG_INFO("\nUsage:^3 cl_cmd blurtest\n");
  64                         LOG_INFO("  No arguments required.\n");
  65                         return;
  66                 }
  67         }
  68         #else
  69         if (request)
  70         {
  71                 LOG_INFO("Blurtest is not enabled on this client.\n");
  72                 return;
  73         }
  74         #endif
  75 }
  76
  77 void LocalCommand_boxparticles(int request, int argc)
  78 {
  79         switch (request)
  80         {
  81                 case CMD_REQUEST_COMMAND:
  82                 {
  83                         if (argc == 9)
  84                         {
  85                                 int effect = _particleeffectnum(argv(1));
  86                                 if (effect >= 0)
  87                                 {
  88                                         int index = stoi(argv(2));
  89                                         entity own;
  90                                         if (index <= 0)
  91                                                 own = entitybyindex(-index);
  92                                         else
  93                                                 own = findfloat(world, entnum, index);
  94                                         vector org_from = stov(argv(3));
  95                                         vector org_to = stov(argv(4));
  96                                         vector dir_from = stov(argv(5));
  97                                         vector dir_to = stov(argv(6));
  98                                         int countmultiplier = stoi(argv(7));
  99                                         int flags = stoi(argv(8));
 100                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
 101                                         return;
 102                                 }
 103                         }
 104                 }
 105
 106                 default:
 107                 {
 108                         LOG_INFO("Incorrect parameters for ^2boxparticles^7\n");
 109                 }
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         LOG_INFO("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
 113                         LOG_INFO("  'effectname' is the name of a particle effect in effectinfo.txt\n");
 114                         LOG_INFO("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
 115                         LOG_INFO("  'org_from' is the starting origin of the box\n");
 116                         LOG_INFO("  'org_to' is the ending origin of the box\n");
 117                         LOG_INFO("  'dir_from' is the minimum velocity\n");
 118                         LOG_INFO("  'dir_to' is the maximum velocity\n");
 119                         LOG_INFO("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 120                         LOG_INFO("  'flags' can contain:\n");
 121                         LOG_INFO("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 122                         LOG_INFO("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 123                         LOG_INFO("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 124                         LOG_INFO("    128 to draw a trail, not a box\n");
 125                         return;
 126                 }
 127         }
 128 }
 129
 130 void LocalCommand_create_scrshot_ent(int request)
 131 {
 132         switch (request)
 133         {
 134                 case CMD_REQUEST_COMMAND:
 135                 {
 136                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 137                         int fh = fopen(filename, FILE_WRITE);
 138
 139                         if (fh >= 0)
 140                         {
 141                                 fputs(fh, "{\n");
 142                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 143                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 144                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 145                                 fputs(fh, "}\n");
 146
 147                                 LOG_INFO("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 148
 149                                 fclose(fh);
 150                         }
 151                         else
 152                         {
 153                                 LOG_INFO("^1Error: ^7Could not dump to file!\n");
 154                         }
 155                         return;
 156                 }
 157
 158                 default:
 159                 case CMD_REQUEST_USAGE:
 160                 {
 161                         LOG_INFO("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 162                         LOG_INFO("  No arguments required.\n");
 163                         return;
 164                 }
 165         }
 166 }
 167
 168 void LocalCommand_debugmodel(int request, int argc)
 169 {
 170         switch (request)
 171         {
 172                 case CMD_REQUEST_COMMAND:
 173                 {
 174                         string modelname = argv(1);
 175                         entity debugmodel_entity;
 176
 177                         debugmodel_entity = spawn();
 178                         precache_model(modelname);
 179                         _setmodel(debugmodel_entity, modelname);
 180                         setorigin(debugmodel_entity, view_origin);
 181                         debugmodel_entity.angles = view_angles;
 182                         debugmodel_entity.draw = DrawDebugModel;
 183                         debugmodel_entity.classname = "debugmodel";
 184
 185                         return;
 186                 }
 187
 188                 default:
 189                 case CMD_REQUEST_USAGE:
 190                 {
 191                         LOG_INFO("\nUsage:^3 cl_cmd debugmodel model\n");
 192                         LOG_INFO("  Where 'model' is a string of the model name to use for the debug model.\n");
 193                         return;
 194                 }
 195         }
 196 }
 197
 198 void LocalCommand_handlevote(int request, int argc)
 199 {
 200         switch (request)
 201         {
 202                 case CMD_REQUEST_COMMAND:
 203                 {
 204                         int vote_selection;
 205                         string vote_string;
 206
 207                         if (InterpretBoolean(argv(1)))
 208                         {
 209                                 vote_selection = 2;
 210                                 vote_string = "yes";
 211                         }
 212                         else
 213                         {
 214                                 vote_selection = 1;
 215                                 vote_string = "no";
 216                         }
 217
 218                         if (vote_selection)
 219                         {
 220                                 if (uid2name_dialog)  // handled by "uid2name" option
 221                                 {
 222                                         vote_active = 0;
 223                                         vote_prev = 0;
 224                                         vote_change = -9999;
 225                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 226                                         uid2name_dialog = 0;
 227                                 }
 228                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 229
 230                                 return;
 231                         }
 232                 }
 233
 234                 default:
 235                 {
 236                         LOG_INFO("Incorrect parameters for ^2handlevote^7\n");
 237                 }
 238                 case CMD_REQUEST_USAGE:
 239                 {
 240                         LOG_INFO("\nUsage:^3 cl_cmd handlevote vote\n");
 241                         LOG_INFO("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 242                         return;
 243                 }
 244         }
 245 }
 246
 247 bool QuickMenu_IsOpened();
 248 void QuickMenu_Close();
 249 bool QuickMenu_Open(string mode, string submenu);
 250
 251 bool HUD_MinigameMenu_IsOpened();
 252 void HUD_MinigameMenu_Close();
 253 void HUD_MinigameMenu_Open();
 254
 255 void HUD_Radar_Show_Maximized(bool doshow, bool clickable);
 256
 257 void LocalCommand_hud(int request, int argc)
 258 {
 259         switch (request)
 260         {
 261                 case CMD_REQUEST_COMMAND:
 262                 {
 263                         switch (argv(1))
 264                         {
 265                                 case "configure":
 266                                 {
 267                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 268                                         return;
 269                                 }
 270
 271                                 case "quickmenu":
 272                                 {
 273                                         if (QuickMenu_IsOpened())
 274                                                 QuickMenu_Close();
 275                                         else
 276                                                 QuickMenu_Open(argv(2), argv(3));  // mode, submenu
 277                                         return;
 278                                 }
 279
 280                                 case "minigame":
 281                                 {
 282                                         if (HUD_MinigameMenu_IsOpened())
 283                                                 HUD_MinigameMenu_Close();
 284                                         else
 285                                                 HUD_MinigameMenu_Open();
 286                                         return;
 287                                 }
 288
 289                                 case "save":
 290                                 {
 291                                         if (argv(2))
 292                                         {
 293                                                 HUD_Panel_ExportCfg(argv(2));
 294                                                 return;
 295                                         }
 296                                         else
 297                                         {
 298                                                 break;  // go to usage, we're missing the paramater needed here.
 299                                         }
 300                                 }
 301
 302                                 case "scoreboard_columns_set":
 303                                 {
 304                                         Cmd_HUD_SetFields(argc);
 305                                         return;
 306                                 }
 307
 308                                 case "scoreboard_columns_help":
 309                                 {
 310                                         Cmd_HUD_Help();
 311                                         return;
 312                                 }
 313
 314                                 case "radar":
 315                                 {
 316                                         if (argv(2))
 317                                                 HUD_Radar_Show_Maximized(InterpretBoolean(argv(2)), 0);
 318                                         else
 319                                                 HUD_Radar_Show_Maximized(!hud_panel_radar_maximized, 0);
 320                                         return;
 321                                 }
 322
 323                                 case "clickradar":
 324                                 {
 325                                         HUD_Radar_Show_Maximized(!hud_panel_radar_mouse, 1);
 326                                         return;
 327                                 }
 328                         }
 329                 }
 330
 331                 default:
 332                 {
 333                         LOG_INFO("Incorrect parameters for ^2hud^7\n");
 334                 }
 335                 case CMD_REQUEST_USAGE:
 336                 {
 337                         LOG_INFO("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 338                         LOG_INFO("  Where 'action' is the command to complete,\n");
 339                         LOG_INFO("  'configname' is the name to save to for \"save\" action,\n");
 340                         LOG_INFO("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 341                         LOG_INFO("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 342                         LOG_INFO("  quickmenu [[default | file | \"\"] submenu]\n");
 343                         LOG_INFO("    Called without options (or with " ") loads either the default quickmenu or a quickmenu file if hud_panel_quickmenu_file is set to a valid filename.\n");
 344                         LOG_INFO("    Submenu option allows to open quickmenu directly in a submenu, it requires to specify 'default', 'file' or '\"\"' option.\n");
 345                         LOG_INFO("  Full list of commands here: \"configure, minigame, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 346                         return;
 347                 }
 348         }
 349 }
 350
 351 void LocalCommand_localprint(int request, int argc)
 352 {
 353         switch (request)
 354         {
 355                 case CMD_REQUEST_COMMAND:
 356                 {
 357                         if (argv(1))
 358                         {
 359                                 centerprint_hud(argv(1));
 360                                 return;
 361                         }
 362                 }
 363
 364                 default:
 365                 {
 366                         LOG_INFO("Incorrect parameters for ^2localprint^7\n");
 367                 }
 368                 case CMD_REQUEST_USAGE:
 369                 {
 370                         LOG_INFO("\nUsage:^3 cl_cmd localprint \"message\"\n");
 371                         LOG_INFO("  'message' is the centerprint message to send to yourself.\n");
 372                         return;
 373                 }
 374         }
 375 }
 376
 377 void LocalCommand_mv_download(int request, int argc)
 378 {
 379         switch (request)
 380         {
 381                 case CMD_REQUEST_COMMAND:
 382                 {
 383                         if (argv(1))
 384                         {
 385                                 Cmd_MapVote_MapDownload(argc);
 386                                 return;
 387                         }
 388                 }
 389
 390                 default:
 391                 {
 392                         LOG_INFO("Incorrect parameters for ^2mv_download^7\n");
 393                 }
 394                 case CMD_REQUEST_USAGE:
 395                 {
 396                         LOG_INFO("\nUsage:^3 cl_cmd mv_download mapid\n");
 397                         LOG_INFO("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 398                         return;
 399                 }
 400         }
 401 }
 402
 403 void LocalCommand_find(int request, int argc)
 404 {
 405         switch (request)
 406         {
 407                 case CMD_REQUEST_COMMAND:
 408                 {
 409                         entity client;
 410
 411                         for (client = world; (client = find(client, classname, argv(1))); )
 412                                 LOG_INFO(etos(client), "\n");
 413
 414                         return;
 415                 }
 416
 417                 default:
 418                 {
 419                         LOG_INFO("Incorrect parameters for ^2find^7\n");
 420                 }
 421                 case CMD_REQUEST_USAGE:
 422                 {
 423                         LOG_INFO("\nUsage:^3 cl_cmd find classname\n");
 424                         LOG_INFO("  Where 'classname' is the classname to search for.\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 void LocalCommand_sendcvar(int request, int argc)
 431 {
 432         switch (request)
 433         {
 434                 case CMD_REQUEST_COMMAND:
 435                 {
 436                         if (argv(1))
 437                         {
 438                                 // W_FixWeaponOrder will trash argv, so save what we need.
 439                                 string thiscvar = strzone(argv(1));
 440                                 string s = cvar_string(thiscvar);
 441
 442                                 if (thiscvar == "cl_weaponpriority")
 443                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 444                                 else if (substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 445                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 446
 447                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 448                                 strunzone(thiscvar);
 449                                 return;
 450                         }
 451                 }
 452
 453                 default:
 454                 {
 455                         LOG_INFO("Incorrect parameters for ^2sendcvar^7\n");
 456                 }
 457                 case CMD_REQUEST_USAGE:
 458                 {
 459                         LOG_INFO("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 460                         LOG_INFO("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 461                         return;
 462                 }
 463         }
 464 }
 465
 466 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 467 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 468 void LocalCommand_(int request)
 469 {
 470     switch(request)
 471     {
 472         case CMD_REQUEST_COMMAND:
 473         {
 474
 475             return;
 476         }
 477
 478         default:
 479         case CMD_REQUEST_USAGE:
 480         {
 481             print("\nUsage:^3 cl_cmd \n");
 482             print("  No arguments required.\n");
 483             return;
 484         }
 485     }
 486 }
 487 */
 488
 489
 490 // ==================================
 491 //  Macro system for client commands
 492 // ==================================
 493
 494 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 495 #define CLIENT_COMMANDS(request, arguments) \
 496         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 497         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 498         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 499         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 500         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 501         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 502         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 503         CLIENT_COMMAND("find", LocalCommand_find(request, arguments), "Search through entities for matching classname") \
 504         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 505         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 506         /* nothing */
 507
 508 void LocalCommand_macro_help()
 509 {
 510         #define CLIENT_COMMAND(name, function, description) \
 511                 { if (strtolower(description) != "") { LOG_INFO("  ^2", name, "^7: ", description, "\n"); } }
 512
 513         CLIENT_COMMANDS(0, 0);
 514         #undef CLIENT_COMMAND
 515 }
 516
 517 bool LocalCommand_macro_command(int argc)
 518 {
 519         #define CLIENT_COMMAND(name, function, description) \
 520                 { if (name == strtolower(argv(0))) { function; return true; } }
 521
 522         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc);
 523         #undef CLIENT_COMMAND
 524
 525         return false;
 526 }
 527
 528 bool LocalCommand_macro_usage(int argc)
 529 {
 530         #define CLIENT_COMMAND(name, function, description) \
 531                 { if (name == strtolower(argv(1))) { function; return true; } }
 532
 533         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc);
 534         #undef CLIENT_COMMAND
 535
 536         return false;
 537 }
 538
 539 void LocalCommand_macro_write_aliases(int fh)
 540 {
 541         #define CLIENT_COMMAND(name, function, description) \
 542                 { if (strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 543
 544         CLIENT_COMMANDS(0, 0);
 545         #undef CLIENT_COMMAND
 546 }
 547
 548
 549 // =========================================
 550 //  Main Function Called By Engine (cl_cmd)
 551 // =========================================
 552 // If this function exists, client code handles gamecommand instead of the engine code.
 553
 554 void GameCommand(string command)
 555 {
 556         int argc = tokenize_console(command);
 557
 558         // Guide for working with argc arguments by example:
 559         // argc:   1    - 2      - 3     - 4
 560         // argv:   0    - 1      - 2     - 3
 561         // cmd     vote - master - login - password
 562         string s = strtolower(argv(0));
 563         if (s == "help")
 564         {
 565                 if (argc == 1)
 566                 {
 567                         LOG_INFO("\nClient console commands:\n");
 568                         LocalCommand_macro_help();
 569
 570                         LOG_INFO("\nGeneric commands shared by all programs:\n");
 571                         GenericCommand_macro_help();
 572
 573                         LOG_INFO("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 574                         LOG_INFO("For help about a specific command, type cl_cmd help COMMAND\n");
 575
 576                         return;
 577                 }
 578                 else if (GenericCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
 579                 {
 580                         return;
 581                 }
 582                 else if (LocalCommand_macro_usage(argc))  // now try for normal commands too
 583                 {
 584                         return;
 585                 }
 586         }
 587         // continue as usual and scan for normal commands
 588         if (GenericCommand(command)                                    // handled by common/command/generic.qc
 589             || LocalCommand_macro_command(argc)                        // handled by one of the above LocalCommand_* functions
 590             || MUTATOR_CALLHOOK(CSQC_ConsoleCommand, s, argc, command) // handled by a mutator
 591            ) return;
 592
 593         // nothing above caught the command, must be invalid
 594         LOG_INFO(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 595 }
 596
 597
 598 // ===================================
 599 //  Macro system for console commands
 600 // ===================================
 601
 602 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 603 // Please add client commands to the function above this, as this is only for special reasons.
 604 #define CONSOLE_COMMANDS_NORMAL() \
 605         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 606         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 607         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 608         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 609         /* nothing */
 610
 611 #define CONSOLE_COMMANDS_MOVEMENT() \
 612         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 613         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 614         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 615         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 616         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 617         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 618         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 619         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 620         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 621         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 622         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 623         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 624         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 625         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 626         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 627         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 628         /* nothing */
 629
 630 void ConsoleCommand_macro_init()
 631 {
 632         // first init normal commands
 633         #define CONSOLE_COMMAND(name, execution) \
 634                 { registercommand(name); }
 635
 636         CONSOLE_COMMANDS_NORMAL();
 637         #undef CONSOLE_COMMAND
 638
 639         // then init movement commands
 640         #ifndef CAMERATEST
 641         if (isdemo())
 642         {
 643         #endif
 644         #define CONSOLE_COMMAND(name, execution) \
 645                 registercommand(name);
 646
 647         CONSOLE_COMMANDS_MOVEMENT();
 648                 #undef CONSOLE_COMMAND
 649         #ifndef CAMERATEST
 650 }
 651         #endif
 652 }
 653
 654 bool ConsoleCommand_macro_normal(string s, int argc)
 655 {
 656         #define CONSOLE_COMMAND(name, execution) \
 657                 { if (name == s) { { execution } return true; } }
 658
 659         CONSOLE_COMMANDS_NORMAL();
 660         #undef CONSOLE_COMMAND
 661
 662         return false;
 663 }
 664
 665 bool ConsoleCommand_macro_movement(string s, int argc)
 666 {
 667         if (camera_active)
 668         {
 669                 #define CONSOLE_COMMAND(name, execution) \
 670                         { if (name == s) { { execution } return true; } }
 671
 672                 CONSOLE_COMMANDS_MOVEMENT();
 673                 #undef CONSOLE_COMMAND
 674         }
 675
 676         return false;
 677 }
 678
 679
 680 // ======================================================
 681 //  Main Function Called By Engine (registered commands)
 682 // ======================================================
 683 // Used to parse commands in the console that have been registered with the "registercommand" function
 684
 685 bool CSQC_ConsoleCommand(string command)
 686 {
 687         int argc = tokenize_console(command);
 688         string s = strtolower(argv(0));
 689         // Return value should be true if CSQC handled the command, otherwise return false to have the engine handle it.
 690         return ConsoleCommand_macro_normal(s, argc)
 691                || ConsoleCommand_macro_movement(s, argc)
 692         ;
 693 }