qcsrc/client/gibs.qc

   1 .float silent;
   2
   3 void Gib_Delete()
   4 {
   5         remove(self);
   6 }
   7
   8 string species_prefix(float specnum)
   9 {
  10         switch(specnum)
  11         {
  12                 case SPECIES_HUMAN:       return "";
  13                 case SPECIES_ALIEN:       return "alien_";
  14                 case SPECIES_ROBOT_SHINY: return "robot_";
  15                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  16                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
  17                 case SPECIES_ANIMAL:      return "animal_";
  18                 case SPECIES_RESERVED:    return "reserved_";
  19                 default:         return "";
  20         }
  21 }
  22
  23 void Gib_setmodel(entity gib, string mdlname, float specnum)
  24 {
  25         switch(specnum)
  26         {
  27                 case SPECIES_ROBOT_RUSTY:
  28                 case SPECIES_ROBOT_SHINY:
  29                 case SPECIES_ROBOT_SOLID:
  30                         if(specnum != SPECIES_ROBOT_SOLID || mdlname == "models/gibs/chunk.mdl")
  31                         {
  32                                 if(mdlname == "models/gibs/bloodyskull.md3")
  33                                         setmodel(gib, "models/gibs/robo.md3");
  34                                 else
  35                                         setmodel(gib, strcat("models/gibs/robo", ftos(floor(random() * 8) + 1), ".md3"));
  36                                 if(specnum == SPECIES_ROBOT_SHINY)
  37                                 {
  38                                         gib.skin = 1;
  39                                         gib.colormod = '2 2 2';
  40                                 }
  41                                 gib.scale = 1;
  42                                 break;
  43                         }
  44                 default:
  45                         setmodel(gib, mdlname);
  46                         gib.skin = specnum;
  47                         break;
  48         }
  49 }
  50
  51 void new_te_bloodshower (float ef, vector org, float explosionspeed, float howmany)
  52 {
  53         float i, pmod;
  54         pmod = autocvar_cl_particles_quality;
  55         for (i = 0; i < 250 * pmod; ++i)
  56                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 250);
  57 }
  58
  59 void SUB_RemoveOnNoImpact()
  60 {
  61         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  62                 Gib_Delete();
  63 }
  64
  65 void Gib_Touch()
  66 {
  67         // TODO maybe bounce of walls, make more gibs, etc.
  68
  69         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  70         {
  71                 Gib_Delete();
  72                 return;
  73         }
  74
  75         if(!self.silent)
  76                 sound(self, CH_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
  77         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  78
  79         Gib_Delete();
  80 }
  81
  82 void Gib_Draw()
  83 {
  84         vector oldorg;
  85         oldorg = self.origin;
  86
  87         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
  88         if(wasfreed(self))
  89                 return;
  90
  91         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
  92                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
  93         else
  94                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
  95
  96         self.renderflags = 0;
  97         self.alpha = bound(0, self.nextthink - time, 1);
  98
  99         if(self.alpha < ALPHA_MIN_VISIBLE)
 100         {
 101                 self.drawmask = 0;
 102                 Gib_Delete();
 103         }
 104 }
 105
 106 void TossGib (string mdlname, vector safeorg, vector org, vector vconst, vector vrand, float specnum, float destroyontouch, float issilent, float gibownernum)
 107 {
 108         entity gib;
 109
 110         // TODO remove some gibs according to cl_nogibs
 111         gib = RubbleNew("gib");
 112         gib.classname = "gib";
 113         gib.move_movetype = MOVETYPE_BOUNCE;
 114         gib.gravity = 1;
 115         gib.solid = SOLID_CORPSE;
 116         gib.cnt = specnum;
 117         gib.silent = issilent;
 118         gib.team = gibownernum;
 119         Gib_setmodel(gib, mdlname, specnum);
 120
 121         setsize (gib, '-8 -8 -8', '8 8 8');
 122
 123         gib.draw = Gib_Draw;
 124         if(destroyontouch)
 125                 gib.move_touch = Gib_Touch;
 126         else
 127                 gib.move_touch = SUB_RemoveOnNoImpact;
 128
 129         // don't spawn gibs inside solid - just don't
 130         if(org != safeorg)
 131         {
 132                 tracebox(safeorg, gib.mins, gib.maxs, org, MOVE_NOMONSTERS, gib);
 133                 org = trace_endpos;
 134         }
 135
 136         gib.move_origin = gib.origin = org;
 137         gib.move_velocity = vconst * autocvar_cl_gibs_velocity_scale + vrand * autocvar_cl_gibs_velocity_random + '0 0 1' * autocvar_cl_gibs_velocity_up;
 138         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity);
 139         gib.move_time = time;
 140         gib.damageforcescale = autocvar_cl_gibs_damageforcescale;
 141
 142         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 143         gib.drawmask = MASK_NORMAL;
 144
 145         RubbleLimit("gib", autocvar_cl_gibs_maxcount, Gib_Delete);
 146 }
 147
 148 void Ent_GibSplash(float isNew)
 149 {
 150         float amount, type, specnum, entnumber;
 151         vector org, vel;
 152         string specstr;
 153         float issilent;
 154         string gentle_prefix;
 155
 156         float c, randomvalue;
 157
 158         type = ReadByte(); // gibbage type
 159         amount = ReadByte() / 16.0; // gibbage amount
 160         entnumber = ReadByte(); // player num
 161         org_x = ReadShort() * 4 + 2;
 162         org_y = ReadShort() * 4 + 2;
 163         org_z = ReadShort() * 4 + 2;
 164         vel = decompressShortVector(ReadShort());
 165
 166         float cl_gentle_gibs = autocvar_cl_gentle_gibs;
 167         if(cl_gentle_gibs || autocvar_cl_gentle)
 168                 type |= 0x80; // set gentle bit
 169
 170         if(type & 0x80)
 171         {
 172                 if(cl_gentle_gibs == 2)
 173                         gentle_prefix = "";
 174                 else if(cl_gentle_gibs == 3)
 175                         gentle_prefix = "happy_";
 176                 else
 177                         gentle_prefix = "morphed_";
 178         }
 179         else if(autocvar_cl_particlegibs)
 180         {
 181                 type |= 0x80;
 182                 gentle_prefix = "particlegibs_";
 183         }
 184
 185         if not(cl_gentle_gibs || autocvar_cl_gentle)
 186                 amount *= 1 - autocvar_cl_nogibs;
 187
 188         if(autocvar_ekg)
 189                 amount *= 5;
 190
 191         if(amount <= 0 || !isNew)
 192                 return;
 193
 194         self.origin = org; // for the sounds
 195
 196         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 197         issilent = (type & 0x40);
 198         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 199         specstr = species_prefix(specnum);
 200
 201         switch(type)
 202         {
 203                 case 0x01:
 204                         if(!issilent)
 205                                 sound (self, CH_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 206
 207                         if(prandom() < amount)
 208                                 TossGib ("models/gibs/eye.md3", org, org, vel, prandomvec() * 150, specnum, 0, issilent, entnumber);
 209                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 210                         if(prandom() < amount)
 211                                 TossGib ("models/gibs/bloodyskull.md3", org, org + 16 * prandomvec(), vel, prandomvec() * 100, specnum, 0, issilent, entnumber);
 212
 213                         for(c = 0; c < amount; ++c)
 214                         {
 215                                 randomvalue = amount - c;
 216
 217                                 if(prandom() < randomvalue)
 218                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent, entnumber);
 219                                 if(prandom() < randomvalue)
 220                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent, entnumber);
 221                                 if(prandom() < randomvalue)
 222                                         TossGib ("models/gibs/chest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent, entnumber);
 223                                 if(prandom() < randomvalue)
 224                                         TossGib ("models/gibs/smallchest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent, entnumber);
 225                                 if(prandom() < randomvalue)
 226                                         TossGib ("models/gibs/leg1.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent, entnumber);
 227                                 if(prandom() < randomvalue)
 228                                         TossGib ("models/gibs/leg2.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent, entnumber);
 229
 230                                 // these splat on impact
 231                                 if(prandom() < randomvalue)
 232                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 233                                 if(prandom() < randomvalue)
 234                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 235                                 if(prandom() < randomvalue)
 236                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 237                                 if(prandom() < randomvalue)
 238                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 239                         }
 240                         break;
 241                 case 0x02:
 242                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 243                         break;
 244                 case 0x03:
 245                         if(prandom() < amount)
 246                                 TossGib ("models/gibs/chunk.mdl", org, org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent, entnumber); // TODO maybe adjust to more randomization?
 247                         break;
 248                 case 0x81:
 249                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
 250                         break;
 251                 case 0x82:
 252                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
 253                         break;
 254                 case 0x83:
 255                         // no gibs in gentle mode, sorry
 256                         break;
 257         }
 258 }
 259
 260 void GibSplash_Precache()
 261 {
 262         precache_model("models/gibs/chunk.mdl");
 263         precache_model("models/gibs/leg1.md3");
 264         precache_model("models/gibs/leg2.md3");
 265         precache_model("models/gibs/chest.md3");
 266         precache_model("models/gibs/smallchest.md3");
 267         precache_model("models/gibs/arm.md3");
 268         precache_model("models/gibs/bloodyskull.md3");
 269         precache_model("models/gibs/eye.md3");
 270
 271         precache_model("models/gibs/robo.md3");
 272         precache_model("models/gibs/robo1.md3");
 273         precache_model("models/gibs/robo2.md3");
 274         precache_model("models/gibs/robo3.md3");
 275         precache_model("models/gibs/robo4.md3");
 276         precache_model("models/gibs/robo5.md3");
 277         precache_model("models/gibs/robo6.md3");
 278         precache_model("models/gibs/robo7.md3");
 279         precache_model("models/gibs/robo8.md3");
 280
 281         precache_sound ("misc/gib.wav");
 282     precache_sound ("misc/gib_splat01.wav");
 283     precache_sound ("misc/gib_splat02.wav");
 284     precache_sound ("misc/gib_splat03.wav");
 285     precache_sound ("misc/gib_splat04.wav");
 286 }
 287
 288 void Ent_DamageEffect()
 289 {
 290         float type, specnum1, specnum2, entnumber, body;
 291         vector org;
 292         string specstr, effectnum;
 293         entity e;
 294
 295         type = ReadByte(); // damage weapon
 296         specnum1 = ReadByte(); // player species
 297         entnumber = ReadByte(); // player entnum
 298         body = ReadByte(); // is dead body / gibbed
 299         org_x = ReadCoord();
 300         org_y = ReadCoord();
 301         org_z = ReadCoord();
 302
 303         if not(autocvar_cl_damageeffect)
 304                 return;
 305         if(autocvar_cl_gentle || autocvar_cl_gentle_damage)
 306                 return;
 307
 308         e = get_weaponinfo(type);
 309
 310         specnum2 = (specnum1 & 0x78) / 8; // blood type: using four bits (0..7, bit indexes 3,4,5)
 311         specstr = species_prefix(specnum2);
 312
 313         effectnum = strcat("weapondamage_", e.netname);
 314         // If the weapon is a bullet weapon, its damage effect is blood.
 315         // Since blood is species dependent, we make this effect per-species.
 316         if(type == WEP_SHOTGUN || type == WEP_UZI || type == WEP_RIFLE)
 317         if(specstr != "")
 318         {
 319                 effectnum = strcat(effectnum, "_", specstr);
 320                 effectnum = substring(effectnum, 0, strlen(effectnum) - 1); // remove the _ symbol at the end of the species name
 321         }
 322
 323         entity head;
 324
 325         // Scan the owner of all gibs in the world. If a gib owner is the same as the player we're applying the
 326         // effect to, it means our player is gibbed. Therefore, apply the particles to the gibs as well.
 327         if(autocvar_cl_damageeffect_gibs && body > 1)
 328         for(head = world; (head = find(head, classname, "gib")); )
 329         {
 330                 if(head.team == entnumber)
 331                 if(random() < autocvar_cl_damageeffect_gibs)
 332                         pointparticles(particleeffectnum(effectnum), head.origin, '0 0 0', 1);
 333         }
 334
 335         // if we aren't in third person mode, hide our own damage effect
 336         if(entnumber == player_localentnum && !body)
 337         if(!autocvar_chase_active)
 338                 return;
 339         // if this is a gibbed dead body, don't apply the effects to it, only the gibs as done above
 340         if(body > 1)
 341                 return;
 342
 343         // Now apply the effect to the actual player.
 344         if(random() < autocvar_cl_damageeffect)
 345                 pointparticles(particleeffectnum(effectnum), org, '0 0 0', 1);
 346 }