qcsrc/client/gibs.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qc"
   3         #include "Defs.qc"
   4         #include "../common/constants.qh"
   5         #include "../common/util.qh"
   6         #include "../common/buffs.qh"
   7         #include "autocvars.qh"
   8         #include "movetypes.qh"
   9         #include "prandom.qh"
  10         #include "main.qh"
  11         #include "../csqcmodellib/cl_model.qh"
  12         #include "../server/t_items.qh"
  13 #elif defined(MENUQC)
  14 #elif defined(SVQC)
  15 #endif
  16
  17 .bool silent;
  18
  19 void Gib_Delete()
  20 {
  21         remove(self);
  22 }
  23
  24 string species_prefix(int specnum)
  25 {
  26         switch(specnum)
  27         {
  28                 case SPECIES_HUMAN:       return "";
  29                 case SPECIES_ALIEN:       return "alien_";
  30                 case SPECIES_ROBOT_SHINY: return "robot_";
  31                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  32                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
  33                 case SPECIES_ANIMAL:      return "animal_";
  34                 case SPECIES_RESERVED:    return "reserved_";
  35                 default:         return "";
  36         }
  37 }
  38
  39 void Gib_setmodel(entity gib, string mdlname, int specnum)
  40 {
  41         switch(specnum)
  42         {
  43                 case SPECIES_ROBOT_RUSTY:
  44                 case SPECIES_ROBOT_SHINY:
  45                 case SPECIES_ROBOT_SOLID:
  46                         if(specnum != SPECIES_ROBOT_SOLID || mdlname == "models/gibs/chunk.mdl")
  47                         {
  48                                 if(mdlname == "models/gibs/bloodyskull.md3")
  49                                         setmodel(gib, "models/gibs/robo.md3");
  50                                 else
  51                                         setmodel(gib, strcat("models/gibs/robo", ftos(floor(random() * 8) + 1), ".md3"));
  52                                 if(specnum == SPECIES_ROBOT_SHINY)
  53                                 {
  54                                         gib.skin = 1;
  55                                         gib.colormod = '2 2 2';
  56                                 }
  57                                 gib.scale = 1;
  58                                 break;
  59                         }
  60                 default:
  61                         setmodel(gib, mdlname);
  62                         gib.skin = specnum;
  63                         break;
  64         }
  65 }
  66
  67 void new_te_bloodshower (int ef, vector org, float explosionspeed, int howmany)
  68 {
  69         float i, pmod;
  70         pmod = autocvar_cl_particles_quality;
  71         for (i = 0; i < 50 * pmod; ++i)
  72                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 50);
  73 }
  74
  75 void SUB_RemoveOnNoImpact()
  76 {
  77         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  78                 Gib_Delete();
  79 }
  80
  81 void Gib_Touch()
  82 {
  83         // TODO maybe bounce of walls, make more gibs, etc.
  84
  85         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  86         {
  87                 Gib_Delete();
  88                 return;
  89         }
  90
  91         if(!self.silent)
  92                 sound(self, CH_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTEN_NORM);
  93         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  94
  95         Gib_Delete();
  96 }
  97
  98 void Gib_Draw()
  99 {
 100         vector oldorg;
 101         oldorg = self.origin;
 102
 103         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
 104         if(wasfreed(self))
 105                 return;
 106
 107         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
 108                 // TODO somehow make it spray in a direction dependent on self.angles
 109                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
 110         else
 111                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
 112
 113         self.renderflags = 0;
 114
 115         // make gibs die faster at low view quality
 116         // if view_quality is 0.5, we want to have them die twice as fast
 117         self.nextthink -= frametime * (1 / bound(0.01, view_quality, 1.00) - 1);
 118
 119         self.alpha = bound(0, self.nextthink - time, 1);
 120
 121         if(self.alpha < ALPHA_MIN_VISIBLE)
 122         {
 123                 self.drawmask = 0;
 124                 Gib_Delete();
 125         }
 126 }
 127
 128 void TossGib (string mdlname, vector safeorg, vector org, vector vconst, vector vrand, int specnum, bool destroyontouch, bool issilent)
 129 {
 130         entity gib;
 131
 132         // TODO remove some gibs according to cl_nogibs
 133         gib = RubbleNew("gib");
 134         gib.classname = "gib";
 135         gib.move_movetype = MOVETYPE_BOUNCE;
 136         gib.gravity = 1;
 137         gib.solid = SOLID_CORPSE;
 138         gib.cnt = specnum;
 139         gib.silent = issilent;
 140         Gib_setmodel(gib, mdlname, specnum);
 141
 142         setsize (gib, '-8 -8 -8', '8 8 8');
 143
 144         gib.draw = Gib_Draw;
 145         if(destroyontouch)
 146                 gib.move_touch = Gib_Touch;
 147         else
 148                 gib.move_touch = SUB_RemoveOnNoImpact;
 149
 150         // don't spawn gibs inside solid - just don't
 151         if(org != safeorg)
 152         {
 153                 tracebox(safeorg, gib.mins, gib.maxs, org, MOVE_NOMONSTERS, gib);
 154                 org = trace_endpos;
 155         }
 156
 157         gib.move_origin = org;
 158         setorigin(gib, org);
 159         gib.move_velocity = vconst * autocvar_cl_gibs_velocity_scale + vrand * autocvar_cl_gibs_velocity_random + '0 0 1' * autocvar_cl_gibs_velocity_up;
 160         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity) * autocvar_cl_gibs_avelocity_scale;
 161         gib.move_time = time;
 162         gib.damageforcescale = autocvar_cl_gibs_damageforcescale;
 163
 164         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 165         gib.drawmask = MASK_NORMAL;
 166
 167         RubbleLimit("gib", autocvar_cl_gibs_maxcount, Gib_Delete);
 168 }
 169
 170 void Ent_GibSplash(bool isNew)
 171 {
 172         int amount, type, specnum;
 173         vector org, vel;
 174         string specstr;
 175         bool issilent;
 176         string gentle_prefix = "morphed_";
 177
 178         float randomvalue;
 179         int c;
 180
 181         type = ReadByte(); // gibbage type
 182         amount = ReadByte() / 16.0; // gibbage amount
 183         org_x = ReadShort() * 4 + 2;
 184         org_y = ReadShort() * 4 + 2;
 185         org_z = ReadShort() * 4 + 2;
 186         vel = decompressShortVector(ReadShort());
 187
 188         float cl_gentle_gibs = autocvar_cl_gentle_gibs;
 189         if(cl_gentle_gibs || autocvar_cl_gentle)
 190                 type |= 0x80; // set gentle bit
 191
 192         if(type & 0x80)
 193         {
 194                 if(cl_gentle_gibs == 2)
 195                         gentle_prefix = "";
 196                 else if(cl_gentle_gibs == 3)
 197                         gentle_prefix = "happy_";
 198         }
 199         else if(autocvar_cl_particlegibs)
 200         {
 201                 type |= 0x80;
 202                 gentle_prefix = "particlegibs_";
 203         }
 204
 205         if (!(cl_gentle_gibs || autocvar_cl_gentle))
 206                 amount *= 1 - autocvar_cl_nogibs;
 207
 208         if(autocvar_ekg)
 209                 amount *= 5;
 210
 211         if(amount <= 0 || !isNew)
 212                 return;
 213
 214         setorigin(self, org); // for the sounds
 215
 216         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 217         issilent = (type & 0x40);
 218         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 219         specstr = species_prefix(specnum);
 220
 221         switch(type)
 222         {
 223                 case 0x01:
 224                         if(!issilent)
 225                                 sound (self, CH_PAIN, "misc/gib.wav", VOL_BASE, ATTEN_NORM);
 226
 227                         if(prandom() < amount)
 228                                 TossGib ("models/gibs/eye.md3", org, org, vel, prandomvec() * 150, specnum, 0, issilent);
 229                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 230                         if(prandom() < amount)
 231                                 TossGib ("models/gibs/bloodyskull.md3", org, org + 16 * prandomvec(), vel, prandomvec() * 100, specnum, 0, issilent);
 232
 233                         for(c = 0; c < amount; ++c)
 234                         {
 235                                 randomvalue = amount - c;
 236
 237                                 if(prandom() < randomvalue)
 238                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 239                                 if(prandom() < randomvalue)
 240                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 241                                 if(prandom() < randomvalue)
 242                                         TossGib ("models/gibs/chest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 243                                 if(prandom() < randomvalue)
 244                                         TossGib ("models/gibs/smallchest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 245                                 if(prandom() < randomvalue)
 246                                         TossGib ("models/gibs/leg1.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 247                                 if(prandom() < randomvalue)
 248                                         TossGib ("models/gibs/leg2.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 249
 250                                 // these splat on impact
 251                                 if(prandom() < randomvalue)
 252                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 253                                 if(prandom() < randomvalue)
 254                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 255                                 if(prandom() < randomvalue)
 256                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 257                                 if(prandom() < randomvalue)
 258                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 259                         }
 260                         break;
 261                 case 0x02:
 262                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 263                         break;
 264                 case 0x03:
 265                         if(prandom() < amount)
 266                                 TossGib ("models/gibs/chunk.mdl", org, org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent); // TODO maybe adjust to more randomization?
 267                         break;
 268                 case 0x81:
 269                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
 270                         break;
 271                 case 0x82:
 272                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
 273                         break;
 274                 case 0x83:
 275                         // no gibs in gentle mode, sorry
 276                         break;
 277         }
 278 }
 279
 280 void GibSplash_Precache()
 281 {
 282         precache_model("models/gibs/chunk.mdl");
 283         precache_model("models/gibs/leg1.md3");
 284         precache_model("models/gibs/leg2.md3");
 285         precache_model("models/gibs/chest.md3");
 286         precache_model("models/gibs/smallchest.md3");
 287         precache_model("models/gibs/arm.md3");
 288         precache_model("models/gibs/bloodyskull.md3");
 289         precache_model("models/gibs/eye.md3");
 290
 291         precache_model("models/gibs/robo.md3");
 292         precache_model("models/gibs/robo1.md3");
 293         precache_model("models/gibs/robo2.md3");
 294         precache_model("models/gibs/robo3.md3");
 295         precache_model("models/gibs/robo4.md3");
 296         precache_model("models/gibs/robo5.md3");
 297         precache_model("models/gibs/robo6.md3");
 298         precache_model("models/gibs/robo7.md3");
 299         precache_model("models/gibs/robo8.md3");
 300
 301         precache_sound ("misc/gib.wav");
 302     precache_sound ("misc/gib_splat01.wav");
 303     precache_sound ("misc/gib_splat02.wav");
 304     precache_sound ("misc/gib_splat03.wav");
 305     precache_sound ("misc/gib_splat04.wav");
 306 }