06f66557a069722a10cc2190f102735df0fb0ebd
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / csqcmodel_hooks.qc
1 #include "csqcmodel_hooks.qh"
2 #include "autocvars.qh"
3 #include "csqcmodel_hooks.qh"
4 #include "miscfunctions.qh"
5 #include <client/mutators/_mod.qh>
6 #include "player_skeleton.qh"
7 #include "weapons/projectile.qh"
8 #include <common/animdecide.qh>
9 #include <common/ent_cs.qh>
10 #include <common/physics/movetypes/movetypes.qh>
11 #include <common/viewloc.qh>
12 #include <common/effects/all.qh>
13 #include <common/effects/all.inc>
14 #include <lib/csqcmodel/cl_model.qh>
15 #include <lib/csqcmodel/cl_player.qh>
16 #include <lib/csqcmodel/interpolate.qh>
17
18 .float death_time;
19 .int modelflags;
20
21 // FEATURE: LOD
22 .int lodmodelindex0;
23 .int lodmodelindex1;
24 .int lodmodelindex2;
25 void CSQCPlayer_LOD_Apply(entity this)
26 {
27         // LOD model loading
28         if(this.lodmodelindex0 != this.modelindex)
29         {
30                 string modelname = this.model;
31                 string s;
32
33                 vector mi = this.mins;
34                 vector ma = this.maxs;
35
36                 // set modelindex
37                 this.lodmodelindex0 = this.modelindex;
38                 this.lodmodelindex1 = this.modelindex;
39                 this.lodmodelindex2 = this.modelindex;
40
41                 // FIXME: this only supports 3-letter extensions
42                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
43                 if(fexists(s))
44                 {
45                         precache_model(s);
46                         _setmodel(this, s);
47                         if(this.modelindex)
48                                 this.lodmodelindex1 = this.modelindex;
49                 }
50
51                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
52                 if(fexists(s))
53                 {
54                         precache_model(s);
55                         _setmodel(this, s);
56                         if(this.modelindex)
57                                 this.lodmodelindex2 = this.modelindex;
58                 }
59
60                 _setmodel(this, modelname); // make everything normal again
61                 setsize(this, mi, ma);
62         }
63
64         // apply LOD
65         if(autocvar_cl_playerdetailreduction <= 0)
66         {
67                 if(autocvar_cl_playerdetailreduction <= -2)
68                         this.modelindex = this.lodmodelindex2;
69                 else if(autocvar_cl_playerdetailreduction <= -1)
70                         this.modelindex = this.lodmodelindex1;
71                 else
72                         this.modelindex = this.lodmodelindex0;
73         }
74         else
75         {
76                 float distance = vlen(this.origin - view_origin);
77                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
78                 f *= 1.0 / bound(0.01, view_quality, 1);
79                 if(f > autocvar_cl_loddistance2)
80                         this.modelindex = this.lodmodelindex2;
81                 else if(f > autocvar_cl_loddistance1)
82                         this.modelindex = this.lodmodelindex1;
83                 else
84                         this.modelindex = this.lodmodelindex0;
85         }
86 }
87
88 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
89 string forceplayermodels_model;
90 bool forceplayermodels_modelisgoodmodel;
91 int forceplayermodels_modelindex;
92 int forceplayermodels_skin;
93
94 string forceplayermodels_mymodel;
95 bool forceplayermodels_myisgoodmodel;
96 int forceplayermodels_mymodelindex;
97
98 bool forceplayermodels_attempted;
99
100 .string forceplayermodels_savemodel;
101 .int forceplayermodels_savemodelindex;
102 .int forceplayermodels_saveskin;
103 .int forceplayermodels_savecolormap;
104
105 .string forceplayermodels_isgoodmodel_mdl;
106 .bool forceplayermodels_isgoodmodel;
107
108 string forceplayermodels_goodmodel;
109 int forceplayermodels_goodmodelindex;
110
111 .vector glowmod;
112 .vector old_glowmod;
113
114 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
115 {
116         this.model = this.forceplayermodels_savemodel;
117         this.modelindex = this.forceplayermodels_savemodelindex;
118         this.skin = this.forceplayermodels_saveskin;
119         this.colormap = this.forceplayermodels_savecolormap;
120 }
121 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
122 {
123         this.forceplayermodels_savemodel = this.model;
124         this.forceplayermodels_savemodelindex = this.modelindex;
125         this.forceplayermodels_saveskin = this.skin;
126         this.forceplayermodels_savecolormap = this.colormap;
127
128         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
129         {
130                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
131                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
132                 if(!this.forceplayermodels_isgoodmodel)
133                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
134         }
135 }
136 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
137 {
138         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
139                 goto skipforcemodels;
140
141         // FORCEMODEL
142         // which one is ALWAYS good?
143         if (!forceplayermodels_goodmodel)
144         {
145                 entity e = spawn();
146                 precache_model(cvar_defstring("_cl_playermodel"));
147                 _setmodel(e, cvar_defstring("_cl_playermodel"));
148                 forceplayermodels_goodmodel = e.model;
149                 forceplayermodels_goodmodelindex = e.modelindex;
150                 delete(e);
151         }
152
153         // first, try finding it from the server
154         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
155         {
156                 if(islocalplayer)
157                 {
158                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
159                         {
160                                 // trust server's idea of "own player model"
161                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
162                                 forceplayermodels_model = this.forceplayermodels_savemodel;
163                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
164                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
165                                 forceplayermodels_attempted = 1;
166                         }
167                 }
168         }
169
170         // forcemodel finding
171         if(!forceplayermodels_attempted)
172         {
173                 forceplayermodels_attempted = 1;
174
175                 // only if this failed, find it out on our own
176                 entity e = spawn();
177                 precache_model(autocvar__cl_playermodel);
178                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
179                 forceplayermodels_modelisgoodmodel = fexists(e.model);
180                 forceplayermodels_model = e.model;
181                 forceplayermodels_modelindex = e.modelindex;
182                 forceplayermodels_skin = autocvar__cl_playerskin;
183                 delete(e);
184         }
185
186         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
187         {
188                 entity e = spawn();
189                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
190                 forceplayermodels_myisgoodmodel = fexists(e.model);
191                 forceplayermodels_mymodel = e.model;
192                 forceplayermodels_mymodelindex = e.modelindex;
193                 delete(e);
194         }
195
196         // apply it
197         bool isfriend;
198         int cm;
199         cm = this.forceplayermodels_savecolormap;
200         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
201
202         if(teamplay)
203                 isfriend = (cm == 1024 + 17 * myteam);
204         else
205                 isfriend = islocalplayer;
206
207         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
208         {
209                 this.model = forceplayermodels_mymodel;
210                 this.modelindex = forceplayermodels_mymodelindex;
211                 this.skin = autocvar_cl_forcemyplayerskin;
212         }
213         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
214         {
215                 this.model = forceplayermodels_model;
216                 this.modelindex = forceplayermodels_modelindex;
217                 this.skin = forceplayermodels_skin;
218         }
219         else if(this.forceplayermodels_isgoodmodel)
220         {
221                 this.model = this.forceplayermodels_savemodel;
222                 this.modelindex = this.forceplayermodels_savemodelindex;
223                 this.skin = this.forceplayermodels_saveskin;
224         }
225         else
226         {
227                 this.model = forceplayermodels_goodmodel;
228                 this.modelindex = forceplayermodels_goodmodelindex;
229                 this.skin = this.forceplayermodels_saveskin;
230         }
231
232         // forceplayercolors too
233         if(teamplay)
234         {
235                 // own team's color is never forced
236                 int forcecolor_friend = 0;
237                 int forcecolor_enemy = 0;
238                 entity tm;
239
240                 if(autocvar_cl_forcemyplayercolors)
241                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
242                 if(autocvar_cl_forceplayercolors == 2 && team_count == 2)
243                         forcecolor_enemy = 1024 + autocvar__cl_color;
244
245                 if(forcecolor_enemy && !forcecolor_friend)
246                 {
247                         // only enemy color is forced?
248                         // verify it is not equal to the friend color
249                         if(forcecolor_enemy == 1024 + 17 * myteam)
250                                 forcecolor_enemy = 0;
251                 }
252
253                 if(forcecolor_friend && !forcecolor_enemy)
254                 {
255                         // only friend color is forced?
256                         // verify it is not equal to the enemy color
257                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
258                                 // note: we even compare against our own team.
259                                 // if we rejected because we matched our OWN team color,
260                                 // this is not bad; we then simply keep our color as is
261                                 // anyway.
262                                 if(forcecolor_friend == 1024 + 17 * tm.team)
263                                         forcecolor_friend = 0;
264                 }
265
266                 if(cm == 1024 + 17 * myteam)
267                 {
268                         if(forcecolor_friend)
269                                 this.colormap = forcecolor_friend;
270                 }
271                 else
272                 {
273                         if(forcecolor_enemy)
274                                 this.colormap = forcecolor_enemy;
275                 }
276         }
277         else
278         {
279                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
280                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
281                 else if(autocvar_cl_forceplayercolors)
282                         this.colormap = player_localnum + 1;
283         }
284
285         LABEL(skipforcemodels)
286
287         // GLOWMOD AND DEATH FADING
288         if(this.colormap > 0)
289                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true) * 2;
290         else
291                 this.glowmod = '1 1 1';
292
293         if(autocvar_cl_deathglow > 0)
294         {
295                 if(this.csqcmodel_isdead)
296                 {
297                         // Fade out to black now...
298                         if(this.old_glowmod == '0 0 0') { this.old_glowmod = this.glowmod; }
299                         this.colormap = 0;
300
301                         this.glowmod = this.old_glowmod * bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
302                         this.glowmod_x = max(this.glowmod.x, 0.0001);
303                         this.glowmod_y = max(this.glowmod.y, 0.0001);
304                         this.glowmod_z = max(this.glowmod.z, 0.0001);
305                 }
306                 else if(this.old_glowmod != '0 0 0') { this.old_glowmod = '0 0 0'; }
307         }
308
309         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
310 }
311
312 // FEATURE: fallback frames
313 .int csqcmodel_saveframe;
314 .int csqcmodel_saveframe2;
315 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
316 .int csqcmodel_saveframe3;
317 .int csqcmodel_saveframe4;
318 #endif
319 .int csqcmodel_framecount;
320
321 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
322 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
323 {
324         this.frame = this.csqcmodel_saveframe;
325         this.frame2 = this.csqcmodel_saveframe2;
326 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
327         this.frame3 = this.csqcmodel_saveframe3;
328         this.frame4 = this.csqcmodel_saveframe4;
329 #endif
330 }
331 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
332 {
333         this.csqcmodel_saveframe = this.frame;
334         this.csqcmodel_saveframe2 = this.frame2;
335 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
336         this.csqcmodel_saveframe3 = this.frame3;
337         this.csqcmodel_saveframe4 = this.frame4;
338 #endif
339
340         // hack for death animations: set their frametime to zero in case a
341         // player "pops in"
342         if(isnew)
343         {
344 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN {                                                                                                                                                       \
345                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0)                                                                                       \
346                         this.ft = this.death_time;                                                                                                                                                              \
347 } MACRO_END
348                 FIX_FRAMETIME(frame, frame1time);
349                 FIX_FRAMETIME(frame2, frame2time);
350 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
351                 FIX_FRAMETIME(frame3, frame3time);
352                 FIX_FRAMETIME(frame4, frame4time);
353 #endif
354         }
355         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
356 }
357 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
358 {
359         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
360 }
361 int CSQCPlayer_FallbackFrame(entity this, int f)
362 {
363         TC(int, f);
364         if(frameduration(this.modelindex, f) > 0)
365                 return f; // goooooood
366         if(frameduration(this.modelindex, 1) <= 0)
367                 return f; // this is a static model. We can't fix it if we wanted to
368         switch(f)
369         {
370                 case 23: return 11; // anim_melee -> anim_shoot
371                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
372                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
373                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
374                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
375                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
376                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
377                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
378         }
379         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
380         return f;
381 }
382 void CSQCPlayer_FallbackFrame_Apply(entity this)
383 {
384         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
385         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
386 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
387         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
388         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
389 #endif
390 }
391
392 // FEATURE: auto tag_index
393 .entity tag_entity;
394 .int tag_entity_lastmodelindex;
395 .int tag_index;
396 void CSQCModel_AutoTagIndex_Apply(entity this)
397 {
398         if(this.tag_entity && wasfreed(this.tag_entity))
399                 this.tag_entity = NULL;
400
401         MUTATOR_CALLHOOK(TagIndex_Update, this);
402
403         if(this.tag_networkentity)
404         {
405                 // we are ATTACHED!
406                 bool changed = 0;
407                 if(this.tag_entity.entnum != this.tag_networkentity)
408                 {
409                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
410                         changed = 1;
411                 }
412
413                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
414                 if(this.tag_entity.classname == "csqcmodel")
415                 {
416                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
417                 }
418
419                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
420                 {
421                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
422                         changed = 1;
423                 }
424                 if(changed)
425                 {
426                         if(this.tag_entity)
427                         {
428                                 // the best part is: IT EXISTS
429                                 if(substring(this.model, 0, 14) == "models/weapons")
430                                 {
431                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
432                                         {
433                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
434                                                 if(!this.tag_index)
435                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
436                                                 if(!this.tag_index)
437                                                 {
438                                                         // we need to prevent this from 'appening
439                                                         this.tag_entity = NULL;
440                                                         this.drawmask = 0;
441                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
442                                                 }
443                                         }
444                                         else if(this.tag_entity.isplayermodel)
445                                         {
446                                                 skeleton_loadinfo(this.tag_entity);
447                                                 this.tag_index = this.tag_entity.bone_weapon;
448                                         }
449                                 }
450
451                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
452                                 {
453                                         this.tag_index = gettagindex(this.tag_entity, "shot");
454                                         if(!this.tag_index)
455                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
456                                 }
457
458                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
459                         }
460                         else
461                         {
462                                 // damn, see you next frame
463                                 this.drawmask = 0;
464                         }
465                 }
466         }
467 }
468
469 void CSQCModel_Effects_PreUpdate(entity this)
470 {
471         this.effects = this.csqcmodel_effects;
472         this.modelflags = this.csqcmodel_modelflags;
473         this.traileffect = this.csqcmodel_traileffect;
474 }
475 void Reset_ArcBeam();
476 void CSQCModel_Effects_PostUpdate(entity this)
477 {
478         if (this == csqcplayer) {
479                 if (this.csqcmodel_teleported) {
480                         Reset_ArcBeam();
481                 }
482         }
483         this.csqcmodel_effects = this.effects;
484         this.csqcmodel_modelflags = this.modelflags;
485         this.csqcmodel_traileffect = this.traileffect;
486         this.effects = 0;
487         this.modelflags = 0;
488         if(this.csqcmodel_teleported)
489                 Projectile_ResetTrail(this, this.origin);
490 }
491 .int snd_looping;
492 void CSQCModel_Effects_Apply(entity this)
493 {
494         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
495         int tref = this.csqcmodel_traileffect;
496
497         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
498         this.effects = 0;
499         this.traileffect = 0;
500
501         if(eff & EF_BRIGHTFIELD)
502                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
503         // ignoring EF_MUZZLEFLASH
504         if(eff & EF_BRIGHTLIGHT)
505                 adddynamiclight(this.origin, 400, '3 3 3');
506         if(eff & EF_DIMLIGHT)
507                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
508         if((eff & EF_NODRAW) || (this.alpha < 0))
509                 this.drawmask = 0;
510         if(eff & EF_ADDITIVE)
511                 this.renderflags |= RF_ADDITIVE;
512         if(eff & EF_BLUE)
513                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
514         if(eff & EF_RED)
515                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
516         // ignoring EF_NOGUNBOB
517         if(eff & EF_FULLBRIGHT)
518                 this.renderflags |= RF_FULLBRIGHT;
519         if(eff & EF_FLAME)
520                 pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
521         if(eff & EF_STARDUST)
522                 pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
523         if(eff & EF_NOSHADOW)
524                 this.renderflags |= RF_NOSHADOW;
525         if(eff & EF_NODEPTHTEST)
526                 this.renderflags |= RF_DEPTHHACK;
527         // ignoring EF_SELECTABLE
528         if(eff & EF_DOUBLESIDED)
529                 this.effects |= EF_DOUBLESIDED;
530         if(eff & EF_NOSELFSHADOW)
531                 this.effects |= EF_NOSELFSHADOW;
532         if(eff & EF_DYNAMICMODELLIGHT)
533                 this.renderflags |= RF_DYNAMICMODELLIGHT;
534         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
535         if(this.csqcmodel_modelflags & MF_ROCKET)
536                 tref = EFFECT_TR_ROCKET.m_id;
537         if(this.csqcmodel_modelflags & MF_GRENADE)
538                 tref = EFFECT_TR_GRENADE.m_id;
539         if(this.csqcmodel_modelflags & MF_GIB)
540                 tref = EFFECT_TR_BLOOD.m_id;
541         if(this.csqcmodel_modelflags & MF_ROTATE)
542         {
543                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
544                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
545                 // However MR_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
546                 this.renderflags |= RF_USEAXIS;
547                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
548         }
549         if(this.csqcmodel_modelflags & MF_TRACER)
550                 tref = EFFECT_TR_WIZSPIKE.m_id;
551         if(this.csqcmodel_modelflags & MF_ZOMGIB)
552                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
553         if(this.csqcmodel_modelflags & MF_TRACER2)
554                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
555         if(this.csqcmodel_modelflags & MF_TRACER3)
556                 tref = EFFECT_TR_VORESPIKE.m_id;
557
558         this.traileffect = tref;
559
560         if(this.drawmask)
561                 Projectile_DrawTrail(this, this.origin);
562         else
563                 Projectile_ResetTrail(this, this.origin);
564
565         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
566                 this.renderflags |= RF_ADDITIVE;
567                 // also special in CSQCPlayer_GlowMod_Apply
568
569         if(this.csqcmodel_modelflags & MF_ROCKET)
570         {
571                 if(!this.snd_looping)
572                 {
573                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
574                         this.snd_looping = CH_TRIGGER_SINGLE;
575                 }
576         }
577         else
578         {
579                 if(this.snd_looping)
580                 {
581                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
582                         this.snd_looping = 0;
583                 }
584         }
585 }
586
587 // general functions
588 .int csqcmodel_predraw_run;
589 .int anim_frame;
590 .int anim_frame1time;
591 .int anim_frame2;
592 .int anim_frame2time;
593 .int anim_saveframe;
594 .int anim_saveframe1time;
595 .int anim_saveframe2;
596 .int anim_saveframe2time;
597 .int anim_prev_pmove_flags;
598 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
599 {
600         if(this.csqcmodel_predraw_run == framecount)
601                 return;
602         this.csqcmodel_predraw_run = framecount;
603
604         if(!this.modelindex || this.model == "null" || this.alpha < 0)
605         {
606                 this.drawmask = 0;
607                 return;
608         }
609         else
610                 this.drawmask = MASK_NORMAL;
611
612         if(this.isplayermodel && this.drawmask) // this checks if it's a player MODEL!
613         {
614                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
615                 CSQCPlayer_LOD_Apply(this);
616
617                 if(!isplayer)
618                 {
619                         skeleton_loadinfo(this);
620                         bool doblend = (this.bone_upperbody >= 0);
621                         CSQCPlayer_FallbackFrame_Apply(this);
622                         if(doblend)
623                         {
624                                 skeleton_from_frames(this, this.csqcmodel_isdead);
625                         }
626                         else
627                         {
628                                 free_skeleton_from_frames(this);
629                                 // just in case, clear these (we're animating in frame and frame3)
630                                 this.lerpfrac = 0;
631                                 this.lerpfrac4 = 0;
632                         }
633                 }
634                 else
635                 {
636                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
637                         skeleton_loadinfo(this);
638                         bool doblend = (this.bone_upperbody >= 0);
639                         bool onground = 0;
640                         if(this == csqcplayer)
641                         {
642                                 if(IS_ONGROUND(this))
643                                         onground = 1;
644                                 this.anim_prev_pmove_flags = this.flags;
645                                 if(this.flags & FL_DUCKED)
646                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
647                                 else if(this.anim_state & ANIMSTATE_DUCK)
648                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
649                         }
650                         else
651                         {
652                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
653                                 if(trace_startsolid || trace_fraction < 1)
654                                         onground = 1;
655                         }
656                         animdecide_load_if_needed(this);
657                         animdecide_setimplicitstate(this, onground);
658                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
659                         int sf = 0;
660                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
661                                 sf |= CSQCMODEL_PROPERTY_FRAME;
662                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
663                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
664                         this.anim_saveframe = this.anim_frame;
665                         this.anim_saveframe1time = this.anim_frame1time;
666                         this.anim_saveframe2 = this.anim_frame2;
667                         this.anim_saveframe2time = this.anim_frame2time;
668                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
669                         // This ensures that .frame etc. are always written.
670                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
671                         this.lerpfrac = (doblend ? 0.5 : 0);
672                         this.frame = this.anim_frame;
673                         this.frame1time = this.anim_frame1time;
674                         this.frame2 = this.anim_frame2;
675                         this.frame2time = this.anim_frame2time;
676                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
677                         CSQCModel_InterpolateAnimation_2To4_Do(this);
678                         if(doblend)
679                         {
680                                 skeleton_from_frames(this, this.csqcmodel_isdead);
681                         }
682                         else
683                         {
684                                 free_skeleton_from_frames(this);
685                                 // just in case, clear these (we're animating in frame and frame3)
686                                 this.lerpfrac = 0;
687                                 this.lerpfrac4 = 0;
688                         }
689                 }
690         }
691
692         CSQCModel_AutoTagIndex_Apply(this);
693
694         CSQCModel_Effects_Apply(this);
695 }
696
697 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
698 {
699         // interpolate v_angle
700         this.iflags |= IFLAG_V_ANGLE_X;
701         // revert to values from server
702         CSQCModel_Effects_PreUpdate(this);
703         if(this.isplayermodel)
704         {
705                 if(!isplayer)
706                         CSQCPlayer_FallbackFrame_PreUpdate(this);
707                 CSQCPlayer_ModelAppearance_PreUpdate(this);
708         }
709 }
710
711 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
712 {
713         // is it a player model? (shared state)
714         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" || 
715                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
716         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
717
718         // save values set by server
719         if(this.isplayermodel)
720         {
721                 CSQCPlayer_ModelAppearance_PostUpdate(this);
722                 if(isplayer)
723                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
724                 else
725                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
726         }
727         CSQCModel_Effects_PostUpdate(this);
728 }