qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw(float isplayer);
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 void CSQCPlayer_ForceModel_PreUpdate(void)
  96 {
  97         self.model = self.forceplayermodels_savemodel;
  98         self.modelindex = self.forceplayermodels_savemodelindex;
  99         self.skin = self.forceplayermodels_saveskin;
 100         self.colormap = self.forceplayermodels_savecolormap;
 101 }
 102 void CSQCPlayer_ForceModel_PostUpdate(void)
 103 {
 104         self.forceplayermodels_savemodel = self.model;
 105         self.forceplayermodels_savemodelindex = self.modelindex;
 106         self.forceplayermodels_saveskin = self.skin;
 107         self.forceplayermodels_savecolormap = self.colormap;
 108
 109         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 110         {
 111                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 112                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 113                 if(!self.forceplayermodels_isgoodmodel)
 114                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 115         }
 116 }
 117 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 118 {
 119         // which one is ALWAYS good?
 120         if not(forceplayermodels_goodmodel)
 121         {
 122                 entity e;
 123                 e = spawn();
 124                 precache_model(cvar_defstring("_cl_playermodel"));
 125                 setmodel(e, cvar_defstring("_cl_playermodel"));
 126                 forceplayermodels_goodmodel = e.model;
 127                 forceplayermodels_goodmodelindex = e.modelindex;
 128                 remove(e);
 129         }
 130
 131         // first, try finding it from the server
 132         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 133         {
 134                 if(islocalplayer)
 135                 {
 136                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 137                         {
 138                                 // trust server's idea of "own player model"
 139                                 forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 140                                 forceplayermodels_model = self.forceplayermodels_savemodel;
 141                                 forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 142                                 forceplayermodels_skin = self.forceplayermodels_saveskin;
 143                                 forceplayermodels_attempted = 1;
 144                         }
 145                 }
 146         }
 147
 148         // forcemodel finding
 149         if(!forceplayermodels_attempted)
 150         {
 151                 forceplayermodels_attempted = 1;
 152
 153                 // only if this failed, find it out on our own
 154                 entity e;
 155                 e = spawn();
 156                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 157                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 158                 forceplayermodels_model = e.model;
 159                 forceplayermodels_modelindex = e.modelindex;
 160                 forceplayermodels_skin = autocvar__cl_playerskin;
 161                 remove(e);
 162         }
 163
 164         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 165         {
 166                 entity e;
 167                 e = spawn();
 168                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 169                 forceplayermodels_myisgoodmodel = fexists(e.model);
 170                 forceplayermodels_mymodel = e.model;
 171                 forceplayermodels_mymodelindex = e.modelindex;
 172                 remove(e);
 173         }
 174
 175         // apply it
 176         float isfriend;
 177         float cm;
 178         cm = self.forceplayermodels_savecolormap;
 179         cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(self.colormap - 1, "colors")) + 1024);
 180
 181         if(teamplay)
 182                 isfriend = (cm == 1024 + 17 * myteam);
 183         else
 184                 isfriend = islocalplayer;
 185
 186         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 187         {
 188                 self.model = forceplayermodels_mymodel;
 189                 self.modelindex = forceplayermodels_mymodelindex;
 190                 self.skin = autocvar_cl_forcemyplayerskin;
 191         }
 192         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 193         {
 194                 self.model = forceplayermodels_model;
 195                 self.modelindex = forceplayermodels_modelindex;
 196                 self.skin = forceplayermodels_skin;
 197         }
 198         else if(self.forceplayermodels_isgoodmodel)
 199         {
 200                 self.model = self.forceplayermodels_savemodel;
 201                 self.modelindex = self.forceplayermodels_savemodelindex;
 202                 self.skin = self.forceplayermodels_saveskin;
 203         }
 204         else
 205         {
 206                 self.model = forceplayermodels_goodmodel;
 207                 self.modelindex = forceplayermodels_goodmodelindex;
 208                 self.skin = self.forceplayermodels_saveskin;
 209         }
 210
 211         // forceplayercolors too
 212         if(teamplay)
 213         {
 214                 // own team's color is never forced
 215                 float forcecolor_friend = 0;
 216                 float forcecolor_enemy = 0;
 217                 float teams_count = 0;
 218                 entity tm;
 219
 220                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 221                         if(tm.team != NUM_SPECTATOR)
 222                                 ++teams_count;
 223
 224                 if(autocvar_cl_forcemyplayercolors)
 225                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 226                 if(autocvar_cl_forceplayercolors && teams_count == 2)
 227                         forcecolor_enemy = 1024 + autocvar__cl_color;
 228
 229                 if(forcecolor_enemy && !forcecolor_friend)
 230                 {
 231                         // only enemy color is forced?
 232                         // verify it is not equal to the friend color
 233                         if(forcecolor_enemy == 1024 + 17 * myteam)
 234                                 forcecolor_enemy = 0;
 235                 }
 236
 237                 if(forcecolor_friend && !forcecolor_enemy)
 238                 {
 239                         // only friend color is forced?
 240                         // verify it is not equal to the enemy color
 241                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 242                                 // note: we even compare against our own team.
 243                                 // if we rejected because we matched our OWN team color,
 244                                 // this is not bad; we then simply keep our color as is
 245                                 // anyway.
 246                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 247                                         forcecolor_friend = 0;
 248                 }
 249
 250                 if(cm == 1024 + 17 * myteam)
 251                 {
 252                         if(forcecolor_friend)
 253                                 self.colormap = forcecolor_friend;
 254                 }
 255                 else
 256                 {
 257                         if(forcecolor_enemy)
 258                                 self.colormap = forcecolor_enemy;
 259                 }
 260         }
 261         else
 262         {
 263                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 264                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 265                 else if(autocvar_cl_forceplayercolors)
 266                         self.colormap = player_localnum + 1;
 267         }
 268 }
 269
 270 // FEATURE: fallback frames
 271 .float csqcmodel_saveframe;
 272 .float csqcmodel_saveframe2;
 273 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 274 .float csqcmodel_saveframe3;
 275 .float csqcmodel_saveframe4;
 276 #endif
 277 .float csqcmodel_framecount;
 278
 279 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 280 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 281 {
 282         self.frame = self.csqcmodel_saveframe;
 283         self.frame2 = self.csqcmodel_saveframe2;
 284 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 285         self.frame3 = self.csqcmodel_saveframe3;
 286         self.frame4 = self.csqcmodel_saveframe4;
 287 #endif
 288 }
 289 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 290 {
 291         self.csqcmodel_saveframe = self.frame;
 292         self.csqcmodel_saveframe2 = self.frame2;
 293 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 294         self.csqcmodel_saveframe3 = self.frame3;
 295         self.csqcmodel_saveframe4 = self.frame4;
 296 #endif
 297
 298         // hack for death animations: set their frametime to zero in case a
 299         // player "pops in"
 300         if(isnew)
 301         {
 302 #define FIX_FRAMETIME(f,ft) \
 303                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 304                 { \
 305                         self.ft = self.death_time; \
 306                 }
 307                 FIX_FRAMETIME(frame, frame1time)
 308                 FIX_FRAMETIME(frame2, frame2time)
 309 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 310                 FIX_FRAMETIME(frame3, frame3time)
 311                 FIX_FRAMETIME(frame4, frame4time)
 312 #endif
 313         }
 314         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 315 }
 316 float CSQCPlayer_FallbackFrame(float f)
 317 {
 318         if(frameduration(self.modelindex, f) > 0)
 319                 return f; // goooooood
 320         if(frameduration(self.modelindex, 1) <= 0)
 321                 return f; // this is a static model. We can't fix it if we wanted to
 322         switch(f)
 323         {
 324                 case 23: return 11; // anim_melee -> anim_shoot
 325                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 326                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 327                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 328                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 329                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 330                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 331                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 332         }
 333         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 334         return f;
 335 }
 336 void CSQCPlayer_FallbackFrame_Apply(void)
 337 {
 338         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 339         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 340 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 341         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 342         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 343 #endif
 344 }
 345
 346 // FEATURE: auto tag_index
 347 .entity tag_entity;
 348 .float tag_entity_lastmodelindex;
 349 .float tag_index;
 350 void CSQCModel_AutoTagIndex_Apply(void)
 351 {
 352         if(self.tag_entity && wasfreed(self.tag_entity))
 353                 self.tag_entity = world;
 354
 355         if(self.tag_networkentity)
 356         {
 357                 // we are ATTACHED!
 358                 float changed = 0;
 359                 if(self.tag_entity.entnum != self.tag_networkentity)
 360                 {
 361                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 362                         changed = 1;
 363                 }
 364
 365                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 366                 if(self.tag_entity.classname == "csqcmodel")
 367                 {
 368                         entity oldself = self;
 369                         self = self.tag_entity;
 370                         CSQCModel_Hook_PreDraw((self.entnum >= 1 && self.entnum <= maxclients));
 371                         self = oldself;
 372                 }
 373
 374                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 375                 {
 376                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 377                         changed = 1;
 378                 }
 379                 if(changed)
 380                 {
 381                         if(self.tag_entity)
 382                         {
 383                                 // the best part is: IT EXISTS
 384                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 385                                 {
 386                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 387                                         {
 388                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 389                                                 if(!self.tag_index)
 390                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 391                                                 if(!self.tag_index)
 392                                                 {
 393                                                         // we need to prevent this from 'appening
 394                                                         self.tag_entity = world;
 395                                                         self.drawmask = 0;
 396                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 397                                                 }
 398                                         }
 399                                         else if(self.tag_entity.isplayermodel)
 400                                         {
 401                                                 skeleton_loadinfo(self.tag_entity);
 402                                                 self.tag_index = self.tag_entity.bone_weapon;
 403                                         }
 404                                 }
 405
 406                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 407                                 {
 408                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 409                                         if(!self.tag_index)
 410                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 411                                 }
 412                         }
 413                         else
 414                         {
 415                                 // damn, see you next frame
 416                                 self.drawmask = 0;
 417                         }
 418                 }
 419         }
 420 }
 421
 422 // FEATURE: EF_NODRAW workalike
 423 float EF_BRIGHTFIELD    = 1;
 424 float EF_BRIGHTLIGHT    = 4;
 425 float EF_DIMLIGHT       = 8;
 426 float EF_DOUBLESIDED = 32768;
 427 float EF_NOSELFSHADOW = 65536;
 428 float EF_DYNAMICMODELLIGHT = 131072;
 429 float EF_RESTARTANIM_BIT = 1048576;
 430 float EF_TELEPORT_BIT = 2097152;
 431 float MF_ROCKET  =   1; // leave a trail
 432 float MF_GRENADE =   2; // leave a trail
 433 float MF_GIB     =   4; // leave a trail
 434 float MF_ROTATE  =   8; // rotate (bonus items)
 435 float MF_TRACER  =  16; // green split trail
 436 float MF_ZOMGIB  =  32; // small blood trail
 437 float MF_TRACER2 =  64; // orange split trail
 438 float MF_TRACER3 = 128; // purple trail
 439 .float csqcmodel_effects;
 440 .float csqcmodel_modelflags;
 441 void CSQCModel_Effects_PreUpdate(void)
 442 {
 443         self.effects = self.csqcmodel_effects;
 444         self.modelflags = self.csqcmodel_modelflags;
 445 }
 446 void CSQCModel_Effects_PostUpdate(void)
 447 {
 448         self.csqcmodel_effects = self.effects;
 449         self.csqcmodel_modelflags = self.modelflags;
 450         self.effects = 0;
 451         self.modelflags = 0;
 452         if(self.csqcmodel_teleported)
 453                 Projectile_ResetTrail(self.origin);
 454 }
 455 .float snd_looping;
 456 void CSQCModel_Effects_Apply(void)
 457 {
 458         float eff = self.csqcmodel_effects;
 459         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 460
 461         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 462         self.effects = 0;
 463         self.traileffect = 0;
 464
 465         if(eff & EF_BRIGHTFIELD)
 466                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 467         // ignoring EF_MUZZLEFLASH
 468         if(eff & EF_BRIGHTLIGHT)
 469                 adddynamiclight(self.origin, 400, '3 3 3');
 470         if(eff & EF_DIMLIGHT)
 471                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 472         if((eff & EF_NODRAW) || (self.alpha < 0))
 473                 self.drawmask = 0;
 474         if(eff & EF_ADDITIVE)
 475                 self.renderflags |= RF_ADDITIVE;
 476         if(eff & EF_BLUE)
 477                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 478         if(eff & EF_RED)
 479                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 480         // ignoring EF_NOGUNBOB
 481         if(eff & EF_FULLBRIGHT)
 482                 self.renderflags |= RF_FULLBRIGHT;
 483         if(eff & EF_FLAME)
 484                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 485         if(eff & EF_STARDUST)
 486                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 487         if(eff & EF_NOSHADOW)
 488                 self.renderflags |= RF_NOSHADOW;
 489         if(eff & EF_NODEPTHTEST)
 490                 self.renderflags |= RF_DEPTHHACK;
 491         // ignoring EF_SELECTABLE
 492         if(eff & EF_DOUBLESIDED)
 493                 self.effects |= EF_DOUBLESIDED;
 494         if(eff & EF_NOSELFSHADOW)
 495                 self.effects |= EF_NOSELFSHADOW;
 496         if(eff & EF_DYNAMICMODELLIGHT)
 497                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 498         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 499         if(self.csqcmodel_modelflags & MF_ROCKET)
 500                 self.traileffect = particleeffectnum("TR_ROCKET");
 501         if(self.csqcmodel_modelflags & MF_GRENADE)
 502                 self.traileffect = particleeffectnum("TR_GRENADE");
 503         if(self.csqcmodel_modelflags & MF_GIB)
 504                 self.traileffect = particleeffectnum("TR_BLOOD");
 505         if(self.csqcmodel_modelflags & MF_ROTATE)
 506         {
 507                 self.renderflags |= RF_USEAXIS;
 508                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 509         }
 510         if(self.csqcmodel_modelflags & MF_TRACER)
 511                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 512         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 513                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 514         if(self.csqcmodel_modelflags & MF_TRACER2)
 515                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 516         if(self.csqcmodel_modelflags & MF_TRACER3)
 517                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 518
 519         if(self.drawmask)
 520                 Projectile_DrawTrail(self.origin);
 521         else
 522                 Projectile_ResetTrail(self.origin);
 523
 524         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 525                 self.renderflags |= RF_ADDITIVE;
 526                 // also special in CSQCPlayer_GlowMod_Apply
 527
 528         if(self.csqcmodel_modelflags & MF_ROCKET)
 529         {
 530                 if(!self.snd_looping)
 531                 {
 532                         sound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 533                         self.snd_looping = CH_TRIGGER_SINGLE;
 534                 }
 535         }
 536         else
 537         {
 538                 if(self.snd_looping)
 539                 {
 540                         sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 541                         self.snd_looping = 0;
 542                 }
 543         }
 544 }
 545
 546 void CSQCPlayer_Precache()
 547 {
 548         precache_sound("misc/jetpack_fly.wav");
 549 }
 550
 551 // FEATURE: auto glowmod
 552 .vector glowmod;
 553 void CSQCPlayer_GlowMod_Apply(void)
 554 {
 555         float cm = self.colormap;
 556
 557         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 558                 cm = 1024;
 559
 560         if(self.colormap > 0)
 561                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 562         else
 563                 self.glowmod = '1 1 1';
 564
 565         if(autocvar_cl_deathglow > 0)
 566                 if(self.csqcmodel_isdead)
 567                 {
 568                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 569                         // prevent the zero vector
 570                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 571                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 572                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 573                 }
 574 }
 575
 576 // general functions
 577 .float csqcmodel_predraw_run;
 578 .float anim_frame;
 579 .float anim_frame1time;
 580 .float anim_frame2;
 581 .float anim_frame2time;
 582 .float anim_saveframe;
 583 .float anim_saveframe1time;
 584 .float anim_saveframe2;
 585 .float anim_saveframe2time;
 586 .float anim_prev_pmove_flags;
 587 void CSQCModel_Hook_PreDraw(float isplayer)
 588 {
 589         if(self.csqcmodel_predraw_run == framecount)
 590                 return;
 591         self.csqcmodel_predraw_run = framecount;
 592
 593         if(!self.modelindex || self.model == "null")
 594         {
 595                 self.drawmask = 0;
 596                 return;
 597         }
 598         else
 599                 self.drawmask = MASK_NORMAL;
 600
 601         if(self.isplayermodel) // this checks if it's a player MODEL!
 602         {
 603                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 604                 CSQCPlayer_GlowMod_Apply();
 605                 CSQCPlayer_LOD_Apply();
 606                 if(!isplayer)
 607                         CSQCPlayer_FallbackFrame_Apply();
 608                 else
 609                 {
 610                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 611                         skeleton_loadinfo(self);
 612                         float doblend = (self.bone_upperbody >= 0);
 613                         float onground = 0;
 614                         if(self == csqcplayer)
 615                         {
 616                                 if(self.pmove_flags & PMF_ONGROUND)
 617                                         onground = 1;
 618                                 self.anim_prev_pmove_flags = self.pmove_flags;
 619                                 if(self.pmove_flags & PMF_DUCKED)
 620                                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DUCK, FALSE);
 621                                 else if(self.anim_state & ANIMSTATE_DUCK)
 622                                         animdecide_setstate(self, self.anim_state - ANIMSTATE_DUCK, FALSE);
 623                         }
 624                         else
 625                         {
 626                                 tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 627                                 if(trace_startsolid || trace_fraction < 1)
 628                                         onground = 1;
 629                         }
 630                         animdecide_init(self);
 631                         animdecide_setimplicitstate(self, onground);
 632                         animdecide_setframes(self, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 633                         float sf = 0;
 634                         if(self.anim_saveframe != self.anim_frame || self.anim_saveframe1time != self.anim_frame1time)
 635                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 636                         if(self.anim_saveframe2 != self.anim_frame2 || self.anim_saveframe2time != self.anim_frame2time)
 637                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 638                         self.anim_saveframe = self.anim_frame;
 639                         self.anim_saveframe1time = self.anim_frame1time;
 640                         self.anim_saveframe2 = self.anim_frame2;
 641                         self.anim_saveframe2time = self.anim_frame2time;
 642                         if(sf)
 643                         {
 644                                 CSQCModel_InterpolateAnimation_2To4_PreNote(sf | CSQCMODEL_PROPERTY_LERPFRAC);
 645                                 self.lerpfrac = (doblend ? 0.5 : 0);
 646                                 self.frame = self.anim_frame;
 647                                 self.frame1time = self.anim_frame1time;
 648                                 self.frame2 = self.anim_frame2;
 649                                 self.frame2time = self.anim_frame2time;
 650                                 CSQCModel_InterpolateAnimation_2To4_Note(sf | CSQCMODEL_PROPERTY_LERPFRAC, FALSE);
 651                         }
 652                         CSQCModel_InterpolateAnimation_2To4_Do();
 653                         if(doblend)
 654                         {
 655                                 skeleton_from_frames(self, self.csqcmodel_isdead);
 656                         }
 657                         else
 658                         {
 659                                 free_skeleton_from_frames(self);
 660                                 // just in case, clear these (we're animating in frame and frame3)
 661                                 self.lerpfrac = 0;
 662                                 self.lerpfrac4 = 0;
 663                         }
 664                 }
 665         }
 666
 667         CSQCModel_AutoTagIndex_Apply();
 668
 669         CSQCModel_Effects_Apply();
 670 }
 671
 672 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 673 {
 674         // interpolate v_angle
 675         self.iflags |= IFLAG_V_ANGLE_X;
 676         // revert to values from server
 677         CSQCModel_Effects_PreUpdate();
 678         if(self.isplayermodel)
 679         {
 680                 if(!isplayer)
 681                         CSQCPlayer_FallbackFrame_PreUpdate();
 682                 CSQCPlayer_ForceModel_PreUpdate();
 683         }
 684 }
 685
 686 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 687 {
 688         // is it a player model? (shared state)
 689         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 690
 691         // save values set by server
 692         if(self.isplayermodel)
 693         {
 694                 CSQCPlayer_ForceModel_PostUpdate();
 695                 if(!isplayer)
 696                         CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 697         }
 698         CSQCModel_Effects_PostUpdate();
 699 }