qcsrc/client/gibs.qc

   1 #include "gibs.qh"
   2
   3 #include "autocvars.qh"
   4 #include "defs.qh"
   5 #include "main.qh"
   6 #include "movetypes.qh"
   7 #include "prandom.qh"
   8 #include "rubble.qh"
   9
  10 #include "../common/constants.qh"
  11 #include "../common/util.qh"
  12
  13 .float scale;
  14 .float alpha;
  15 .float cnt;
  16 .float gravity;
  17
  18 void Gib_Delete()
  19 {
  20         remove(self);
  21 }
  22
  23 string species_prefix(int specnum)
  24 {
  25         switch(specnum)
  26         {
  27                 case SPECIES_HUMAN:       return "";
  28                 case SPECIES_ALIEN:       return "alien_";
  29                 case SPECIES_ROBOT_SHINY: return "robot_";
  30                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  31                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
  32                 case SPECIES_ANIMAL:      return "animal_";
  33                 case SPECIES_RESERVED:    return "reserved_";
  34                 default:         return "";
  35         }
  36 }
  37
  38 void Gib_setmodel(entity gib, string mdlname, int specnum)
  39 {
  40         switch(specnum)
  41         {
  42                 case SPECIES_ROBOT_RUSTY:
  43                 case SPECIES_ROBOT_SHINY:
  44                 case SPECIES_ROBOT_SOLID:
  45                         if(specnum != SPECIES_ROBOT_SOLID || mdlname == "models/gibs/chunk.mdl")
  46                         {
  47                                 if(mdlname == "models/gibs/bloodyskull.md3")
  48                                         setmodel(gib, "models/gibs/robo.md3");
  49                                 else
  50                                         setmodel(gib, strcat("models/gibs/robo", ftos(floor(random() * 8) + 1), ".md3"));
  51                                 if(specnum == SPECIES_ROBOT_SHINY)
  52                                 {
  53                                         gib.skin = 1;
  54                                         gib.colormod = '2 2 2';
  55                                 }
  56                                 gib.scale = 1;
  57                                 break;
  58                         }
  59                 default:
  60                         setmodel(gib, mdlname);
  61                         gib.skin = specnum;
  62                         break;
  63         }
  64 }
  65
  66 void new_te_bloodshower (int ef, vector org, float explosionspeed, int howmany)
  67 {
  68         float i, pmod;
  69         pmod = autocvar_cl_particles_quality;
  70         for (i = 0; i < 50 * pmod; ++i)
  71                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 50);
  72 }
  73
  74 void SUB_RemoveOnNoImpact()
  75 {
  76         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  77                 Gib_Delete();
  78 }
  79
  80 void Gib_Touch()
  81 {
  82         // TODO maybe bounce of walls, make more gibs, etc.
  83
  84         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  85         {
  86                 Gib_Delete();
  87                 return;
  88         }
  89
  90         if(!self.silent)
  91                 sound(self, CH_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTEN_NORM);
  92         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  93
  94         Gib_Delete();
  95 }
  96
  97 void Gib_Draw()
  98 {
  99         vector oldorg;
 100         oldorg = self.origin;
 101
 102         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
 103         if(wasfreed(self))
 104                 return;
 105
 106         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
 107                 // TODO somehow make it spray in a direction dependent on self.angles
 108                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
 109         else
 110                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
 111
 112         self.renderflags = 0;
 113
 114         // make gibs die faster at low view quality
 115         // if view_quality is 0.5, we want to have them die twice as fast
 116         self.nextthink -= frametime * (1 / bound(0.01, view_quality, 1.00) - 1);
 117
 118         self.alpha = bound(0, self.nextthink - time, 1);
 119
 120         if(self.alpha < ALPHA_MIN_VISIBLE)
 121         {
 122                 self.drawmask = 0;
 123                 Gib_Delete();
 124         }
 125 }
 126
 127 void TossGib (string mdlname, vector safeorg, vector org, vector vconst, vector vrand, int specnum, bool destroyontouch, bool issilent)
 128 {
 129         entity gib;
 130
 131         // TODO remove some gibs according to cl_nogibs
 132         gib = RubbleNew("gib");
 133         gib.classname = "gib";
 134         gib.move_movetype = MOVETYPE_BOUNCE;
 135         gib.gravity = 1;
 136         gib.solid = SOLID_CORPSE;
 137         gib.cnt = specnum;
 138         gib.silent = issilent;
 139         Gib_setmodel(gib, mdlname, specnum);
 140
 141         setsize (gib, '-8 -8 -8', '8 8 8');
 142
 143         gib.draw = Gib_Draw;
 144         if(destroyontouch)
 145                 gib.move_touch = Gib_Touch;
 146         else
 147                 gib.move_touch = SUB_RemoveOnNoImpact;
 148
 149         // don't spawn gibs inside solid - just don't
 150         if(org != safeorg)
 151         {
 152                 tracebox(safeorg, gib.mins, gib.maxs, org, MOVE_NOMONSTERS, gib);
 153                 org = trace_endpos;
 154         }
 155
 156         gib.move_origin = org;
 157         setorigin(gib, org);
 158         gib.move_velocity = vconst * autocvar_cl_gibs_velocity_scale + vrand * autocvar_cl_gibs_velocity_random + '0 0 1' * autocvar_cl_gibs_velocity_up;
 159         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity) * autocvar_cl_gibs_avelocity_scale;
 160         gib.move_time = time;
 161         gib.damageforcescale = autocvar_cl_gibs_damageforcescale;
 162
 163         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 164         gib.drawmask = MASK_NORMAL;
 165
 166         RubbleLimit("gib", autocvar_cl_gibs_maxcount, Gib_Delete);
 167 }
 168
 169 void Ent_GibSplash(bool isNew)
 170 {
 171         int amount, type, specnum;
 172         vector org, vel;
 173         string specstr;
 174         bool issilent;
 175         string gentle_prefix = "morphed_";
 176
 177         float randomvalue;
 178         int c;
 179
 180         type = ReadByte(); // gibbage type
 181         amount = ReadByte() / 16.0; // gibbage amount
 182         org.x = ReadShort() * 4 + 2;
 183         org.y = ReadShort() * 4 + 2;
 184         org.z = ReadShort() * 4 + 2;
 185         vel = decompressShortVector(ReadShort());
 186
 187         float cl_gentle_gibs = autocvar_cl_gentle_gibs;
 188         if(cl_gentle_gibs || autocvar_cl_gentle)
 189                 type |= 0x80; // set gentle bit
 190
 191         if(type & 0x80)
 192         {
 193                 if(cl_gentle_gibs == 2)
 194                         gentle_prefix = "";
 195                 else if(cl_gentle_gibs == 3)
 196                         gentle_prefix = "happy_";
 197         }
 198         else if(autocvar_cl_particlegibs)
 199         {
 200                 type |= 0x80;
 201                 gentle_prefix = "particlegibs_";
 202         }
 203
 204         if (!(cl_gentle_gibs || autocvar_cl_gentle))
 205                 amount *= 1 - autocvar_cl_nogibs;
 206
 207         if(autocvar_ekg)
 208                 amount *= 5;
 209
 210         if(amount <= 0 || !isNew)
 211                 return;
 212
 213         setorigin(self, org); // for the sounds
 214
 215         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 216         issilent = (type & 0x40);
 217         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 218         specstr = species_prefix(specnum);
 219
 220         switch(type)
 221         {
 222                 case 0x01:
 223                         if(!issilent)
 224                                 sound (self, CH_PAIN, "misc/gib.wav", VOL_BASE, ATTEN_NORM);
 225
 226                         if(prandom() < amount)
 227                                 TossGib ("models/gibs/eye.md3", org, org, vel, prandomvec() * 150, specnum, 0, issilent);
 228                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 229                         if(prandom() < amount)
 230                                 TossGib ("models/gibs/bloodyskull.md3", org, org + 16 * prandomvec(), vel, prandomvec() * 100, specnum, 0, issilent);
 231
 232                         for(c = 0; c < amount; ++c)
 233                         {
 234                                 randomvalue = amount - c;
 235
 236                                 if(prandom() < randomvalue)
 237                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 238                                 if(prandom() < randomvalue)
 239                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 240                                 if(prandom() < randomvalue)
 241                                         TossGib ("models/gibs/chest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 242                                 if(prandom() < randomvalue)
 243                                         TossGib ("models/gibs/smallchest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 244                                 if(prandom() < randomvalue)
 245                                         TossGib ("models/gibs/leg1.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 246                                 if(prandom() < randomvalue)
 247                                         TossGib ("models/gibs/leg2.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 248
 249                                 // these splat on impact
 250                                 if(prandom() < randomvalue)
 251                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 252                                 if(prandom() < randomvalue)
 253                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 254                                 if(prandom() < randomvalue)
 255                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 256                                 if(prandom() < randomvalue)
 257                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 258                         }
 259                         break;
 260                 case 0x02:
 261                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 262                         break;
 263                 case 0x03:
 264                         if(prandom() < amount)
 265                                 TossGib ("models/gibs/chunk.mdl", org, org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent); // TODO maybe adjust to more randomization?
 266                         break;
 267                 case 0x81:
 268                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
 269                         break;
 270                 case 0x82:
 271                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
 272                         break;
 273                 case 0x83:
 274                         // no gibs in gentle mode, sorry
 275                         break;
 276         }
 277 }
 278
 279 void GibSplash_Precache()
 280 {
 281         precache_model("models/gibs/chunk.mdl");
 282         precache_model("models/gibs/leg1.md3");
 283         precache_model("models/gibs/leg2.md3");
 284         precache_model("models/gibs/chest.md3");
 285         precache_model("models/gibs/smallchest.md3");
 286         precache_model("models/gibs/arm.md3");
 287         precache_model("models/gibs/bloodyskull.md3");
 288         precache_model("models/gibs/eye.md3");
 289
 290         precache_model("models/gibs/robo.md3");
 291         precache_model("models/gibs/robo1.md3");
 292         precache_model("models/gibs/robo2.md3");
 293         precache_model("models/gibs/robo3.md3");
 294         precache_model("models/gibs/robo4.md3");
 295         precache_model("models/gibs/robo5.md3");
 296         precache_model("models/gibs/robo6.md3");
 297         precache_model("models/gibs/robo7.md3");
 298         precache_model("models/gibs/robo8.md3");
 299
 300         precache_sound ("misc/gib.wav");
 301     precache_sound ("misc/gib_splat01.wav");
 302     precache_sound ("misc/gib_splat02.wav");
 303     precache_sound ("misc/gib_splat03.wav");
 304     precache_sound ("misc/gib_splat04.wav");
 305 }