speed up more csqc ent drawing
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / gibs.qc
1 .float silent;
2
3 void Gib_Delete()
4 {
5         remove(self);
6 }
7
8 string species_prefix(float specnum)
9 {
10         switch(specnum)
11         {
12                 case SPECIES_HUMAN:       return "";
13                 case SPECIES_ALIEN:       return "alien_";
14                 case SPECIES_ROBOT_SHINY: return "robot_";
15                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
16                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
17                 case SPECIES_ANIMAL:      return "animal_";
18                 case SPECIES_RESERVED:    return "reserved_";
19                 default:         return "";
20         }
21 }
22
23 void Gib_setmodel(entity gib, string mdlname, float specnum)
24 {
25         switch(specnum)
26         {
27                 case SPECIES_ROBOT_RUSTY:
28                 case SPECIES_ROBOT_SHINY:
29                 case SPECIES_ROBOT_SOLID:
30                         if(specnum != SPECIES_ROBOT_SOLID || mdlname == "models/gibs/chunk.mdl")
31                         {
32                                 if(mdlname == "models/gibs/bloodyskull.md3")
33                                         setmodel(gib, "models/gibs/robo.md3");
34                                 else
35                                         setmodel(gib, strcat("models/gibs/robo", ftos(floor(random() * 8) + 1), ".md3"));
36                                 if(specnum == SPECIES_ROBOT_SHINY)
37                                 {
38                                         gib.skin = 1;
39                                         gib.colormod = '2 2 2';
40                                 }
41                                 gib.scale = 1;
42                                 break;
43                         }
44                 default:
45                         setmodel(gib, mdlname);
46                         gib.skin = specnum;
47                         break;
48         }
49 }
50
51 void new_te_bloodshower (float ef, vector org, float explosionspeed, float howmany)
52 {
53         float i, pmod;
54         pmod = cvar("cl_particles_quality");
55         for (i = 0; i < 250 * pmod; ++i)
56                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 250);
57 }
58
59 void SUB_RemoveOnNoImpact()
60 {
61         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
62                 Gib_Delete();
63 }
64
65 void Gib_Touch()
66 {
67         // TODO maybe bounce of walls, make more gibs, etc.
68
69         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
70         {
71                 Gib_Delete();
72                 return;
73         }
74
75         if(!self.silent)
76                 sound(self, CHAN_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
77         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
78
79         Gib_Delete();
80 }
81
82 void Gib_Draw()
83 {
84         vector oldorg;
85         oldorg = self.origin;
86
87         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
88         if(wasfreed(self))
89                 return;
90
91         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
92                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
93         else
94                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
95
96         self.renderflags = 0;
97         self.alpha = bound(0, self.nextthink - time, 1);
98
99         if(self.alpha < ALPHA_MIN_VISIBLE)
100         {
101                 self.drawmask = 0;
102                 Gib_Delete();
103         }
104 }
105
106 void TossGib (string mdlname, vector org, vector vconst, vector vrand, float specnum, float destroyontouch, float issilent)
107 {
108         entity gib;
109
110         // TODO remove some gibs according to cl_nogibs
111         gib = RubbleNew("gib");
112         gib.move_movetype = MOVETYPE_BOUNCE;
113         gib.gravity = 1;
114         gib.solid = SOLID_CORPSE;
115         gib.cnt = specnum;
116         gib.silent = issilent;
117         Gib_setmodel(gib, mdlname, specnum);
118
119         setsize (gib, '-8 -8 -8', '8 8 8');
120
121         gib.draw = Gib_Draw;
122         if(destroyontouch)
123                 gib.move_touch = Gib_Touch;
124         else
125                 gib.move_touch = SUB_RemoveOnNoImpact;
126
127         gib.move_origin = gib.origin = org;
128         gib.move_velocity = vconst * cvar_or("cl_gibs_velocity_scale", 1) + vrand * cvar_or("cl_gibs_velocity_random", 1) + '0 0 1' * cvar("cl_gibs_velocity_up");
129         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity);
130         gib.move_time = time;
131         gib.damageforcescale = cvar_or("cl_gibs_damageforcescale", 3.5);
132
133         gib.nextthink = time + cvar_or("cl_gibs_lifetime", 14) * (1 + prandom() * 0.15);
134         gib.drawmask = MASK_NORMAL;
135
136         RubbleLimit("gib", cvar_or("cl_gibs_maxcount",100), Gib_Delete);
137 }
138
139 void Ent_GibSplash(float isNew)
140 {
141         float amount, type, specnum;
142         vector org, vel;
143         string specstr;
144         float issilent;
145         string gentle_prefix;
146
147         float c, randomvalue;
148
149         type = ReadByte(); // gibbage type
150         amount = ReadByte() / 16.0; // gibbage amount
151         org_x = ReadShort() * 4 + 2;
152         org_y = ReadShort() * 4 + 2;
153         org_z = ReadShort() * 4 + 2;
154         vel = decompressShortVector(ReadShort());
155
156         if(cvar("cl_gentle_gibs") || cvar("cl_gentle"))
157                 type |= 0x80; // set gentle bit
158
159         if(type & 0x80)
160         {
161                 if(cvar("cl_gentle_gibs") == 2)
162                         gentle_prefix = "";
163                 else if(cvar("cl_gentle_gibs") == 3) 
164                         gentle_prefix = "happy_";
165                 else
166                         gentle_prefix = "morphed_";
167         }
168         else if(cvar("cl_particlegibs"))
169         {
170                 type |= 0x80;
171                 gentle_prefix = "particlegibs_";
172         }
173
174         if not(cvar("cl_gentle_gibs") || cvar("cl_gentle"))
175                 amount *= 1 - cvar("cl_nogibs");
176
177         if(cvar("ekg"))
178                 amount *= 5;
179
180         if(amount <= 0 || !isNew)
181                 return;
182
183         self.origin = org; // for the sounds
184
185         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
186         issilent = (type & 0x40);
187         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
188         specstr = species_prefix(specnum);
189
190         switch(type)
191         {
192                 case 0x01:
193                         if(!issilent)
194                                 sound (self, CHAN_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
195
196                         if(prandom() < amount)
197                                 TossGib ("models/gibs/eye.md3", org, vel, prandomvec() * 150, specnum, 0, issilent);
198                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
199                         if(prandom() < amount)
200                                 TossGib ("models/gibs/bloodyskull.md3", org + 16 * prandomvec(), vel, prandomvec() * 100, specnum, 0, issilent);
201
202                         for(c = 0; c < amount; ++c)
203                         {
204                                 randomvalue = amount - c;
205
206                                 if(prandom() < randomvalue)
207                                         TossGib ("models/gibs/arm.md3", org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
208                                 if(prandom() < randomvalue)
209                                         TossGib ("models/gibs/arm.md3", org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
210                                 if(prandom() < randomvalue)
211                                         TossGib ("models/gibs/chest.md3", org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
212                                 if(prandom() < randomvalue)
213                                         TossGib ("models/gibs/smallchest.md3", org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
214                                 if(prandom() < randomvalue)
215                                         TossGib ("models/gibs/leg1.md3", org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
216                                 if(prandom() < randomvalue)
217                                         TossGib ("models/gibs/leg2.md3", org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
218
219                                 // these splat on impact
220                                 if(prandom() < randomvalue)
221                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
222                                 if(prandom() < randomvalue)
223                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
224                                 if(prandom() < randomvalue)
225                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
226                                 if(prandom() < randomvalue)
227                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
228                         }
229                         break;
230                 case 0x02:
231                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
232                         break;
233                 case 0x03:
234                         if(prandom() < amount)
235                                 TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent); // TODO maybe adjust to more randomization?
236                         break;
237                 case 0x81:
238                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
239                         break;
240                 case 0x82:
241                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
242                         break;
243                 case 0x83:
244                         // no gibs in gentle mode, sorry
245                         break;
246         }
247 }
248
249 void GibSplash_Precache()
250 {
251         precache_model("models/gibs/chunk.mdl");
252         precache_model("models/gibs/leg1.md3");
253         precache_model("models/gibs/leg2.md3");
254         precache_model("models/gibs/chest.md3");
255         precache_model("models/gibs/smallchest.md3");
256         precache_model("models/gibs/arm.md3");
257         precache_model("models/gibs/bloodyskull.md3");
258         precache_model("models/gibs/eye.md3");
259
260         precache_model("models/gibs/robo.md3");
261         precache_model("models/gibs/robo1.md3");
262         precache_model("models/gibs/robo2.md3");
263         precache_model("models/gibs/robo3.md3");
264         precache_model("models/gibs/robo4.md3");
265         precache_model("models/gibs/robo5.md3");
266         precache_model("models/gibs/robo6.md3");
267         precache_model("models/gibs/robo7.md3");
268         precache_model("models/gibs/robo8.md3");
269
270         precache_sound ("misc/gib.wav");
271     precache_sound ("misc/gib_splat01.wav");
272     precache_sound ("misc/gib_splat02.wav");
273     precache_sound ("misc/gib_splat03.wav");
274     precache_sound ("misc/gib_splat04.wav");
275 }