8463117dfd4c7c6f58ed9c5745e343c04573b968
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / hud.qc
1 #include "scoreboard.qh"
2 #include "teamradar.qh"
3 #include "../common/buffs.qh"
4 #include "../common/counting.qh"
5 #include "../common/mapinfo.qh"
6 #include "../common/nades.qh"
7 #include "../server/t_items.qh"
8
9 /*
10 ==================
11 Misc HUD functions
12 ==================
13 */
14
15 // a border picture is a texture containing nine parts:
16 //   1/4 width: left part
17 //   1/2 width: middle part (stretched)
18 //   1/4 width: right part
19 // divided into
20 //   1/4 height: top part
21 //   1/2 height: middle part (stretched)
22 //   1/4 height: bottom part
23 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
24 {
25     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
26     {
27                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
28                 return;
29     }
30         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
31         {
32                 // draw only the central part
33                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
34                 return;
35         }
36
37         vector dX, dY;
38         vector width, height;
39         vector bW, bH;
40         //pic = draw_UseSkinFor(pic);
41         width = eX * theSize.x;
42         height = eY * theSize.y;
43         if(theSize.x <= theBorderSize.x * 2)
44         {
45                 // not wide enough... draw just left and right then
46                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
47                 if(theSize.y <= theBorderSize.y * 2)
48                 {
49                         // not high enough... draw just corners
50                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
51                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
52                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
53                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
54                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
55                 }
56                 else
57                 {
58                         dY = theBorderSize.x * eY;
59                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
60                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
61                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
62                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
63                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
64                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
65                 }
66         }
67         else
68         {
69                 if(theSize.y <= theBorderSize.y * 2)
70                 {
71                         // not high enough... draw just top and bottom then
72                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
73                         dX = theBorderSize.x * eX;
74                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
75                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
76                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
77                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
78                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
79                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
80                 }
81                 else
82                 {
83                         dX = theBorderSize.x * eX;
84                         dY = theBorderSize.x * eY;
85                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
86                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
87                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
88                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
89                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
90                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
91                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
92                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
93                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
94                 }
95         }
96 }
97
98 vector HUD_Get_Num_Color (float x, float maxvalue)
99 {
100         float blinkingamt;
101         vector color;
102         if(x >= maxvalue) {
103                 color.x = sin(2*M_PI*time);
104                 color.y = 1;
105                 color.z = sin(2*M_PI*time);
106         }
107         else if(x > maxvalue * 0.75) {
108                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
109                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
110                 color.z = 0;
111         }
112         else if(x > maxvalue * 0.5) {
113                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
114                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
115                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
116         }
117         else if(x > maxvalue * 0.25) {
118                 color.x = 1;
119                 color.y = 1;
120                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
121         }
122         else if(x > maxvalue * 0.1) {
123                 color.x = 1;
124                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
125                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
126         }
127         else {
128                 color.x = 1;
129                 color.y = 0;
130                 color.z = 0;
131         }
132
133         blinkingamt = (1 - x/maxvalue/0.25);
134         if(blinkingamt > 0)
135         {
136                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
137                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
138                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
139         }
140         return color;
141 }
142
143 float HUD_GetRowCount(float item_count, vector size, float item_aspect)
144 {
145         float aspect = size_y / size_x;
146         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
147 }
148
149 vector HUD_GetTableSize(float item_count, vector psize, float item_aspect)
150 {
151         float columns, rows;
152         float ratio, best_ratio = 0;
153         float best_columns = 1, best_rows = 1;
154         bool vertical = (psize.x / psize.y >= item_aspect);
155         if(vertical)
156         {
157                 psize = eX * psize.y + eY * psize.x;
158                 item_aspect = 1 / item_aspect;
159         }
160
161         rows = ceil(sqrt(item_count));
162         columns = ceil(item_count/rows);
163         while(columns >= 1)
164         {
165                 ratio = (psize.x/columns) / (psize.y/rows);
166                 if(ratio > item_aspect)
167                         ratio = item_aspect * item_aspect / ratio;
168
169                 if(ratio <= best_ratio)
170                         break; // ratio starts decreasing by now, skip next configurations
171
172                 best_columns = columns;
173                 best_rows = rows;
174                 best_ratio = ratio;
175
176                 if(columns == 1)
177                         break;
178
179                 --columns;
180                 rows = ceil(item_count/columns);
181         }
182
183         if(vertical)
184                 return eX * best_rows + eY * best_columns;
185         else
186                 return eX * best_columns + eY * best_rows;
187 }
188
189 float stringwidth_colors(string s, vector theSize)
190 {
191         return stringwidth(s, true, theSize);
192 }
193
194 float stringwidth_nocolors(string s, vector theSize)
195 {
196         return stringwidth(s, false, theSize);
197 }
198
199 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
200 {
201         position.x -= 2 / 3 * strlen(text) * theScale.x;
202         drawstring(position, text, theScale, rgb, theAlpha, flag);
203 }
204
205 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
206 {
207         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
208         drawstring(position, text, theScale, rgb, theAlpha, flag);
209 }
210
211 // return the string of the onscreen race timer
212 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
213 {
214         string col;
215         string timestr;
216         string cpname;
217         string lapstr;
218         lapstr = "";
219
220         if(histime == 0) // goal hit
221         {
222                 if(mytime > 0)
223                 {
224                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
225                         col = "^1";
226                 }
227                 else if(mytime == 0)
228                 {
229                         timestr = "+0.0";
230                         col = "^3";
231                 }
232                 else
233                 {
234                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
235                         col = "^2";
236                 }
237
238                 if(lapdelta > 0)
239                 {
240                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
241                         col = "^2";
242                 }
243                 else if(lapdelta < 0)
244                 {
245                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
246                         col = "^1";
247                 }
248         }
249         else if(histime > 0) // anticipation
250         {
251                 if(mytime >= histime)
252                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
253                 else
254                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
255                 col = "^3";
256         }
257         else
258         {
259                 col = "^7";
260                 timestr = "";
261         }
262
263         if(cp == 254)
264                 cpname = _("Start line");
265         else if(cp == 255)
266                 cpname = _("Finish line");
267         else if(cp)
268                 cpname = sprintf(_("Intermediate %d"), cp);
269         else
270                 cpname = _("Finish line");
271
272         if(histime < 0)
273                 return strcat(col, cpname);
274         else if(hisname == "")
275                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
276         else
277                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(hisname, col, lapstr)));
278 }
279
280 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
281 float race_CheckName(string net_name) {
282         float i;
283         for (i=RANKINGS_CNT-1;i>=0;--i)
284                 if(grecordholder[i] == net_name)
285                         return i+1;
286         return 0;
287 }
288
289 float GetPlayerColorForce(int i)
290 {
291         if(!teamplay)
292                 return 0;
293         else
294                 return stof(getplayerkeyvalue(i, "colors")) & 15;
295 }
296
297 float GetPlayerColor(int i)
298 {
299         if(!playerslots[i].gotscores) // unconnected
300                 return NUM_SPECTATOR;
301         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
302                 return NUM_SPECTATOR;
303         else
304                 return GetPlayerColorForce(i);
305 }
306
307 string GetPlayerName(int i)
308 {
309         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
310 }
311
312
313 /*
314 ==================
315 HUD panels
316 ==================
317 */
318
319 // draw the background/borders
320 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
321         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
322                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
323 } while(0)
324
325 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
326 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
327 {
328         if(!length_ratio || !theAlpha)
329                 return;
330         if(length_ratio > 1)
331                 length_ratio = 1;
332         if (baralign == 3)
333         {
334                 if(length_ratio < -1)
335                         length_ratio = -1;
336         }
337         else if(length_ratio < 0)
338                 return;
339
340         vector square;
341         vector width, height;
342         if(vertical) {
343                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
344                 if(precache_pic(pic) == "") {
345                         pic = "gfx/hud/default/progressbar_vertical";
346                 }
347
348         if (baralign == 1) // bottom align
349                         theOrigin.y += (1 - length_ratio) * theSize.y;
350         else if (baralign == 2) // center align
351             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
352         else if (baralign == 3) // center align, positive values down, negative up
353                 {
354                         theSize.y *= 0.5;
355                         if (length_ratio > 0)
356                                 theOrigin.y += theSize.y;
357                         else
358                         {
359                                 theOrigin.y += (1 + length_ratio) * theSize.y;
360                                 length_ratio = -length_ratio;
361                         }
362                 }
363                 theSize.y *= length_ratio;
364
365                 vector bH;
366                 width = eX * theSize.x;
367                 height = eY * theSize.y;
368                 if(theSize.y <= theSize.x * 2)
369                 {
370                         // button not high enough
371                         // draw just upper and lower part then
372                         square = eY * theSize.y * 0.5;
373                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
374                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
375                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
376                 }
377                 else
378                 {
379                         square = eY * theSize.x;
380                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
381                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
382                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
383                 }
384         } else {
385                 pic = strcat(hud_skin_path, "/", pic);
386                 if(precache_pic(pic) == "") {
387                         pic = "gfx/hud/default/progressbar";
388                 }
389
390                 if (baralign == 1) // right align
391                         theOrigin.x += (1 - length_ratio) * theSize.x;
392         else if (baralign == 2) // center align
393             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
394         else if (baralign == 3) // center align, positive values on the right, negative on the left
395                 {
396                         theSize.x *= 0.5;
397                         if (length_ratio > 0)
398                                 theOrigin.x += theSize.x;
399                         else
400                         {
401                                 theOrigin.x += (1 + length_ratio) * theSize.x;
402                                 length_ratio = -length_ratio;
403                         }
404                 }
405                 theSize.x *= length_ratio;
406
407                 vector bW;
408                 width = eX * theSize.x;
409                 height = eY * theSize.y;
410                 if(theSize.x <= theSize.y * 2)
411                 {
412                         // button not wide enough
413                         // draw just left and right part then
414                         square = eX * theSize.x * 0.5;
415                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
416                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
417                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
418                 }
419                 else
420                 {
421                         square = eX * theSize.y;
422                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
423                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
424                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
425                 }
426         }
427 }
428
429 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
430 {
431         if(!theAlpha)
432                 return;
433
434         string pic;
435         pic = strcat(hud_skin_path, "/num_leading");
436         if(precache_pic(pic) == "") {
437                 pic = "gfx/hud/default/num_leading";
438         }
439
440         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
441         if(mySize.x/mySize.y > 2)
442                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
443         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
444 }
445
446 // Weapon icons (#0)
447 //
448 entity weaponorder[WEP_MAXCOUNT];
449 void weaponorder_swap(int i, int j, entity pass)
450 {
451         entity h = weaponorder[i];
452         weaponorder[i] = weaponorder[j];
453         weaponorder[j] = h;
454 }
455
456 string weaponorder_cmp_str;
457 float weaponorder_cmp(float i, float j, entity pass)
458 {
459         float ai, aj;
460         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
461         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
462         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
463 }
464
465 void HUD_Weapons(void)
466 {
467         // declarations
468         WepSet weapons_stat = WepSet_GetFromStat();
469         float i, f, a;
470         float screen_ar;
471         vector center = '0 0 0';
472         float weapon_count, weapon_id;
473         float row, column, rows = 0, columns = 0;
474         bool vertical_order = true;
475         float aspect = autocvar_hud_panel_weapons_aspect;
476
477         float timeout = autocvar_hud_panel_weapons_timeout;
478         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
479         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
480
481         vector barsize = '0 0 0', baroffset = '0 0 0';
482         vector ammo_color = '1 0 1';
483         float ammo_alpha = 1;
484
485         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
486         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
487
488         vector weapon_pos, weapon_size = '0 0 0';
489         vector color;
490
491         // check to see if we want to continue
492         if(hud != HUD_NORMAL) { return; }
493
494         if(!autocvar__hud_configure)
495         {
496                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
497                         return;
498                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
499                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
500                 {
501                         weaponprevtime = time;
502                         return;
503                 }
504         }
505
506         // update generic hud functions
507         HUD_Panel_UpdateCvars();
508
509         draw_beginBoldFont();
510
511         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
512         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
513         {
514                 int weapon_cnt;
515                 if(weaponorder_bypriority)
516                         strunzone(weaponorder_bypriority);
517                 if(weaponorder_byimpulse)
518                         strunzone(weaponorder_byimpulse);
519
520                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
521                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
522                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
523
524                 weapon_cnt = 0;
525                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
526                 {
527                         self = get_weaponinfo(i);
528                         if(self.impulse >= 0)
529                         {
530                                 weaponorder[weapon_cnt] = self;
531                                 ++weapon_cnt;
532                         }
533                 }
534                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
535                         weaponorder[i] = world;
536                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
537
538                 weaponorder_cmp_str = string_null;
539         }
540
541         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
542                 complain_weapon = 0;
543
544         if(autocvar__hud_configure)
545         {
546                 if(!weapons_stat)
547                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
548                                 weapons_stat |= WepSet_FromWeapon(i);
549
550                 #if 0
551                 /// debug code
552                 if(cvar("wep_add"))
553                 {
554                         weapons_stat = '0 0 0';
555                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
556                         for(i = WEP_FIRST; i <= countw; ++i)
557                                 weapons_stat |= WepSet_FromWeapon(i);
558                 }
559                 #endif
560         }
561
562         // determine which weapons are going to be shown
563         if (autocvar_hud_panel_weapons_onlyowned)
564         {
565                 if(autocvar__hud_configure)
566                 {
567                         if(menu_enabled != 2)
568                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
569                 }
570
571                 // do we own this weapon?
572                 weapon_count = 0;
573                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
574                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
575                                 ++weapon_count;
576
577
578                 // might as well commit suicide now, no reason to live ;)
579                 if (weapon_count == 0)
580                 {
581                         draw_endBoldFont();
582                         return;
583                 }
584
585                 vector old_panel_size = panel_size;
586                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
587
588                 // get the all-weapons layout
589                 vector table_size = HUD_GetTableSize(WEP_COUNT, padded_panel_size, aspect);
590                 columns = table_size.x;
591                 rows = table_size.y;
592                 weapon_size.x = padded_panel_size.x / columns;
593                 weapon_size.y = padded_panel_size.y / rows;
594
595                 // reduce table trying to keep the original table proportions as much as possible
596                 vertical_order = (columns >= rows);
597                 if(vertical_order)
598                 {
599                         rows = ceil(sqrt(weapon_count / (columns / rows)));
600                         columns = ceil(weapon_count / rows);
601                 }
602                 else
603                 {
604                         columns = ceil(sqrt(weapon_count / (rows / columns)));
605                         rows = ceil(weapon_count / columns);
606                 }
607
608                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
609                 // we enlarge them a bit when possible to better match the desired aspect ratio
610                 if(padded_panel_size.y > padded_panel_size.x)
611                 {
612                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
613                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
614                 }
615                 else
616                 {
617                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
618                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
619                 }
620
621                 // reduce size of the panel
622                 panel_size.x = columns * weapon_size.x;
623                 panel_size.y = rows * weapon_size.y;
624                 panel_size += '2 2 0' * panel_bg_padding;
625
626                 // center the resized panel, or snap it to the screen edge when close enough
627                 if(panel_pos.x > vid_conwidth * 0.001)
628                 {
629                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
630                                 panel_pos.x += old_panel_size.x - panel_size.x;
631                         else
632                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
633                 }
634                 else if(old_panel_size.x > vid_conwidth * 0.999)
635                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
636
637                 if(panel_pos.y > vid_conheight * 0.001)
638                 {
639                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
640                                 panel_pos.y += old_panel_size.y - panel_size.y;
641                         else
642                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
643                 }
644                 else if(old_panel_size.y > vid_conheight * 0.999)
645                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
646         }
647         else
648                 weapon_count = WEP_COUNT;
649
650         // animation for fading in/out the panel respectively when not in use
651         if(!autocvar__hud_configure)
652         {
653                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
654                 {
655                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
656
657                         // fade the panel alpha
658                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
659                         {
660                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
661                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
662                         }
663                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
664                         {
665                                 panel_bg_alpha *= (1 - f);
666                                 panel_fg_alpha *= (1 - f);
667                         }
668
669                         // move the panel off the screen
670                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
671                         {
672                                 f *= f; // for a cooler movement
673                                 center.x = panel_pos.x + panel_size.x/2;
674                                 center.y = panel_pos.y + panel_size.y/2;
675                                 screen_ar = vid_conwidth/vid_conheight;
676                                 if (center.x/center.y < screen_ar) //bottom left
677                                 {
678                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
679                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
680                                         else //left
681                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
682                                 }
683                                 else //top right
684                                 {
685                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
686                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
687                                         else //top
688                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
689                                 }
690                                 if(f == 1)
691                                         center.x = -1; // mark the panel as off screen
692                         }
693                         weaponprevtime = time - (1 - f) * timein_effect_length;
694                 }
695                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
696                 {
697                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
698
699                         // fade the panel alpha
700                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
701                         {
702                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
703                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
704                         }
705                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
706                         {
707                                 panel_bg_alpha *= (f);
708                                 panel_fg_alpha *= (f);
709                         }
710
711                         // move the panel back on screen
712                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
713                         {
714                                 f *= f; // for a cooler movement
715                                 f = 1 - f;
716                                 center.x = panel_pos.x + panel_size.x/2;
717                                 center.y = panel_pos.y + panel_size.y/2;
718                                 screen_ar = vid_conwidth/vid_conheight;
719                                 if (center.x/center.y < screen_ar) //bottom left
720                                 {
721                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
722                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
723                                         else //left
724                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
725                                 }
726                                 else //top right
727                                 {
728                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
729                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
730                                         else //top
731                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
732                                 }
733                         }
734                 }
735         }
736
737         // draw the background, then change the virtual size of it to better fit other items inside
738         HUD_Panel_DrawBg(1);
739
740         if(center.x == -1)
741         {
742                 draw_endBoldFont();
743                 return;
744         }
745
746         if(panel_bg_padding)
747         {
748                 panel_pos += '1 1 0' * panel_bg_padding;
749                 panel_size -= '2 2 0' * panel_bg_padding;
750         }
751
752         // after the sizing and animations are done, update the other values
753
754         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
755         {
756                 vector table_size = HUD_GetTableSize(WEP_COUNT, panel_size, aspect);
757                 columns = table_size.x;
758                 rows = table_size.y;
759                 weapon_size.x = panel_size.x / columns;
760                 weapon_size.y = panel_size.y / rows;
761                 vertical_order = (columns >= rows);
762         }
763
764         // calculate position/size for visual bar displaying ammount of ammo status
765         if (autocvar_hud_panel_weapons_ammo)
766         {
767                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
768                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
769
770                 if(weapon_size.x/weapon_size.y > aspect)
771                 {
772                         barsize.x = aspect * weapon_size.y;
773                         barsize.y = weapon_size.y;
774                         baroffset.x = (weapon_size.x - barsize.x) / 2;
775                 }
776                 else
777                 {
778                         barsize.y = 1/aspect * weapon_size.x;
779                         barsize.x = weapon_size.x;
780                         baroffset.y = (weapon_size.y - barsize.y) / 2;
781                 }
782         }
783         if(autocvar_hud_panel_weapons_accuracy)
784                 Accuracy_LoadColors();
785
786         // draw items
787         row = column = 0;
788         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
789         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
790         {
791                 // retrieve information about the current weapon to be drawn
792                 self = weaponorder[i];
793                 weapon_id = self.impulse;
794
795                 // skip if this weapon doesn't exist
796                 if(!self || weapon_id < 0) { continue; }
797
798                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
799                 if(autocvar_hud_panel_weapons_onlyowned)
800                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
801                         continue;
802
803                 // figure out the drawing position of weapon
804                 weapon_pos = (panel_pos
805                         + eX * column * weapon_size.x
806                         + eY * row * weapon_size.y);
807
808                 // draw background behind currently selected weapon
809                 if(self.weapon == switchweapon)
810                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
811
812                 // draw the weapon accuracy
813                 if(autocvar_hud_panel_weapons_accuracy)
814                 {
815                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
816                         if(panel_weapon_accuracy >= 0)
817                         {
818                                 color = Accuracy_GetColor(panel_weapon_accuracy);
819                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
820                         }
821                 }
822
823                 // drawing all the weapon items
824                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
825                 {
826                         // draw the weapon image
827                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
828
829                         // draw weapon label string
830                         switch(autocvar_hud_panel_weapons_label)
831                         {
832                                 case 1: // weapon number
833                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
834                                         break;
835
836                                 case 2: // bind
837                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
838                                         break;
839
840                                 case 3: // weapon name
841                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
842                                         break;
843
844                                 default: // nothing
845                                         break;
846                         }
847
848                         // draw ammo status bar
849                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
850                         {
851                                 float ammo_full;
852                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
853
854                                 if(a > 0)
855                                 {
856                                         switch(self.ammo_field)
857                                         {
858                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
859                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
860                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
861                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
862                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
863                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
864                                                 default: ammo_full = 60;
865                                         }
866
867                                         drawsetcliparea(
868                                                 weapon_pos.x + baroffset.x,
869                                                 weapon_pos.y + baroffset.y,
870                                                 barsize.x * bound(0, a/ammo_full, 1),
871                                                 barsize.y
872                                         );
873
874                                         drawpic_aspect_skin(
875                                                 weapon_pos,
876                                                 "weapon_ammo",
877                                                 weapon_size,
878                                                 ammo_color,
879                                                 ammo_alpha,
880                                                 DRAWFLAG_NORMAL
881                                         );
882
883                                         drawresetcliparea();
884                                 }
885                         }
886                 }
887                 else // draw a "ghost weapon icon" if you don't have the weapon
888                 {
889                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
890                 }
891
892                 // draw the complain message
893                 if(self.weapon == complain_weapon)
894                 {
895                         if(fadetime)
896                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
897                         else
898                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
899
900                         string s;
901                         if(complain_weapon_type == 0) {
902                                 s = _("Out of ammo");
903                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
904                         }
905                         else if(complain_weapon_type == 1) {
906                                 s = _("Don't have");
907                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
908                         }
909                         else {
910                                 s = _("Unavailable");
911                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
912                         }
913                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
914                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
915                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
916                 }
917
918                 #if 0
919                 /// debug code
920                 if(!autocvar_hud_panel_weapons_onlyowned)
921                 {
922                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
923                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
924                 }
925                 #endif
926
927                 // continue with new position for the next weapon
928                 if(vertical_order)
929                 {
930                         ++column;
931                         if(column >= columns)
932                         {
933                                 column = 0;
934                                 ++row;
935                         }
936                 }
937                 else
938                 {
939                         ++row;
940                         if(row >= rows)
941                         {
942                                 row = 0;
943                                 ++column;
944                         }
945                 }
946         }
947
948         draw_endBoldFont();
949 }
950
951 // Ammo (#1)
952 void DrawNadeScoreBar(vector myPos, vector mySize, vector color)
953 {
954
955         HUD_Panel_DrawProgressBar(
956                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
957                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
958                 autocvar_hud_panel_ammo_progressbar_name,
959                 getstatf(STAT_NADE_BONUS_SCORE), 0, 0, color,
960                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
961
962 }
963
964 void DrawAmmoNades(vector myPos, vector mySize, float draw_expanding, float expand_time)
965 {
966         float theAlpha = 1, a, b;
967         vector nade_color, picpos, numpos;
968
969         nade_color = Nade_Color(getstati(STAT_NADE_BONUS_TYPE));
970
971         a = getstatf(STAT_NADE_BONUS);
972         b = getstatf(STAT_NADE_BONUS_SCORE);
973
974         if(autocvar_hud_panel_ammo_iconalign)
975         {
976                 numpos = myPos;
977                 picpos = myPos + eX * 2 * mySize.y;
978         }
979         else
980         {
981                 numpos = myPos + eX * mySize.y;
982                 picpos = myPos;
983         }
984
985         DrawNadeScoreBar(myPos, mySize, nade_color);
986
987         if(b > 0 || a > 0)
988         {
989                 if(autocvar_hud_panel_ammo_text)
990                         drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
991
992                 if(draw_expanding)
993                         drawpic_aspect_skin_expanding(picpos, "nade_nbg", '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, expand_time);
994
995                 drawpic_aspect_skin(picpos, "nade_bg" , '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
996                 drawpic_aspect_skin(picpos, "nade_nbg" , '1 1 0' * mySize.y, nade_color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
997         }
998 }
999
1000 void DrawAmmoItem(vector myPos, vector mySize, .float ammoType, float isCurrent, float isInfinite)
1001 {
1002         if(ammoType == ammo_none)
1003                 return;
1004
1005         // Initialize variables
1006
1007         float ammo;
1008         if(autocvar__hud_configure)
1009         {
1010                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1011                 ammo = 60;
1012         }
1013         else
1014                 ammo = getstati(GetAmmoStat(ammoType));
1015
1016         if(!isCurrent)
1017         {
1018                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1019                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1020                 mySize = mySize * scale;
1021         }
1022
1023         vector iconPos, textPos;
1024         if(autocvar_hud_panel_ammo_iconalign)
1025         {
1026                 iconPos = myPos + eX * 2 * mySize.y;
1027                 textPos = myPos;
1028         }
1029         else
1030         {
1031                 iconPos = myPos;
1032                 textPos = myPos + eX * mySize.y;
1033         }
1034
1035         float isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1036
1037         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1038         vector textColor;
1039         if(isInfinite)
1040                 textColor = '0.2 0.95 0';
1041         else if(isShadowed)
1042                 textColor = '0 0 0';
1043         else if(ammo < 10)
1044                 textColor = '0.8 0.04 0';
1045         else
1046                 textColor = '1 1 1';
1047
1048         float alpha;
1049         if(isCurrent)
1050                 alpha = panel_fg_alpha;
1051         else if(isShadowed)
1052                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1053         else
1054                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1055
1056         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1057
1058         // Draw item
1059
1060         if(isCurrent)
1061                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1062
1063         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1064                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1065
1066         if(autocvar_hud_panel_ammo_text)
1067                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1068
1069         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1070 }
1071
1072 float nade_prevstatus;
1073 float nade_prevframe;
1074 float nade_statuschange_time;
1075 void HUD_Ammo(void)
1076 {
1077         if(hud != HUD_NORMAL) return;
1078         if(!autocvar__hud_configure)
1079         {
1080                 if(!autocvar_hud_panel_ammo) return;
1081                 if(spectatee_status == -1) return;
1082         }
1083
1084         HUD_Panel_UpdateCvars();
1085
1086         draw_beginBoldFont();
1087
1088         vector pos, mySize;
1089         pos = panel_pos;
1090         mySize = panel_size;
1091
1092         HUD_Panel_DrawBg(1);
1093         if(panel_bg_padding)
1094         {
1095                 pos += '1 1 0' * panel_bg_padding;
1096                 mySize -= '2 2 0' * panel_bg_padding;
1097         }
1098
1099         float rows = 0, columns, row, column;
1100         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1101         float draw_nades = (nade_cnt > 0 || nade_score > 0), nade_statuschange_elapsedtime;
1102         float total_ammo_count;
1103
1104         vector ammo_size;
1105         if (autocvar_hud_panel_ammo_onlycurrent)
1106                 total_ammo_count = 1;
1107         else
1108                 total_ammo_count = AMMO_COUNT;
1109
1110         if(draw_nades)
1111         {
1112                 ++total_ammo_count;
1113                 if (nade_cnt != nade_prevframe)
1114                 {
1115                         nade_statuschange_time = time;
1116                         nade_prevstatus = nade_prevframe;
1117                         nade_prevframe = nade_cnt;
1118                 }
1119         }
1120         else
1121                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1122
1123         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1124         columns = ceil((total_ammo_count)/rows);
1125         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1126
1127         vector offset = '0 0 0'; // fteqcc sucks
1128         float newSize;
1129         if(ammo_size.x/ammo_size.y > 3)
1130         {
1131                 newSize = 3 * ammo_size.y;
1132                 offset.x = ammo_size.x - newSize;
1133                 pos.x += offset.x/2;
1134                 ammo_size.x = newSize;
1135         }
1136         else
1137         {
1138                 newSize = 1/3 * ammo_size.x;
1139                 offset.y = ammo_size.y - newSize;
1140                 pos.y += offset.y/2;
1141                 ammo_size.y = newSize;
1142         }
1143
1144         float i;
1145         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1146         row = column = 0;
1147         if(autocvar_hud_panel_ammo_onlycurrent)
1148         {
1149                 if(autocvar__hud_configure)
1150                 {
1151                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1152                 }
1153                 else
1154                 {
1155                         DrawAmmoItem(
1156                                 pos,
1157                                 ammo_size,
1158                                 (get_weaponinfo(switchweapon)).ammo_field,
1159                                 true,
1160                                 infinite_ammo
1161                         );
1162                 }
1163
1164                 ++row;
1165                 if(row >= rows)
1166                 {
1167                         row = 0;
1168                         column = column + 1;
1169                 }
1170         }
1171         else
1172         {
1173                 .float ammotype;
1174                 row = column = 0;
1175                 for(i = 0; i < AMMO_COUNT; ++i)
1176                 {
1177                         ammotype = GetAmmoFieldFromNum(i);
1178                         DrawAmmoItem(
1179                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1180                                 ammo_size,
1181                                 ammotype,
1182                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1183                                 infinite_ammo
1184                         );
1185
1186                         ++row;
1187                         if(row >= rows)
1188                         {
1189                                 row = 0;
1190                                 column = column + 1;
1191                         }
1192                 }
1193         }
1194
1195         if (draw_nades)
1196         {
1197                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1198
1199                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1200
1201                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1202         }
1203
1204         draw_endBoldFont();
1205 }
1206
1207 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1208 {
1209         vector newPos = '0 0 0', newSize = '0 0 0';
1210         vector picpos, numpos;
1211
1212         if (vertical)
1213         {
1214                 if(mySize.y/mySize.x > 2)
1215                 {
1216                         newSize.y = 2 * mySize.x;
1217                         newSize.x = mySize.x;
1218
1219                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1220                         newPos.x = myPos.x;
1221                 }
1222                 else
1223                 {
1224                         newSize.x = 1/2 * mySize.y;
1225                         newSize.y = mySize.y;
1226
1227                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1228                         newPos.y = myPos.y;
1229                 }
1230
1231                 if(icon_right_align)
1232                 {
1233                         numpos = newPos;
1234                         picpos = newPos + eY * newSize.x;
1235                 }
1236                 else
1237                 {
1238                         picpos = newPos;
1239                         numpos = newPos + eY * newSize.x;
1240                 }
1241
1242                 newSize.y /= 2;
1243                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1244                 // make number smaller than icon, it looks better
1245                 // reduce only y to draw numbers with different number of digits with the same y size
1246                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1247                 newSize.y *= 0.7;
1248                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1249                 return;
1250         }
1251
1252         if(mySize.x/mySize.y > 3)
1253         {
1254                 newSize.x = 3 * mySize.y;
1255                 newSize.y = mySize.y;
1256
1257                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1258                 newPos.y = myPos.y;
1259         }
1260         else
1261         {
1262                 newSize.y = 1/3 * mySize.x;
1263                 newSize.x = mySize.x;
1264
1265                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1266                 newPos.x = myPos.x;
1267         }
1268
1269         if(icon_right_align) // right align
1270         {
1271                 numpos = newPos;
1272                 picpos = newPos + eX * 2 * newSize.y;
1273         }
1274         else // left align
1275         {
1276                 numpos = newPos + eX * newSize.y;
1277                 picpos = newPos;
1278         }
1279
1280         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1281         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1282         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1283         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1284 }
1285
1286 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1287 {
1288         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1289 }
1290
1291 // Powerups (#2)
1292 //
1293 void HUD_Powerups(void)
1294 {
1295         float strength_time, shield_time, superweapons_time;
1296         if(!autocvar__hud_configure)
1297         {
1298                 if(!autocvar_hud_panel_powerups) return;
1299                 if(spectatee_status == -1) return;
1300                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1301                 if (getstati(STAT_HEALTH) <= 0) return;
1302
1303                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1304                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1305                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1306
1307                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1308                         superweapons_time = 99; // force max
1309
1310                 // prevent stuff to show up on mismatch that will be fixed next frame
1311                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1312                         superweapons_time = 0;
1313         }
1314         else
1315         {
1316                 strength_time = 15;
1317                 shield_time = 27;
1318                 superweapons_time = 13;
1319         }
1320
1321         HUD_Panel_UpdateCvars();
1322
1323         draw_beginBoldFont();
1324
1325         vector pos, mySize;
1326         pos = panel_pos;
1327         mySize = panel_size;
1328
1329         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1330         if(panel_bg_padding)
1331         {
1332                 pos += '1 1 0' * panel_bg_padding;
1333                 mySize -= '2 2 0' * panel_bg_padding;
1334         }
1335
1336         float panel_ar = mySize.x/mySize.y;
1337         float is_vertical = (panel_ar < 1);
1338         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1339
1340         float superweapons_is = -1;
1341
1342         if(superweapons_time)
1343         {
1344                 if(strength_time)
1345                 {
1346                         if(shield_time)
1347                                 superweapons_is = 0;
1348                         else
1349                                 superweapons_is = 2;
1350                 }
1351                 else
1352                 {
1353                         if(shield_time)
1354                                 superweapons_is = 1;
1355                         else
1356                                 superweapons_is = 2;
1357                 }
1358         }
1359
1360         // FIXME handle superweapons here
1361         if(superweapons_is == 0)
1362         {
1363                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1364                 {
1365                         mySize.x *= (1.0 / 3.0);
1366                         superweapons_offset.x = mySize.x;
1367                         if (autocvar_hud_panel_powerups_flip)
1368                                 shield_offset.x = 2*mySize.x;
1369                         else
1370                                 strength_offset.x = 2*mySize.x;
1371                 }
1372                 else
1373                 {
1374                         mySize.y *= (1.0 / 3.0);
1375                         superweapons_offset.y = mySize.y;
1376                         if (autocvar_hud_panel_powerups_flip)
1377                                 shield_offset.y = 2*mySize.y;
1378                         else
1379                                 strength_offset.y = 2*mySize.y;
1380                 }
1381         }
1382         else
1383         {
1384                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1385                 {
1386                         mySize.x *= 0.5;
1387                         if (autocvar_hud_panel_powerups_flip)
1388                                 shield_offset.x = mySize.x;
1389                         else
1390                                 strength_offset.x = mySize.x;
1391                 }
1392                 else
1393                 {
1394                         mySize.y *= 0.5;
1395                         if (autocvar_hud_panel_powerups_flip)
1396                                 shield_offset.y = mySize.y;
1397                         else
1398                                 strength_offset.y = mySize.y;
1399                 }
1400         }
1401
1402         float shield_baralign, strength_baralign, superweapons_baralign;
1403         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1404
1405         if (autocvar_hud_panel_powerups_flip)
1406         {
1407                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1408                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1409                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1410                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1411         }
1412         else
1413         {
1414                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1415                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1416                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1417                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1418         }
1419
1420         if(superweapons_is == 0)
1421         {
1422                 superweapons_iconalign = strength_iconalign;
1423                 superweapons_baralign = 2;
1424         }
1425         else if(superweapons_is == 1)
1426         {
1427                 superweapons_offset = strength_offset;
1428                 superweapons_iconalign = strength_iconalign;
1429                 superweapons_baralign = strength_baralign;
1430         }
1431         else // if(superweapons_is == 2)
1432         {
1433                 superweapons_offset = shield_offset;
1434                 superweapons_iconalign = shield_iconalign;
1435                 superweapons_baralign = shield_baralign;
1436         }
1437
1438         if(shield_time)
1439         {
1440                 const float maxshield = 30;
1441                 float shield = ceil(shield_time);
1442                 if(autocvar_hud_panel_powerups_progressbar)
1443                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1444                 if(autocvar_hud_panel_powerups_text)
1445                 {
1446                         if(shield > 1)
1447                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1448                         if(shield <= 5)
1449                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1450                 }
1451         }
1452
1453         if(strength_time)
1454         {
1455                 const float maxstrength = 30;
1456                 float strength = ceil(strength_time);
1457                 if(autocvar_hud_panel_powerups_progressbar)
1458                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1459                 if(autocvar_hud_panel_powerups_text)
1460                 {
1461                         if(strength > 1)
1462                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1463                         if(strength <= 5)
1464                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1465                 }
1466         }
1467
1468         if(superweapons_time)
1469         {
1470                 const float maxsuperweapons = 30;
1471                 float superweapons = ceil(superweapons_time);
1472                 if(autocvar_hud_panel_powerups_progressbar)
1473                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1474                 if(autocvar_hud_panel_powerups_text)
1475                 {
1476                         if(superweapons > 1)
1477                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1478                         if(superweapons <= 5)
1479                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1480                 }
1481         }
1482
1483         draw_endBoldFont();
1484 }
1485
1486 // Health/armor (#3)
1487 //
1488
1489 // prev_* vars contain the health/armor at the previous FRAME
1490 // set to -1 when player is dead or was not playing
1491 float prev_health, prev_armor;
1492 float health_damagetime, armor_damagetime;
1493 float health_beforedamage, armor_beforedamage;
1494 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1495 float old_p_health, old_p_armor;
1496 float old_p_healthtime, old_p_armortime;
1497 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1498 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1499 float prev_p_health, prev_p_armor;
1500
1501 void HUD_HealthArmor(void)
1502 {
1503         float armor, health, fuel;
1504         if(!autocvar__hud_configure)
1505         {
1506                 if(!autocvar_hud_panel_healtharmor) return;
1507                 if(hud != HUD_NORMAL) return;
1508                 if(spectatee_status == -1) return;
1509
1510                 health = getstati(STAT_HEALTH);
1511                 if(health <= 0)
1512                 {
1513                         prev_health = -1;
1514                         return;
1515                 }
1516                 armor = getstati(STAT_ARMOR);
1517
1518                 // code to check for spectatee_status changes is in Ent_ClientData()
1519                 // prev_p_health and prev_health can be set to -1 there
1520
1521                 if (prev_p_health == -1)
1522                 {
1523                         // no effect
1524                         health_beforedamage = 0;
1525                         armor_beforedamage = 0;
1526                         health_damagetime = 0;
1527                         armor_damagetime = 0;
1528                         prev_health = health;
1529                         prev_armor = armor;
1530                         old_p_health = health;
1531                         old_p_armor = armor;
1532                         prev_p_health = health;
1533                         prev_p_armor = armor;
1534                 }
1535                 else if (prev_health == -1)
1536                 {
1537                         //start the load effect
1538                         health_damagetime = 0;
1539                         armor_damagetime = 0;
1540                         prev_health = 0;
1541                         prev_armor = 0;
1542                 }
1543                 fuel = getstati(STAT_FUEL);
1544         }
1545         else
1546         {
1547                 health = 150;
1548                 armor = 75;
1549                 fuel = 20;
1550         }
1551
1552         HUD_Panel_UpdateCvars();
1553         vector pos, mySize;
1554         pos = panel_pos;
1555         mySize = panel_size;
1556
1557         HUD_Panel_DrawBg(1);
1558         if(panel_bg_padding)
1559         {
1560                 pos += '1 1 0' * panel_bg_padding;
1561                 mySize -= '2 2 0' * panel_bg_padding;
1562         }
1563
1564         float baralign = autocvar_hud_panel_healtharmor_baralign;
1565         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1566
1567     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1568     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1569         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1570         {
1571                 vector v;
1572                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1573
1574                 float x;
1575                 x = floor(v.x + 1);
1576
1577         float maxtotal = maxhealth + maxarmor;
1578                 string biggercount;
1579                 if(v.z) // NOT fully armored
1580                 {
1581                         biggercount = "health";
1582                         if(autocvar_hud_panel_healtharmor_progressbar)
1583                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1584                         if(armor)
1585             if(autocvar_hud_panel_healtharmor_text)
1586                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1587                 }
1588                 else
1589                 {
1590                         biggercount = "armor";
1591                         if(autocvar_hud_panel_healtharmor_progressbar)
1592                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1593                         if(health)
1594             if(autocvar_hud_panel_healtharmor_text)
1595                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1596                 }
1597         if(autocvar_hud_panel_healtharmor_text)
1598                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1599
1600                 if(fuel)
1601                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1602         }
1603         else
1604         {
1605                 float panel_ar = mySize.x/mySize.y;
1606                 float is_vertical = (panel_ar < 1);
1607                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1608                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1609                 {
1610                         mySize.x *= 0.5;
1611                         if (autocvar_hud_panel_healtharmor_flip)
1612                                 health_offset.x = mySize.x;
1613                         else
1614                                 armor_offset.x = mySize.x;
1615                 }
1616                 else
1617                 {
1618                         mySize.y *= 0.5;
1619                         if (autocvar_hud_panel_healtharmor_flip)
1620                                 health_offset.y = mySize.y;
1621                         else
1622                                 armor_offset.y = mySize.y;
1623                 }
1624
1625                 float health_baralign, armor_baralign, fuel_baralign;
1626                 float health_iconalign, armor_iconalign;
1627                 if (autocvar_hud_panel_healtharmor_flip)
1628                 {
1629                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1630                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1631                         fuel_baralign = health_baralign;
1632                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1633                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1634                 }
1635                 else
1636                 {
1637                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1638                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1639                         fuel_baralign = armor_baralign;
1640                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1641                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1642                 }
1643
1644                 //if(health)
1645                 {
1646                         if(autocvar_hud_panel_healtharmor_progressbar)
1647                         {
1648                                 float p_health, pain_health_alpha;
1649                                 p_health = health;
1650                                 pain_health_alpha = 1;
1651                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1652                                 {
1653                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1654                                         {
1655                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1656                                                 {
1657                                                         if (time - old_p_healthtime < 1)
1658                                                                 old_p_health = prev_p_health;
1659                                                         else
1660                                                                 old_p_health = prev_health;
1661                                                         old_p_healthtime = time;
1662                                                 }
1663                                                 if (time - old_p_healthtime < 1)
1664                                                 {
1665                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1666                                                         prev_p_health = p_health;
1667                                                 }
1668                                         }
1669                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1670                                         {
1671                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1672                                                 {
1673                                                         if (time - health_damagetime >= 1)
1674                                                                 health_beforedamage = prev_health;
1675                                                         health_damagetime = time;
1676                                                 }
1677                                                 if (time - health_damagetime < 1)
1678                                                 {
1679                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1680                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1681                                                 }
1682                                         }
1683                                         prev_health = health;
1684
1685                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1686                                         {
1687                                                 float BLINK_FACTOR = 0.15;
1688                                                 float BLINK_BASE = 0.85;
1689                                                 float BLINK_FREQ = 9;
1690                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1691                                         }
1692                                 }
1693                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1694                         }
1695                         if(autocvar_hud_panel_healtharmor_text)
1696                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1697                 }
1698
1699                 if(armor)
1700                 {
1701                         if(autocvar_hud_panel_healtharmor_progressbar)
1702                         {
1703                                 float p_armor;
1704                                 p_armor = armor;
1705                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1706                                 {
1707                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1708                                         {
1709                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1710                                                 {
1711                                                         if (time - old_p_armortime < 1)
1712                                                                 old_p_armor = prev_p_armor;
1713                                                         else
1714                                                                 old_p_armor = prev_armor;
1715                                                         old_p_armortime = time;
1716                                                 }
1717                                                 if (time - old_p_armortime < 1)
1718                                                 {
1719                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1720                                                         prev_p_armor = p_armor;
1721                                                 }
1722                                         }
1723                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1724                                         {
1725                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1726                                                 {
1727                                                         if (time - armor_damagetime >= 1)
1728                                                                 armor_beforedamage = prev_armor;
1729                                                         armor_damagetime = time;
1730                                                 }
1731                                                 if (time - armor_damagetime < 1)
1732                                                 {
1733                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1734                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1735                                                 }
1736                                         }
1737                                         prev_armor = armor;
1738                                 }
1739                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1740                         }
1741                         if(autocvar_hud_panel_healtharmor_text)
1742                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1743                 }
1744
1745                 if(fuel)
1746                 {
1747                         if (is_vertical)
1748                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1749                         else
1750                                 mySize.y *= 0.2;
1751                         if (panel_ar >= 4)
1752                                 mySize.x *= 2; //restore full panel size
1753                         else if (panel_ar < 1/4)
1754                                 mySize.y *= 2; //restore full panel size
1755                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1756                 }
1757         }
1758 }
1759
1760 // Notification area (#4)
1761 //
1762
1763 void HUD_Notify_Push(string icon, string attacker, string victim)
1764 {
1765         if (icon == "")
1766                 return;
1767
1768         ++notify_count;
1769         --notify_index;
1770
1771         if (notify_index == -1)
1772                 notify_index = NOTIFY_MAX_ENTRIES-1;
1773
1774         // Free old strings
1775         if (notify_attackers[notify_index])
1776                 strunzone(notify_attackers[notify_index]);
1777
1778         if (notify_victims[notify_index])
1779                 strunzone(notify_victims[notify_index]);
1780
1781         if (notify_icons[notify_index])
1782                 strunzone(notify_icons[notify_index]);
1783
1784         // Allocate new strings
1785         if (victim != "")
1786         {
1787                 notify_attackers[notify_index] = strzone(attacker);
1788                 notify_victims[notify_index] = strzone(victim);
1789         }
1790         else
1791         {
1792                 // In case of a notification without a victim, the attacker
1793                 // is displayed on the victim's side. Instead of special
1794                 // treatment later on, we can simply switch them here.
1795                 notify_attackers[notify_index] = string_null;
1796                 notify_victims[notify_index] = strzone(attacker);
1797         }
1798
1799         notify_icons[notify_index] = strzone(icon);
1800         notify_times[notify_index] = time;
1801 }
1802
1803 void HUD_Notify(void)
1804 {
1805         if (!autocvar__hud_configure)
1806                 if (!autocvar_hud_panel_notify)
1807                         return;
1808
1809         HUD_Panel_UpdateCvars();
1810         HUD_Panel_DrawBg(1);
1811
1812         if (!autocvar__hud_configure)
1813                 if (notify_count == 0)
1814                         return;
1815
1816         vector pos, size;
1817         pos  = panel_pos;
1818         size = panel_size;
1819
1820         if (panel_bg_padding)
1821         {
1822                 pos  += '1 1 0' * panel_bg_padding;
1823                 size -= '2 2 0' * panel_bg_padding;
1824         }
1825
1826         float fade_start = max(0, autocvar_hud_panel_notify_time);
1827         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1828         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1829
1830         float entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1831         float entry_height = size.y / entry_count;
1832
1833         float panel_width_half = size.x * 0.5;
1834         float icon_width_half = entry_height * icon_aspect / 2;
1835         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1836
1837         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1838         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1839         vector icon_left = eX * (panel_width_half - icon_width_half);
1840         vector attacker_right = eX * name_maxwidth;
1841         vector victim_left = eX * (size.x - name_maxwidth);
1842
1843         vector attacker_pos, victim_pos, icon_pos;
1844         string attacker, victim, icon;
1845         float i, j, count, step, limit, alpha;
1846
1847         if (autocvar_hud_panel_notify_flip)
1848         {
1849                 // Order items from the top down
1850                 i = 0;
1851                 step = +1;
1852                 limit = entry_count;
1853         }
1854         else
1855         {
1856                 // Order items from the bottom up
1857                 i = entry_count - 1;
1858                 step = -1;
1859                 limit = -1;
1860         }
1861
1862         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1863         {
1864                 if(autocvar__hud_configure)
1865                 {
1866                         attacker = sprintf(_("Player %d"), count + 1);
1867                         victim = sprintf(_("Player %d"), count + 2);
1868                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1869                         alpha = bound(0, 1.2 - count / entry_count, 1);
1870                 }
1871                 else
1872                 {
1873                         if (j == NOTIFY_MAX_ENTRIES)
1874                                 j = 0;
1875
1876                         if (notify_times[j] + fade_start > time)
1877                                 alpha = 1;
1878                         else if (fade_time != 0)
1879                         {
1880                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1881                                 if (alpha == 0)
1882                                         break;
1883                         }
1884                         else
1885                                 break;
1886
1887                         attacker = notify_attackers[j];
1888                         victim = notify_victims[j];
1889                         icon = notify_icons[j];
1890                 }
1891
1892                 if (icon != "" && victim != "")
1893                 {
1894                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1895
1896                         icon_pos = pos + icon_left + eY * i * entry_height;
1897                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1898
1899                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1900                         victim_pos = pos + victim_left + name_top;
1901                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1902
1903                         if (attacker != "")
1904                         {
1905                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1906                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1907                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1908                         }
1909                 }
1910         }
1911
1912         notify_count = count;
1913 }
1914
1915 // Timer (#5)
1916 //
1917 // TODO: macro
1918 string seconds_tostring(float sec)
1919 {
1920         float minutes;
1921         minutes = floor(sec / 60);
1922
1923         sec -= minutes * 60;
1924         return sprintf("%d:%02d", minutes, sec);
1925 }
1926
1927 void HUD_Timer(void)
1928 {
1929         if(!autocvar__hud_configure)
1930         {
1931                 if(!autocvar_hud_panel_timer) return;
1932         }
1933
1934         HUD_Panel_UpdateCvars();
1935
1936         draw_beginBoldFont();
1937
1938         vector pos, mySize;
1939         pos = panel_pos;
1940         mySize = panel_size;
1941
1942         HUD_Panel_DrawBg(1);
1943         if(panel_bg_padding)
1944         {
1945                 pos += '1 1 0' * panel_bg_padding;
1946                 mySize -= '2 2 0' * panel_bg_padding;
1947         }
1948
1949         string timer;
1950         float timelimit, elapsedTime, timeleft, minutesLeft;
1951
1952         timelimit = getstatf(STAT_TIMELIMIT);
1953
1954         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1955         timeleft = ceil(timeleft);
1956
1957         minutesLeft = floor(timeleft / 60);
1958
1959         vector timer_color;
1960         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1961                 timer_color = '1 1 1'; //white
1962         else if(minutesLeft >= 1)
1963                 timer_color = '1 1 0'; //yellow
1964         else
1965                 timer_color = '1 0 0'; //red
1966
1967         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1968                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1969                         //while restart is still active, show 00:00
1970                         timer = seconds_tostring(0);
1971                 } else {
1972                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1973                         timer = seconds_tostring(elapsedTime);
1974                 }
1975         } else {
1976                 timer = seconds_tostring(timeleft);
1977         }
1978
1979         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1980
1981         draw_endBoldFont();
1982 }
1983
1984 // Radar (#6)
1985 //
1986 void HUD_Radar(void)
1987 {
1988         if (!autocvar__hud_configure)
1989         {
1990                 if (hud_panel_radar_maximized)
1991                 {
1992                         if (!hud_draw_maximized) return;
1993                 }
1994                 else
1995                 {
1996                         if (autocvar_hud_panel_radar == 0) return;
1997                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1998                         if(radar_panel_modified)
1999                         {
2000                                 panel.update_time = time; // forces reload of panel attributes
2001                                 radar_panel_modified = false;
2002                         }
2003                 }
2004         }
2005
2006         HUD_Panel_UpdateCvars();
2007
2008         float f = 0;
2009
2010         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2011         {
2012                 panel_size = autocvar_hud_panel_radar_maximized_size;
2013                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2014                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2015                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2016                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2017
2018                 string panel_bg;
2019                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2020                 if(precache_pic(panel_bg) == "")
2021                         panel_bg = "gfx/hud/default/border_default"; // fallback
2022                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2023                         radar_panel_modified = true;
2024                 if(panel.current_panel_bg)
2025                         strunzone(panel.current_panel_bg);
2026                 panel.current_panel_bg = strzone(panel_bg);
2027
2028                 switch(hud_panel_radar_maximized_zoommode)
2029                 {
2030                         default:
2031                         case 0:
2032                                 f = current_zoomfraction;
2033                                 break;
2034                         case 1:
2035                                 f = 1 - current_zoomfraction;
2036                                 break;
2037                         case 2:
2038                                 f = 0;
2039                                 break;
2040                         case 3:
2041                                 f = 1;
2042                                 break;
2043                 }
2044
2045                 switch(hud_panel_radar_maximized_rotation)
2046                 {
2047                         case 0:
2048                                 teamradar_angle = view_angles.y - 90;
2049                                 break;
2050                         default:
2051                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2052                                 break;
2053                 }
2054         }
2055         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2056         {
2057                 switch(hud_panel_radar_zoommode)
2058                 {
2059                         default:
2060                         case 0:
2061                                 f = current_zoomfraction;
2062                                 break;
2063                         case 1:
2064                                 f = 1 - current_zoomfraction;
2065                                 break;
2066                         case 2:
2067                                 f = 0;
2068                                 break;
2069                         case 3:
2070                                 f = 1;
2071                                 break;
2072                 }
2073
2074                 switch(hud_panel_radar_rotation)
2075                 {
2076                         case 0:
2077                                 teamradar_angle = view_angles.y - 90;
2078                                 break;
2079                         default:
2080                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2081                                 break;
2082                 }
2083         }
2084
2085         vector pos, mySize;
2086         pos = panel_pos;
2087         mySize = panel_size;
2088
2089         HUD_Panel_DrawBg(1);
2090         if(panel_bg_padding)
2091         {
2092                 pos += '1 1 0' * panel_bg_padding;
2093                 mySize -= '2 2 0' * panel_bg_padding;
2094         }
2095
2096         float color2;
2097         entity tm;
2098         float scale2d, normalsize, bigsize;
2099
2100         teamradar_origin2d = pos + 0.5 * mySize;
2101         teamradar_size2d = mySize;
2102
2103         if(minimapname == "")
2104                 return;
2105
2106         teamradar_loadcvars();
2107
2108         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2109         teamradar_size2d = mySize;
2110
2111         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2112
2113         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2114         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2115         {
2116                 // max-min distance must fit the radar in any rotation
2117                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2118         }
2119         else
2120         {
2121                 vector c0, c1, c2, c3, span;
2122                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2123                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2124                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2125                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2126                 span = '0 0 0';
2127                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2128                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2129
2130                 // max-min distance must fit the radar in x=x, y=y
2131                 bigsize = min(
2132                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2133                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2134                 );
2135         }
2136
2137         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2138         if(bigsize > normalsize)
2139                 normalsize = bigsize;
2140
2141         teamradar_size =
2142                   f * bigsize
2143                 + (1 - f) * normalsize;
2144         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2145                   f * mi_center
2146                 + (1 - f) * view_origin);
2147
2148         drawsetcliparea(
2149                 pos.x,
2150                 pos.y,
2151                 mySize.x,
2152                 mySize.y
2153         );
2154
2155         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2156
2157         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2158                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2159         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2160                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2161         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2162         {
2163                 color2 = GetPlayerColor(tm.sv_entnum);
2164                 //if(color == NUM_SPECTATOR || color == color2)
2165                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2166         }
2167         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2168
2169         drawresetcliparea();
2170 }
2171
2172 // Score (#7)
2173 //
2174 void HUD_UpdatePlayerTeams();
2175 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2176 {
2177         float score;
2178         entity tm = world, pl;
2179         float SCOREPANEL_MAX_ENTRIES = 6;
2180         float SCOREPANEL_ASPECTRATIO = 2;
2181         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2182         vector fontsize = '1 1 0' * (mySize.y/entries);
2183
2184         vector rgb, score_color;
2185         rgb = '1 1 1';
2186         score_color = '1 1 1';
2187
2188         float name_size = mySize.x*0.75;
2189         float spacing_size = mySize.x*0.04;
2190         const float highlight_alpha = 0.2;
2191         float i = 0, me_printed = 0, first_pl = 0;
2192         string s;
2193         if (autocvar__hud_configure)
2194         {
2195                 float players_per_team = 0;
2196                 if (team_count)
2197                 {
2198                         // show team scores in the first line
2199                         float score_size = mySize.x / team_count;
2200                         players_per_team = max(2, ceil((entries - 1) / team_count));
2201                         for(i=0; i<team_count; ++i) {
2202                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2203                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2204                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2205                         }
2206                         first_pl = 1;
2207                         pos.y += fontsize.y;
2208                 }
2209                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2210                 for (i=first_pl; i<entries; ++i)
2211                 {
2212                         //simulate my score is lower than all displayed players,
2213                         //so that I don't appear at all showing pure rankings.
2214                         //This is to better show the difference between the 2 ranking views
2215                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2216                         {
2217                                 rgb = '1 1 0';
2218                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2219                                 s = GetPlayerName(player_localnum);
2220                                 score = 7;
2221                         }
2222                         else
2223                         {
2224                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2225                                 score -= 3;
2226                         }
2227
2228                         if (team_count)
2229                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2230                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2231                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2232                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2233                         pos.y += fontsize.y;
2234                 }
2235                 return;
2236         }
2237
2238         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2239                 HUD_UpdatePlayerTeams();
2240         if (team_count)
2241         {
2242                 // show team scores in the first line
2243                 float score_size = mySize.x / team_count;
2244                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2245                         if(tm.team == NUM_SPECTATOR)
2246                                 continue;
2247                         if (tm.team == myteam)
2248                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2249                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2250                         ++i;
2251                 }
2252                 first_pl = 1;
2253                 pos.y += fontsize.y;
2254                 tm = teams.sort_next;
2255         }
2256         i = first_pl;
2257
2258         do
2259         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2260         {
2261                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2262                         continue;
2263
2264                 if (i == entries-1 && !me_printed && pl != me)
2265                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2266                 {
2267                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2268                                 if (pl.team != NUM_SPECTATOR)
2269                                         break;
2270
2271                         if (pl)
2272                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2273                         else
2274                                 rgb = '1 0 0'; //last: red
2275                         pl = me;
2276                 }
2277
2278                 if (pl == me)
2279                 {
2280                         if (i == first_pl)
2281                                 rgb = '0 1 0'; //first: green
2282                         me_printed = 1;
2283                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2284                 }
2285                 if (team_count)
2286                         score_color = Team_ColorRGB(pl.team) * 0.8;
2287                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2288                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2289                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2290                 pos.y += fontsize.y;
2291                 ++i;
2292         }
2293         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2294 }
2295
2296 void HUD_Score(void)
2297 {
2298         if(!autocvar__hud_configure)
2299         {
2300                 if(!autocvar_hud_panel_score) return;
2301                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2302         }
2303
2304         HUD_Panel_UpdateCvars();
2305         vector pos, mySize;
2306         pos = panel_pos;
2307         mySize = panel_size;
2308
2309         HUD_Panel_DrawBg(1);
2310         if(panel_bg_padding)
2311         {
2312                 pos += '1 1 0' * panel_bg_padding;
2313                 mySize -= '2 2 0' * panel_bg_padding;
2314         }
2315
2316         float score, distribution = 0;
2317         string sign;
2318         vector distribution_color;
2319         entity tm, pl, me;
2320
2321         me = playerslots[player_localentnum - 1];
2322
2323         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2324                 string timer, distrtimer;
2325
2326                 pl = players.sort_next;
2327                 if(pl == me)
2328                         pl = pl.sort_next;
2329                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2330                         if(pl.scores[ps_primary] == 0)
2331                                 pl = world;
2332
2333                 score = me.(scores[ps_primary]);
2334                 timer = TIME_ENCODED_TOSTRING(score);
2335
2336                 draw_beginBoldFont();
2337                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2338                         // distribution display
2339                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2340
2341                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2342
2343                         if (distribution <= 0) {
2344                                 distribution_color = '0 1 0';
2345                                 sign = "-";
2346                         }
2347                         else {
2348                                 distribution_color = '1 0 0';
2349                                 sign = "+";
2350                         }
2351                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2352                 }
2353                 // race record display
2354                 if (distribution <= 0)
2355                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2356                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2357                 draw_endBoldFont();
2358         } else if (!teamplay) { // non-teamgames
2359                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2360                 {
2361                         HUD_Score_Rankings(pos, mySize, me);
2362                         return;
2363                 }
2364                 // me vector := [team/connected frags id]
2365                 pl = players.sort_next;
2366                 if(pl == me)
2367                         pl = pl.sort_next;
2368
2369                 if(autocvar__hud_configure)
2370                         distribution = 42;
2371                 else if(pl)
2372                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2373                 else
2374                         distribution = 0;
2375
2376                 score = me.(scores[ps_primary]);
2377                 if(autocvar__hud_configure)
2378                         score = 123;
2379
2380                 if(distribution >= 5)
2381                         distribution_color = eY;
2382                 else if(distribution >= 0)
2383                         distribution_color = '1 1 1';
2384                 else if(distribution >= -5)
2385                         distribution_color = '1 1 0';
2386                 else
2387                         distribution_color = eX;
2388
2389                 string distribution_str;
2390                 distribution_str = ftos(distribution);
2391                 draw_beginBoldFont();
2392                 if (distribution >= 0)
2393                 {
2394                         if (distribution > 0)
2395                                 distribution_str = strcat("+", distribution_str);
2396                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2397                 }
2398                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2399                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2400                 draw_endBoldFont();
2401         } else { // teamgames
2402                 float row, column, rows = 0, columns = 0;
2403                 vector offset = '0 0 0';
2404                 vector score_pos, score_size; //for scores other than myteam
2405                 if(autocvar_hud_panel_score_rankings)
2406                 {
2407                         HUD_Score_Rankings(pos, mySize, me);
2408                         return;
2409                 }
2410                 if(spectatee_status == -1)
2411                 {
2412                         rows = HUD_GetRowCount(team_count, mySize, 3);
2413                         columns = ceil(team_count/rows);
2414                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2415
2416                         float newSize;
2417                         if(score_size.x/score_size.y > 3)
2418                         {
2419                                 newSize = 3 * score_size.y;
2420                                 offset.x = score_size.x - newSize;
2421                                 pos.x += offset.x/2;
2422                                 score_size.x = newSize;
2423                         }
2424                         else
2425                         {
2426                                 newSize = 1/3 * score_size.x;
2427                                 offset.y = score_size.y - newSize;
2428                                 pos.y += offset.y/2;
2429                                 score_size.y = newSize;
2430                         }
2431                 }
2432                 else
2433                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2434
2435                 float max_fragcount;
2436                 max_fragcount = -99;
2437                 draw_beginBoldFont();
2438                 row = column = 0;
2439                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2440                         if(tm.team == NUM_SPECTATOR)
2441                                 continue;
2442                         score = tm.(teamscores[ts_primary]);
2443                         if(autocvar__hud_configure)
2444                                 score = 123;
2445
2446                         if (score > max_fragcount)
2447                                 max_fragcount = score;
2448
2449                         if (spectatee_status == -1)
2450                         {
2451                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2452                                 if (max_fragcount == score)
2453                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2454                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2455                                 ++row;
2456                                 if(row >= rows)
2457                                 {
2458                                         row = 0;
2459                                         ++column;
2460                                 }
2461                         }
2462                         else if(tm.team == myteam) {
2463                                 if (max_fragcount == score)
2464                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2465                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2466                         } else {
2467                                 if (max_fragcount == score)
2468                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2469                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2470                                 ++rows;
2471                         }
2472                 }
2473                 draw_endBoldFont();
2474         }
2475 }
2476
2477 // Race timer (#8)
2478 //
2479 void HUD_RaceTimer (void)
2480 {
2481         if(!autocvar__hud_configure)
2482         {
2483                 if(!autocvar_hud_panel_racetimer) return;
2484                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2485                 if(spectatee_status == -1) return;
2486         }
2487
2488         HUD_Panel_UpdateCvars();
2489
2490         draw_beginBoldFont();
2491
2492         vector pos, mySize;
2493         pos = panel_pos;
2494         mySize = panel_size;
2495
2496         HUD_Panel_DrawBg(1);
2497         if(panel_bg_padding)
2498         {
2499                 pos += '1 1 0' * panel_bg_padding;
2500                 mySize -= '2 2 0' * panel_bg_padding;
2501         }
2502
2503         // always force 4:1 aspect
2504         vector newSize = '0 0 0';
2505         if(mySize.x/mySize.y > 4)
2506         {
2507                 newSize.x = 4 * mySize.y;
2508                 newSize.y = mySize.y;
2509
2510                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2511         }
2512         else
2513         {
2514                 newSize.y = 1/4 * mySize.x;
2515                 newSize.x = mySize.x;
2516
2517                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2518         }
2519         mySize = newSize;
2520
2521         float a, t;
2522         string s, forcetime;
2523
2524         if(autocvar__hud_configure)
2525         {
2526                 s = "0:13:37";
2527                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2528                 s = _("^1Intermediate 1 (+15.42)");
2529                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2530                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2531                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2532         }
2533         else if(race_checkpointtime)
2534         {
2535                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2536                 s = "";
2537                 forcetime = "";
2538                 if(a > 0) // just hit a checkpoint?
2539                 {
2540                         if(race_checkpoint != 254)
2541                         {
2542                                 if(race_time && race_previousbesttime)
2543                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2544                                 else
2545                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2546                                 if(race_time)
2547                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2548                         }
2549                 }
2550                 else
2551                 {
2552                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2553                         {
2554                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2555                                 if(a > 0) // next one?
2556                                 {
2557                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2558                                 }
2559                         }
2560                 }
2561
2562                 if(s != "" && a > 0)
2563                 {
2564                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2565                 }
2566
2567                 if(race_penaltytime)
2568                 {
2569                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2570                         if(a > 0)
2571                         {
2572                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2573                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2574                         }
2575                 }
2576
2577                 if(forcetime != "")
2578                 {
2579                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2580                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2581                 }
2582                 else
2583                         a = 1;
2584
2585                 if(race_laptime && race_checkpoint != 255)
2586                 {
2587                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2588                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2589                 }
2590         }
2591         else
2592         {
2593                 if(race_mycheckpointtime)
2594                 {
2595                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2596                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2597                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2598                 }
2599                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2600                 {
2601                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2602                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2603                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2604                 }
2605
2606                 if(race_penaltytime && !race_penaltyaccumulator)
2607                 {
2608                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2609                         a = bound(0, (1 + t - time), 1);
2610                         if(a > 0)
2611                         {
2612                                 if(time < t)
2613                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2614                                 else
2615                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2616                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2617                         }
2618                 }
2619         }
2620
2621         draw_endBoldFont();
2622 }
2623
2624 // Vote window (#9)
2625 //
2626 float vote_yescount;
2627 float vote_nocount;
2628 float vote_needed;
2629 float vote_highlighted; // currently selected vote
2630
2631 float vote_active; // is there an active vote?
2632 float vote_prev; // previous state of vote_active to check for a change
2633 float vote_alpha;
2634 float vote_change; // "time" when vote_active changed
2635
2636 void HUD_Vote(void)
2637 {
2638         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2639         {
2640                 vote_active = 1;
2641                 if (autocvar__hud_configure)
2642                 {
2643                         vote_yescount = 0;
2644                         vote_nocount = 0;
2645                         print(_("^1You must answer before entering hud configure mode\n"));
2646                         cvar_set("_hud_configure", "0");
2647                 }
2648                 if(vote_called_vote)
2649                         strunzone(vote_called_vote);
2650                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2651                 uid2name_dialog = 1;
2652         }
2653
2654         if(!autocvar__hud_configure)
2655         {
2656                 if(!autocvar_hud_panel_vote) return;
2657
2658                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2659                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2660
2661                 if(panel_bg_alpha_str == "") {
2662                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2663                 }
2664                 panel_bg_alpha = stof(panel_bg_alpha_str);
2665         }
2666         else
2667         {
2668                 vote_yescount = 3;
2669                 vote_nocount = 2;
2670                 vote_needed = 4;
2671         }
2672
2673         string s;
2674         float a;
2675         if(vote_active != vote_prev) {
2676                 vote_change = time;
2677                 vote_prev = vote_active;
2678         }
2679
2680         if(vote_active || autocvar__hud_configure)
2681                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2682         else
2683                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2684
2685         if(!vote_alpha)
2686                 return;
2687
2688         HUD_Panel_UpdateCvars();
2689
2690         if(uid2name_dialog)
2691         {
2692                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2693                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2694         }
2695
2696     // these must be below above block
2697         vector pos, mySize;
2698         pos = panel_pos;
2699         mySize = panel_size;
2700
2701         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2702         HUD_Panel_DrawBg(a);
2703         a = panel_fg_alpha * a;
2704
2705         if(panel_bg_padding)
2706         {
2707                 pos += '1 1 0' * panel_bg_padding;
2708                 mySize -= '2 2 0' * panel_bg_padding;
2709         }
2710
2711         // always force 3:1 aspect
2712         vector newSize = '0 0 0';
2713         if(mySize.x/mySize.y > 3)
2714         {
2715                 newSize.x = 3 * mySize.y;
2716                 newSize.y = mySize.y;
2717
2718                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2719         }
2720         else
2721         {
2722                 newSize.y = 1/3 * mySize.x;
2723                 newSize.x = mySize.x;
2724
2725                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2726         }
2727         mySize = newSize;
2728
2729         s = _("A vote has been called for:");
2730         if(uid2name_dialog)
2731                 s = _("Allow servers to store and display your name?");
2732         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2733         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2734         if(autocvar__hud_configure)
2735                 s = _("^1Configure the HUD");
2736         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2737
2738         // print the yes/no counts
2739     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2740         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2741     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2742         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2743
2744         // draw the progress bar backgrounds
2745         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2746
2747         // draw the highlights
2748         if(vote_highlighted == 1) {
2749                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2750                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2751         }
2752         else if(vote_highlighted == -1) {
2753                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2754                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2755         }
2756
2757         // draw the progress bars
2758         if(vote_yescount && vote_needed)
2759         {
2760                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2761                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2762         }
2763
2764         if(vote_nocount && vote_needed)
2765         {
2766                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2767                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2768         }
2769
2770         drawresetcliparea();
2771 }
2772
2773 // Mod icons panel (#10)
2774 //
2775
2776 float mod_active; // is there any active mod icon?
2777
2778 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, float i)
2779 {
2780         float stat = -1;
2781         string pic = "";
2782         vector color = '0 0 0';
2783         switch(i)
2784         {
2785                 case 0:
2786                         stat = getstati(STAT_REDALIVE);
2787                         pic = "player_red.tga";
2788                         color = '1 0 0';
2789                         break;
2790                 case 1:
2791                         stat = getstati(STAT_BLUEALIVE);
2792                         pic = "player_blue.tga";
2793                         color = '0 0 1';
2794                         break;
2795                 case 2:
2796                         stat = getstati(STAT_YELLOWALIVE);
2797                         pic = "player_yellow.tga";
2798                         color = '1 1 0';
2799                         break;
2800                 default:
2801                 case 3:
2802                         stat = getstati(STAT_PINKALIVE);
2803                         pic = "player_pink.tga";
2804                         color = '1 0 1';
2805                         break;
2806         }
2807
2808         if(mySize.x/mySize.y > aspect_ratio)
2809         {
2810                 i = aspect_ratio * mySize.y;
2811                 myPos.x = myPos.x + (mySize.x - i) / 2;
2812                 mySize.x = i;
2813         }
2814         else
2815         {
2816                 i = 1/aspect_ratio * mySize.x;
2817                 myPos.y = myPos.y + (mySize.y - i) / 2;
2818                 mySize.y = i;
2819         }
2820
2821         if(layout)
2822         {
2823                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2824                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2825         }
2826         else
2827                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2828 }
2829
2830 // Clan Arena and Freeze Tag HUD modicons
2831 void HUD_Mod_CA(vector myPos, vector mySize)
2832 {
2833         mod_active = 1; // required in each mod function that always shows something
2834
2835         int layout;
2836         if(gametype == MAPINFO_TYPE_CA)
2837                 layout = autocvar_hud_panel_modicons_ca_layout;
2838         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2839                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2840         float rows, columns, aspect_ratio;
2841         aspect_ratio = (layout) ? 2 : 1;
2842         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2843         columns = ceil(team_count/rows);
2844
2845         int i;
2846         float row = 0, column = 0;
2847         vector pos, itemSize;
2848         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2849         for(i=0; i<team_count; ++i)
2850         {
2851                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2852
2853                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2854
2855                 ++row;
2856                 if(row >= rows)
2857                 {
2858                         row = 0;
2859                         ++column;
2860                 }
2861         }
2862 }
2863
2864 // CTF HUD modicon section
2865 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2866 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2867 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2868
2869 void HUD_Mod_CTF_Reset(void)
2870 {
2871         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2872 }
2873
2874 void HUD_Mod_CTF(vector pos, vector mySize)
2875 {
2876         vector redflag_pos, blueflag_pos;
2877         vector flag_size;
2878         float f; // every function should have that
2879
2880         float redflag, blueflag; // current status
2881         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2882         float stat_items;
2883
2884         stat_items = getstati(STAT_ITEMS, 0, 24);
2885         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2886         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2887
2888         if(redflag || blueflag)
2889                 mod_active = 1;
2890         else
2891                 mod_active = 0;
2892
2893         if(autocvar__hud_configure)
2894         {
2895                 redflag = 1;
2896                 blueflag = 2;
2897         }
2898
2899         // when status CHANGES, set old status into prevstatus and current status into status
2900         if (redflag != redflag_prevframe)
2901         {
2902                 redflag_statuschange_time = time;
2903                 redflag_prevstatus = redflag_prevframe;
2904                 redflag_prevframe = redflag;
2905         }
2906
2907         if (blueflag != blueflag_prevframe)
2908         {
2909                 blueflag_statuschange_time = time;
2910                 blueflag_prevstatus = blueflag_prevframe;
2911                 blueflag_prevframe = blueflag;
2912         }
2913
2914         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2915         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2916
2917         float BLINK_FACTOR = 0.15;
2918         float BLINK_BASE = 0.85;
2919         // note:
2920         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2921         // thus
2922         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2923         // ensure RMS == 1
2924         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2925
2926         string red_icon, red_icon_prevstatus;
2927         float red_alpha, red_alpha_prevstatus;
2928         red_alpha = red_alpha_prevstatus = 1;
2929         switch(redflag) {
2930                 case 1: red_icon = "flag_red_taken"; break;
2931                 case 2: red_icon = "flag_red_lost"; break;
2932                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2933                 default:
2934                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2935                                 red_icon = "flag_red_shielded";
2936                         else
2937                                 red_icon = string_null;
2938                         break;
2939         }
2940         switch(redflag_prevstatus) {
2941                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2942                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2943                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2944                 default:
2945                         if(redflag == 3)
2946                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2947                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2948                                 red_icon_prevstatus = "flag_red_shielded";
2949                         else
2950                                 red_icon_prevstatus = string_null;
2951                         break;
2952         }
2953
2954         string blue_icon, blue_icon_prevstatus;
2955         float blue_alpha, blue_alpha_prevstatus;
2956         blue_alpha = blue_alpha_prevstatus = 1;
2957         switch(blueflag) {
2958                 case 1: blue_icon = "flag_blue_taken"; break;
2959                 case 2: blue_icon = "flag_blue_lost"; break;
2960                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2961                 default:
2962                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2963                                 blue_icon = "flag_blue_shielded";
2964                         else
2965                                 blue_icon = string_null;
2966                         break;
2967         }
2968         switch(blueflag_prevstatus) {
2969                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2970                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2971                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2972                 default:
2973                         if(blueflag == 3)
2974                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2975                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2976                                 blue_icon_prevstatus = "flag_blue_shielded";
2977                         else
2978                                 blue_icon_prevstatus = string_null;
2979                         break;
2980         }
2981
2982         if(mySize.x > mySize.y) {
2983                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2984                         redflag_pos = pos;
2985                         blueflag_pos = pos + eX * 0.5 * mySize.x;
2986                 } else {
2987                         blueflag_pos = pos;
2988                         redflag_pos = pos + eX * 0.5 * mySize.x;
2989                 }
2990                 flag_size = eX * 0.5 * mySize.x + eY * mySize.y;
2991         } else {
2992                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2993                         redflag_pos = pos;
2994                         blueflag_pos = pos + eY * 0.5 * mySize.y;
2995                 } else {
2996                         blueflag_pos = pos;
2997                         redflag_pos = pos + eY * 0.5 * mySize.y;
2998                 }
2999                 flag_size = eY * 0.5 * mySize.y + eX * mySize.x;
3000         }
3001
3002         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
3003         if(red_icon_prevstatus && f < 1)
3004                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
3005         if(red_icon)
3006                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
3007
3008         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
3009         if(blue_icon_prevstatus && f < 1)
3010                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
3011         if(blue_icon)
3012                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
3013 }
3014
3015 // Keyhunt HUD modicon section
3016 vector KH_SLOTS[4];
3017
3018 void HUD_Mod_KH(vector pos, vector mySize)
3019 {
3020         mod_active = 1; // keyhunt should never hide the mod icons panel
3021
3022         // Read current state
3023
3024         float state = getstati(STAT_KH_KEYS);
3025         float i, key_state;
3026         float all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3027         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3028
3029         for(i = 0; i < 4; ++i)
3030         {
3031                 key_state = (bitshift(state, i * -5) & 31) - 1;
3032
3033                 if(key_state == -1)
3034                         continue;
3035
3036                 if(key_state == 30)
3037                 {
3038                         ++carrying_keys;
3039                         key_state = myteam;
3040                 }
3041
3042                 switch(key_state)
3043                 {
3044                         case NUM_TEAM_1: ++team1_keys; break;
3045                         case NUM_TEAM_2: ++team2_keys; break;
3046                         case NUM_TEAM_3: ++team3_keys; break;
3047                         case NUM_TEAM_4: ++team4_keys; break;
3048                         case 29: ++dropped_keys; break;
3049                 }
3050
3051                 ++all_keys;
3052         }
3053
3054         // Calculate slot measurements
3055
3056         vector slot_size;
3057
3058         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3059         {
3060                 // Quadratic arrangement
3061                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3062                 KH_SLOTS[0] = pos;
3063                 KH_SLOTS[1] = pos + eX * slot_size.x;
3064                 KH_SLOTS[2] = pos + eY * slot_size.y;
3065                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3066         }
3067         else
3068         {
3069                 if(mySize.x > mySize.y)
3070                 {
3071                         // Horizontal arrangement
3072                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3073                         for(i = 0; i < all_keys; ++i)
3074                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3075                 }
3076                 else
3077                 {
3078                         // Vertical arrangement
3079                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3080                         for(i = 0; i < all_keys; ++i)
3081                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3082                 }
3083         }
3084
3085         // Make icons blink in case of RUN HERE
3086
3087         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3088         float alpha;
3089         alpha = 1;
3090
3091         if(carrying_keys)
3092                 switch(myteam)
3093                 {
3094                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3095                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3096                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3097                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3098                 }
3099
3100         // Draw icons
3101
3102         i = 0;
3103
3104         while(team1_keys--)
3105                 if(myteam == NUM_TEAM_1 && carrying_keys)
3106                 {
3107                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3108                         --carrying_keys;
3109                 }
3110                 else
3111                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3112
3113         while(team2_keys--)
3114                 if(myteam == NUM_TEAM_2 && carrying_keys)
3115                 {
3116                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3117                         --carrying_keys;
3118                 }
3119                 else
3120                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3121
3122         while(team3_keys--)
3123                 if(myteam == NUM_TEAM_3 && carrying_keys)
3124                 {
3125                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3126                         --carrying_keys;
3127                 }
3128                 else
3129                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3130
3131         while(team4_keys--)
3132                 if(myteam == NUM_TEAM_4 && carrying_keys)
3133                 {
3134                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3135                         --carrying_keys;
3136                 }
3137                 else
3138                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3139
3140         while(dropped_keys--)
3141                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3142 }
3143
3144 // Keepaway HUD mod icon
3145 float kaball_prevstatus; // last remembered status
3146 float kaball_statuschange_time; // time when the status changed
3147
3148 // we don't need to reset for keepaway since it immediately
3149 // autocorrects prevstatus as to if the player has the ball or not
3150
3151 void HUD_Mod_Keepaway(vector pos, vector mySize)
3152 {
3153         mod_active = 1; // keepaway should always show the mod HUD
3154
3155         float BLINK_FACTOR = 0.15;
3156         float BLINK_BASE = 0.85;
3157         float BLINK_FREQ = 5;
3158         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3159
3160         float stat_items = getstati(STAT_ITEMS, 0, 24);
3161         float kaball = (stat_items/IT_KEY1) & 1;
3162
3163         if(kaball != kaball_prevstatus)
3164         {
3165                 kaball_statuschange_time = time;
3166                 kaball_prevstatus = kaball;
3167         }
3168
3169         vector kaball_pos, kaball_size;
3170
3171         if(mySize.x > mySize.y) {
3172                 kaball_pos = pos + eX * 0.25 * mySize.x;
3173                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3174         } else {
3175                 kaball_pos = pos + eY * 0.25 * mySize.y;
3176                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3177         }
3178
3179         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3180         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3181
3182         if(kaball_prevstatus && f < 1)
3183                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3184
3185         if(kaball)
3186                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3187 }
3188
3189
3190 // Nexball HUD mod icon
3191 void HUD_Mod_NexBall(vector pos, vector mySize)
3192 {
3193         float stat_items, nb_pb_starttime, dt, p;
3194
3195         stat_items = getstati(STAT_ITEMS, 0, 24);
3196         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3197
3198         if (stat_items & IT_KEY1)
3199                 mod_active = 1;
3200         else
3201                 mod_active = 0;
3202
3203         //Manage the progress bar if any
3204         if (nb_pb_starttime > 0)
3205         {
3206                 dt = (time - nb_pb_starttime) % nb_pb_period;
3207                 // one period of positive triangle
3208                 p = 2 * dt / nb_pb_period;
3209                 if (p > 1)
3210                         p = 2 - p;
3211
3212                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3213         }
3214
3215         if (stat_items & IT_KEY1)
3216                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3217 }
3218
3219 // Race/CTS HUD mod icons
3220 float crecordtime_prev; // last remembered crecordtime
3221 float crecordtime_change_time; // time when crecordtime last changed
3222 float srecordtime_prev; // last remembered srecordtime
3223 float srecordtime_change_time; // time when srecordtime last changed
3224
3225 float race_status_time;
3226 float race_status_prev;
3227 string race_status_name_prev;
3228 void HUD_Mod_Race(vector pos, vector mySize)
3229 {
3230         mod_active = 1; // race should never hide the mod icons panel
3231         entity me;
3232         me = playerslots[player_localnum];
3233         float t, score;
3234         float f; // yet another function has this
3235         score = me.(scores[ps_primary]);
3236
3237         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3238                 return; // no records in the actual race
3239
3240         // clientside personal record
3241         string rr;
3242         if(gametype == MAPINFO_TYPE_CTS)
3243                 rr = CTS_RECORD;
3244         else
3245                 rr = RACE_RECORD;
3246         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3247
3248         if(score && (score < t || !t)) {
3249                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3250                 if(autocvar_cl_autodemo_delete_keeprecords)
3251                 {
3252                         f = autocvar_cl_autodemo_delete;
3253                         f &= ~1;
3254                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3255                 }
3256         }
3257
3258         if(t != crecordtime_prev) {
3259                 crecordtime_prev = t;
3260                 crecordtime_change_time = time;
3261         }
3262
3263         vector textPos, medalPos;
3264         float squareSize;
3265         if(mySize.x > mySize.y) {
3266                 // text on left side
3267                 squareSize = min(mySize.y, mySize.x/2);
3268                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3269                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3270         } else {
3271                 // text on top
3272                 squareSize = min(mySize.x, mySize.y/2);
3273                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3274                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3275         }
3276
3277         f = time - crecordtime_change_time;
3278
3279         if (f > 1) {
3280                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3281                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3282         } else {
3283                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3284                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3285                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3286                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3287         }
3288
3289         // server record
3290         t = race_server_record;
3291         if(t != srecordtime_prev) {
3292                 srecordtime_prev = t;
3293                 srecordtime_change_time = time;
3294         }
3295         f = time - srecordtime_change_time;
3296
3297         if (f > 1) {
3298                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3299                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3300         } else {
3301                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3302                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3303                 drawstring_aspect_expanding(textPos + eY * 0.5 *