allow hiding text in these cases too
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / hud.qc
1 /*
2 ==================
3 Misc HUD functions
4 ==================
5 */
6
7 // a border picture is a texture containing nine parts:
8 //   1/4 width: left part
9 //   1/2 width: middle part (stretched)
10 //   1/4 width: right part
11 // divided into
12 //   1/4 height: top part
13 //   1/2 height: middle part (stretched)
14 //   1/4 height: bottom part
15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
16 {
17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
18     {
19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
20                 return;
21     }
22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
23         {
24                 // draw only the central part
25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
26                 return;
27         }
28
29         vector dX, dY;
30         vector width, height;
31         vector bW, bH;
32         //pic = draw_UseSkinFor(pic);
33         width = eX * theSize_x;
34         height = eY * theSize_y;
35         if(theSize_x <= theBorderSize_x * 2)
36         {
37                 // not wide enough... draw just left and right then
38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
39                 if(theSize_y <= theBorderSize_y * 2)
40                 {
41                         // not high enough... draw just corners
42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
47                 }
48                 else
49                 {
50                         dY = theBorderSize_x * eY;
51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
57                 }
58         }
59         else
60         {
61                 if(theSize_y <= theBorderSize_y * 2)
62                 {
63                         // not high enough... draw just top and bottom then
64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
65                         dX = theBorderSize_x * eX;
66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
72                 }
73                 else
74                 {
75                         dX = theBorderSize_x * eX;
76                         dY = theBorderSize_x * eY;
77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
86                 }
87         }
88 }
89
90 vector HUD_Get_Num_Color (float x, float maxvalue)
91 {
92         vector color;
93         if(x > maxvalue) {
94                 color_x = 0;
95                 color_y = 1;
96                 color_z = 0;
97         }
98         else if(x > maxvalue * 0.75) {
99                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
100                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
101                 color_z = 0;
102         }
103         else if(x > maxvalue * 0.5) {
104                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
105                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
106                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
107         }
108         else if(x > maxvalue * 0.25) {
109                 color_x = 1;
110                 color_y = 1;
111                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
112         }
113         else if(x > maxvalue * 0.1) {
114                 color_x = 1;
115                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
116                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
117         }
118         else {
119                 color_x = 1;
120                 color_y = 0;
121                 color_z = 0;
122         }
123         return color;
124 }
125
126 float stringwidth_colors(string s, vector theSize)
127 {
128         return stringwidth(s, TRUE, theSize);
129 }
130
131 float stringwidth_nocolors(string s, vector theSize)
132 {
133         return stringwidth(s, FALSE, theSize);
134 }
135
136 #define CENTERPRINT_MAX_LINES 30
137 string centerprint_messages[CENTERPRINT_MAX_LINES];
138 float centerprint_width[CENTERPRINT_MAX_LINES];
139 float centerprint_time;
140 float centerprint_expire;
141 float centerprint_num;
142 float centerprint_offset_hint;
143 vector centerprint_fontsize;
144
145 void centerprint(string strMessage)
146 {
147         float i, j, n, hcount;
148         string s;
149
150         centerprint_fontsize = HUD_GetFontsize("scr_centersize");
151
152         centerprint_expire = min(centerprint_expire, time); // if any of the returns happens, this message will fade out
153
154         if(cvar("scr_centertime") <= 0)
155                 return;
156
157         if(strMessage == "")
158                 return;
159
160         // strip trailing newlines
161         j = strlen(strMessage) - 1;
162         while(substring(strMessage, j, 1) == "\n" && j >= 0)
163                 j = j - 1;
164         strMessage = substring(strMessage, 0, j + 1);
165
166         if(strMessage == "")
167                 return;
168
169         // strip leading newlines and remember them, they are a hint that the message should be lower on the screen
170         j = 0;
171         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
172                 j = j + 1;
173         strMessage = substring(strMessage, j, strlen(strMessage) - j);
174         centerprint_offset_hint = j;
175
176         if(strMessage == "")
177                 return;
178
179         // if we get here, we have a message. Initialize its height.
180         centerprint_num = 0;
181
182         n = tokenizebyseparator(strMessage, "\n");
183         i = hcount = 0;
184         for(j = 0; j < n; ++j)
185         {
186                 getWrappedLine_remaining = argv(j);
187                 while(getWrappedLine_remaining)
188                 {
189                         s = getWrappedLine(vid_conwidth * 0.75, centerprint_fontsize, stringwidth_colors);
190                         if(centerprint_messages[i] != s) // don't fade the same message in, looks stupid
191                                 centerprint_time = time;
192                         if(centerprint_messages[i])
193                                 strunzone(centerprint_messages[i]);
194                         centerprint_messages[i] = strzone(s);
195                         centerprint_width[i] = stringwidth(s, TRUE, centerprint_fontsize);
196                         ++i;
197
198                         // half height for empty lines looks better
199                         if(s == "")
200                                 hcount += 0.5;
201                         else
202                                 hcount += 1;
203
204                         if(i >= CENTERPRINT_MAX_LINES)
205                                 break;
206                 }
207         }
208
209         float h, havail;
210         h = centerprint_fontsize_y*hcount;
211
212         havail = vid_conheight;
213         if(cvar("con_chatpos") < 0)
214                 havail -= (-cvar("con_chatpos") + cvar("con_chat")) * cvar("con_chatsize"); // avoid overlapping chat
215         if(havail > vid_conheight - 70)
216                 havail = vid_conheight - 70; // avoid overlapping HUD
217
218 #if 0
219         float forbiddenmin, forbiddenmax, allowedmin, allowedmax, preferred;
220
221         // here, the centerprint would cover the crosshair. REALLY BAD.
222         forbiddenmin = vid_conheight * 0.5 - h - 16;
223         forbiddenmax = vid_conheight * 0.5 + 16;
224
225         allowedmin = scoreboard_bottom;
226         allowedmax = havail - h;
227         preferred = (havail - h)/2;
228
229
230         // possible orderings (total: 4! / 4 = 6)
231         //  allowedmin allowedmax forbiddenmin forbiddenmax
232         //  forbiddenmin forbiddenmax allowedmin allowedmax
233         if(allowedmax < forbiddenmin || allowedmin > forbiddenmax)
234         {
235                 // forbidden doesn't matter in this case
236                 centerprint_start_y = bound(allowedmin, preferred, allowedmax);
237         }
238         //  allowedmin forbiddenmin allowedmax forbiddenmax
239         else if(allowedmin < forbiddenmin && allowedmax < forbiddenmax)
240         {
241                 centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
242         }
243         //  allowedmin forbiddenmin forbiddenmax allowedmax
244         else if(allowedmin < forbiddenmin)
245         {
246                 // make sure the forbidden zone is not covered
247                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
248                         centerprint_start_y = bound(allowedmin, preferred, forbiddenmin);
249                 else
250                         centerprint_start_y = bound(forbiddenmax, preferred, allowedmin);
251         }
252         //  forbiddenmin allowedmin allowedmax forbiddenmax
253         else if(allowedmax < forbiddenmax)
254         {
255                 // it's better to leave the allowed zone (overlap with scoreboard) than
256                 // to cover the forbidden zone (crosshair)
257                 if(preferred > (forbiddenmin + forbiddenmax) * 0.5)
258                         centerprint_start_y = forbiddenmax;
259                 else
260                         centerprint_start_y = forbiddenmin;
261         }
262         //  forbiddenmin allowedmin forbiddenmax allowedmax
263         else
264         {
265                 centerprint_start_y = bound(forbiddenmax, preferred, allowedmax);
266         }
267 #else
268 #endif
269
270         centerprint_num = i;
271
272         centerprint_expire = time + cvar("scr_centertime");
273 }
274
275 void HUD_DrawCenterPrint (void)
276 {
277         float i;
278         vector pos;
279         string ts;
280         float a, sz;
281
282         if(time - centerprint_time < 0.25)
283                 a = (time - centerprint_time) / 0.25;
284         else
285                 a = bound(0, 1 - 4 * (time - centerprint_expire), 1);
286
287         if(a <= 0)
288                 return;
289
290         sz = 0.8 + (a / 5);
291
292         if(centerprint_num * cvar("scr_centersize") > 24 && scoreboard_active) // 24 = height of Scoreboard text
293                 centerprint_start_y = scoreboard_bottom + centerprint_fontsize_y;
294
295         pos = centerprint_start;
296         for (i=0; i<centerprint_num; i = i + 1)
297         {
298                 ts = centerprint_messages[i];
299                 drawfontscale = sz * '1 1 0';
300                 drawfont = hud_bigfont;
301                 pos_x = (vid_conwidth - stringwidth(ts, TRUE, centerprint_fontsize)) * 0.5;
302                 if (ts != "")
303                 {
304                         drawcolorcodedstring(pos + '0 1 0' * (1 - sz) * 0.5 *centerprint_fontsize_y, ts, centerprint_fontsize, a, DRAWFLAG_NORMAL);
305                         pos_y = pos_y + centerprint_fontsize_y;
306                 }
307                 else
308                         // half height for empty lines looks better
309                         pos_y = pos_y + sz * centerprint_fontsize_y * 0.5;
310                 drawfontscale = '1 1 0';
311                 drawfont = hud_font;
312         }
313 }
314
315 void drawstringright(vector position, string text, vector scale, vector rgb, float alpha, float flag)
316 {
317         position_x -= 2 / 3 * strlen(text) * scale_x;
318         drawstring(position, text, scale, rgb, alpha, flag);
319 }
320
321 void drawstringcenter(vector position, string text, vector scale, vector rgb, float alpha, float flag)
322 {
323         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
324         drawstring(position, text, scale, rgb, alpha, flag);
325 }
326
327 // return the string of the given race place
328 string race_PlaceName(float pos) {
329         if(pos == 1)
330                 return "1st";
331         else if(pos == 2)
332                 return "2nd";
333         else if(pos == 3)
334                 return "3rd";
335         else
336                 return strcat(ftos(pos), "th");
337 }
338
339 // return the string of the onscreen race timer
340 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
341 {
342         string col;
343         string timestr;
344         string cpname;
345         string lapstr;
346         lapstr = "";
347
348         if(histime == 0) // goal hit
349         {
350                 if(mytime > 0)
351                 {
352                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
353                         col = "^1";
354                 }
355                 else if(mytime == 0)
356                 {
357                         timestr = "+0.0";
358                         col = "^3";
359                 }
360                 else
361                 {
362                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
363                         col = "^2";
364                 }
365
366                 if(lapdelta > 0)
367                 {
368                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
369                         col = "^2";
370                 }
371                 else if(lapdelta < 0)
372                 {
373                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
374                         col = "^1";
375                 }
376         }
377         else if(histime > 0) // anticipation
378         {
379                 if(mytime >= histime)
380                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
381                 else
382                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
383                 col = "^3";
384         }
385         else
386                 col = "^7";
387
388         if(cp == 254)
389                 cpname = "Start line";
390         else if(cp == 255)
391                 cpname = "Finish line";
392         else if(cp)
393                 cpname = strcat("Intermediate ", ftos(cp));
394         else
395                 cpname = "Finish line";
396
397         if(histime < 0)
398                 return strcat(col, cpname);
399         else if(hisname == "")
400                 return strcat(col, cpname, " (", timestr, ")");
401         else
402                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
403 }
404
405 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
406 float race_CheckName(string net_name) {
407         float i;
408         for (i=RANKINGS_CNT-1;i>=0;--i)
409                 if(grecordholder[i] == net_name)
410                         return i+1;
411         return 0;
412 }
413
414 /*
415 ==================
416 HUD panels
417 ==================
418 */
419
420 #define HUD_Write(s) fputs(fh, s)
421 // q: quoted, n: not quoted
422 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
423 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
424 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
425 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
426 // Save the config
427 void HUD_Panel_ExportCfg(string cfgname)
428 {
429         float fh;
430         string filename = strcat("hud_", cvar_string("hud_skin"), "_", cfgname, ".cfg");
431         fh = fopen(filename, FILE_WRITE);
432         if(fh >= 0)
433         {
434                 HUD_Write_Cvar_q("hud_skin");
435                 HUD_Write_Cvar_q("hud_panel_bg");
436                 HUD_Write_Cvar_q("hud_panel_bg_color");
437                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
438                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
439                 HUD_Write_Cvar_q("hud_panel_bg_border");
440                 HUD_Write_Cvar_q("hud_panel_bg_padding");
441                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
442                 HUD_Write("\n");
443
444                 HUD_Write_Cvar_q("hud_dock");
445                 HUD_Write_Cvar_q("hud_dock_color");
446                 HUD_Write_Cvar_q("hud_dock_color_team");
447                 HUD_Write_Cvar_q("hud_dock_alpha");
448                 HUD_Write("\n");
449
450                 HUD_Write_Cvar_q("hud_progressbar_alpha");
451                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
452                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
453                 HUD_Write_Cvar_q("hud_progressbar_health_color");
454                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
455                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
456                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
457                 HUD_Write("\n");
458
459                 HUD_Write_Cvar_q("_hud_panelorder");
460                 HUD_Write("\n");
461
462                 HUD_Write_Cvar_q("hud_configure_grid");
463                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
464                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
465                 HUD_Write("\n");
466
467                 HUD_Write_Cvar_q("scr_centerpos");
468                 HUD_Write("\n");
469
470                 // common cvars for all panels
471                 float i;
472                 for (i = 0; i < HUD_PANEL_NUM; ++i)
473                 {
474                         HUD_Panel_GetName(i);
475
476                         HUD_Write_PanelCvar_n("");
477                         HUD_Write_PanelCvar_q("_pos");
478                         HUD_Write_PanelCvar_q("_size");
479                         HUD_Write_PanelCvar_q("_bg");
480                         HUD_Write_PanelCvar_q("_bg_color");
481                         HUD_Write_PanelCvar_q("_bg_color_team");
482                         HUD_Write_PanelCvar_q("_bg_alpha");
483                         HUD_Write_PanelCvar_q("_bg_border");
484                         HUD_Write_PanelCvar_q("_bg_padding");
485                         switch(i) {
486                                 case HUD_PANEL_WEAPONS:
487                                         HUD_Write_PanelCvar_q("_complainbubble");
488                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
489                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
490                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
491                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
492                                         HUD_Write_PanelCvar_q("_ammo_color");
493                                         HUD_Write_PanelCvar_q("_ammo_alpha");
494                                         HUD_Write_PanelCvar_q("_aspect");
495                                         break;
496                                 case HUD_PANEL_AMMO:
497                                         HUD_Write_PanelCvar_q("_onlycurrent");
498                                         HUD_Write_PanelCvar_q("_iconalign");
499                                         break;
500                                 case HUD_PANEL_POWERUPS:
501                                         HUD_Write_PanelCvar_q("_flip");
502                                         HUD_Write_PanelCvar_q("_iconalign");
503                                         HUD_Write_PanelCvar_q("_baralign");
504                                         HUD_Write_PanelCvar_q("_progressbar");
505                                         HUD_Write_PanelCvar_q("_progressbar_strength");
506                                         HUD_Write_PanelCvar_q("_progressbar_shield");
507                                         break;
508                                 case HUD_PANEL_HEALTHARMOR:
509                                         HUD_Write_PanelCvar_q("_flip");
510                                         HUD_Write_PanelCvar_q("_iconalign");
511                                         HUD_Write_PanelCvar_q("_baralign");
512                                         HUD_Write_PanelCvar_q("_progressbar");
513                                         HUD_Write_PanelCvar_q("_progressbar_health");
514                                         HUD_Write_PanelCvar_q("_progressbar_armor");
515                                         HUD_Write_PanelCvar_q("_text");
516                                         break;
517                                 case HUD_PANEL_NOTIFY:
518                                         HUD_Write_PanelCvar_q("_flip");
519                                         HUD_Write_PanelCvar_q("_print");
520                                         break;
521                                 case HUD_PANEL_RADAR:
522                                         HUD_Write_PanelCvar_q("_foreground_alpha");
523                                         break;
524                                 case HUD_PANEL_VOTE:
525                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
526                                         break;
527                                 case HUD_PANEL_PRESSEDKEYS:
528                                         HUD_Write_PanelCvar_q("_aspect");
529                                         break;
530                                 case HUD_PANEL_INFOMESSAGES:
531                                         HUD_Write_PanelCvar_q("_flip");
532                                         break;
533                         }
534                         HUD_Write("\n");
535                 }
536                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
537
538                 print("^2Successfully exported to ", filename, "! (Note: It's saved in data/data/)\n");
539                 fclose(fh);
540         }
541         else
542                 print("^1Couldn't write to ", filename, "\n");
543 }
544
545 const float hlBorderSize = 4;
546 const string hlBorder = "gfx/hud/default/border_highlighted";
547 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
548 void HUD_Panel_HlBorder(float myBorder, vector color, float alpha)
549 {
550         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * alpha, DRAWFLAG_NORMAL);
551         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
552         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
553         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
554         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
555 }
556
557 // draw the background/borders
558 #define HUD_Panel_DrawBg(alpha)\
559 if(panel_bg != "0")\
560         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * alpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
561 if(highlightedPanel_prev == active_panel && autocvar__hud_configure)\
562 {\
563         HUD_Panel_HlBorder(panel_bg_border + 1.5 * hlBorderSize, '0 0.5 1', 0.25 * (1 - autocvar__menu_alpha) * alpha);\
564 } ENDS_WITH_CURLY_BRACE
565
566 void HUD_Panel_DrawProgressBar(vector pos, vector mySize, string pic, float vertical, float barflip, float x, vector color, float alpha, float drawflag)
567 {
568         if(!alpha || x == 0)
569                 return;
570
571     x = bound(0, x, 1);
572
573         if(vertical) {
574                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
575                 if(precache_pic(pic) == "") {
576                         pic = "gfx/hud/default/statusbar_vertical";
577                 }
578
579         if(barflip)
580             drawsetcliparea(pos_x, pos_y + mySize_y * (1 - x), mySize_x, mySize_y * x);
581         else
582             drawsetcliparea(pos_x, pos_y, mySize_x, mySize_y * x);
583         } else {
584                 pic = strcat(hud_skin_path, "/", pic);
585                 if(precache_pic(pic) == "") {
586                         pic = "gfx/hud/default/statusbar";
587                 }
588
589         if(barflip)
590             drawsetcliparea(pos_x + mySize_x * (1 - x), pos_y, mySize_x * x, mySize_y);
591         else
592             drawsetcliparea(pos_x, pos_y, mySize_x * x, mySize_y);
593         }
594
595     drawpic(pos, pic, mySize, color, alpha, drawflag);
596     drawresetcliparea();
597 }
598
599 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float alpha, float drawflag)
600 {
601         if(!alpha)
602                 return;
603
604         string pic;
605         pic = strcat(hud_skin_path, "/num_leading");
606         if(precache_pic(pic) == "") {
607                 pic = "gfx/hud/default/num_leading";
608         }
609
610         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, alpha, drawflag);
611         if(mySize_x/mySize_y > 2)
612                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, alpha, drawflag);
613         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, alpha, drawflag);
614 }
615
616 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
617 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
618 {
619         float i;
620
621         vector myTarget;
622         myTarget = myPos;
623
624         vector myCenter;
625         vector targCenter;
626         myCenter = '0 0 0'; // shut up fteqcc, there IS a reference
627         targCenter = '0 0 0'; // shut up fteqcc, there IS a reference
628
629         for (i = 0; i < HUD_PANEL_NUM; ++i) {
630                 if(i == highlightedPanel || !panel_enabled)
631                         continue;
632
633                 HUD_Panel_UpdatePosSizeForId(i);
634
635                 panel_pos -= '1 1 0' * panel_bg_border;
636                 panel_size += '2 2 0' * panel_bg_border;
637
638                 if(myPos_y + mySize_y < panel_pos_y)
639                         continue;
640                 if(myPos_y > panel_pos_y + panel_size_y)
641                         continue;
642
643                 if(myPos_x + mySize_x < panel_pos_x)
644                         continue;
645                 if(myPos_x > panel_pos_x + panel_size_x)
646                         continue;
647
648                 // OK, there IS a collision.
649
650                 myCenter_x = myPos_x + 0.5 * mySize_x;
651                 myCenter_y = myPos_y + 0.5 * mySize_y;
652
653                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
654                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
655
656                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
657                 {
658                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
659                                 myTarget_x = panel_pos_x - mySize_x;
660                         else // push it upwards
661                                 myTarget_y = panel_pos_y - mySize_y;
662                 }
663                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
664                 {
665                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
666                                 myTarget_x = panel_pos_x + panel_size_x;
667                         else // push it upwards
668                                 myTarget_y = panel_pos_y - mySize_y;
669                 }
670                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
671                 {
672                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
673                                 myTarget_x = panel_pos_x - mySize_x;
674                         else // push it downwards
675                                 myTarget_y = panel_pos_y + panel_size_y;
676                 }
677                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
678                 {
679                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
680                                 myTarget_x = panel_pos_x + panel_size_x;
681                         else // push it downwards
682                                 myTarget_y = panel_pos_y + panel_size_y;
683                 }
684                 //if(cvar("hud_configure_checkcollisions_debug"))
685                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
686         }
687
688         return myTarget;
689 }
690
691 void HUD_Panel_SetPos(vector pos)
692 {
693         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
694         vector mySize;
695         mySize = panel_size;
696
697         //if(cvar("hud_configure_checkcollisions_debug"))
698                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
699
700         if(autocvar_hud_configure_grid)
701         {
702                 pos_x = floor((pos_x/vid_conwidth)/bound(0.005, autocvar_hud_configure_grid_xsize, 0.2) + 0.5) * bound(0.005, autocvar_hud_configure_grid_xsize, 0.2) * vid_conwidth;
703                 pos_y = floor((pos_y/vid_conheight)/bound(0.005, autocvar_hud_configure_grid_ysize, 0.2) + 0.5) * bound(0.005, autocvar_hud_configure_grid_ysize, 0.2) * vid_conheight;
704         }
705
706         if(hud_configure_checkcollisions)
707                 pos = HUD_Panel_CheckMove(pos, mySize);
708
709         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
710         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
711
712         string s;
713         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
714
715         HUD_Panel_GetName(highlightedPanel);
716         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
717 }
718
719 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
720 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
721         float i;
722
723         vector targEndPos;
724
725         float dist_x, dist_y;
726         float ratio;
727         ratio = mySize_x/mySize_y;
728
729         for (i = 0; i < HUD_PANEL_NUM; ++i) {
730                 if(i == highlightedPanel || !panel_enabled)
731                         continue;
732
733                 HUD_Panel_UpdatePosSizeForId(i);
734
735                 panel_pos -= '1 1 0' * panel_bg_border;
736                 panel_size += '2 2 0' * panel_bg_border;
737
738                 targEndPos = panel_pos + panel_size;
739
740                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
741                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
742                         continue;
743
744                 if (resizeCorner == 1)
745                 {
746                         // check if this panel is on our way
747                         if (resizeorigin_x <= panel_pos_x)
748                                 continue;
749                         if (resizeorigin_y <= panel_pos_y)
750                                 continue;
751                         if (targEndPos_x <= resizeorigin_x - mySize_x)
752                                 continue;
753                         if (targEndPos_y <= resizeorigin_y - mySize_y)
754                                 continue;
755
756                         // there is a collision:
757                         // detect which side of the panel we are facing is actually limiting the resizing
758                         // (which side the resize direction finds for first) and reduce the size up to there
759                         //
760                         // dist is the distance between resizeorigin and the "analogous" point of the panel
761                         // in this case resizeorigin (bottom-right point) and the bottom-right point of the panel
762                         dist_x = resizeorigin_x - targEndPos_x;
763                         dist_y = resizeorigin_y - targEndPos_y;
764                         if (dist_y <= 0 || dist_x / dist_y > ratio)
765                                 mySize_x = min(mySize_x, dist_x);
766                         else
767                                 mySize_y = min(mySize_y, dist_y);
768                 }
769                 else if (resizeCorner == 2)
770                 {
771                         if (resizeorigin_x >= targEndPos_x)
772                                 continue;
773                         if (resizeorigin_y <= panel_pos_y)
774                                 continue;
775                         if (panel_pos_x >= resizeorigin_x + mySize_x)
776                                 continue;
777                         if (targEndPos_y <= resizeorigin_y - mySize_y)
778                                 continue;
779
780                         dist_x = panel_pos_x - resizeorigin_x;
781                         dist_y = resizeorigin_y - targEndPos_y;
782                         if (dist_y <= 0 || dist_x / dist_y > ratio)
783                                 mySize_x = min(mySize_x, dist_x);
784                         else
785                                 mySize_y = min(mySize_y, dist_y);
786                 }
787                 else if (resizeCorner == 3)
788                 {
789                         if (resizeorigin_x <= panel_pos_x)
790                                 continue;
791                         if (resizeorigin_y >= targEndPos_y)
792                                 continue;
793                         if (targEndPos_x <= resizeorigin_x - mySize_x)
794                                 continue;
795                         if (panel_pos_y >= resizeorigin_y + mySize_y)
796                                 continue;
797
798                         dist_x = resizeorigin_x - targEndPos_x;
799                         dist_y = panel_pos_y - resizeorigin_y;
800                         if (dist_y <= 0 || dist_x / dist_y > ratio)
801                                 mySize_x = min(mySize_x, dist_x);
802                         else
803                                 mySize_y = min(mySize_y, dist_y);
804                 }
805                 else if (resizeCorner == 4)
806                 {
807                         if (resizeorigin_x >= targEndPos_x)
808                                 continue;
809                         if (resizeorigin_y >= targEndPos_y)
810                                 continue;
811                         if (panel_pos_x >= resizeorigin_x + mySize_x)
812                                 continue;
813                         if (panel_pos_y >= resizeorigin_y + mySize_y)
814                                 continue;
815
816                         dist_x = panel_pos_x - resizeorigin_x;
817                         dist_y = panel_pos_y - resizeorigin_y;
818                         if (dist_y <= 0 || dist_x / dist_y > ratio)
819                                 mySize_x = min(mySize_x, dist_x);
820                         else
821                                 mySize_y = min(mySize_y, dist_y);
822                 }
823                 //if(cvar("hud_configure_checkcollisions_debug"))
824                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
825         }
826
827         return mySize;
828 }
829
830 void HUD_Panel_SetPosSize(vector mySize)
831 {
832         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
833         vector resizeorigin;
834         resizeorigin = panel_click_resizeorigin;
835         vector myPos;
836
837         // minimum panel size cap
838         mySize_x = max(0.025 * vid_conwidth, mySize_x);
839         mySize_y = max(0.025 * vid_conheight, mySize_y);
840
841         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
842         {
843                 mySize_x = max(17 * cvar("con_chatsize"), mySize_x);
844                 mySize_y = max(2 * cvar("con_chatsize") + 2 * panel_bg_padding, mySize_y);
845         }
846
847         // collision testing|
848         // -----------------+
849
850         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
851         if(resizeCorner == 1) {
852                 myPos_x = resizeorigin_x - mySize_x;
853                 myPos_y = resizeorigin_y - mySize_y;
854         } else if(resizeCorner == 2) {
855                 myPos_x = resizeorigin_x;
856                 myPos_y = resizeorigin_y - mySize_y;
857         } else if(resizeCorner == 3) {
858                 myPos_x = resizeorigin_x - mySize_x;
859                 myPos_y = resizeorigin_y;
860         } else { // resizeCorner == 4
861                 myPos_x = resizeorigin_x;
862                 myPos_y = resizeorigin_y;
863         }
864
865         // left/top screen edges
866         if(myPos_x < 0)
867                 mySize_x = mySize_x + myPos_x;
868         if(myPos_y < 0)
869                 mySize_y = mySize_y + myPos_y;
870
871         // bottom/right screen edges
872         if(myPos_x + mySize_x > vid_conwidth)
873                 mySize_x = vid_conwidth - myPos_x;
874         if(myPos_y + mySize_y > vid_conheight)
875                 mySize_y = vid_conheight - myPos_y;
876
877         //if(cvar("hud_configure_checkcollisions_debug"))
878                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
879
880         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
881         if(autocvar_hud_configure_grid)
882         {
883                 mySize_x = floor((mySize_x/vid_conwidth)/bound(0.005, autocvar_hud_configure_grid_xsize, 0.2) + 0.5) * bound(0.005, autocvar_hud_configure_grid_xsize, 0.2) * vid_conwidth;
884                 mySize_y = floor((mySize_y/vid_conheight)/bound(0.005, autocvar_hud_configure_grid_ysize, 0.2) + 0.5) * bound(0.005, autocvar_hud_configure_grid_ysize, 0.2) * vid_conheight;
885         }
886
887         if(hud_configure_checkcollisions)
888                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
889
890         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
891         mySize_x = max(0.025 * vid_conwidth, mySize_x);
892         mySize_y = max(0.025 * vid_conheight, mySize_y);
893
894         // do another pos check, as size might have changed by now
895         if(resizeCorner == 1) {
896                 myPos_x = resizeorigin_x - mySize_x;
897                 myPos_y = resizeorigin_y - mySize_y;
898         } else if(resizeCorner == 2) {
899                 myPos_x = resizeorigin_x;
900                 myPos_y = resizeorigin_y - mySize_y;
901         } else if(resizeCorner == 3) {
902                 myPos_x = resizeorigin_x - mySize_x;
903                 myPos_y = resizeorigin_y;
904         } else { // resizeCorner == 4
905                 myPos_x = resizeorigin_x;
906                 myPos_y = resizeorigin_y;
907         }
908
909         //if(cvar("hud_configure_checkcollisions_debug"))
910                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
911
912         HUD_Panel_GetName(highlightedPanel);
913         string s;
914         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
915         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
916
917         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
918         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
919 }
920
921 float mouseClicked;
922 float prevMouseClicked; // previous state
923 float prevMouseClickedTime; // time during previous mouse click, to check for doubleclicks
924 vector prevMouseClickedPos; // pos during previous mouse click, to check for doubleclicks
925
926 float pressed_key_time;
927 void HUD_Panel_Arrow_Action(float nPrimary)
928 {
929         if (highlightedPanel_prev == -1 || mouseClicked)
930                 return;
931
932         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && cvar("hud_configure_checkcollisions"));
933
934         float step;
935         if(autocvar_hud_configure_grid)
936         {
937                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
938                 {
939                         if (hudShiftState & S_SHIFT)
940                                 step = bound(0.005, autocvar_hud_configure_grid_ysize, 0.2) * vid_conheight;
941                         else
942                                 step = 2 * bound(0.005, autocvar_hud_configure_grid_ysize, 0.2) * vid_conheight;
943                 }
944                 else
945                 {
946                         if (hudShiftState & S_SHIFT)
947                                 step = bound(0.005, autocvar_hud_configure_grid_xsize, 0.2) * vid_conwidth;
948                         else
949                                 step = 2 * bound(0.005, autocvar_hud_configure_grid_xsize, 0.2) * vid_conwidth;
950                 }
951         }
952         else
953         {
954                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
955                         step = vid_conheight;
956                 else
957                         step = vid_conwidth;
958                 if (hudShiftState & S_SHIFT)
959                         step = (step / 256); // more precision
960                 else
961                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
962         }
963
964         highlightedPanel = highlightedPanel_prev;
965
966         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
967
968         vector prev_pos, prev_size;
969         prev_pos = panel_pos;
970         prev_size = panel_size;
971
972         if (hudShiftState & S_ALT) // resize
973         {
974                 highlightedAction = 1;
975                 if(nPrimary == K_UPARROW)
976                         resizeCorner = 1;
977                 else if(nPrimary == K_RIGHTARROW)
978                         resizeCorner = 2;
979                 else if(nPrimary == K_LEFTARROW)
980                         resizeCorner = 3;
981                 else // if(nPrimary == K_DOWNARROW)
982                         resizeCorner = 4;
983
984                 // ctrl+arrow reduces the size, instead of increasing it
985                 // Note that ctrl disables collisions check too, but it's fine
986                 // since we don't collide with anything reducing the size
987                 if (hudShiftState & S_CTRL) {
988                         step = -step;
989                         resizeCorner = 5 - resizeCorner;
990                 }
991
992                 vector mySize;
993                 mySize = panel_size;
994                 panel_click_resizeorigin = panel_pos;
995                 if(resizeCorner == 1) {
996                         panel_click_resizeorigin += mySize;
997                         mySize_y += step;
998                 } else if(resizeCorner == 2) {
999                         panel_click_resizeorigin_y += mySize_y;
1000                         mySize_x += step;
1001                 } else if(resizeCorner == 3) {
1002                         panel_click_resizeorigin_x += mySize_x;
1003                         mySize_x += step;
1004                 } else { // resizeCorner == 4
1005                         mySize_y += step;
1006                 }
1007                 HUD_Panel_SetPosSize(mySize);
1008         }
1009         else // move
1010         {
1011                 highlightedAction = 2;
1012                 vector pos;
1013                 pos = panel_pos;
1014                 if(nPrimary == K_UPARROW)
1015                         pos_y -= step;
1016                 else if(nPrimary == K_DOWNARROW)
1017                         pos_y += step;
1018                 else if(nPrimary == K_LEFTARROW)
1019                         pos_x -= step;
1020                 else // if(nPrimary == K_RIGHTARROW)
1021                         pos_x += step;
1022
1023                 HUD_Panel_SetPos(pos);
1024         }
1025
1026         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1027
1028         if (prev_pos != panel_pos || prev_size != panel_size)
1029         {
1030                 // backup!
1031                 panel_pos_backup = prev_pos;
1032                 panel_size_backup = prev_size;
1033                 highlightedPanel_backup = highlightedPanel;
1034         }
1035 }
1036
1037 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
1038 {
1039         string s;
1040
1041         if(!autocvar__hud_configure)
1042                 return false;
1043
1044         // allow console bind to work
1045         string con_keys;
1046         float keys;
1047         con_keys = findkeysforcommand("toggleconsole");
1048         keys = tokenize(con_keys);
1049
1050         float hit_con_bind, i;
1051         for (i = 0; i < keys; ++i)
1052         {
1053                 if(nPrimary == stof(argv(i)))
1054                         hit_con_bind = 1;
1055         }
1056
1057         if(bInputType == 0) {
1058                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
1059                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
1060                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
1061         }
1062         else if(bInputType == 1) {
1063                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
1064                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
1065                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
1066         }
1067
1068         if(nPrimary == K_MOUSE1)
1069         {
1070                 if(bInputType == 0) { // key pressed
1071                         mouseClicked = 1;
1072                         return true;
1073                 }
1074                 else if(bInputType == 1) {// key released
1075                         mouseClicked = 0;
1076                         return true;
1077                 }
1078         }
1079         else if(nPrimary == K_ESCAPE)
1080         {
1081                 if (bInputType == 1)
1082                         return true;
1083                 menu_enabled = 1;
1084                 menu_enabled_time = time;
1085                 localcmd("menu_showhudexit\n");
1086         }
1087         else if(hudShiftState & S_CTRL)
1088         {
1089                 if (mouseClicked)
1090                         return true;
1091
1092                 if(nPrimary == K_SPACE) // enable/disable highlighted panel or dock
1093                 {
1094                         if (bInputType == 1)
1095                                 return true;
1096
1097                         if (highlightedPanel_prev != -1)
1098                                 cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
1099                         else
1100                                 cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
1101                 }
1102                 if(nPrimary == 'c') // copy highlighted panel size
1103                 {
1104                         if (bInputType == 1)
1105                                 return true;
1106
1107                         if (highlightedPanel_prev != -1)
1108                         {
1109                                 panel_size_copied = panel_size;
1110                                 highlightedPanel_copied = highlightedPanel_prev;
1111                         }
1112                 }
1113                 else if(nPrimary == 'v') // past copied size on the highlighted panel
1114                 {
1115                         if (bInputType == 1)
1116                                 return true;
1117
1118                         if (highlightedPanel_copied == -1 || highlightedPanel_prev == -1)
1119                                 return true;
1120
1121                         HUD_Panel_UpdatePosSizeForId(highlightedPanel_prev);
1122
1123                         // reduce size if it'd go beyond screen boundaries
1124                         vector tmp_size = panel_size_copied;
1125                         if (panel_pos_x + panel_size_copied_x > vid_conwidth)
1126                                 tmp_size_x = vid_conwidth - panel_pos_x;
1127                         if (panel_pos_y + panel_size_copied_y > vid_conheight)
1128                                 tmp_size_y = vid_conheight - panel_pos_y;
1129
1130                         if (panel_size == tmp_size)
1131                                 return true;
1132
1133                         // backup first!
1134                         panel_pos_backup = panel_pos;
1135                         panel_size_backup = panel_size;
1136                         highlightedPanel_backup = highlightedPanel_prev;
1137
1138                         s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
1139                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
1140                 }
1141                 else if(nPrimary == 'z') // undo last action
1142                 {
1143                         if (bInputType == 1)
1144                                 return true;
1145                         //restore previous values
1146                         if (highlightedPanel_backup != -1)
1147                         {
1148                                 HUD_Panel_GetName(highlightedPanel_backup);
1149                                 s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
1150                                 cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
1151                                 s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
1152                                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
1153                                 highlightedPanel_backup = -1;
1154                         }
1155                 }
1156         }
1157         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
1158         {
1159                 if (bInputType == 1)
1160                 {
1161                         pressed_key_time = 0;
1162                         return true;
1163                 }
1164                 else if (pressed_key_time == 0)
1165                         pressed_key_time = time;
1166
1167                 HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
1168         }
1169         else if(hit_con_bind)
1170                 return false;
1171
1172         return true; // Suppress ALL other input
1173 }
1174
1175 float HUD_Panel_HighlightCheck()
1176 {
1177         float i, j, border;
1178         vector panelPos;
1179         vector panelSize;
1180
1181         while(j <= HUD_PANEL_NUM)
1182         {
1183                 i = panel_order[j];
1184                 j += 1;
1185
1186                 HUD_Panel_UpdatePosSizeForId(i);
1187
1188                 panelPos = panel_pos;
1189                 panelSize = panel_size;
1190                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1191
1192                 // move
1193                 if(mousepos_x >= panelPos_x && mousepos_y >= panelPos_y && mousepos_x <= panelPos_x + panelSize_x && mousepos_y <= panelPos_y + panelSize_y)
1194                 {
1195                         return 1;
1196                 }
1197                 // resize from topleft border
1198                 else if(mousepos_x >= panelPos_x - border && mousepos_y >= panelPos_y - border && mousepos_x <= panelPos_x + 0.5 * panelSize_x && mousepos_y <= panelPos_y + 0.5 * panelSize_y)
1199                 {
1200                         return 2;
1201                 }
1202                 // resize from topright border
1203                 else if(mousepos_x >= panelPos_x + 0.5 * panelSize_x && mousepos_y >= panelPos_y - border && mousepos_x <= panelPos_x + panelSize_x + border && mousepos_y <= panelPos_y + 0.5 * panelSize_y)
1204                 {
1205                         return 3;
1206                 }
1207                 // resize from bottomleft border
1208                 else if(mousepos_x >= panelPos_x - border && mousepos_y >= panelPos_y + 0.5 * panelSize_y && mousepos_x <= panelPos_x + 0.5 * panelSize_x && mousepos_y <= panelPos_y + panelSize_y + border)
1209                 {
1210                         return 3;
1211                 }
1212                 // resize from bottomright border
1213                 else if(mousepos_x >= panelPos_x + 0.5 * panelSize_x && mousepos_y >= panelPos_y + 0.5 * panelSize_y && mousepos_x <= panelPos_x + panelSize_x + border && mousepos_y <= panelPos_y + panelSize_y + border)
1214                 {
1215                         return 2;
1216                 }
1217         }
1218         return 0;
1219 }
1220
1221 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
1222 void HUD_Panel_FirstInDrawQ(float id)
1223 {
1224         float i;
1225         var float place = -1;
1226         // find out where in the array our current id is, save into place
1227         for(i = 0; i < HUD_PANEL_NUM; ++i)
1228         {
1229                 if(panel_order[i] == id)
1230                 {
1231                         place = i;
1232                         break;
1233                 }
1234         }
1235         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
1236         if(place == -1)
1237                 place = HUD_PANEL_NUM - 1;
1238
1239         // move all ids up by one step in the array until "place"
1240         for(i = place; i > 0; --i)
1241         {
1242                 panel_order[i] = panel_order[i-1];
1243         }
1244         // now save the new top id
1245         panel_order[0] = id;
1246         
1247         // let's save them into the cvar by some strcat trickery
1248         string s;
1249         for(i = 0; i < HUD_PANEL_NUM; ++i)
1250         {
1251                 s = strcat(s, ftos(panel_order[i]), " ");
1252         }
1253         cvar_set("_hud_panelorder", s);
1254         if(hud_panelorder_prev)
1255                 strunzone(hud_panelorder_prev);
1256         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1257 }
1258
1259 void HUD_Panel_Highlight()
1260 {
1261         float i, j, border;
1262         vector panelPos;
1263         vector panelSize;
1264
1265         while(j <= HUD_PANEL_NUM)
1266         {
1267                 i = panel_order[j];
1268                 j += 1;
1269
1270                 HUD_Panel_UpdatePosSizeForId(i);
1271
1272                 panelPos = panel_pos;
1273                 panelSize = panel_size;
1274                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1275
1276                 // move
1277                 if(mousepos_x >= panelPos_x && mousepos_y >= panelPos_y && mousepos_x <= panelPos_x + panelSize_x && mousepos_y <= panelPos_y + panelSize_y)
1278                 {
1279                         highlightedPanel = i;
1280                         HUD_Panel_FirstInDrawQ(i);
1281                         highlightedAction = 1;
1282                         panel_click_distance = mousepos - panelPos;
1283                         return;
1284                 }
1285                 // resize from topleft border
1286                 else if(mousepos_x >= panelPos_x - border && mousepos_y >= panelPos_y - border && mousepos_x <= panelPos_x + 0.5 * panelSize_x && mousepos_y <= panelPos_y + 0.5 * panelSize_y)
1287                 {
1288                         highlightedPanel = i;
1289                         HUD_Panel_FirstInDrawQ(i);
1290                         highlightedAction = 2;
1291                         resizeCorner = 1;
1292                         panel_click_distance = mousepos - panelPos;
1293                         panel_click_resizeorigin = panelPos + panelSize;
1294                         return;
1295                 }
1296                 // resize from topright border
1297                 else if(mousepos_x >= panelPos_x + 0.5 * panelSize_x && mousepos_y >= panelPos_y - border && mousepos_x <= panelPos_x + panelSize_x + border && mousepos_y <= panelPos_y + 0.5 * panelSize_y)
1298                 {
1299                         highlightedPanel = i;
1300                         HUD_Panel_FirstInDrawQ(i);
1301                         highlightedAction = 2;
1302                         resizeCorner = 2;
1303                         panel_click_distance_x = panelSize_x - mousepos_x + panelPos_x;
1304                         panel_click_distance_y = mousepos_y - panelPos_y;
1305                         panel_click_resizeorigin = panelPos + eY * panelSize_y;
1306                         return;
1307                 }
1308                 // resize from bottomleft border
1309                 else if(mousepos_x >= panelPos_x - border && mousepos_y >= panelPos_y + 0.5 * panelSize_y && mousepos_x <= panelPos_x + 0.5 * panelSize_x && mousepos_y <= panelPos_y + panelSize_y + border)
1310                 {
1311                         highlightedPanel = i;
1312                         HUD_Panel_FirstInDrawQ(i);
1313                         highlightedAction = 2;
1314                         resizeCorner = 3;
1315                         panel_click_distance_x = mousepos_x - panelPos_x;
1316                         panel_click_distance_y = panelSize_y - mousepos_y + panelPos_y;
1317                         panel_click_resizeorigin = panelPos + eX * panelSize_x;
1318                         return;
1319                 }
1320                 // resize from bottomright border
1321                 else if(mousepos_x >= panelPos_x + 0.5 * panelSize_x && mousepos_y >= panelPos_y + 0.5 * panelSize_y && mousepos_x <= panelPos_x + panelSize_x + border && mousepos_y <= panelPos_y + panelSize_y + border)
1322                 {
1323                         highlightedPanel = i;
1324                         HUD_Panel_FirstInDrawQ(i);
1325                         highlightedAction = 2;
1326                         resizeCorner = 4;
1327                         panel_click_distance = panelSize - mousepos + panelPos;
1328                         panel_click_resizeorigin = panelPos;
1329                         return;
1330                 }
1331                 else
1332                 {
1333                         highlightedPanel_prev = -1;
1334                 }
1335         }
1336 }
1337
1338 float highlightcheck;
1339 vector prev_pos, prev_size;
1340 void HUD_Panel_Mouse()
1341 {
1342         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1343         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1344                 menu_enabled = 0;
1345
1346         /*
1347         print("menu_enabled: ", ftos(menu_enabled), "\n");
1348         print("Highlighted: ", ftos(highlightedPanel), "\n");
1349         print("Menu alpha: ", cvar_string("_menu_alpha"), "\n");
1350         */
1351
1352         // instantly hide the editor cursor if we open the HUDExit dialog
1353         // as hud_fade_alpha doesn't decrease to 0 in this case
1354         // TODO: find a way to fade the cursor out even in this case
1355         if(menu_enabled == 1 || (menu_enabled == 2 && !hud_fade_alpha))
1356                 return;
1357
1358         if(mouseClicked == 0 && menu_enabled != 2 && highlightedPanel >= 0) { // don't reset these variables in menu_enabled mode 2!
1359                 highlightedPanel = -1;
1360                 highlightedAction = 0;
1361         }
1362         if(highlightedPanel != -1)
1363                 highlightedPanel_prev = highlightedPanel;
1364
1365         mousepos = mousepos + getmousepos() * cvar("menu_mouse_speed");
1366
1367         mousepos_x = bound(0, mousepos_x, vid_conwidth);
1368         mousepos_y = bound(0, mousepos_y, vid_conheight);
1369
1370         if(mouseClicked)
1371         {
1372                 if(prevMouseClicked == 0)
1373                 {
1374                         HUD_Panel_Highlight(); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1375                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1376                         prev_pos = panel_pos;
1377                         prev_size = panel_size;
1378                 }
1379                 else
1380                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1381
1382                 if (prev_pos != panel_pos || prev_size != panel_size)
1383                 {
1384                         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && cvar("hud_configure_checkcollisions"));
1385                         // backup!
1386                         panel_pos_backup = prev_pos;
1387                         panel_size_backup = prev_size;
1388                         highlightedPanel_backup = highlightedPanel;
1389                 }
1390                 else
1391                         // in case the clicked panel is inside another panel and we aren't
1392                         // moving it, avoid the immediate "fix" of its position/size
1393                         // (often unwanted and hateful) by disabling collisions check
1394                         hud_configure_checkcollisions = false;
1395
1396                 if(highlightedAction == 1)
1397                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1398                 else if(highlightedAction == 2)
1399                 {
1400                         vector mySize;
1401                         if(resizeCorner == 1) {
1402                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1403                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1404                         } else if(resizeCorner == 2) {
1405                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1406                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1407                         } else if(resizeCorner == 3) {
1408                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1409                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1410                         } else { // resizeCorner == 4
1411                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1412                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1413                         }
1414                         HUD_Panel_SetPosSize(mySize);
1415                 }
1416
1417                 // doubleclick check
1418                 if(time - prevMouseClickedTime < 0.4 && prevMouseClicked == 0 && prevMouseClickedPos == mousepos && highlightedPanel >= 0)
1419                 {
1420                         mouseClicked = 0; // to prevent spam, I guess.
1421                         menu_enabled = 2;
1422                         menu_enabled_time = time;
1423                         HUD_Panel_GetName(highlightedPanel);
1424                         localcmd("menu_showhudoptions ", panel_name, "\n");
1425                         return;
1426                 }
1427                 if(prevMouseClicked == 0)
1428                 {
1429                         prevMouseClickedTime = time;
1430                         prevMouseClickedPos = mousepos;
1431                 }
1432         }
1433         else
1434         {
1435                 highlightcheck = HUD_Panel_HighlightCheck();
1436         }
1437         // draw cursor after performing move/resize to have the panel pos/size updated before highlightcheck
1438         vector cursorsize;
1439         cursorsize = '32 32 0';
1440
1441         if(highlightcheck == 0)
1442                 drawpic(mousepos, strcat("gfx/menu/", cvar_string("menu_skin"), "/cursor.tga"), '32 32 0', '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1443         else if(highlightcheck == 1)
1444                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", cvar_string("menu_skin"), "/cursor_move.tga"), '32 32 0', '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1445         else if(highlightcheck == 2)
1446                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", cvar_string("menu_skin"), "/cursor_resize.tga"), '32 32 0', '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1447         else
1448                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", cvar_string("menu_skin"), "/cursor_resize2.tga"), '32 32 0', '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1449
1450         prevMouseClicked = mouseClicked;
1451 }
1452
1453 // Weapon icons (#0)
1454 //
1455 float weaponspace[10];
1456 #define HUD_Weapons_Clear()\
1457         float idx;\
1458         for(idx = 0; idx < 10; ++idx)\
1459                 weaponspace[idx] = 0
1460
1461 entity weaponorder[WEP_MAXCOUNT];
1462 void weaponorder_swap(float i, float j, entity pass)
1463 {
1464         entity h;
1465         h = weaponorder[i];
1466         weaponorder[i] = weaponorder[j];
1467         weaponorder[j] = h;
1468 }
1469
1470 string weaponorder_cmp_str;
1471 float weaponorder_cmp(float i, float j, entity pass)
1472 {
1473         float ai, aj;
1474         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
1475         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
1476         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
1477 }
1478
1479 float GetAmmoStat(float i)
1480 {
1481         switch(i)
1482         {
1483                 case 0: return STAT_SHELLS;
1484                 case 1: return STAT_NAILS;
1485                 case 2: return STAT_ROCKETS;
1486                 case 3: return STAT_CELLS;
1487                 case 4: return STAT_FUEL;
1488                 default: return -1;
1489         }
1490 }
1491
1492 float GetAmmoTypeForWep(float i)
1493 {
1494         switch(i)
1495         {
1496                 case WEP_SHOTGUN: return 0;
1497                 case WEP_UZI: return 1;
1498                 case WEP_GRENADE_LAUNCHER: return 2;
1499                 case WEP_MINE_LAYER: return 2;
1500                 case WEP_ELECTRO: return 3;
1501                 case WEP_CRYLINK: return 3;
1502                 case WEP_HLAC: return 3;
1503                 case WEP_MINSTANEX: return 3;
1504                 case WEP_NEX: return 3;
1505                 case WEP_CAMPINGRIFLE: return 1;
1506                 case WEP_HAGAR: return 2;
1507                 case WEP_ROCKET_LAUNCHER: return 2;
1508                 case WEP_SEEKER: return 2;
1509                 case WEP_FIREBALL: return 4;
1510                 case WEP_HOOK: return 3;
1511                 default: return -1;
1512         }
1513 }
1514
1515 void HUD_Weapons(void)
1516 {
1517         float f, screen_ar;
1518         float center_x, center_y;
1519
1520         if(!autocvar_hud_panel_weapons && !autocvar__hud_configure)
1521                 return;
1522
1523         float timeout = cvar("hud_panel_weapons_timeout");
1524         float timeout_effect_length, timein_effect_length;
1525         if (cvar("hud_panel_weapons_timeout_effect") == 0)
1526         {
1527                 timeout_effect_length = 0;
1528                 timein_effect_length = 0;
1529         }
1530         else
1531         {
1532                 timeout_effect_length = 0.75;
1533                 timein_effect_length = 0.375;
1534         }
1535
1536         if (timeout && time >= weapontime + timeout + timeout_effect_length && !autocvar__hud_configure)
1537         {
1538                 weaponprevtime = time;
1539                 return;
1540         }
1541
1542         active_panel = HUD_PANEL_WEAPONS;
1543         HUD_Panel_UpdateCvars(weapons);
1544
1545         if (timeout && time >= weapontime + timeout && !autocvar__hud_configure)
1546         {
1547                 f = (time - (weapontime + timeout)) / timeout_effect_length;
1548                 if (cvar("hud_panel_weapons_timeout_effect"))
1549                 {
1550                         panel_bg_alpha *= (1 - f);
1551                         panel_fg_alpha *= (1 - f);
1552                 }
1553                 if (cvar("hud_panel_weapons_timeout_effect") == 1)
1554                 {
1555                         f *= f; // for a cooler movement
1556                         center_x = panel_pos_x + panel_size_x/2;
1557                         center_y = panel_pos_y + panel_size_y/2;
1558                         screen_ar = vid_conwidth/vid_conheight;
1559                         if (center_x/center_y < screen_ar) //bottom left
1560                         {
1561                                 if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
1562                                         panel_pos_y += f * (vid_conheight - panel_pos_y);
1563                                 else //left
1564                                         panel_pos_x -= f * (panel_pos_x + panel_size_x);
1565                         }
1566                         else //top right
1567                         {
1568                                 if ((vid_conwidth - center_x)/center_y < screen_ar) //right
1569                                         panel_pos_x += f * (vid_conwidth - panel_pos_x);
1570                                 else //top
1571                                         panel_pos_y -= f * (panel_pos_y + panel_size_y);
1572                         }
1573                 }
1574                 weaponprevtime = time - (1 - f) * timein_effect_length;
1575         }
1576         else if (timeout && time < weaponprevtime + timein_effect_length && !autocvar__hud_configure)
1577         {
1578                 f = (time - weaponprevtime) / timein_effect_length;
1579                 if (cvar("hud_panel_weapons_timeout_effect"))
1580                 {
1581                         panel_bg_alpha *= (f);
1582                         panel_fg_alpha *= (f);
1583                 }
1584                 if (cvar("hud_panel_weapons_timeout_effect") == 1)
1585                 {
1586                         f *= f; // for a cooler movement
1587                         f = 1 - f;
1588                         center_x = panel_pos_x + panel_size_x/2;
1589                         center_y = panel_pos_y + panel_size_y/2;
1590                         screen_ar = vid_conwidth/vid_conheight;
1591                         if (center_x/center_y < screen_ar) //bottom left
1592                         {
1593                                 if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
1594                                         panel_pos_y += f * (vid_conheight - panel_pos_y);
1595                                 else //left
1596                                         panel_pos_x -= f * (panel_pos_x + panel_size_x);
1597                         }
1598                         else //top right
1599                         {
1600                                 if ((vid_conwidth - center_x)/center_y < screen_ar) //right
1601                                         panel_pos_x += f * (vid_conwidth - panel_pos_x);
1602                                 else //top
1603                                         panel_pos_y -= f * (panel_pos_y + panel_size_y);
1604                         }
1605                 }
1606         }
1607
1608         float i, weapid, wpnalpha, weapon_cnt;
1609         weapon_cnt = 0;
1610         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1611         {
1612                 self = get_weaponinfo(i);
1613                 if(self.impulse >= 0)
1614                         ++weapon_cnt;
1615         }
1616
1617         // TODO make this configurable
1618         if(weaponorder_bypriority != cvar_string("cl_weaponpriority"))
1619         {
1620                 if(weaponorder_bypriority)
1621                         strunzone(weaponorder_bypriority);
1622                 if(weaponorder_byimpulse)
1623                         strunzone(weaponorder_byimpulse);
1624
1625                 weaponorder_bypriority = strzone(cvar_string("cl_weaponpriority"));
1626                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
1627                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
1628
1629                 weapon_cnt = 0;
1630                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1631                 {
1632                         self = get_weaponinfo(i);
1633                         if(self.impulse >= 0)
1634                         {
1635                                 weaponorder[weapon_cnt] = self;
1636                                 ++weapon_cnt;
1637                         }
1638                 }
1639                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
1640
1641                 weaponorder_cmp_str = string_null;
1642         }
1643
1644         HUD_Panel_DrawBg(1);
1645         if(panel_bg_padding)
1646         {
1647                 panel_pos += '1 1 0' * panel_bg_padding;
1648                 panel_size -= '2 2 0' * panel_bg_padding;
1649         }
1650
1651         if(cvar_or("hud_panel_weapons_fade", 1))
1652         {
1653                 wpnalpha = 3.2 - 2 * (time - weapontime);
1654                 wpnalpha = bound(0.7, wpnalpha, 1) * panel_fg_alpha;
1655         }
1656         else
1657                 wpnalpha = panel_fg_alpha;
1658
1659         HUD_Weapons_Clear();
1660
1661         float rows, columns;
1662         float aspect = cvar("hud_panel_weapons_aspect");
1663         rows = panel_size_y/panel_size_x;
1664         rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
1665
1666         columns = ceil(WEP_COUNT/rows);
1667         float row, column;
1668
1669         float a, type, fullammo;
1670         float when;
1671         when = cvar("hud_panel_weapons_complainbubble_time");
1672         float fadetime;
1673         fadetime = cvar("hud_panel_weapons_complainbubble_fadetime");
1674
1675         vector color;
1676         vector wpnpos;
1677         vector wpnsize;
1678         
1679         float fullammo_shells, fullammo_nails, fullammo_rockets, fullammo_cells, fullammo_fuel;
1680         vector ammo_color;
1681         float ammo_alpha;
1682         wpnsize = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
1683         float barsize_x, barsize_y, baroffset_x, baroffset_y;
1684         float show_ammo = cvar("hud_panel_weapons_ammo");
1685         if (show_ammo)
1686         {
1687                 fullammo_shells = cvar("hud_panel_weapons_ammo_full_shells");
1688                 fullammo_nails = cvar("hud_panel_weapons_ammo_full_nails");
1689                 fullammo_rockets = cvar("hud_panel_weapons_ammo_full_rockets");
1690                 fullammo_cells = cvar("hud_panel_weapons_ammo_full_cells");
1691                 fullammo_fuel = cvar("hud_panel_weapons_ammo_full_fuel");
1692                 ammo_color = stov(cvar_string("hud_panel_weapons_ammo_color"));
1693                 ammo_alpha = panel_fg_alpha * cvar("hud_panel_weapons_ammo_alpha");
1694
1695
1696                 if(wpnsize_x/wpnsize_y > aspect)
1697                 {
1698                         barsize_x = aspect * wpnsize_y;
1699                         barsize_y = wpnsize_y;
1700                         baroffset_x = (wpnsize_x - barsize_x) / 2;
1701                 }
1702                 else
1703                 {
1704                         barsize_y = 1/aspect * wpnsize_x;
1705                         barsize_x = wpnsize_x;
1706                         baroffset_y = (wpnsize_y - barsize_y) / 2;
1707                 }
1708         }
1709
1710         float show_accuracy;
1711         float weapon_stats;
1712         if(cvar("hud_panel_weapons_accuracy") && acc_levels)
1713         {
1714                 show_accuracy = true;
1715                 if (acc_col_x[0] == -1)
1716                         for (i = 0; i < acc_levels; ++i)
1717                                 acc_col[i] = stov(cvar_string(strcat("accuracy_color", ftos(i))));
1718         }
1719
1720         float weapons_st = getstati(STAT_WEAPONS);
1721         float label = cvar("hud_panel_weapons_label");
1722
1723         for(i = 0; i < weapon_cnt; ++i)
1724         {
1725                 wpnpos = panel_pos + eX * column * wpnsize_x + eY * row * wpnsize_y;
1726
1727                 self = weaponorder[i];
1728                 weapid = self.impulse;
1729
1730                 // draw background behind currently selected weapon
1731                 if(self.weapon == activeweapon)
1732                         drawpic_aspect_skin(wpnpos, "weapon_current_bg", wpnsize, '1 1 1', wpnalpha, DRAWFLAG_NORMAL);
1733
1734                 // draw the weapon accuracy
1735                 if(show_accuracy)
1736                 {
1737                         weapon_stats = weapon_accuracy[self.weapon-WEP_FIRST];
1738                         if(weapon_stats >= 0)
1739                         {
1740                                 // find the max level lower than weapon_stats
1741                                 float j;
1742                                 j = acc_levels-1;
1743                                 while ( j && weapon_stats < acc_lev[j] )
1744                                         --j;
1745
1746                                 // inject color j+1 in color j, how much depending on how much weapon_stats is higher than level j
1747                                 float factor;
1748                                 factor = (weapon_stats - acc_lev[j]) / (acc_lev[j+1] - acc_lev[j]);
1749                                 color = acc_col[j];
1750                                 color = color + factor * (acc_col[j+1] - color);
1751
1752                                 drawpic_aspect_skin(wpnpos, "weapon_accuracy", wpnsize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
1753                         }
1754                 }
1755
1756                 // draw the weapon icon
1757                 if((weapid >= 0) && (weapons_st & self.weapons))
1758                 {
1759                         drawpic_aspect_skin(wpnpos, strcat("weapon", self.netname), wpnsize, '1 1 1', wpnalpha, DRAWFLAG_NORMAL);
1760
1761                         if(label == 1) // weapon number
1762                                 drawstring(wpnpos, ftos(weapid), '1 1 0' * 0.5 * wpnsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1763                         else if(label == 2) // bind
1764                                 drawstring(wpnpos, getcommandkey(ftos(weapid), strcat("impulse ", ftos(weapid))), '1 1 0' * 0.5 * wpnsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1765
1766                         // draw ammo status bar
1767                         if(show_ammo && weapid != WEP_TUBA && weapid != WEP_LASER && weapid != WEP_PORTO)
1768                         {
1769                                 a = 0;
1770                                 type = GetAmmoTypeForWep(weapid);
1771                                 if(type != -1)
1772                                         a = getstati(GetAmmoStat(type)); // how much ammo do we have?
1773
1774                                 if(a > 0)
1775                                 {
1776                                         switch(type) {
1777                                                 case 0: fullammo = fullammo_shells; break;
1778                                                 case 1: fullammo = fullammo_nails; break;
1779                                                 case 2: fullammo = fullammo_rockets; break;
1780                                                 case 3: fullammo = fullammo_cells; break;
1781                                                 case 4: fullammo = fullammo_fuel; break;
1782                                                 default: fullammo = 60;
1783                                         }
1784
1785                                         drawsetcliparea(
1786                                                 wpnpos_x + baroffset_x,
1787                                                 wpnpos_y + baroffset_y,
1788                                                 barsize_x * bound(0, a/fullammo, 1),
1789                                                 barsize_y);
1790                                         drawpic_aspect_skin(wpnpos, "weapon_ammo", wpnsize, ammo_color, ammo_alpha, DRAWFLAG_NORMAL);
1791                                         drawresetcliparea();
1792                                 }
1793                         }
1794                 }
1795
1796                 // draw a "ghost weapon icon" if you don't have the weapon
1797                 else
1798                 {
1799                         drawpic_aspect_skin(wpnpos, strcat("weapon", self.netname), wpnsize, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
1800                 }
1801
1802                 // draw the complain message
1803                 if(time - complain_weapon_time < when + fadetime && self.weapon == complain_weapon && cvar("hud_panel_weapons_complainbubble"))
1804                 {
1805                         if(fadetime)
1806                         {
1807                                 if(complain_weapon_time + when > time)
1808                                         a = 1;
1809                                 else
1810                                         a = bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1);
1811                         }
1812                         else
1813                         {
1814                                 if(complain_weapon_time + when > time)
1815                                         a = 1;
1816                                 else
1817                                         a = 0;
1818                         }
1819
1820                         string s;
1821                         if(complain_weapon_type == 0) {
1822                                 s = "Out of ammo";
1823                                 color = stov(cvar_string("hud_panel_weapons_complainbubble_color_outofammo"));
1824                         }
1825                         else if(complain_weapon_type == 1) {
1826                                 s = "Don't have";
1827                                 color = stov(cvar_string("hud_panel_weapons_complainbubble_color_donthave"));
1828                         }
1829                         else {
1830                                 s = "Unavailable";
1831                                 color = stov(cvar_string("hud_panel_weapons_complainbubble_color_unavailable"));
1832                         }
1833                         float padding = cvar("hud_panel_weapons_complainbubble_padding");
1834                         drawpic_aspect_skin(wpnpos + '1 1 0' * padding, "weapon_complainbubble", wpnsize - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
1835                         drawstring_aspect(wpnpos + '1 1 0' * padding, s, wpnsize - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1836                 }
1837
1838                 ++row;
1839                 if(row >= rows)
1840                 {
1841                         row = 0;
1842                         ++column;
1843                 }
1844         }
1845
1846 }
1847
1848 // Ammo (#1)
1849 //
1850 // TODO: macro
1851 float GetAmmoItemCode(float i)
1852 {
1853         switch(i)
1854         {
1855                 case 0: return IT_SHELLS;
1856                 case 1: return IT_NAILS;
1857                 case 2: return IT_ROCKETS;
1858                 case 3: return IT_CELLS;
1859                 case 4: return IT_FUEL;
1860                 default: return -1;
1861         }
1862 }
1863
1864 string GetAmmoPicture(float i)
1865 {
1866         switch(i)
1867         {
1868                 case 0: return "ammo_shells";
1869                 case 1: return "ammo_bullets";
1870                 case 2: return "ammo_rockets";
1871                 case 3: return "ammo_cells";
1872                 case 4: return "ammo_fuel";
1873                 default: return "";
1874         }
1875 }
1876
1877 void DrawAmmoItem(vector myPos, vector mySize, float itemcode, float currently_selected)
1878 {
1879         float a;
1880         if(autocvar__hud_configure)
1881         {
1882                 currently_selected = (itemcode == 2); //rockets always selected
1883                 a = 100;
1884         }
1885         else
1886                 a = getstati(GetAmmoStat(itemcode)); // how much ammo do we have of type itemcode?
1887
1888         vector color;
1889         if(a < 10)
1890                 color = '0.7 0 0';
1891         else
1892                 color = '1 1 1';
1893
1894         float alpha;
1895         if(currently_selected)
1896                 alpha = 1;
1897         else
1898                 alpha = 0.7;
1899
1900         vector picpos, numpos;
1901         if(autocvar_hud_panel_ammo_iconalign)
1902         {
1903                 numpos = myPos;
1904                 picpos = myPos + eX * 2 * mySize_y;
1905         }
1906         else
1907         {
1908                 numpos = myPos + eX * mySize_y;
1909                 picpos = myPos;
1910         }
1911
1912         if (currently_selected)
1913                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1914
1915         if(a > 0)
1916                 drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1917         else // "ghost" ammo count
1918                 drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * alpha * 0.5, DRAWFLAG_NORMAL);
1919         if(a > 0)
1920                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1921         else // "ghost" ammo icon
1922                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * alpha * 0.5, DRAWFLAG_NORMAL);
1923 }
1924
1925 void HUD_Ammo(void)
1926 {
1927         if(!autocvar_hud_panel_ammo && !autocvar__hud_configure)
1928                 return;
1929
1930         active_panel = HUD_PANEL_AMMO;
1931         HUD_Panel_UpdateCvars(ammo);
1932         vector pos, mySize;
1933         pos = panel_pos;
1934         mySize = panel_size;
1935
1936         HUD_Panel_DrawBg(1);
1937         if(panel_bg_padding)
1938         {
1939                 pos += '1 1 0' * panel_bg_padding;
1940                 mySize -= '2 2 0' * panel_bg_padding;
1941         }
1942
1943         float rows, columns, row, column;
1944         vector ammo_size;
1945         if (autocvar_hud_panel_ammo_onlycurrent)
1946                 ammo_size = mySize;
1947         else
1948         {
1949                 rows = mySize_y/mySize_x;
1950                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
1951                 //                               ^^^ ammo item aspect goes here
1952
1953                 columns = ceil(AMMO_COUNT/rows);
1954
1955                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
1956         }
1957
1958         vector offset;
1959         float newSize;
1960         if(ammo_size_x/ammo_size_y > 3)
1961         {
1962                 newSize = 3 * ammo_size_y;
1963                 offset_x = ammo_size_x - newSize;
1964                 pos_x += offset_x/2;
1965                 ammo_size_x = newSize;
1966         }
1967         else
1968         {
1969                 newSize = 1/3 * ammo_size_x;
1970                 offset_y = ammo_size_y - newSize;
1971                 pos_y += offset_y/2;
1972                 ammo_size_y = newSize;
1973         }
1974
1975         drawfont = hud_bigfont;
1976         float i, stat_items, currently_selected;
1977         if (autocvar_hud_panel_ammo_onlycurrent)
1978         {
1979                 if(autocvar__hud_configure)
1980                 {
1981                         DrawAmmoItem(pos, ammo_size, 2, true); //show rockets
1982                         return;
1983                 }
1984                 stat_items = getstati(STAT_ITEMS);
1985                 for (i = 0; i < AMMO_COUNT; ++i) {
1986                         currently_selected = stat_items & GetAmmoItemCode(i);
1987                         if (currently_selected)
1988                         {
1989                                 DrawAmmoItem(pos, ammo_size, i, true);
1990                                 return;
1991                         }
1992                 }
1993                 return; // nothing to display
1994         }
1995
1996         stat_items = getstati(STAT_ITEMS);
1997         for (i = 0; i < AMMO_COUNT; ++i) {
1998                 currently_selected = stat_items & GetAmmoItemCode(i);
1999                 DrawAmmoItem(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, i, currently_selected);
2000                 ++row;
2001                 if(row >= rows)
2002                 {
2003                         row = 0;
2004                         column = column + 1;
2005                 }
2006         }
2007         drawfont = hud_font;
2008 }
2009
2010 void DrawNumIcon(float iconalign, vector myPos, vector mySize, float x, string icon, float left, vector color, float alpha)
2011 {
2012         vector newPos;
2013         float newSize_x, newSize_y;
2014         if(mySize_x/mySize_y > 3)
2015         {
2016                 newSize_x = 3 * mySize_y;
2017                 newSize_y = mySize_y;
2018
2019                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
2020                 newPos_y = myPos_y;
2021         }
2022         else
2023         {
2024                 newSize_y = 1/3 * mySize_x;
2025                 newSize_x = mySize_x;
2026
2027                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
2028                 newPos_x = myPos_x;
2029         }
2030
2031         vector picpos, numpos;
2032         if(left)
2033         {
2034                 if(iconalign == 1 || iconalign == 3) // right align
2035                 {
2036                         numpos = newPos;
2037                         picpos = newPos + eX * 2 * newSize_y;
2038                 }
2039                 else // left align
2040                 {
2041                         numpos = newPos + eX * newSize_y;
2042                         picpos = newPos;
2043                 }
2044         }
2045         else
2046         {
2047                 if(iconalign == 0 || iconalign == 3) // left align
2048                 {
2049                         numpos = newPos + eX * newSize_y;
2050                         picpos = newPos;
2051                 } 
2052                 else // right align
2053                 {
2054                         numpos = newPos;
2055                         picpos = newPos + eX * 2 * newSize_y;
2056                 }
2057         }
2058
2059         drawfont = hud_bigfont;
2060         drawstring_aspect(numpos, ftos(x), eX * (2/3) * newSize_x + eY * newSize_y, color, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
2061         drawfont = hud_font;
2062         drawpic_aspect_skin(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
2063 }
2064
2065 void DrawNumIcon_expanding(float iconalign, vector myPos, vector mySize, float x, string icon, float left, vector color, float fadelerp)
2066 {
2067         float sz;
2068         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
2069
2070         DrawNumIcon(iconalign, myPos + expandingbox_resize_centered_box_offset(sz, mySize, 1), mySize * sz, x, icon, left, color, (1 - fadelerp));
2071 }
2072
2073 // Powerups (#2)
2074 //
2075 void HUD_Powerups(void) {
2076         if(!autocvar_hud_panel_powerups && !autocvar__hud_configure)
2077                 return;
2078
2079         if(!autocvar__hud_configure)
2080         {
2081                 if not(getstati(STAT_ITEMS) & (IT_STRENGTH | IT_INVINCIBLE))
2082                         return;
2083
2084                 if (getstati(STAT_HEALTH) <= 0)
2085                         return;
2086         }
2087
2088         active_panel = HUD_PANEL_POWERUPS;
2089         HUD_Panel_UpdateCvars(powerups);
2090         vector pos, mySize;
2091         pos = panel_pos;
2092         mySize = panel_size;
2093
2094         float strength_time, shield_time;
2095         if(autocvar__hud_configure)
2096         {
2097                 strength_time = 15;
2098                 shield_time = 27;
2099         }
2100         else
2101         {
2102                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
2103                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
2104         }
2105
2106         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time), 1));
2107         if(panel_bg_padding)
2108         {
2109                 pos += '1 1 0' * panel_bg_padding;
2110                 mySize -= '2 2 0' * panel_bg_padding;
2111         }
2112
2113         vector barpos, barsize;
2114         vector picpos;
2115         vector numpos;
2116
2117         string leftname, rightname;
2118     string leftprogressname, rightprogressname;
2119         float leftcnt, rightcnt;
2120         float leftexact, rightexact;
2121         float flip = cvar("hud_panel_powerups_flip");
2122         if (flip) {
2123                 leftname = "strength";
2124         leftprogressname = cvar_string("hud_panel_powerups_progressbar_strength");
2125                 leftcnt = ceil(strength_time);
2126                 leftexact = strength_time;
2127
2128                 rightname = "shield";
2129         rightprogressname = cvar_string("hud_panel_powerups_progressbar_shield");
2130                 rightcnt = ceil(shield_time);
2131                 rightexact = shield_time;
2132         } else {
2133                 leftname = "shield";
2134         leftprogressname = cvar_string("hud_panel_powerups_progressbar_shield");
2135                 leftcnt = ceil(shield_time);
2136                 leftexact = shield_time;
2137
2138                 rightname = "strength";
2139         rightprogressname = cvar_string("hud_panel_powerups_progressbar_strength");
2140                 rightcnt = ceil(strength_time);
2141                 rightexact = strength_time;
2142         }
2143
2144         drawfont = hud_bigfont;
2145         float baralign = cvar("hud_panel_powerups_baralign");
2146     float barflip;
2147         float iconalign = cvar("hud_panel_powerups_iconalign");
2148         float progressbar = cvar("hud_panel_powerups_progressbar");
2149         if (mySize_x/mySize_y > 4)
2150         {
2151         barsize = eX * 0.5 * mySize_x + eY * mySize_y;
2152                 if(leftcnt)
2153                 {
2154                         if(baralign == 1 || baralign == 3) { // right align
2155                 barpos = pos + eX * 0.5 * mySize_x;
2156                 barflip = 1;
2157                         } else { // left align
2158                 barpos = pos;
2159                 barflip = 0;
2160                         }
2161
2162                         if(progressbar)
2163                         {
2164                                 HUD_Panel_GetProgressBarColorForString(leftname);
2165                                 HUD_Panel_DrawProgressBar(barpos, barsize, leftprogressname, 0, barflip, min(1, leftcnt/30), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * bound(0, max(strength_time, shield_time), 1), DRAWFLAG_NORMAL);
2166                         }
2167             if(cvar("hud_panel_powerups_text"))
2168             {
2169                 if(leftcnt > 1)
2170                     DrawNumIcon(iconalign, pos, eX * 0.5 * mySize_x + eY * mySize_y, leftcnt, leftname, 1, '1 1 1', 1);
2171                 if(leftcnt <= 5)
2172                     DrawNumIcon_expanding(iconalign, pos, eX * 0.5 * mySize_x + eY * mySize_y, leftcnt, leftname, 1, '1 1 1', bound(0, (leftcnt - leftexact) / 0.5, 1));
2173             }
2174                 }
2175
2176                 if(rightcnt)
2177                 {
2178                         if(baralign == 0 || baralign == 3) { // left align
2179                 barpos = pos;
2180                 barflip = 0;
2181                         } else { // right align
2182                 barpos = pos + eX * 0.5 * mySize_x;
2183                 barflip = 1;
2184                         }
2185
2186                         if(progressbar)
2187                         {
2188                                 HUD_Panel_GetProgressBarColorForString(rightname);
2189                                 HUD_Panel_DrawProgressBar(barpos, barsize, rightprogressname, 0, barflip, min(1, rightcnt/30), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * bound(0, max(strength_time, shield_time), 1), DRAWFLAG_NORMAL);
2190                         }
2191             if(cvar("hud_panel_powerups_text"))
2192             {
2193                 if(rightcnt > 1)
2194                     DrawNumIcon(iconalign, pos + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * mySize_y, rightcnt, rightname, 0, '1 1 1', 1);
2195                 if(rightcnt <= 5)
2196                     DrawNumIcon_expanding(iconalign, pos + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * mySize_y, rightcnt, rightname, 0, '1 1 1', bound(0, (rightcnt - rightexact) / 0.5, 1));
2197             }
2198                 }
2199         }
2200         else if (mySize_x/mySize_y > 1.5)
2201         {
2202         barsize = eX * mySize_x + eY * 0.5 * mySize_y;
2203                 if(leftcnt)
2204                 {
2205             barpos = pos;
2206                         if(baralign == 1 || baralign == 3) { // right/down align
2207                 barflip = 1;
2208                         } else { // left/up align
2209                 barflip = 0;
2210                         }
2211
2212                         if(progressbar)
2213                         {
2214                                 HUD_Panel_GetProgressBarColorForString(leftname);
2215                                 HUD_Panel_DrawProgressBar(barpos, barsize, leftprogressname, 0, barflip, min(1, leftcnt/30), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * bound(0, max(strength_time, shield_time), 1), DRAWFLAG_NORMAL);
2216                         }
2217             if(cvar("hud_panel_powerups_text"))
2218             {
2219                 if(leftcnt > 1)
2220                     DrawNumIcon(iconalign, pos, eX * mySize_x + eY * 0.5 * mySize_y, leftcnt, leftname, 1, '1 1 1', 1);
2221                 if(leftcnt <= 5)
2222                     DrawNumIcon_expanding(iconalign, pos, eX * mySize_x + eY * 0.5 * mySize_y, leftcnt, leftname, 1, '1 1 1', bound(0, (leftcnt - leftexact) / 0.5, 1));
2223             }
2224                 }
2225
2226                 if(rightcnt)
2227                 {
2228             barpos = pos + eY * 0.5 * mySize_y;
2229                         if(baralign == 0 || baralign == 3) { // left align
2230                 barflip = 0;
2231                         } else { // right align
2232                 barflip = 1;
2233                         }
2234
2235                         if(progressbar)
2236                         {
2237                                 HUD_Panel_GetProgressBarColorForString(rightname);
2238                                 HUD_Panel_DrawProgressBar(barpos, barsize, rightprogressname, 0, barflip, min(1, rightcnt/30), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * bound(0, max(strength_time, shield_time), 1), DRAWFLAG_NORMAL);
2239                         }
2240             if(cvar("hud_panel_powerups_text"))
2241             {
2242                 if(rightcnt > 1)
2243                     DrawNumIcon(iconalign, pos + eY * 0.5 * mySize_y, eX * mySize_x + eY * 0.5 * mySize_y, rightcnt, rightname, 0, '1 1 1', 1);
2244                 if(rightcnt <= 5)
2245                     DrawNumIcon_expanding(iconalign, pos + eY * 0.5 * mySize_y, eX * mySize_x + eY * 0.5 * mySize_y, rightcnt, rightname, 0, '1 1 1', bound(0, (rightcnt - rightexact) / 0.5, 1));
2246             }
2247                 }
2248         }
2249         else
2250         {
2251         barsize = eX * 0.5 * mySize_x + eY * mySize_y;
2252                 if(leftcnt)
2253                 {
2254             barpos = pos;
2255                         if(baralign == 1 || baralign == 3) { // down align
2256                 barflip = 1;
2257                         } else { // up align
2258                 barflip = 0;
2259                         }
2260
2261                         if(iconalign == 1 || iconalign == 3) { // down align
2262                                 picpos = pos + eX * 0.05 * mySize_x + eY * (mySize_y - 0.65 * mySize_x);
2263                                 numpos = pos + eY * mySize_y - eY * 0.25 * mySize_x;
2264                         } else { // up align
2265                                 picpos = pos + eX * 0.05 * mySize_x;
2266                                 numpos = pos + eY * 0.4 * mySize_x;
2267                         }
2268
2269                         if(progressbar)
2270                         {
2271                                 HUD_Panel_GetProgressBarColorForString(leftname);
2272                                 HUD_Panel_DrawProgressBar(barpos, barsize, leftprogressname, 1, barflip, min(1, leftcnt/30), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * bound(0, max(strength_time, shield_time), 1), DRAWFLAG_NORMAL);
2273                         }
2274             if(cvar("hud_panel_powerups_text"))
2275             {
2276                 if(leftcnt <= 5)
2277                     drawpic_aspect_skin_expanding(picpos, leftname, '0.4 0.4 0' * mySize_x, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, bound(0, (leftcnt - leftexact) / 0.5, 1));
2278                 if(leftcnt > 1)
2279                     drawpic_aspect_skin(picpos, leftname, '0.4 0.4 0' * mySize_x, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2280                 drawstring_aspect(numpos, ftos(leftcnt), eX * 0.5 * mySize_x + eY * 0.25 * mySize_x, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2281             }
2282                 }
2283
2284                 if(rightcnt)
2285                 {
2286             barpos = pos + eX * 0.5 * mySize_x;
2287                         if(baralign == 0 || baralign == 3) { // down align
2288                 barflip = 1;
2289                         } else { // up align
2290                 barflip = 0;
2291                         }
2292
2293                         if(iconalign == 0 || iconalign == 3) { // up align
2294                                 picpos = pos + eX * 0.05 * mySize_x + eX * 0.5 * mySize_x;
2295                                 numpos = pos + eY * 0.4 * mySize_x + eX * 0.5 * mySize_x;
2296                         } else { // down align
2297                                 picpos = pos + eX * 0.05 * mySize_x + eY * (mySize_y - 0.65 * mySize_x) + eX * 0.5 * mySize_x;
2298                                 numpos = pos + eY * mySize_y - eY * 0.25 * mySize_x + eX * 0.5 * mySize_x;
2299                         }
2300
2301                         if(progressbar)
2302                         {
2303                                 HUD_Panel_GetProgressBarColorForString(rightname);
2304                                 HUD_Panel_DrawProgressBar(barpos, barsize, rightprogressname, 1, barflip, min(1, rightcnt/30), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * bound(0, max(strength_time, shield_time), 1), DRAWFLAG_NORMAL);
2305                         }
2306             if(cvar("hud_panel_powerups_text"))
2307             {
2308                 if(rightcnt <= 5)
2309                     drawpic_aspect_skin_expanding(picpos, rightname, '0.4 0.4 0' * mySize_x, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, bound(0, (rightcnt - rightexact) / 0.5, 1));
2310                 if(rightcnt > 1)
2311                     drawpic_aspect_skin(picpos, rightname, '0.4 0.4 0' * mySize_x, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2312                 drawstring_aspect(numpos, ftos(rightcnt), eX * 0.5 * mySize_x + eY * 0.25 * mySize_x, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2313             }
2314                 }
2315         }
2316         drawfont = hud_font;
2317 }
2318
2319 // Health/armor (#3)
2320 //
2321 void HUD_HealthArmor(void)
2322 {
2323         if(!autocvar_hud_panel_healtharmor && !autocvar__hud_configure)
2324                 return;
2325
2326         active_panel = HUD_PANEL_HEALTHARMOR;
2327         HUD_Panel_UpdateCvars(healtharmor);
2328         vector pos, mySize;
2329         pos = panel_pos;
2330         mySize = panel_size;
2331
2332         HUD_Panel_DrawBg(1);
2333         if(panel_bg_padding)
2334         {
2335                 pos += '1 1 0' * panel_bg_padding;
2336                 mySize -= '2 2 0' * panel_bg_padding;
2337         }
2338
2339         float armor, health, fuel;
2340         armor = getstati(STAT_ARMOR);
2341         health = getstati(STAT_HEALTH);
2342         fuel = getstati(STAT_FUEL);
2343
2344         if(autocvar__hud_configure)
2345         {
2346                 armor = 75;
2347                 health = 150;
2348                 fuel = 20;
2349         }
2350
2351         if(health <= 0)
2352                 return;
2353
2354         vector barpos, barsize;
2355         vector picpos;
2356         vector numpos;
2357
2358         drawfont = hud_bigfont;
2359         float baralign = cvar("hud_panel_healtharmor_baralign");
2360         float iconalign = cvar("hud_panel_healtharmor_iconalign");
2361         float progressbar = cvar("hud_panel_healtharmor_progressbar");
2362
2363     float maxhealth = cvar("hud_panel_healtharmor_maxhealth");
2364     float maxarmor = cvar("hud_panel_healtharmor_maxarmor");
2365         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
2366         {
2367                 vector v;
2368                 v = healtharmor_maxdamage(health, armor, armorblockpercent);
2369
2370                 float x;
2371                 x = floor(v_x + 1);
2372
2373         float maxtotal = maxhealth + maxarmor;
2374
2375         barpos = pos;
2376         barsize = mySize;
2377
2378                 string biggercount;
2379                 if(v_z) // NOT fully armored
2380                 {
2381                         biggercount = "health";
2382                         if(progressbar)
2383                         {
2384                                 HUD_Panel_GetProgressBarColor(health);
2385                                 HUD_Panel_DrawProgressBar(barpos, barsize, cvar_string("hud_panel_healtharmor_progressbar_health"), 0, mod(baralign, 2), x/maxtotal, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2386                         }
2387                         if(armor)
2388             if(cvar("hud_panel_healtharmor_text"))
2389                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
2390                 }
2391                 else
2392                 {
2393                         biggercount = "armor";
2394                         if(progressbar)
2395                         {
2396                                 HUD_Panel_GetProgressBarColor(armor);
2397                                 HUD_Panel_DrawProgressBar(barpos, barsize, cvar_string("hud_panel_healtharmor_progressbar_armor"), 0, mod(baralign, 2), x/maxtotal, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2398                         }
2399                         if(health)
2400             if(cvar("hud_panel_healtharmor_text"))
2401                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2402                 }
2403         if(cvar("hud_panel_healtharmor_text"))
2404             DrawNumIcon(iconalign, pos, mySize, x, biggercount, 1, HUD_Get_Num_Color(x, maxtotal), 1);
2405
2406                 // fuel
2407                 if(fuel)
2408                 {
2409             barpos = pos;
2410             barsize = eX * mySize_x + eY * 0.2 * mySize_y;
2411                         HUD_Panel_GetProgressBarColor(fuel);
2412             HUD_Panel_DrawProgressBar(barpos, barsize, "progressbar", 0, mod(baralign, 2), min(1, fuel/100), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
2413                 }
2414         }
2415         else
2416         {
2417                 string leftname, rightname;
2418         string leftprogressname, rightprogressname;
2419                 float leftcnt, rightcnt;
2420                 float leftmax, rightmax;
2421                 float leftactive, rightactive;
2422                 float leftalpha, rightalpha;
2423                 float flip = cvar("hud_panel_healtharmor_flip");
2424         float barflip;
2425                 if (flip) { // old style layout with armor left/top of health
2426                         leftname = "armor";
2427             leftprogressname = cvar_string("hud_panel_healtharmor_progressbar_armor");
2428                         leftcnt = armor;
2429                         if(leftcnt)
2430                                 leftactive = 1;
2431                         leftalpha = min((armor+10)/55, 1);
2432             leftmax = maxarmor;
2433
2434                         rightname = "health";
2435             rightprogressname = cvar_string("hud_panel_healtharmor_progressbar_health");
2436                         rightcnt = health;
2437                         rightactive = 1;
2438                         rightalpha = 1;
2439             rightmax = maxhealth;
2440                 } else {
2441                         leftname = "health";
2442             leftprogressname = cvar_string("hud_panel_healtharmor_progressbar_health");
2443                         leftcnt = health;
2444                         leftactive = 1;
2445                         leftalpha = 1;
2446             leftmax = maxhealth;
2447
2448                         rightname = "armor";
2449             rightprogressname = cvar_string("hud_panel_healtharmor_progressbar_armor");
2450                         rightcnt = armor;
2451                         if(rightcnt)
2452                                 rightactive = 1;
2453                         rightalpha = min((armor+10)/55, 1);
2454             rightmax = maxarmor;
2455                 }
2456
2457                 if (mySize_x/mySize_y > 4)
2458                 {
2459             barsize = eX * 0.5 * mySize_x + eY * mySize_y;
2460                         if(leftactive)
2461                         {
2462                 barpos = pos;
2463                                 if(baralign == 1 || baralign == 3) { // right align
2464                     barflip = 1;
2465                                 } else { // left align
2466                     barflip = 0;
2467                                 }
2468
2469                                 if(progressbar)
2470                                 {
2471                                         HUD_Panel_GetProgressBarColorForString(leftname);
2472                     HUD_Panel_DrawProgressBar(barpos, barsize, leftprogressname, 0, barflip, min(1, leftcnt/leftmax), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2473                                 }
2474                 if(cvar("hud_panel_healtharmor_text"))
2475                     DrawNumIcon(iconalign, pos, eX * 0.5 * mySize_x + eY * mySize_y, leftcnt, leftname, 1, HUD_Get_Num_Color(leftcnt, leftmax), 1);
2476                         }
2477
2478                         if(rightactive)
2479                         {
2480                 barpos = pos + eX * 0.5 * mySize_x;
2481                                 if(baralign == 0 || baralign == 3) { // left align
2482                     barflip = 0;
2483                                 } else { // right align
2484                     barflip = 1;
2485                                 }
2486
2487                                 if(progressbar)
2488                                 {
2489                                         HUD_Panel_GetProgressBarColorForString(rightname);
2490                     HUD_Panel_DrawProgressBar(barpos, barsize, rightprogressname, 0, barflip, min(1, rightcnt/rightmax), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2491                                 }
2492                 if(cvar("hud_panel_healtharmor_text"))
2493                     DrawNumIcon(iconalign, pos + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * mySize_y, rightcnt, rightname, 0, HUD_Get_Num_Color(rightcnt, rightmax), 1);
2494                         }
2495
2496                         if(fuel)
2497                         {
2498                 barpos = pos;
2499                 barsize = eX * mySize_x + eY * 0.2 * mySize_y;
2500                 HUD_Panel_GetProgressBarColor(fuel);
2501                 HUD_Panel_DrawProgressBar(barpos, barsize, "progressbar", 0, mod(baralign, 2), min(1, fuel/100), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
2502                         }
2503                 }
2504                 else if (mySize_x/mySize_y > 1.5)
2505                 {
2506             barsize = eX * mySize_x + eY * 0.5 * mySize_y;
2507                         if(leftactive)
2508                         {
2509                 barpos = pos;
2510                                 if(baralign == 1 || baralign == 3) { // right align
2511                     barflip = 1;
2512                                 } else { // left align
2513                     barflip = 0;
2514                                 }
2515
2516                                 if(progressbar)
2517                                 {
2518                                         HUD_Panel_GetProgressBarColorForString(leftname);
2519                     HUD_Panel_DrawProgressBar(barpos, barsize, leftprogressname, 0, barflip, min(1, leftcnt/leftmax), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2520                                 }
2521                 if(cvar("hud_panel_healtharmor_text"))
2522                     DrawNumIcon(iconalign, pos, eX * mySize_x + eY * 0.5 * mySize_y, leftcnt, leftname, 1, HUD_Get_Num_Color(leftcnt, leftmax), 1);
2523                         }
2524
2525                         if(rightactive)
2526                         {
2527                 barpos = pos + eY * 0.5 * mySize_y;
2528                                 if(baralign == 0 || baralign == 3) { // left align
2529                     barflip = 0;
2530                                 } else { // right align
2531                     barflip = 1;
2532                                 }
2533
2534                                 if(progressbar)
2535                                 {
2536                                         HUD_Panel_GetProgressBarColorForString(rightname);
2537                     HUD_Panel_DrawProgressBar(barpos, barsize, rightprogressname, 0, barflip, min(1, rightcnt/rightmax), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2538                                 }
2539                 if(cvar("hud_panel_healtharmor_text"))
2540                     DrawNumIcon(iconalign, pos + eY * 0.5 * mySize_y, eX * mySize_x + eY * 0.5 * mySize_y, rightcnt, rightname, 0, HUD_Get_Num_Color(rightcnt, rightmax), 1);
2541                         }
2542
2543                         if(fuel)
2544                         {
2545                 barpos = pos;
2546                 barsize = eX * mySize_x + eY * 0.2 * mySize_y;
2547                 HUD_Panel_GetProgressBarColor(fuel);
2548                 HUD_Panel_DrawProgressBar(barpos, barsize, "progressbar", 0, mod(baralign, 2), min(1, fuel/100), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
2549                         }
2550                 }
2551                 else
2552                 {
2553             barsize = eX * 0.5 * mySize_x + eY * mySize_y;
2554                         if(leftactive)
2555                         {
2556                 barpos = pos;
2557                                 if(baralign == 1 || baralign == 3) { // right align
2558                     barflip = 1;
2559                                 } else { // left align
2560                     barflip = 0;
2561                                 }
2562
2563                                 if(iconalign == 1 || iconalign == 3) { // down align
2564                                         picpos = pos + eX * 0.05 * mySize_x + eY * (mySize_y - 0.65 * mySize_x);
2565                                         numpos = pos + eY * mySize_y - eY * 0.25 * mySize_x;
2566                                 } else { // up align
2567                                         picpos = pos + eX * 0.05 * mySize_x;
2568                                         numpos = pos + eY * 0.4 * mySize_x;
2569                                 }
2570
2571                                 if(progressbar)
2572                                 {
2573                                         HUD_Panel_GetProgressBarColorForString(leftname);
2574                     HUD_Panel_DrawProgressBar(barpos, barsize, leftprogressname, 1, barflip, min(1, leftcnt/leftmax), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2575                                 }
2576                 if(cvar("hud_panel_healtharmor_text"))
2577                 {
2578                     drawpic_aspect_skin(picpos, leftname, '0.4 0.4 0' * mySize_x, '1 1 1', leftalpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2579                     drawstring_aspect(numpos, ftos(leftcnt), eX * 0.5 * mySize_x + eY * 0.25 * mySize_x, HUD_Get_Num_Color(leftcnt, leftmax), panel_fg_alpha, DRAWFLAG_NORMAL);
2580                 }
2581                         }
2582
2583                         if(rightactive)
2584                         {
2585                 barpos = pos + eX * 0.5 * mySize_x;
2586                                 if(baralign == 0 || baralign == 3) { // left align
2587                     barflip = 0;
2588                                 } else { // right align
2589                     barflip = 1;
2590                                 }
2591
2592                                 if(iconalign == 0 || iconalign == 3) { // up align
2593                                         picpos = pos + eX * 0.05 * mySize_x + eX * 0.5 * mySize_x;
2594                                         numpos = pos + eY * 0.4 * mySize_x + eX * 0.5 * mySize_x;
2595                                 } else { // down align
2596                                         picpos = pos + eX * 0.05 * mySize_x + eY * (mySize_y - 0.65 * mySize_x) + eX * 0.5 * mySize_x;
2597                                         numpos = pos + eY * mySize_y - eY * 0.25 * mySize_x + eX * 0.5 * mySize_x;
2598                                 }
2599
2600                                 if(progressbar)
2601                                 {
2602                                         HUD_Panel_GetProgressBarColorForString(rightname);
2603                     HUD_Panel_DrawProgressBar(barpos, barsize, rightprogressname, 1, barflip, min(1, rightcnt/rightmax), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2604                                 }
2605                 if(cvar("hud_panel_healtharmor_text"))
2606                 {
2607                     drawpic_aspect_skin(picpos, rightname, '0.4 0.4 0' * mySize_x, '1 1 1', rightalpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2608                     drawstring_aspect(numpos, ftos(rightcnt), eX * 0.5 * mySize_x + eY * 0.25 * mySize_x, HUD_Get_Num_Color(rightcnt, rightmax), panel_fg_alpha, DRAWFLAG_NORMAL);
2609                 }
2610                         }
2611
2612                         if(fuel)
2613                         {
2614                 barpos = pos;
2615                 barsize = eX * 0.05 * mySize_x + eY * mySize_y;
2616                 HUD_Panel_GetProgressBarColor(fuel);
2617                 HUD_Panel_DrawProgressBar(barpos, barsize, "progressbar", 1, mod(baralign, 2), min(1, fuel/100), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
2618                         }
2619                 }
2620         }
2621         drawfont = hud_font;
2622 }
2623
2624 // Notification area (#4)
2625 //
2626
2627 string Weapon_SuicideMessage(float deathtype)
2628 {
2629         w_deathtype = deathtype;
2630         get_weaponinfo(DEATH_WEAPONOF(deathtype)).weapon_func(WR_SUICIDEMESSAGE);
2631         return w_deathtypestring;
2632 }
2633
2634 string Weapon_KillMessage(float deathtype)
2635 {
2636         w_deathtype = deathtype;
2637         get_weaponinfo(DEATH_WEAPONOF(deathtype)).weapon_func(WR_KILLMESSAGE);
2638         return w_deathtypestring;
2639 }
2640
2641 #define KN_MAX_ENTRIES 10
2642 float kn_index;
2643 float killnotify_times[KN_MAX_ENTRIES];
2644 float killnotify_deathtype[KN_MAX_ENTRIES];
2645 float killnotify_actiontype[KN_MAX_ENTRIES]; // 0 = "Y [used by] X", 1 = "X [did action to] Y"
2646 string killnotify_attackers[KN_MAX_ENTRIES];
2647 string killnotify_victims[KN_MAX_ENTRIES];
2648 void HUD_KillNotify_Push(string attacker, string victim, float actiontype, float wpn)
2649 {
2650         --kn_index;
2651         if (kn_index == -1)
2652                 kn_index = KN_MAX_ENTRIES-1;
2653         killnotify_times[kn_index] = time;
2654         killnotify_deathtype[kn_index] = wpn;
2655         killnotify_actiontype[kn_index] = actiontype;
2656         if(killnotify_attackers[kn_index])
2657                 strunzone(killnotify_attackers[kn_index]);
2658         killnotify_attackers[kn_index] = strzone(attacker);
2659         if(killnotify_victims[kn_index])
2660                 strunzone(killnotify_victims[kn_index]);
2661         killnotify_victims[kn_index] = strzone(victim);
2662 }
2663
2664 void HUD_KillNotify(string s1, string s2, string s3, float type, float msg) // s1 = attacker, s2 = victim
2665 {
2666         float w;
2667         float alsoprint, gentle;
2668         alsoprint = (cvar("hud_panel_notify_print") || !panel_enabled); // print message to console if: notify panel disabled, or cvar to do so enabled
2669         gentle = (cvar("cl_gentle") || cvar("cl_gentle_messages"));
2670         
2671         if ((msg == MSG_SUICIDE || msg == MSG_KILL || msg == MSG_KILL_ACTION) && gametype == GAME_CTS) // selfkill isn't interesting in CTS and only spams up the notify panel
2672                 return;
2673
2674         if(msg == MSG_SUICIDE) {
2675                 w = DEATH_WEAPONOF(type);
2676                 if(WEP_VALID(w)) {
2677                         HUD_KillNotify_Push(s1, "", 0, DEATH_GENERIC);
2678                         if (alsoprint)
2679                                 print("^1", sprintf(Weapon_SuicideMessage(type), strcat(s1, "^1")), "\n");
2680                 } else if (type == DEATH_KILL) {
2681                         HUD_KillNotify_Push(s1, "", 0, DEATH_KILL);
2682                         if (alsoprint)
2683                                 print ("^1",s1, "^1 couldn't take it anymore\n");
2684                 } else if (type == DEATH_ROT) {
2685                         HUD_KillNotify_Push(s1, "", 0, DEATH_GENERIC);
2686                         if (alsoprint)
2687                                 print ("^1",s1, "^1 died\n");
2688                 } else if (type == DEATH_NOAMMO) {
2689                         HUD_KillNotify_Push(s1, "", 0, DEATH_NOAMMO);
2690                         if (alsoprint)
2691                                 print ("^7",s1, "^7 committed suicide. What's the point of living without ammo?\n");
2692                 } else if (type == DEATH_CAMP) {
2693                         HUD_KillNotify_Push(s1, "", 0, DEATH_CAMP);
2694                         if (alsoprint)
2695                                 print ("^1",s1, "^1 thought they found a nice camping ground\n");
2696                 } else if (type == KILL_TEAM_RED || type == KILL_TEAM_BLUE) {
2697                         HUD_KillNotify_Push(s1, "", 0, type);
2698                         if (alsoprint)
2699                                 print ("^1",s1, "^1 didn't become friends with the Lord of Teamplay\n");
2700                 } else if (type == DEATH_CHEAT) {
2701                         HUD_KillNotify_Push(s1, "", 0, DEATH_GENERIC);
2702                         if (alsoprint)
2703                                 print ("^1",s1, "^1 unfairly eliminated themself\n");
2704                 } else if (type == DEATH_FIRE) {
2705                         HUD_KillNotify_Push(s1, "", 0, DEATH_GENERIC);
2706                         if (alsoprint)
2707                                 print ("^1",s1, "^1 burned to death\n");
2708                 } else if (type != DEATH_TEAMCHANGE && type != DEATH_QUIET) {
2709                         HUD_KillNotify_Push(s1, "", 0, DEATH_GENERIC);
2710                         if (alsoprint)
2711                                 print ("^1",s1, "^1 couldn't resist the urge to self-destruct\n");
2712                 } 
2713                 
2714                 if (stof(s2) > 2) // killcount > 2
2715                         print ("^1",s1,"^1 ended it all after a ",s2," kill spree\n");
2716         } else if(msg == MSG_KILL) {
2717                 w = DEATH_WEAPONOF(type);
2718                 if(WEP_VALID(w)) {
2719                         if((w == WEP_CAMPINGRIFLE || w == WEP_MINSTANEX) && type & HITTYPE_HEADSHOT) // all headshot weapons go here
2720                                 HUD_KillNotify_Push(s1, s2, 1, DEATH_HEADSHOT);
2721                         else
2722                                 HUD_KillNotify_Push(s1, s2, 1, type);
2723
2724                         if (alsoprint)
2725                                 print("^1", sprintf(Weapon_KillMessage(type), strcat(s2, "^1"), strcat(s1, "^1")), "\n"); // default order: victim, killer
2726                 }
2727                 else if(type == KILL_TEAM_RED || type == KILL_TEAM_BLUE || type == KILL_TEAM_SPREE) {
2728                         HUD_KillNotify_Push(s1, s2, 1, type);
2729                         if(alsoprint)
2730                         {
2731                                 if(gentle) {
2732                                         print ("^1", s1, "^1 took action against a team mate\n");
2733                                 } else {
2734                                         print ("^1", s1, "^1 mows down a team mate\n");
2735                                 }
2736                         }
2737                         if (stof(s2) > 2 && type == KILL_TEAM_SPREE) {
2738                                 if(gentle)
2739                                         print ("^1",s1,"^1 ended a ",s3," scoring spree by going against a team mate\n");
2740                                 else
2741                                         print ("^1",s1,"^1 ended a ",s3," kill spree by killing a team mate\n");
2742                         }
2743                         else if (stof(s2) > 2) {
2744                                 if(gentle)
2745                                         print ("^1",s1,"'s ^1",s3," scoring spree was ended by a team mate!\n");
2746                                 else
2747                                         print ("^1",s1,"'s ^1",s3," kill spree was ended by a team mate!\n");
2748                         }
2749                 }
2750                 else if(type == KILL_FIRST_BLOOD)
2751                         print("^1",s1, "^1 drew first blood", "\n");
2752                 else if (type == DEATH_TELEFRAG) {
2753                         HUD_KillNotify_Push(s1, s2, 1, DEATH_TELEFRAG);
2754                         if(gentle)
2755                                 print ("^1",s2, "^1 tried to occupy ", s1, "^1's teleport destination space\n");
2756                         else
2757                                 print ("^1",s2, "^1 was telefragged by ", s1, "\n");
2758                 }
2759                 else if (type == DEATH_DROWN) {
2760                         HUD_KillNotify_Push(s1, s2, 1, DEATH_DROWN);
2761                         if(alsoprint)
2762                                 print ("^1",s2, "^1 was drowned by ", s1, "\n");
2763                 }
2764                 else if (type == DEATH_SLIME) {
2765                         HUD_KillNotify_Push(s1, s2, 1, DEATH_SLIME);
2766                         if(alsoprint)
2767                                 print ("^1",s2, "^1 was slimed by ", s1, "\n");
2768                 }
2769                 else if (type == DEATH_LAVA) {
2770                         HUD_KillNotify_Push(s1, s2, 1, DEATH_LAVA);
2771                         if(alsoprint)
2772                                 print ("^1",s2, "^1 was cooked by ", s1, "\n");
2773                 }
2774                 else if (type == DEATH_FALL) {
2775                         HUD_KillNotify_Push(s1, s2, 1, DEATH_FALL);
2776                         if(alsoprint)
2777                                 print ("^1",s2, "^1 was grounded by ", s1, "\n");
2778                 }
2779                 else if (type == DEATH_SHOOTING_STAR) {
2780                         HUD_KillNotify_Push(s1, s2, 1, DEATH_SHOOTING_STAR);
2781                         if(alsoprint)
2782                                 print ("^1",s2, "^1 was shot into space by ", s1, "\n");
2783                 }
2784                 else if (type == DEATH_SWAMP) {
2785                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2786                         if(alsoprint)
2787                                 print ("^1",s2, "^1 was conserved by ", s1, "\n");
2788                 }
2789                 else if (type == DEATH_HURTTRIGGER)
2790                 {
2791                         HUD_KillNotify_Push(s1, s2, 1, DEATH_HURTTRIGGER);
2792                         if(alsoprint)
2793                                 print("^1",s2, "^1 was thrown into a world of hurt by ", s1, "\n");
2794                 } else if(type == DEATH_SBCRUSH) {
2795                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2796                         if(alsoprint)
2797                                 print ("^1",s2, "^1 was crushed by ^1", s1, "\n");
2798                 } else if(type == DEATH_SBMINIGUN) {
2799                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2800                         if(alsoprint)
2801                                 print ("^1",s2, "^1 got shredded by ^1", s1, "\n");
2802                 } else if(type == DEATH_SBROCKET) {
2803                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2804                         if(alsoprint)
2805                                 print ("^1",s2, "^1 was blased to bits by ^1", s1, "\n");
2806                 } else if(type == DEATH_SBBLOWUP) {
2807                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2808                         if(alsoprint)
2809                                 print ("^1",s2, "^1 got caught in the destruction of ^1", s1, "'s vehicle\n");
2810                 } else if(type == DEATH_WAKIGUN) {
2811                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2812                         if(alsoprint)
2813                                 print ("^1",s2, "^1 was bolted down by ^1", s1, "\n");
2814                 } else if(type == DEATH_WAKIROCKET) {
2815                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2816                         if(alsoprint)
2817                                 print ("^1",s2, "^1 could find no shelter from ^1", s1, "'s rockets\n");
2818                 } else if(type == DEATH_WAKIBLOWUP) {
2819                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2820                         if(alsoprint)
2821                                 print ("^1",s2, "^1 dies when ^1", s1, "'s wakizashi dies.\n");
2822                 } else if(type == DEATH_TURRET) {
2823                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2824                         if(alsoprint)
2825                                 print ("^1",s2, "^1 was pushed into the line of fire by ^1", s1, "\n");
2826                 } else if(type == DEATH_TOUCHEXPLODE) {
2827                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2828                         if(alsoprint)
2829                                 print ("^1",s2, "^1 was pushed into an accident by ^1", s1, "\n");
2830                 } else if(type == DEATH_CHEAT) {
2831                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2832                         if(alsoprint)
2833                                 print ("^1",s2, "^1 was unfairly eliminated by ^1", s1, "\n");
2834                 } else if (type == DEATH_FIRE) {
2835                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2836                         if(alsoprint)
2837                                 print ("^1",s2, "^1 was burnt to death by ^1", s1, "\n");
2838                 } else if (type == DEATH_CUSTOM) {
2839                         HUD_KillNotify_Push(s1, s2, 1, DEATH_CUSTOM);
2840                         if(alsoprint)
2841                                 print("^1", sprintf(s3, strcat(s2, "^1"), strcat(s1, "^1")), "\n");
2842                 } else if (type == DEATH_HURTTRIGGER) {
2843                         HUD_KillNotify_Push(s1, s2, 1, DEATH_HURTTRIGGER);
2844                         if(alsoprint)
2845                                 print("^1", sprintf(s3, strcat(s2, "^1"), strcat(s1, "^1")), "\n");
2846                 } else {
2847                         HUD_KillNotify_Push(s1, s2, 1, DEATH_GENERIC);
2848                         if(alsoprint)
2849                                 print ("^1",s2, "^1 was fragged by ", s1, "\n");
2850                 }
2851         } else if(msg == MSG_SPREE) {
2852                 if(type == KILL_END_SPREE) {
2853                         if(gentle)
2854                                 print ("^1",s1,"'s ^1", s2, " scoring spree was ended by ", s3, "\n");
2855                         else
2856                                 print ("^1",s1,"'s ^1", s2, " kill spree was ended by ", s3, "\n");
2857                 } else if(type == KILL_SPREE) {
2858                         if(gentle)
2859                                 print ("^1",s1,"^1 made ",s2," scores in a row\n");
2860                         else
2861                                 print ("^1",s1,"^1 has ",s2," frags in a row\n");
2862                 } else if(type == KILL_SPREE_3) {
2863                         if(gentle)
2864                                 print (s1,"^7 made a ^1TRIPLE SCORE\n");
2865                         else
2866                                 print (s1,"^7 made a ^1TRIPLE FRAG\n");
2867       &nbs