qcsrc/client/gibs.qc

   1 .float silent;
   2
   3 void Gib_Delete()
   4 {
   5         remove(self);
   6 }
   7
   8 string species_prefix(float specnum)
   9 {
  10         switch(specnum)
  11         {
  12                 case SPECIES_HUMAN:       return "";
  13                 case SPECIES_ALIEN:       return "alien_";
  14                 case SPECIES_ROBOT_SHINY: return "robot_";
  15                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  16                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
  17                 case SPECIES_ANIMAL:      return "animal_";
  18                 case SPECIES_RESERVED:    return "reserved_";
  19                 default:         return "";
  20         }
  21 }
  22
  23 void Gib_setmodel(entity gib, string mdlname, float specnum)
  24 {
  25         switch(specnum)
  26         {
  27                 case SPECIES_ROBOT_RUSTY:
  28                 case SPECIES_ROBOT_SHINY:
  29                 case SPECIES_ROBOT_SOLID:
  30                         if(specnum != SPECIES_ROBOT_SOLID || mdlname == "models/gibs/chunk.mdl")
  31                         {
  32                                 if(mdlname == "models/gibs/bloodyskull.md3")
  33                                         setmodel(gib, "models/gibs/robo.md3");
  34                                 else
  35                                         setmodel(gib, strcat("models/gibs/robo", ftos(floor(random() * 8) + 1), ".md3"));
  36                                 if(specnum == SPECIES_ROBOT_SHINY)
  37                                 {
  38                                         gib.skin = 1;
  39                                         gib.colormod = '2 2 2';
  40                                 }
  41                                 gib.scale = 1;
  42                                 break;
  43                         }
  44                 default:
  45                         setmodel(gib, mdlname);
  46                         gib.skin = specnum;
  47                         break;
  48         }
  49 }
  50
  51 void new_te_bloodshower (float ef, vector org, float explosionspeed, float howmany)
  52 {
  53         float i, pmod;
  54         pmod = autocvar_cl_particles_quality;
  55         for (i = 0; i < 50 * pmod; ++i)
  56                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 50);
  57 }
  58
  59 void SUB_RemoveOnNoImpact()
  60 {
  61         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  62                 Gib_Delete();
  63 }
  64
  65 void Gib_Touch()
  66 {
  67         // TODO maybe bounce of walls, make more gibs, etc.
  68
  69         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  70         {
  71                 Gib_Delete();
  72                 return;
  73         }
  74
  75         if(!self.silent)
  76                 sound(self, CH_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
  77         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  78
  79         Gib_Delete();
  80 }
  81
  82 void Gib_Draw()
  83 {
  84         vector oldorg;
  85         oldorg = self.origin;
  86
  87         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
  88         if(wasfreed(self))
  89                 return;
  90
  91         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
  92                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
  93         else
  94                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
  95
  96         self.renderflags = 0;
  97
  98         // make gibs die faster at low view quality
  99         // if view_quality is 0.5, we want to have them die twice as fast
 100         self.nextthink -= frametime * (1 / bound(0.01, view_quality, 1.00) - 1);
 101
 102         self.alpha = bound(0, self.nextthink - time, 1);
 103
 104         if(self.alpha < ALPHA_MIN_VISIBLE)
 105         {
 106                 self.drawmask = 0;
 107                 Gib_Delete();
 108         }
 109 }
 110
 111 void TossGib (string mdlname, vector safeorg, vector org, vector vconst, vector vrand, float specnum, float destroyontouch, float issilent)
 112 {
 113         entity gib;
 114
 115         // TODO remove some gibs according to cl_nogibs
 116         gib = RubbleNew("gib");
 117         gib.move_movetype = MOVETYPE_BOUNCE;
 118         gib.gravity = 1;
 119         gib.solid = SOLID_CORPSE;
 120         gib.cnt = specnum;
 121         gib.silent = issilent;
 122         Gib_setmodel(gib, mdlname, specnum);
 123
 124         setsize (gib, '-8 -8 -8', '8 8 8');
 125
 126         gib.draw = Gib_Draw;
 127         if(destroyontouch)
 128                 gib.move_touch = Gib_Touch;
 129         else
 130                 gib.move_touch = SUB_RemoveOnNoImpact;
 131
 132         // don't spawn gibs inside solid - just don't
 133         if(org != safeorg)
 134         {
 135                 tracebox(safeorg, gib.mins, gib.maxs, org, MOVE_NOMONSTERS, gib);
 136                 org = trace_endpos;
 137         }
 138
 139         gib.move_origin = gib.origin = org;
 140         gib.move_velocity = vconst * autocvar_cl_gibs_velocity_scale + vrand * autocvar_cl_gibs_velocity_random + '0 0 1' * autocvar_cl_gibs_velocity_up;
 141         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity) * autocvar_cl_gibs_avelocity_scale;
 142         gib.move_time = time;
 143         gib.damageforcescale = autocvar_cl_gibs_damageforcescale;
 144
 145         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 146         gib.drawmask = MASK_NORMAL;
 147
 148         RubbleLimit("gib", autocvar_cl_gibs_maxcount, Gib_Delete);
 149 }
 150
 151 void Ent_GibSplash(float isNew)
 152 {
 153         float amount, type, specnum;
 154         vector org, vel;
 155         string specstr;
 156         float issilent;
 157         string gentle_prefix;
 158
 159         float c, randomvalue;
 160
 161         type = ReadByte(); // gibbage type
 162         amount = ReadByte() / 16.0; // gibbage amount
 163         org_x = ReadShort() * 4 + 2;
 164         org_y = ReadShort() * 4 + 2;
 165         org_z = ReadShort() * 4 + 2;
 166         vel = decompressShortVector(ReadShort());
 167
 168         float cl_gentle_gibs = autocvar_cl_gentle_gibs;
 169         if(cl_gentle_gibs || autocvar_cl_gentle)
 170                 type |= 0x80; // set gentle bit
 171
 172         if(type & 0x80)
 173         {
 174                 if(cl_gentle_gibs == 2)
 175                         gentle_prefix = "";
 176                 else if(cl_gentle_gibs == 3)
 177                         gentle_prefix = "happy_";
 178                 else
 179                         gentle_prefix = "morphed_";
 180         }
 181         else if(autocvar_cl_particlegibs)
 182         {
 183                 type |= 0x80;
 184                 gentle_prefix = "particlegibs_";
 185         }
 186
 187         if not(cl_gentle_gibs || autocvar_cl_gentle)
 188                 amount *= 1 - autocvar_cl_nogibs;
 189
 190         if(autocvar_ekg)
 191                 amount *= 5;
 192
 193         if(amount <= 0 || !isNew)
 194                 return;
 195
 196         self.origin = org; // for the sounds
 197
 198         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 199         issilent = (type & 0x40);
 200         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 201         specstr = species_prefix(specnum);
 202
 203         switch(type)
 204         {
 205                 case 0x01:
 206                         if(!issilent)
 207                                 sound (self, CH_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 208
 209                         if(prandom() < amount)
 210                                 TossGib ("models/gibs/eye.md3", org, org, vel, prandomvec() * 150, specnum, 0, issilent);
 211                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 212                         if(prandom() < amount)
 213                                 TossGib ("models/gibs/bloodyskull.md3", org, org + 16 * prandomvec(), vel, prandomvec() * 100, specnum, 0, issilent);
 214
 215                         for(c = 0; c < amount; ++c)
 216                         {
 217                                 randomvalue = amount - c;
 218
 219                                 if(prandom() < randomvalue)
 220                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 221                                 if(prandom() < randomvalue)
 222                                         TossGib ("models/gibs/arm.md3", org, org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 223                                 if(prandom() < randomvalue)
 224                                         TossGib ("models/gibs/chest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 225                                 if(prandom() < randomvalue)
 226                                         TossGib ("models/gibs/smallchest.md3", org, org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 227                                 if(prandom() < randomvalue)
 228                                         TossGib ("models/gibs/leg1.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 229                                 if(prandom() < randomvalue)
 230                                         TossGib ("models/gibs/leg2.md3", org, org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 231
 232                                 // these splat on impact
 233                                 if(prandom() < randomvalue)
 234                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 235                                 if(prandom() < randomvalue)
 236                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 237                                 if(prandom() < randomvalue)
 238                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 239                                 if(prandom() < randomvalue)
 240                                         TossGib ("models/gibs/chunk.mdl", org, org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 241                         }
 242                         break;
 243                 case 0x02:
 244                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 245                         break;
 246                 case 0x03:
 247                         if(prandom() < amount)
 248                                 TossGib ("models/gibs/chunk.mdl", org, org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent); // TODO maybe adjust to more randomization?
 249                         break;
 250                 case 0x81:
 251                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
 252                         break;
 253                 case 0x82:
 254                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
 255                         break;
 256                 case 0x83:
 257                         // no gibs in gentle mode, sorry
 258                         break;
 259         }
 260 }
 261
 262 void GibSplash_Precache()
 263 {
 264         precache_model("models/gibs/chunk.mdl");
 265         precache_model("models/gibs/leg1.md3");
 266         precache_model("models/gibs/leg2.md3");
 267         precache_model("models/gibs/chest.md3");
 268         precache_model("models/gibs/smallchest.md3");
 269         precache_model("models/gibs/arm.md3");
 270         precache_model("models/gibs/bloodyskull.md3");
 271         precache_model("models/gibs/eye.md3");
 272
 273         precache_model("models/gibs/robo.md3");
 274         precache_model("models/gibs/robo1.md3");
 275         precache_model("models/gibs/robo2.md3");
 276         precache_model("models/gibs/robo3.md3");
 277         precache_model("models/gibs/robo4.md3");
 278         precache_model("models/gibs/robo5.md3");
 279         precache_model("models/gibs/robo6.md3");
 280         precache_model("models/gibs/robo7.md3");
 281         precache_model("models/gibs/robo8.md3");
 282
 283         precache_sound ("misc/gib.wav");
 284     precache_sound ("misc/gib_splat01.wav");
 285     precache_sound ("misc/gib_splat02.wav");
 286     precache_sound ("misc/gib_splat03.wav");
 287     precache_sound ("misc/gib_splat04.wav");
 288 }