811b3649c1fa0f440c5a4b40db9c2b28762a0dc9
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / hud.qc
1 /*
2 ==================
3 Misc HUD functions
4 ==================
5 */
6
7 // a border picture is a texture containing nine parts:
8 //   1/4 width: left part
9 //   1/2 width: middle part (stretched)
10 //   1/4 width: right part
11 // divided into
12 //   1/4 height: top part
13 //   1/2 height: middle part (stretched)
14 //   1/4 height: bottom part
15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
16 {
17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
18     {
19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
20                 return;
21     }
22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
23         {
24                 // draw only the central part
25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
26                 return;
27         }
28
29         vector dX, dY;
30         vector width, height;
31         vector bW, bH;
32         //pic = draw_UseSkinFor(pic);
33         width = eX * theSize_x;
34         height = eY * theSize_y;
35         if(theSize_x <= theBorderSize_x * 2)
36         {
37                 // not wide enough... draw just left and right then
38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
39                 if(theSize_y <= theBorderSize_y * 2)
40                 {
41                         // not high enough... draw just corners
42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
47                 }
48                 else
49                 {
50                         dY = theBorderSize_x * eY;
51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
57                 }
58         }
59         else
60         {
61                 if(theSize_y <= theBorderSize_y * 2)
62                 {
63                         // not high enough... draw just top and bottom then
64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
65                         dX = theBorderSize_x * eX;
66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
72                 }
73                 else
74                 {
75                         dX = theBorderSize_x * eX;
76                         dY = theBorderSize_x * eY;
77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
86                 }
87         }
88 }
89
90 vector HUD_Get_Num_Color (float x, float maxvalue)
91 {
92         float blinkingamt;
93         vector color;
94         if(x >= maxvalue) {
95                 color_x = sin(2*M_PI*time);
96                 color_y = 1;
97                 color_z = sin(2*M_PI*time);
98         }
99         else if(x > maxvalue * 0.75) {
100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
102                 color_z = 0;
103         }
104         else if(x > maxvalue * 0.5) {
105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
108         }
109         else if(x > maxvalue * 0.25) {
110                 color_x = 1;
111                 color_y = 1;
112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
113         }
114         else if(x > maxvalue * 0.1) {
115                 color_x = 1;
116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
118         }
119         else {
120                 color_x = 1;
121                 color_y = 0;
122                 color_z = 0;
123         }
124
125         blinkingamt = (1 - x/maxvalue/0.25);
126         if(blinkingamt > 0)
127         {
128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
131         }
132         return color;
133 }
134
135 float stringwidth_colors(string s, vector theSize)
136 {
137         return stringwidth(s, TRUE, theSize);
138 }
139
140 float stringwidth_nocolors(string s, vector theSize)
141 {
142         return stringwidth(s, FALSE, theSize);
143 }
144
145 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
146 {
147         position_x -= 2 / 3 * strlen(text) * theScale_x;
148         drawstring(position, text, theScale, rgb, theAlpha, flag);
149 }
150
151 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
152 {
153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale_x);
154         drawstring(position, text, theScale, rgb, theAlpha, flag);
155 }
156
157 // return the string of the onscreen race timer
158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
159 {
160         string col;
161         string timestr;
162         string cpname;
163         string lapstr;
164         lapstr = "";
165
166         if(histime == 0) // goal hit
167         {
168                 if(mytime > 0)
169                 {
170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
171                         col = "^1";
172                 }
173                 else if(mytime == 0)
174                 {
175                         timestr = "+0.0";
176                         col = "^3";
177                 }
178                 else
179                 {
180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
181                         col = "^2";
182                 }
183
184                 if(lapdelta > 0)
185                 {
186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
187                         col = "^2";
188                 }
189                 else if(lapdelta < 0)
190                 {
191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
192                         col = "^1";
193                 }
194         }
195         else if(histime > 0) // anticipation
196         {
197                 if(mytime >= histime)
198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
199                 else
200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
201                 col = "^3";
202         }
203         else
204         {
205                 col = "^7";
206                 timestr = "";
207         }
208
209         if(cp == 254)
210                 cpname = _("Start line");
211         else if(cp == 255)
212                 cpname = _("Finish line");
213         else if(cp)
214                 cpname = sprintf(_("Intermediate %d"), cp);
215         else
216                 cpname = _("Finish line");
217
218         if(histime < 0)
219                 return strcat(col, cpname);
220         else if(hisname == "")
221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
222         else
223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
224 }
225
226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
227 float race_CheckName(string net_name) {
228         float i;
229         for (i=RANKINGS_CNT-1;i>=0;--i)
230                 if(grecordholder[i] == net_name)
231                         return i+1;
232         return 0;
233 }
234
235 float GetPlayerColorForce(float i)
236 {
237         if(!teamplay)
238                 return 0;
239         else
240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
241 }
242
243 float GetPlayerColor(float i)
244 {
245         if(!playerslots[i].gotscores) // unconnected
246                 return NUM_SPECTATOR;
247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
248                 return NUM_SPECTATOR;
249         else
250                 return GetPlayerColorForce(i);
251 }
252
253 string GetPlayerName(float i)
254 {
255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
256 }
257
258
259 /*
260 ==================
261 HUD panels
262 ==================
263 */
264
265 // draw the background/borders
266 #define HUD_Panel_DrawBg(theAlpha)\
267 if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")\
268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
269
270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
272 {
273         if(!length_ratio || !theAlpha)
274                 return;
275         if(length_ratio > 1)
276                 length_ratio = 1;
277         if (baralign == 3)
278         {
279                 if(length_ratio < -1)
280                         length_ratio = -1;
281         }
282         else if(length_ratio < 0)
283                 return;
284
285         vector square;
286         vector width, height;
287         if(vertical) {
288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
289                 if(precache_pic(pic) == "") {
290                         pic = "gfx/hud/default/progressbar_vertical";
291                 }
292
293         if (baralign == 1) // bottom align
294                         theOrigin_y += (1 - length_ratio) * theSize_y;
295         else if (baralign == 2) // center align
296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
297         else if (baralign == 3) // center align, positive values down, negative up
298                 {
299                         theSize_y *= 0.5;
300                         if (length_ratio > 0)
301                                 theOrigin_y += theSize_y;
302                         else
303                         {
304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
305                                 length_ratio = -length_ratio;
306                         }
307                 }
308                 theSize_y *= length_ratio;
309
310                 vector bH;
311                 width = eX * theSize_x;
312                 height = eY * theSize_y;
313                 if(theSize_y <= theSize_x * 2)
314                 {
315                         // button not high enough
316                         // draw just upper and lower part then
317                         square = eY * theSize_y * 0.5;
318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
321                 }
322                 else
323                 {
324                         square = eY * theSize_x;
325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
328                 }
329         } else {
330                 pic = strcat(hud_skin_path, "/", pic);
331                 if(precache_pic(pic) == "") {
332                         pic = "gfx/hud/default/progressbar";
333                 }
334
335                 if (baralign == 1) // right align
336                         theOrigin_x += (1 - length_ratio) * theSize_x;
337         else if (baralign == 2) // center align
338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
339         else if (baralign == 3) // center align, positive values on the right, negative on the left
340                 {
341                         theSize_x *= 0.5;
342                         if (length_ratio > 0)
343                                 theOrigin_x += theSize_x;
344                         else
345                         {
346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
347                                 length_ratio = -length_ratio;
348                         }
349                 }
350                 theSize_x *= length_ratio;
351
352                 vector bW;
353                 width = eX * theSize_x;
354                 height = eY * theSize_y;
355                 if(theSize_x <= theSize_y * 2)
356                 {
357                         // button not wide enough
358                         // draw just left and right part then
359                         square = eX * theSize_x * 0.5;
360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
363                 }
364                 else
365                 {
366                         square = eX * theSize_y;
367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
370                 }
371         }
372 }
373
374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
375 {
376         if(!theAlpha)
377                 return;
378
379         string pic;
380         pic = strcat(hud_skin_path, "/num_leading");
381         if(precache_pic(pic) == "") {
382                 pic = "gfx/hud/default/num_leading";
383         }
384
385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
386         if(mySize_x/mySize_y > 2)
387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
389 }
390
391 // Weapon icons (#0)
392 //
393 entity weaponorder[WEP_MAXCOUNT];
394 void weaponorder_swap(float i, float j, entity pass)
395 {
396         entity h;
397         h = weaponorder[i];
398         weaponorder[i] = weaponorder[j];
399         weaponorder[j] = h;
400 }
401
402 string weaponorder_cmp_str;
403 float weaponorder_cmp(float i, float j, entity pass)
404 {
405         float ai, aj;
406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
409 }
410
411 void HUD_Weapons(void)
412 {
413         // declarations
414         WepSet weapons_stat = WepSet_GetFromStat();
415         float i, f, a;
416         float screen_ar, center_x = 0, center_y;
417         float weapon_count, weapon_id;
418         float row, column, rows = 0, columns;
419         float aspect = autocvar_hud_panel_weapons_aspect;
420
421         float panel_weapon_accuracy;
422
423         float timeout = autocvar_hud_panel_weapons_timeout;
424         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
425         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
426
427         float ammo_full;
428         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
429         vector ammo_color = '1 0 1';
430         float ammo_alpha = 1;
431
432         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
433         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
434
435         vector weapon_pos, weapon_size = '0 0 0';
436         local noref vector old_panel_size; // fteqcc sucks
437         vector color;
438
439         // check to see if we want to continue
440         if(hud != HUD_NORMAL) { return; }
441
442         if(!autocvar__hud_configure)
443         {
444                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
445                         return;
446                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
447                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
448                 {
449                         weaponprevtime = time;
450                         return;
451                 }
452         }
453
454         // update generic hud functions
455         HUD_Panel_UpdateCvars();
456
457         draw_beginBoldFont();
458
459         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
460         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
461         {
462                 float weapon_cnt;
463                 if(weaponorder_bypriority)
464                         strunzone(weaponorder_bypriority);
465                 if(weaponorder_byimpulse)
466                         strunzone(weaponorder_byimpulse);
467
468                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
469                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
470                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
471
472                 weapon_cnt = 0;
473                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
474                 {
475                         self = get_weaponinfo(i);
476                         if(self.impulse >= 0)
477                         {
478                                 weaponorder[weapon_cnt] = self;
479                                 ++weapon_cnt;
480                         }
481                 }
482                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
483                         weaponorder[i] = world;
484                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
485
486                 weaponorder_cmp_str = string_null;
487         }
488
489         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
490                 complain_weapon = 0;
491
492         // determine which weapons are going to be shown
493         if (autocvar_hud_panel_weapons_onlyowned)
494         {
495                 if(autocvar__hud_configure)
496                 {
497                         if (!weapons_stat)
498                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
499                                         weapons_stat |= WepSet_FromWeapon(i);
500
501                         if(menu_enabled != 2)
502                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
503                 }
504
505                 // do we own this weapon?
506                 weapon_count = 0;
507                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
508                         if(weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon))
509                                 ++weapon_count;
510
511                 // add it anyway if weaponcomplain is shown
512                 if(complain_weapon)
513                         ++weapon_count;
514
515                 // might as well commit suicide now, no reason to live ;)
516                 if (weapon_count == 0)
517                 {
518                         draw_endBoldFont();
519                         return;
520                 }
521
522                 old_panel_size = panel_size;
523                 if(panel_bg_padding)
524                         old_panel_size -= '2 2 0' * panel_bg_padding;
525
526                 // first find values for the standard table (with all the weapons)
527                 rows = old_panel_size_y/old_panel_size_x;
528                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
529                 columns = ceil(WEP_COUNT/rows);
530                 weapon_size_x = old_panel_size_x / columns;
531                 weapon_size_y = old_panel_size_y / rows;
532
533                 // change table values to include only the owned weapons
534                 float columns_save = columns;
535                 if(weapon_count <= rows)
536                 {
537                         rows = weapon_count;
538                         columns = 1;
539                 }
540                 else
541                         columns = ceil(weapon_count / rows);
542
543                 // enlarge weapon_size to match desired aspect ratio in order to capitalize on panel space
544                 if(columns < columns_save)
545                         weapon_size_x = min(old_panel_size_x / columns, aspect * weapon_size_y);
546
547                 // reduce size of the panel
548                 panel_size_x = columns * weapon_size_x;
549                 panel_size_y = rows * weapon_size_y;
550                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
551                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
552                 if(panel_bg_padding)
553                         panel_size += '2 2 0' * panel_bg_padding;
554         }
555         else
556                 weapon_count = WEP_COUNT;
557
558         // animation for fading in/out the panel respectively when not in use
559         if(!autocvar__hud_configure)
560         {
561                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
562                 {
563                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
564
565                         // fade the panel alpha
566                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
567                         {
568                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
569                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
570                         }
571                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
572                         {
573                                 panel_bg_alpha *= (1 - f);
574                                 panel_fg_alpha *= (1 - f);
575                         }
576
577                         // move the panel off the screen
578                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
579                         {
580                                 f *= f; // for a cooler movement
581                                 center_x = panel_pos_x + panel_size_x/2;
582                                 center_y = panel_pos_y + panel_size_y/2;
583                                 screen_ar = vid_conwidth/vid_conheight;
584                                 if (center_x/center_y < screen_ar) //bottom left
585                                 {
586                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
587                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
588                                         else //left
589                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
590                                 }
591                                 else //top right
592                                 {
593                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
594                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
595                                         else //top
596                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
597                                 }
598                                 if(f == 1)
599                                         center_x = -1; // mark the panel as off screen
600                         }
601                         weaponprevtime = time - (1 - f) * timein_effect_length;
602                 }
603                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
604                 {
605                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
606
607                         // fade the panel alpha
608                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
609                         {
610                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
611                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
612                         }
613                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
614                         {
615                                 panel_bg_alpha *= (f);
616                                 panel_fg_alpha *= (f);
617                         }
618
619                         // move the panel back on screen
620                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
621                         {
622                                 f *= f; // for a cooler movement
623                                 f = 1 - f;
624                                 center_x = panel_pos_x + panel_size_x/2;
625                                 center_y = panel_pos_y + panel_size_y/2;
626                                 screen_ar = vid_conwidth/vid_conheight;
627                                 if (center_x/center_y < screen_ar) //bottom left
628                                 {
629                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
630                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
631                                         else //left
632                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
633                                 }
634                                 else //top right
635                                 {
636                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
637                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
638                                         else //top
639                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
640                                 }
641                         }
642                 }
643         }
644
645         // draw the background, then change the virtual size of it to better fit other items inside
646         HUD_Panel_DrawBg(1);
647
648         if(center_x == -1)
649         {
650                 draw_endBoldFont();
651                 return;
652         }
653
654         if(panel_bg_padding)
655         {
656                 panel_pos += '1 1 0' * panel_bg_padding;
657                 panel_size -= '2 2 0' * panel_bg_padding;
658         }
659
660         // after the sizing and animations are done, update the other values
661
662         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
663         {
664                 rows = panel_size_y/panel_size_x;
665                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
666                 columns = ceil(weapon_count/rows);
667                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
668         }
669
670         // calculate position/size for visual bar displaying ammount of ammo status
671         if (autocvar_hud_panel_weapons_ammo)
672         {
673                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
674                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
675
676                 if(weapon_size_x/weapon_size_y > aspect)
677                 {
678                         barsize_x = aspect * weapon_size_y;
679                         barsize_y = weapon_size_y;
680                         baroffset_x = (weapon_size_x - barsize_x) / 2;
681                 }
682                 else
683                 {
684                         barsize_y = 1/aspect * weapon_size_x;
685                         barsize_x = weapon_size_x;
686                         baroffset_y = (weapon_size_y - barsize_y) / 2;
687                 }
688         }
689         if(autocvar_hud_panel_weapons_accuracy)
690                 Accuracy_LoadColors();
691
692         row = column = 0;
693         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
694         {
695                 // retrieve information about the current weapon to be drawn
696                 self = weaponorder[i];
697                 weapon_id = self.impulse;
698
699                 // skip if this weapon doesn't exist
700                 if(!self || weapon_id < 0) { continue; }
701
702                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
703                 if(autocvar_hud_panel_weapons_onlyowned)
704                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
705                         continue;
706
707                 // figure out the drawing position of weapon
708                 weapon_pos = (panel_pos
709                         + eX * column * weapon_size_x
710                         + eY * row * weapon_size_y);
711
712                 // draw background behind currently selected weapon
713                 if(self.weapon == switchweapon)
714                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
715
716                 // draw the weapon accuracy
717                 if(autocvar_hud_panel_weapons_accuracy)
718                 {
719                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
720                         if(panel_weapon_accuracy >= 0)
721                         {
722                                 color = Accuracy_GetColor(panel_weapon_accuracy);
723                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
724                         }
725                 }
726
727                 // drawing all the weapon items
728                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
729                 {
730                         // draw the weapon image
731                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
732
733                         // draw weapon label string
734                         switch(autocvar_hud_panel_weapons_label)
735                         {
736                                 case 1: // weapon number
737                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
738                                         break;
739
740                                 case 2: // bind
741                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
742                                         break;
743
744                                 case 3: // weapon name
745                                         drawstring(weapon_pos, strtolower(self.message), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
746                                         break;
747
748                                 default: // nothing
749                                         break;
750                         }
751
752                         // draw ammo status bar
753                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
754                         {
755                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
756
757                                 if(a > 0)
758                                 {
759                                         switch(self.ammo_field)
760                                         {
761                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
762                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
763                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
764                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
765                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
766                                                 default: ammo_full = 60;
767                                         }
768
769                                         drawsetcliparea(
770                                                 weapon_pos_x + baroffset_x,
771                                                 weapon_pos_y + baroffset_y,
772                                                 barsize_x * bound(0, a/ammo_full, 1),
773                                                 barsize_y
774                                         );
775
776                                         drawpic_aspect_skin(
777                                                 weapon_pos,
778                                                 "weapon_ammo",
779                                                 weapon_size,
780                                                 ammo_color,
781                                                 ammo_alpha,
782                                                 DRAWFLAG_NORMAL
783                                         );
784
785                                         drawresetcliparea();
786                                 }
787                         }
788                 }
789                 else // draw a "ghost weapon icon" if you don't have the weapon
790                 {
791                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
792                 }
793
794                 // draw the complain message
795                 if(self.weapon == complain_weapon)
796                 {
797                         if(fadetime)
798                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
799                         else
800                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
801
802                         string s;
803                         if(complain_weapon_type == 0) {
804                                 s = _("Out of ammo");
805                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
806                         }
807                         else if(complain_weapon_type == 1) {
808                                 s = _("Don't have");
809                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
810                         }
811                         else {
812                                 s = _("Unavailable");
813                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
814                         }
815                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
816                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
817                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
818                 }
819
820                 // continue with new position for the next weapon
821                 ++row;
822                 if(row >= rows)
823                 {
824                         row = 0;
825                         ++column;
826                 }
827         }
828
829         draw_endBoldFont();
830 }
831
832 // Ammo (#1)
833 void DrawAmmoItem(vector myPos, vector mySize, .float ammotype, float currently_selected, float infinite_ammo)
834 {
835         float a = 0;
836         if(ammotype != ammo_none)
837         {
838                 if(autocvar__hud_configure)
839                 {
840                         currently_selected = (ammotype == ammo_rockets); //rockets always selected
841                         a = 60;
842                 }
843                 else
844                 {
845                         // how much ammo do we have of this ammotype?
846                         a = getstati(GetAmmoStat(ammotype));
847                 }
848         }
849         else
850         {
851                 #if 0
852                 infinite_ammo = TRUE;
853                 #else
854                 return; // just don't draw infinite ammo at all.
855                 #endif
856         }
857
858         vector color;
859         if(infinite_ammo)
860                 color = '0 0.5 0.75';
861         else if(a < 10)
862                 color = '0.7 0 0';
863         else
864                 color = '1 1 1';
865
866         float theAlpha;
867         if(currently_selected)
868                 theAlpha = 1;
869         else
870                 theAlpha = 0.7;
871
872         vector picpos, numpos;
873         if(autocvar_hud_panel_ammo_iconalign)
874         {
875                 numpos = myPos;
876                 picpos = myPos + eX * 2 * mySize_y;
877         }
878         else
879         {
880                 numpos = myPos + eX * mySize_y;
881                 picpos = myPos;
882         }
883
884         if(currently_selected)
885                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
886
887     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
888         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
889
890     if(autocvar_hud_panel_ammo_text)
891     {
892         if(a > 0 || infinite_ammo)
893             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
894         else // "ghost" ammo count
895             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
896     }
897         if(a > 0 || infinite_ammo)
898                 drawpic_aspect_skin(picpos, GetAmmoPicture(ammotype), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
899         else // "ghost" ammo icon
900                 drawpic_aspect_skin(picpos, GetAmmoPicture(ammotype), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
901 }
902
903 void HUD_Ammo(void)
904 {
905         if(hud != HUD_NORMAL) return;
906         if(!autocvar__hud_configure)
907         {
908                 if(!autocvar_hud_panel_ammo) return;
909                 if(spectatee_status == -1) return;
910         }
911
912         HUD_Panel_UpdateCvars();
913
914         draw_beginBoldFont();
915
916         vector pos, mySize;
917         pos = panel_pos;
918         mySize = panel_size;
919
920         HUD_Panel_DrawBg(1);
921         if(panel_bg_padding)
922         {
923                 pos += '1 1 0' * panel_bg_padding;
924                 mySize -= '2 2 0' * panel_bg_padding;
925         }
926
927         const float AMMO_COUNT = 4;
928         float rows = 0, columns, row, column;
929         vector ammo_size;
930         if(autocvar_hud_panel_ammo_onlycurrent)
931                 ammo_size = mySize;
932         else
933         {
934                 rows = mySize_y/mySize_x;
935                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
936                 //                               ^^^ ammo item aspect goes here
937
938                 columns = ceil(AMMO_COUNT/rows);
939
940                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
941         }
942
943         local vector offset = '0 0 0'; // fteqcc sucks
944         float newSize;
945         if(ammo_size_x/ammo_size_y > 3)
946         {
947                 newSize = 3 * ammo_size_y;
948                 offset_x = ammo_size_x - newSize;
949                 pos_x += offset_x/2;
950                 ammo_size_x = newSize;
951         }
952         else
953         {
954                 newSize = 1/3 * ammo_size_x;
955                 offset_y = ammo_size_y - newSize;
956                 pos_y += offset_y/2;
957                 ammo_size_y = newSize;
958         }
959
960         float i;
961         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
962         if(autocvar_hud_panel_ammo_onlycurrent)
963         {
964                 if(autocvar__hud_configure)
965                 {
966                         DrawAmmoItem(pos, ammo_size, ammo_rockets, TRUE, FALSE);
967                 }
968                 else
969                 {
970                         DrawAmmoItem(
971                                 pos,
972                                 ammo_size,
973                                 (get_weaponinfo(switchweapon)).ammo_field,
974                                 TRUE,
975                                 infinite_ammo
976                         );
977                 }
978         }
979         else
980         {
981                 .float ammotype;
982                 row = column = 0;
983                 for(i = 0; i < AMMO_COUNT; ++i)
984                 {
985                         ammotype = GetAmmoFieldFromNum(i);
986                         DrawAmmoItem(
987                                 pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y),
988                                 ammo_size,
989                                 ammotype,
990                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
991                                 infinite_ammo
992                         );
993
994                         ++row;
995                         if(row >= rows)
996                         {
997                                 row = 0;
998                                 column = column + 1;
999                         }
1000                 }
1001         }
1002
1003         draw_endBoldFont();
1004 }
1005
1006 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1007 {
1008         vector newPos = '0 0 0', newSize = '0 0 0';
1009         vector picpos, numpos;
1010
1011         if (vertical)
1012         {
1013                 if(mySize_y/mySize_x > 2)
1014                 {
1015                         newSize_y = 2 * mySize_x;
1016                         newSize_x = mySize_x;
1017
1018                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1019                         newPos_x = myPos_x;
1020                 }
1021                 else
1022                 {
1023                         newSize_x = 1/2 * mySize_y;
1024                         newSize_y = mySize_y;
1025
1026                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1027                         newPos_y = myPos_y;
1028                 }
1029
1030                 if(icon_right_align)
1031                 {
1032                         numpos = newPos;
1033                         picpos = newPos + eY * newSize_x;
1034                 }
1035                 else
1036                 {
1037                         picpos = newPos;
1038                         numpos = newPos + eY * newSize_x;
1039                 }
1040
1041                 newSize_y /= 2;
1042                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1043                 // make number smaller than icon, it looks better
1044                 // reduce only y to draw numbers with different number of digits with the same y size
1045                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1046                 newSize_y *= 0.7;
1047                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1048                 return;
1049         }
1050
1051         if(mySize_x/mySize_y > 3)
1052         {
1053                 newSize_x = 3 * mySize_y;
1054                 newSize_y = mySize_y;
1055
1056                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1057                 newPos_y = myPos_y;
1058         }
1059         else
1060         {
1061                 newSize_y = 1/3 * mySize_x;
1062                 newSize_x = mySize_x;
1063
1064                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1065                 newPos_x = myPos_x;
1066         }
1067
1068         if(icon_right_align) // right align
1069         {
1070                 numpos = newPos;
1071                 picpos = newPos + eX * 2 * newSize_y;
1072         }
1073         else // left align
1074         {
1075                 numpos = newPos + eX * newSize_y;
1076                 picpos = newPos;
1077         }
1078
1079         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1080         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1081         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1082         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1083 }
1084
1085 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1086 {
1087         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1088 }
1089
1090 // Powerups (#2)
1091 //
1092 void HUD_Powerups(void)
1093 {
1094         float strength_time, shield_time, superweapons_time;
1095         if(!autocvar__hud_configure)
1096         {
1097                 if(!autocvar_hud_panel_powerups) return;
1098                 if(spectatee_status == -1) return;
1099                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1100                 if (getstati(STAT_HEALTH) <= 0) return;
1101
1102                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1103                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1104                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1105
1106                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1107                         superweapons_time = 99; // force max
1108
1109                 // prevent stuff to show up on mismatch that will be fixed next frame
1110                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1111                         superweapons_time = 0;
1112         }
1113         else
1114         {
1115                 strength_time = 15;
1116                 shield_time = 27;
1117                 superweapons_time = 13;
1118         }
1119
1120         HUD_Panel_UpdateCvars();
1121
1122         draw_beginBoldFont();
1123
1124         vector pos, mySize;
1125         pos = panel_pos;
1126         mySize = panel_size;
1127
1128         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1129         if(panel_bg_padding)
1130         {
1131                 pos += '1 1 0' * panel_bg_padding;
1132                 mySize -= '2 2 0' * panel_bg_padding;
1133         }
1134
1135         float panel_ar = mySize_x/mySize_y;
1136         float is_vertical = (panel_ar < 1);
1137         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1138
1139         float superweapons_is = -1;
1140
1141         if(superweapons_time)
1142         {
1143                 if(strength_time)
1144                 {
1145                         if(shield_time)
1146                                 superweapons_is = 0;
1147                         else
1148                                 superweapons_is = 2;
1149                 }
1150                 else
1151                 {
1152                         if(shield_time)
1153                                 superweapons_is = 1;
1154                         else
1155                                 superweapons_is = 2;
1156                 }
1157         }
1158
1159         // FIXME handle superweapons here
1160         if(superweapons_is == 0)
1161         {
1162                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1163                 {
1164                         mySize_x *= (1.0 / 3.0);
1165                         superweapons_offset_x = mySize_x;
1166                         if (autocvar_hud_panel_powerups_flip)
1167                                 shield_offset_x = 2*mySize_x;
1168                         else
1169                                 strength_offset_x = 2*mySize_x;
1170                 }
1171                 else
1172                 {
1173                         mySize_y *= (1.0 / 3.0);
1174                         superweapons_offset_y = mySize_y;
1175                         if (autocvar_hud_panel_powerups_flip)
1176                                 shield_offset_y = 2*mySize_y;
1177                         else
1178                                 strength_offset_y = 2*mySize_y;
1179                 }
1180         }
1181         else
1182         {
1183                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1184                 {
1185                         mySize_x *= 0.5;
1186                         if (autocvar_hud_panel_powerups_flip)
1187                                 shield_offset_x = mySize_x;
1188                         else
1189                                 strength_offset_x = mySize_x;
1190                 }
1191                 else
1192                 {
1193                         mySize_y *= 0.5;
1194                         if (autocvar_hud_panel_powerups_flip)
1195                                 shield_offset_y = mySize_y;
1196                         else
1197                                 strength_offset_y = mySize_y;
1198                 }
1199         }
1200
1201         float shield_baralign, strength_baralign, superweapons_baralign;
1202         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1203
1204         if (autocvar_hud_panel_powerups_flip)
1205         {
1206                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1207                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1208                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1209                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1210         }
1211         else
1212         {
1213                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1214                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1215                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1216                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1217         }
1218
1219         if(superweapons_is == 0)
1220         {
1221                 superweapons_iconalign = strength_iconalign;
1222                 superweapons_baralign = 2;
1223         }
1224         else if(superweapons_is == 1)
1225         {
1226                 superweapons_offset = strength_offset;
1227                 superweapons_iconalign = strength_iconalign;
1228                 superweapons_baralign = strength_baralign;
1229         }
1230         else // if(superweapons_is == 2)
1231         {
1232                 superweapons_offset = shield_offset;
1233                 superweapons_iconalign = shield_iconalign;
1234                 superweapons_baralign = shield_baralign;
1235         }
1236
1237         if(shield_time)
1238         {
1239                 const float maxshield = 30;
1240                 float shield = ceil(shield_time);
1241                 if(autocvar_hud_panel_powerups_progressbar)
1242                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1243                 if(autocvar_hud_panel_powerups_text)
1244                 {
1245                         if(shield > 1)
1246                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1247                         if(shield <= 5)
1248                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1249                 }
1250         }
1251
1252         if(strength_time)
1253         {
1254                 const float maxstrength = 30;
1255                 float strength = ceil(strength_time);
1256                 if(autocvar_hud_panel_powerups_progressbar)
1257                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1258                 if(autocvar_hud_panel_powerups_text)
1259                 {
1260                         if(strength > 1)
1261                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1262                         if(strength <= 5)
1263                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1264                 }
1265         }
1266
1267         if(superweapons_time)
1268         {
1269                 const float maxsuperweapons = 30;
1270                 float superweapons = ceil(superweapons_time);
1271                 if(autocvar_hud_panel_powerups_progressbar)
1272                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1273                 if(autocvar_hud_panel_powerups_text)
1274                 {
1275                         if(superweapons > 1)
1276                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1277                         if(superweapons <= 5)
1278                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1279                 }
1280         }
1281
1282         draw_endBoldFont();
1283 }
1284
1285 // Health/armor (#3)
1286 //
1287
1288 // prev_* vars contain the health/armor at the previous FRAME
1289 // set to -1 when player is dead or was not playing
1290 float prev_health, prev_armor;
1291 float health_damagetime, armor_damagetime;
1292 float health_beforedamage, armor_beforedamage;
1293 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1294 float old_p_health, old_p_armor;
1295 float old_p_healthtime, old_p_armortime;
1296 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1297 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1298 float prev_p_health, prev_p_armor;
1299
1300 void HUD_HealthArmor(void)
1301 {
1302         float armor, health, fuel;
1303         if(!autocvar__hud_configure)
1304         {
1305                 if(!autocvar_hud_panel_healtharmor) return;
1306                 if(hud != HUD_NORMAL) return;
1307                 if(spectatee_status == -1) return;
1308
1309                 health = getstati(STAT_HEALTH);
1310                 if(health <= 0)
1311                 {
1312                         prev_health = -1;
1313                         return;
1314                 }
1315                 armor = getstati(STAT_ARMOR);
1316
1317                 // code to check for spectatee_status changes is in Ent_ClientData()
1318                 // prev_p_health and prev_health can be set to -1 there
1319
1320                 if (prev_p_health == -1)
1321                 {
1322                         // no effect
1323                         health_beforedamage = 0;
1324                         armor_beforedamage = 0;
1325                         health_damagetime = 0;
1326                         armor_damagetime = 0;
1327                         prev_health = health;
1328                         prev_armor = armor;
1329                         old_p_health = health;
1330                         old_p_armor = armor;
1331                         prev_p_health = health;
1332                         prev_p_armor = armor;
1333                 }
1334                 else if (prev_health == -1)
1335                 {
1336                         //start the load effect
1337                         health_damagetime = 0;
1338                         armor_damagetime = 0;
1339                         prev_health = 0;
1340                         prev_armor = 0;
1341                 }
1342                 fuel = getstati(STAT_FUEL);
1343         }
1344         else
1345         {
1346                 health = 150;
1347                 armor = 75;
1348                 fuel = 20;
1349         }
1350
1351         HUD_Panel_UpdateCvars();
1352         vector pos, mySize;
1353         pos = panel_pos;
1354         mySize = panel_size;
1355
1356         HUD_Panel_DrawBg(1);
1357         if(panel_bg_padding)
1358         {
1359                 pos += '1 1 0' * panel_bg_padding;
1360                 mySize -= '2 2 0' * panel_bg_padding;
1361         }
1362
1363         float baralign = autocvar_hud_panel_healtharmor_baralign;
1364         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1365
1366     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1367     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1368         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1369         {
1370                 vector v;
1371                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1372
1373                 float x;
1374                 x = floor(v_x + 1);
1375
1376         float maxtotal = maxhealth + maxarmor;
1377                 string biggercount;
1378                 if(v_z) // NOT fully armored
1379                 {
1380                         biggercount = "health";
1381                         if(autocvar_hud_panel_healtharmor_progressbar)
1382                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1383                         if(armor)
1384             if(autocvar_hud_panel_healtharmor_text)
1385                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1386                 }
1387                 else
1388                 {
1389                         biggercount = "armor";
1390                         if(autocvar_hud_panel_healtharmor_progressbar)
1391                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1392                         if(health)
1393             if(autocvar_hud_panel_healtharmor_text)
1394                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1395                 }
1396         if(autocvar_hud_panel_healtharmor_text)
1397                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1398
1399                 if(fuel)
1400                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1401         }
1402         else
1403         {
1404                 float panel_ar = mySize_x/mySize_y;
1405                 float is_vertical = (panel_ar < 1);
1406                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1407                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1408                 {
1409                         mySize_x *= 0.5;
1410                         if (autocvar_hud_panel_healtharmor_flip)
1411                                 health_offset_x = mySize_x;
1412                         else
1413                                 armor_offset_x = mySize_x;
1414                 }
1415                 else
1416                 {
1417                         mySize_y *= 0.5;
1418                         if (autocvar_hud_panel_healtharmor_flip)
1419                                 health_offset_y = mySize_y;
1420                         else
1421                                 armor_offset_y = mySize_y;
1422                 }
1423
1424                 float health_baralign, armor_baralign, fuel_baralign;
1425                 float health_iconalign, armor_iconalign;
1426                 if (autocvar_hud_panel_healtharmor_flip)
1427                 {
1428                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1429                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1430                         fuel_baralign = health_baralign;
1431                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1432                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1433                 }
1434                 else
1435                 {
1436                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1437                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1438                         fuel_baralign = armor_baralign;
1439                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1440                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1441                 }
1442
1443                 //if(health)
1444                 {
1445                         if(autocvar_hud_panel_healtharmor_progressbar)
1446                         {
1447                                 float p_health, pain_health_alpha;
1448                                 p_health = health;
1449                                 pain_health_alpha = 1;
1450                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1451                                 {
1452                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1453                                         {
1454                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1455                                                 {
1456                                                         if (time - old_p_healthtime < 1)
1457                                                                 old_p_health = prev_p_health;
1458                                                         else
1459                                                                 old_p_health = prev_health;
1460                                                         old_p_healthtime = time;
1461                                                 }
1462                                                 if (time - old_p_healthtime < 1)
1463                                                 {
1464                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1465                                                         prev_p_health = p_health;
1466                                                 }
1467                                         }
1468                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1469                                         {
1470                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1471                                                 {
1472                                                         if (time - health_damagetime >= 1)
1473                                                                 health_beforedamage = prev_health;
1474                                                         health_damagetime = time;
1475                                                 }
1476                                                 if (time - health_damagetime < 1)
1477                                                 {
1478                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1479                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1480                                                 }
1481                                         }
1482                                         prev_health = health;
1483
1484                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1485                                         {
1486                                                 float BLINK_FACTOR = 0.15;
1487                                                 float BLINK_BASE = 0.85;
1488                                                 float BLINK_FREQ = 9;
1489                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1490                                         }
1491                                 }
1492                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1493                         }
1494                         if(autocvar_hud_panel_healtharmor_text)
1495                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1496                 }
1497
1498                 if(armor)
1499                 {
1500                         if(autocvar_hud_panel_healtharmor_progressbar)
1501                         {
1502                                 float p_armor;
1503                                 p_armor = armor;
1504                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1505                                 {
1506                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1507                                         {
1508                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1509                                                 {
1510                                                         if (time - old_p_armortime < 1)
1511                                                                 old_p_armor = prev_p_armor;
1512                                                         else
1513                                                                 old_p_armor = prev_armor;
1514                                                         old_p_armortime = time;
1515                                                 }
1516                                                 if (time - old_p_armortime < 1)
1517                                                 {
1518                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1519                                                         prev_p_armor = p_armor;
1520                                                 }
1521                                         }
1522                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1523                                         {
1524                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1525                                                 {
1526                                                         if (time - armor_damagetime >= 1)
1527                                                                 armor_beforedamage = prev_armor;
1528                                                         armor_damagetime = time;
1529                                                 }
1530                                                 if (time - armor_damagetime < 1)
1531                                                 {
1532                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1533                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1534                                                 }
1535                                         }
1536                                         prev_armor = armor;
1537                                 }
1538                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1539                         }
1540                         if(autocvar_hud_panel_healtharmor_text)
1541                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1542                 }
1543
1544                 if(fuel)
1545                 {
1546                         if (is_vertical)
1547                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1548                         else
1549                                 mySize_y *= 0.2;
1550                         if (panel_ar >= 4)
1551                                 mySize_x *= 2; //restore full panel size
1552                         else if (panel_ar < 1/4)
1553                                 mySize_y *= 2; //restore full panel size
1554                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1555                 }
1556         }
1557 }
1558
1559 // Notification area (#4)
1560 //
1561
1562 void HUD_Notify_Push(string icon, string attacker, string victim)
1563 {
1564         if (icon == "")
1565                 return;
1566
1567         ++notify_count;
1568         --notify_index;
1569
1570         if (notify_index == -1)
1571                 notify_index = NOTIFY_MAX_ENTRIES-1;
1572
1573         // Free old strings
1574         if (notify_attackers[notify_index])
1575                 strunzone(notify_attackers[notify_index]);
1576
1577         if (notify_victims[notify_index])
1578                 strunzone(notify_victims[notify_index]);
1579
1580         if (notify_icons[notify_index])
1581                 strunzone(notify_icons[notify_index]);
1582
1583         // Allocate new strings
1584         if (victim != "")
1585         {
1586                 notify_attackers[notify_index] = strzone(attacker);
1587                 notify_victims[notify_index] = strzone(victim);
1588         }
1589         else
1590         {
1591                 // In case of a notification without a victim, the attacker
1592                 // is displayed on the victim's side. Instead of special
1593                 // treatment later on, we can simply switch them here.
1594                 notify_attackers[notify_index] = string_null;
1595                 notify_victims[notify_index] = strzone(attacker);
1596         }
1597
1598         notify_icons[notify_index] = strzone(icon);
1599         notify_times[notify_index] = time;
1600 }
1601
1602 void HUD_Notify(void)
1603 {
1604         if (!autocvar__hud_configure)
1605                 if (!autocvar_hud_panel_notify)
1606                         return;
1607
1608         HUD_Panel_UpdateCvars();
1609         HUD_Panel_DrawBg(1);
1610
1611         if (!autocvar__hud_configure)
1612                 if (notify_count == 0)
1613                         return;
1614
1615         vector pos, size;
1616         pos  = panel_pos;
1617         size = panel_size;
1618
1619         if (panel_bg_padding)
1620         {
1621                 pos  += '1 1 0' * panel_bg_padding;
1622                 size -= '2 2 0' * panel_bg_padding;
1623         }
1624
1625         float fade_start = max(0, autocvar_hud_panel_notify_time);
1626         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1627         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1628
1629         float entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size_y / size_x), NOTIFY_MAX_ENTRIES);
1630         float entry_height = size_y / entry_count;
1631
1632         float panel_width_half = size_x * 0.5;
1633         float icon_width_half = entry_height * icon_aspect / 2;
1634         float name_maxwidth = panel_width_half - icon_width_half - size_x * NOTIFY_ICON_MARGIN;
1635
1636         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1637         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1638         vector icon_left = eX * (panel_width_half - icon_width_half);
1639         vector attacker_right = eX * name_maxwidth;
1640         vector victim_left = eX * (size_x - name_maxwidth);
1641
1642         vector attacker_pos, victim_pos, icon_pos;
1643         string attacker, victim, icon;
1644         float i, j, count, step, limit, alpha;
1645
1646         if (autocvar_hud_panel_notify_flip)
1647         {
1648                 // Order items from the top down
1649                 i = 0;
1650                 step = +1;
1651                 limit = entry_count;
1652         }
1653         else
1654         {
1655                 // Order items from the bottom up
1656                 i = entry_count - 1;
1657                 step = -1;
1658                 limit = -1;
1659         }
1660
1661         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1662         {
1663                 if(autocvar__hud_configure)
1664                 {
1665                         attacker = sprintf(_("Player %d"), count + 1);
1666                         victim = sprintf(_("Player %d"), count + 2);
1667                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1668                         alpha = bound(0, 1.2 - count / entry_count, 1);
1669                 }
1670                 else
1671                 {
1672                         if (j == NOTIFY_MAX_ENTRIES)
1673                                 j = 0;
1674
1675                         if (notify_times[j] + fade_start > time)
1676                                 alpha = 1;
1677                         else if (fade_time != 0)
1678                         {
1679                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1680                                 if (alpha == 0)
1681                                         break;
1682                         }
1683                         else
1684                                 break;
1685
1686                         attacker = notify_attackers[j];
1687                         victim = notify_victims[j];
1688                         icon = notify_icons[j];
1689                 }
1690
1691                 if (icon != "" && victim != "")
1692                 {
1693                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size_y));
1694
1695                         icon_pos = pos + icon_left + eY * i * entry_height;
1696                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1697
1698                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1699                         victim_pos = pos + victim_left + name_top;
1700                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1701
1702                         if (attacker != "")
1703                         {
1704                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1705                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, TRUE, font_size) + name_top;
1706                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1707                         }
1708                 }
1709         }
1710
1711         notify_count = count;
1712 }
1713
1714 // Timer (#5)
1715 //
1716 // TODO: macro
1717 string seconds_tostring(float sec)
1718 {
1719         float minutes;
1720         minutes = floor(sec / 60);
1721
1722         sec -= minutes * 60;
1723         return sprintf("%d:%02d", minutes, sec);
1724 }
1725
1726 void HUD_Timer(void)
1727 {
1728         if(!autocvar__hud_configure)
1729         {
1730                 if(!autocvar_hud_panel_timer) return;
1731         }
1732
1733         HUD_Panel_UpdateCvars();
1734
1735         draw_beginBoldFont();
1736
1737         vector pos, mySize;
1738         pos = panel_pos;
1739         mySize = panel_size;
1740
1741         HUD_Panel_DrawBg(1);
1742         if(panel_bg_padding)
1743         {
1744                 pos += '1 1 0' * panel_bg_padding;
1745                 mySize -= '2 2 0' * panel_bg_padding;
1746         }
1747
1748         string timer;
1749         float timelimit, elapsedTime, timeleft, minutesLeft;
1750
1751         timelimit = getstatf(STAT_TIMELIMIT);
1752
1753         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1754         timeleft = ceil(timeleft);
1755
1756         minutesLeft = floor(timeleft / 60);
1757
1758         vector timer_color;
1759         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1760                 timer_color = '1 1 1'; //white
1761         else if(minutesLeft >= 1)
1762                 timer_color = '1 1 0'; //yellow
1763         else
1764                 timer_color = '1 0 0'; //red
1765
1766         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1767                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1768                         //while restart is still active, show 00:00
1769                         timer = seconds_tostring(0);
1770                 } else {
1771                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1772                         timer = seconds_tostring(elapsedTime);
1773                 }
1774         } else {
1775                 timer = seconds_tostring(timeleft);
1776         }
1777
1778         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1779
1780         draw_endBoldFont();
1781 }
1782
1783 // Radar (#6)
1784 //
1785 void HUD_Radar(void)
1786 {
1787         if (!autocvar__hud_configure)
1788         {
1789                 if (hud_panel_radar_maximized)
1790                 {
1791                         if (!hud_draw_maximized) return;
1792                 }
1793                 else
1794                 {
1795                         if (autocvar_hud_panel_radar == 0) return;
1796                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1797                         if(radar_panel_modified)
1798                         {
1799                                 panel.update_time = time; // forces reload of panel attributes
1800                                 radar_panel_modified = false;
1801                         }
1802                 }
1803         }
1804
1805         HUD_Panel_UpdateCvars();
1806
1807         float f = 0;
1808
1809         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1810         {
1811                 panel_size = autocvar_hud_panel_radar_maximized_size;
1812                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1813                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1814                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1815                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1816
1817                 string panel_bg;
1818                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1819                 if(precache_pic(panel_bg) == "")
1820                         panel_bg = "gfx/hud/default/border_default"; // fallback
1821                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
1822                         radar_panel_modified = true;
1823                 if(panel.current_panel_bg)
1824                         strunzone(panel.current_panel_bg);
1825                 panel.current_panel_bg = strzone(panel_bg);
1826
1827                 switch(hud_panel_radar_maximized_zoommode)
1828                 {
1829                         default:
1830                         case 0:
1831                                 f = current_zoomfraction;
1832                                 break;
1833                         case 1:
1834                                 f = 1 - current_zoomfraction;
1835                                 break;
1836                         case 2:
1837                                 f = 0;
1838                                 break;
1839                         case 3:
1840                                 f = 1;
1841                                 break;
1842                 }
1843
1844                 switch(hud_panel_radar_maximized_rotation)
1845                 {
1846                         case 0:
1847                                 teamradar_angle = view_angles_y - 90;
1848                                 break;
1849                         default:
1850                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1851                                 break;
1852                 }
1853         }
1854         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1855         {
1856                 switch(hud_panel_radar_zoommode)
1857                 {
1858                         default:
1859                         case 0:
1860                                 f = current_zoomfraction;
1861                                 break;
1862                         case 1:
1863                                 f = 1 - current_zoomfraction;
1864                                 break;
1865                         case 2:
1866                                 f = 0;
1867                                 break;
1868                         case 3:
1869                                 f = 1;
1870                                 break;
1871                 }
1872
1873                 switch(hud_panel_radar_rotation)
1874                 {
1875                         case 0:
1876                                 teamradar_angle = view_angles_y - 90;
1877                                 break;
1878                         default:
1879                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1880                                 break;
1881                 }
1882         }
1883
1884         vector pos, mySize;
1885         pos = panel_pos;
1886         mySize = panel_size;
1887
1888         HUD_Panel_DrawBg(1);
1889         if(panel_bg_padding)
1890         {
1891                 pos += '1 1 0' * panel_bg_padding;
1892                 mySize -= '2 2 0' * panel_bg_padding;
1893         }
1894
1895         float color2;
1896         entity tm;
1897         float scale2d, normalsize, bigsize;
1898
1899         teamradar_origin2d = pos + 0.5 * mySize;
1900         teamradar_size2d = mySize;
1901
1902         if(minimapname == "")
1903                 return;
1904
1905         teamradar_loadcvars();
1906
1907         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1908         teamradar_size2d = mySize;
1909
1910         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1911
1912         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1913         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1914         {
1915                 // max-min distance must fit the radar in any rotation
1916                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1917         }
1918         else
1919         {
1920                 vector c0, c1, c2, c3, span;
1921                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1922                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1923                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1924                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1925                 span = '0 0 0';
1926                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1927                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1928
1929                 // max-min distance must fit the radar in x=x, y=y
1930                 bigsize = min(
1931                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1932                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1933                 );
1934         }
1935
1936         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1937         if(bigsize > normalsize)
1938                 normalsize = bigsize;
1939
1940         teamradar_size =
1941                   f * bigsize
1942                 + (1 - f) * normalsize;
1943         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
1944                   f * mi_center
1945                 + (1 - f) * view_origin);
1946
1947         drawsetcliparea(
1948                 pos_x,
1949                 pos_y,
1950                 mySize_x,
1951                 mySize_y
1952         );
1953
1954         draw_teamradar_background(hud_panel_radar_foreground_alpha);
1955
1956         for(tm = world; (tm = find(tm, classname, "radarlink")); )
1957                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
1958         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
1959                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
1960         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
1961         {
1962                 color2 = GetPlayerColor(tm.sv_entnum);
1963                 //if(color == NUM_SPECTATOR || color == color2)
1964                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
1965         }
1966         draw_teamradar_player(view_origin, view_angles, '1 1 1');
1967
1968         drawresetcliparea();
1969 }
1970
1971 // Score (#7)
1972 //
1973 void HUD_UpdatePlayerTeams();
1974 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
1975 {
1976         float score;
1977         entity tm = world, pl;
1978 #define SCOREPANEL_MAX_ENTRIES 6
1979 #define SCOREPANEL_ASPECTRATIO 2
1980         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
1981         vector fontsize = '1 1 0' * (mySize_y/entries);
1982
1983         vector rgb, score_color;
1984         rgb = '1 1 1';
1985         score_color = '1 1 1';
1986
1987         float name_size = mySize_x*0.75;
1988         float spacing_size = mySize_x*0.04;
1989         const float highlight_alpha = 0.2;
1990         float i = 0, me_printed = 0, first_pl = 0;
1991         string s;
1992         if (autocvar__hud_configure)
1993         {
1994                 float players_per_team = 0;
1995                 if (team_count)
1996                 {
1997                         // show team scores in the first line
1998                         float score_size = mySize_x / team_count;
1999                         players_per_team = max(2, ceil((entries - 1) / team_count));
2000                         for(i=0; i<team_count; ++i) {
2001                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2002                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2003                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2004                         }
2005                         first_pl = 1;
2006                         pos_y += fontsize_y;
2007                 }
2008                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2009                 for (i=first_pl; i<entries; ++i)
2010                 {
2011                         //simulate my score is lower than all displayed players,
2012                         //so that I don't appear at all showing pure rankings.
2013                         //This is to better show the difference between the 2 ranking views
2014                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2015                         {
2016                                 rgb = '1 1 0';
2017                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2018                                 s = GetPlayerName(player_localnum);
2019                                 score = 7;
2020                         }
2021                         else
2022                         {
2023                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2024                                 score -= 3;
2025                         }
2026
2027                         if (team_count)
2028                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2029                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2030                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2031                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2032                         pos_y += fontsize_y;
2033                 }
2034                 return;
2035         }
2036
2037         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2038                 HUD_UpdatePlayerTeams();
2039         if (team_count)
2040         {
2041                 // show team scores in the first line
2042                 float score_size = mySize_x / team_count;
2043                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2044                         if(tm.team == NUM_SPECTATOR)
2045                                 continue;
2046                         if (tm.team == myteam)
2047                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2048                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2049                         ++i;
2050                 }
2051                 first_pl = 1;
2052                 pos_y += fontsize_y;
2053                 tm = teams.sort_next;
2054         }
2055         i = first_pl;
2056
2057         do
2058         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2059         {
2060                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2061                         continue;
2062
2063                 if (i == entries-1 && !me_printed && pl != me)
2064                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2065                 {
2066                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2067                                 if (pl.team != NUM_SPECTATOR)
2068                                         break;
2069
2070                         if (pl)
2071                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2072                         else
2073                                 rgb = '1 0 0'; //last: red
2074                         pl = me;
2075                 }
2076
2077                 if (pl == me)
2078                 {
2079                         if (i == first_pl)
2080                                 rgb = '0 1 0'; //first: green
2081                         me_printed = 1;
2082                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2083                 }
2084                 if (team_count)
2085                         score_color = Team_ColorRGB(pl.team) * 0.8;
2086                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2087                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2088                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2089                 pos_y += fontsize_y;
2090                 ++i;
2091         }
2092         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2093 }
2094
2095 void HUD_Score(void)
2096 {
2097         if(!autocvar__hud_configure)
2098         {
2099                 if(!autocvar_hud_panel_score) return;
2100                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2101         }
2102
2103         HUD_Panel_UpdateCvars();
2104         vector pos, mySize;
2105         pos = panel_pos;
2106         mySize = panel_size;
2107
2108         HUD_Panel_DrawBg(1);
2109         if(panel_bg_padding)
2110         {
2111                 pos += '1 1 0' * panel_bg_padding;
2112                 mySize -= '2 2 0' * panel_bg_padding;
2113         }
2114
2115         float score, distribution = 0;
2116         string sign;
2117         vector distribution_color;
2118         entity tm, pl, me;
2119
2120 #ifdef COMPAT_XON050_ENGINE
2121         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2122 #else
2123         me = playerslots[player_localentnum - 1];
2124 #endif
2125
2126         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2127                 string timer, distrtimer;
2128
2129                 pl = players.sort_next;
2130                 if(pl == me)
2131                         pl = pl.sort_next;
2132                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2133                         if(pl.scores[ps_primary] == 0)
2134                                 pl = world;
2135
2136                 score = me.(scores[ps_primary]);
2137                 timer = TIME_ENCODED_TOSTRING(score);
2138
2139                 draw_beginBoldFont();
2140                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2141                         // distribution display
2142                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2143
2144                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2145
2146                         if (distribution <= 0) {
2147                                 distribution_color = '0 1 0';
2148                                 sign = "-";
2149                         }
2150                         else {
2151                                 distribution_color = '1 0 0';
2152                                 sign = "+";
2153                         }
2154                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2155                 }
2156                 // race record display
2157                 if (distribution <= 0)
2158                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2159                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2160                 draw_endBoldFont();
2161         } else if (!teamplay) { // non-teamgames
2162                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2163                 {
2164                         HUD_Score_Rankings(pos, mySize, me);
2165                         return;
2166                 }
2167                 // me vector := [team/connected frags id]
2168                 pl = players.sort_next;
2169                 if(pl == me)
2170                         pl = pl.sort_next;
2171
2172                 if(autocvar__hud_configure)
2173                         distribution = 42;
2174                 else if(pl)
2175                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2176                 else
2177                         distribution = 0;
2178
2179                 score = me.(scores[ps_primary]);
2180                 if(autocvar__hud_configure)
2181                         score = 123;
2182
2183                 if(distribution >= 5)
2184                         distribution_color = eY;
2185                 else if(distribution >= 0)
2186                         distribution_color = '1 1 1';
2187                 else if(distribution >= -5)
2188                         distribution_color = '1 1 0';
2189                 else
2190                         distribution_color = eX;
2191
2192                 string distribution_str;
2193                 distribution_str = ftos(distribution);
2194                 draw_beginBoldFont();
2195                 if (distribution >= 0)
2196                 {
2197                         if (distribution > 0)
2198                                 distribution_str = strcat("+", distribution_str);
2199                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2200                 }
2201                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2202                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2203                 draw_endBoldFont();
2204         } else { // teamgames
2205                 float row, column, rows = 0, columns = 0;
2206                 local noref vector offset = '0 0 0';
2207                 vector score_pos, score_size; //for scores other than myteam
2208                 if(autocvar_hud_panel_score_rankings)
2209                 {
2210                         HUD_Score_Rankings(pos, mySize, me);
2211                         return;
2212                 }
2213                 if(spectatee_status == -1)
2214                 {
2215                         rows = mySize_y/mySize_x;
2216                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * team_count + rows * rows) + rows + 0.5) / 2), team_count);
2217                         //                               ^^^ ammo item aspect goes here
2218
2219                         columns = ceil(team_count/rows);
2220
2221                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2222
2223                         float newSize;
2224                         if(score_size_x/score_size_y > 3)
2225                         {
2226                                 newSize = 3 * score_size_y;
2227                                 offset_x = score_size_x - newSize;
2228                                 pos_x += offset_x/2;
2229                                 score_size_x = newSize;
2230                         }
2231                         else
2232                         {
2233                                 newSize = 1/3 * score_size_x;
2234                                 offset_y = score_size_y - newSize;
2235                                 pos_y += offset_y/2;
2236                                 score_size_y = newSize;
2237                         }
2238                 }
2239                 else
2240                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2241
2242                 float max_fragcount;
2243                 max_fragcount = -99;
2244                 draw_beginBoldFont();
2245                 row = column = 0;
2246                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2247                         if(tm.team == NUM_SPECTATOR)
2248                                 continue;
2249                         score = tm.(teamscores[ts_primary]);
2250                         if(autocvar__hud_configure)
2251                                 score = 123;
2252
2253                         if (score > max_fragcount)
2254                                 max_fragcount = score;
2255
2256                         if (spectatee_status == -1)
2257                         {
2258                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2259                                 if (max_fragcount == score)
2260                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2261                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2262                                 ++row;
2263                                 if(row >= rows)
2264                                 {
2265                                         row = 0;
2266                                         ++column;
2267                                 }
2268                         }
2269                         else if(tm.team == myteam) {
2270                                 if (max_fragcount == score)
2271                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2272                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2273                         } else {
2274                                 if (max_fragcount == score)
2275                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2276                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2277                                 ++rows;
2278                         }
2279                 }
2280                 draw_endBoldFont();
2281         }
2282 }
2283
2284 // Race timer (#8)
2285 //
2286 void HUD_RaceTimer (void)
2287 {
2288         if(!autocvar__hud_configure)
2289         {
2290                 if(!autocvar_hud_panel_racetimer) return;
2291                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2292                 if(spectatee_status == -1) return;
2293         }
2294
2295         HUD_Panel_UpdateCvars();
2296
2297         draw_beginBoldFont();
2298
2299         vector pos, mySize;
2300         pos = panel_pos;
2301         mySize = panel_size;
2302
2303         HUD_Panel_DrawBg(1);
2304         if(panel_bg_padding)
2305         {
2306                 pos += '1 1 0' * panel_bg_padding;
2307                 mySize -= '2 2 0' * panel_bg_padding;
2308         }
2309
2310         // always force 4:1 aspect
2311         vector newSize = '0 0 0';
2312         if(mySize_x/mySize_y > 4)
2313         {
2314                 newSize_x = 4 * mySize_y;
2315                 newSize_y = mySize_y;
2316
2317                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2318         }
2319         else
2320         {
2321                 newSize_y = 1/4 * mySize_x;
2322                 newSize_x = mySize_x;
2323
2324                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2325         }
2326         mySize = newSize;
2327
2328         float a, t;
2329         string s, forcetime;
2330
2331         if(autocvar__hud_configure)
2332         {
2333                 s = "0:13:37";
2334                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2335                 s = _("^1Intermediate 1 (+15.42)");
2336                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2337                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2338                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2339         }
2340         else if(race_checkpointtime)
2341         {
2342                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2343                 s = "";
2344                 forcetime = "";
2345                 if(a > 0) // just hit a checkpoint?
2346                 {
2347                         if(race_checkpoint != 254)
2348                         {
2349                                 if(race_time && race_previousbesttime)
2350                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2351                                 else
2352                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2353                                 if(race_time)
2354                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2355                         }
2356                 }
2357                 else
2358                 {
2359                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2360                         {
2361                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2362                                 if(a > 0) // next one?
2363                                 {
2364                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2365                                 }
2366                         }
2367                 }
2368
2369                 if(s != "" && a > 0)
2370                 {
2371                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2372                 }
2373
2374                 if(race_penaltytime)
2375                 {
2376                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2377                         if(a > 0)
2378                         {
2379                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2380                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2381                         }
2382                 }
2383
2384                 if(forcetime != "")
2385                 {
2386                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2387                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2388                 }
2389                 else
2390                         a = 1;
2391
2392                 if(race_laptime && race_checkpoint != 255)
2393                 {
2394                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2395                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2396                 }
2397         }
2398         else
2399         {
2400                 if(race_mycheckpointtime)
2401                 {
2402                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2403                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2404                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2405                 }
2406                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2407                 {
2408                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2409                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2410                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2411                 }
2412
2413                 if(race_penaltytime && !race_penaltyaccumulator)
2414                 {
2415                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2416                         a = bound(0, (1 + t - time), 1);
2417                         if(a > 0)
2418                         {
2419                                 if(time < t)
2420                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2421                                 else
2422                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2423                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2424                         }
2425                 }
2426         }
2427
2428         draw_endBoldFont();
2429 }
2430
2431 // Vote window (#9)
2432 //
2433 float vote_yescount;
2434 float vote_nocount;
2435 float vote_needed;
2436 float vote_highlighted; // currently selected vote
2437
2438 float vote_active; // is there an active vote?
2439 float vote_prev; // previous state of vote_active to check for a change
2440 float vote_alpha;
2441 float vote_change; // "time" when vote_active changed
2442
2443 void HUD_Vote(void)
2444 {
2445         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2446         {
2447                 vote_active = 1;
2448                 if (autocvar__hud_configure)
2449                 {
2450                         vote_yescount = 0;
2451                         vote_nocount = 0;
2452                         print(_("^1You must answer before entering hud configure mode\n"));
2453                         cvar_set("_hud_configure", "0");
2454                 }
2455                 if(vote_called_vote)
2456                         strunzone(vote_called_vote);
2457                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2458                 uid2name_dialog = 1;
2459         }
2460
2461         if(!autocvar__hud_configure)
2462         {
2463                 if(!autocvar_hud_panel_vote) return;
2464
2465                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2466                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2467
2468                 if(panel_bg_alpha_str == "") {
2469                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2470                 }
2471                 panel_bg_alpha = stof(panel_bg_alpha_str);
2472         }
2473         else
2474         {
2475                 vote_yescount = 3;
2476                 vote_nocount = 2;
2477                 vote_needed = 4;
2478         }
2479
2480         string s;
2481         float a;
2482         if(vote_active != vote_prev) {
2483                 vote_change = time;
2484                 vote_prev = vote_active;
2485         }
2486
2487         if(vote_active || autocvar__hud_configure)
2488                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2489         else
2490                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2491
2492         if(!vote_alpha)
2493                 return;
2494
2495         HUD_Panel_UpdateCvars();
2496
2497         if(uid2name_dialog)
2498         {
2499                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2500                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2501         }
2502
2503     // these must be below above block
2504         vector pos, mySize;
2505         pos = panel_pos;
2506         mySize = panel_size;
2507
2508         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2509         HUD_Panel_DrawBg(a);
2510         a = panel_fg_alpha * a;
2511
2512         if(panel_bg_padding)
2513         {
2514                 pos += '1 1 0' * panel_bg_padding;
2515                 mySize -= '2 2 0' * panel_bg_padding;
2516         }
2517
2518         // always force 3:1 aspect
2519         vector newSize = '0 0 0';
2520         if(mySize_x/mySize_y > 3)
2521         {
2522                 newSize_x = 3 * mySize_y;
2523                 newSize_y = mySize_y;
2524
2525                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2526         }
2527         else
2528         {
2529                 newSize_y = 1/3 * mySize_x;
2530                 newSize_x = mySize_x;
2531
2532                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2533         }
2534         mySize = newSize;
2535
2536         s = _("A vote has been called for:");
2537         if(uid2name_dialog)
2538                 s = _("Allow servers to store and display your name?");
2539         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2540         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2541         if(autocvar__hud_configure)
2542                 s = _("^1Configure the HUD");
2543         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2544
2545         // print the yes/no counts
2546     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2547         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2548     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2549         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2550
2551         // draw the progress bar backgrounds
2552         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2553
2554         // draw the highlights
2555         if(vote_highlighted == 1) {
2556                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2557                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2558         }
2559         else if(vote_highlighted == -1) {
2560                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2561                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2562         }
2563
2564         // draw the progress bars
2565         if(vote_yescount && vote_needed)
2566         {
2567                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2568                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2569         }
2570
2571         if(vote_nocount && vote_needed)
2572         {
2573                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2574                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2575         }
2576
2577         drawresetcliparea();
2578 }
2579
2580 // Mod icons panel (#10)
2581 //
2582
2583 float mod_active; // is there any active mod icon?
2584
2585 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2586 {
2587         float stat;
2588         string pic;
2589         vector color;
2590 #ifdef GMQCC
2591         stat = -1;
2592         pic = "";
2593         color = '0 0 0';
2594 #endif
2595         switch(i)
2596         {
2597                 case 0:
2598                         stat = getstati(STAT_REDALIVE);
2599                         pic = "player_red.tga";
2600                         color = '1 0 0';
2601                         break;
2602                 case 1:
2603                         stat = getstati(STAT_BLUEALIVE);
2604                         pic = "player_blue.tga";
2605                         color = '0 0 1';
2606                         break;
2607                 case 2:
2608                         stat = getstati(STAT_YELLOWALIVE);
2609                         pic = "player_yellow.tga";
2610                         color = '1 1 0';
2611                         break;
2612                 default:
2613                 case 3:
2614                         stat = getstati(STAT_PINKALIVE);
2615                         pic = "player_pink.tga";
2616                         color = '1 0 1';
2617                         break;
2618         }
2619
2620         if(mySize_x/mySize_y > aspect_ratio)
2621         {
2622                 i = aspect_ratio * mySize_y;
2623                 myPos_x = myPos_x + (mySize_x - i) / 2;
2624                 mySize_x = i;
2625         }
2626         else
2627         {
2628                 i = 1/aspect_ratio * mySize_x;
2629                 myPos_y = myPos_y + (mySize_y - i) / 2;
2630                 mySize_y = i;
2631         }
2632
2633         if(layout)
2634         {
2635                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2636                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2637         }
2638         else
2639                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2640 }
2641
2642 // Clan Arena and Freeze Tag HUD modicons
2643 void HUD_Mod_CA(vector myPos, vector mySize)
2644 {
2645         mod_active = 1; // required in each mod function that always shows something
2646
2647         float layout;
2648         if(gametype == MAPINFO_TYPE_CA)
2649                 layout = autocvar_hud_panel_modicons_ca_layout;
2650         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2651                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2652         float rows, columns, aspect_ratio;
2653         rows = mySize_y/mySize_x;
2654         aspect_ratio = (layout) ? 2 : 1;
2655         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
2656         columns = ceil(team_count/rows);
2657
2658         int i;
2659         float row = 0, column = 0;
2660         vector pos, itemSize;
2661         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2662         for(i=0; i<team_count; ++i)
2663         {
2664                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2665
2666                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2667
2668                 ++row;
2669                 if(row >= rows)
2670                 {
2671                         row = 0;
2672                         ++column;
2673                 }
2674         }
2675 }
2676
2677 // CTF HUD modicon section
2678 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2679 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2680 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2681
2682 void HUD_Mod_CTF_Reset(void)
2683 {
2684         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2685 }
2686
2687 void HUD_Mod_CTF(vector pos, vector mySize)
2688 {
2689         vector redflag_pos, blueflag_pos;
2690         vector flag_size;
2691         float f; // every function should have that
2692
2693         float redflag, blueflag; // current status
2694         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2695         float stat_items;
2696
2697         stat_items = getstati(STAT_ITEMS, 0, 24);
2698         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2699         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2700
2701         if(redflag || blueflag)
2702                 mod_active = 1;
2703         else
2704                 mod_active = 0;
2705
2706         if(autocvar__hud_configure)
2707         {
2708                 redflag = 1;
2709                 blueflag = 2;
2710         }
2711
2712         // when status CHANGES, set old status into prevstatus and current status into status
2713         if (redflag != redflag_prevframe)
2714         {
2715                 redflag_statuschange_time = time;
2716                 redflag_prevstatus = redflag_prevframe;
2717                 redflag_prevframe = redflag;
2718         }
2719
2720         if (blueflag != blueflag_prevframe)
2721         {
2722                 blueflag_statuschange_time = time;
2723                 blueflag_prevstatus = blueflag_prevframe;
2724                 blueflag_prevframe = blueflag;
2725         }
2726
2727         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2728         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2729
2730         float BLINK_FACTOR = 0.15;
2731         float BLINK_BASE = 0.85;
2732         // note:
2733         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2734         // thus
2735         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2736         // ensure RMS == 1
2737         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2738
2739         string red_icon, red_icon_prevstatus;
2740         float red_alpha, red_alpha_prevstatus;
2741         red_alpha = red_alpha_prevstatus = 1;
2742         switch(redflag) {
2743                 case 1: red_icon = "flag_red_taken"; break;
2744                 case 2: red_icon = "flag_red_lost"; break;
2745                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2746                 default:
2747                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2748                                 red_icon = "flag_red_shielded";
2749                         else
2750                                 red_icon = string_null;
2751                         break;
2752         }
2753         switch(redflag_prevstatus) {
2754                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2755                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2756                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2757                 default:
2758                         if(redflag == 3)
2759                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2760                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2761                                 red_icon_prevstatus = "flag_red_shielded";
2762                         else
2763                                 red_icon_prevstatus = string_null;
2764                         break;
2765         }
2766
2767         string blue_icon, blue_icon_prevstatus;
2768         float blue_alpha, blue_alpha_prevstatus;
2769         blue_alpha = blue_alpha_prevstatus = 1;
2770         switch(blueflag) {
2771                 case 1: blue_icon = "flag_blue_taken"; break;
2772                 case 2: blue_icon = "flag_blue_lost"; break;
2773                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2774                 default:
2775                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2776                                 blue_icon = "flag_blue_shielded";
2777                         else
2778                                 blue_icon = string_null;
2779                         break;
2780         }
2781         switch(blueflag_prevstatus) {
2782                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2783                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2784                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2785                 default:
2786                         if(blueflag == 3)
2787                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2788                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2789                                 blue_icon_prevstatus = "flag_blue_shielded";
2790                         else
2791                                 blue_icon_prevstatus = string_null;
2792                         break;
2793         }
2794
2795         if(mySize_x > mySize_y) {
2796                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2797                         redflag_pos = pos;
2798                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2799                 } else {
2800                         blueflag_pos = pos;
2801                         redflag_pos = pos + eX * 0.5 * mySize_x;
2802                 }
2803                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2804         } else {
2805                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2806                         redflag_pos = pos;
2807                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2808                 } else {
2809                         blueflag_pos = pos;
2810                         redflag_pos = pos + eY * 0.5 * mySize_y;
2811                 }
2812                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2813         }
2814
2815         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2816         if(red_icon_prevstatus && f < 1)
2817                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2818         if(red_icon)
2819                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2820
2821         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2822         if(blue_icon_prevstatus && f < 1)
2823                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2824         if(blue_icon)
2825                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2826 }
2827
2828 // Keyhunt HUD modicon section
2829 float kh_runheretime;
2830
2831 void HUD_Mod_KH_Reset(void)
2832 {
2833         kh_runheretime = 0;
2834 }
2835
2836 void HUD_Mod_KH(vector pos, vector mySize)
2837 {
2838         mod_active = 1; // keyhunt should never hide the mod icons panel
2839         float kh_keys;
2840         float keyteam;
2841         float a, aa;
2842         vector p = '0 0 0', pa, kh_size = '0 0 0', kh_asize = '0 0 0';
2843
2844         kh_keys = getstati(STAT_KH_KEYS);
2845
2846         p_x = pos_x;
2847         if(mySize_x > mySize_y)
2848         {
2849                 p_y = pos_y + 0.25 * mySize_y;
2850                 pa = p - eY * 0.25 * mySize_y;
2851
2852                 kh_size_x = mySize_x * 0.25;
2853                 kh_size_y = 0.75 * mySize_y;
2854                 kh_asize_x = mySize_x * 0.25;
2855                 kh_asize_y = mySize_y * 0.25;
2856         }
2857         else
2858         {
2859                 p_y = pos_y + 0.125 * mySize_y;
2860                 pa = p - eY * 0.125 * mySize_y;
2861
2862                 kh_size_x = mySize_x * 0.5;
2863                 kh_size_y = 0.375 * mySize_y;
2864                 kh_asize_x = mySize_x * 0.5;
2865                 kh_asize_y = mySize_y * 0.125;
2866         }
2867
2868         float i, key;
2869
2870         float keycount;
2871         keycount = 0;
2872         for(i = 0; i < 4; ++i)
2873         {
2874                 key = floor(kh_keys / pow(32, i)) & 31;
2875                 keyteam = key - 1;
2876                 if(keyteam == 30 && keycount <= 4)
2877                         keycount += 4;
2878                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2879                         keycount += 1;