3cb9a8c599aebc6fcdb3b032ce56bd48a05b143f
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / damage.qc
1 void DamageEffect_Think()
2 {
3         // if particle distribution is enabled, slow ticrate by total number of damages
4         if(autocvar_cl_damageeffect_distribute)
5                 self.nextthink = time + autocvar_cl_damageeffect_ticrate * self.owner.total_damages;
6         else
7                 self.nextthink = time + autocvar_cl_damageeffect_ticrate;
8
9         if(time >= self.cnt || !self.owner || !self.owner.modelindex || !self.owner.drawmask)
10         {
11                 // time is up or the player got gibbed / disconnected
12                 self.owner.total_damages = max(0, self.owner.total_damages - 1);
13                 remove(self);
14                 return;
15         }
16         if(self.state && !self.owner.csqcmodel_isdead)
17         {
18                 // if the player was dead but is now alive, it means he respawned
19                 // if so, clear his damage effects, or damages from his dead body will be copied back
20                 self.owner.total_damages = max(0, self.owner.total_damages - 1);
21                 remove(self);
22                 return;
23         }
24         self.state = self.owner.csqcmodel_isdead;
25 #ifdef COMPAT_XON050_ENGINE
26         if(self.owner.isplayermodel && (self.owner.entnum == player_localentnum || self.owner.entnum == spectatee_status) && !autocvar_chase_active)
27 #else
28         if(self.owner.isplayermodel && (self.owner.entnum == player_localentnum) && !autocvar_chase_active)
29 #endif
30                 return; // if we aren't using a third person camera, hide our own effects
31
32         // now generate the particles
33         vector org;
34         org = gettaginfo(self, 0); // origin at attached location
35         pointparticles(self.team, org, '0 0 0', 1);
36 }
37
38 void DamageEffect(vector hitorg, float dmg, float type, float specnum)
39 {
40         // particle effects for players and objects damaged by weapons (eg: flames coming out of victims shot with rockets)
41
42         float life, nearestbone = 0;
43         string specstr, effectname;
44         entity e;
45
46         if(!autocvar_cl_damageeffect || autocvar_cl_gentle || autocvar_cl_gentle_damage)
47                 return;
48         if(!self || !self.modelindex || !self.drawmask)
49                 return;
50
51         // if this is a rigged mesh, the effect will show on the bone where damage was dealt
52         // we do this by choosing the skeletal bone closest to the impact, and attaching our entity to it
53         // if there's no skeleton, object origin will automatically be selected
54         FOR_EACH_TAG(self)
55         {
56                 if(!tagnum)
57                         continue; // skip empty bones
58                 // blacklist bones positioned outside the mesh, or the effect will be floating
59                 // TODO: Do we have to do it this way? Why do these bones exist at all?
60                 if(gettaginfo_name == "master" || gettaginfo_name == "knee_L" || gettaginfo_name == "knee_R" || gettaginfo_name == "leg_L" || gettaginfo_name == "leg_R")
61                         continue; // player model bone blacklist
62
63                 // now choose the bone closest to impact origin
64                 if(nearestbone == 0 || vlen(hitorg - gettaginfo(self, tagnum)) <= vlen(hitorg - gettaginfo(self, nearestbone)))
65                         nearestbone = tagnum;
66         }
67         gettaginfo(self, nearestbone); // set gettaginfo_name
68
69         // return if we reached our damage effect limit or damages are disabled
70         // TODO: When the limit is reached, it would be better if the oldest damage was removed instead of not adding a new one
71         if(nearestbone)
72         {
73                 if(self.total_damages >= autocvar_cl_damageeffect_bones)
74                         return; // allow multiple damages on skeletal models
75         }
76         else
77         {
78                 if(autocvar_cl_damageeffect < 2 || self.total_damages)
79                         return; // allow a single damage on non-skeletal models
80         }
81
82         life = bound(autocvar_cl_damageeffect_lifetime_min, dmg * autocvar_cl_damageeffect_lifetime, autocvar_cl_damageeffect_lifetime_max);
83         specstr = species_prefix(specnum);
84         type = DEATH_WEAPONOF(type);
85         e = get_weaponinfo(type);
86
87         effectname = strcat("damage_", e.netname);
88
89         // if damage was dealt with a bullet weapon, our effect is blood
90         // since blood is species dependent, include the species tag
91         if(type == WEP_SHOTGUN || type == WEP_UZI || type == WEP_RIFLE) // WEAPONTODO: when we kill shells and bullets, what happens to this?
92         {
93                 if(self.isplayermodel)
94                 {
95                         effectname = strcat(effectname, "_", specstr);
96                         effectname = substring(effectname, 0, strlen(effectname) - 1); // remove the _ symbol at the end of the species tag
97                 }
98                 else
99                         return; // objects don't bleed
100         }
101
102         e = spawn();
103         setmodel(e, "null"); // necessary to attach and read origin
104         setattachment(e, self, gettaginfo_name); // attach to the given bone
105         e.classname = "damage";
106         e.owner = self;
107         e.cnt = time + life;
108         e.team = particleeffectnum(effectname);
109         e.think = DamageEffect_Think;
110         e.nextthink = time;
111         self.total_damages += 1;
112 }
113
114 void Ent_DamageInfo(float isNew)
115 {
116         float dmg, rad, edge, thisdmg, forcemul, species, hitplayer = FALSE;
117         vector force, thisforce;
118         entity oldself;
119
120         oldself = self;
121
122         w_deathtype = ReadShort();
123         w_issilent = (w_deathtype & 0x8000);
124         w_deathtype = (w_deathtype & 0x7FFF);
125
126         w_org_x = ReadCoord();
127         w_org_y = ReadCoord();
128         w_org_z = ReadCoord();
129
130         dmg = ReadByte();
131         rad = ReadByte();
132         edge = ReadByte();
133         force = decompressShortVector(ReadShort());
134         species = ReadByte();
135
136         if (!isNew)
137                 return;
138
139         if(rad < 0)
140         {
141                 rad = -rad;
142                 forcemul = -1;
143         }
144         else
145                 forcemul = 1;
146
147         for(self = findradius(w_org, rad + MAX_DAMAGEEXTRARADIUS); self; self = self.chain)
148         {
149                 // attached ents suck
150                 if(self.tag_entity)
151                         continue;
152
153                 vector nearest = NearestPointOnBox(self, w_org);
154                 if(rad)
155                 {
156                         thisdmg = ((vlen (nearest - w_org) - bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
157                         if(thisdmg >= 1)
158                                 continue;
159                         if(thisdmg < 0)
160                                 thisdmg = 0;
161                         if(dmg)
162                         {
163                                 thisdmg = dmg + (edge - dmg) * thisdmg;
164                                 thisforce = forcemul * vlen(force) * (thisdmg / dmg) * normalize(self.origin - w_org);
165                         }
166                         else
167                         {
168                                 thisdmg = 0;
169                                 thisforce = forcemul * vlen(force) * normalize(self.origin - w_org);
170                         }
171                 }
172                 else
173                 {
174                         if(vlen(nearest - w_org) > bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS))
175                                 continue;
176
177                         thisdmg = dmg;
178                         thisforce = forcemul * force;
179                 }
180
181                 if(self.damageforcescale)
182                         if(vlen(thisforce))
183                         {
184                                 self.move_velocity = self.move_velocity + damage_explosion_calcpush(self.damageforcescale * thisforce, self.move_velocity, autocvar_g_balance_damagepush_speedfactor);
185                                 self.move_flags &= ~FL_ONGROUND;
186                         }
187
188                 if(w_issilent)
189                         self.silent = 1;
190
191                 if(self.event_damage)
192                         self.event_damage(thisdmg, w_deathtype, w_org, thisforce);
193
194                 DamageEffect(w_org, thisdmg, w_deathtype, species);
195
196                 if(self.isplayermodel)
197                         hitplayer = TRUE; // this impact damaged a player
198         }
199
200         self = oldself;
201
202         if(DEATH_ISVEHICLE(w_deathtype))
203         {
204                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
205                 if(trace_plane_normal != '0 0 0')
206                         w_backoff = trace_plane_normal;
207                 else
208                         w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
209
210                 setorigin(self, w_org + w_backoff * 2); // for sound() calls
211
212                 switch(w_deathtype)
213                 {
214                         case DEATH_VH_CRUSH:
215                                 break;
216
217                         // spiderbot
218                         case DEATH_VH_SPID_MINIGUN:
219                                 string _snd;
220                                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
221                                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTEN_NORM);
222                                 pointparticles(particleeffectnum("spiderbot_minigun_impact"), self.origin, w_backoff * 1000, 1);
223                                 break;
224                         case DEATH_VH_SPID_ROCKET:
225                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
226                                 pointparticles(particleeffectnum("spiderbot_rocket_explode"), self.origin, w_backoff * 1000, 1);
227                                 break;
228                         case DEATH_VH_SPID_DEATH:
229                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_MIN);
230                                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
231                                 break;
232
233                         case DEATH_VH_WAKI_GUN:
234                                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTEN_NORM);
235                                 pointparticles(particleeffectnum("wakizashi_gun_impact"), self.origin, w_backoff * 1000, 1);
236                                 break;
237                         case DEATH_VH_WAKI_ROCKET:
238                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
239                                 pointparticles(particleeffectnum("wakizashi_rocket_explode"), self.origin, w_backoff * 1000, 1);
240                                 break;
241                         case DEATH_VH_WAKI_DEATH:
242                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_MIN);
243                                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
244                                 break;
245
246                         case DEATH_VH_RAPT_CANNON:
247                                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTEN_NORM);
248                                 pointparticles(particleeffectnum("raptor_cannon_impact"), self.origin, w_backoff * 1000, 1);
249                                 break;
250                         case DEATH_VH_RAPT_FRAGMENT:
251                                 float i;
252                                 vector ang, vel;
253                                 for(i = 1; i < 4; ++i)
254                                 {
255                                         vel = normalize(w_org - (w_org + normalize(force) * 16)) + randomvec() * 128;
256                                         ang = vectoangles(vel);
257                                         RaptorCBShellfragToss(w_org, vel, ang + '0 0 1' * (120 * i));
258                                 }
259                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
260                                 pointparticles(particleeffectnum("raptor_bomb_spread"), self.origin, w_backoff * 1000, 1);
261                                 break;
262                         case DEATH_VH_RAPT_BOMB:
263                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
264                                 pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, w_backoff * 1000, 1);
265                                 break;
266                         case DEATH_VH_RAPT_DEATH:
267                                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTEN_MIN);
268                                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
269                                 break;
270                         case DEATH_VH_BUMB_GUN:
271                                 sound(self, CH_SHOTS, "weapons/fireball_impact2.wav", VOL_BASE, ATTEN_NORM);
272                                 pointparticles(particleeffectnum("bigplasma_impact"), self.origin, w_backoff * 1000, 1);
273                                 break;
274                 }
275         }
276
277
278         if(DEATH_ISTURRET(w_deathtype))
279         {
280                 string _snd;
281                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
282                 if(trace_plane_normal != '0 0 0')
283                         w_backoff = trace_plane_normal;
284                 else
285                         w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
286
287                 setorigin(self, w_org + w_backoff * 2); // for sound() calls
288
289                 switch(w_deathtype)
290                 {
291                          case DEATH_TURRET_EWHEEL:
292                                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTEN_MIN);
293                                 pointparticles(particleeffectnum("laser_impact"), self.origin, w_backoff * 1000, 1);
294                                 break;
295
296                          case DEATH_TURRET_FLAC:
297                                 pointparticles(particleeffectnum("hagar_explode"), w_org, '0 0 0', 1);
298                                 _snd = strcat("weapons/hagexp", ftos(1 + rint(random() * 2)), ".waw");
299                                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTEN_NORM);
300                                 break;
301
302                          case DEATH_TURRET_MLRS:
303                          case DEATH_TURRET_HK:
304                          case DEATH_TURRET_WALK_ROCKET:
305                          case DEATH_TURRET_HELLION:
306                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_MIN);
307                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, w_backoff * 1000, 1);
308                                 break;
309
310                          case DEATH_TURRET_MACHINEGUN:
311                          case DEATH_TURRET_WALK_GUN:
312                                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
313                                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTEN_NORM);
314                                 pointparticles(particleeffectnum("machinegun_impact"), self.origin, w_backoff * 1000, 1);
315                                 break;
316
317                          case DEATH_TURRET_PLASMA:
318                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_MIN);
319                                 pointparticles(particleeffectnum("electro_impact"), self.origin, w_backoff * 1000, 1);
320                                 break;
321
322                          case DEATH_TURRET_WALK_MEELE:
323                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTEN_MIN);
324                                 pointparticles(particleeffectnum("TE_SPARK"), self.origin, w_backoff * 1000, 1);
325                                 break;
326
327                          case DEATH_TURRET_PHASER:
328                                 break;
329
330                          case DEATH_TURRET_TESLA:
331                                 te_smallflash(self.origin);
332                                 break;
333
334                 }
335         }
336
337         // TODO spawn particle effects and sounds based on w_deathtype
338         if(!DEATH_ISSPECIAL(w_deathtype))
339         if(!hitplayer || rad) // don't show ground impacts for hitscan weapons if a player was hit
340         {
341                 float hitwep;
342
343                 hitwep = DEATH_WEAPONOFWEAPONDEATH(w_deathtype);
344                 w_random = prandom();
345
346                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
347                 if(trace_fraction < 1 && hitwep != WEP_NEX && hitwep != WEP_MINSTANEX)
348                         w_backoff = trace_plane_normal;
349                 else
350                         w_backoff = -1 * normalize(force);
351                 setorigin(self, w_org + w_backoff * 2); // for sound() calls
352
353                 WEP_ACTION(hitwep, WR_IMPACTEFFECT);
354         }
355 }