qcsrc/client/gibs.qc

   1 .float silent;
   2
   3 void Gib_Delete()
   4 {
   5         remove(self);
   6 }
   7
   8 string species_prefix(float specnum)
   9 {
  10         switch(specnum)
  11         {
  12                 case SPECIES_HUMAN:       return "";
  13                 case SPECIES_ALIEN:       return "alien_";
  14                 case SPECIES_ROBOT_SHINY: return "robot_";
  15                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  16                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
  17                 case SPECIES_ANIMAL:      return "animal_";
  18                 case SPECIES_RESERVED:    return "reserved_";
  19                 default:         return "";
  20         }
  21 }
  22
  23 void Gib_setmodel(entity gib, string mdlname, float specnum)
  24 {
  25         switch(specnum)
  26         {
  27                 case SPECIES_ROBOT_RUSTY:
  28                 case SPECIES_ROBOT_SHINY:
  29                 case SPECIES_ROBOT_SOLID:
  30                         if(specnum != SPECIES_ROBOT_SOLID || mdlname == "models/gibs/chunk.mdl")
  31                         {
  32                                 if(mdlname == "models/gibs/bloodyskull.md3")
  33                                         setmodel(gib, "models/gibs/robo.md3");
  34                                 else
  35                                         setmodel(gib, strcat("models/gibs/robo", ftos(floor(random() * 8) + 1), ".md3"));
  36                                 if(specnum == SPECIES_ROBOT_SHINY)
  37                                 {
  38                                         gib.skin = 1;
  39                                         gib.colormod = '2 2 2';
  40                                 }
  41                                 gib.scale = 1;
  42                                 break;
  43                         }
  44                 default:
  45                         setmodel(gib, mdlname);
  46                         gib.skin = specnum;
  47                         break;
  48         }
  49 }
  50
  51 void new_te_bloodshower (float ef, vector org, float explosionspeed, float howmany)
  52 {
  53         float i, pmod;
  54         pmod = autocvar_cl_particles_quality;
  55         for (i = 0; i < 250 * pmod; ++i)
  56                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 250);
  57 }
  58
  59 void SUB_RemoveOnNoImpact()
  60 {
  61         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  62                 Gib_Delete();
  63 }
  64
  65 void Gib_Touch()
  66 {
  67         // TODO maybe bounce of walls, make more gibs, etc.
  68
  69         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  70         {
  71                 Gib_Delete();
  72                 return;
  73         }
  74
  75         if(!self.silent)
  76                 sound(self, CHAN_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
  77         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  78
  79         Gib_Delete();
  80 }
  81
  82 void Gib_Draw()
  83 {
  84         vector oldorg;
  85         oldorg = self.origin;
  86
  87         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
  88         if(wasfreed(self))
  89                 return;
  90
  91         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
  92                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
  93         else
  94                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
  95
  96         self.renderflags = 0;
  97         self.alpha = bound(0, self.nextthink - time, 1);
  98
  99         if(self.alpha < ALPHA_MIN_VISIBLE)
 100         {
 101                 self.drawmask = 0;
 102                 Gib_Delete();
 103         }
 104 }
 105
 106 void TossGib (string mdlname, vector org, vector vconst, vector vrand, float specnum, float destroyontouch, float issilent, float gibownernum)
 107 {
 108         entity gib;
 109
 110         // TODO remove some gibs according to cl_nogibs
 111         gib = RubbleNew("gib");
 112         gib.classname = "gib";
 113         gib.move_movetype = MOVETYPE_BOUNCE;
 114         gib.gravity = 1;
 115         gib.solid = SOLID_CORPSE;
 116         gib.cnt = specnum;
 117         gib.silent = issilent;
 118         gib.team = gibownernum;
 119         Gib_setmodel(gib, mdlname, specnum);
 120
 121         setsize (gib, '-8 -8 -8', '8 8 8');
 122
 123         gib.draw = Gib_Draw;
 124         if(destroyontouch)
 125                 gib.move_touch = Gib_Touch;
 126         else
 127                 gib.move_touch = SUB_RemoveOnNoImpact;
 128
 129         gib.move_origin = gib.origin = org;
 130         gib.move_velocity = vconst * autocvar_cl_gibs_velocity_scale + vrand * autocvar_cl_gibs_velocity_random + '0 0 1' * autocvar_cl_gibs_velocity_up;
 131         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity);
 132         gib.move_time = time;
 133         gib.damageforcescale = autocvar_cl_gibs_damageforcescale;
 134
 135         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 136         gib.drawmask = MASK_NORMAL;
 137
 138         RubbleLimit("gib", autocvar_cl_gibs_maxcount, Gib_Delete);
 139 }
 140
 141 void Ent_GibSplash(float isNew)
 142 {
 143         float amount, type, specnum, entnumber;
 144         vector org, vel;
 145         string specstr;
 146         float issilent;
 147         string gentle_prefix;
 148
 149         float c, randomvalue;
 150
 151         type = ReadByte(); // gibbage type
 152         amount = ReadByte() / 16.0; // gibbage amount
 153         entnumber = ReadByte(); // player num
 154         org_x = ReadShort() * 4 + 2;
 155         org_y = ReadShort() * 4 + 2;
 156         org_z = ReadShort() * 4 + 2;
 157         vel = decompressShortVector(ReadShort());
 158
 159         float cl_gentle_gibs = autocvar_cl_gentle_gibs;
 160         if(cl_gentle_gibs || autocvar_cl_gentle)
 161                 type |= 0x80; // set gentle bit
 162
 163         if(type & 0x80)
 164         {
 165                 if(cl_gentle_gibs == 2)
 166                         gentle_prefix = "";
 167                 else if(cl_gentle_gibs == 3)
 168                         gentle_prefix = "happy_";
 169                 else
 170                         gentle_prefix = "morphed_";
 171         }
 172         else if(autocvar_cl_particlegibs)
 173         {
 174                 type |= 0x80;
 175                 gentle_prefix = "particlegibs_";
 176         }
 177
 178         if not(cl_gentle_gibs || autocvar_cl_gentle)
 179                 amount *= 1 - autocvar_cl_nogibs;
 180
 181         if(autocvar_ekg)
 182                 amount *= 5;
 183
 184         if(amount <= 0 || !isNew)
 185                 return;
 186
 187         self.origin = org; // for the sounds
 188
 189         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 190         issilent = (type & 0x40);
 191         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 192         specstr = species_prefix(specnum);
 193
 194         switch(type)
 195         {
 196                 case 0x01:
 197                         if(!issilent)
 198                                 sound (self, CHAN_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 199
 200                         if(prandom() < amount)
 201                                 TossGib ("models/gibs/eye.md3", org, vel, prandomvec() * 150, specnum, 0, issilent, entnumber);
 202                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 203                         if(prandom() < amount)
 204                                 TossGib ("models/gibs/bloodyskull.md3", org + 16 * prandomvec(), vel, prandomvec() * 100, specnum, 0, issilent, entnumber);
 205
 206                         for(c = 0; c < amount; ++c)
 207                         {
 208                                 randomvalue = amount - c;
 209
 210                                 if(prandom() < randomvalue)
 211                                         TossGib ("models/gibs/arm.md3", org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent, entnumber);
 212                                 if(prandom() < randomvalue)
 213                                         TossGib ("models/gibs/arm.md3", org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent, entnumber);
 214                                 if(prandom() < randomvalue)
 215                                         TossGib ("models/gibs/chest.md3", org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent, entnumber);
 216                                 if(prandom() < randomvalue)
 217                                         TossGib ("models/gibs/smallchest.md3", org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent, entnumber);
 218                                 if(prandom() < randomvalue)
 219                                         TossGib ("models/gibs/leg1.md3", org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent, entnumber);
 220                                 if(prandom() < randomvalue)
 221                                         TossGib ("models/gibs/leg2.md3", org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent, entnumber);
 222
 223                                 // these splat on impact
 224                                 if(prandom() < randomvalue)
 225                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 226                                 if(prandom() < randomvalue)
 227                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 228                                 if(prandom() < randomvalue)
 229                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 230                                 if(prandom() < randomvalue)
 231                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent, entnumber);
 232                         }
 233                         break;
 234                 case 0x02:
 235                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 236                         break;
 237                 case 0x03:
 238                         if(prandom() < amount)
 239                                 TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent, entnumber); // TODO maybe adjust to more randomization?
 240                         break;
 241                 case 0x81:
 242                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
 243                         break;
 244                 case 0x82:
 245                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
 246                         break;
 247                 case 0x83:
 248                         // no gibs in gentle mode, sorry
 249                         break;
 250         }
 251 }
 252
 253 void GibSplash_Precache()
 254 {
 255         precache_model("models/gibs/chunk.mdl");
 256         precache_model("models/gibs/leg1.md3");
 257         precache_model("models/gibs/leg2.md3");
 258         precache_model("models/gibs/chest.md3");
 259         precache_model("models/gibs/smallchest.md3");
 260         precache_model("models/gibs/arm.md3");
 261         precache_model("models/gibs/bloodyskull.md3");
 262         precache_model("models/gibs/eye.md3");
 263
 264         precache_model("models/gibs/robo.md3");
 265         precache_model("models/gibs/robo1.md3");
 266         precache_model("models/gibs/robo2.md3");
 267         precache_model("models/gibs/robo3.md3");
 268         precache_model("models/gibs/robo4.md3");
 269         precache_model("models/gibs/robo5.md3");
 270         precache_model("models/gibs/robo6.md3");
 271         precache_model("models/gibs/robo7.md3");
 272         precache_model("models/gibs/robo8.md3");
 273
 274         precache_sound ("misc/gib.wav");
 275     precache_sound ("misc/gib_splat01.wav");
 276     precache_sound ("misc/gib_splat02.wav");
 277     precache_sound ("misc/gib_splat03.wav");
 278     precache_sound ("misc/gib_splat04.wav");
 279 }
 280
 281 void Ent_DamageEffect()
 282 {
 283         float type, specnum1, specnum2, entnumber;
 284         vector org;
 285         string specstr, effectnum;
 286         entity e;
 287
 288         type = ReadByte(); // damage weapon
 289         specnum1 = ReadByte(); // player species
 290         entnumber = ReadByte(); // player entnum
 291         org_x = ReadCoord();
 292         org_y = ReadCoord();
 293         org_z = ReadCoord();
 294
 295         if not(autocvar_cl_damageeffect)
 296                 return;
 297         if(autocvar_cl_gentle || autocvar_cl_gentle_damage)
 298                 return;
 299         // if we aren't in third person mode, hide our own damage effect
 300         if(entnumber == player_localentnum && !autocvar_chase_active)
 301                 return;
 302
 303         e = get_weaponinfo(type);
 304
 305         specnum2 = (specnum1 & 0x78) / 8; // blood type: using four bits (0..7, bit indexes 3,4,5)
 306         specstr = species_prefix(specnum2);
 307
 308         effectnum = strcat("weapondamage_", e.netname);
 309         // If the weapon is a bullet weapon, its damage effect is blood.
 310         // Since blood is species dependent, we make this effect per-species.
 311         if(type == WEP_SHOTGUN || type == WEP_UZI || type == WEP_SNIPERRIFLE)
 312         if(specstr != "")
 313         {
 314                 effectnum = strcat(effectnum, "_", specstr);
 315                 effectnum = substring(effectnum, 0, strlen(effectnum) - 1); // remove the _ symbol at the end of the species name
 316         }
 317
 318         entity head;
 319         float foundgib;
 320
 321         // Scan the owner of all gibs in the world. If a gib owner is the same as the player we're applying the
 322         // effect to, it means our player is gibbed. Therefore, apply the particles to the gibs instead.
 323         for(head = world; (head = find(head, classname, "gib")); )
 324         {
 325                 if(head.team == entnumber)
 326                 {
 327                         pointparticles(particleeffectnum(effectnum), head.origin, '0 0 0', 1);
 328                         foundgib = TRUE;
 329                 }
 330         }
 331
 332         // If our player isn't gibbed, apply the effect to him instead.
 333         if(!foundgib)
 334                 pointparticles(particleeffectnum(effectnum), org, '0 0 0', 1);
 335 }