Makefile: use `-I.`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / csqcmodel_hooks.qc
1 #include "mutators/events.qh"
2 #include "player_skeleton.qh"
3 #include "weapons/projectile.qh"
4 #include <common/animdecide.qh>
5 #include <common/physics/movetypes/movetypes.qh>
6 #include <common/viewloc.qh>
7 #include <lib/csqcmodel/cl_model.qh>
8 #include <lib/csqcmodel/cl_player.qh>
9 #include <lib/csqcmodel/interpolate.qh>
10
11 .float death_time;
12 .int modelflags;
13
14 void CSQCModel_Hook_PreDraw(bool isplayer);
15
16 .bool isplayermodel;
17
18 // FEATURE: LOD
19 .int lodmodelindex0;
20 .int lodmodelindex1;
21 .int lodmodelindex2;
22 void CSQCPlayer_LOD_Apply()
23 {SELFPARAM();
24         // LOD model loading
25         if(self.lodmodelindex0 != self.modelindex)
26         {
27                 string modelname = self.model;
28                 string s;
29
30                 vector mi = self.mins;
31                 vector ma = self.maxs;
32
33                 // set modelindex
34                 self.lodmodelindex0 = self.modelindex;
35                 self.lodmodelindex1 = self.modelindex;
36                 self.lodmodelindex2 = self.modelindex;
37
38                 // FIXME: this only supports 3-letter extensions
39                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
40                 if(fexists(s))
41                 {
42                         precache_model(s);
43                         _setmodel(self, s);
44                         if(self.modelindex)
45                                 self.lodmodelindex1 = self.modelindex;
46                 }
47
48                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
49                 if(fexists(s))
50                 {
51                         precache_model(s);
52                         _setmodel(self, s);
53                         if(self.modelindex)
54                                 self.lodmodelindex2 = self.modelindex;
55                 }
56
57                 _setmodel(self, modelname); // make everything normal again
58                 setsize(self, mi, ma);
59         }
60
61         // apply LOD
62         if(autocvar_cl_playerdetailreduction <= 0)
63         {
64                 if(autocvar_cl_playerdetailreduction <= -2)
65                         self.modelindex = self.lodmodelindex2;
66                 else if(autocvar_cl_playerdetailreduction <= -1)
67                         self.modelindex = self.lodmodelindex1;
68                 else
69                         self.modelindex = self.lodmodelindex0;
70         }
71         else
72         {
73                 float distance = vlen(self.origin - view_origin);
74                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
75                 f *= 1.0 / bound(0.01, view_quality, 1);
76                 if(f > autocvar_cl_loddistance2)
77                         self.modelindex = self.lodmodelindex2;
78                 else if(f > autocvar_cl_loddistance1)
79                         self.modelindex = self.lodmodelindex1;
80                 else
81                         self.modelindex = self.lodmodelindex0;
82         }
83 }
84
85 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
86 string forceplayermodels_model;
87 bool forceplayermodels_modelisgoodmodel;
88 int forceplayermodels_modelindex;
89 int forceplayermodels_skin;
90
91 string forceplayermodels_mymodel;
92 bool forceplayermodels_myisgoodmodel;
93 int forceplayermodels_mymodelindex;
94
95 bool forceplayermodels_attempted;
96
97 .string forceplayermodels_savemodel;
98 .int forceplayermodels_savemodelindex;
99 .int forceplayermodels_saveskin;
100 .int forceplayermodels_savecolormap;
101
102 .string forceplayermodels_isgoodmodel_mdl;
103 .bool forceplayermodels_isgoodmodel;
104
105 string forceplayermodels_goodmodel;
106 int forceplayermodels_goodmodelindex;
107
108 .vector glowmod;
109 .vector old_glowmod;
110
111 void CSQCPlayer_ModelAppearance_PreUpdate()
112 {SELFPARAM();
113         self.model = self.forceplayermodels_savemodel;
114         self.modelindex = self.forceplayermodels_savemodelindex;
115         self.skin = self.forceplayermodels_saveskin;
116         self.colormap = self.forceplayermodels_savecolormap;
117 }
118 void CSQCPlayer_ModelAppearance_PostUpdate()
119 {SELFPARAM();
120         self.forceplayermodels_savemodel = self.model;
121         self.forceplayermodels_savemodelindex = self.modelindex;
122         self.forceplayermodels_saveskin = self.skin;
123         self.forceplayermodels_savecolormap = self.colormap;
124
125         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
126         {
127                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
128                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
129                 if(!self.forceplayermodels_isgoodmodel)
130                         LOG_INFOF("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel);
131         }
132 }
133 void CSQCPlayer_ModelAppearance_Apply(bool islocalplayer)
134 {SELFPARAM();
135         // FORCEMODEL
136         // which one is ALWAYS good?
137         if (!forceplayermodels_goodmodel)
138         {
139                 entity e = spawn();
140                 precache_model(cvar_defstring("_cl_playermodel"));
141                 _setmodel(e, cvar_defstring("_cl_playermodel"));
142                 forceplayermodels_goodmodel = e.model;
143                 forceplayermodels_goodmodelindex = e.modelindex;
144                 remove(e);
145         }
146
147         // first, try finding it from the server
148         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
149         {
150                 if(islocalplayer)
151                 {
152                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
153                         {
154                                 // trust server's idea of "own player model"
155                                 forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
156                                 forceplayermodels_model = self.forceplayermodels_savemodel;
157                                 forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
158                                 forceplayermodels_skin = self.forceplayermodels_saveskin;
159                                 forceplayermodels_attempted = 1;
160                         }
161                 }
162         }
163
164         // forcemodel finding
165         if(!forceplayermodels_attempted)
166         {
167                 forceplayermodels_attempted = 1;
168
169                 // only if this failed, find it out on our own
170                 entity e = spawn();
171                 precache_model(autocvar__cl_playermodel);
172                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
173                 forceplayermodels_modelisgoodmodel = fexists(e.model);
174                 forceplayermodels_model = e.model;
175                 forceplayermodels_modelindex = e.modelindex;
176                 forceplayermodels_skin = autocvar__cl_playerskin;
177                 remove(e);
178         }
179
180         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
181         {
182                 entity e = spawn();
183                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
184                 forceplayermodels_myisgoodmodel = fexists(e.model);
185                 forceplayermodels_mymodel = e.model;
186                 forceplayermodels_mymodelindex = e.modelindex;
187                 remove(e);
188         }
189
190         // apply it
191         bool isfriend;
192         int cm;
193         cm = self.forceplayermodels_savecolormap;
194         cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(cm - 1, "colors")) + 1024);
195
196         if(teamplay)
197                 isfriend = (cm == 1024 + 17 * myteam);
198         else
199                 isfriend = islocalplayer;
200
201         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
202         {
203                 self.model = forceplayermodels_mymodel;
204                 self.modelindex = forceplayermodels_mymodelindex;
205                 self.skin = autocvar_cl_forcemyplayerskin;
206         }
207         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
208         {
209                 self.model = forceplayermodels_model;
210                 self.modelindex = forceplayermodels_modelindex;
211                 self.skin = forceplayermodels_skin;
212         }
213         else if(self.forceplayermodels_isgoodmodel)
214         {
215                 self.model = self.forceplayermodels_savemodel;
216                 self.modelindex = self.forceplayermodels_savemodelindex;
217                 self.skin = self.forceplayermodels_saveskin;
218         }
219         else
220         {
221                 self.model = forceplayermodels_goodmodel;
222                 self.modelindex = forceplayermodels_goodmodelindex;
223                 self.skin = self.forceplayermodels_saveskin;
224         }
225
226         // forceplayercolors too
227         if(teamplay)
228         {
229                 // own team's color is never forced
230                 int forcecolor_friend = 0;
231                 int forcecolor_enemy = 0;
232                 entity tm;
233
234                 if(autocvar_cl_forcemyplayercolors)
235                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
236                 if(autocvar_cl_forceplayercolors == 2 && team_count == 2)
237                         forcecolor_enemy = 1024 + autocvar__cl_color;
238
239                 if(forcecolor_enemy && !forcecolor_friend)
240                 {
241                         // only enemy color is forced?
242                         // verify it is not equal to the friend color
243                         if(forcecolor_enemy == 1024 + 17 * myteam)
244                                 forcecolor_enemy = 0;
245                 }
246
247                 if(forcecolor_friend && !forcecolor_enemy)
248                 {
249                         // only friend color is forced?
250                         // verify it is not equal to the enemy color
251                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
252                                 // note: we even compare against our own team.
253                                 // if we rejected because we matched our OWN team color,
254                                 // this is not bad; we then simply keep our color as is
255                                 // anyway.
256                                 if(forcecolor_friend == 1024 + 17 * tm.team)
257                                         forcecolor_friend = 0;
258                 }
259
260                 if(cm == 1024 + 17 * myteam)
261                 {
262                         if(forcecolor_friend)
263                                 self.colormap = forcecolor_friend;
264                 }
265                 else
266                 {
267                         if(forcecolor_enemy)
268                                 self.colormap = forcecolor_enemy;
269                 }
270         }
271         else
272         {
273                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
274                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
275                 else if(autocvar_cl_forceplayercolors)
276                         self.colormap = player_localnum + 1;
277         }
278
279         // GLOWMOD AND DEATH FADING
280         if(self.colormap > 0)
281                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, true) * 2;
282         else
283                 self.glowmod = '1 1 1';
284
285         if(autocvar_cl_deathglow > 0)
286         {
287                 if(self.csqcmodel_isdead)
288                 {
289                         // Fade out to black now...
290                         if(self.old_glowmod == '0 0 0') { self.old_glowmod = self.glowmod; }
291                         self.colormap = 0;
292
293                         self.glowmod = self.old_glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
294                         self.glowmod_x = max(self.glowmod.x, 0.0001);
295                         self.glowmod_y = max(self.glowmod.y, 0.0001);
296                         self.glowmod_z = max(self.glowmod.z, 0.0001);
297                 }
298                 else if(self.old_glowmod != '0 0 0') { self.old_glowmod = '0 0 0'; }
299         }
300
301         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (self.csqcmodel_isdead ? "DEAD" : "ALIVE"), self.colormap, vtos(self.glowmod));
302 }
303
304 // FEATURE: fallback frames
305 .int csqcmodel_saveframe;
306 .int csqcmodel_saveframe2;
307 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
308 .int csqcmodel_saveframe3;
309 .int csqcmodel_saveframe4;
310 #endif
311 .int csqcmodel_framecount;
312
313 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
314 void CSQCPlayer_FallbackFrame_PreUpdate()
315 {SELFPARAM();
316         self.frame = self.csqcmodel_saveframe;
317         self.frame2 = self.csqcmodel_saveframe2;
318 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
319         self.frame3 = self.csqcmodel_saveframe3;
320         self.frame4 = self.csqcmodel_saveframe4;
321 #endif
322 }
323 void CSQCPlayer_FallbackFrame_PostUpdate(bool isnew)
324 {SELFPARAM();
325         self.csqcmodel_saveframe = self.frame;
326         self.csqcmodel_saveframe2 = self.frame2;
327 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
328         self.csqcmodel_saveframe3 = self.frame3;
329         self.csqcmodel_saveframe4 = self.frame4;
330 #endif
331
332         // hack for death animations: set their frametime to zero in case a
333         // player "pops in"
334         if(isnew)
335         {
336 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN {                                                                                                                                                       \
337                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0)                                                                                       \
338                         self.ft = self.death_time;                                                                                                                                                              \
339 } MACRO_END
340                 FIX_FRAMETIME(frame, frame1time);
341                 FIX_FRAMETIME(frame2, frame2time);
342 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
343                 FIX_FRAMETIME(frame3, frame3time);
344                 FIX_FRAMETIME(frame4, frame4time);
345 #endif
346         }
347         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
348 }
349 void CSQCPlayer_AnimDecide_PostUpdate(bool isnew)
350 {SELFPARAM();
351         self.csqcmodel_isdead = boolean(self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
352 }
353 int CSQCPlayer_FallbackFrame(int f)
354 {SELFPARAM();
355         if(frameduration(self.modelindex, f) > 0)
356                 return f; // goooooood
357         if(frameduration(self.modelindex, 1) <= 0)
358                 return f; // this is a static model. We can't fix it if we wanted to
359         switch(f)
360         {
361                 case 23: return 11; // anim_melee -> anim_shoot
362                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
363                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
364                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
365                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
366                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
367                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
368                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
369         }
370         LOG_INFOF("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model);
371         return f;
372 }
373 void CSQCPlayer_FallbackFrame_Apply()
374 {SELFPARAM();
375         self.frame = CSQCPlayer_FallbackFrame(self.frame);
376         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
377 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
378         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
379         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
380 #endif
381 }
382
383 // FEATURE: auto tag_index
384 .entity tag_entity;
385 .int tag_entity_lastmodelindex;
386 .int tag_index;
387 void CSQCModel_AutoTagIndex_Apply()
388 {SELFPARAM();
389         if(self.tag_entity && wasfreed(self.tag_entity))
390                 self.tag_entity = world;
391
392         viewloc_SetTags();
393
394         MUTATOR_CALLHOOK(TagIndex_Update, self);
395
396         if(self.tag_networkentity)
397         {
398                 // we are ATTACHED!
399                 bool changed = 0;
400                 if(self.tag_entity.entnum != self.tag_networkentity)
401                 {
402                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
403                         changed = 1;
404                 }
405
406                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
407                 if(self.tag_entity.classname == "csqcmodel")
408                 {
409                         WITH(entity, self, self.tag_entity, CSQCModel_Hook_PreDraw((self.entnum >= 1 && self.entnum <= maxclients)));
410                 }
411
412                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
413                 {
414                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
415                         changed = 1;
416                 }
417                 if(changed)
418                 {
419                         if(self.tag_entity)
420                         {
421                                 // the best part is: IT EXISTS
422                                 if(substring(self.model, 0, 14) == "models/weapons")
423                                 {
424                                         if(substring(self.tag_entity.model, 0, 14) == "models/weapons")
425                                         {
426                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
427                                                 if(!self.tag_index)
428                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
429                                                 if(!self.tag_index)
430                                                 {
431                                                         // we need to prevent this from 'appening
432                                                         self.tag_entity = world;
433                                                         self.drawmask = 0;
434                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it\n");
435                                                 }
436                                         }
437                                         else if(self.tag_entity.isplayermodel)
438                                         {
439                                                 skeleton_loadinfo(self.tag_entity);
440                                                 self.tag_index = self.tag_entity.bone_weapon;
441                                         }
442                                 }
443
444                                 if(substring(self.tag_entity.model, 0, 14) == "models/weapons")
445                                 {
446                                         self.tag_index = gettagindex(self.tag_entity, "shot");
447                                         if(!self.tag_index)
448                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
449                                 }
450
451                                 MUTATOR_CALLHOOK(TagIndex_Apply, self);
452                         }
453                         else
454                         {
455                                 // damn, see you next frame
456                                 self.drawmask = 0;
457                         }
458                 }
459         }
460 }
461
462 // FEATURE: EF_NODRAW workalike
463 const int EF_BRIGHTFIELD        = BIT(0);
464 const int EF_BRIGHTLIGHT        = BIT(2);
465 const int EF_DIMLIGHT           = BIT(3);
466 const int EF_DOUBLESIDED        = BIT(15);
467 const int EF_NOSELFSHADOW       = BIT(16);
468 const int EF_DYNAMICMODELLIGHT = BIT(17);
469 const int EF_RESTARTANIM_BIT = BIT(20);
470 const int EF_TELEPORT_BIT = BIT(21);
471 const int MF_ROCKET  =  BIT(0); // leave a trail
472 const int MF_GRENADE =  BIT(1); // leave a trail
473 const int MF_GIB     =  BIT(2); // leave a trail
474 const int MF_ROTATE  =  BIT(3); // rotate (bonus items)
475 const int MF_TRACER  =  BIT(4); // green split trail
476 const int MF_ZOMGIB  =  BIT(5); // small blood trail
477 const int MF_TRACER2 =  BIT(6); // orange split trail
478 const int MF_TRACER3 = BIT(7); // purple trail
479 .int csqcmodel_effects;
480 .int csqcmodel_modelflags;
481 .int csqcmodel_traileffect;
482 void CSQCModel_Effects_PreUpdate()
483 {SELFPARAM();
484         self.effects = self.csqcmodel_effects;
485         self.modelflags = self.csqcmodel_modelflags;
486         self.traileffect = self.csqcmodel_traileffect;
487 }
488 void Reset_ArcBeam();
489 void CSQCModel_Effects_PostUpdate()
490 {SELFPARAM();
491         if (self == csqcplayer) {
492                 if (self.csqcmodel_teleported) {
493                         Reset_ArcBeam();
494                 }
495         }
496         self.csqcmodel_effects = self.effects;
497         self.csqcmodel_modelflags = self.modelflags;
498         self.csqcmodel_traileffect = self.traileffect;
499         self.effects = 0;
500         self.modelflags = 0;
501         if(self.csqcmodel_teleported)
502                 Projectile_ResetTrail(self, self.origin);
503 }
504 .int snd_looping;
505 void CSQCModel_Effects_Apply()
506 {SELFPARAM();
507         int eff = self.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
508         int tref = self.csqcmodel_traileffect;
509
510         self.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
511         self.effects = 0;
512         self.traileffect = 0;
513
514         if(eff & EF_BRIGHTFIELD)
515                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
516         // ignoring EF_MUZZLEFLASH
517         if(eff & EF_BRIGHTLIGHT)
518                 adddynamiclight(self.origin, 400, '3 3 3');
519         if(eff & EF_DIMLIGHT)
520                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
521         if((eff & EF_NODRAW) || (self.alpha < 0))
522                 self.drawmask = 0;
523         if(eff & EF_ADDITIVE)
524                 self.renderflags |= RF_ADDITIVE;
525         if(eff & EF_BLUE)
526                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
527         if(eff & EF_RED)
528                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
529         // ignoring EF_NOGUNBOB
530         if(eff & EF_FULLBRIGHT)
531                 self.renderflags |= RF_FULLBRIGHT;
532         if(eff & EF_FLAME)
533                 pointparticles(EFFECT_EF_FLAME, self.origin, '0 0 0', bound(0, frametime, 0.1));
534         if(eff & EF_STARDUST)
535                 pointparticles(EFFECT_EF_STARDUST, self.origin, '0 0 0', bound(0, frametime, 0.1));
536         if(eff & EF_NOSHADOW)
537                 self.renderflags |= RF_NOSHADOW;
538         if(eff & EF_NODEPTHTEST)
539                 self.renderflags |= RF_DEPTHHACK;
540         // ignoring EF_SELECTABLE
541         if(eff & EF_DOUBLESIDED)
542                 self.effects |= EF_DOUBLESIDED;
543         if(eff & EF_NOSELFSHADOW)
544                 self.effects |= EF_NOSELFSHADOW;
545         if(eff & EF_DYNAMICMODELLIGHT)
546                 self.renderflags |= RF_DYNAMICMODELLIGHT;
547         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
548         if(self.csqcmodel_modelflags & MF_ROCKET)
549                 tref = EFFECT_TR_ROCKET.m_id;
550         if(self.csqcmodel_modelflags & MF_GRENADE)
551                 tref = EFFECT_TR_GRENADE.m_id;
552         if(self.csqcmodel_modelflags & MF_GIB)
553                 tref = EFFECT_TR_BLOOD.m_id;
554         if(self.csqcmodel_modelflags & MF_ROTATE)
555         {
556                 self.renderflags |= RF_USEAXIS;
557                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
558         }
559         if(self.csqcmodel_modelflags & MF_TRACER)
560                 tref = EFFECT_TR_WIZSPIKE.m_id;
561         if(self.csqcmodel_modelflags & MF_ZOMGIB)
562                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
563         if(self.csqcmodel_modelflags & MF_TRACER2)
564                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
565         if(self.csqcmodel_modelflags & MF_TRACER3)
566                 tref = EFFECT_TR_VORESPIKE.m_id;
567
568         self.traileffect = tref;
569
570         if(self.drawmask)
571                 Projectile_DrawTrail(self, self.origin);
572         else
573                 Projectile_ResetTrail(self, self.origin);
574
575         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
576                 self.renderflags |= RF_ADDITIVE;
577                 // also special in CSQCPlayer_GlowMod_Apply
578
579         if(self.csqcmodel_modelflags & MF_ROCKET)
580         {
581                 if(!self.snd_looping)
582                 {
583                         sound(self, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_g_jetpack_attenuation);
584                         self.snd_looping = CH_TRIGGER_SINGLE;
585                 }
586         }
587         else
588         {
589                 if(self.snd_looping)
590                 {
591                         sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
592                         self.snd_looping = 0;
593                 }
594         }
595 }
596
597 // general functions
598 .int csqcmodel_predraw_run;
599 .int anim_frame;
600 .int anim_frame1time;
601 .int anim_frame2;
602 .int anim_frame2time;
603 .int anim_saveframe;
604 .int anim_saveframe1time;
605 .int anim_saveframe2;
606 .int anim_saveframe2time;
607 .int anim_prev_pmove_flags;
608 void CSQCModel_Hook_PreDraw(bool isplayer)
609 {SELFPARAM();
610         if(self.csqcmodel_predraw_run == framecount)
611                 return;
612         self.csqcmodel_predraw_run = framecount;
613
614         if(!self.modelindex || self.model == "null")
615         {
616                 self.drawmask = 0;
617                 return;
618         }
619         else
620                 self.drawmask = MASK_NORMAL;
621
622         if(self.isplayermodel) // this checks if it's a player MODEL!
623         {
624                 CSQCPlayer_ModelAppearance_Apply(self.entnum == player_localnum + 1);
625                 CSQCPlayer_LOD_Apply();
626
627                 if(!isplayer)
628                 {
629                         skeleton_loadinfo(self);
630                         bool doblend = (self.bone_upperbody >= 0);
631                         CSQCPlayer_FallbackFrame_Apply();
632                         if(doblend)
633                         {
634                                 skeleton_from_frames(self, self.csqcmodel_isdead);
635                         }
636                         else
637                         {
638                                 free_skeleton_from_frames(self);
639                                 // just in case, clear these (we're animating in frame and frame3)
640                                 self.lerpfrac = 0;
641                                 self.lerpfrac4 = 0;
642                         }
643                 }
644                 else
645                 {
646                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
647                         skeleton_loadinfo(self);
648                         bool doblend = (self.bone_upperbody >= 0);
649                         bool onground = 0;
650                         if(self == csqcplayer)
651                         {
652                                 if(IS_ONGROUND(self))
653                                         onground = 1;
654                                 self.anim_prev_pmove_flags = self.flags;
655                                 if(self.flags & FL_DUCKED)
656                                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DUCK, false);
657                                 else if(self.anim_state & ANIMSTATE_DUCK)
658                                         animdecide_setstate(self, self.anim_state - ANIMSTATE_DUCK, false);
659                         }
660                         else
661                         {
662                                 tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
663                                 if(trace_startsolid || trace_fraction < 1)
664                                         onground = 1;
665                         }
666                         animdecide_load_if_needed(self);
667                         animdecide_setimplicitstate(self, onground);
668                         animdecide_setframes(self, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
669                         int sf = 0;
670                         if(self.anim_saveframe != self.anim_frame || self.anim_saveframe1time != self.anim_frame1time)
671                                 sf |= CSQCMODEL_PROPERTY_FRAME;
672                         if(self.anim_saveframe2 != self.anim_frame2 || self.anim_saveframe2time != self.anim_frame2time)
673                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
674                         self.anim_saveframe = self.anim_frame;
675                         self.anim_saveframe1time = self.anim_frame1time;
676                         self.anim_saveframe2 = self.anim_frame2;
677                         self.anim_saveframe2time = self.anim_frame2time;
678                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
679                         // This ensures that .frame etc. are always written.
680                         CSQCModel_InterpolateAnimation_2To4_PreNote(sf | CSQCMODEL_PROPERTY_LERPFRAC);
681                         self.lerpfrac = (doblend ? 0.5 : 0);
682                         self.frame = self.anim_frame;
683                         self.frame1time = self.anim_frame1time;
684                         self.frame2 = self.anim_frame2;
685                         self.frame2time = self.anim_frame2time;
686                         CSQCModel_InterpolateAnimation_2To4_Note(sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
687                         CSQCModel_InterpolateAnimation_2To4_Do();
688                         if(doblend)
689                         {
690                                 skeleton_from_frames(self, self.csqcmodel_isdead);
691                         }
692                         else
693                         {
694                                 free_skeleton_from_frames(self);
695                                 // just in case, clear these (we're animating in frame and frame3)
696                                 self.lerpfrac = 0;
697                                 self.lerpfrac4 = 0;
698                         }
699                 }
700         }
701
702         CSQCModel_AutoTagIndex_Apply();
703
704         CSQCModel_Effects_Apply();
705 }
706
707 void CSQCModel_Hook_PreUpdate(bool isnew, bool isplayer, bool islocalplayer)
708 {SELFPARAM();
709         // interpolate v_angle
710         self.iflags |= IFLAG_V_ANGLE_X;
711         // revert to values from server
712         CSQCModel_Effects_PreUpdate();
713         if(self.isplayermodel)
714         {
715                 if(!isplayer)
716                         CSQCPlayer_FallbackFrame_PreUpdate();
717                 CSQCPlayer_ModelAppearance_PreUpdate();
718         }
719 }
720
721 void CSQCModel_Hook_PostUpdate(bool isnew, bool isplayer, bool islocalplayer)
722 {SELFPARAM();
723         // is it a player model? (shared state)
724         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/" || (substring(self.model, 0, 16) == "models/monsters/" && (self.entnum >= 1 && self.entnum <= maxclients)));
725
726         // save values set by server
727         if(self.isplayermodel)
728         {
729                 CSQCPlayer_ModelAppearance_PostUpdate();
730                 if(isplayer)
731                         CSQCPlayer_AnimDecide_PostUpdate(isnew);
732                 else
733                         CSQCPlayer_FallbackFrame_PostUpdate(isnew);
734         }
735         CSQCModel_Effects_PostUpdate();
736 }