qcsrc/client/hud.qc

   1 #include "hud.qh"
   2 #include "_all.qh"
   3
   4 #include "hud_config.qh"
   5 #include "scoreboard.qh"
   6 #include "sortlist.qh"
   7 #include "teamradar.qh"
   8 #include "t_items.qh"
   9
  10 #include "../common/buffs.qh"
  11 #include "../common/constants.qh"
  12 #include "../common/counting.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16 #include "../common/stats.qh"
  17
  18 #include "../csqcmodellib/cl_player.qh"
  19
  20 #include "../warpzonelib/mathlib.qh"
  21
  22 /*
  23 ==================
  24 Misc HUD functions
  25 ==================
  26 */
  27
  28 // a border picture is a texture containing nine parts:
  29 //   1/4 width: left part
  30 //   1/2 width: middle part (stretched)
  31 //   1/4 width: right part
  32 // divided into
  33 //   1/4 height: top part
  34 //   1/2 height: middle part (stretched)
  35 //   1/4 height: bottom part
  36 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  37 {
  38     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  39     {
  40                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  41                 return;
  42     }
  43         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  44         {
  45                 // draw only the central part
  46                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  47                 return;
  48         }
  49
  50         vector dX, dY;
  51         vector width, height;
  52         vector bW, bH;
  53         //pic = draw_UseSkinFor(pic);
  54         width = eX * theSize.x;
  55         height = eY * theSize.y;
  56         if(theSize.x <= theBorderSize.x * 2)
  57         {
  58                 // not wide enough... draw just left and right then
  59                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  60                 if(theSize.y <= theBorderSize.y * 2)
  61                 {
  62                         // not high enough... draw just corners
  63                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  64                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  65                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  66                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  68                 }
  69                 else
  70                 {
  71                         dY = theBorderSize.x * eY;
  72                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  73                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  74                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  75                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  78                 }
  79         }
  80         else
  81         {
  82                 if(theSize.y <= theBorderSize.y * 2)
  83                 {
  84                         // not high enough... draw just top and bottom then
  85                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  86                         dX = theBorderSize.x * eX;
  87                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  88                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  89                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  90                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  93                 }
  94                 else
  95                 {
  96                         dX = theBorderSize.x * eX;
  97                         dY = theBorderSize.x * eY;
  98                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  99                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
 100                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 101                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 102                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
 103                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 104                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 105                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
 106                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 107                 }
 108         }
 109 }
 110
 111 vector HUD_Get_Num_Color (float x, float maxvalue)
 112 {
 113         float blinkingamt;
 114         vector color;
 115         if(x >= maxvalue) {
 116                 color.x = sin(2*M_PI*time);
 117                 color.y = 1;
 118                 color.z = sin(2*M_PI*time);
 119         }
 120         else if(x > maxvalue * 0.75) {
 121                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 122                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 123                 color.z = 0;
 124         }
 125         else if(x > maxvalue * 0.5) {
 126                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 127                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 128                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 129         }
 130         else if(x > maxvalue * 0.25) {
 131                 color.x = 1;
 132                 color.y = 1;
 133                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 134         }
 135         else if(x > maxvalue * 0.1) {
 136                 color.x = 1;
 137                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 138                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 139         }
 140         else {
 141                 color.x = 1;
 142                 color.y = 0;
 143                 color.z = 0;
 144         }
 145
 146         blinkingamt = (1 - x/maxvalue/0.25);
 147         if(blinkingamt > 0)
 148         {
 149                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 150                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 151                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 152         }
 153         return color;
 154 }
 155
 156 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
 157 {
 158         float aspect = size_y / size_x;
 159         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 160 }
 161
 162 vector HUD_GetTableSize(int item_count, vector psize, float item_aspect)
 163 {
 164         float columns, rows;
 165         float ratio, best_ratio = 0;
 166         float best_columns = 1, best_rows = 1;
 167         bool vertical = (psize.x / psize.y >= item_aspect);
 168         if(vertical)
 169         {
 170                 psize = eX * psize.y + eY * psize.x;
 171                 item_aspect = 1 / item_aspect;
 172         }
 173
 174         rows = ceil(sqrt(item_count));
 175         columns = ceil(item_count/rows);
 176         while(columns >= 1)
 177         {
 178                 ratio = (psize.x/columns) / (psize.y/rows);
 179                 if(ratio > item_aspect)
 180                         ratio = item_aspect * item_aspect / ratio;
 181
 182                 if(ratio <= best_ratio)
 183                         break; // ratio starts decreasing by now, skip next configurations
 184
 185                 best_columns = columns;
 186                 best_rows = rows;
 187                 best_ratio = ratio;
 188
 189                 if(columns == 1)
 190                         break;
 191
 192                 --columns;
 193                 rows = ceil(item_count/columns);
 194         }
 195
 196         if(vertical)
 197                 return eX * best_rows + eY * best_columns;
 198         else
 199                 return eX * best_columns + eY * best_rows;
 200 }
 201
 202 float stringwidth_colors(string s, vector theSize)
 203 {
 204         return stringwidth(s, true, theSize);
 205 }
 206
 207 float stringwidth_nocolors(string s, vector theSize)
 208 {
 209         return stringwidth(s, false, theSize);
 210 }
 211
 212 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 213 {
 214         position.x -= 2 / 3 * strlen(text) * theScale.x;
 215         drawstring(position, text, theScale, rgb, theAlpha, flag);
 216 }
 217
 218 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 219 {
 220         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 221         drawstring(position, text, theScale, rgb, theAlpha, flag);
 222 }
 223
 224 // return the string of the onscreen race timer
 225 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 226 {
 227         string col;
 228         string timestr;
 229         string cpname;
 230         string lapstr;
 231         lapstr = "";
 232
 233         if(theirtime == 0) // goal hit
 234         {
 235                 if(mytime > 0)
 236                 {
 237                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 238                         col = "^1";
 239                 }
 240                 else if(mytime == 0)
 241                 {
 242                         timestr = "+0.0";
 243                         col = "^3";
 244                 }
 245                 else
 246                 {
 247                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 248                         col = "^2";
 249                 }
 250
 251                 if(lapdelta > 0)
 252                 {
 253                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 254                         col = "^2";
 255                 }
 256                 else if(lapdelta < 0)
 257                 {
 258                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 259                         col = "^1";
 260                 }
 261         }
 262         else if(theirtime > 0) // anticipation
 263         {
 264                 if(mytime >= theirtime)
 265                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 266                 else
 267                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 268                 col = "^3";
 269         }
 270         else
 271         {
 272                 col = "^7";
 273                 timestr = "";
 274         }
 275
 276         if(cp == 254)
 277                 cpname = _("Start line");
 278         else if(cp == 255)
 279                 cpname = _("Finish line");
 280         else if(cp)
 281                 cpname = sprintf(_("Intermediate %d"), cp);
 282         else
 283                 cpname = _("Finish line");
 284
 285         if(theirtime < 0)
 286                 return strcat(col, cpname);
 287         else if(theirname == "")
 288                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 289         else
 290                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 291 }
 292
 293 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 294 int race_CheckName(string net_name)
 295 {
 296         int i;
 297         for (i=RANKINGS_CNT-1;i>=0;--i)
 298                 if(grecordholder[i] == net_name)
 299                         return i+1;
 300         return 0;
 301 }
 302
 303 int GetPlayerColorForce(int i)
 304 {
 305         if(!teamplay)
 306                 return 0;
 307         else
 308                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 309 }
 310
 311 int GetPlayerColor(int i)
 312 {
 313         if(!playerslots[i].gotscores) // unconnected
 314                 return NUM_SPECTATOR;
 315         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 316                 return NUM_SPECTATOR;
 317         else
 318                 return GetPlayerColorForce(i);
 319 }
 320
 321 string GetPlayerName(int i)
 322 {
 323         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 324 }
 325
 326
 327 /*
 328 ==================
 329 HUD panels
 330 ==================
 331 */
 332
 333 // draw the background/borders
 334 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 335         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 336                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 337 } while(0)
 338
 339 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 340 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 341 {
 342         if(!length_ratio || !theAlpha)
 343                 return;
 344         if(length_ratio > 1)
 345                 length_ratio = 1;
 346         if (baralign == 3)
 347         {
 348                 if(length_ratio < -1)
 349                         length_ratio = -1;
 350         }
 351         else if(length_ratio < 0)
 352                 return;
 353
 354         vector square;
 355         vector width, height;
 356         if(vertical) {
 357                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 358                 if(precache_pic(pic) == "") {
 359                         pic = "gfx/hud/default/progressbar_vertical";
 360                 }
 361
 362         if (baralign == 1) // bottom align
 363                         theOrigin.y += (1 - length_ratio) * theSize.y;
 364         else if (baralign == 2) // center align
 365             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 366         else if (baralign == 3) // center align, positive values down, negative up
 367                 {
 368                         theSize.y *= 0.5;
 369                         if (length_ratio > 0)
 370                                 theOrigin.y += theSize.y;
 371                         else
 372                         {
 373                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 374                                 length_ratio = -length_ratio;
 375                         }
 376                 }
 377                 theSize.y *= length_ratio;
 378
 379                 vector bH;
 380                 width = eX * theSize.x;
 381                 height = eY * theSize.y;
 382                 if(theSize.y <= theSize.x * 2)
 383                 {
 384                         // button not high enough
 385                         // draw just upper and lower part then
 386                         square = eY * theSize.y * 0.5;
 387                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 388                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 389                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 390                 }
 391                 else
 392                 {
 393                         square = eY * theSize.x;
 394                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 395                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 396                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 397                 }
 398         } else {
 399                 pic = strcat(hud_skin_path, "/", pic);
 400                 if(precache_pic(pic) == "") {
 401                         pic = "gfx/hud/default/progressbar";
 402                 }
 403
 404                 if (baralign == 1) // right align
 405                         theOrigin.x += (1 - length_ratio) * theSize.x;
 406         else if (baralign == 2) // center align
 407             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 408         else if (baralign == 3) // center align, positive values on the right, negative on the left
 409                 {
 410                         theSize.x *= 0.5;
 411                         if (length_ratio > 0)
 412                                 theOrigin.x += theSize.x;
 413                         else
 414                         {
 415                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 416                                 length_ratio = -length_ratio;
 417                         }
 418                 }
 419                 theSize.x *= length_ratio;
 420
 421                 vector bW;
 422                 width = eX * theSize.x;
 423                 height = eY * theSize.y;
 424                 if(theSize.x <= theSize.y * 2)
 425                 {
 426                         // button not wide enough
 427                         // draw just left and right part then
 428                         square = eX * theSize.x * 0.5;
 429                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 430                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 431                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 432                 }
 433                 else
 434                 {
 435                         square = eX * theSize.y;
 436                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 437                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 438                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 439                 }
 440         }
 441 }
 442
 443 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 444 {
 445         if(!theAlpha)
 446                 return;
 447
 448         string pic;
 449         pic = strcat(hud_skin_path, "/num_leading");
 450         if(precache_pic(pic) == "") {
 451                 pic = "gfx/hud/default/num_leading";
 452         }
 453
 454         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 455         if(mySize.x/mySize.y > 2)
 456                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 457         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 458 }
 459
 460 // Weapon icons (#0)
 461 //
 462 entity weaponorder[WEP_MAXCOUNT];
 463 void weaponorder_swap(int i, int j, entity pass)
 464 {
 465         entity h = weaponorder[i];
 466         weaponorder[i] = weaponorder[j];
 467         weaponorder[j] = h;
 468 }
 469
 470 string weaponorder_cmp_str;
 471 int weaponorder_cmp(int i, int j, entity pass)
 472 {
 473         int ai, aj;
 474         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 475         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 476         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 477 }
 478
 479 void HUD_Weapons(void)
 480 {
 481         // declarations
 482         WepSet weapons_stat = WepSet_GetFromStat();
 483         int i;
 484         float f, a;
 485         float screen_ar;
 486         vector center = '0 0 0';
 487         int weapon_count, weapon_id;
 488         int row, column, rows = 0, columns = 0;
 489         bool vertical_order = true;
 490         float aspect = autocvar_hud_panel_weapons_aspect;
 491
 492         float timeout = autocvar_hud_panel_weapons_timeout;
 493         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 494         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 495
 496         vector barsize = '0 0 0', baroffset = '0 0 0';
 497         vector ammo_color = '1 0 1';
 498         float ammo_alpha = 1;
 499
 500         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 501         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 502
 503         vector weapon_pos, weapon_size = '0 0 0';
 504         vector color;
 505
 506         // check to see if we want to continue
 507         if(hud != HUD_NORMAL) { return; }
 508
 509         if(!autocvar__hud_configure)
 510         {
 511                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 512                         return;
 513                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 514                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 515                 {
 516                         weaponprevtime = time;
 517                         return;
 518                 }
 519         }
 520
 521         // update generic hud functions
 522         HUD_Panel_UpdateCvars();
 523
 524         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 525         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 526         {
 527                 int weapon_cnt;
 528                 if(weaponorder_bypriority)
 529                         strunzone(weaponorder_bypriority);
 530                 if(weaponorder_byimpulse)
 531                         strunzone(weaponorder_byimpulse);
 532
 533                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 534                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 535                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 536
 537                 weapon_cnt = 0;
 538                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 539                 {
 540                         self = get_weaponinfo(i);
 541                         if(self.impulse >= 0)
 542                         {
 543                                 weaponorder[weapon_cnt] = self;
 544                                 ++weapon_cnt;
 545                         }
 546                 }
 547                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 548                         weaponorder[i] = world;
 549                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 550
 551                 weaponorder_cmp_str = string_null;
 552         }
 553
 554         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 555                 complain_weapon = 0;
 556
 557         if(autocvar__hud_configure)
 558         {
 559                 if(!weapons_stat)
 560                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 561                                 weapons_stat |= WepSet_FromWeapon(i);
 562
 563                 #if 0
 564                 /// debug code
 565                 if(cvar("wep_add"))
 566                 {
 567                         weapons_stat = '0 0 0';
 568                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
 569                         for(i = WEP_FIRST; i <= countw; ++i)
 570                                 weapons_stat |= WepSet_FromWeapon(i);
 571                 }
 572                 #endif
 573         }
 574
 575         // determine which weapons are going to be shown
 576         if (autocvar_hud_panel_weapons_onlyowned)
 577         {
 578                 if(autocvar__hud_configure)
 579                 {
 580                         if(menu_enabled != 2)
 581                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 582                 }
 583
 584                 // do we own this weapon?
 585                 weapon_count = 0;
 586                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 587                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 588                                 ++weapon_count;
 589
 590
 591                 // might as well commit suicide now, no reason to live ;)
 592                 if (weapon_count == 0)
 593                         return;
 594
 595                 vector old_panel_size = panel_size;
 596                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 597
 598                 // get the all-weapons layout
 599                 vector table_size = HUD_GetTableSize(WEP_COUNT, padded_panel_size, aspect);
 600                 columns = table_size.x;
 601                 rows = table_size.y;
 602                 weapon_size.x = padded_panel_size.x / columns;
 603                 weapon_size.y = padded_panel_size.y / rows;
 604
 605                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 606                 // we enlarge them a bit when possible to better match the desired aspect ratio
 607                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 608                 {
 609                         // maximum number of rows that allows to display items with the desired aspect ratio
 610                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 611                         columns = min(columns, ceil(weapon_count / max_rows));
 612                         rows = ceil(weapon_count / columns);
 613                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 614                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 615                         vertical_order = false;
 616                 }
 617                 else
 618                 {
 619                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 620                         rows = min(rows, ceil(weapon_count / max_columns));
 621                         columns = ceil(weapon_count / rows);
 622                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 623                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 624                         vertical_order = true;
 625                 }
 626
 627                 // reduce size of the panel
 628                 panel_size.x = columns * weapon_size.x;
 629                 panel_size.y = rows * weapon_size.y;
 630                 panel_size += '2 2 0' * panel_bg_padding;
 631
 632                 // center the resized panel, or snap it to the screen edge when close enough
 633                 if(panel_pos.x > vid_conwidth * 0.001)
 634                 {
 635                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 636                                 panel_pos.x += old_panel_size.x - panel_size.x;
 637                         else
 638                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 639                 }
 640                 else if(old_panel_size.x > vid_conwidth * 0.999)
 641                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 642
 643                 if(panel_pos.y > vid_conheight * 0.001)
 644                 {
 645                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 646                                 panel_pos.y += old_panel_size.y - panel_size.y;
 647                         else
 648                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 649                 }
 650                 else if(old_panel_size.y > vid_conheight * 0.999)
 651                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 652         }
 653         else
 654                 weapon_count = WEP_COUNT;
 655
 656         // animation for fading in/out the panel respectively when not in use
 657         if(!autocvar__hud_configure)
 658         {
 659                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 660                 {
 661                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 662
 663                         // fade the panel alpha
 664                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 665                         {
 666                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 667                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 668                         }
 669                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 670                         {
 671                                 panel_bg_alpha *= (1 - f);
 672                                 panel_fg_alpha *= (1 - f);
 673                         }
 674
 675                         // move the panel off the screen
 676                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 677                         {
 678                                 f *= f; // for a cooler movement
 679                                 center.x = panel_pos.x + panel_size.x/2;
 680                                 center.y = panel_pos.y + panel_size.y/2;
 681                                 screen_ar = vid_conwidth/vid_conheight;
 682                                 if (center.x/center.y < screen_ar) //bottom left
 683                                 {
 684                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 685                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 686                                         else //left
 687                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 688                                 }
 689                                 else //top right
 690                                 {
 691                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 692                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 693                                         else //top
 694                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 695                                 }
 696                                 if(f == 1)
 697                                         center.x = -1; // mark the panel as off screen
 698                         }
 699                         weaponprevtime = time - (1 - f) * timein_effect_length;
 700                 }
 701                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 702                 {
 703                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 704
 705                         // fade the panel alpha
 706                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 707                         {
 708                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 709                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 710                         }
 711                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 712                         {
 713                                 panel_bg_alpha *= (f);
 714                                 panel_fg_alpha *= (f);
 715                         }
 716
 717                         // move the panel back on screen
 718                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 719                         {
 720                                 f *= f; // for a cooler movement
 721                                 f = 1 - f;
 722                                 center.x = panel_pos.x + panel_size.x/2;
 723                                 center.y = panel_pos.y + panel_size.y/2;
 724                                 screen_ar = vid_conwidth/vid_conheight;
 725                                 if (center.x/center.y < screen_ar) //bottom left
 726                                 {
 727                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 728                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 729                                         else //left
 730                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 731                                 }
 732                                 else //top right
 733                                 {
 734                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 735                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 736                                         else //top
 737                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 738                                 }
 739                         }
 740                 }
 741         }
 742
 743         // draw the background, then change the virtual size of it to better fit other items inside
 744         HUD_Panel_DrawBg(1);
 745
 746         if(center.x == -1)
 747                 return;
 748
 749         if(panel_bg_padding)
 750         {
 751                 panel_pos += '1 1 0' * panel_bg_padding;
 752                 panel_size -= '2 2 0' * panel_bg_padding;
 753         }
 754
 755         // after the sizing and animations are done, update the other values
 756
 757         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 758         {
 759                 vector table_size = HUD_GetTableSize(WEP_COUNT, panel_size, aspect);
 760                 columns = table_size.x;
 761                 rows = table_size.y;
 762                 weapon_size.x = panel_size.x / columns;
 763                 weapon_size.y = panel_size.y / rows;
 764                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 765         }
 766
 767         // calculate position/size for visual bar displaying ammount of ammo status
 768         if (autocvar_hud_panel_weapons_ammo)
 769         {
 770                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 771                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 772
 773                 if(weapon_size.x/weapon_size.y > aspect)
 774                 {
 775                         barsize.x = aspect * weapon_size.y;
 776                         barsize.y = weapon_size.y;
 777                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 778                 }
 779                 else
 780                 {
 781                         barsize.y = 1/aspect * weapon_size.x;
 782                         barsize.x = weapon_size.x;
 783                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 784                 }
 785         }
 786         if(autocvar_hud_panel_weapons_accuracy)
 787                 Accuracy_LoadColors();
 788
 789         // draw items
 790         row = column = 0;
 791         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 792         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 793         {
 794                 // retrieve information about the current weapon to be drawn
 795                 self = weaponorder[i];
 796                 weapon_id = self.impulse;
 797
 798                 // skip if this weapon doesn't exist
 799                 if(!self || weapon_id < 0) { continue; }
 800
 801                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 802                 if(autocvar_hud_panel_weapons_onlyowned)
 803                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 804                         continue;
 805
 806                 // figure out the drawing position of weapon
 807                 weapon_pos = (panel_pos
 808                         + eX * column * weapon_size.x
 809                         + eY * row * weapon_size.y);
 810
 811                 // draw background behind currently selected weapon
 812                 if(self.weapon == switchweapon)
 813                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 814
 815                 // draw the weapon accuracy
 816                 if(autocvar_hud_panel_weapons_accuracy)
 817                 {
 818                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 819                         if(panel_weapon_accuracy >= 0)
 820                         {
 821                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 822                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 823                         }
 824                 }
 825
 826                 // drawing all the weapon items
 827                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 828                 {
 829                         // draw the weapon image
 830                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 831
 832                         // draw weapon label string
 833                         switch(autocvar_hud_panel_weapons_label)
 834                         {
 835                                 case 1: // weapon number
 836                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 837                                         break;
 838
 839                                 case 2: // bind
 840                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 841                                         break;
 842
 843                                 case 3: // weapon name
 844                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 845                                         break;
 846
 847                                 default: // nothing
 848                                         break;
 849                         }
 850
 851                         // draw ammo status bar
 852                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 853                         {
 854                                 float ammo_full;
 855                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 856
 857                                 if(a > 0)
 858                                 {
 859                                         switch(self.ammo_field)
 860                                         {
 861                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 862                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 863                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 864                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 865                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 866                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 867                                                 default: ammo_full = 60;
 868                                         }
 869
 870                                         drawsetcliparea(
 871                                                 weapon_pos.x + baroffset.x,
 872                                                 weapon_pos.y + baroffset.y,
 873                                                 barsize.x * bound(0, a/ammo_full, 1),
 874                                                 barsize.y
 875                                         );
 876
 877                                         drawpic_aspect_skin(
 878                                                 weapon_pos,
 879                                                 "weapon_ammo",
 880                                                 weapon_size,
 881                                                 ammo_color,
 882                                                 ammo_alpha,
 883                                                 DRAWFLAG_NORMAL
 884                                         );
 885
 886                                         drawresetcliparea();
 887                                 }
 888                         }
 889                 }
 890                 else // draw a "ghost weapon icon" if you don't have the weapon
 891                 {
 892                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 893                 }
 894
 895                 // draw the complain message
 896                 if(self.weapon == complain_weapon)
 897                 {
 898                         if(fadetime)
 899                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 900                         else
 901                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 902
 903                         string s;
 904                         if(complain_weapon_type == 0) {
 905                                 s = _("Out of ammo");
 906                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 907                         }
 908                         else if(complain_weapon_type == 1) {
 909                                 s = _("Don't have");
 910                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 911                         }
 912                         else {
 913                                 s = _("Unavailable");
 914                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 915                         }
 916                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 917                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 918                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 919                 }
 920
 921                 #if 0
 922                 /// debug code
 923                 if(!autocvar_hud_panel_weapons_onlyowned)
 924                 {
 925                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 926                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 927                 }
 928                 #endif
 929
 930                 // continue with new position for the next weapon
 931                 if(vertical_order)
 932                 {
 933                         ++column;
 934                         if(column >= columns)
 935                         {
 936                                 column = 0;
 937                                 ++row;
 938                         }
 939                 }
 940                 else
 941                 {
 942                         ++row;
 943                         if(row >= rows)
 944                         {
 945                                 row = 0;
 946                                 ++column;
 947                         }
 948                 }
 949         }
 950 }
 951
 952 // Ammo (#1)
 953 void DrawNadeScoreBar(vector myPos, vector mySize, vector color)
 954 {
 955
 956         HUD_Panel_DrawProgressBar(
 957                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 958                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 959                 autocvar_hud_panel_ammo_progressbar_name,
 960                 getstatf(STAT_NADE_BONUS_SCORE), 0, 0, color,
 961                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 962
 963 }
 964
 965 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 966 {
 967         float theAlpha = 1, a, b;
 968         vector nade_color, picpos, numpos;
 969
 970         nade_color = Nade_Color(getstati(STAT_NADE_BONUS_TYPE));
 971
 972         a = getstatf(STAT_NADE_BONUS);
 973         b = getstatf(STAT_NADE_BONUS_SCORE);
 974
 975         if(autocvar_hud_panel_ammo_iconalign)
 976         {
 977                 numpos = myPos;
 978                 picpos = myPos + eX * 2 * mySize.y;
 979         }
 980         else
 981         {
 982                 numpos = myPos + eX * mySize.y;
 983                 picpos = myPos;
 984         }
 985
 986         DrawNadeScoreBar(myPos, mySize, nade_color);
 987
 988         if(b > 0 || a > 0)
 989         {
 990                 if(autocvar_hud_panel_ammo_text)
 991                         drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 992
 993                 if(draw_expanding)
 994                         drawpic_aspect_skin_expanding(picpos, "nade_nbg", '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, expand_time);
 995
 996                 drawpic_aspect_skin(picpos, "nade_bg" , '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 997                 drawpic_aspect_skin(picpos, "nade_nbg" , '1 1 0' * mySize.y, nade_color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 998         }
 999 }
1000
1001 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
1002 {
1003         if(ammoType == ammo_none)
1004                 return;
1005
1006         // Initialize variables
1007
1008         int ammo;
1009         if(autocvar__hud_configure)
1010         {
1011                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1012                 ammo = 60;
1013         }
1014         else
1015                 ammo = getstati(GetAmmoStat(ammoType));
1016
1017         if(!isCurrent)
1018         {
1019                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1020                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1021                 mySize = mySize * scale;
1022         }
1023
1024         vector iconPos, textPos;
1025         if(autocvar_hud_panel_ammo_iconalign)
1026         {
1027                 iconPos = myPos + eX * 2 * mySize.y;
1028                 textPos = myPos;
1029         }
1030         else
1031         {
1032                 iconPos = myPos;
1033                 textPos = myPos + eX * mySize.y;
1034         }
1035
1036         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1037
1038         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1039         vector textColor;
1040         if(isInfinite)
1041                 textColor = '0.2 0.95 0';
1042         else if(isShadowed)
1043                 textColor = '0 0 0';
1044         else if(ammo < 10)
1045                 textColor = '0.8 0.04 0';
1046         else
1047                 textColor = '1 1 1';
1048
1049         float alpha;
1050         if(isCurrent)
1051                 alpha = panel_fg_alpha;
1052         else if(isShadowed)
1053                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1054         else
1055                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1056
1057         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1058
1059         // Draw item
1060
1061         if(isCurrent)
1062                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1063
1064         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1065                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1066
1067         if(autocvar_hud_panel_ammo_text)
1068                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1069
1070         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1071 }
1072
1073 int nade_prevstatus;
1074 int nade_prevframe;
1075 float nade_statuschange_time;
1076 void HUD_Ammo(void)
1077 {
1078         if(hud != HUD_NORMAL) return;
1079         if(!autocvar__hud_configure)
1080         {
1081                 if(!autocvar_hud_panel_ammo) return;
1082                 if(spectatee_status == -1) return;
1083         }
1084
1085         HUD_Panel_UpdateCvars();
1086
1087         draw_beginBoldFont();
1088
1089         vector pos, mySize;
1090         pos = panel_pos;
1091         mySize = panel_size;
1092
1093         HUD_Panel_DrawBg(1);
1094         if(panel_bg_padding)
1095         {
1096                 pos += '1 1 0' * panel_bg_padding;
1097                 mySize -= '2 2 0' * panel_bg_padding;
1098         }
1099
1100         int rows = 0, columns, row, column;
1101         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1102         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
1103         float nade_statuschange_elapsedtime;
1104         int total_ammo_count;
1105
1106         vector ammo_size;
1107         if (autocvar_hud_panel_ammo_onlycurrent)
1108                 total_ammo_count = 1;
1109         else
1110                 total_ammo_count = AMMO_COUNT;
1111
1112         if(draw_nades)
1113         {
1114                 ++total_ammo_count;
1115                 if (nade_cnt != nade_prevframe)
1116                 {
1117                         nade_statuschange_time = time;
1118                         nade_prevstatus = nade_prevframe;
1119                         nade_prevframe = nade_cnt;
1120                 }
1121         }
1122         else
1123                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1124
1125         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1126         columns = ceil((total_ammo_count)/rows);
1127         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1128
1129         vector offset = '0 0 0'; // fteqcc sucks
1130         float newSize;
1131         if(ammo_size.x/ammo_size.y > 3)
1132         {
1133                 newSize = 3 * ammo_size.y;
1134                 offset.x = ammo_size.x - newSize;
1135                 pos.x += offset.x/2;
1136                 ammo_size.x = newSize;
1137         }
1138         else
1139         {
1140                 newSize = 1/3 * ammo_size.x;
1141                 offset.y = ammo_size.y - newSize;
1142                 pos.y += offset.y/2;
1143                 ammo_size.y = newSize;
1144         }
1145
1146         int i;
1147         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1148         row = column = 0;
1149         if(autocvar_hud_panel_ammo_onlycurrent)
1150         {
1151                 if(autocvar__hud_configure)
1152                 {
1153                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1154                 }
1155                 else
1156                 {
1157                         DrawAmmoItem(
1158                                 pos,
1159                                 ammo_size,
1160                                 (get_weaponinfo(switchweapon)).ammo_field,
1161                                 true,
1162                                 infinite_ammo
1163                         );
1164                 }
1165
1166                 ++row;
1167                 if(row >= rows)
1168                 {
1169                         row = 0;
1170                         column = column + 1;
1171                 }
1172         }
1173         else
1174         {
1175                 .int ammotype;
1176                 row = column = 0;
1177                 for(i = 0; i < AMMO_COUNT; ++i)
1178                 {
1179                         ammotype = GetAmmoFieldFromNum(i);
1180                         DrawAmmoItem(
1181                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1182                                 ammo_size,
1183                                 ammotype,
1184                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1185                                 infinite_ammo
1186                         );
1187
1188                         ++row;
1189                         if(row >= rows)
1190                         {
1191                                 row = 0;
1192                                 column = column + 1;
1193                         }
1194                 }
1195         }
1196
1197         if (draw_nades)
1198         {
1199                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1200
1201                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1202
1203                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1204         }
1205
1206         draw_endBoldFont();
1207 }
1208
1209 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1210 {
1211         vector newPos = '0 0 0', newSize = '0 0 0';
1212         vector picpos, numpos;
1213
1214         if (vertical)
1215         {
1216                 if(mySize.y/mySize.x > 2)
1217                 {
1218                         newSize.y = 2 * mySize.x;
1219                         newSize.x = mySize.x;
1220
1221                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1222                         newPos.x = myPos.x;
1223                 }
1224                 else
1225                 {
1226                         newSize.x = 1/2 * mySize.y;
1227                         newSize.y = mySize.y;
1228
1229                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1230                         newPos.y = myPos.y;
1231                 }
1232
1233                 if(icon_right_align)
1234                 {
1235                         numpos = newPos;
1236                         picpos = newPos + eY * newSize.x;
1237                 }
1238                 else
1239                 {
1240                         picpos = newPos;
1241                         numpos = newPos + eY * newSize.x;
1242                 }
1243
1244                 newSize.y /= 2;
1245                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1246                 // make number smaller than icon, it looks better
1247                 // reduce only y to draw numbers with different number of digits with the same y size
1248                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1249                 newSize.y *= 0.7;
1250                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1251                 return;
1252         }
1253
1254         if(mySize.x/mySize.y > 3)
1255         {
1256                 newSize.x = 3 * mySize.y;
1257                 newSize.y = mySize.y;
1258
1259                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1260                 newPos.y = myPos.y;
1261         }
1262         else
1263         {
1264                 newSize.y = 1/3 * mySize.x;
1265                 newSize.x = mySize.x;
1266
1267                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1268                 newPos.x = myPos.x;
1269         }
1270
1271         if(icon_right_align) // right align
1272         {
1273                 numpos = newPos;
1274                 picpos = newPos + eX * 2 * newSize.y;
1275         }
1276         else // left align
1277         {
1278                 numpos = newPos + eX * newSize.y;
1279                 picpos = newPos;
1280         }
1281
1282         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1283         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1284         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1285         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1286 }
1287
1288 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1289 {
1290         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1291 }
1292
1293 // Powerups (#2)
1294 //
1295 void HUD_Powerups(void)
1296 {
1297         float strength_time, shield_time, superweapons_time;
1298         if(!autocvar__hud_configure)
1299         {
1300                 if(!autocvar_hud_panel_powerups) return;
1301                 if(spectatee_status == -1) return;
1302                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1303                 if (getstati(STAT_HEALTH) <= 0) return;
1304
1305                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1306                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1307                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1308
1309                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1310                         superweapons_time = 99; // force max
1311
1312                 // prevent stuff to show up on mismatch that will be fixed next frame
1313                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1314                         superweapons_time = 0;
1315         }
1316         else
1317         {
1318                 strength_time = 15;
1319                 shield_time = 27;
1320                 superweapons_time = 13;
1321         }
1322
1323         HUD_Panel_UpdateCvars();
1324
1325         draw_beginBoldFont();
1326
1327         vector pos, mySize;
1328         pos = panel_pos;
1329         mySize = panel_size;
1330
1331         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1332         if(panel_bg_padding)
1333         {
1334                 pos += '1 1 0' * panel_bg_padding;
1335                 mySize -= '2 2 0' * panel_bg_padding;
1336         }
1337
1338         float panel_ar = mySize.x/mySize.y;
1339         bool is_vertical = (panel_ar < 1);
1340         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1341
1342         int superweapons_is = -1;
1343
1344         if(superweapons_time)
1345         {
1346                 if(strength_time)
1347                 {
1348                         if(shield_time)
1349                                 superweapons_is = 0;
1350                         else
1351                                 superweapons_is = 2;
1352                 }
1353                 else
1354                 {
1355                         if(shield_time)
1356                                 superweapons_is = 1;
1357                         else
1358                                 superweapons_is = 2;
1359                 }
1360         }
1361
1362         // FIXME handle superweapons here
1363         if(superweapons_is == 0)
1364         {
1365                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1366                 {
1367                         mySize.x *= (1.0 / 3.0);
1368                         superweapons_offset.x = mySize.x;
1369                         if (autocvar_hud_panel_powerups_flip)
1370                                 shield_offset.x = 2*mySize.x;
1371                         else
1372                                 strength_offset.x = 2*mySize.x;
1373                 }
1374                 else
1375                 {
1376                         mySize.y *= (1.0 / 3.0);
1377                         superweapons_offset.y = mySize.y;
1378                         if (autocvar_hud_panel_powerups_flip)
1379                                 shield_offset.y = 2*mySize.y;
1380                         else
1381                                 strength_offset.y = 2*mySize.y;
1382                 }
1383         }
1384         else
1385         {
1386                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1387                 {
1388                         mySize.x *= 0.5;
1389                         if (autocvar_hud_panel_powerups_flip)
1390                                 shield_offset.x = mySize.x;
1391                         else
1392                                 strength_offset.x = mySize.x;
1393                 }
1394                 else
1395                 {
1396                         mySize.y *= 0.5;
1397                         if (autocvar_hud_panel_powerups_flip)
1398                                 shield_offset.y = mySize.y;
1399                         else
1400                                 strength_offset.y = mySize.y;
1401                 }
1402         }
1403
1404         bool shield_baralign, strength_baralign, superweapons_baralign;
1405         bool shield_iconalign, strength_iconalign, superweapons_iconalign;
1406
1407         if (autocvar_hud_panel_powerups_flip)
1408         {
1409                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1410                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1411                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1412                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1413         }
1414         else
1415         {
1416                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1417                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1418                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1419                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1420         }
1421
1422         if(superweapons_is == 0)
1423         {
1424                 superweapons_iconalign = strength_iconalign;
1425                 superweapons_baralign = 2;
1426         }
1427         else if(superweapons_is == 1)
1428         {
1429                 superweapons_offset = strength_offset;
1430                 superweapons_iconalign = strength_iconalign;
1431                 superweapons_baralign = strength_baralign;
1432         }
1433         else // if(superweapons_is == 2)
1434         {
1435                 superweapons_offset = shield_offset;
1436                 superweapons_iconalign = shield_iconalign;
1437                 superweapons_baralign = shield_baralign;
1438         }
1439
1440         if(shield_time)
1441         {
1442                 const float maxshield = 30;
1443                 float shield = ceil(shield_time);
1444                 if(autocvar_hud_panel_powerups_progressbar)
1445                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1446                 if(autocvar_hud_panel_powerups_text)
1447                 {
1448                         if(shield > 1)
1449                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1450                         if(shield <= 5)
1451                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1452                 }
1453         }
1454
1455         if(strength_time)
1456         {
1457                 const float maxstrength = 30;
1458                 float strength = ceil(strength_time);
1459                 if(autocvar_hud_panel_powerups_progressbar)
1460                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1461                 if(autocvar_hud_panel_powerups_text)
1462                 {
1463                         if(strength > 1)
1464                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1465                         if(strength <= 5)
1466                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1467                 }
1468         }
1469
1470         if(superweapons_time)
1471         {
1472                 const float maxsuperweapons = 30;
1473                 float superweapons = ceil(superweapons_time);
1474                 if(autocvar_hud_panel_powerups_progressbar)
1475                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1476                 if(autocvar_hud_panel_powerups_text)
1477                 {
1478                         if(superweapons > 1)
1479                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1480                         if(superweapons <= 5)
1481                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1482                 }
1483         }
1484
1485         draw_endBoldFont();
1486 }
1487
1488 // Health/armor (#3)
1489 //
1490
1491
1492 void HUD_HealthArmor(void)
1493 {
1494         int armor, health, fuel;
1495         if(!autocvar__hud_configure)
1496         {
1497                 if(!autocvar_hud_panel_healtharmor) return;
1498                 if(hud != HUD_NORMAL) return;
1499                 if(spectatee_status == -1) return;
1500
1501                 health = getstati(STAT_HEALTH);
1502                 if(health <= 0)
1503                 {
1504                         prev_health = -1;
1505                         return;
1506                 }
1507                 armor = getstati(STAT_ARMOR);
1508
1509                 // code to check for spectatee_status changes is in Ent_ClientData()
1510                 // prev_p_health and prev_health can be set to -1 there
1511
1512                 if (prev_p_health == -1)
1513                 {
1514                         // no effect
1515                         health_beforedamage = 0;
1516                         armor_beforedamage = 0;
1517                         health_damagetime = 0;
1518                         armor_damagetime = 0;
1519                         prev_health = health;
1520                         prev_armor = armor;
1521                         old_p_health = health;
1522                         old_p_armor = armor;
1523                         prev_p_health = health;
1524                         prev_p_armor = armor;
1525                 }
1526                 else if (prev_health == -1)
1527                 {
1528                         //start the load effect
1529                         health_damagetime = 0;
1530                         armor_damagetime = 0;
1531                         prev_health = 0;
1532                         prev_armor = 0;
1533                 }
1534                 fuel = getstati(STAT_FUEL);
1535         }
1536         else
1537         {
1538                 health = 150;
1539                 armor = 75;
1540                 fuel = 20;
1541         }
1542
1543         HUD_Panel_UpdateCvars();
1544
1545         draw_beginBoldFont();
1546
1547         vector pos, mySize;
1548         pos = panel_pos;
1549         mySize = panel_size;
1550
1551         HUD_Panel_DrawBg(1);
1552         if(panel_bg_padding)
1553         {
1554                 pos += '1 1 0' * panel_bg_padding;
1555                 mySize -= '2 2 0' * panel_bg_padding;
1556         }
1557
1558         int baralign = autocvar_hud_panel_healtharmor_baralign;
1559         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1560
1561     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1562     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1563         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1564         {
1565                 vector v;
1566                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1567
1568                 float x;
1569                 x = floor(v.x + 1);
1570
1571         float maxtotal = maxhealth + maxarmor;
1572                 string biggercount;
1573                 if(v.z) // NOT fully armored
1574                 {
1575                         biggercount = "health";
1576                         if(autocvar_hud_panel_healtharmor_progressbar)
1577                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1578                         if(armor)
1579             if(autocvar_hud_panel_healtharmor_text)
1580                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1581                 }
1582                 else
1583                 {
1584                         biggercount = "armor";
1585                         if(autocvar_hud_panel_healtharmor_progressbar)
1586                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1587                         if(health)
1588             if(autocvar_hud_panel_healtharmor_text)
1589                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1590                 }
1591         if(autocvar_hud_panel_healtharmor_text)
1592                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1593
1594                 if(fuel)
1595                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1596         }
1597         else
1598         {
1599                 float panel_ar = mySize.x/mySize.y;
1600                 bool is_vertical = (panel_ar < 1);
1601                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1602                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1603                 {
1604                         mySize.x *= 0.5;
1605                         if (autocvar_hud_panel_healtharmor_flip)
1606                                 health_offset.x = mySize.x;
1607                         else
1608                                 armor_offset.x = mySize.x;
1609                 }
1610                 else
1611                 {
1612                         mySize.y *= 0.5;
1613                         if (autocvar_hud_panel_healtharmor_flip)
1614                                 health_offset.y = mySize.y;
1615                         else
1616                                 armor_offset.y = mySize.y;
1617                 }
1618
1619                 bool health_baralign, armor_baralign, fuel_baralign;
1620                 bool health_iconalign, armor_iconalign;
1621                 if (autocvar_hud_panel_healtharmor_flip)
1622                 {
1623                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1624                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1625                         fuel_baralign = health_baralign;
1626                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1627                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1628                 }
1629                 else
1630                 {
1631                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1632                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1633                         fuel_baralign = armor_baralign;
1634                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1635                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1636                 }
1637
1638                 //if(health)
1639                 {
1640                         if(autocvar_hud_panel_healtharmor_progressbar)
1641                         {
1642                                 float p_health, pain_health_alpha;
1643                                 p_health = health;
1644                                 pain_health_alpha = 1;
1645                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1646                                 {
1647                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1648                                         {
1649                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1650                                                 {
1651                                                         if (time - old_p_healthtime < 1)
1652                                                                 old_p_health = prev_p_health;
1653                                                         else
1654                                                                 old_p_health = prev_health;
1655                                                         old_p_healthtime = time;
1656                                                 }
1657                                                 if (time - old_p_healthtime < 1)
1658                                                 {
1659                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1660                                                         prev_p_health = p_health;
1661                                                 }
1662                                         }
1663                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1664                                         {
1665                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1666                                                 {
1667                                                         if (time - health_damagetime >= 1)
1668                                                                 health_beforedamage = prev_health;
1669                                                         health_damagetime = time;
1670                                                 }
1671                                                 if (time - health_damagetime < 1)
1672                                                 {
1673                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1674                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1675                                                 }
1676                                         }
1677                                         prev_health = health;
1678
1679                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1680                                         {
1681                                                 float BLINK_FACTOR = 0.15;
1682                                                 float BLINK_BASE = 0.85;
1683                                                 float BLINK_FREQ = 9;
1684                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1685                                         }
1686                                 }
1687                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1688                         }
1689                         if(autocvar_hud_panel_healtharmor_text)
1690                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1691                 }
1692
1693                 if(armor)
1694                 {
1695                         if(autocvar_hud_panel_healtharmor_progressbar)
1696                         {
1697                                 float p_armor;
1698                                 p_armor = armor;
1699                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1700                                 {
1701                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1702                                         {
1703                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1704                                                 {
1705                                                         if (time - old_p_armortime < 1)
1706                                                                 old_p_armor = prev_p_armor;
1707                                                         else
1708                                                                 old_p_armor = prev_armor;
1709                                                         old_p_armortime = time;
1710                                                 }
1711                                                 if (time - old_p_armortime < 1)
1712                                                 {
1713                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1714                                                         prev_p_armor = p_armor;
1715                                                 }
1716                                         }
1717                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1718                                         {
1719                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1720                                                 {
1721                                                         if (time - armor_damagetime >= 1)
1722                                                                 armor_beforedamage = prev_armor;
1723                                                         armor_damagetime = time;
1724                                                 }
1725                                                 if (time - armor_damagetime < 1)
1726                                                 {
1727                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1728                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1729                                                 }
1730                                         }
1731                                         prev_armor = armor;
1732                                 }
1733                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1734                         }
1735                         if(autocvar_hud_panel_healtharmor_text)
1736                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1737                 }
1738
1739                 if(fuel)
1740                 {
1741                         if (is_vertical)
1742                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1743                         else
1744                                 mySize.y *= 0.2;
1745                         if (panel_ar >= 4)
1746                                 mySize.x *= 2; //restore full panel size
1747                         else if (panel_ar < 1/4)
1748                                 mySize.y *= 2; //restore full panel size
1749                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1750                 }
1751         }
1752
1753         draw_endBoldFont();
1754 }
1755
1756 // Notification area (#4)
1757 //
1758
1759 void HUD_Notify_Push(string icon, string attacker, string victim)
1760 {
1761         if (icon == "")
1762                 return;
1763
1764         ++notify_count;
1765         --notify_index;
1766
1767         if (notify_index == -1)
1768                 notify_index = NOTIFY_MAX_ENTRIES-1;
1769
1770         // Free old strings
1771         if (notify_attackers[notify_index])
1772                 strunzone(notify_attackers[notify_index]);
1773
1774         if (notify_victims[notify_index])
1775                 strunzone(notify_victims[notify_index]);
1776
1777         if (notify_icons[notify_index])
1778                 strunzone(notify_icons[notify_index]);
1779
1780         // Allocate new strings
1781         if (victim != "")
1782         {
1783                 notify_attackers[notify_index] = strzone(attacker);
1784                 notify_victims[notify_index] = strzone(victim);
1785         }
1786         else
1787         {
1788                 // In case of a notification without a victim, the attacker
1789                 // is displayed on the victim's side. Instead of special
1790                 // treatment later on, we can simply switch them here.
1791                 notify_attackers[notify_index] = string_null;
1792                 notify_victims[notify_index] = strzone(attacker);
1793         }
1794
1795         notify_icons[notify_index] = strzone(icon);
1796         notify_times[notify_index] = time;
1797 }
1798
1799 void HUD_Notify(void)
1800 {
1801         if (!autocvar__hud_configure)
1802                 if (!autocvar_hud_panel_notify)
1803                         return;
1804
1805         HUD_Panel_UpdateCvars();
1806         HUD_Panel_DrawBg(1);
1807
1808         if (!autocvar__hud_configure)
1809                 if (notify_count == 0)
1810                         return;
1811
1812         vector pos, size;
1813         pos  = panel_pos;
1814         size = panel_size;
1815
1816         if (panel_bg_padding)
1817         {
1818                 pos  += '1 1 0' * panel_bg_padding;
1819                 size -= '2 2 0' * panel_bg_padding;
1820         }
1821
1822         float fade_start = max(0, autocvar_hud_panel_notify_time);
1823         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1824         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1825
1826         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1827         float entry_height = size.y / entry_count;
1828
1829         float panel_width_half = size.x * 0.5;
1830         float icon_width_half = entry_height * icon_aspect / 2;
1831         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1832
1833         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1834         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1835         vector icon_left = eX * (panel_width_half - icon_width_half);
1836         vector attacker_right = eX * name_maxwidth;
1837         vector victim_left = eX * (size.x - name_maxwidth);
1838
1839         vector attacker_pos, victim_pos, icon_pos;
1840         string attacker, victim, icon;
1841         int i, j, count, step, limit;
1842         float alpha;
1843
1844         if (autocvar_hud_panel_notify_flip)
1845         {
1846                 // Order items from the top down
1847                 i = 0;
1848                 step = +1;
1849                 limit = entry_count;
1850         }
1851         else
1852         {
1853                 // Order items from the bottom up
1854                 i = entry_count - 1;
1855                 step = -1;
1856                 limit = -1;
1857         }
1858
1859         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1860         {
1861                 if(autocvar__hud_configure)
1862                 {
1863                         attacker = sprintf(_("Player %d"), count + 1);
1864                         victim = sprintf(_("Player %d"), count + 2);
1865                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1866                         alpha = bound(0, 1.2 - count / entry_count, 1);
1867                 }
1868                 else
1869                 {
1870                         if (j == NOTIFY_MAX_ENTRIES)
1871                                 j = 0;
1872
1873                         if (notify_times[j] + fade_start > time)
1874                                 alpha = 1;
1875                         else if (fade_time != 0)
1876                         {
1877                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1878                                 if (alpha == 0)
1879                                         break;
1880                         }
1881                         else
1882                                 break;
1883
1884                         attacker = notify_attackers[j];
1885                         victim = notify_victims[j];
1886                         icon = notify_icons[j];
1887                 }
1888
1889                 if (icon != "" && victim != "")
1890                 {
1891                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1892
1893                         icon_pos = pos + icon_left + eY * i * entry_height;
1894                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1895
1896                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1897                         victim_pos = pos + victim_left + name_top;
1898                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1899
1900                         if (attacker != "")
1901                         {
1902                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1903                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1904                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1905                         }
1906                 }
1907         }
1908
1909         notify_count = count;
1910 }
1911
1912 // Timer (#5)
1913 //
1914 // TODO: macro
1915 string seconds_tostring(float sec)
1916 {
1917         float minutes;
1918         minutes = floor(sec / 60);
1919
1920         sec -= minutes * 60;
1921         return sprintf("%d:%02d", minutes, sec);
1922 }
1923
1924 void HUD_Timer(void)
1925 {
1926         if(!autocvar__hud_configure)
1927         {
1928                 if(!autocvar_hud_panel_timer) return;
1929         }
1930
1931         HUD_Panel_UpdateCvars();
1932
1933         draw_beginBoldFont();
1934
1935         vector pos, mySize;
1936         pos = panel_pos;
1937         mySize = panel_size;
1938
1939         HUD_Panel_DrawBg(1);
1940         if(panel_bg_padding)
1941         {
1942                 pos += '1 1 0' * panel_bg_padding;
1943                 mySize -= '2 2 0' * panel_bg_padding;
1944         }
1945
1946         string timer;
1947         float timelimit, elapsedTime, timeleft, minutesLeft;
1948
1949         timelimit = getstatf(STAT_TIMELIMIT);
1950
1951         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1952         timeleft = ceil(timeleft);
1953
1954         minutesLeft = floor(timeleft / 60);
1955
1956         vector timer_color;
1957         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1958                 timer_color = '1 1 1'; //white
1959         else if(minutesLeft >= 1)
1960                 timer_color = '1 1 0'; //yellow
1961         else
1962                 timer_color = '1 0 0'; //red
1963
1964         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1965                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1966                         //while restart is still active, show 00:00
1967                         timer = seconds_tostring(0);
1968                 } else {
1969                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1970                         timer = seconds_tostring(elapsedTime);
1971                 }
1972         } else {
1973                 timer = seconds_tostring(timeleft);
1974         }
1975
1976         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1977
1978         draw_endBoldFont();
1979 }
1980
1981 // Radar (#6)
1982 //
1983 void HUD_Radar(void)
1984 {
1985         if (!autocvar__hud_configure)
1986         {
1987                 if (hud_panel_radar_maximized)
1988                 {
1989                         if (!hud_draw_maximized) return;
1990                 }
1991                 else
1992                 {
1993                         if (autocvar_hud_panel_radar == 0) return;
1994                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1995                         if(radar_panel_modified)
1996                         {
1997                                 panel.update_time = time; // forces reload of panel attributes
1998                                 radar_panel_modified = false;
1999                         }
2000                 }
2001         }
2002
2003         HUD_Panel_UpdateCvars();
2004
2005         float f = 0;
2006
2007         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2008         {
2009                 panel_size = autocvar_hud_panel_radar_maximized_size;
2010                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2011                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2012                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2013                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2014
2015                 string panel_bg;
2016                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2017                 if(precache_pic(panel_bg) == "")
2018                         panel_bg = "gfx/hud/default/border_default"; // fallback
2019                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2020                         radar_panel_modified = true;
2021                 if(panel.current_panel_bg)
2022                         strunzone(panel.current_panel_bg);
2023                 panel.current_panel_bg = strzone(panel_bg);
2024
2025                 switch(hud_panel_radar_maximized_zoommode)
2026                 {
2027                         default:
2028                         case 0:
2029                                 f = current_zoomfraction;
2030                                 break;
2031                         case 1:
2032                                 f = 1 - current_zoomfraction;
2033                                 break;
2034                         case 2:
2035                                 f = 0;
2036                                 break;
2037                         case 3:
2038                                 f = 1;
2039                                 break;
2040                 }
2041
2042                 switch(hud_panel_radar_maximized_rotation)
2043                 {
2044                         case 0:
2045                                 teamradar_angle = view_angles.y - 90;
2046                                 break;
2047                         default:
2048                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2049                                 break;
2050                 }
2051         }
2052         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2053         {
2054                 switch(hud_panel_radar_zoommode)
2055                 {
2056                         default:
2057                         case 0:
2058                                 f = current_zoomfraction;
2059                                 break;
2060                         case 1:
2061                                 f = 1 - current_zoomfraction;
2062                                 break;
2063                         case 2:
2064                                 f = 0;
2065                                 break;
2066                         case 3:
2067                                 f = 1;
2068                                 break;
2069                 }
2070
2071                 switch(hud_panel_radar_rotation)
2072                 {
2073                         case 0:
2074                                 teamradar_angle = view_angles.y - 90;
2075                                 break;
2076                         default:
2077                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2078                                 break;
2079                 }
2080         }
2081
2082         vector pos, mySize;
2083         pos = panel_pos;
2084         mySize = panel_size;
2085
2086         HUD_Panel_DrawBg(1);
2087         if(panel_bg_padding)
2088         {
2089                 pos += '1 1 0' * panel_bg_padding;
2090                 mySize -= '2 2 0' * panel_bg_padding;
2091         }
2092
2093         int color2;
2094         entity tm;
2095         float scale2d, normalsize, bigsize;
2096
2097         teamradar_origin2d = pos + 0.5 * mySize;
2098         teamradar_size2d = mySize;
2099
2100         if(minimapname == "")
2101                 return;
2102
2103         teamradar_loadcvars();
2104
2105         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2106         teamradar_size2d = mySize;
2107
2108         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2109
2110         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2111         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2112         {
2113                 // max-min distance must fit the radar in any rotation
2114                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2115         }
2116         else
2117         {
2118                 vector c0, c1, c2, c3, span;
2119                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2120                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2121                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2122                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2123                 span = '0 0 0';
2124                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2125                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2126
2127                 // max-min distance must fit the radar in x=x, y=y
2128                 bigsize = min(
2129                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2130                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2131                 );
2132         }
2133
2134         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2135         if(bigsize > normalsize)
2136                 normalsize = bigsize;
2137
2138         teamradar_size =
2139                   f * bigsize
2140                 + (1 - f) * normalsize;
2141         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2142                   f * mi_center
2143                 + (1 - f) * view_origin);
2144
2145         drawsetcliparea(
2146                 pos.x,
2147                 pos.y,
2148                 mySize.x,
2149                 mySize.y
2150         );
2151
2152         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2153
2154         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2155                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2156         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2157                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2158         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2159         {
2160                 color2 = GetPlayerColor(tm.sv_entnum);
2161                 //if(color == NUM_SPECTATOR || color == color2)
2162                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2163         }
2164         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2165
2166         drawresetcliparea();
2167 }
2168
2169 // Score (#7)
2170 //
2171 void HUD_UpdatePlayerTeams();
2172 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2173 {
2174         float score;
2175         entity tm = world, pl;
2176         int SCOREPANEL_MAX_ENTRIES = 6;
2177         float SCOREPANEL_ASPECTRATIO = 2;
2178         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2179         vector fontsize = '1 1 0' * (mySize.y/entries);
2180
2181         vector rgb, score_color;
2182         rgb = '1 1 1';
2183         score_color = '1 1 1';
2184
2185         float name_size = mySize.x*0.75;
2186         float spacing_size = mySize.x*0.04;
2187         const float highlight_alpha = 0.2;
2188         int i = 0, first_pl = 0;
2189         bool me_printed = false;
2190         string s;
2191         if (autocvar__hud_configure)
2192         {
2193                 float players_per_team = 0;
2194                 if (team_count)
2195                 {
2196                         // show team scores in the first line
2197                         float score_size = mySize.x / team_count;
2198                         players_per_team = max(2, ceil((entries - 1) / team_count));
2199                         for(i=0; i<team_count; ++i) {
2200                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2201                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2202                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2203                         }
2204                         first_pl = 1;
2205                         pos.y += fontsize.y;
2206                 }
2207                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2208                 for (i=first_pl; i<entries; ++i)
2209                 {
2210                         //simulate my score is lower than all displayed players,
2211                         //so that I don't appear at all showing pure rankings.
2212                         //This is to better show the difference between the 2 ranking views
2213                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2214                         {
2215                                 rgb = '1 1 0';
2216                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2217                                 s = GetPlayerName(player_localnum);
2218                                 score = 7;
2219                         }
2220                         else
2221                         {
2222                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2223                                 score -= 3;
2224                         }
2225
2226                         if (team_count)
2227                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2228                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2229                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2230                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2231                         pos.y += fontsize.y;
2232                 }
2233                 return;
2234         }
2235
2236         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2237                 HUD_UpdatePlayerTeams();
2238         if (team_count)
2239         {
2240                 // show team scores in the first line
2241                 float score_size = mySize.x / team_count;
2242                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2243                         if(tm.team == NUM_SPECTATOR)
2244                                 continue;
2245                         if (tm.team == myteam)
2246                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2247                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2248                         ++i;
2249                 }
2250                 first_pl = 1;
2251                 pos.y += fontsize.y;
2252                 tm = teams.sort_next;
2253         }
2254         i = first_pl;
2255
2256         do
2257         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2258         {
2259                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2260                         continue;
2261
2262                 if (i == entries-1 && !me_printed && pl != me)
2263                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2264                 {
2265                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2266                                 if (pl.team != NUM_SPECTATOR)
2267                                         break;
2268
2269                         if (pl)
2270                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2271                         else
2272                                 rgb = '1 0 0'; //last: red
2273                         pl = me;
2274                 }
2275
2276                 if (pl == me)
2277                 {
2278                         if (i == first_pl)
2279                                 rgb = '0 1 0'; //first: green
2280                         me_printed = true;
2281                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2282                 }
2283                 if (team_count)
2284                         score_color = Team_ColorRGB(pl.team) * 0.8;
2285                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2286                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2287                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2288                 pos.y += fontsize.y;
2289                 ++i;
2290         }
2291         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2292 }
2293
2294 void HUD_Score(void)
2295 {
2296         if(!autocvar__hud_configure)
2297         {
2298                 if(!autocvar_hud_panel_score) return;
2299                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2300         }
2301
2302         HUD_Panel_UpdateCvars();
2303         vector pos, mySize;
2304         pos = panel_pos;
2305         mySize = panel_size;
2306
2307         HUD_Panel_DrawBg(1);
2308         if(panel_bg_padding)
2309         {
2310                 pos += '1 1 0' * panel_bg_padding;
2311                 mySize -= '2 2 0' * panel_bg_padding;
2312         }
2313
2314         float score, distribution = 0;
2315         string sign;
2316         vector distribution_color;
2317         entity tm, pl, me;
2318
2319         me = playerslots[player_localentnum - 1];
2320
2321         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2322                 string timer, distrtimer;
2323
2324                 pl = players.sort_next;
2325                 if(pl == me)
2326                         pl = pl.sort_next;
2327                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2328                         if(pl.scores[ps_primary] == 0)
2329                                 pl = world;
2330
2331                 score = me.(scores[ps_primary]);
2332                 timer = TIME_ENCODED_TOSTRING(score);
2333
2334                 draw_beginBoldFont();
2335                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2336                         // distribution display
2337                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2338
2339                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2340
2341                         if (distribution <= 0) {
2342                                 distribution_color = '0 1 0';
2343                                 sign = "-";
2344                         }
2345                         else {
2346                                 distribution_color = '1 0 0';
2347                                 sign = "+";
2348                         }
2349                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2350                 }
2351                 // race record display
2352                 if (distribution <= 0)
2353                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2354                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2355                 draw_endBoldFont();
2356         } else if (!teamplay) { // non-teamgames
2357                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2358                 {
2359                         HUD_Score_Rankings(pos, mySize, me);
2360                         return;
2361                 }
2362                 // me vector := [team/connected frags id]
2363                 pl = players.sort_next;
2364                 if(pl == me)
2365                         pl = pl.sort_next;
2366
2367                 if(autocvar__hud_configure)
2368                         distribution = 42;
2369                 else if(pl)
2370                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2371                 else
2372                         distribution = 0;
2373
2374                 score = me.(scores[ps_primary]);
2375                 if(autocvar__hud_configure)
2376                         score = 123;
2377
2378                 if(distribution >= 5)
2379                         distribution_color = eY;
2380                 else if(distribution >= 0)
2381                         distribution_color = '1 1 1';
2382                 else if(distribution >= -5)
2383                         distribution_color = '1 1 0';
2384                 else
2385                         distribution_color = eX;
2386
2387                 string distribution_str;
2388                 distribution_str = ftos(distribution);
2389                 draw_beginBoldFont();
2390                 if (distribution >= 0)
2391                 {
2392                         if (distribution > 0)
2393                                 distribution_str = strcat("+", distribution_str);
2394                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2395                 }
2396                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2397                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2398                 draw_endBoldFont();
2399         } else { // teamgames
2400                 float row, column, rows = 0, columns = 0;
2401                 vector offset = '0 0 0';
2402                 vector score_pos, score_size; //for scores other than myteam
2403                 if(autocvar_hud_panel_score_rankings)
2404                 {
2405                         HUD_Score_Rankings(pos, mySize, me);
2406                         return;
2407                 }
2408                 if(spectatee_status == -1)
2409                 {
2410                         rows = HUD_GetRowCount(team_count, mySize, 3);
2411                         columns = ceil(team_count/rows);
2412                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2413
2414                         float newSize;
2415                         if(score_size.x/score_size.y > 3)
2416                         {
2417                                 newSize = 3 * score_size.y;
2418                                 offset.x = score_size.x - newSize;
2419                                 pos.x += offset.x/2;
2420                                 score_size.x = newSize;
2421                         }
2422                         else
2423                         {
2424                                 newSize = 1/3 * score_size.x;
2425                                 offset.y = score_size.y - newSize;
2426                                 pos.y += offset.y/2;
2427                                 score_size.y = newSize;
2428                         }
2429                 }
2430                 else
2431                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2432
2433                 float max_fragcount;
2434                 max_fragcount = -99;
2435                 draw_beginBoldFont();
2436                 row = column = 0;
2437                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2438                         if(tm.team == NUM_SPECTATOR)
2439                                 continue;
2440                         score = tm.(teamscores[ts_primary]);
2441                         if(autocvar__hud_configure)
2442                                 score = 123;
2443
2444                         if (score > max_fragcount)
2445                                 max_fragcount = score;
2446
2447                         if (spectatee_status == -1)
2448                         {
2449                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2450                                 if (max_fragcount == score)
2451                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2452                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2453                                 ++row;
2454                                 if(row >= rows)
2455                                 {
2456                                         row = 0;
2457                                         ++column;
2458                                 }
2459                         }
2460                         else if(tm.team == myteam) {
2461                                 if (max_fragcount == score)
2462                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2463                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2464                         } else {
2465                                 if (max_fragcount == score)
2466                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2467                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2468                                 ++rows;
2469                         }
2470                 }
2471                 draw_endBoldFont();
2472         }
2473 }
2474
2475 // Race timer (#8)
2476 //
2477 void HUD_RaceTimer (void)
2478 {
2479         if(!autocvar__hud_configure)
2480         {
2481                 if(!autocvar_hud_panel_racetimer) return;
2482                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2483                 if(spectatee_status == -1) return;
2484         }
2485
2486         HUD_Panel_UpdateCvars();
2487
2488         vector pos, mySize;
2489         pos = panel_pos;
2490         mySize = panel_size;
2491
2492         HUD_Panel_DrawBg(1);
2493         if(panel_bg_padding)
2494         {
2495                 pos += '1 1 0' * panel_bg_padding;
2496                 mySize -= '2 2 0' * panel_bg_padding;
2497         }
2498
2499         // always force 4:1 aspect
2500         vector newSize = '0 0 0';
2501         if(mySize.x/mySize.y > 4)
2502         {
2503                 newSize.x = 4 * mySize.y;
2504                 newSize.y = mySize.y;
2505
2506                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2507         }
2508         else
2509         {
2510                 newSize.y = 1/4 * mySize.x;
2511                 newSize.x = mySize.x;
2512
2513                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2514         }
2515         mySize = newSize;
2516
2517         float a, t;
2518         string s, forcetime;
2519
2520         if(autocvar__hud_configure)
2521         {
2522                 s = "0:13:37";
2523                 draw_beginBoldFont();
2524                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2525                 draw_endBoldFont();
2526                 s = _("^1Intermediate 1 (+15.42)");
2527                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2528                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2529                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2530         }
2531         else if(race_checkpointtime)
2532         {
2533                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2534                 s = "";
2535                 forcetime = "";
2536                 if(a > 0) // just hit a checkpoint?
2537                 {
2538                         if(race_checkpoint != 254)
2539                         {
2540                                 if(race_time && race_previousbesttime)
2541                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2542                                 else
2543                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2544                                 if(race_time)
2545                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2546                         }
2547                 }
2548                 else
2549                 {
2550                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2551                         {
2552                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2553                                 if(a > 0) // next one?
2554                                 {
2555                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2556                                 }
2557                         }
2558                 }
2559
2560                 if(s != "" && a > 0)
2561                 {
2562                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2563                 }
2564
2565                 if(race_penaltytime)
2566                 {
2567                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2568                         if(a > 0)
2569                         {
2570                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2571                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2572                         }
2573                 }
2574
2575                 draw_beginBoldFont();
2576
2577                 if(forcetime != "")
2578                 {
2579                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2580                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2581                 }
2582                 else
2583                         a = 1;
2584
2585                 if(race_laptime && race_checkpoint != 255)
2586                 {
2587                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2588                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2589                 }
2590
2591                 draw_endBoldFont();
2592         }
2593         else
2594         {
2595                 if(race_mycheckpointtime)
2596                 {
2597                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2598                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2599                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2600                 }
2601                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2602                 {
2603                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2604                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2605                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2606                 }
2607
2608                 if(race_penaltytime && !race_penaltyaccumulator)
2609                 {
2610                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2611                         a = bound(0, (1 + t - time), 1);
2612                         if(a > 0)
2613                         {
2614                                 if(time < t)
2615                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2616                                 else
2617                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2618                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2619                         }
2620                 }
2621         }
2622 }
2623
2624 // Vote window (#9)
2625 //
2626
2627 void HUD_Vote(void)
2628 {
2629         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2630         {
2631                 vote_active = 1;
2632                 if (autocvar__hud_configure)
2633                 {
2634                         vote_yescount = 0;
2635                         vote_nocount = 0;
2636                         print(_("^1You must answer before entering hud configure mode\n"));
2637                         cvar_set("_hud_configure", "0");
2638                 }
2639                 if(vote_called_vote)
2640                         strunzone(vote_called_vote);
2641                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2642                 uid2name_dialog = 1;
2643         }
2644
2645         if(!autocvar__hud_configure)
2646         {
2647                 if(!autocvar_hud_panel_vote) return;
2648
2649                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2650                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2651
2652                 if(panel_bg_alpha_str == "") {
2653                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2654                 }
2655                 panel_bg_alpha = stof(panel_bg_alpha_str);
2656         }
2657         else
2658         {
2659                 vote_yescount = 3;
2660                 vote_nocount = 2;
2661                 vote_needed = 4;
2662         }
2663
2664         string s;
2665         float a;
2666         if(vote_active != vote_prev) {
2667                 vote_change = time;
2668                 vote_prev = vote_active;
2669         }
2670
2671         if(vote_active || autocvar__hud_configure)
2672                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2673         else
2674                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2675
2676         if(!vote_alpha)
2677                 return;
2678
2679         HUD_Panel_UpdateCvars();
2680
2681         if(uid2name_dialog)
2682         {
2683                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2684                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2685         }
2686
2687     // these must be below above block
2688         vector pos, mySize;
2689         pos = panel_pos;
2690         mySize = panel_size;
2691
2692         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2693         HUD_Panel_DrawBg(a);
2694         a = panel_fg_alpha * a;
2695
2696         if(panel_bg_padding)
2697         {
2698                 pos += '1 1 0' * panel_bg_padding;
2699                 mySize -= '2 2 0' * panel_bg_padding;
2700         }
2701
2702         // always force 3:1 aspect
2703         vector newSize = '0 0 0';
2704         if(mySize.x/mySize.y > 3)
2705         {
2706                 newSize.x = 3 * mySize.y;
2707                 newSize.y = mySize.y;
2708
2709                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2710         }
2711         else
2712         {
2713                 newSize.y = 1/3 * mySize.x;
2714                 newSize.x = mySize.x;
2715
2716                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2717         }
2718         mySize = newSize;
2719
2720         s = _("A vote has been called for:");
2721         if(uid2name_dialog)
2722                 s = _("Allow servers to store and display your name?");
2723         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2724         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2725         if(autocvar__hud_configure)
2726                 s = _("^1Configure the HUD");
2727         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2728
2729         // print the yes/no counts
2730     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2731         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2732     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2733         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2734
2735         // draw the progress bar backgrounds
2736         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2737
2738         // draw the highlights
2739         if(vote_highlighted == 1) {
2740                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2741                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2742         }
2743         else if(vote_highlighted == -1) {
2744                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2745                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2746         }
2747
2748         // draw the progress bars
2749         if(vote_yescount && vote_needed)
2750         {
2751                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2752                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2753         }
2754
2755         if(vote_nocount && vote_needed)
2756         {
2757                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2758                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2759         }
2760
2761         drawresetcliparea();
2762 }
2763
2764 // Mod icons panel (#10)
2765 //
2766
2767 bool mod_active; // is there any active mod icon?
2768
2769 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2770 {
2771         int stat = -1;
2772         string pic = "";
2773         vector color = '0 0 0';
2774         switch(i)
2775         {
2776                 case 0:
2777                         stat = getstati(STAT_REDALIVE);
2778                         pic = "player_red.tga";
2779                         color = '1 0 0';
2780                         break;
2781                 case 1:
2782                         stat = getstati(STAT_BLUEALIVE);
2783                         pic = "player_blue.tga";
2784                         color = '0 0 1';
2785                         break;
2786                 case 2:
2787                         stat = getstati(STAT_YELLOWALIVE);
2788                         pic = "player_yellow.tga";
2789                         color = '1 1 0';
2790                         break;
2791                 default:
2792                 case 3:
2793                         stat = getstati(STAT_PINKALIVE);
2794                         pic = "player_pink.tga";
2795                         color = '1 0 1';
2796                         break;
2797         }
2798
2799         if(mySize.x/mySize.y > aspect_ratio)
2800         {
2801                 i = aspect_ratio * mySize.y;
2802                 myPos.x = myPos.x + (mySize.x - i) / 2;
2803                 mySize.x = i;
2804         }
2805         else
2806         {
2807                 i = 1/aspect_ratio * mySize.x;
2808                 myPos.y = myPos.y + (mySize.y - i) / 2;
2809                 mySize.y = i;
2810         }
2811
2812         if(layout)
2813         {
2814                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2815                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2816         }
2817         else
2818                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2819 }
2820
2821 // Clan Arena and Freeze Tag HUD modicons
2822 void HUD_Mod_CA(vector myPos, vector mySize)
2823 {
2824         mod_active = 1; // required in each mod function that always shows something
2825
2826         int layout;
2827         if(gametype == MAPINFO_TYPE_CA)
2828                 layout = autocvar_hud_panel_modicons_ca_layout;
2829         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2830                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2831         int rows, columns;
2832         float aspect_ratio;
2833         aspect_ratio = (layout) ? 2 : 1;
2834         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2835         columns = ceil(team_count/rows);
2836
2837         int i;
2838         float row = 0, column = 0;
2839         vector pos, itemSize;
2840         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2841         for(i=0; i<team_count; ++i)
2842         {
2843                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2844
2845                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2846
2847                 ++row;
2848                 if(row >= rows)
2849                 {
2850                         row = 0;
2851                         ++column;
2852                 }
2853         }
2854 }
2855
2856 // CTF HUD modicon section
2857 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2858 int redflag_prevstatus, blueflag_prevstatus; // last remembered status
2859 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2860
2861 void HUD_Mod_CTF_Reset(void)
2862 {
2863         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2864 }
2865
2866 void HUD_Mod_CTF(vector pos, vector mySize)
2867 {
2868         vector redflag_pos, blueflag_pos;
2869         vector flag_size;
2870         float f; // every function should have that
2871
2872         int redflag, blueflag; // current status
2873         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2874         int stat_items;
2875
2876         stat_items = getstati(STAT_ITEMS, 0, 24);
2877         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2878         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2879
2880         if(redflag || blueflag)
2881                 mod_active = 1;
2882         else
2883                 mod_active = 0;
2884
2885         if(autocvar__hud_configure)
2886         {
2887                 redflag = 1;
2888                 blueflag = 2;
2889         }
2890
2891         // when status CHANGES, set old status into prevstatus and current status into status
2892         if (redflag != redflag_prevframe)
2893         {
2894                 redflag_statuschange_time = time;
2895                 redflag_prevstatus = redflag_prevframe;
2896                 redflag_prevframe = redflag;
2897         }
2898
2899         if (blueflag != blueflag_prevframe)
2900         {
2901                 blueflag_statuschange_time = time;
2902                 blueflag_prevstatus = blueflag_prevframe;
2903                 blueflag_prevframe = blueflag;
2904         }
2905
2906         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2907         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2908
2909         float BLINK_FACTOR = 0.15;
2910         float BLINK_BASE = 0.85;
2911         // note:
2912         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2913         // thus
2914         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2915         // ensure RMS == 1
2916         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2917
2918         string red_icon, red_icon_prevstatus;
2919         float red_alpha, red_alpha_prevstatus;
2920         red_alpha = red_alpha_prevstatus = 1;
2921         switch(redflag) {
2922                 case 1: red_icon = "flag_red_taken"; break;
2923                 case 2: red_icon = "flag_red_lost"; break;
2924                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2925                 default:
2926                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2927                                 red_icon = "flag_red_shielded";
2928                         else
2929                                 red_icon = string_null;
2930                         break;
2931         }
2932         switch(redflag_prevstatus) {
2933                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2934                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2935                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2936                 default:
2937                         if(redflag == 3)
2938                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2939                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2940                                 red_icon_prevstatus = "flag_red_shielded";
2941                         else
2942                                 red_icon_prevstatus = string_null;
2943                         break;
2944         }
2945
2946         string blue_icon, blue_icon_prevstatus;
2947         float blue_alpha, blue_alpha_prevstatus;
2948         blue_alpha = blue_alpha_prevstatus = 1;
2949         switch(blueflag) {
2950                 case 1: blue_icon = "flag_blue_taken"; break;
2951                 case 2: blue_icon = "flag_blue_lost"; break;
2952                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2953                 default:
2954                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2955                                 blue_icon = "flag_blue_shielded";
2956                         else
2957                                 blue_icon = string_null;
2958                         break;
2959         }
2960         switch(blueflag_prevstatus) {
2961                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2962                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2963                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2964                 default:
2965                         if(blueflag == 3)
2966                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2967                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2968                                 blue_icon_prevstatus = "flag_blue_shielded";
2969                         else
2970                                 blue_icon_prevstatus = string_null;
2971                         break;
2972         }
2973
2974         if(mySize.x > mySize.y) {
2975                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2976                         redflag_pos = pos;
2977                         blueflag_pos = pos + eX * 0.5 * mySize.x;
2978                 } else {
2979                         blueflag_pos = pos;
2980                         redflag_pos = pos + eX * 0.5 * mySize.x;
2981                 }
2982                 flag_size = eX * 0.5 * mySize.x + eY * mySize.y;
2983         } else {
2984                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2985                         redflag_pos = pos;
2986                         blueflag_pos = pos + eY * 0.5 * mySize.y;
2987                 } else {
2988                         blueflag_pos = pos;
2989                         redflag_pos = pos + eY * 0.5 * mySize.y;
2990                 }
2991                 flag_size = eY * 0.5 * mySize.y + eX * mySize.x;
2992         }
2993
2994         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2995         if(red_icon_prevstatus && f < 1)
2996                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2997         if(red_icon)
2998                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2999
3000         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
3001         if(blue_icon_prevstatus && f < 1)
3002                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
3003         if(blue_icon)
3004                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
3005 }
3006
3007 // Keyhunt HUD modicon section
3008 vector KH_SLOTS[4];
3009
3010 void HUD_Mod_KH(vector pos, vector mySize)
3011 {
3012         mod_active = 1; // keyhunt should never hide the mod icons panel
3013
3014         // Read current state
3015
3016         int state = getstati(STAT_KH_KEYS);
3017         int i, key_state;
3018         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3019         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3020
3021         for(i = 0; i < 4; ++i)
3022         {
3023                 key_state = (bitshift(state, i * -5) & 31) - 1;
3024
3025                 if(key_state == -1)
3026                         continue;
3027
3028                 if(key_state == 30)
3029                 {
3030                         ++carrying_keys;
3031                         key_state = myteam;
3032                 }
3033
3034                 switch(key_state)
3035                 {
3036                         case NUM_TEAM_1: ++team1_keys; break;
3037                         case NUM_TEAM_2: ++team2_keys; break;
3038                         case NUM_TEAM_3: ++team3_keys; break;
3039                         case NUM_TEAM_4: ++team4_keys; break;
3040                         case 29: ++dropped_keys; break;
3041                 }
3042
3043                 ++all_keys;
3044         }
3045
3046         // Calculate slot measurements
3047
3048         vector slot_size;
3049
3050         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3051         {
3052                 // Quadratic arrangement
3053                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3054                 KH_SLOTS[0] = pos;
3055                 KH_SLOTS[1] = pos + eX * slot_size.x;
3056                 KH_SLOTS[2] = pos + eY * slot_size.y;
3057                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3058         }
3059         else
3060         {
3061                 if(mySize.x > mySize.y)
3062                 {
3063                         // Horizontal arrangement
3064                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3065                         for(i = 0; i < all_keys; ++i)
3066                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3067                 }
3068                 else
3069                 {
3070                         // Vertical arrangement
3071                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3072                         for(i = 0; i < all_keys; ++i)
3073                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3074                 }
3075         }
3076
3077         // Make icons blink in case of RUN HERE
3078
3079         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3080         float alpha;
3081         alpha = 1;
3082
3083         if(carrying_keys)
3084                 switch(myteam)
3085                 {
3086                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3087                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3088                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3089                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3090                 }
3091
3092         // Draw icons
3093
3094         i = 0;
3095
3096         while(team1_keys--)
3097                 if(myteam == NUM_TEAM_1 && carrying_keys)
3098                 {
3099                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3100                         --carrying_keys;
3101                 }
3102                 else
3103                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3104
3105         while(team2_keys--)
3106                 if(myteam == NUM_TEAM_2 && carrying_keys)
3107                 {
3108                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3109                         --carrying_keys;
3110                 }
3111                 else
3112                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3113
3114         while(team3_keys--)
3115                 if(myteam == NUM_TEAM_3 && carrying_keys)
3116                 {
3117                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3118                         --carrying_keys;
3119                 }
3120                 else
3121                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3122
3123         while(team4_keys--)
3124                 if(myteam == NUM_TEAM_4 && carrying_keys)
3125                 {
3126                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3127                         --carrying_keys;
3128                 }
3129                 else
3130                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3131
3132         while(dropped_keys--)
3133                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3134 }
3135
3136 // Keepaway HUD mod icon
3137 int kaball_prevstatus; // last remembered status
3138 float kaball_statuschange_time; // time when the status changed
3139
3140 // we don't need to reset for keepaway since it immediately
3141 // autocorrects prevstatus as to if the player has the ball or not
3142
3143 void HUD_Mod_Keepaway(vector pos, vector mySize)
3144 {
3145         mod_active = 1; // keepaway should always show the mod HUD
3146
3147         float BLINK_FACTOR = 0.15;
3148         float BLINK_BASE = 0.85;
3149         float BLINK_FREQ = 5;
3150         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3151
3152         int stat_items = getstati(STAT_ITEMS, 0, 24);
3153         int kaball = (stat_items/IT_KEY1) & 1;
3154
3155         if(kaball != kaball_prevstatus)
3156         {
3157                 kaball_statuschange_time = time;
3158                 kaball_prevstatus = kaball;
3159         }
3160
3161         vector kaball_pos, kaball_size;
3162
3163         if(mySize.x > mySize.y) {
3164                 kaball_pos = pos + eX * 0.25 * mySize.x;
3165                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3166         } else {
3167                 kaball_pos = pos + eY * 0.25 * mySize.y;
3168                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3169         }
3170
3171         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3172         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3173
3174         if(kaball_prevstatus && f < 1)
3175                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3176
3177         if(kaball)
3178                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3179 }
3180
3181
3182 // Nexball HUD mod icon
3183 void HUD_Mod_NexBall(vector pos, vector mySize)
3184 {
3185         float nb_pb_starttime, dt, p;
3186         int stat_items;
3187
3188         stat_items = getstati(STAT_ITEMS, 0, 24);
3189         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3190
3191         if (stat_items & IT_KEY1)
3192                 mod_active = 1;
3193         else
3194                 mod_active = 0;
3195
3196         //Manage the progress bar if any
3197         if (nb_pb_starttime > 0)
3198         {
3199                 dt = (time - nb_pb_starttime) % nb_pb_period;
3200                 // one period of positive triangle
3201                 p = 2 * dt / nb_pb_period;
3202                 if (p > 1)
3203                         p = 2 - p;
3204
3205                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3206         }
3207
3208         if (stat_items & IT_KEY1)
3209                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3210 }
3211
3212 // Race/CTS HUD mod icons
3213 float crecordtime_prev; // last remembered crecordtime
3214 float crecordtime_change_time; // time when crecordtime last changed
3215 float srecordtime_prev; // last remembered srecordtime
3216 float srecordtime_change_time; // time when srecordtime last changed
3217
3218 float race_status_time;
3219 int race_status_prev;
3220 string race_status_name_prev;
3221 void HUD_Mod_Race(vector pos, vector mySize)
3222 {
3223         mod_active = 1; // race should never hide the mod icons panel
3224         entity me;
3225         me = playerslots[player_localnum];
3226         float t, score;
3227         float f; // yet another function has this
3228         score = me.(scores[ps_primary]);
3229
3230         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3231                 return; // no records in the actual race
3232
3233         // clientside personal record
3234         string rr;
3235         if(gametype == MAPINFO_TYPE_CTS)
3236                 rr = CTS_RECORD;
3237         else
3238                 rr = RACE_RECORD;
3239         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3240
3241         if(score && (score < t || !t)) {
3242                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3243                 if(autocvar_cl_autodemo_delete_keeprecords)
3244                 {
3245                         f = autocvar_cl_autodemo_delete;
3246                         f &= ~1;
3247                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3248                 }
3249         }
3250
3251         if(t != crecordtime_prev) {
3252                 crecordtime_prev = t;
3253                 crecordtime_change_time = time;
3254         }
3255
3256         vector textPos, medalPos;
3257         float squareSize;
3258         if(mySize.x > mySize.y) {
3259                 // text on left side
3260                 squareSize = min(mySize.y, mySize.x/2);
3261                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3262                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3263         } else {
3264                 // text on top
3265                 squareSize = min(mySize.x, mySize.y/2);
3266                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3267                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3268         }
3269
3270         f = time - crecordtime_change_time;
3271
3272         if (f > 1) {
3273                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3274                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3275         } else {
3276                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3277                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3278                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3279                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3280         }
3281
3282         // server record
3283         t = race_server_record;
3284         if(t != srecordtime_prev) {
3285                 srecordtime_prev = t;
3286                 srecordtime_change_time = time;
3287         }
3288         f = time - srecordtime_change_time;
3289
3290         if (f > 1) {
3291                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3292                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3293         } else {
3294                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3295                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3296                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3297                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3298         }
3299
3300         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3301                 race_status_time = time + 5;
3302                 race_status_prev = race_status;
3303                 if (race_status_name_prev)
3304                         strunzone(race_status_name_prev);
3305                 race_status_name_prev = strzone(race_status_name);
3306         }
3307
3308         // race "awards"
3309         float a;
3310         a = bound(0, race_status_time - time, 1);
3311
3312         string s;
3313         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3314
3315         float rank;
3316         if(race_status > 0)
3317                 rank = race_CheckName(race_status_name);
3318         else
3319                 rank = 0;
3320         string rankname;
3321         rankname = count_ordinal(rank);
3322
3323         vector namepos;
3324         namepos = medalPos + '0 0.8 0' * squareSize;
3325         vector rankpos;
3326         rankpos = medalPos + '0 0.15 0' * squareSize;
3327
3328         if(race_status == 0)
3329                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3330         else if(race_status == 1) {
3331                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3332                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3333                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3334         } else if(race_status == 2) {
3335                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3336                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3337                 else
3338                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3339                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3340                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3341         } else if(race_status == 3) {
3342                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3343                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3344                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3345         }
3346
3347         if (race_status_time - time <= 0) {
3348                 race_status_prev = -1;
3349                 race_status = -1;
3350                 if(race_status_name)
3351                         strunzone(race_status_name);
3352                 race_status_name = string_null;
3353                 if(race_status_name_prev)
3354                         strunzone(race_status_name_prev);
3355                 race_status_name_prev = string_null;
3356         }
3357 }
3358
3359 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3360 {
3361         float stat = -1;
3362         string pic = "";
3363         vector color = '0 0 0';
3364         switch(i)
3365         {
3366                 case 0:
3367                         stat = getstatf(STAT_DOM_PPS_RED);
3368                         pic = "dom_icon_red";
3369                         color = '1 0 0';
3370                         break;
3371                 case 1:
3372                         stat = getstatf(STAT_DOM_PPS_BLUE);
3373                         pic = "dom_icon_blue";
3374                         color = '0 0 1';
3375                         break;
3376                 case 2:
3377                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3378                         pic = "dom_icon_yellow";
3379                         color = '1 1 0';
3380                         break;
3381                 default:
3382                 case 3:
3383                         stat = getstatf(STAT_DOM_PPS_PINK);
3384                         pic = "dom_icon_pink";
3385                         color = '1 0 1';
3386                         break;
3387         }
3388         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3389
3390         if(mySize.x/mySize.y > aspect_ratio)
3391         {
3392                 i = aspect_ratio * mySize.y;
3393                 myPos.x = myPos.x + (mySize.x - i) / 2;
3394                 mySize.x = i;
3395         }
3396         else
3397         {
3398                 i = 1/aspect_ratio * mySize.x;
3399                 myPos.y = myPos.y + (mySize.y - i) / 2;
3400                 mySize.y = i;
3401         }
3402
3403         if (layout) // show text too
3404         {
3405                 //draw the text
3406                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3407                 if (layout == 2) // average pps
3408                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3409                 else // percentage of average pps
3410                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3411         }
3412
3413         //draw the icon
3414         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3415         if (stat > 0)
3416         {
3417                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3418                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3419                 drawresetcliparea();
3420         }
3421 }
3422
3423 void HUD_Mod_Dom(vector myPos, vector mySize)
3424 {
3425         mod_active = 1; // required in each mod function that always shows something
3426
3427         int layout = autocvar_hud_panel_modicons_dom_layout;
3428         int rows, columns;
3429         float aspect_ratio;
3430         aspect_ratio = (layout) ? 3 : 1;
3431         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3432         columns = ceil(team_count/rows);
3433
3434         int i;
3435         float row = 0, column = 0;
3436         vector pos, itemSize;
3437         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3438         for(i=0; i<team_count; ++i)
3439         {
3440                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3441
3442                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3443
3444                 ++row;
3445                 if(row >= rows)
3446                 {
3447                         row = 0;
3448                         ++column;
3449                 }
3450         }
3451 }
3452
3453 void HUD_ModIcons_SetFunc()
3454 {
3455         switch(gametype)
3456         {
3457                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3458                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3459                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3460                 case MAPINFO_TYPE_CTS:
3461                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3462                 case MAPINFO_TYPE_CA:
3463                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3464                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3465                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3466         }
3467 }
3468
3469 int mod_prev; // previous state of mod_active to check for a change
3470 float mod_alpha;
3471 float mod_change; // "time" when mod_active changed
3472
3473 void HUD_ModIcons(void)
3474 {
3475         if(!autocvar__hud_configure)
3476         {
3477                 if(!autocvar_hud_panel_modicons) return;
3478                 if(!HUD_ModIcons_GameType) return;
3479         }
3480
3481         HUD_Panel_UpdateCvars();
3482
3483         draw_beginBoldFont();
3484
3485         if(mod_active != mod_prev) {
3486                 mod_change = time;
3487                 mod_prev = mod_active;
3488         }
3489
3490         if(mod_active || autocvar__hud_configure)
3491                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3492         else
3493                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3494
3495         if(mod_alpha)
3496                 HUD_Panel_DrawBg(mod_alpha);
3497
3498         if(panel_bg_padding)
3499         {
3500                 panel_pos += '1 1 0' * panel_bg_padding;
3501                 panel_size -= '2 2 0' * panel_bg_padding;
3502         }
3503
3504         if(autocvar__hud_configure)
3505                 HUD_Mod_CTF(panel_pos, panel_size);
3506         else
3507                 HUD_ModIcons_GameType(panel_pos, panel_size);
3508
3509         draw_endBoldFont();
3510 }
3511
3512 // Draw pressed keys (#11)
3513 //
3514 void HUD_PressedKeys(void)
3515 {
3516         if(!autocvar__hud_configure)
3517         {
3518                 if(!autocvar_hud_panel_pressedkeys) return;
3519                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3520         }
3521
3522         HUD_Panel_UpdateCvars();
3523         vector pos, mySize;
3524         pos = panel_pos;
3525         mySize = panel_size;
3526
3527         HUD_Panel_DrawBg(1);
3528         if(panel_bg_padding)
3529         {
3530                 pos += '1 1 0' * panel_bg_padding;
3531                 mySize -= '2 2 0' * panel_bg_padding;
3532         }
3533
3534         // force custom aspect
3535         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3536         if(aspect)
3537         {
3538                 vector newSize = '0 0 0';
3539                 if(mySize.x/mySize.y > aspect)
3540                 {
3541                         newSize.x = aspect * mySize.y;
3542                         newSize.y = mySize.y;
3543
3544                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3545                 }
3546                 else
3547                 {
3548                         newSize.y = 1/aspect * mySize.x;
3549                         newSize.x = mySize.x;
3550
3551                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3552                 }
3553                 mySize = newSize;
3554         }
3555
3556         vector keysize;
3557         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3558         float pressedkeys;
3559         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3560
3561         if(autocvar_hud_panel_pressedkeys_attack)
3562         {
3563                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3564                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3565                 pos.y += keysize.y;
3566         }
3567
3568         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3569         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3570         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3571         pos.y += keysize.y;
3572         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3573         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3574         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3575 }
3576
3577 // Handle chat as a panel (#12)
3578 //
3579 void HUD_Chat(void)
3580 {
3581         if(!autocvar__hud_configure)
3582         {
3583                 if (!autocvar_hud_panel_chat)
3584                 {
3585                         if (!autocvar_con_chatrect)
3586                                 cvar_set("con_chatrect", "0");
3587                         return;
3588                 }
3589                 if(autocvar__con_chat_maximized)
3590                 {
3591                         if(!hud_draw_maximized) return;
3592                 }
3593                 else if(chat_panel_modified)
3594                 {
3595                         panel.update_time = time; // forces reload of panel attributes
3596                         chat_panel_modified = false;
3597                 }
3598         }
3599
3600         HUD_Panel_UpdateCvars();
3601
3602         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3603         {
3604                 panel_pos.y = panel_bg_border;
3605                 panel_size.y = vid_conheight - panel_bg_border * 2;
3606                 if(panel.current_panel_bg == "0") // force a border when maximized
3607                 {
3608                         string panel_bg;
3609                         panel_bg = strcat(hud_skin_path, "/border_default");
3610                         if(precache_pic(panel_bg) == "")
3611                                 panel_bg = "gfx/hud/default/border_default";
3612                         if(panel.current_panel_bg)
3613                                 strunzone(panel.current_panel_bg);
3614                         panel.current_panel_bg = strzone(panel_bg);
3615                         chat_panel_modified = true;
3616                 }
3617                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3618         }
3619
3620         vector pos, mySize;
3621         pos = panel_pos;
3622         mySize = panel_size;
3623
3624         HUD_Panel_DrawBg(1);
3625
3626         if(panel_bg_padding)
3627         {
3628                 pos += '1 1 0' * panel_bg_padding;
3629                 mySize -= '2 2 0' * panel_bg_padding;
3630         }
3631
3632         if (!autocvar_con_chatrect)
3633                 cvar_set("con_chatrect", "1");
3634
3635         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3636         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3637
3638         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3639         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3640
3641         if(autocvar__hud_configure)
3642         {
3643                 vector chatsize;
3644                 chatsize = '1 1 0' * autocvar_con_chatsize;
3645                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3646                 float i, a;
3647                 for(i = 0; i < autocvar_con_chat; ++i)
3648                 {
3649                         if(i == autocvar_con_chat - 1)
3650                                 a = panel_fg_alpha;
3651                         else
3652                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3653                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3654                         pos.y += chatsize.y;
3655                 }
3656         }
3657 }
3658
3659 // Engine info panel (#13)
3660 //
3661 float prevfps;
3662 float prevfps_time;
3663 int framecounter;
3664
3665 float frametimeavg;
3666 float frametimeavg1; // 1 frame ago
3667 float frametimeavg2; // 2 frames ago
3668 void HUD_EngineInfo(void)
3669 {
3670         if(!autocvar__hud_configure)
3671         {
3672                 if(!autocvar_hud_panel_engineinfo) return;
3673         }
3674
3675         HUD_Panel_UpdateCvars();
3676         vector pos, mySize;
3677         pos = panel_pos;
3678         mySize = panel_size;
3679
3680         HUD_Panel_DrawBg(1);
3681         if(panel_bg_padding)
3682         {
3683                 pos += '1 1 0' * panel_bg_padding;
3684                 mySize -= '2 2 0' * panel_bg_padding;
3685         }
3686
3687         float currentTime = gettime(GETTIME_REALTIME);
3688         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3689         {
3690                 float currentframetime = currentTime - prevfps_time;
3691                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3692                 frametimeavg2 = frametimeavg1;
3693                 frametimeavg1 = frametimeavg;
3694
3695                 float weight;
3696                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3697                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3698                 {
3699                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3700                                 prevfps = (1/currentframetime);
3701                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3702                 }
3703                 prevfps_time = currentTime;
3704         }
3705         else
3706         {
3707                 framecounter += 1;
3708                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3709                 {
3710                         prevfps = framecounter/(currentTime - prevfps_time);
3711                         framecounter = 0;
3712                         prevfps_time = currentTime;
3713                 }
3714         }
3715
3716         vector color;
3717         color = HUD_Get_Num_Color (prevfps, 100);
3718         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3719 }
3720
3721 // Info messages panel (#14)
3722 //
3723 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3724         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3725                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3726         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3727         o.y += fontsize.y;                                                                                                                                                                                              \
3728 } while(0)
3729 void HUD_InfoMessages(void)
3730 {
3731         if(!autocvar__hud_configure)
3732         {
3733                 if(!autocvar_hud_panel_infomessages) return;
3734         }
3735
3736         HUD_Panel_UpdateCvars();
3737         vector pos, mySize;
3738         pos = panel_pos;
3739         mySize = panel_size;
3740
3741         HUD_Panel_DrawBg(1);
3742         if(panel_bg_padding)
3743         {
3744                 pos += '1 1 0' * panel_bg_padding;
3745                 mySize -= '2 2 0' * panel_bg_padding;
3746         }
3747
3748         // always force 5:1 aspect
3749         vector newSize = '0 0 0';
3750         if(mySize.x/mySize.y > 5)
3751         {
3752                 newSize.x = 5 * mySize.y;
3753                 newSize.y = mySize.y;
3754
3755                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3756         }
3757         else
3758         {
3759                 newSize.y = 1/5 * mySize.x;
3760                 newSize.x = mySize.x;
3761
3762                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3763         }
3764
3765         mySize = newSize;
3766         entity tm;
3767         vector o;
3768         o = pos;
3769
3770         vector fontsize;
3771         fontsize = '0.20 0.20 0' * mySize.y;
3772
3773         float a;
3774         a = panel_fg_alpha;
3775
3776         string s;
3777         if(!autocvar__hud_configure)
3778         {
3779                 if(spectatee_status && !intermission)
3780                 {
3781                         a = 1;
3782                         if(spectatee_status == -1)
3783                                 s = _("^1Observing");
3784                         else
3785                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3786                         drawInfoMessage(s);
3787
3788                         if(spectatee_status == -1)
3789                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3790                         else
3791                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3792                         drawInfoMessage(s);
3793
3794                         if(spectatee_status == -1)
3795                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3796                         else
3797                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3798                         drawInfoMessage(s);
3799
3800                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3801                         drawInfoMessage(s);
3802
3803                         if(gametype == MAPINFO_TYPE_LMS)
3804                         {
3805                                 entity sk;
3806                                 sk = playerslots[player_localnum];
3807                                 if(sk.(scores[ps_primary]) >= 666)
3808                                         s = _("^1Match has already begun");
3809                                 else if(sk.(scores[ps_primary]) > 0)
3810                                         s = _("^1You have no more lives left");
3811                                 else
3812                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3813                         }
3814                         else
3815                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3816                         drawInfoMessage(s);
3817
3818                         //show restart countdown:
3819                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3820                                 float countdown;
3821                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3822                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3823                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3824                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3825                                 o.y += fontsize.y;
3826                         }
3827                 }
3828                 if(warmup_stage && !intermission)
3829                 {
3830                         s = _("^2Currently in ^1warmup^2 stage!");
3831                         drawInfoMessage(s);
3832                 }
3833
3834                 string blinkcolor;
3835                 if(time % 1 >= 0.5)
3836                         blinkcolor = "^1";
3837                 else
3838                         blinkcolor = "^3";
3839
3840                 if(ready_waiting && !intermission && !spectatee_status)
3841                 {
3842                         if(ready_waiting_for_me)
3843                         {
3844                                 if(warmup_stage)
3845                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3846                                 else
3847                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3848                         }
3849                         else
3850                         {
3851                                 if(warmup_stage)
3852                                         s = _("^2Waiting for others to ready up to end warmup...");
3853                                 else
3854                                         s = _("^2Waiting for others to ready up...");
3855                         }
3856                         drawInfoMessage(s);
3857                 }
3858                 else if(warmup_stage && !intermission && !spectatee_status)
3859                 {
3860                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3861                         drawInfoMessage(s);
3862                 }
3863
3864                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3865                 {
3866                         float ts_min = 0, ts_max = 0;
3867                         tm = teams.sort_next;
3868                         if (tm)
3869                         {
3870                                 for (; tm.sort_next; tm = tm.sort_next)
3871                                 {
3872                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3873                                                 continue;
3874                                         if(!ts_min) ts_min = tm.team_size;
3875                                         else ts_min = min(ts_min, tm.team_size);
3876                                         if(!ts_max) ts_max = tm.team_size;
3877                                         else ts_max = max(ts_max, tm.team_size);
3878                                 }
3879                                 if ((ts_max - ts_min) > 1)
3880                                 {
3881                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3882                                         tm = GetTeam(myteam, false);
3883                                         if (tm)
3884                                         if (tm.team != NUM_SPECTATOR)
3885                                         if (tm.team_size == ts_max)
3886                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3887                                         drawInfoMessage(s);
3888                                 }
3889                         }
3890                 }
3891         }
3892         else
3893         {
3894                 s = _("^7Press ^3ESC ^7to show HUD options.");
3895                 drawInfoMessage(s);
3896                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3897                 drawInfoMessage(s);
3898                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3899                 drawInfoMessage(s);
3900                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3901                 drawInfoMessage(s);
3902         }
3903 }
3904
3905 // Physics panel (#15)
3906 //
3907 vector acc_prevspeed;
3908 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3909 float physics_update_time, discrete_speed, discrete_acceleration;
3910 void HUD_Physics(void)
3911 {
3912         if(!autocvar__hud_configure)
3913         {
3914                 if(!autocvar_hud_panel_physics) return;
3915                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3916                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3917         }
3918
3919         HUD_Panel_UpdateCvars();
3920
3921         draw_beginBoldFont();
3922
3923         HUD_Panel_DrawBg(1);
3924         if(panel_bg_padding)
3925         {
3926                 panel_pos += '1 1 0' * panel_bg_padding;
3927                 panel_size -= '2 2 0' * panel_bg_padding;
3928         }
3929
3930         float acceleration_progressbar_scale = 0;
3931         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3932                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3933
3934         float text_scale;
3935         if (autocvar_hud_panel_physics_text_scale <= 0)
3936                 text_scale = 1;
3937         else
3938                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3939
3940         //compute speed
3941         float speed, conversion_factor;
3942         string unit;
3943
3944         switch(autocvar_hud_panel_physics_speed_unit)
3945         {
3946                 default:
3947                 case 1:
3948                         unit = _(" qu/s");
3949                         conversion_factor = 1.0;
3950                         break;
3951                 case 2:
3952                         unit = _(" m/s");
3953                         conversion_factor = 0.0254;
3954                         break;
3955                 case 3:
3956                         unit = _(" km/h");
3957                         conversion_factor = 0.0254 * 3.6;
3958                         break;
3959                 case 4:
3960                         unit = _(" mph");
3961                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3962                         break;
3963                 case 5:
3964                         unit = _(" knots");
3965                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3966                         break;
3967         }
3968
3969         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3970
3971         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3972         if (autocvar__hud_configure)
3973                 speed = floor( max_speed * 0.65 + 0.5 );
3974         else if(autocvar_hud_panel_physics_speed_vertical)
3975                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3976         else
3977                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
3978
3979         //compute acceleration
3980         float acceleration, f;
3981         if (autocvar__hud_configure)
3982                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3983         else
3984         {
3985                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3986                 f = time - acc_prevtime;
3987                 if(autocvar_hud_panel_physics_acceleration_vertical)
3988                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3989                 else
3990                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
3991
3992                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3993
3994                 acc_prevspeed = vel;
3995                 acc_prevtime = time;
3996
3997                 if(autocvar_hud_panel_physics_acceleration_movingaverage)
3998                 {
3999                         f = bound(0, f * 10, 1);
4000                         acc_avg = acc_avg * (1 - f) + acceleration * f;
4001                         acceleration = acc_avg;
4002                 }
4003         }
4004
4005         int acc_decimals = 2;
4006         if(time > physics_update_time)
4007         {
4008                 // workaround for ftos_decimals returning a negative 0
4009                 if(discrete_acceleration > -1 / pow(10, acc_decimals) && discrete_acceleration < 0)
4010                         discrete_acceleration = 0;
4011                 discrete_acceleration = acceleration;
4012                 discrete_speed = speed;
4013                 physics_update_time += autocvar_hud_panel_physics_update_interval;
4014         }
4015
4016         //compute layout
4017         float panel_ar = panel_size.x/panel_size.y;
4018         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4019         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4020         {
4021                 panel_size.x *= 0.5;
4022                 if (autocvar_hud_panel_physics_flip)
4023                         speed_offset.x = panel_size.x;
4024                 else
4025                         acceleration_offset.x = panel_size.x;
4026         }
4027         else
4028         {
4029                 panel_size.y *= 0.5;
4030                 if (autocvar_hud_panel_physics_flip)
4031                         speed_offset.y = panel_size.y;
4032                 else
4033                         acceleration_offset.y = panel_size.y;
4034         }
4035         int speed_baralign, acceleration_baralign;
4036         if (autocvar_hud_panel_physics_baralign == 1)
4037                 acceleration_baralign = speed_baralign = 1;
4038     else if(autocvar_hud_panel_physics_baralign == 4)
4039                 acceleration_baralign = speed_baralign = 2;
4040         else if (autocvar_hud_panel_physics_flip)
4041         {
4042                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4043                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4044         }
4045         else
4046         {
4047                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4048                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4049         }
4050         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4051                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4052
4053         //draw speed
4054         if(speed)
4055         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4056                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4057         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4058         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4059         {
4060                 tmp_size.x = panel_size.x * 0.75;
4061                 tmp_size.y = panel_size.y * text_scale;
4062                 if (speed_baralign)
4063                         tmp_offset.x = panel_size.x - tmp_size.x;
4064                 //else
4065                         //tmp_offset_x = 0;
4066                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4067                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(discrete_speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4068
4069                 //draw speed unit
4070                 if (speed_baralign)
4071                         tmp_offset.x = 0;
4072                 else
4073                         tmp_offset.x = tmp_size.x;
4074                 if (autocvar_hud_panel_physics_speed_unit_show)
4075                 {
4076                         //tmp_offset_y = 0;
4077                         tmp_size.x = panel_size.x * (1 - 0.75);
4078                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4079                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4080                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4081                 }
4082         }
4083
4084         //compute and draw top speed
4085         if (autocvar_hud_panel_physics_topspeed)
4086         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4087         {
4088                 if (autocvar__hud_configure)
4089                 {
4090                         top_speed = floor( max_speed * 0.75 + 0.5 );
4091                         f = 1;
4092                 }
4093                 else
4094                 {
4095                         if (speed >= top_speed)
4096                         {
4097                                 top_speed = speed;
4098                                 top_speed_time = time;
4099                         }
4100                         if (top_speed != 0)
4101                         {
4102                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4103                                 // divide by f to make it start from 1
4104                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4105                         }
4106             else //hide top speed 0, it would be stupid
4107                                 f = 0;
4108                 }
4109                 if (f > 0)
4110                 {
4111                         //top speed progressbar peak
4112                         if(speed < top_speed)
4113                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4114                         {
4115                                 float peak_offsetX;
4116                                 vector peak_size = '0 0 0';
4117                                 if (speed_baralign == 0)
4118                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4119                 else if (speed_baralign == 1)
4120                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4121                 else // if (speed_baralign == 2)
4122                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4123                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4124                 peak_size.y = panel_size.y;
4125                 if (speed_baralign == 2) // draw two peaks, on both sides
4126                 {
4127                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4128                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4129                 }
4130                 else
4131                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4132                         }
4133
4134                         //top speed
4135                         tmp_offset.y = panel_size.y * 0.4;
4136                         tmp_size.x = panel_size.x * (1 - 0.75);
4137                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4138                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4139                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4140                 }
4141                 else
4142                         top_speed = 0;
4143         }
4144
4145         //draw acceleration
4146         if(acceleration)
4147         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4148         {
4149                 vector progressbar_color;
4150                 if(acceleration < 0)
4151                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4152                 else
4153                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4154
4155                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4156                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4157                         f = (f >= 0 ? sqrt(f) : -sqrt(-f));
4158
4159                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4160                 {
4161                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4162
4163                         if (acceleration_baralign == 1)
4164                                 tmp_offset.x = panel_size.x - tmp_size.x;
4165                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4166                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4167                         else
4168                                 tmp_offset.x = 0;
4169                         tmp_offset.y = 0;
4170                 }
4171                 else
4172                 {
4173                         tmp_size = panel_size;
4174                         tmp_offset = '0 0 0';
4175                 }
4176
4177                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4178         }
4179
4180         if(autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4181         {
4182                 tmp_size.x = panel_size.x;
4183                 tmp_size.y = panel_size.y * text_scale;
4184                 tmp_offset.x = 0;
4185                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4186
4187                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(discrete_acceleration, acc_decimals), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4188         }
4189
4190         draw_endBoldFont();
4191 }
4192
4193 // CenterPrint (#16)
4194 //
4195 const int CENTERPRINT_MAX_MSGS = 10;
4196 const int CENTERPRINT_MAX_ENTRIES = 50;
4197 const float CENTERPRINT_SPACING = 0.7;
4198 int cpm_index;
4199 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4200 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4201 float centerprint_time[CENTERPRINT_MAX_MSGS];
4202 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4203 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4204 bool centerprint_showing;
4205
4206 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4207 {
4208         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4209         int i, j;
4210
4211         if(strMessage == "" && new_id == 0)
4212                 return;
4213
4214         // strip trailing newlines
4215         j = strlen(strMessage) - 1;
4216         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4217                 --j;
4218         if (j < strlen(strMessage) - 1)
4219                 strMessage = substring(strMessage, 0, j + 1);
4220
4221         if(strMessage == "" && new_id == 0)
4222                 return;
4223
4224         // strip leading newlines
4225         j = 0;
4226         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4227                 ++j;
4228         if (j > 0)
4229                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4230
4231         if(strMessage == "" && new_id == 0)
4232                 return;
4233
4234         if (!centerprint_showing)
4235                 centerprint_showing = true;
4236
4237         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4238         {
4239                 if (j == CENTERPRINT_MAX_MSGS)
4240                         j = 0;
4241                 if (new_id && new_id == centerprint_msgID[j])
4242                 {
4243                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4244                         {
4245                                 // fade out the current msg (duration and countdown_num are ignored)
4246                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4247                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4248                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4249                                 return;
4250                         }
4251                         break; // found a msg with the same id, at position j
4252                 }
4253         }
4254
4255         if (i == CENTERPRINT_MAX_MSGS)
4256         {
4257                 // a msg with the same id was not found, add the msg at the next position
4258                 --cpm_index;
4259                 if (cpm_index == -1)
4260                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4261                 j = cpm_index;
4262         }
4263         if(centerprint_messages[j])
4264                 strunzone(centerprint_messages[j]);
4265         centerprint_messages[j] = strzone(strMessage);
4266         centerprint_msgID[j] = new_id;
4267         if (duration < 0)
4268         {
4269                 centerprint_time[j] = -1;
4270                 centerprint_expire_time[j] = time;
4271         }
4272         else
4273         {
4274                 if(duration == 0)
4275                         duration = max(1, autocvar_hud_panel_centerprint_time);
4276                 centerprint_time[j] = duration;
4277                 centerprint_expire_time[j] = time + duration;
4278         }
4279         centerprint_countdown_num[j] = countdown_num;
4280 }
4281
4282 void centerprint_hud(string strMessage)
4283 {
4284         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4285 }
4286
4287 void reset_centerprint_messages(void)
4288 {
4289         int i;
4290         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4291         {
4292                 centerprint_expire_time[i] = 0;
4293                 centerprint_time[i] = 1;
4294                 centerprint_msgID[i] = 0;
4295                 if(centerprint_messages[i])
4296                         strunzone(centerprint_messages[i]);
4297                 centerprint_messages[i] = string_null;
4298         }
4299 }
4300 float hud_configure_cp_generation_time;
4301 void HUD_CenterPrint (void)
4302 {
4303         if(!autocvar__hud_configure)
4304         {
4305                 if(!autocvar_hud_panel_centerprint) return;
4306
4307                 if(hud_configure_prev)
4308                         reset_centerprint_messages();
4309         }
4310         else
4311         {
4312                 if(!hud_configure_prev)
4313                         reset_centerprint_messages();
4314                 if (time > hud_configure_cp_generation_time)
4315                 {
4316                         if(HUD_PANEL(CENTERPRINT) == highlightedPanel)
4317                         {
4318                                 float r;
4319                                 r = random();
4320                                 if (r > 0.8)
4321                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4322                                 else if (r > 0.55)
4323                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4324                                 else
4325                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4326                                 hud_configure_cp_generation_time = time + 1 + random()*4;
4327                         }
4328                         else
4329                         {
4330                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
4331                                 hud_configure_cp_generation_time = time + 10 - random()*3;
4332                         }
4333                 }
4334         }
4335
4336         // this panel fades only when the menu does
4337         float hud_fade_alpha_save = 0;
4338         if(scoreboard_fade_alpha)
4339         {
4340                 hud_fade_alpha_save = hud_fade_alpha;
4341                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4342         }
4343         HUD_Panel_UpdateCvars();
4344
4345         if(scoreboard_fade_alpha)
4346         {
4347                 hud_fade_alpha = hud_fade_alpha_save;
4348
4349                 // move the panel below the scoreboard
4350                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4351                         return;
4352                 vector target_pos;
4353
4354                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4355
4356                 if(target_pos.y > panel_pos.y)
4357                 {
4358                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4359                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4360                 }
4361         }
4362
4363         HUD_Panel_DrawBg(1);
4364
4365         if (!centerprint_showing)
4366                 return;
4367
4368         if(panel_bg_padding)
4369         {
4370                 panel_pos += '1 1 0' * panel_bg_padding;
4371                 panel_size -= '2 2 0' * panel_bg_padding;
4372         }
4373
4374         int entries;
4375         float height;
4376         vector fontsize;
4377         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4378         // height = panel_size_y/entries;
4379         // fontsize = '1 1 0' * height;
4380         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4381         fontsize = '1 1 0' * height;
4382         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4383
4384         int i, j, k, n, g;
4385         float a, sz, align, current_msg_posY = 0, msg_size;
4386         vector pos;
4387         string ts;
4388         bool all_messages_expired = true;
4389
4390         pos = panel_pos;
4391         if (autocvar_hud_panel_centerprint_flip)
4392                 pos.y += panel_size.y;
4393         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4394         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4395         {
4396                 if (j == CENTERPRINT_MAX_MSGS)
4397                         j = 0;
4398                 if (centerprint_expire_time[j] <= time)
4399                 {
4400                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4401                         {
4402                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4403                                 if (centerprint_countdown_num[j] == 0)
4404                                         continue;
4405                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4406                         }
4407                         else if(centerprint_time[j] != -1)
4408                                 continue;
4409                 }
4410
4411                 all_messages_expired = false;
4412
4413                 // fade the centerprint_hud in/out
4414                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4415                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4416                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4417                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4418                 else // Expiring soon, so fade it out.
4419                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4420
4421                 // while counting down show it anyway in order to hold the current message position
4422                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4423                         continue;
4424                 if (a > 1)
4425                         a = 1;
4426
4427                 // set the size from fading in/out before subsequent fading
4428                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4429
4430                 // also fade it based on positioning
4431                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4432                 {
4433                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4434                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4435                 }
4436                 a *= panel_fg_alpha;
4437
4438                 // finally set the size based on the new theAlpha from subsequent fading
4439                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4440                 drawfontscale = sz * '1 1 0';
4441
4442                 if (centerprint_countdown_num[j])
4443                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4444                 else
4445                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4446
4447                 if (autocvar_hud_panel_centerprint_flip)
4448                 {
4449                         // check if the message can be entirely shown
4450                         for(k = 0; k < n; ++k)
4451                         {
4452                                 getWrappedLine_remaining = argv(k);
4453                                 while(getWrappedLine_remaining)
4454                                 {
4455                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4456                                         if (ts != "")
4457                                                 pos.y -= fontsize.y;
4458                                         else
4459                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4460                                 }
4461                         }
4462                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4463                 }
4464
4465                 msg_size = pos.y;
4466                 for(k = 0; k < n; ++k)
4467                 {
4468                         getWrappedLine_remaining = argv(k);
4469                         while(getWrappedLine_remaining)
4470                         {
4471                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4472                                 if (ts != "")
4473                                 {
4474                                         if (align)
4475                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4476                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4477                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4478                                         pos.y += fontsize.y;
4479                                 }
4480                                 else
4481                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4482                         }
4483                 }
4484
4485                 ++g; // move next position number up
4486
4487                 msg_size = pos.y - msg_size;
4488                 if (autocvar_hud_panel_centerprint_flip)
4489                 {
4490                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4491                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4492                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4493
4494                         if (pos.y < panel_pos.y) // check if the next message can be shown
4495                         {
4496                                 drawfontscale = '1 1 0';
4497                                 return;
4498                         }
4499                 }
4500                 else
4501                 {
4502                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4503                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4504                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4505
4506                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4507                         {
4508                                 drawfontscale = '1 1 0';
4509                                 return;
4510                         }
4511                 }
4512         }
4513         drawfontscale = '1 1 0';
4514         if (all_messages_expired)
4515         {
4516                 centerprint_showing = false;
4517                 reset_centerprint_messages();
4518         }
4519 }
4520
4521 // Buffs (#18)
4522 //
4523 void HUD_Buffs(void)
4524 {
4525         int buffs = getstati(STAT_BUFFS, 0, 24);
4526         if(!autocvar__hud_configure)
4527         {
4528                 if(!autocvar_hud_panel_buffs) return;
4529                 if(spectatee_status == -1) return;
4530                 if(getstati(STAT_HEALTH) <= 0) return;
4531                 if(!buffs) return;
4532         }
4533         else
4534         {
4535                 buffs = Buff_Type_first.items; // force first buff
4536         }
4537
4538         int b = 0; // counter to tell other functions that we have buffs
4539         entity e;
4540         string s = "";
4541         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4542         {
4543                 ++b;
4544                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4545                 if(s == "")
4546                         s = o;
4547                 else
4548                         s = strcat(s, " ", o);
4549         }
4550
4551         HUD_Panel_UpdateCvars();
4552
4553         draw_beginBoldFont();
4554
4555         vector pos, mySize;
4556         pos = panel_pos;
4557         mySize = panel_size;
4558
4559         HUD_Panel_DrawBg(bound(0, b, 1));
4560         if(panel_bg_padding)
4561         {
4562                 pos += '1 1 0' * panel_bg_padding;
4563                 mySize -= '2 2 0' * panel_bg_padding;
4564         }
4565
4566         //float panel_ar = mySize_x/mySize_y;
4567         //bool is_vertical = (panel_ar < 1);
4568         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4569         vector buff_offset = '0 0 0';
4570
4571         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4572         {
4573                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4574                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4575         }
4576
4577         draw_endBoldFont();
4578 }
4579
4580
4581 /*
4582 ==================
4583 Main HUD system
4584 ==================
4585 */
4586
4587 void HUD_Reset (void)
4588 {
4589         // reset gametype specific icons
4590         if(gametype == MAPINFO_TYPE_CTF)
4591                 HUD_Mod_CTF_Reset();
4592 }
4593
4594 void HUD_Main (void)
4595 {
4596         int i;
4597         // global hud theAlpha fade
4598         if(menu_enabled == 1)
4599                 hud_fade_alpha = 1;
4600         else
4601                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4602
4603         if(scoreboard_fade_alpha)
4604                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4605
4606         HUD_Configure_Frame();
4607
4608         if(intermission == 2) // no hud during mapvote
4609                 hud_fade_alpha = 0;
4610
4611         // panels that we want to be active together with the scoreboard
4612         // they must fade only when the menu does
4613         if(scoreboard_fade_alpha == 1)
4614         {
4615                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4616                 return;
4617         }
4618
4619         if(!autocvar__hud_configure && !hud_fade_alpha)
4620                 return;
4621
4622         // Drawing stuff
4623         if (hud_skin_prev != autocvar_hud_skin)
4624         {
4625                 if (hud_skin_path)
4626                         strunzone(hud_skin_path);
4627                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4628                 if (hud_skin_prev)
4629                         strunzone(hud_skin_prev);
4630                 hud_skin_prev = strzone(autocvar_hud_skin);
4631         }
4632
4633     current_player = player_localentnum;
4634
4635         // draw the dock
4636         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4637         {
4638                 int f;
4639                 vector color;
4640                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4641                 if((teamplay) && hud_dock_color_team) {
4642                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4643                                 color = '1 0 0' * hud_dock_color_team;
4644                         else
4645                                 color = myteamcolors * hud_dock_color_team;
4646                 }
4647                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4648                         color = '1 0 0' * hud_dock_color_team;
4649                 }
4650                 else
4651                 {
4652                         string hud_dock_color = autocvar_hud_dock_color;
4653                         if(hud_dock_color == "shirt") {
4654                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4655                                 color = colormapPaletteColor(floor(f / 16), 0);
4656                         }
4657                         else if(hud_dock_color == "pants") {
4658                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4659                                 color = colormapPaletteColor(f % 16, 1);
4660                         }
4661                         else
4662                                 color = stov(hud_dock_color);
4663                 }
4664
4665                 string pic;
4666                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4667                 if(precache_pic(pic) == "") {
4668                         pic = strcat(hud_skin_path, "/dock_medium");
4669                         if(precache_pic(pic) == "") {
4670                                 pic = "gfx/hud/default/dock_medium";
4671                         }
4672                 }
4673                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4674         }
4675
4676         // cache the panel order into the panel_order array
4677         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4678                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4679                         panel_order[i] = -1;
4680                 string s = "";
4681                 int p_num;
4682                 bool warning = false;
4683                 int argc = tokenize_console(autocvar__hud_panelorder);
4684                 if (argc > HUD_PANEL_NUM)
4685                         warning = true;
4686                 //first detect wrong/missing panel numbers
4687                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4688                         p_num = stoi(argv(i));
4689                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4690                                 if (panel_order[p_num] == -1) //found for the first time?
4691                                         s = strcat(s, ftos(p_num), " ");
4692                                 panel_order[p_num] = 1; //mark as found
4693                         }
4694                         else
4695                                 warning = true;
4696                 }
4697                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4698                         if (panel_order[i] == -1) {
4699                                 warning = true;
4700                                 s = strcat(s, ftos(i), " "); //add missing panel number
4701                         }
4702                 }
4703                 if (warning)
4704                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4705
4706                 cvar_set("_hud_panelorder", s);
4707                 if(hud_panelorder_prev)
4708                         strunzone(hud_panelorder_prev);
4709                 hud_panelorder_prev = strzone(s);
4710
4711                 //now properly set panel_order
4712                 tokenize_console(s);
4713                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4714                         panel_order[i] = stof(argv(i));
4715                 }
4716         }
4717
4718         hud_draw_maximized = 0;
4719         // draw panels in order specified by panel_order array
4720         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4721                 (panel = hud_panel[panel_order[i]]).panel_draw();
4722
4723         hud_draw_maximized = 1; // panels that may be maximized must check this var
4724         // draw maximized panels on top
4725         if(hud_panel_radar_maximized)
4726                 (panel = HUD_PANEL(RADAR)).panel_draw();
4727         if(autocvar__con_chat_maximized)
4728                 (panel = HUD_PANEL(CHAT)).panel_draw();
4729
4730         HUD_Configure_PostDraw();
4731
4732         hud_configure_prev = autocvar__hud_configure;
4733 }