qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw(float isplayer);
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 .vector glowmod;
  96 .vector old_glowmod;
  97
  98 void CSQCPlayer_ModelAppearance_PreUpdate(void)
  99 {
 100         self.model = self.forceplayermodels_savemodel;
 101         self.modelindex = self.forceplayermodels_savemodelindex;
 102         self.skin = self.forceplayermodels_saveskin;
 103         self.colormap = self.forceplayermodels_savecolormap;
 104 }
 105 void CSQCPlayer_ModelAppearance_PostUpdate(void)
 106 {
 107         self.forceplayermodels_savemodel = self.model;
 108         self.forceplayermodels_savemodelindex = self.modelindex;
 109         self.forceplayermodels_saveskin = self.skin;
 110         self.forceplayermodels_savecolormap = self.colormap;
 111
 112         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 113         {
 114                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 115                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 116                 if(!self.forceplayermodels_isgoodmodel)
 117                         printf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel);
 118         }
 119 }
 120 void CSQCPlayer_ModelAppearance_Apply(float islocalplayer)
 121 {
 122         // FORCEMODEL
 123         // which one is ALWAYS good?
 124         if (!forceplayermodels_goodmodel)
 125         {
 126                 entity e;
 127                 e = spawn();
 128                 precache_model(cvar_defstring("_cl_playermodel"));
 129                 setmodel(e, cvar_defstring("_cl_playermodel"));
 130                 forceplayermodels_goodmodel = e.model;
 131                 forceplayermodels_goodmodelindex = e.modelindex;
 132                 remove(e);
 133         }
 134
 135         // first, try finding it from the server
 136         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 137         {
 138                 if(islocalplayer)
 139                 {
 140                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 141                         {
 142                                 // trust server's idea of "own player model"
 143                                 forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 144                                 forceplayermodels_model = self.forceplayermodels_savemodel;
 145                                 forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 146                                 forceplayermodels_skin = self.forceplayermodels_saveskin;
 147                                 forceplayermodels_attempted = 1;
 148                         }
 149                 }
 150         }
 151
 152         // forcemodel finding
 153         if(!forceplayermodels_attempted)
 154         {
 155                 forceplayermodels_attempted = 1;
 156
 157                 // only if this failed, find it out on our own
 158                 entity e;
 159                 e = spawn();
 160                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 161                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 162                 forceplayermodels_model = e.model;
 163                 forceplayermodels_modelindex = e.modelindex;
 164                 forceplayermodels_skin = autocvar__cl_playerskin;
 165                 remove(e);
 166         }
 167
 168         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 169         {
 170                 entity e;
 171                 e = spawn();
 172                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 173                 forceplayermodels_myisgoodmodel = fexists(e.model);
 174                 forceplayermodels_mymodel = e.model;
 175                 forceplayermodels_mymodelindex = e.modelindex;
 176                 remove(e);
 177         }
 178
 179         // apply it
 180         float isfriend;
 181         float cm;
 182         cm = self.forceplayermodels_savecolormap;
 183         cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(cm - 1, "colors")) + 1024);
 184
 185         if(teamplay)
 186                 isfriend = (cm == 1024 + 17 * myteam);
 187         else
 188                 isfriend = islocalplayer;
 189
 190         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 191         {
 192                 self.model = forceplayermodels_mymodel;
 193                 self.modelindex = forceplayermodels_mymodelindex;
 194                 self.skin = autocvar_cl_forcemyplayerskin;
 195         }
 196         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 197         {
 198                 self.model = forceplayermodels_model;
 199                 self.modelindex = forceplayermodels_modelindex;
 200                 self.skin = forceplayermodels_skin;
 201         }
 202         else if(self.forceplayermodels_isgoodmodel)
 203         {
 204                 self.model = self.forceplayermodels_savemodel;
 205                 self.modelindex = self.forceplayermodels_savemodelindex;
 206                 self.skin = self.forceplayermodels_saveskin;
 207         }
 208         else
 209         {
 210                 self.model = forceplayermodels_goodmodel;
 211                 self.modelindex = forceplayermodels_goodmodelindex;
 212                 self.skin = self.forceplayermodels_saveskin;
 213         }
 214
 215         // forceplayercolors too
 216         if(teamplay)
 217         {
 218                 // own team's color is never forced
 219                 float forcecolor_friend = 0;
 220                 float forcecolor_enemy = 0;
 221                 entity tm;
 222
 223                 if(autocvar_cl_forcemyplayercolors)
 224                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 225                 if(autocvar_cl_forceplayercolors && team_count == 2)
 226                         forcecolor_enemy = 1024 + autocvar__cl_color;
 227
 228                 if(forcecolor_enemy && !forcecolor_friend)
 229                 {
 230                         // only enemy color is forced?
 231                         // verify it is not equal to the friend color
 232                         if(forcecolor_enemy == 1024 + 17 * myteam)
 233                                 forcecolor_enemy = 0;
 234                 }
 235
 236                 if(forcecolor_friend && !forcecolor_enemy)
 237                 {
 238                         // only friend color is forced?
 239                         // verify it is not equal to the enemy color
 240                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 241                                 // note: we even compare against our own team.
 242                                 // if we rejected because we matched our OWN team color,
 243                                 // this is not bad; we then simply keep our color as is
 244                                 // anyway.
 245                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 246                                         forcecolor_friend = 0;
 247                 }
 248
 249                 if(cm == 1024 + 17 * myteam)
 250                 {
 251                         if(forcecolor_friend)
 252                                 self.colormap = forcecolor_friend;
 253                 }
 254                 else
 255                 {
 256                         if(forcecolor_enemy)
 257                                 self.colormap = forcecolor_enemy;
 258                 }
 259         }
 260         else
 261         {
 262                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 263                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 264                 else if(autocvar_cl_forceplayercolors)
 265                         self.colormap = player_localnum + 1;
 266         }
 267
 268         // GLOWMOD AND DEATH FADING
 269         if(self.colormap > 0)
 270                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 271         else
 272                 self.glowmod = '1 1 1';
 273
 274         if(autocvar_cl_deathglow > 0)
 275         {
 276                 if(self.csqcmodel_isdead)
 277                 {
 278                         // Fade out to black now...
 279                         if(self.old_glowmod == '0 0 0') { self.old_glowmod = self.glowmod; }
 280                         self.colormap = 0;
 281
 282                         self.glowmod = self.old_glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 283                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 284                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 285                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 286                 }
 287                 else if(self.old_glowmod != '0 0 0') { self.old_glowmod = '0 0 0'; }
 288         }
 289
 290         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (self.csqcmodel_isdead ? "DEAD" : "ALIVE"), self.colormap, vtos(self.glowmod));
 291 }
 292
 293 // FEATURE: fallback frames
 294 .float csqcmodel_saveframe;
 295 .float csqcmodel_saveframe2;
 296 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 297 .float csqcmodel_saveframe3;
 298 .float csqcmodel_saveframe4;
 299 #endif
 300 .float csqcmodel_framecount;
 301
 302 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 303 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 304 {
 305         self.frame = self.csqcmodel_saveframe;
 306         self.frame2 = self.csqcmodel_saveframe2;
 307 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 308         self.frame3 = self.csqcmodel_saveframe3;
 309         self.frame4 = self.csqcmodel_saveframe4;
 310 #endif
 311 }
 312 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 313 {
 314         self.csqcmodel_saveframe = self.frame;
 315         self.csqcmodel_saveframe2 = self.frame2;
 316 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 317         self.csqcmodel_saveframe3 = self.frame3;
 318         self.csqcmodel_saveframe4 = self.frame4;
 319 #endif
 320
 321         // hack for death animations: set their frametime to zero in case a
 322         // player "pops in"
 323         if(isnew)
 324         {
 325 #define FIX_FRAMETIME(f,ft) \
 326                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 327                 { \
 328                         self.ft = self.death_time; \
 329                 }
 330                 FIX_FRAMETIME(frame, frame1time)
 331                 FIX_FRAMETIME(frame2, frame2time)
 332 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 333                 FIX_FRAMETIME(frame3, frame3time)
 334                 FIX_FRAMETIME(frame4, frame4time)
 335 #endif
 336         }
 337         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 338 }
 339 void CSQCPlayer_AnimDecide_PostUpdate(float isnew)
 340 {
 341         self.csqcmodel_isdead = !!(self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 342 }
 343 float CSQCPlayer_FallbackFrame(float f)
 344 {
 345         if(frameduration(self.modelindex, f) > 0)
 346                 return f; // goooooood
 347         if(frameduration(self.modelindex, 1) <= 0)
 348                 return f; // this is a static model. We can't fix it if we wanted to
 349         switch(f)
 350         {
 351                 case 23: return 11; // anim_melee -> anim_shoot
 352                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 353                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 354                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 355                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 356                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 357                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 358                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 359         }
 360         printf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model);
 361         return f;
 362 }
 363 void CSQCPlayer_FallbackFrame_Apply(void)
 364 {
 365         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 366         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 367 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 368         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 369         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 370 #endif
 371 }
 372
 373 // FEATURE: auto tag_index
 374 .entity tag_entity;
 375 .float tag_entity_lastmodelindex;
 376 .float tag_index;
 377 void CSQCModel_AutoTagIndex_Apply(void)
 378 {
 379         if(self.tag_entity && wasfreed(self.tag_entity))
 380                 self.tag_entity = world;
 381
 382         if(self.tag_networkentity)
 383         {
 384                 // we are ATTACHED!
 385                 float changed = 0;
 386                 if(self.tag_entity.entnum != self.tag_networkentity)
 387                 {
 388                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 389                         changed = 1;
 390                 }
 391
 392                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 393                 if(self.tag_entity.classname == "csqcmodel")
 394                 {
 395                         entity oldself = self;
 396                         self = self.tag_entity;
 397                         CSQCModel_Hook_PreDraw((self.entnum >= 1 && self.entnum <= maxclients));
 398                         self = oldself;
 399                 }
 400
 401                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 402                 {
 403                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 404                         changed = 1;
 405                 }
 406                 if(changed)
 407                 {
 408                         if(self.tag_entity)
 409                         {
 410                                 // the best part is: IT EXISTS
 411                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 412                                 {
 413                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 414                                         {
 415                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 416                                                 if(!self.tag_index)
 417                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 418                                                 if(!self.tag_index)
 419                                                 {
 420                                                         // we need to prevent this from 'appening
 421                                                         self.tag_entity = world;
 422                                                         self.drawmask = 0;
 423                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 424                                                 }
 425                                         }
 426                                         else if(self.tag_entity.isplayermodel)
 427                                         {
 428                                                 skeleton_loadinfo(self.tag_entity);
 429                                                 self.tag_index = self.tag_entity.bone_weapon;
 430                                         }
 431                                 }
 432
 433                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 434                                 {
 435                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 436                                         if(!self.tag_index)
 437                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 438                                 }
 439                         }
 440                         else
 441                         {
 442                                 // damn, see you next frame
 443                                 self.drawmask = 0;
 444                         }
 445                 }
 446         }
 447 }
 448
 449 // FEATURE: EF_NODRAW workalike
 450 const float EF_BRIGHTFIELD      = 1;
 451 const float EF_BRIGHTLIGHT      = 4;
 452 const float EF_DIMLIGHT         = 8;
 453 const float EF_DOUBLESIDED = 32768;
 454 const float EF_NOSELFSHADOW = 65536;
 455 const float EF_DYNAMICMODELLIGHT = 131072;
 456 const float EF_RESTARTANIM_BIT = 1048576;
 457 const float EF_TELEPORT_BIT = 2097152;
 458 const float MF_ROCKET  =   1; // leave a trail
 459 const float MF_GRENADE =   2; // leave a trail
 460 const float MF_GIB     =   4; // leave a trail
 461 const float MF_ROTATE  =   8; // rotate (bonus items)
 462 const float MF_TRACER  =  16; // green split trail
 463 const float MF_ZOMGIB  =  32; // small blood trail
 464 const float MF_TRACER2 =  64; // orange split trail
 465 const float MF_TRACER3 = 128; // purple trail
 466 .float csqcmodel_effects;
 467 .float csqcmodel_modelflags;
 468 void CSQCModel_Effects_PreUpdate(void)
 469 {
 470         self.effects = self.csqcmodel_effects;
 471         self.modelflags = self.csqcmodel_modelflags;
 472 }
 473 void CSQCModel_Effects_PostUpdate(void)
 474 {
 475         self.csqcmodel_effects = self.effects;
 476         self.csqcmodel_modelflags = self.modelflags;
 477         self.effects = 0;
 478         self.modelflags = 0;
 479         if(self.csqcmodel_teleported)
 480                 Projectile_ResetTrail(self.origin);
 481 }
 482 .float snd_looping;
 483 void CSQCModel_Effects_Apply(void)
 484 {
 485         float eff = self.csqcmodel_effects;
 486         eff &= ~CSQCMODEL_EF_RESPAWNGHOST;
 487
 488         self.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 489         self.effects = 0;
 490         self.traileffect = 0;
 491
 492         if(eff & EF_BRIGHTFIELD)
 493                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 494         // ignoring EF_MUZZLEFLASH
 495         if(eff & EF_BRIGHTLIGHT)
 496                 adddynamiclight(self.origin, 400, '3 3 3');
 497         if(eff & EF_DIMLIGHT)
 498                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 499         if((eff & EF_NODRAW) || (self.alpha < 0))
 500                 self.drawmask = 0;
 501         if(eff & EF_ADDITIVE)
 502                 self.renderflags |= RF_ADDITIVE;
 503         if(eff & EF_BLUE)
 504                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 505         if(eff & EF_RED)
 506                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 507         // ignoring EF_NOGUNBOB
 508         if(eff & EF_FULLBRIGHT)
 509                 self.renderflags |= RF_FULLBRIGHT;
 510         if(eff & EF_FLAME)
 511                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 512         if(eff & EF_STARDUST)
 513                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 514         if(eff & EF_NOSHADOW)
 515                 self.renderflags |= RF_NOSHADOW;
 516         if(eff & EF_NODEPTHTEST)
 517                 self.renderflags |= RF_DEPTHHACK;
 518         // ignoring EF_SELECTABLE
 519         if(eff & EF_DOUBLESIDED)
 520                 self.effects |= EF_DOUBLESIDED;
 521         if(eff & EF_NOSELFSHADOW)
 522                 self.effects |= EF_NOSELFSHADOW;
 523         if(eff & EF_DYNAMICMODELLIGHT)
 524                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 525         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 526         if(self.csqcmodel_modelflags & MF_ROCKET)
 527                 self.traileffect = particleeffectnum("TR_ROCKET");
 528         if(self.csqcmodel_modelflags & MF_GRENADE)
 529                 self.traileffect = particleeffectnum("TR_GRENADE");
 530         if(self.csqcmodel_modelflags & MF_GIB)
 531                 self.traileffect = particleeffectnum("TR_BLOOD");
 532         if(self.csqcmodel_modelflags & MF_ROTATE)
 533         {
 534                 self.renderflags |= RF_USEAXIS;
 535                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 536         }
 537         if(self.csqcmodel_modelflags & MF_TRACER)
 538                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 539         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 540                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 541         if(self.csqcmodel_modelflags & MF_TRACER2)
 542                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 543         if(self.csqcmodel_modelflags & MF_TRACER3)
 544                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 545
 546         if(self.drawmask)
 547                 Projectile_DrawTrail(self.origin);
 548         else
 549                 Projectile_ResetTrail(self.origin);
 550
 551         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 552                 self.renderflags |= RF_ADDITIVE;
 553                 // also special in CSQCPlayer_GlowMod_Apply
 554
 555         if(self.csqcmodel_modelflags & MF_ROCKET)
 556         {
 557                 if(!self.snd_looping)
 558                 {
 559                         sound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 560                         self.snd_looping = CH_TRIGGER_SINGLE;
 561                 }
 562         }
 563         else
 564         {
 565                 if(self.snd_looping)
 566                 {
 567                         sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 568                         self.snd_looping = 0;
 569                 }
 570         }
 571 }
 572
 573 void CSQCPlayer_Precache()
 574 {
 575         precache_sound("misc/jetpack_fly.wav");
 576 }
 577
 578 // general functions
 579 .float csqcmodel_predraw_run;
 580 .float anim_frame;
 581 .float anim_frame1time;
 582 .float anim_frame2;
 583 .float anim_frame2time;
 584 .float anim_saveframe;
 585 .float anim_saveframe1time;
 586 .float anim_saveframe2;
 587 .float anim_saveframe2time;
 588 .float anim_prev_pmove_flags;
 589 void CSQCModel_Hook_PreDraw(float isplayer)
 590 {
 591         if(self.csqcmodel_predraw_run == framecount)
 592                 return;
 593         self.csqcmodel_predraw_run = framecount;
 594
 595         if(!self.modelindex || self.model == "null")
 596         {
 597                 self.drawmask = 0;
 598                 return;
 599         }
 600         else
 601                 self.drawmask = MASK_NORMAL;
 602
 603         if(self.isplayermodel) // this checks if it's a player MODEL!
 604         {
 605                 CSQCPlayer_ModelAppearance_Apply(self.entnum == player_localnum + 1);
 606                 CSQCPlayer_LOD_Apply();
 607                 if(!isplayer)
 608                 {
 609                         skeleton_loadinfo(self);
 610                         float doblend = (self.bone_upperbody >= 0);
 611                         CSQCPlayer_FallbackFrame_Apply();
 612                         if(doblend)
 613                         {
 614                                 skeleton_from_frames(self, self.csqcmodel_isdead);
 615                         }
 616                         else
 617                         {
 618                                 free_skeleton_from_frames(self);
 619                                 // just in case, clear these (we're animating in frame and frame3)
 620                                 self.lerpfrac = 0;
 621                                 self.lerpfrac4 = 0;
 622                         }
 623                 }
 624                 else
 625                 {
 626                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 627                         skeleton_loadinfo(self);
 628                         float doblend = (self.bone_upperbody >= 0);
 629                         float onground = 0;
 630                         if(self == csqcplayer)
 631                         {
 632                                 if(self.pmove_flags & PMF_ONGROUND)
 633                                         onground = 1;
 634                                 self.anim_prev_pmove_flags = self.pmove_flags;
 635                                 if(self.pmove_flags & PMF_DUCKED)
 636                                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DUCK, FALSE);
 637                                 else if(self.anim_state & ANIMSTATE_DUCK)
 638                                         animdecide_setstate(self, self.anim_state - ANIMSTATE_DUCK, FALSE);
 639                         }
 640                         else
 641                         {
 642                                 tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 643                                 if(trace_startsolid || trace_fraction < 1)
 644                                         onground = 1;
 645                         }
 646                         animdecide_init(self);
 647                         animdecide_setimplicitstate(self, onground);
 648                         animdecide_setframes(self, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 649                         float sf = 0;
 650                         if(self.anim_saveframe != self.anim_frame || self.anim_saveframe1time != self.anim_frame1time)
 651                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 652                         if(self.anim_saveframe2 != self.anim_frame2 || self.anim_saveframe2time != self.anim_frame2time)
 653                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 654                         self.anim_saveframe = self.anim_frame;
 655                         self.anim_saveframe1time = self.anim_frame1time;
 656                         self.anim_saveframe2 = self.anim_frame2;
 657                         self.anim_saveframe2time = self.anim_frame2time;
 658                         if(sf)
 659                         {
 660                                 CSQCModel_InterpolateAnimation_2To4_PreNote(sf | CSQCMODEL_PROPERTY_LERPFRAC);
 661                                 self.lerpfrac = (doblend ? 0.5 : 0);
 662                                 self.frame = self.anim_frame;
 663                                 self.frame1time = self.anim_frame1time;
 664                                 self.frame2 = self.anim_frame2;
 665                                 self.frame2time = self.anim_frame2time;
 666                                 CSQCModel_InterpolateAnimation_2To4_Note(sf | CSQCMODEL_PROPERTY_LERPFRAC, FALSE);
 667                         }
 668                         CSQCModel_InterpolateAnimation_2To4_Do();
 669                         if(doblend)
 670                         {
 671                                 skeleton_from_frames(self, self.csqcmodel_isdead);
 672                         }
 673                         else
 674                         {
 675                                 free_skeleton_from_frames(self);
 676                                 // just in case, clear these (we're animating in frame and frame3)
 677                                 self.lerpfrac = 0;
 678                                 self.lerpfrac4 = 0;
 679                         }
 680                 }
 681         }
 682
 683         CSQCModel_AutoTagIndex_Apply();
 684
 685         CSQCModel_Effects_Apply();
 686 }
 687
 688 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 689 {
 690         // interpolate v_angle
 691         self.iflags |= IFLAG_V_ANGLE_X;
 692         // revert to values from server
 693         CSQCModel_Effects_PreUpdate();
 694         if(self.isplayermodel)
 695         {
 696                 if(!isplayer)
 697                         CSQCPlayer_FallbackFrame_PreUpdate();
 698                 CSQCPlayer_ModelAppearance_PreUpdate();
 699         }
 700 }
 701
 702 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 703 {
 704         // is it a player model? (shared state)
 705         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 706
 707         // save values set by server
 708         if(self.isplayermodel)
 709         {
 710                 CSQCPlayer_ModelAppearance_PostUpdate();
 711                 if(isplayer)
 712                         CSQCPlayer_AnimDecide_PostUpdate(isnew);
 713                 else
 714                         CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 715         }
 716         CSQCModel_Effects_PostUpdate();
 717 }