qcsrc/client/hud.qc

   1 #include "scoreboard.qh"
   2 #include "teamradar.qh"
   3 #include "../common/buffs.qh"
   4 #include "../common/counting.qh"
   5 #include "../common/mapinfo.qh"
   6 #include "../common/nades.qh"
   7 #include "../server/t_items.qh"
   8
   9 /*
  10 ==================
  11 Misc HUD functions
  12 ==================
  13 */
  14
  15 // a border picture is a texture containing nine parts:
  16 //   1/4 width: left part
  17 //   1/2 width: middle part (stretched)
  18 //   1/4 width: right part
  19 // divided into
  20 //   1/4 height: top part
  21 //   1/2 height: middle part (stretched)
  22 //   1/4 height: bottom part
  23 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  24 {
  25     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  26     {
  27                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  28                 return;
  29     }
  30         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  31         {
  32                 // draw only the central part
  33                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  34                 return;
  35         }
  36
  37         vector dX, dY;
  38         vector width, height;
  39         vector bW, bH;
  40         //pic = draw_UseSkinFor(pic);
  41         width = eX * theSize.x;
  42         height = eY * theSize.y;
  43         if(theSize.x <= theBorderSize.x * 2)
  44         {
  45                 // not wide enough... draw just left and right then
  46                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  47                 if(theSize.y <= theBorderSize.y * 2)
  48                 {
  49                         // not high enough... draw just corners
  50                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  51                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  55                 }
  56                 else
  57                 {
  58                         dY = theBorderSize.x * eY;
  59                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  60                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  61                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  62                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  63                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  64                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  65                 }
  66         }
  67         else
  68         {
  69                 if(theSize.y <= theBorderSize.y * 2)
  70                 {
  71                         // not high enough... draw just top and bottom then
  72                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  73                         dX = theBorderSize.x * eX;
  74                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  75                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  80                 }
  81                 else
  82                 {
  83                         dX = theBorderSize.x * eX;
  84                         dY = theBorderSize.x * eY;
  85                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  87                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  88                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  89                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  90                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  93                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  94                 }
  95         }
  96 }
  97
  98 vector HUD_Get_Num_Color (float x, float maxvalue)
  99 {
 100         float blinkingamt;
 101         vector color;
 102         if(x >= maxvalue) {
 103                 color.x = sin(2*M_PI*time);
 104                 color.y = 1;
 105                 color.z = sin(2*M_PI*time);
 106         }
 107         else if(x > maxvalue * 0.75) {
 108                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 109                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 110                 color.z = 0;
 111         }
 112         else if(x > maxvalue * 0.5) {
 113                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 114                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 115                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 116         }
 117         else if(x > maxvalue * 0.25) {
 118                 color.x = 1;
 119                 color.y = 1;
 120                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 121         }
 122         else if(x > maxvalue * 0.1) {
 123                 color.x = 1;
 124                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 125                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 126         }
 127         else {
 128                 color.x = 1;
 129                 color.y = 0;
 130                 color.z = 0;
 131         }
 132
 133         blinkingamt = (1 - x/maxvalue/0.25);
 134         if(blinkingamt > 0)
 135         {
 136                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 137                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 138                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 139         }
 140         return color;
 141 }
 142
 143 float HUD_GetRowCount(float item_count, vector size, float item_aspect)
 144 {
 145         float aspect = size_y / size_x;
 146         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 147 }
 148
 149 float stringwidth_colors(string s, vector theSize)
 150 {
 151         return stringwidth(s, true, theSize);
 152 }
 153
 154 float stringwidth_nocolors(string s, vector theSize)
 155 {
 156         return stringwidth(s, false, theSize);
 157 }
 158
 159 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 160 {
 161         position.x -= 2 / 3 * strlen(text) * theScale.x;
 162         drawstring(position, text, theScale, rgb, theAlpha, flag);
 163 }
 164
 165 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 166 {
 167         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 168         drawstring(position, text, theScale, rgb, theAlpha, flag);
 169 }
 170
 171 // return the string of the onscreen race timer
 172 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 173 {
 174         string col;
 175         string timestr;
 176         string cpname;
 177         string lapstr;
 178         lapstr = "";
 179
 180         if(histime == 0) // goal hit
 181         {
 182                 if(mytime > 0)
 183                 {
 184                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 185                         col = "^1";
 186                 }
 187                 else if(mytime == 0)
 188                 {
 189                         timestr = "+0.0";
 190                         col = "^3";
 191                 }
 192                 else
 193                 {
 194                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 195                         col = "^2";
 196                 }
 197
 198                 if(lapdelta > 0)
 199                 {
 200                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 201                         col = "^2";
 202                 }
 203                 else if(lapdelta < 0)
 204                 {
 205                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 206                         col = "^1";
 207                 }
 208         }
 209         else if(histime > 0) // anticipation
 210         {
 211                 if(mytime >= histime)
 212                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 213                 else
 214                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 215                 col = "^3";
 216         }
 217         else
 218         {
 219                 col = "^7";
 220                 timestr = "";
 221         }
 222
 223         if(cp == 254)
 224                 cpname = _("Start line");
 225         else if(cp == 255)
 226                 cpname = _("Finish line");
 227         else if(cp)
 228                 cpname = sprintf(_("Intermediate %d"), cp);
 229         else
 230                 cpname = _("Finish line");
 231
 232         if(histime < 0)
 233                 return strcat(col, cpname);
 234         else if(hisname == "")
 235                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 236         else
 237                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(hisname, col, lapstr)));
 238 }
 239
 240 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 241 float race_CheckName(string net_name) {
 242         float i;
 243         for (i=RANKINGS_CNT-1;i>=0;--i)
 244                 if(grecordholder[i] == net_name)
 245                         return i+1;
 246         return 0;
 247 }
 248
 249 float GetPlayerColorForce(int i)
 250 {
 251         if(!teamplay)
 252                 return 0;
 253         else
 254                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 255 }
 256
 257 float GetPlayerColor(int i)
 258 {
 259         if(!playerslots[i].gotscores) // unconnected
 260                 return NUM_SPECTATOR;
 261         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 262                 return NUM_SPECTATOR;
 263         else
 264                 return GetPlayerColorForce(i);
 265 }
 266
 267 string GetPlayerName(int i)
 268 {
 269         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 270 }
 271
 272
 273 /*
 274 ==================
 275 HUD panels
 276 ==================
 277 */
 278
 279 // draw the background/borders
 280 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 281         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 282                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 283 } while(0)
 284
 285 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 286 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 287 {
 288         if(!length_ratio || !theAlpha)
 289                 return;
 290         if(length_ratio > 1)
 291                 length_ratio = 1;
 292         if (baralign == 3)
 293         {
 294                 if(length_ratio < -1)
 295                         length_ratio = -1;
 296         }
 297         else if(length_ratio < 0)
 298                 return;
 299
 300         vector square;
 301         vector width, height;
 302         if(vertical) {
 303                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 304                 if(precache_pic(pic) == "") {
 305                         pic = "gfx/hud/default/progressbar_vertical";
 306                 }
 307
 308         if (baralign == 1) // bottom align
 309                         theOrigin.y += (1 - length_ratio) * theSize.y;
 310         else if (baralign == 2) // center align
 311             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 312         else if (baralign == 3) // center align, positive values down, negative up
 313                 {
 314                         theSize.y *= 0.5;
 315                         if (length_ratio > 0)
 316                                 theOrigin.y += theSize.y;
 317                         else
 318                         {
 319                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 320                                 length_ratio = -length_ratio;
 321                         }
 322                 }
 323                 theSize.y *= length_ratio;
 324
 325                 vector bH;
 326                 width = eX * theSize.x;
 327                 height = eY * theSize.y;
 328                 if(theSize.y <= theSize.x * 2)
 329                 {
 330                         // button not high enough
 331                         // draw just upper and lower part then
 332                         square = eY * theSize.y * 0.5;
 333                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 334                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 335                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 336                 }
 337                 else
 338                 {
 339                         square = eY * theSize.x;
 340                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 341                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 342                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 343                 }
 344         } else {
 345                 pic = strcat(hud_skin_path, "/", pic);
 346                 if(precache_pic(pic) == "") {
 347                         pic = "gfx/hud/default/progressbar";
 348                 }
 349
 350                 if (baralign == 1) // right align
 351                         theOrigin.x += (1 - length_ratio) * theSize.x;
 352         else if (baralign == 2) // center align
 353             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 354         else if (baralign == 3) // center align, positive values on the right, negative on the left
 355                 {
 356                         theSize.x *= 0.5;
 357                         if (length_ratio > 0)
 358                                 theOrigin.x += theSize.x;
 359                         else
 360                         {
 361                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 362                                 length_ratio = -length_ratio;
 363                         }
 364                 }
 365                 theSize.x *= length_ratio;
 366
 367                 vector bW;
 368                 width = eX * theSize.x;
 369                 height = eY * theSize.y;
 370                 if(theSize.x <= theSize.y * 2)
 371                 {
 372                         // button not wide enough
 373                         // draw just left and right part then
 374                         square = eX * theSize.x * 0.5;
 375                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 376                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 377                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 378                 }
 379                 else
 380                 {
 381                         square = eX * theSize.y;
 382                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 383                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 384                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 385                 }
 386         }
 387 }
 388
 389 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 390 {
 391         if(!theAlpha)
 392                 return;
 393
 394         string pic;
 395         pic = strcat(hud_skin_path, "/num_leading");
 396         if(precache_pic(pic) == "") {
 397                 pic = "gfx/hud/default/num_leading";
 398         }
 399
 400         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 401         if(mySize.x/mySize.y > 2)
 402                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 403         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 404 }
 405
 406 // Weapon icons (#0)
 407 //
 408 entity weaponorder[WEP_MAXCOUNT];
 409 void weaponorder_swap(int i, int j, entity pass)
 410 {
 411         entity h = weaponorder[i];
 412         weaponorder[i] = weaponorder[j];
 413         weaponorder[j] = h;
 414 }
 415
 416 string weaponorder_cmp_str;
 417 float weaponorder_cmp(float i, float j, entity pass)
 418 {
 419         float ai, aj;
 420         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 421         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 422         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 423 }
 424
 425 void HUD_Weapons(void)
 426 {
 427         // declarations
 428         WepSet weapons_stat = WepSet_GetFromStat();
 429         float i, f, a;
 430         float screen_ar;
 431         vector center = '0 0 0';
 432         float weapon_count, weapon_id;
 433         float row, column, rows = 0, columns;
 434         float aspect = autocvar_hud_panel_weapons_aspect;
 435
 436         float timeout = autocvar_hud_panel_weapons_timeout;
 437         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 438         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 439
 440         vector barsize = '0 0 0', baroffset = '0 0 0';
 441         vector ammo_color = '1 0 1';
 442         float ammo_alpha = 1;
 443
 444         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 445         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 446
 447         vector weapon_pos, weapon_size = '0 0 0';
 448         vector color;
 449
 450         // check to see if we want to continue
 451         if(hud != HUD_NORMAL) { return; }
 452
 453         if(!autocvar__hud_configure)
 454         {
 455                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 456                         return;
 457                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 458                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 459                 {
 460                         weaponprevtime = time;
 461                         return;
 462                 }
 463         }
 464
 465         // update generic hud functions
 466         HUD_Panel_UpdateCvars();
 467
 468         draw_beginBoldFont();
 469
 470         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 471         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 472         {
 473                 int weapon_cnt;
 474                 if(weaponorder_bypriority)
 475                         strunzone(weaponorder_bypriority);
 476                 if(weaponorder_byimpulse)
 477                         strunzone(weaponorder_byimpulse);
 478
 479                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 480                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 481                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 482
 483                 weapon_cnt = 0;
 484                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 485                 {
 486                         self = get_weaponinfo(i);
 487                         if(self.impulse >= 0)
 488                         {
 489                                 weaponorder[weapon_cnt] = self;
 490                                 ++weapon_cnt;
 491                         }
 492                 }
 493                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 494                         weaponorder[i] = world;
 495                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 496
 497                 weaponorder_cmp_str = string_null;
 498         }
 499
 500         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 501                 complain_weapon = 0;
 502
 503         if(autocvar__hud_configure)
 504         {
 505                 if(!weapons_stat)
 506                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 507                                 weapons_stat |= WepSet_FromWeapon(i);
 508         }
 509
 510         // determine which weapons are going to be shown
 511         if (autocvar_hud_panel_weapons_onlyowned)
 512         {
 513                 if(autocvar__hud_configure)
 514                 {
 515                         if(menu_enabled != 2)
 516                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 517                 }
 518
 519                 // do we own this weapon?
 520                 weapon_count = 0;
 521                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 522                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 523                                 ++weapon_count;
 524
 525                 // might as well commit suicide now, no reason to live ;)
 526                 if (weapon_count == 0)
 527                 {
 528                         draw_endBoldFont();
 529                         return;
 530                 }
 531
 532                 vector old_panel_size = panel_size;
 533                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 534
 535                 // get the all-weapons layout
 536                 rows = HUD_GetRowCount(WEP_COUNT, padded_panel_size, aspect);
 537                 columns = ceil(WEP_COUNT / rows);
 538                 weapon_size.x = padded_panel_size.x / columns;
 539                 weapon_size.y = padded_panel_size.y / rows;
 540
 541                 // reduce rows and columns as needed
 542                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 543                 // we enlarge them a bit when possible to better match the desired aspect ratio
 544                 if(padded_panel_size.y > padded_panel_size.x)
 545                 {
 546                         columns = ceil(weapon_count / rows);
 547                         rows = ceil(weapon_count / columns);
 548                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 549                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 550                 }
 551                 else
 552                 {
 553                         rows = ceil(weapon_count / columns);
 554                         columns = ceil(weapon_count / rows);
 555                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 556                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 557                 }
 558
 559                 // reduce size of the panel
 560                 panel_size.x = columns * weapon_size.x;
 561                 panel_size.y = rows * weapon_size.y;
 562                 panel_size += '2 2 0' * panel_bg_padding;
 563
 564                 // center the resized panel, or snap it to the screen edge when close enough
 565                 if(panel_pos.x > vid_conwidth * 0.001)
 566                 {
 567                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 568                                 panel_pos.x += old_panel_size.x - panel_size.x;
 569                         else
 570                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 571                 }
 572                 else if(old_panel_size.x > vid_conwidth * 0.999)
 573                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 574
 575                 if(panel_pos.y > vid_conheight * 0.001)
 576                 {
 577                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 578                                 panel_pos.y += old_panel_size.y - panel_size.y;
 579                         else
 580                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 581                 }
 582                 else if(old_panel_size.y > vid_conheight * 0.999)
 583                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 584         }
 585         else
 586                 weapon_count = WEP_COUNT;
 587
 588         // animation for fading in/out the panel respectively when not in use
 589         if(!autocvar__hud_configure)
 590         {
 591                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 592                 {
 593                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 594
 595                         // fade the panel alpha
 596                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 597                         {
 598                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 599                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 600                         }
 601                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 602                         {
 603                                 panel_bg_alpha *= (1 - f);
 604                                 panel_fg_alpha *= (1 - f);
 605                         }
 606
 607                         // move the panel off the screen
 608                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 609                         {
 610                                 f *= f; // for a cooler movement
 611                                 center.x = panel_pos.x + panel_size.x/2;
 612                                 center.y = panel_pos.y + panel_size.y/2;
 613                                 screen_ar = vid_conwidth/vid_conheight;
 614                                 if (center.x/center.y < screen_ar) //bottom left
 615                                 {
 616                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 617                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 618                                         else //left
 619                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 620                                 }
 621                                 else //top right
 622                                 {
 623                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 624                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 625                                         else //top
 626                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 627                                 }
 628                                 if(f == 1)
 629                                         center.x = -1; // mark the panel as off screen
 630                         }
 631                         weaponprevtime = time - (1 - f) * timein_effect_length;
 632                 }
 633                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 634                 {
 635                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 636
 637                         // fade the panel alpha
 638                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 639                         {
 640                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 641                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 642                         }
 643                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 644                         {
 645                                 panel_bg_alpha *= (f);
 646                                 panel_fg_alpha *= (f);
 647                         }
 648
 649                         // move the panel back on screen
 650                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 651                         {
 652                                 f *= f; // for a cooler movement
 653                                 f = 1 - f;
 654                                 center.x = panel_pos.x + panel_size.x/2;
 655                                 center.y = panel_pos.y + panel_size.y/2;
 656                                 screen_ar = vid_conwidth/vid_conheight;
 657                                 if (center.x/center.y < screen_ar) //bottom left
 658                                 {
 659                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 660                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 661                                         else //left
 662                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 663                                 }
 664                                 else //top right
 665                                 {
 666                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 667                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 668                                         else //top
 669                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 670                                 }
 671                         }
 672                 }
 673         }
 674
 675         // draw the background, then change the virtual size of it to better fit other items inside
 676         HUD_Panel_DrawBg(1);
 677
 678         if(center.x == -1)
 679         {
 680                 draw_endBoldFont();
 681                 return;
 682         }
 683
 684         if(panel_bg_padding)
 685         {
 686                 panel_pos += '1 1 0' * panel_bg_padding;
 687                 panel_size -= '2 2 0' * panel_bg_padding;
 688         }
 689
 690         // after the sizing and animations are done, update the other values
 691
 692         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 693         {
 694                 rows = HUD_GetRowCount(weapon_count, panel_size, aspect);
 695                 columns = ceil(weapon_count/rows);
 696                 weapon_size = eX * panel_size.x*(1/columns) + eY * panel_size.y*(1/rows);
 697         }
 698
 699         // calculate position/size for visual bar displaying ammount of ammo status
 700         if (autocvar_hud_panel_weapons_ammo)
 701         {
 702                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 703                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 704
 705                 if(weapon_size.x/weapon_size.y > aspect)
 706                 {
 707                         barsize.x = aspect * weapon_size.y;
 708                         barsize.y = weapon_size.y;
 709                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 710                 }
 711                 else
 712                 {
 713                         barsize.y = 1/aspect * weapon_size.x;
 714                         barsize.x = weapon_size.x;
 715                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 716                 }
 717         }
 718         if(autocvar_hud_panel_weapons_accuracy)
 719                 Accuracy_LoadColors();
 720
 721         // draw items
 722         row = column = 0;
 723         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 724         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 725         {
 726                 // retrieve information about the current weapon to be drawn
 727                 self = weaponorder[i];
 728                 weapon_id = self.impulse;
 729
 730                 // skip if this weapon doesn't exist
 731                 if(!self || weapon_id < 0) { continue; }
 732
 733                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 734                 if(autocvar_hud_panel_weapons_onlyowned)
 735                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 736                         continue;
 737
 738                 // figure out the drawing position of weapon
 739                 weapon_pos = (panel_pos
 740                         + eX * column * weapon_size.x
 741                         + eY * row * weapon_size.y);
 742
 743                 // draw background behind currently selected weapon
 744                 if(self.weapon == switchweapon)
 745                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 746
 747                 // draw the weapon accuracy
 748                 if(autocvar_hud_panel_weapons_accuracy)
 749                 {
 750                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 751                         if(panel_weapon_accuracy >= 0)
 752                         {
 753                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 754                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 755                         }
 756                 }
 757
 758                 // drawing all the weapon items
 759                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 760                 {
 761                         // draw the weapon image
 762                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 763
 764                         // draw weapon label string
 765                         switch(autocvar_hud_panel_weapons_label)
 766                         {
 767                                 case 1: // weapon number
 768                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 769                                         break;
 770
 771                                 case 2: // bind
 772                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 773                                         break;
 774
 775                                 case 3: // weapon name
 776                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 777                                         break;
 778
 779                                 default: // nothing
 780                                         break;
 781                         }
 782
 783                         // draw ammo status bar
 784                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 785                         {
 786                                 float ammo_full;
 787                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 788
 789                                 if(a > 0)
 790                                 {
 791                                         switch(self.ammo_field)
 792                                         {
 793                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 794                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 795                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 796                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 797                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 798                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 799                                                 default: ammo_full = 60;
 800                                         }
 801
 802                                         drawsetcliparea(
 803                                                 weapon_pos.x + baroffset.x,
 804                                                 weapon_pos.y + baroffset.y,
 805                                                 barsize.x * bound(0, a/ammo_full, 1),
 806                                                 barsize.y
 807                                         );
 808
 809                                         drawpic_aspect_skin(
 810                                                 weapon_pos,
 811                                                 "weapon_ammo",
 812                                                 weapon_size,
 813                                                 ammo_color,
 814                                                 ammo_alpha,
 815                                                 DRAWFLAG_NORMAL
 816                                         );
 817
 818                                         drawresetcliparea();
 819                                 }
 820                         }
 821                 }
 822                 else // draw a "ghost weapon icon" if you don't have the weapon
 823                 {
 824                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 825                 }
 826
 827                 // draw the complain message
 828                 if(self.weapon == complain_weapon)
 829                 {
 830                         if(fadetime)
 831                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 832                         else
 833                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 834
 835                         string s;
 836                         if(complain_weapon_type == 0) {
 837                                 s = _("Out of ammo");
 838                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 839                         }
 840                         else if(complain_weapon_type == 1) {
 841                                 s = _("Don't have");
 842                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 843                         }
 844                         else {
 845                                 s = _("Unavailable");
 846                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 847                         }
 848                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 849                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 850                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 851                 }
 852
 853                 // continue with new position for the next weapon
 854                 ++row;
 855                 if(row >= rows)
 856                 {
 857                         row = 0;
 858                         ++column;
 859                 }
 860         }
 861
 862         draw_endBoldFont();
 863 }
 864
 865 // Ammo (#1)
 866 void DrawNadeScoreBar(vector myPos, vector mySize, vector color)
 867 {
 868
 869         HUD_Panel_DrawProgressBar(
 870                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 871                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 872                 autocvar_hud_panel_ammo_progressbar_name,
 873                 getstatf(STAT_NADE_BONUS_SCORE), 0, 0, color,
 874                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 875
 876 }
 877
 878 void DrawAmmoNades(vector myPos, vector mySize, float draw_expanding, float expand_time)
 879 {
 880         float theAlpha = 1, a, b;
 881         vector nade_color, picpos, numpos;
 882
 883         nade_color = Nade_Color(getstati(STAT_NADE_BONUS_TYPE));
 884
 885         a = getstatf(STAT_NADE_BONUS);
 886         b = getstatf(STAT_NADE_BONUS_SCORE);
 887
 888         if(autocvar_hud_panel_ammo_iconalign)
 889         {
 890                 numpos = myPos;
 891                 picpos = myPos + eX * 2 * mySize.y;
 892         }
 893         else
 894         {
 895                 numpos = myPos + eX * mySize.y;
 896                 picpos = myPos;
 897         }
 898
 899         DrawNadeScoreBar(myPos, mySize, nade_color);
 900
 901         if(b > 0 || a > 0)
 902         {
 903                 if(autocvar_hud_panel_ammo_text)
 904                         drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 905
 906                 if(draw_expanding)
 907                         drawpic_aspect_skin_expanding(picpos, "nade_nbg", '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, expand_time);
 908
 909                 drawpic_aspect_skin(picpos, "nade_bg" , '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 910                 drawpic_aspect_skin(picpos, "nade_nbg" , '1 1 0' * mySize.y, nade_color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 911         }
 912 }
 913
 914 void DrawAmmoItem(vector myPos, vector mySize, .float ammoType, float isCurrent, float isInfinite)
 915 {
 916         if(ammoType == ammo_none)
 917                 return;
 918
 919         // Initialize variables
 920
 921         float ammo;
 922         if(autocvar__hud_configure)
 923         {
 924                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
 925                 ammo = 60;
 926         }
 927         else
 928                 ammo = getstati(GetAmmoStat(ammoType));
 929
 930         if(!isCurrent)
 931         {
 932                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
 933                 myPos = myPos + (mySize - mySize * scale) * 0.5;
 934                 mySize = mySize * scale;
 935         }
 936
 937         vector iconPos, textPos;
 938         if(autocvar_hud_panel_ammo_iconalign)
 939         {
 940                 iconPos = myPos + eX * 2 * mySize.y;
 941                 textPos = myPos;
 942         }
 943         else
 944         {
 945                 iconPos = myPos;
 946                 textPos = myPos + eX * mySize.y;
 947         }
 948
 949         float isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
 950
 951         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
 952         vector textColor;
 953         if(isInfinite)
 954                 textColor = '0.2 0.95 0';
 955         else if(isShadowed)
 956                 textColor = '0 0 0';
 957         else if(ammo < 10)
 958                 textColor = '0.8 0.04 0';
 959         else
 960                 textColor = '1 1 1';
 961
 962         float alpha;
 963         if(isCurrent)
 964                 alpha = panel_fg_alpha;
 965         else if(isShadowed)
 966                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
 967         else
 968                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
 969
 970         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
 971
 972         // Draw item
 973
 974         if(isCurrent)
 975                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 976
 977         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
 978                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
 979
 980         if(autocvar_hud_panel_ammo_text)
 981                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
 982
 983         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
 984 }
 985
 986 float nade_prevstatus;
 987 float nade_prevframe;
 988 float nade_statuschange_time;
 989 void HUD_Ammo(void)
 990 {
 991         if(hud != HUD_NORMAL) return;
 992         if(!autocvar__hud_configure)
 993         {
 994                 if(!autocvar_hud_panel_ammo) return;
 995                 if(spectatee_status == -1) return;
 996         }
 997
 998         HUD_Panel_UpdateCvars();
 999
1000         draw_beginBoldFont();
1001
1002         vector pos, mySize;
1003         pos = panel_pos;
1004         mySize = panel_size;
1005
1006         HUD_Panel_DrawBg(1);
1007         if(panel_bg_padding)
1008         {
1009                 pos += '1 1 0' * panel_bg_padding;
1010                 mySize -= '2 2 0' * panel_bg_padding;
1011         }
1012
1013         float rows = 0, columns, row, column;
1014         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1015         float draw_nades = (nade_cnt > 0 || nade_score > 0), nade_statuschange_elapsedtime;
1016         float total_ammo_count;
1017
1018         vector ammo_size;
1019         if (autocvar_hud_panel_ammo_onlycurrent)
1020                 total_ammo_count = 1;
1021         else
1022                 total_ammo_count = AMMO_COUNT;
1023
1024         if(draw_nades)
1025         {
1026                 ++total_ammo_count;
1027                 if (nade_cnt != nade_prevframe)
1028                 {
1029                         nade_statuschange_time = time;
1030                         nade_prevstatus = nade_prevframe;
1031                         nade_prevframe = nade_cnt;
1032                 }
1033         }
1034         else
1035                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1036
1037         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1038         columns = ceil((total_ammo_count)/rows);
1039         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1040
1041         vector offset = '0 0 0'; // fteqcc sucks
1042         float newSize;
1043         if(ammo_size.x/ammo_size.y > 3)
1044         {
1045                 newSize = 3 * ammo_size.y;
1046                 offset.x = ammo_size.x - newSize;
1047                 pos.x += offset.x/2;
1048                 ammo_size.x = newSize;
1049         }
1050         else
1051         {
1052                 newSize = 1/3 * ammo_size.x;
1053                 offset.y = ammo_size.y - newSize;
1054                 pos.y += offset.y/2;
1055                 ammo_size.y = newSize;
1056         }
1057
1058         float i;
1059         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1060         row = column = 0;
1061         if(autocvar_hud_panel_ammo_onlycurrent)
1062         {
1063                 if(autocvar__hud_configure)
1064                 {
1065                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1066                 }
1067                 else
1068                 {
1069                         DrawAmmoItem(
1070                                 pos,
1071                                 ammo_size,
1072                                 (get_weaponinfo(switchweapon)).ammo_field,
1073                                 true,
1074                                 infinite_ammo
1075                         );
1076                 }
1077
1078                 ++row;
1079                 if(row >= rows)
1080                 {
1081                         row = 0;
1082                         column = column + 1;
1083                 }
1084         }
1085         else
1086         {
1087                 .float ammotype;
1088                 row = column = 0;
1089                 for(i = 0; i < AMMO_COUNT; ++i)
1090                 {
1091                         ammotype = GetAmmoFieldFromNum(i);
1092                         DrawAmmoItem(
1093                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1094                                 ammo_size,
1095                                 ammotype,
1096                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1097                                 infinite_ammo
1098                         );
1099
1100                         ++row;
1101                         if(row >= rows)
1102                         {
1103                                 row = 0;
1104                                 column = column + 1;
1105                         }
1106                 }
1107         }
1108
1109         if (draw_nades)
1110         {
1111                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1112
1113                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1114
1115                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1116         }
1117
1118         draw_endBoldFont();
1119 }
1120
1121 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1122 {
1123         vector newPos = '0 0 0', newSize = '0 0 0';
1124         vector picpos, numpos;
1125
1126         if (vertical)
1127         {
1128                 if(mySize.y/mySize.x > 2)
1129                 {
1130                         newSize.y = 2 * mySize.x;
1131                         newSize.x = mySize.x;
1132
1133                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1134                         newPos.x = myPos.x;
1135                 }
1136                 else
1137                 {
1138                         newSize.x = 1/2 * mySize.y;
1139                         newSize.y = mySize.y;
1140
1141                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1142                         newPos.y = myPos.y;
1143                 }
1144
1145                 if(icon_right_align)
1146                 {
1147                         numpos = newPos;
1148                         picpos = newPos + eY * newSize.x;
1149                 }
1150                 else
1151                 {
1152                         picpos = newPos;
1153                         numpos = newPos + eY * newSize.x;
1154                 }
1155
1156                 newSize.y /= 2;
1157                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1158                 // make number smaller than icon, it looks better
1159                 // reduce only y to draw numbers with different number of digits with the same y size
1160                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1161                 newSize.y *= 0.7;
1162                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1163                 return;
1164         }
1165
1166         if(mySize.x/mySize.y > 3)
1167         {
1168                 newSize.x = 3 * mySize.y;
1169                 newSize.y = mySize.y;
1170
1171                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1172                 newPos.y = myPos.y;
1173         }
1174         else
1175         {
1176                 newSize.y = 1/3 * mySize.x;
1177                 newSize.x = mySize.x;
1178
1179                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1180                 newPos.x = myPos.x;
1181         }
1182
1183         if(icon_right_align) // right align
1184         {
1185                 numpos = newPos;
1186                 picpos = newPos + eX * 2 * newSize.y;
1187         }
1188         else // left align
1189         {
1190                 numpos = newPos + eX * newSize.y;
1191                 picpos = newPos;
1192         }
1193
1194         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1195         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1196         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1197         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1198 }
1199
1200 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1201 {
1202         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1203 }
1204
1205 // Powerups (#2)
1206 //
1207 void HUD_Powerups(void)
1208 {
1209         float strength_time, shield_time, superweapons_time;
1210         if(!autocvar__hud_configure)
1211         {
1212                 if(!autocvar_hud_panel_powerups) return;
1213                 if(spectatee_status == -1) return;
1214                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1215                 if (getstati(STAT_HEALTH) <= 0) return;
1216
1217                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1218                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1219                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1220
1221                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1222                         superweapons_time = 99; // force max
1223
1224                 // prevent stuff to show up on mismatch that will be fixed next frame
1225                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1226                         superweapons_time = 0;
1227         }
1228         else
1229         {
1230                 strength_time = 15;
1231                 shield_time = 27;
1232                 superweapons_time = 13;
1233         }
1234
1235         HUD_Panel_UpdateCvars();
1236
1237         draw_beginBoldFont();
1238
1239         vector pos, mySize;
1240         pos = panel_pos;
1241         mySize = panel_size;
1242
1243         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1244         if(panel_bg_padding)
1245         {
1246                 pos += '1 1 0' * panel_bg_padding;
1247                 mySize -= '2 2 0' * panel_bg_padding;
1248         }
1249
1250         float panel_ar = mySize.x/mySize.y;
1251         float is_vertical = (panel_ar < 1);
1252         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1253
1254         float superweapons_is = -1;
1255
1256         if(superweapons_time)
1257         {
1258                 if(strength_time)
1259                 {
1260                         if(shield_time)
1261                                 superweapons_is = 0;
1262                         else
1263                                 superweapons_is = 2;
1264                 }
1265                 else
1266                 {
1267                         if(shield_time)
1268                                 superweapons_is = 1;
1269                         else
1270                                 superweapons_is = 2;
1271                 }
1272         }
1273
1274         // FIXME handle superweapons here
1275         if(superweapons_is == 0)
1276         {
1277                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1278                 {
1279                         mySize.x *= (1.0 / 3.0);
1280                         superweapons_offset.x = mySize.x;
1281                         if (autocvar_hud_panel_powerups_flip)
1282                                 shield_offset.x = 2*mySize.x;
1283                         else
1284                                 strength_offset.x = 2*mySize.x;
1285                 }
1286                 else
1287                 {
1288                         mySize.y *= (1.0 / 3.0);
1289                         superweapons_offset.y = mySize.y;
1290                         if (autocvar_hud_panel_powerups_flip)
1291                                 shield_offset.y = 2*mySize.y;
1292                         else
1293                                 strength_offset.y = 2*mySize.y;
1294                 }
1295         }
1296         else
1297         {
1298                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1299                 {
1300                         mySize.x *= 0.5;
1301                         if (autocvar_hud_panel_powerups_flip)
1302                                 shield_offset.x = mySize.x;
1303                         else
1304                                 strength_offset.x = mySize.x;
1305                 }
1306                 else
1307                 {
1308                         mySize.y *= 0.5;
1309                         if (autocvar_hud_panel_powerups_flip)
1310                                 shield_offset.y = mySize.y;
1311                         else
1312                                 strength_offset.y = mySize.y;
1313                 }
1314         }
1315
1316         float shield_baralign, strength_baralign, superweapons_baralign;
1317         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1318
1319         if (autocvar_hud_panel_powerups_flip)
1320         {
1321                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1322                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1323                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1324                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1325         }
1326         else
1327         {
1328                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1329                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1330                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1331                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1332         }
1333
1334         if(superweapons_is == 0)
1335         {
1336                 superweapons_iconalign = strength_iconalign;
1337                 superweapons_baralign = 2;
1338         }
1339         else if(superweapons_is == 1)
1340         {
1341                 superweapons_offset = strength_offset;
1342                 superweapons_iconalign = strength_iconalign;
1343                 superweapons_baralign = strength_baralign;
1344         }
1345         else // if(superweapons_is == 2)
1346         {
1347                 superweapons_offset = shield_offset;
1348                 superweapons_iconalign = shield_iconalign;
1349                 superweapons_baralign = shield_baralign;
1350         }
1351
1352         if(shield_time)
1353         {
1354                 const float maxshield = 30;
1355                 float shield = ceil(shield_time);
1356                 if(autocvar_hud_panel_powerups_progressbar)
1357                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1358                 if(autocvar_hud_panel_powerups_text)
1359                 {
1360                         if(shield > 1)
1361                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1362                         if(shield <= 5)
1363                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1364                 }
1365         }
1366
1367         if(strength_time)
1368         {
1369                 const float maxstrength = 30;
1370                 float strength = ceil(strength_time);
1371                 if(autocvar_hud_panel_powerups_progressbar)
1372                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1373                 if(autocvar_hud_panel_powerups_text)
1374                 {
1375                         if(strength > 1)
1376                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1377                         if(strength <= 5)
1378                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1379                 }
1380         }
1381
1382         if(superweapons_time)
1383         {
1384                 const float maxsuperweapons = 30;
1385                 float superweapons = ceil(superweapons_time);
1386                 if(autocvar_hud_panel_powerups_progressbar)
1387                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1388                 if(autocvar_hud_panel_powerups_text)
1389                 {
1390                         if(superweapons > 1)
1391                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1392                         if(superweapons <= 5)
1393                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1394                 }
1395         }
1396
1397         draw_endBoldFont();
1398 }
1399
1400 // Health/armor (#3)
1401 //
1402
1403 // prev_* vars contain the health/armor at the previous FRAME
1404 // set to -1 when player is dead or was not playing
1405 float prev_health, prev_armor;
1406 float health_damagetime, armor_damagetime;
1407 float health_beforedamage, armor_beforedamage;
1408 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1409 float old_p_health, old_p_armor;
1410 float old_p_healthtime, old_p_armortime;
1411 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1412 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1413 float prev_p_health, prev_p_armor;
1414
1415 void HUD_HealthArmor(void)
1416 {
1417         float armor, health, fuel;
1418         if(!autocvar__hud_configure)
1419         {
1420                 if(!autocvar_hud_panel_healtharmor) return;
1421                 if(hud != HUD_NORMAL) return;
1422                 if(spectatee_status == -1) return;
1423
1424                 health = getstati(STAT_HEALTH);
1425                 if(health <= 0)
1426                 {
1427                         prev_health = -1;
1428                         return;
1429                 }
1430                 armor = getstati(STAT_ARMOR);
1431
1432                 // code to check for spectatee_status changes is in Ent_ClientData()
1433                 // prev_p_health and prev_health can be set to -1 there
1434
1435                 if (prev_p_health == -1)
1436                 {
1437                         // no effect
1438                         health_beforedamage = 0;
1439                         armor_beforedamage = 0;
1440                         health_damagetime = 0;
1441                         armor_damagetime = 0;
1442                         prev_health = health;
1443                         prev_armor = armor;
1444                         old_p_health = health;
1445                         old_p_armor = armor;
1446                         prev_p_health = health;
1447                         prev_p_armor = armor;
1448                 }
1449                 else if (prev_health == -1)
1450                 {
1451                         //start the load effect
1452                         health_damagetime = 0;
1453                         armor_damagetime = 0;
1454                         prev_health = 0;
1455                         prev_armor = 0;
1456                 }
1457                 fuel = getstati(STAT_FUEL);
1458         }
1459         else
1460         {
1461                 health = 150;
1462                 armor = 75;
1463                 fuel = 20;
1464         }
1465
1466         HUD_Panel_UpdateCvars();
1467         vector pos, mySize;
1468         pos = panel_pos;
1469         mySize = panel_size;
1470
1471         HUD_Panel_DrawBg(1);
1472         if(panel_bg_padding)
1473         {
1474                 pos += '1 1 0' * panel_bg_padding;
1475                 mySize -= '2 2 0' * panel_bg_padding;
1476         }
1477
1478         float baralign = autocvar_hud_panel_healtharmor_baralign;
1479         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1480
1481     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1482     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1483         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1484         {
1485                 vector v;
1486                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1487
1488                 float x;
1489                 x = floor(v.x + 1);
1490
1491         float maxtotal = maxhealth + maxarmor;
1492                 string biggercount;
1493                 if(v.z) // NOT fully armored
1494                 {
1495                         biggercount = "health";
1496                         if(autocvar_hud_panel_healtharmor_progressbar)
1497                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1498                         if(armor)
1499             if(autocvar_hud_panel_healtharmor_text)
1500                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1501                 }
1502                 else
1503                 {
1504                         biggercount = "armor";
1505                         if(autocvar_hud_panel_healtharmor_progressbar)
1506                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1507                         if(health)
1508             if(autocvar_hud_panel_healtharmor_text)
1509                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1510                 }
1511         if(autocvar_hud_panel_healtharmor_text)
1512                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1513
1514                 if(fuel)
1515                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1516         }
1517         else
1518         {
1519                 float panel_ar = mySize.x/mySize.y;
1520                 float is_vertical = (panel_ar < 1);
1521                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1522                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1523                 {
1524                         mySize.x *= 0.5;
1525                         if (autocvar_hud_panel_healtharmor_flip)
1526                                 health_offset.x = mySize.x;
1527                         else
1528                                 armor_offset.x = mySize.x;
1529                 }
1530                 else
1531                 {
1532                         mySize.y *= 0.5;
1533                         if (autocvar_hud_panel_healtharmor_flip)
1534                                 health_offset.y = mySize.y;
1535                         else
1536                                 armor_offset.y = mySize.y;
1537                 }
1538
1539                 float health_baralign, armor_baralign, fuel_baralign;
1540                 float health_iconalign, armor_iconalign;
1541                 if (autocvar_hud_panel_healtharmor_flip)
1542                 {
1543                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1544                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1545                         fuel_baralign = health_baralign;
1546                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1547                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1548                 }
1549                 else
1550                 {
1551                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1552                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1553                         fuel_baralign = armor_baralign;
1554                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1555                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1556                 }
1557
1558                 //if(health)
1559                 {
1560                         if(autocvar_hud_panel_healtharmor_progressbar)
1561                         {
1562                                 float p_health, pain_health_alpha;
1563                                 p_health = health;
1564                                 pain_health_alpha = 1;
1565                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1566                                 {
1567                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1568                                         {
1569                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1570                                                 {
1571                                                         if (time - old_p_healthtime < 1)
1572                                                                 old_p_health = prev_p_health;
1573                                                         else
1574                                                                 old_p_health = prev_health;
1575                                                         old_p_healthtime = time;
1576                                                 }
1577                                                 if (time - old_p_healthtime < 1)
1578                                                 {
1579                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1580                                                         prev_p_health = p_health;
1581                                                 }
1582                                         }
1583                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1584                                         {
1585                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1586                                                 {
1587                                                         if (time - health_damagetime >= 1)
1588                                                                 health_beforedamage = prev_health;
1589                                                         health_damagetime = time;
1590                                                 }
1591                                                 if (time - health_damagetime < 1)
1592                                                 {
1593                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1594                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1595                                                 }
1596                                         }
1597                                         prev_health = health;
1598
1599                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1600                                         {
1601                                                 float BLINK_FACTOR = 0.15;
1602                                                 float BLINK_BASE = 0.85;
1603                                                 float BLINK_FREQ = 9;
1604                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1605                                         }
1606                                 }
1607                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1608                         }
1609                         if(autocvar_hud_panel_healtharmor_text)
1610                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1611                 }
1612
1613                 if(armor)
1614                 {
1615                         if(autocvar_hud_panel_healtharmor_progressbar)
1616                         {
1617                                 float p_armor;
1618                                 p_armor = armor;
1619                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1620                                 {
1621                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1622                                         {
1623                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1624                                                 {
1625                                                         if (time - old_p_armortime < 1)
1626                                                                 old_p_armor = prev_p_armor;
1627                                                         else
1628                                                                 old_p_armor = prev_armor;
1629                                                         old_p_armortime = time;
1630                                                 }
1631                                                 if (time - old_p_armortime < 1)
1632                                                 {
1633                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1634                                                         prev_p_armor = p_armor;
1635                                                 }
1636                                         }
1637                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1638                                         {
1639                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1640                                                 {
1641                                                         if (time - armor_damagetime >= 1)
1642                                                                 armor_beforedamage = prev_armor;
1643                                                         armor_damagetime = time;
1644                                                 }
1645                                                 if (time - armor_damagetime < 1)
1646                                                 {
1647                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1648                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1649                                                 }
1650                                         }
1651                                         prev_armor = armor;
1652                                 }
1653                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1654                         }
1655                         if(autocvar_hud_panel_healtharmor_text)
1656                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1657                 }
1658
1659                 if(fuel)
1660                 {
1661                         if (is_vertical)
1662                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1663                         else
1664                                 mySize.y *= 0.2;
1665                         if (panel_ar >= 4)
1666                                 mySize.x *= 2; //restore full panel size
1667                         else if (panel_ar < 1/4)
1668                                 mySize.y *= 2; //restore full panel size
1669                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1670                 }
1671         }
1672 }
1673
1674 // Notification area (#4)
1675 //
1676
1677 void HUD_Notify_Push(string icon, string attacker, string victim)
1678 {
1679         if (icon == "")
1680                 return;
1681
1682         ++notify_count;
1683         --notify_index;
1684
1685         if (notify_index == -1)
1686                 notify_index = NOTIFY_MAX_ENTRIES-1;
1687
1688         // Free old strings
1689         if (notify_attackers[notify_index])
1690                 strunzone(notify_attackers[notify_index]);
1691
1692         if (notify_victims[notify_index])
1693                 strunzone(notify_victims[notify_index]);
1694
1695         if (notify_icons[notify_index])
1696                 strunzone(notify_icons[notify_index]);
1697
1698         // Allocate new strings
1699         if (victim != "")
1700         {
1701                 notify_attackers[notify_index] = strzone(attacker);
1702                 notify_victims[notify_index] = strzone(victim);
1703         }
1704         else
1705         {
1706                 // In case of a notification without a victim, the attacker
1707                 // is displayed on the victim's side. Instead of special
1708                 // treatment later on, we can simply switch them here.
1709                 notify_attackers[notify_index] = string_null;
1710                 notify_victims[notify_index] = strzone(attacker);
1711         }
1712
1713         notify_icons[notify_index] = strzone(icon);
1714         notify_times[notify_index] = time;
1715 }
1716
1717 void HUD_Notify(void)
1718 {
1719         if (!autocvar__hud_configure)
1720                 if (!autocvar_hud_panel_notify)
1721                         return;
1722
1723         HUD_Panel_UpdateCvars();
1724         HUD_Panel_DrawBg(1);
1725
1726         if (!autocvar__hud_configure)
1727                 if (notify_count == 0)
1728                         return;
1729
1730         vector pos, size;
1731         pos  = panel_pos;
1732         size = panel_size;
1733
1734         if (panel_bg_padding)
1735         {
1736                 pos  += '1 1 0' * panel_bg_padding;
1737                 size -= '2 2 0' * panel_bg_padding;
1738         }
1739
1740         float fade_start = max(0, autocvar_hud_panel_notify_time);
1741         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1742         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1743
1744         float entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1745         float entry_height = size.y / entry_count;
1746
1747         float panel_width_half = size.x * 0.5;
1748         float icon_width_half = entry_height * icon_aspect / 2;
1749         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1750
1751         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1752         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1753         vector icon_left = eX * (panel_width_half - icon_width_half);
1754         vector attacker_right = eX * name_maxwidth;
1755         vector victim_left = eX * (size.x - name_maxwidth);
1756
1757         vector attacker_pos, victim_pos, icon_pos;
1758         string attacker, victim, icon;
1759         float i, j, count, step, limit, alpha;
1760
1761         if (autocvar_hud_panel_notify_flip)
1762         {
1763                 // Order items from the top down
1764                 i = 0;
1765                 step = +1;
1766                 limit = entry_count;
1767         }
1768         else
1769         {
1770                 // Order items from the bottom up
1771                 i = entry_count - 1;
1772                 step = -1;
1773                 limit = -1;
1774         }
1775
1776         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1777         {
1778                 if(autocvar__hud_configure)
1779                 {
1780                         attacker = sprintf(_("Player %d"), count + 1);
1781                         victim = sprintf(_("Player %d"), count + 2);
1782                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1783                         alpha = bound(0, 1.2 - count / entry_count, 1);
1784                 }
1785                 else
1786                 {
1787                         if (j == NOTIFY_MAX_ENTRIES)
1788                                 j = 0;
1789
1790                         if (notify_times[j] + fade_start > time)
1791                                 alpha = 1;
1792                         else if (fade_time != 0)
1793                         {
1794                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1795                                 if (alpha == 0)
1796                                         break;
1797                         }
1798                         else
1799                                 break;
1800
1801                         attacker = notify_attackers[j];
1802                         victim = notify_victims[j];
1803                         icon = notify_icons[j];
1804                 }
1805
1806                 if (icon != "" && victim != "")
1807                 {
1808                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1809
1810                         icon_pos = pos + icon_left + eY * i * entry_height;
1811                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1812
1813                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1814                         victim_pos = pos + victim_left + name_top;
1815                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1816
1817                         if (attacker != "")
1818                         {
1819                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1820                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1821                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1822                         }
1823                 }
1824         }
1825
1826         notify_count = count;
1827 }
1828
1829 // Timer (#5)
1830 //
1831 // TODO: macro
1832 string seconds_tostring(float sec)
1833 {
1834         float minutes;
1835         minutes = floor(sec / 60);
1836
1837         sec -= minutes * 60;
1838         return sprintf("%d:%02d", minutes, sec);
1839 }
1840
1841 void HUD_Timer(void)
1842 {
1843         if(!autocvar__hud_configure)
1844         {
1845                 if(!autocvar_hud_panel_timer) return;
1846         }
1847
1848         HUD_Panel_UpdateCvars();
1849
1850         draw_beginBoldFont();
1851
1852         vector pos, mySize;
1853         pos = panel_pos;
1854         mySize = panel_size;
1855
1856         HUD_Panel_DrawBg(1);
1857         if(panel_bg_padding)
1858         {
1859                 pos += '1 1 0' * panel_bg_padding;
1860                 mySize -= '2 2 0' * panel_bg_padding;
1861         }
1862
1863         string timer;
1864         float timelimit, elapsedTime, timeleft, minutesLeft;
1865
1866         timelimit = getstatf(STAT_TIMELIMIT);
1867
1868         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1869         timeleft = ceil(timeleft);
1870
1871         minutesLeft = floor(timeleft / 60);
1872
1873         vector timer_color;
1874         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1875                 timer_color = '1 1 1'; //white
1876         else if(minutesLeft >= 1)
1877                 timer_color = '1 1 0'; //yellow
1878         else
1879                 timer_color = '1 0 0'; //red
1880
1881         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1882                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1883                         //while restart is still active, show 00:00
1884                         timer = seconds_tostring(0);
1885                 } else {
1886                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1887                         timer = seconds_tostring(elapsedTime);
1888                 }
1889         } else {
1890                 timer = seconds_tostring(timeleft);
1891         }
1892
1893         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1894
1895         draw_endBoldFont();
1896 }
1897
1898 // Radar (#6)
1899 //
1900 void HUD_Radar(void)
1901 {
1902         if (!autocvar__hud_configure)
1903         {
1904                 if (hud_panel_radar_maximized)
1905                 {
1906                         if (!hud_draw_maximized) return;
1907                 }
1908                 else
1909                 {
1910                         if (autocvar_hud_panel_radar == 0) return;
1911                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1912                         if(radar_panel_modified)
1913                         {
1914                                 panel.update_time = time; // forces reload of panel attributes
1915                                 radar_panel_modified = false;
1916                         }
1917                 }
1918         }
1919
1920         HUD_Panel_UpdateCvars();
1921
1922         float f = 0;
1923
1924         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1925         {
1926                 panel_size = autocvar_hud_panel_radar_maximized_size;
1927                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
1928                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
1929                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
1930                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
1931
1932                 string panel_bg;
1933                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1934                 if(precache_pic(panel_bg) == "")
1935                         panel_bg = "gfx/hud/default/border_default"; // fallback
1936                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
1937                         radar_panel_modified = true;
1938                 if(panel.current_panel_bg)
1939                         strunzone(panel.current_panel_bg);
1940                 panel.current_panel_bg = strzone(panel_bg);
1941
1942                 switch(hud_panel_radar_maximized_zoommode)
1943                 {
1944                         default:
1945                         case 0:
1946                                 f = current_zoomfraction;
1947                                 break;
1948                         case 1:
1949                                 f = 1 - current_zoomfraction;
1950                                 break;
1951                         case 2:
1952                                 f = 0;
1953                                 break;
1954                         case 3:
1955                                 f = 1;
1956                                 break;
1957                 }
1958
1959                 switch(hud_panel_radar_maximized_rotation)
1960                 {
1961                         case 0:
1962                                 teamradar_angle = view_angles.y - 90;
1963                                 break;
1964                         default:
1965                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1966                                 break;
1967                 }
1968         }
1969         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1970         {
1971                 switch(hud_panel_radar_zoommode)
1972                 {
1973                         default:
1974                         case 0:
1975                                 f = current_zoomfraction;
1976                                 break;
1977                         case 1:
1978                                 f = 1 - current_zoomfraction;
1979                                 break;
1980                         case 2:
1981                                 f = 0;
1982                                 break;
1983                         case 3:
1984                                 f = 1;
1985                                 break;
1986                 }
1987
1988                 switch(hud_panel_radar_rotation)
1989                 {
1990                         case 0:
1991                                 teamradar_angle = view_angles.y - 90;
1992                                 break;
1993                         default:
1994                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1995                                 break;
1996                 }
1997         }
1998
1999         vector pos, mySize;
2000         pos = panel_pos;
2001         mySize = panel_size;
2002
2003         HUD_Panel_DrawBg(1);
2004         if(panel_bg_padding)
2005         {
2006                 pos += '1 1 0' * panel_bg_padding;
2007                 mySize -= '2 2 0' * panel_bg_padding;
2008         }
2009
2010         float color2;
2011         entity tm;
2012         float scale2d, normalsize, bigsize;
2013
2014         teamradar_origin2d = pos + 0.5 * mySize;
2015         teamradar_size2d = mySize;
2016
2017         if(minimapname == "")
2018                 return;
2019
2020         teamradar_loadcvars();
2021
2022         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2023         teamradar_size2d = mySize;
2024
2025         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2026
2027         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2028         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2029         {
2030                 // max-min distance must fit the radar in any rotation
2031                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2032         }
2033         else
2034         {
2035                 vector c0, c1, c2, c3, span;
2036                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2037                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2038                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2039                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2040                 span = '0 0 0';
2041                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2042                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2043
2044                 // max-min distance must fit the radar in x=x, y=y
2045                 bigsize = min(
2046                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2047                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2048                 );
2049         }
2050
2051         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2052         if(bigsize > normalsize)
2053                 normalsize = bigsize;
2054
2055         teamradar_size =
2056                   f * bigsize
2057                 + (1 - f) * normalsize;
2058         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2059                   f * mi_center
2060                 + (1 - f) * view_origin);
2061
2062         drawsetcliparea(
2063                 pos.x,
2064                 pos.y,
2065                 mySize.x,
2066                 mySize.y
2067         );
2068
2069         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2070
2071         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2072                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2073         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2074                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2075         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2076         {
2077                 color2 = GetPlayerColor(tm.sv_entnum);
2078                 //if(color == NUM_SPECTATOR || color == color2)
2079                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2080         }
2081         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2082
2083         drawresetcliparea();
2084 }
2085
2086 // Score (#7)
2087 //
2088 void HUD_UpdatePlayerTeams();
2089 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2090 {
2091         float score;
2092         entity tm = world, pl;
2093         float SCOREPANEL_MAX_ENTRIES = 6;
2094         float SCOREPANEL_ASPECTRATIO = 2;
2095         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2096         vector fontsize = '1 1 0' * (mySize.y/entries);
2097
2098         vector rgb, score_color;
2099         rgb = '1 1 1';
2100         score_color = '1 1 1';
2101
2102         float name_size = mySize.x*0.75;
2103         float spacing_size = mySize.x*0.04;
2104         const float highlight_alpha = 0.2;
2105         float i = 0, me_printed = 0, first_pl = 0;
2106         string s;
2107         if (autocvar__hud_configure)
2108         {
2109                 float players_per_team = 0;
2110                 if (team_count)
2111                 {
2112                         // show team scores in the first line
2113                         float score_size = mySize.x / team_count;
2114                         players_per_team = max(2, ceil((entries - 1) / team_count));
2115                         for(i=0; i<team_count; ++i) {
2116                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2117                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2118                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2119                         }
2120                         first_pl = 1;
2121                         pos.y += fontsize.y;
2122                 }
2123                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2124                 for (i=first_pl; i<entries; ++i)
2125                 {
2126                         //simulate my score is lower than all displayed players,
2127                         //so that I don't appear at all showing pure rankings.
2128                         //This is to better show the difference between the 2 ranking views
2129                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2130                         {
2131                                 rgb = '1 1 0';
2132                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2133                                 s = GetPlayerName(player_localnum);
2134                                 score = 7;
2135                         }
2136                         else
2137                         {
2138                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2139                                 score -= 3;
2140                         }
2141
2142                         if (team_count)
2143                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2144                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2145                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2146                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2147                         pos.y += fontsize.y;
2148                 }
2149                 return;
2150         }
2151
2152         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2153                 HUD_UpdatePlayerTeams();
2154         if (team_count)
2155         {
2156                 // show team scores in the first line
2157                 float score_size = mySize.x / team_count;
2158                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2159                         if(tm.team == NUM_SPECTATOR)
2160                                 continue;
2161                         if (tm.team == myteam)
2162                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2163                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2164                         ++i;
2165                 }
2166                 first_pl = 1;
2167                 pos.y += fontsize.y;
2168                 tm = teams.sort_next;
2169         }
2170         i = first_pl;
2171
2172         do
2173         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2174         {
2175                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2176                         continue;
2177
2178                 if (i == entries-1 && !me_printed && pl != me)
2179                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2180                 {
2181                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2182                                 if (pl.team != NUM_SPECTATOR)
2183                                         break;
2184
2185                         if (pl)
2186                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2187                         else
2188                                 rgb = '1 0 0'; //last: red
2189                         pl = me;
2190                 }
2191
2192                 if (pl == me)
2193                 {
2194                         if (i == first_pl)
2195                                 rgb = '0 1 0'; //first: green
2196                         me_printed = 1;
2197                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2198                 }
2199                 if (team_count)
2200                         score_color = Team_ColorRGB(pl.team) * 0.8;
2201                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2202                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2203                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2204                 pos.y += fontsize.y;
2205                 ++i;
2206         }
2207         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2208 }
2209
2210 void HUD_Score(void)
2211 {
2212         if(!autocvar__hud_configure)
2213         {
2214                 if(!autocvar_hud_panel_score) return;
2215                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2216         }
2217
2218         HUD_Panel_UpdateCvars();
2219         vector pos, mySize;
2220         pos = panel_pos;
2221         mySize = panel_size;
2222
2223         HUD_Panel_DrawBg(1);
2224         if(panel_bg_padding)
2225         {
2226                 pos += '1 1 0' * panel_bg_padding;
2227                 mySize -= '2 2 0' * panel_bg_padding;
2228         }
2229
2230         float score, distribution = 0;
2231         string sign;
2232         vector distribution_color;
2233         entity tm, pl, me;
2234
2235         me = playerslots[player_localentnum - 1];
2236
2237         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2238                 string timer, distrtimer;
2239
2240                 pl = players.sort_next;
2241                 if(pl == me)
2242                         pl = pl.sort_next;
2243                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2244                         if(pl.scores[ps_primary] == 0)
2245                                 pl = world;
2246
2247                 score = me.(scores[ps_primary]);
2248                 timer = TIME_ENCODED_TOSTRING(score);
2249
2250                 draw_beginBoldFont();
2251                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2252                         // distribution display
2253                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2254
2255                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2256
2257                         if (distribution <= 0) {
2258                                 distribution_color = '0 1 0';
2259                                 sign = "-";
2260                         }
2261                         else {
2262                                 distribution_color = '1 0 0';
2263                                 sign = "+";
2264                         }
2265                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2266                 }
2267                 // race record display
2268                 if (distribution <= 0)
2269                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2270                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2271                 draw_endBoldFont();
2272         } else if (!teamplay) { // non-teamgames
2273                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2274                 {
2275                         HUD_Score_Rankings(pos, mySize, me);
2276                         return;
2277                 }
2278                 // me vector := [team/connected frags id]
2279                 pl = players.sort_next;
2280                 if(pl == me)
2281                         pl = pl.sort_next;
2282
2283                 if(autocvar__hud_configure)
2284                         distribution = 42;
2285                 else if(pl)
2286                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2287                 else
2288                         distribution = 0;
2289
2290                 score = me.(scores[ps_primary]);
2291                 if(autocvar__hud_configure)
2292                         score = 123;
2293
2294                 if(distribution >= 5)
2295                         distribution_color = eY;
2296                 else if(distribution >= 0)
2297                         distribution_color = '1 1 1';
2298                 else if(distribution >= -5)
2299                         distribution_color = '1 1 0';
2300                 else
2301                         distribution_color = eX;
2302
2303                 string distribution_str;
2304                 distribution_str = ftos(distribution);
2305                 draw_beginBoldFont();
2306                 if (distribution >= 0)
2307                 {
2308                         if (distribution > 0)
2309                                 distribution_str = strcat("+", distribution_str);
2310                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2311                 }
2312                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2313                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2314                 draw_endBoldFont();
2315         } else { // teamgames
2316                 float row, column, rows = 0, columns = 0;
2317                 vector offset = '0 0 0';
2318                 vector score_pos, score_size; //for scores other than myteam
2319                 if(autocvar_hud_panel_score_rankings)
2320                 {
2321                         HUD_Score_Rankings(pos, mySize, me);
2322                         return;
2323                 }
2324                 if(spectatee_status == -1)
2325                 {
2326                         rows = HUD_GetRowCount(team_count, mySize, 3);
2327                         columns = ceil(team_count/rows);
2328                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2329
2330                         float newSize;
2331                         if(score_size.x/score_size.y > 3)
2332                         {
2333                                 newSize = 3 * score_size.y;
2334                                 offset.x = score_size.x - newSize;
2335                                 pos.x += offset.x/2;
2336                                 score_size.x = newSize;
2337                         }
2338                         else
2339                         {
2340                                 newSize = 1/3 * score_size.x;
2341                                 offset.y = score_size.y - newSize;
2342                                 pos.y += offset.y/2;
2343                                 score_size.y = newSize;
2344                         }
2345                 }
2346                 else
2347                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2348
2349                 float max_fragcount;
2350                 max_fragcount = -99;
2351                 draw_beginBoldFont();
2352                 row = column = 0;
2353                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2354                         if(tm.team == NUM_SPECTATOR)
2355                                 continue;
2356                         score = tm.(teamscores[ts_primary]);
2357                         if(autocvar__hud_configure)
2358                                 score = 123;
2359
2360                         if (score > max_fragcount)
2361                                 max_fragcount = score;
2362
2363                         if (spectatee_status == -1)
2364                         {
2365                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2366                                 if (max_fragcount == score)
2367                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2368                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2369                                 ++row;
2370                                 if(row >= rows)
2371                                 {
2372                                         row = 0;
2373                                         ++column;
2374                                 }
2375                         }
2376                         else if(tm.team == myteam) {
2377                                 if (max_fragcount == score)
2378                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2379                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2380                         } else {
2381                                 if (max_fragcount == score)
2382                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2383                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2384                                 ++rows;
2385                         }
2386                 }
2387                 draw_endBoldFont();
2388         }
2389 }
2390
2391 // Race timer (#8)
2392 //
2393 void HUD_RaceTimer (void)
2394 {
2395         if(!autocvar__hud_configure)
2396         {
2397                 if(!autocvar_hud_panel_racetimer) return;
2398                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2399                 if(spectatee_status == -1) return;
2400         }
2401
2402         HUD_Panel_UpdateCvars();
2403
2404         draw_beginBoldFont();
2405
2406         vector pos, mySize;
2407         pos = panel_pos;
2408         mySize = panel_size;
2409
2410         HUD_Panel_DrawBg(1);
2411         if(panel_bg_padding)
2412         {
2413                 pos += '1 1 0' * panel_bg_padding;
2414                 mySize -= '2 2 0' * panel_bg_padding;
2415         }
2416
2417         // always force 4:1 aspect
2418         vector newSize = '0 0 0';
2419         if(mySize.x/mySize.y > 4)
2420         {
2421                 newSize.x = 4 * mySize.y;
2422                 newSize.y = mySize.y;
2423
2424                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2425         }
2426         else
2427         {
2428                 newSize.y = 1/4 * mySize.x;
2429                 newSize.x = mySize.x;
2430
2431                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2432         }
2433         mySize = newSize;
2434
2435         float a, t;
2436         string s, forcetime;
2437
2438         if(autocvar__hud_configure)
2439         {
2440                 s = "0:13:37";
2441                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2442                 s = _("^1Intermediate 1 (+15.42)");
2443                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2444                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2445                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2446         }
2447         else if(race_checkpointtime)
2448         {
2449                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2450                 s = "";
2451                 forcetime = "";
2452                 if(a > 0) // just hit a checkpoint?
2453                 {
2454                         if(race_checkpoint != 254)
2455                         {
2456                                 if(race_time && race_previousbesttime)
2457                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2458                                 else
2459                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2460                                 if(race_time)
2461                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2462                         }
2463                 }
2464                 else
2465                 {
2466                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2467                         {
2468                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2469                                 if(a > 0) // next one?
2470                                 {
2471                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2472                                 }
2473                         }
2474                 }
2475
2476                 if(s != "" && a > 0)
2477                 {
2478                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2479                 }
2480
2481                 if(race_penaltytime)
2482                 {
2483                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2484                         if(a > 0)
2485                         {
2486                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2487                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2488                         }
2489                 }
2490
2491                 if(forcetime != "")
2492                 {
2493                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2494                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2495                 }
2496                 else
2497                         a = 1;
2498
2499                 if(race_laptime && race_checkpoint != 255)
2500                 {
2501                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2502                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2503                 }
2504         }
2505         else
2506         {
2507                 if(race_mycheckpointtime)
2508                 {
2509                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2510                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2511                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2512                 }
2513                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2514                 {
2515                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2516                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2517                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2518                 }
2519
2520                 if(race_penaltytime && !race_penaltyaccumulator)
2521                 {
2522                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2523                         a = bound(0, (1 + t - time), 1);
2524                         if(a > 0)
2525                         {
2526                                 if(time < t)
2527                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2528                                 else
2529                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2530                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2531                         }
2532                 }
2533         }
2534
2535         draw_endBoldFont();
2536 }
2537
2538 // Vote window (#9)
2539 //
2540 float vote_yescount;
2541 float vote_nocount;
2542 float vote_needed;
2543 float vote_highlighted; // currently selected vote
2544
2545 float vote_active; // is there an active vote?
2546 float vote_prev; // previous state of vote_active to check for a change
2547 float vote_alpha;
2548 float vote_change; // "time" when vote_active changed
2549
2550 void HUD_Vote(void)
2551 {
2552         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2553         {
2554                 vote_active = 1;
2555                 if (autocvar__hud_configure)
2556                 {
2557                         vote_yescount = 0;
2558                         vote_nocount = 0;
2559                         print(_("^1You must answer before entering hud configure mode\n"));
2560                         cvar_set("_hud_configure", "0");
2561                 }
2562                 if(vote_called_vote)
2563                         strunzone(vote_called_vote);
2564                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2565                 uid2name_dialog = 1;
2566         }
2567
2568         if(!autocvar__hud_configure)
2569         {
2570                 if(!autocvar_hud_panel_vote) return;
2571
2572                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2573                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2574
2575                 if(panel_bg_alpha_str == "") {
2576                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2577                 }
2578                 panel_bg_alpha = stof(panel_bg_alpha_str);
2579         }
2580         else
2581         {
2582                 vote_yescount = 3;
2583                 vote_nocount = 2;
2584                 vote_needed = 4;
2585         }
2586
2587         string s;
2588         float a;
2589         if(vote_active != vote_prev) {
2590                 vote_change = time;
2591                 vote_prev = vote_active;
2592         }
2593
2594         if(vote_active || autocvar__hud_configure)
2595                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2596         else
2597                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2598
2599         if(!vote_alpha)
2600                 return;
2601
2602         HUD_Panel_UpdateCvars();
2603
2604         if(uid2name_dialog)
2605         {
2606                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2607                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2608         }
2609
2610     // these must be below above block
2611         vector pos, mySize;
2612         pos = panel_pos;
2613         mySize = panel_size;
2614
2615         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2616         HUD_Panel_DrawBg(a);
2617         a = panel_fg_alpha * a;
2618
2619         if(panel_bg_padding)
2620         {
2621                 pos += '1 1 0' * panel_bg_padding;
2622                 mySize -= '2 2 0' * panel_bg_padding;
2623         }
2624
2625         // always force 3:1 aspect
2626         vector newSize = '0 0 0';
2627         if(mySize.x/mySize.y > 3)
2628         {
2629                 newSize.x = 3 * mySize.y;
2630                 newSize.y = mySize.y;
2631
2632                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2633         }
2634         else
2635         {
2636                 newSize.y = 1/3 * mySize.x;
2637                 newSize.x = mySize.x;
2638
2639                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2640         }
2641         mySize = newSize;
2642
2643         s = _("A vote has been called for:");
2644         if(uid2name_dialog)
2645                 s = _("Allow servers to store and display your name?");
2646         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2647         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2648         if(autocvar__hud_configure)
2649                 s = _("^1Configure the HUD");
2650         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2651
2652         // print the yes/no counts
2653     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2654         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2655     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2656         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2657
2658         // draw the progress bar backgrounds
2659         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2660
2661         // draw the highlights
2662         if(vote_highlighted == 1) {
2663                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2664                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2665         }
2666         else if(vote_highlighted == -1) {
2667                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2668                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2669         }
2670
2671         // draw the progress bars
2672         if(vote_yescount && vote_needed)
2673         {
2674                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2675                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2676         }
2677
2678         if(vote_nocount && vote_needed)
2679         {
2680                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2681                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2682         }
2683
2684         drawresetcliparea();
2685 }
2686
2687 // Mod icons panel (#10)
2688 //
2689
2690 float mod_active; // is there any active mod icon?
2691
2692 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, float i)
2693 {
2694         float stat = -1;
2695         string pic = "";
2696         vector color = '0 0 0';
2697         switch(i)
2698         {
2699                 case 0:
2700                         stat = getstati(STAT_REDALIVE);
2701                         pic = "player_red.tga";
2702                         color = '1 0 0';
2703                         break;
2704                 case 1:
2705                         stat = getstati(STAT_BLUEALIVE);
2706                         pic = "player_blue.tga";
2707                         color = '0 0 1';
2708                         break;
2709                 case 2:
2710                         stat = getstati(STAT_YELLOWALIVE);
2711                         pic = "player_yellow.tga";
2712                         color = '1 1 0';
2713                         break;
2714                 default:
2715                 case 3:
2716                         stat = getstati(STAT_PINKALIVE);
2717                         pic = "player_pink.tga";
2718                         color = '1 0 1';
2719                         break;
2720         }
2721
2722         if(mySize.x/mySize.y > aspect_ratio)
2723         {
2724                 i = aspect_ratio * mySize.y;
2725                 myPos.x = myPos.x + (mySize.x - i) / 2;
2726                 mySize.x = i;
2727         }
2728         else
2729         {
2730                 i = 1/aspect_ratio * mySize.x;
2731                 myPos.y = myPos.y + (mySize.y - i) / 2;
2732                 mySize.y = i;
2733         }
2734
2735         if(layout)
2736         {
2737                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2738                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2739         }
2740         else
2741                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2742 }
2743
2744 // Clan Arena and Freeze Tag HUD modicons
2745 void HUD_Mod_CA(vector myPos, vector mySize)
2746 {
2747         mod_active = 1; // required in each mod function that always shows something
2748
2749         int layout;
2750         if(gametype == MAPINFO_TYPE_CA)
2751                 layout = autocvar_hud_panel_modicons_ca_layout;
2752         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2753                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2754         float rows, columns, aspect_ratio;
2755         aspect_ratio = (layout) ? 2 : 1;
2756         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2757         columns = ceil(team_count/rows);
2758
2759         int i;
2760         float row = 0, column = 0;
2761         vector pos, itemSize;
2762         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2763         for(i=0; i<team_count; ++i)
2764         {
2765                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2766
2767                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2768
2769                 ++row;
2770                 if(row >= rows)
2771                 {
2772                         row = 0;
2773                         ++column;
2774                 }
2775         }
2776 }
2777
2778 // CTF HUD modicon section
2779 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2780 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2781 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2782
2783 void HUD_Mod_CTF_Reset(void)
2784 {
2785         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2786 }
2787
2788 void HUD_Mod_CTF(vector pos, vector mySize)
2789 {
2790         vector redflag_pos, blueflag_pos;
2791         vector flag_size;
2792         float f; // every function should have that
2793
2794         float redflag, blueflag; // current status
2795         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2796         float stat_items;
2797
2798         stat_items = getstati(STAT_ITEMS, 0, 24);
2799         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2800         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2801
2802         if(redflag || blueflag)
2803                 mod_active = 1;
2804         else
2805                 mod_active = 0;
2806
2807         if(autocvar__hud_configure)
2808         {
2809                 redflag = 1;
2810                 blueflag = 2;
2811         }
2812
2813         // when status CHANGES, set old status into prevstatus and current status into status
2814         if (redflag != redflag_prevframe)
2815         {
2816                 redflag_statuschange_time = time;
2817                 redflag_prevstatus = redflag_prevframe;
2818                 redflag_prevframe = redflag;
2819         }
2820
2821         if (blueflag != blueflag_prevframe)
2822         {
2823                 blueflag_statuschange_time = time;
2824                 blueflag_prevstatus = blueflag_prevframe;
2825                 blueflag_prevframe = blueflag;
2826         }
2827
2828         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2829         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2830
2831         float BLINK_FACTOR = 0.15;
2832         float BLINK_BASE = 0.85;
2833         // note:
2834         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2835         // thus
2836         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2837         // ensure RMS == 1
2838         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2839
2840         string red_icon, red_icon_prevstatus;
2841         float red_alpha, red_alpha_prevstatus;
2842         red_alpha = red_alpha_prevstatus = 1;
2843         switch(redflag) {
2844                 case 1: red_icon = "flag_red_taken"; break;
2845                 case 2: red_icon = "flag_red_lost"; break;
2846                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2847                 default:
2848                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2849                                 red_icon = "flag_red_shielded";
2850                         else
2851                                 red_icon = string_null;
2852                         break;
2853         }
2854         switch(redflag_prevstatus) {
2855                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2856                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2857                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2858                 default:
2859                         if(redflag == 3)
2860                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2861                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2862                                 red_icon_prevstatus = "flag_red_shielded";
2863                         else
2864                                 red_icon_prevstatus = string_null;
2865                         break;
2866         }
2867
2868         string blue_icon, blue_icon_prevstatus;
2869         float blue_alpha, blue_alpha_prevstatus;
2870         blue_alpha = blue_alpha_prevstatus = 1;
2871         switch(blueflag) {
2872                 case 1: blue_icon = "flag_blue_taken"; break;
2873                 case 2: blue_icon = "flag_blue_lost"; break;
2874                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2875                 default:
2876                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2877                                 blue_icon = "flag_blue_shielded";
2878                         else
2879                                 blue_icon = string_null;
2880                         break;
2881         }
2882         switch(blueflag_prevstatus) {
2883                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2884                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2885                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2886                 default:
2887                         if(blueflag == 3)
2888                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2889                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2890                                 blue_icon_prevstatus = "flag_blue_shielded";
2891                         else
2892                                 blue_icon_prevstatus = string_null;
2893                         break;
2894         }
2895
2896         if(mySize.x > mySize.y) {
2897                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2898                         redflag_pos = pos;
2899                         blueflag_pos = pos + eX * 0.5 * mySize.x;
2900                 } else {
2901                         blueflag_pos = pos;
2902                         redflag_pos = pos + eX * 0.5 * mySize.x;
2903                 }
2904                 flag_size = eX * 0.5 * mySize.x + eY * mySize.y;
2905         } else {
2906                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2907                         redflag_pos = pos;
2908                         blueflag_pos = pos + eY * 0.5 * mySize.y;
2909                 } else {
2910                         blueflag_pos = pos;
2911                         redflag_pos = pos + eY * 0.5 * mySize.y;
2912                 }
2913                 flag_size = eY * 0.5 * mySize.y + eX * mySize.x;
2914         }
2915
2916         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2917         if(red_icon_prevstatus && f < 1)
2918                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2919         if(red_icon)
2920                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2921
2922         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2923         if(blue_icon_prevstatus && f < 1)
2924                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2925         if(blue_icon)
2926                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2927 }
2928
2929 // Keyhunt HUD modicon section
2930 vector KH_SLOTS[4];
2931
2932 void HUD_Mod_KH(vector pos, vector mySize)
2933 {
2934         mod_active = 1; // keyhunt should never hide the mod icons panel
2935
2936         // Read current state
2937
2938         float state = getstati(STAT_KH_KEYS);
2939         float i, key_state;
2940         float all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
2941         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
2942
2943         for(i = 0; i < 4; ++i)
2944         {
2945                 key_state = (bitshift(state, i * -5) & 31) - 1;
2946
2947                 if(key_state == -1)
2948                         continue;
2949
2950                 if(key_state == 30)
2951                 {
2952                         ++carrying_keys;
2953                         key_state = myteam;
2954                 }
2955
2956                 switch(key_state)
2957                 {
2958                         case NUM_TEAM_1: ++team1_keys; break;
2959                         case NUM_TEAM_2: ++team2_keys; break;
2960                         case NUM_TEAM_3: ++team3_keys; break;
2961                         case NUM_TEAM_4: ++team4_keys; break;
2962                         case 29: ++dropped_keys; break;
2963                 }
2964
2965                 ++all_keys;
2966         }
2967
2968         // Calculate slot measurements
2969
2970         vector slot_size;
2971
2972         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
2973         {
2974                 // Quadratic arrangement
2975                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
2976                 KH_SLOTS[0] = pos;
2977                 KH_SLOTS[1] = pos + eX * slot_size.x;
2978                 KH_SLOTS[2] = pos + eY * slot_size.y;
2979                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
2980         }
2981         else
2982         {
2983                 if(mySize.x > mySize.y)
2984                 {
2985                         // Horizontal arrangement
2986                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
2987                         for(i = 0; i < all_keys; ++i)
2988                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
2989                 }
2990                 else
2991                 {
2992                         // Vertical arrangement
2993                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
2994                         for(i = 0; i < all_keys; ++i)
2995                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
2996                 }
2997         }
2998
2999         // Make icons blink in case of RUN HERE
3000
3001         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3002         float alpha;
3003         alpha = 1;
3004
3005         if(carrying_keys)
3006                 switch(myteam)
3007                 {
3008                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3009                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3010                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3011                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3012                 }
3013
3014         // Draw icons
3015
3016         i = 0;
3017
3018         while(team1_keys--)
3019                 if(myteam == NUM_TEAM_1 && carrying_keys)
3020                 {
3021                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3022                         --carrying_keys;
3023                 }
3024                 else
3025                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3026
3027         while(team2_keys--)
3028                 if(myteam == NUM_TEAM_2 && carrying_keys)
3029                 {
3030                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3031                         --carrying_keys;
3032                 }
3033                 else
3034                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3035
3036         while(team3_keys--)
3037                 if(myteam == NUM_TEAM_3 && carrying_keys)
3038                 {
3039                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3040                         --carrying_keys;
3041                 }
3042                 else
3043                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3044
3045         while(team4_keys--)
3046                 if(myteam == NUM_TEAM_4 && carrying_keys)
3047                 {
3048                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3049                         --carrying_keys;
3050                 }
3051                 else
3052                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3053
3054         while(dropped_keys--)
3055                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3056 }
3057
3058 // Keepaway HUD mod icon
3059 float kaball_prevstatus; // last remembered status
3060 float kaball_statuschange_time; // time when the status changed
3061
3062 // we don't need to reset for keepaway since it immediately
3063 // autocorrects prevstatus as to if the player has the ball or not
3064
3065 void HUD_Mod_Keepaway(vector pos, vector mySize)
3066 {
3067         mod_active = 1; // keepaway should always show the mod HUD
3068
3069         float BLINK_FACTOR = 0.15;
3070         float BLINK_BASE = 0.85;
3071         float BLINK_FREQ = 5;
3072         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3073
3074         float stat_items = getstati(STAT_ITEMS, 0, 24);
3075         float kaball = (stat_items/IT_KEY1) & 1;
3076
3077         if(kaball != kaball_prevstatus)
3078         {
3079                 kaball_statuschange_time = time;
3080                 kaball_prevstatus = kaball;
3081         }
3082
3083         vector kaball_pos, kaball_size;
3084
3085         if(mySize.x > mySize.y) {
3086                 kaball_pos = pos + eX * 0.25 * mySize.x;
3087                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3088         } else {
3089                 kaball_pos = pos + eY * 0.25 * mySize.y;
3090                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3091         }
3092
3093         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3094         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3095
3096         if(kaball_prevstatus && f < 1)
3097                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3098
3099         if(kaball)
3100                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3101 }
3102
3103
3104 // Nexball HUD mod icon
3105 void HUD_Mod_NexBall(vector pos, vector mySize)
3106 {
3107         float stat_items, nb_pb_starttime, dt, p;
3108
3109         stat_items = getstati(STAT_ITEMS, 0, 24);
3110         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3111
3112         if (stat_items & IT_KEY1)
3113                 mod_active = 1;
3114         else
3115                 mod_active = 0;
3116
3117         //Manage the progress bar if any
3118         if (nb_pb_starttime > 0)
3119         {
3120                 dt = (time - nb_pb_starttime) % nb_pb_period;
3121                 // one period of positive triangle
3122                 p = 2 * dt / nb_pb_period;
3123                 if (p > 1)
3124                         p = 2 - p;
3125
3126                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3127         }
3128
3129         if (stat_items & IT_KEY1)
3130                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3131 }
3132
3133 // Race/CTS HUD mod icons
3134 float crecordtime_prev; // last remembered crecordtime
3135 float crecordtime_change_time; // time when crecordtime last changed
3136 float srecordtime_prev; // last remembered srecordtime
3137 float srecordtime_change_time; // time when srecordtime last changed
3138
3139 float race_status_time;
3140 float race_status_prev;
3141 string race_status_name_prev;
3142 void HUD_Mod_Race(vector pos, vector mySize)
3143 {
3144         mod_active = 1; // race should never hide the mod icons panel
3145         entity me;
3146         me = playerslots[player_localnum];
3147         float t, score;
3148         float f; // yet another function has this
3149         score = me.(scores[ps_primary]);
3150
3151         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3152                 return; // no records in the actual race
3153
3154         // clientside personal record
3155         string rr;
3156         if(gametype == MAPINFO_TYPE_CTS)
3157                 rr = CTS_RECORD;
3158         else
3159                 rr = RACE_RECORD;
3160         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3161
3162         if(score && (score < t || !t)) {
3163                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3164                 if(autocvar_cl_autodemo_delete_keeprecords)
3165                 {
3166                         f = autocvar_cl_autodemo_delete;
3167                         f &= ~1;
3168                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3169                 }
3170         }
3171
3172         if(t != crecordtime_prev) {
3173                 crecordtime_prev = t;
3174                 crecordtime_change_time = time;
3175         }
3176
3177         vector textPos, medalPos;
3178         float squareSize;
3179         if(mySize.x > mySize.y) {
3180                 // text on left side
3181                 squareSize = min(mySize.y, mySize.x/2);
3182                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3183                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3184         } else {
3185                 // text on top
3186                 squareSize = min(mySize.x, mySize.y/2);
3187                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3188                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3189         }
3190
3191         f = time - crecordtime_change_time;
3192
3193         if (f > 1) {
3194                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3195                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3196         } else {
3197                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3198                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3199                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3200                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3201         }
3202
3203         // server record
3204         t = race_server_record;
3205         if(t != srecordtime_prev) {
3206                 srecordtime_prev = t;
3207                 srecordtime_change_time = time;
3208         }
3209         f = time - srecordtime_change_time;
3210
3211         if (f > 1) {
3212                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3213                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3214         } else {
3215                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3216                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3217                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3218                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3219         }
3220
3221         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3222                 race_status_time = time + 5;
3223                 race_status_prev = race_status;
3224                 if (race_status_name_prev)
3225                         strunzone(race_status_name_prev);
3226                 race_status_name_prev = strzone(race_status_name);
3227         }
3228
3229         // race "awards"
3230         float a;
3231         a = bound(0, race_status_time - time, 1);
3232
3233         string s;
3234         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3235
3236         float rank;
3237         if(race_status > 0)
3238                 rank = race_CheckName(race_status_name);
3239         else
3240                 rank = 0;
3241         string rankname;
3242         rankname = count_ordinal(rank);
3243
3244         vector namepos;
3245         namepos = medalPos + '0 0.8 0' * squareSize;
3246         vector rankpos;
3247         rankpos = medalPos + '0 0.15 0' * squareSize;
3248
3249         if(race_status == 0)
3250                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3251         else if(race_status == 1) {
3252                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3253                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3254                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3255         } else if(race_status == 2) {
3256                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3257                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3258                 else
3259                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3260                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3261                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3262         } else if(race_status == 3) {
3263                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3264                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3265                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3266         }
3267
3268         if (race_status_time - time <= 0) {
3269                 race_status_prev = -1;
3270                 race_status = -1;
3271                 if(race_status_name)
3272                         strunzone(race_status_name);
3273                 race_status_name = string_null;
3274                 if(race_status_name_prev)
3275                         strunzone(race_status_name_prev);
3276                 race_status_name_prev = string_null;
3277         }
3278 }
3279
3280 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, float i)
3281 {
3282         float stat = -1;
3283         string pic = "";
3284         vector color = '0 0 0';
3285         switch(i)
3286         {
3287                 case 0:
3288                         stat = getstatf(STAT_DOM_PPS_RED);
3289                         pic = "dom_icon_red";
3290                         color = '1 0 0';
3291                         break;
3292                 case 1:
3293                         stat = getstatf(STAT_DOM_PPS_BLUE);
3294                         pic = "dom_icon_blue";
3295                         color = '0 0 1';
3296                         break;
3297                 case 2:
3298                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3299                         pic = "dom_icon_yellow";
3300                         color = '1 1 0';
3301                         break;
3302                 default:
3303                 case 3:
3304                         stat = getstatf(STAT_DOM_PPS_PINK);
3305                         pic = "dom_icon_pink";
3306                         color = '1 0 1';
3307                         break;
3308         }
3309         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3310
3311         if(mySize.x/mySize.y > aspect_ratio)
3312         {
3313                 i = aspect_ratio * mySize.y;
3314                 myPos.x = myPos.x + (mySize.x - i) / 2;
3315                 mySize.x = i;
3316         }
3317         else
3318         {
3319                 i = 1/aspect_ratio * mySize.x;
3320                 myPos.y = myPos.y + (mySize.y - i) / 2;
3321                 mySize.y = i;
3322         }
3323
3324         if (layout) // show text too
3325         {
3326                 //draw the text
3327                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3328                 if (layout == 2) // average pps
3329                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3330                 else // percentage of average pps
3331                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3332         }
3333
3334         //draw the icon
3335         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3336         if (stat > 0)
3337         {
3338                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3339                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3340                 drawresetcliparea();
3341         }
3342 }
3343
3344 void HUD_Mod_Dom(vector myPos, vector mySize)
3345 {
3346         mod_active = 1; // required in each mod function that always shows something
3347
3348         int layout = autocvar_hud_panel_modicons_dom_layout;
3349         float rows, columns, aspect_ratio;
3350         aspect_ratio = (layout) ? 3 : 1;
3351         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3352         columns = ceil(team_count/rows);
3353
3354         int i;
3355         float row = 0, column = 0;
3356         vector pos, itemSize;
3357         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3358         for(i=0; i<team_count; ++i)
3359         {
3360                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3361
3362                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3363
3364                 ++row;
3365                 if(row >= rows)
3366                 {
3367                         row = 0;
3368                         ++column;
3369                 }
3370         }
3371 }
3372
3373 void HUD_ModIcons_SetFunc()
3374 {
3375         switch(gametype)
3376         {
3377                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3378                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3379                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3380                 case MAPINFO_TYPE_CTS:
3381                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3382                 case MAPINFO_TYPE_CA:
3383                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3384                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3385                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3386         }
3387 }
3388
3389 float mod_prev; // previous state of mod_active to check for a change
3390 float mod_alpha;
3391 float mod_change; // "time" when mod_active changed
3392
3393 void HUD_ModIcons(void)
3394 {
3395         if(!autocvar__hud_configure)
3396         {
3397                 if(!autocvar_hud_panel_modicons) return;
3398                 if(!HUD_ModIcons_GameType) return;
3399         }
3400
3401         HUD_Panel_UpdateCvars();
3402
3403         draw_beginBoldFont();
3404
3405         if(mod_active != mod_prev) {
3406                 mod_change = time;
3407                 mod_prev = mod_active;
3408         }
3409
3410         if(mod_active || autocvar__hud_configure)
3411                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3412         else
3413                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3414
3415         if(mod_alpha)
3416                 HUD_Panel_DrawBg(mod_alpha);
3417
3418         if(panel_bg_padding)
3419         {
3420                 panel_pos += '1 1 0' * panel_bg_padding;
3421                 panel_size -= '2 2 0' * panel_bg_padding;
3422         }
3423
3424         if(autocvar__hud_configure)
3425                 HUD_Mod_CTF(panel_pos, panel_size);
3426         else
3427                 HUD_ModIcons_GameType(panel_pos, panel_size);
3428
3429         draw_endBoldFont();
3430 }
3431
3432 // Draw pressed keys (#11)
3433 //
3434 void HUD_PressedKeys(void)
3435 {
3436         if(!autocvar__hud_configure)
3437         {
3438                 if(!autocvar_hud_panel_pressedkeys) return;
3439                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3440         }
3441
3442         HUD_Panel_UpdateCvars();
3443         vector pos, mySize;
3444         pos = panel_pos;
3445         mySize = panel_size;
3446
3447         HUD_Panel_DrawBg(1);
3448         if(panel_bg_padding)
3449         {
3450                 pos += '1 1 0' * panel_bg_padding;
3451                 mySize -= '2 2 0' * panel_bg_padding;
3452         }
3453
3454         // force custom aspect
3455         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3456         if(aspect)
3457         {
3458                 vector newSize = '0 0 0';
3459                 if(mySize.x/mySize.y > aspect)
3460                 {
3461                         newSize.x = aspect * mySize.y;
3462                         newSize.y = mySize.y;
3463
3464                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3465                 }
3466                 else
3467                 {
3468                         newSize.y = 1/aspect * mySize.x;
3469                         newSize.x = mySize.x;
3470
3471                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3472                 }
3473                 mySize = newSize;
3474         }
3475
3476         vector keysize;
3477         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3478         float pressedkeys;
3479         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3480
3481         if(autocvar_hud_panel_pressedkeys_attack)
3482         {
3483                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3484                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3485                 pos.y += keysize.y;
3486         }
3487
3488         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3489         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3490         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3491         pos.y += keysize.y;
3492         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3493         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3494         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3495 }
3496
3497 // Handle chat as a panel (#12)
3498 //
3499 void HUD_Chat(void)
3500 {
3501         if(!autocvar__hud_configure)
3502         {
3503                 if (!autocvar_hud_panel_chat)
3504                 {
3505                         if (!autocvar_con_chatrect)
3506                                 cvar_set("con_chatrect", "0");
3507                         return;
3508                 }
3509                 if(autocvar__con_chat_maximized)
3510                 {
3511                         if(!hud_draw_maximized) return;
3512                 }
3513                 else if(chat_panel_modified)
3514                 {
3515                         panel.update_time = time; // forces reload of panel attributes
3516                         chat_panel_modified = false;
3517                 }
3518         }
3519
3520         HUD_Panel_UpdateCvars();
3521
3522         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3523         {
3524                 panel_pos.y = panel_bg_border;
3525                 panel_size.y = vid_conheight - panel_bg_border * 2;
3526                 if(panel.current_panel_bg == "0") // force a border when maximized
3527                 {
3528                         string panel_bg;
3529                         panel_bg = strcat(hud_skin_path, "/border_default");
3530                         if(precache_pic(panel_bg) == "")
3531                                 panel_bg = "gfx/hud/default/border_default";
3532                         if(panel.current_panel_bg)
3533                                 strunzone(panel.current_panel_bg);
3534                         panel.current_panel_bg = strzone(panel_bg);
3535                         chat_panel_modified = true;
3536                 }
3537                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3538         }
3539
3540         vector pos, mySize;
3541         pos = panel_pos;
3542         mySize = panel_size;
3543
3544         HUD_Panel_DrawBg(1);
3545
3546         if(panel_bg_padding)
3547         {
3548                 pos += '1 1 0' * panel_bg_padding;
3549                 mySize -= '2 2 0' * panel_bg_padding;
3550         }
3551
3552         if (!autocvar_con_chatrect)
3553                 cvar_set("con_chatrect", "1");
3554
3555         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3556         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3557
3558         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3559         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3560
3561         if(autocvar__hud_configure)
3562         {
3563                 vector chatsize;
3564                 chatsize = '1 1 0' * autocvar_con_chatsize;
3565                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3566                 float i, a;
3567                 for(i = 0; i < autocvar_con_chat; ++i)
3568                 {
3569                         if(i == autocvar_con_chat - 1)
3570                                 a = panel_fg_alpha;
3571                         else
3572                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3573                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3574                         pos.y += chatsize.y;
3575                 }
3576         }
3577 }
3578
3579 // Engine info panel (#13)
3580 //
3581 float prevfps;
3582 float prevfps_time;
3583 float framecounter;
3584
3585 float frametimeavg;
3586 float frametimeavg1; // 1 frame ago
3587 float frametimeavg2; // 2 frames ago
3588 void HUD_EngineInfo(void)
3589 {
3590         if(!autocvar__hud_configure)
3591         {
3592                 if(!autocvar_hud_panel_engineinfo) return;
3593         }
3594
3595         HUD_Panel_UpdateCvars();
3596         vector pos, mySize;
3597         pos = panel_pos;
3598         mySize = panel_size;
3599
3600         HUD_Panel_DrawBg(1);
3601         if(panel_bg_padding)
3602         {
3603                 pos += '1 1 0' * panel_bg_padding;
3604                 mySize -= '2 2 0' * panel_bg_padding;
3605         }
3606
3607         float currentTime = gettime(GETTIME_REALTIME);
3608         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3609         {
3610                 float currentframetime = currentTime - prevfps_time;
3611                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3612                 frametimeavg2 = frametimeavg1;
3613                 frametimeavg1 = frametimeavg;
3614
3615                 float weight;
3616                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3617                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3618                 {
3619                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3620                                 prevfps = (1/currentframetime);
3621                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3622                 }
3623                 prevfps_time = currentTime;
3624         }
3625         else
3626         {
3627                 framecounter += 1;
3628                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3629                 {
3630                         prevfps = framecounter/(currentTime - prevfps_time);
3631                         framecounter = 0;
3632                         prevfps_time = currentTime;
3633                 }
3634         }
3635
3636         vector color;
3637         color = HUD_Get_Num_Color (prevfps, 100);
3638         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3639 }
3640
3641 // Info messages panel (#14)
3642 //
3643 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3644         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3645                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3646         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3647         o.y += fontsize.y;                                                                                                                                                                                              \
3648 } while(0)
3649 void HUD_InfoMessages(void)
3650 {
3651         if(!autocvar__hud_configure)
3652         {
3653                 if(!autocvar_hud_panel_infomessages) return;
3654         }
3655
3656         HUD_Panel_UpdateCvars();
3657         vector pos, mySize;
3658         pos = panel_pos;
3659         mySize = panel_size;
3660
3661         HUD_Panel_DrawBg(1);
3662         if(panel_bg_padding)
3663         {
3664                 pos += '1 1 0' * panel_bg_padding;
3665                 mySize -= '2 2 0' * panel_bg_padding;
3666         }
3667
3668         // always force 5:1 aspect
3669         vector newSize = '0 0 0';
3670         if(mySize.x/mySize.y > 5)
3671         {
3672                 newSize.x = 5 * mySize.y;
3673                 newSize.y = mySize.y;
3674
3675                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3676         }
3677         else
3678         {
3679                 newSize.y = 1/5 * mySize.x;
3680                 newSize.x = mySize.x;
3681
3682                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3683         }
3684
3685         mySize = newSize;
3686         entity tm;
3687         vector o;
3688         o = pos;
3689
3690         vector fontsize;
3691         fontsize = '0.20 0.20 0' * mySize.y;
3692
3693         float a;
3694         a = panel_fg_alpha;
3695
3696         string s;
3697         if(!autocvar__hud_configure)
3698         {
3699                 if(spectatee_status && !intermission)
3700                 {
3701                         a = 1;
3702                         if(spectatee_status == -1)
3703                                 s = _("^1Observing");
3704                         else
3705                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3706                         drawInfoMessage(s);
3707
3708                         if(spectatee_status == -1)
3709                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3710                         else
3711                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3712                         drawInfoMessage(s);
3713
3714                         if(spectatee_status == -1)
3715                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3716                         else
3717                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3718                         drawInfoMessage(s);
3719
3720                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3721                         drawInfoMessage(s);
3722
3723                         if(gametype == MAPINFO_TYPE_LMS)
3724                         {
3725                                 entity sk;
3726                                 sk = playerslots[player_localnum];
3727                                 if(sk.(scores[ps_primary]) >= 666)
3728                                         s = _("^1Match has already begun");
3729                                 else if(sk.(scores[ps_primary]) > 0)
3730                                         s = _("^1You have no more lives left");
3731                                 else
3732                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3733                         }
3734                         else
3735                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3736                         drawInfoMessage(s);
3737
3738                         //show restart countdown:
3739                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3740                                 float countdown;
3741                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3742                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3743                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3744                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3745                                 o.y += fontsize.y;
3746                         }
3747                 }
3748                 if(warmup_stage && !intermission)
3749                 {
3750                         s = _("^2Currently in ^1warmup^2 stage!");
3751                         drawInfoMessage(s);
3752                 }
3753
3754                 string blinkcolor;
3755                 if(time % 1 >= 0.5)
3756                         blinkcolor = "^1";
3757                 else
3758                         blinkcolor = "^3";
3759
3760                 if(ready_waiting && !intermission && !spectatee_status)
3761                 {
3762                         if(ready_waiting_for_me)
3763                         {
3764                                 if(warmup_stage)
3765                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3766                                 else
3767                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3768                         }
3769                         else
3770                         {
3771                                 if(warmup_stage)
3772                                         s = _("^2Waiting for others to ready up to end warmup...");
3773                                 else
3774                                         s = _("^2Waiting for others to ready up...");
3775                         }
3776                         drawInfoMessage(s);
3777                 }
3778                 else if(warmup_stage && !intermission && !spectatee_status)
3779                 {
3780                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3781                         drawInfoMessage(s);
3782                 }
3783
3784                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3785                 {
3786                         float ts_min = 0, ts_max = 0;
3787                         tm = teams.sort_next;
3788                         if (tm)
3789                         {
3790                                 for (; tm.sort_next; tm = tm.sort_next)
3791                                 {
3792                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3793                                                 continue;
3794                                         if(!ts_min) ts_min = tm.team_size;
3795                                         else ts_min = min(ts_min, tm.team_size);
3796                                         if(!ts_max) ts_max = tm.team_size;
3797                                         else ts_max = max(ts_max, tm.team_size);
3798                                 }
3799                                 if ((ts_max - ts_min) > 1)
3800                                 {
3801                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3802                                         tm = GetTeam(myteam, false);
3803                                         if (tm)
3804                                         if (tm.team != NUM_SPECTATOR)
3805                                         if (tm.team_size == ts_max)
3806                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3807                                         drawInfoMessage(s);
3808                                 }
3809                         }
3810                 }
3811         }
3812         else
3813         {
3814                 s = _("^7Press ^3ESC ^7to show HUD options.");
3815                 drawInfoMessage(s);
3816                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3817                 drawInfoMessage(s);
3818                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3819                 drawInfoMessage(s);
3820                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3821                 drawInfoMessage(s);
3822         }
3823 }
3824
3825 // Physics panel (#15)
3826 //
3827 vector acc_prevspeed;
3828 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3829 void HUD_Physics(void)
3830 {
3831         if(!autocvar__hud_configure)
3832         {
3833                 if(!autocvar_hud_panel_physics) return;
3834                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3835                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3836         }
3837
3838         HUD_Panel_UpdateCvars();
3839
3840         draw_beginBoldFont();
3841
3842         HUD_Panel_DrawBg(1);
3843         if(panel_bg_padding)
3844         {
3845                 panel_pos += '1 1 0' * panel_bg_padding;
3846                 panel_size -= '2 2 0' * panel_bg_padding;
3847         }
3848
3849         float acceleration_progressbar_scale = 0;
3850         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3851                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3852
3853         float text_scale;
3854         if (autocvar_hud_panel_physics_text_scale <= 0)
3855                 text_scale = 1;
3856         else
3857                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3858
3859         //compute speed
3860         float speed, conversion_factor;
3861         string unit;
3862
3863         switch(autocvar_hud_panel_physics_speed_unit)
3864         {
3865                 default:
3866                 case 1:
3867                         unit = _(" qu/s");
3868                         conversion_factor = 1.0;
3869                         break;
3870                 case 2:
3871                         unit = _(" m/s");
3872                         conversion_factor = 0.0254;
3873                         break;
3874                 case 3:
3875                         unit = _(" km/h");
3876                         conversion_factor = 0.0254 * 3.6;
3877                         break;
3878                 case 4:
3879                         unit = _(" mph");
3880                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3881                         break;
3882                 case 5:
3883                         unit = _(" knots");
3884                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3885                         break;
3886         }
3887
3888         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3889
3890         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3891         if (autocvar__hud_configure)
3892                 speed = floor( max_speed * 0.65 + 0.5 );
3893         else if(autocvar_hud_panel_physics_speed_vertical)
3894                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3895         else
3896                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
3897
3898         //compute acceleration
3899         float acceleration, f;
3900         if (autocvar__hud_configure)
3901                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3902         else
3903         {
3904                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3905                 f = time - acc_prevtime;
3906                 if(autocvar_hud_panel_physics_acceleration_vertical)
3907                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3908                 else
3909                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
3910
3911                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3912
3913                 acc_prevspeed = vel;
3914                 acc_prevtime = time;
3915
3916                 f = bound(0, f * 10, 1);
3917                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3918         }
3919
3920         //compute layout
3921         float panel_ar = panel_size.x/panel_size.y;
3922         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3923         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3924         {
3925                 panel_size.x *= 0.5;
3926                 if (autocvar_hud_panel_physics_flip)
3927                         speed_offset.x = panel_size.x;
3928                 else
3929                         acceleration_offset.x = panel_size.x;
3930         }
3931         else
3932         {
3933                 panel_size.y *= 0.5;
3934                 if (autocvar_hud_panel_physics_flip)
3935                         speed_offset.y = panel_size.y;
3936                 else
3937                         acceleration_offset.y = panel_size.y;
3938         }
3939         float speed_baralign, acceleration_baralign;
3940         if (autocvar_hud_panel_physics_baralign == 1)
3941                 acceleration_baralign = speed_baralign = 1;
3942     else if(autocvar_hud_panel_physics_baralign == 4)
3943                 acceleration_baralign = speed_baralign = 2;
3944         else if (autocvar_hud_panel_physics_flip)
3945         {
3946                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3947                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3948         }
3949         else
3950         {
3951                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3952                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3953         }
3954         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3955                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3956
3957         //draw speed
3958         if(speed)
3959         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3960                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3961         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3962         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3963         {
3964                 tmp_size.x = panel_size.x * 0.75;
3965                 tmp_size.y = panel_size.y * text_scale;
3966                 if (speed_baralign)
3967                         tmp_offset.x = panel_size.x - tmp_size.x;
3968                 //else
3969                         //tmp_offset_x = 0;
3970                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
3971                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3972
3973                 //draw speed unit
3974                 if (speed_baralign)
3975                         tmp_offset.x = 0;
3976                 else
3977                         tmp_offset.x = tmp_size.x;
3978                 if (autocvar_hud_panel_physics_speed_unit_show)
3979                 {
3980                         //tmp_offset_y = 0;
3981                         tmp_size.x = panel_size.x * (1 - 0.75);
3982                         tmp_size.y = panel_size.y * 0.4 * text_scale;
3983                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
3984                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3985                 }
3986         }
3987
3988         //compute and draw top speed
3989         if (autocvar_hud_panel_physics_topspeed)
3990         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3991         {
3992                 if (autocvar__hud_configure)
3993                 {
3994                         top_speed = floor( max_speed * 0.75 + 0.5 );
3995                         f = 1;
3996                 }
3997                 else
3998                 {
3999                         if (speed >= top_speed)
4000                         {
4001                                 top_speed = speed;
4002                                 top_speed_time = time;
4003                         }
4004                         if (top_speed != 0)
4005                         {
4006                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4007                                 // divide by f to make it start from 1
4008                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4009                         }
4010             else //hide top speed 0, it would be stupid
4011                                 f = 0;
4012                 }
4013                 if (f > 0)
4014                 {
4015                         //top speed progressbar peak
4016                         if(speed < top_speed)
4017                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4018                         {
4019                                 float peak_offsetX;
4020                                 vector peak_size = '0 0 0';
4021                                 if (speed_baralign == 0)
4022                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4023                 else if (speed_baralign == 1)
4024                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4025                 else // if (speed_baralign == 2)
4026                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4027                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4028                 peak_size.y = panel_size.y;
4029                 if (speed_baralign == 2) // draw two peaks, on both sides
4030                 {
4031                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4032                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4033                 }
4034                 else
4035                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4036                         }
4037
4038                         //top speed
4039                         tmp_offset.y = panel_size.y * 0.4;
4040                         tmp_size.x = panel_size.x * (1 - 0.75);
4041                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4042                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4043                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4044                 }
4045                 else
4046                         top_speed = 0;
4047         }
4048
4049         //draw acceleration
4050         if(acceleration)
4051         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4052         {
4053                 vector progressbar_color;
4054                 if(acceleration < 0)
4055                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4056                 else
4057                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4058
4059                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4060                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4061                         f = sqrt(f);
4062
4063                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4064                 {
4065                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4066
4067                         if (acceleration_baralign == 1)
4068                                 tmp_offset.x = panel_size.x - tmp_size.x;
4069                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4070                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4071                         else
4072                                 tmp_offset.x = 0;
4073                         tmp_offset.y = 0;
4074                 }
4075                 else
4076                 {
4077                         tmp_size = panel_size;
4078                         tmp_offset = '0 0 0';
4079                 }
4080
4081                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4082         }
4083         tmp_size.x = panel_size.x;
4084         tmp_size.y = panel_size.y * text_scale;
4085         tmp_offset.x = 0;
4086         tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4087         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4088                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4089
4090         draw_endBoldFont();
4091 }
4092
4093 // CenterPrint (#16)
4094 //
4095 const float CENTERPRINT_MAX_MSGS = 10;
4096 const float CENTERPRINT_MAX_ENTRIES = 50;
4097 const float CENTERPRINT_SPACING = 0.7;
4098 float cpm_index;
4099 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4100 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4101 float centerprint_time[CENTERPRINT_MAX_MSGS];
4102 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4103 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4104 float centerprint_showing;
4105
4106 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4107 {
4108         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4109         float i, j;
4110
4111         if(strMessage == "" && new_id == 0)
4112                 return;
4113
4114         // strip trailing newlines
4115         j = strlen(strMessage) - 1;
4116         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4117                 --j;
4118         if (j < strlen(strMessage) - 1)
4119                 strMessage = substring(strMessage, 0, j + 1);
4120
4121         if(strMessage == "" && new_id == 0)
4122                 return;
4123
4124         // strip leading newlines
4125         j = 0;
4126         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4127                 ++j;
4128         if (j > 0)
4129                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4130
4131         if(strMessage == "" && new_id == 0)
4132                 return;
4133
4134         if (!centerprint_showing)
4135                 centerprint_showing = true;
4136
4137         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4138         {
4139                 if (j == CENTERPRINT_MAX_MSGS)
4140                         j = 0;
4141                 if (new_id && new_id == centerprint_msgID[j])
4142                 {
4143                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4144                         {
4145                                 // fade out the current msg (duration and countdown_num are ignored)
4146                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4147                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4148                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4149                                 return;
4150                         }
4151                         break; // found a msg with the same id, at position j
4152                 }
4153         }
4154
4155         if (i == CENTERPRINT_MAX_MSGS)
4156         {
4157                 // a msg with the same id was not found, add the msg at the next position
4158                 --cpm_index;
4159                 if (cpm_index == -1)
4160                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4161                 j = cpm_index;
4162         }
4163         if(centerprint_messages[j])
4164                 strunzone(centerprint_messages[j]);
4165         centerprint_messages[j] = strzone(strMessage);
4166         centerprint_msgID[j] = new_id;
4167         if (duration < 0)
4168         {
4169                 centerprint_time[j] = -1;
4170                 centerprint_expire_time[j] = time;
4171         }
4172         else
4173         {
4174                 if(duration == 0)
4175                         duration = max(1, autocvar_hud_panel_centerprint_time);
4176                 centerprint_time[j] = duration;
4177                 centerprint_expire_time[j] = time + duration;
4178         }
4179         centerprint_countdown_num[j] = countdown_num;
4180 }
4181
4182 void centerprint_hud(string strMessage)
4183 {
4184         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4185 }
4186
4187 void reset_centerprint_messages(void)
4188 {
4189         float i;
4190         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4191         {
4192                 centerprint_expire_time[i] = 0;
4193                 centerprint_time[i] = 1;
4194                 centerprint_msgID[i] = 0;
4195                 if(centerprint_messages[i])
4196                         strunzone(centerprint_messages[i]);
4197                 centerprint_messages[i] = string_null;
4198         }
4199 }
4200 float hud_configure_cp_generation_time;
4201 void HUD_CenterPrint (void)
4202 {
4203         if(!autocvar__hud_configure)
4204         {
4205                 if(!autocvar_hud_panel_centerprint) return;
4206
4207                 if (hud_configure_prev && hud_configure_prev != -1)
4208                         reset_centerprint_messages();
4209         }
4210         else
4211         {
4212                 if (!hud_configure_prev)
4213                         reset_centerprint_messages();
4214                 if (time > hud_configure_cp_generation_time)
4215                 {
4216                         float r;
4217                         r = random();
4218                         if (r > 0.75)
4219                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4220                         else if (r > 0.5)
4221                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4222                         else
4223                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4224                         hud_configure_cp_generation_time = time + 1 + random()*4;
4225                 }
4226         }
4227
4228         // this panel fades only when the menu does
4229         float hud_fade_alpha_save = 0;
4230         if(scoreboard_fade_alpha)
4231         {
4232                 hud_fade_alpha_save = hud_fade_alpha;
4233                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4234         }
4235         HUD_Panel_UpdateCvars();
4236
4237         if(scoreboard_fade_alpha)
4238         {
4239                 hud_fade_alpha = hud_fade_alpha_save;
4240
4241                 // move the panel below the scoreboard
4242                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4243                         return;
4244                 vector target_pos;
4245
4246                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4247
4248                 if(target_pos.y > panel_pos.y)
4249                 {
4250                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4251                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4252                 }
4253         }
4254
4255         HUD_Panel_DrawBg(1);
4256
4257         if (!centerprint_showing)
4258                 return;
4259
4260         if(panel_bg_padding)
4261         {
4262                 panel_pos += '1 1 0' * panel_bg_padding;
4263                 panel_size -= '2 2 0' * panel_bg_padding;
4264         }
4265
4266         float entries, height;
4267         vector fontsize;
4268         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4269         // height = panel_size_y/entries;
4270         // fontsize = '1 1 0' * height;
4271         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4272         fontsize = '1 1 0' * height;
4273         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4274
4275         float i, j, k, n, g;
4276         float a, sz, align, current_msg_posY = 0, msg_size;
4277         vector pos;
4278         string ts;
4279         float all_messages_expired = true;
4280
4281         pos = panel_pos;
4282         if (autocvar_hud_panel_centerprint_flip)
4283                 pos.y += panel_size.y;
4284         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4285         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4286         {
4287                 if (j == CENTERPRINT_MAX_MSGS)
4288                         j = 0;
4289                 if (centerprint_expire_time[j] <= time)
4290                 {
4291                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4292                         {
4293                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4294                                 if (centerprint_countdown_num[j] == 0)
4295                                         continue;
4296                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4297                         }
4298                         else if(centerprint_time[j] != -1)
4299                                 continue;
4300                 }
4301
4302                 all_messages_expired = false;
4303
4304                 // fade the centerprint_hud in/out
4305                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4306                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4307                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4308                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4309                 else // Expiring soon, so fade it out.
4310                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4311
4312                 // while counting down show it anyway in order to hold the current message position
4313                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4314                         continue;
4315                 if (a > 1)
4316                         a = 1;
4317
4318                 // set the size from fading in/out before subsequent fading
4319                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4320
4321                 // also fade it based on positioning
4322                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4323                 {
4324                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4325                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4326                 }
4327                 a *= panel_fg_alpha;
4328
4329                 // finally set the size based on the new theAlpha from subsequent fading
4330                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4331                 drawfontscale = sz * '1 1 0';
4332
4333                 if (centerprint_countdown_num[j])
4334                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4335                 else
4336                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4337
4338                 if (autocvar_hud_panel_centerprint_flip)
4339                 {
4340                         // check if the message can be entirely shown
4341                         for(k = 0; k < n; ++k)
4342                         {
4343                                 getWrappedLine_remaining = argv(k);
4344                                 while(getWrappedLine_remaining)
4345                                 {
4346                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4347                                         if (ts != "")
4348                                                 pos.y -= fontsize.y;
4349                                         else
4350                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4351                                 }
4352                         }
4353                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4354                 }
4355
4356                 msg_size = pos.y;
4357                 for(k = 0; k < n; ++k)
4358                 {
4359                         getWrappedLine_remaining = argv(k);
4360                         while(getWrappedLine_remaining)
4361                         {
4362                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4363                                 if (ts != "")
4364                                 {
4365                                         if (align)
4366                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4367                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4368                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4369                                         pos.y += fontsize.y;
4370                                 }
4371                                 else
4372                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4373                         }
4374                 }
4375
4376                 ++g; // move next position number up
4377
4378                 msg_size = pos.y - msg_size;
4379                 if (autocvar_hud_panel_centerprint_flip)
4380                 {
4381                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4382                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4383                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4384
4385                         if (pos.y < panel_pos.y) // check if the next message can be shown
4386                         {
4387                                 drawfontscale = '1 1 0';
4388                                 return;
4389                         }
4390                 }
4391                 else
4392                 {
4393                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4394                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4395                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4396
4397                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4398                         {
4399                                 drawfontscale = '1 1 0';
4400                                 return;
4401                         }
4402                 }
4403         }
4404         drawfontscale = '1 1 0';
4405         if (all_messages_expired)
4406         {
4407                 centerprint_showing = false;
4408                 reset_centerprint_messages();
4409         }
4410 }
4411
4412 // Buffs (#17)
4413 //
4414 void HUD_Buffs(void)
4415 {
4416         float buffs = getstati(STAT_BUFFS, 0, 24);
4417         if(!autocvar__hud_configure)
4418         {
4419                 if(!autocvar_hud_panel_buffs) return;
4420                 if(spectatee_status == -1) return;
4421                 if(getstati(STAT_HEALTH) <= 0) return;
4422                 if(!buffs) return;
4423         }
4424         else
4425         {
4426                 buffs = Buff_Type_first.items; // force first buff
4427         }
4428
4429         float b = 0; // counter to tell other functions that we have buffs
4430         entity e;
4431         string s = "";
4432         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4433         {
4434                 ++b;
4435                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4436                 if(s == "")
4437                         s = o;
4438                 else
4439                         s = strcat(s, " ", o);
4440         }
4441
4442         HUD_Panel_UpdateCvars();
4443
4444         draw_beginBoldFont();
4445
4446         vector pos, mySize;
4447         pos = panel_pos;
4448         mySize = panel_size;
4449
4450         HUD_Panel_DrawBg(bound(0, b, 1));
4451         if(panel_bg_padding)
4452         {
4453                 pos += '1 1 0' * panel_bg_padding;
4454                 mySize -= '2 2 0' * panel_bg_padding;
4455         }
4456
4457         //float panel_ar = mySize_x/mySize_y;
4458         //float is_vertical = (panel_ar < 1);
4459         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4460         vector buff_offset = '0 0 0';
4461
4462         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4463         {
4464                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4465                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4466         }
4467
4468         draw_endBoldFont();
4469 }
4470
4471 // QuickMenu (#18)
4472 //
4473 #include "quickmenu.qc"
4474
4475
4476
4477 /*
4478 ==================
4479 Main HUD system
4480 ==================
4481 */
4482
4483 void HUD_Reset (void)
4484 {
4485         // reset gametype specific icons
4486         if(gametype == MAPINFO_TYPE_CTF)
4487                 HUD_Mod_CTF_Reset();
4488 }
4489
4490 void HUD_Main (void)
4491 {
4492         int i;
4493         // global hud theAlpha fade
4494         if(menu_enabled == 1)
4495                 hud_fade_alpha = 1;
4496         else
4497                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4498
4499         if(scoreboard_fade_alpha)
4500                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4501
4502         HUD_Configure_Frame();
4503
4504         if(intermission == 2) // no hud during mapvote
4505                 hud_fade_alpha = 0;
4506
4507         // panels that we want to be active together with the scoreboard
4508         // they must fade only when the menu does
4509         if(scoreboard_fade_alpha == 1)
4510         {
4511                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4512                 return;
4513         }
4514
4515         if(!autocvar__hud_configure && !hud_fade_alpha)
4516                 return;
4517
4518         // Drawing stuff
4519         if (hud_skin_prev != autocvar_hud_skin)
4520         {
4521                 if (hud_skin_path)
4522                         strunzone(hud_skin_path);
4523                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4524                 if (hud_skin_prev)
4525                         strunzone(hud_skin_prev);
4526                 hud_skin_prev = strzone(autocvar_hud_skin);
4527         }
4528
4529     current_player = player_localentnum;
4530
4531         // draw the dock
4532         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4533         {
4534                 float f;
4535                 vector color;
4536                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4537                 if((teamplay) && hud_dock_color_team) {
4538                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4539                                 color = '1 0 0' * hud_dock_color_team;
4540                         else
4541                                 color = myteamcolors * hud_dock_color_team;
4542                 }
4543                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4544                         color = '1 0 0' * hud_dock_color_team;
4545                 }
4546                 else
4547                 {
4548                         string hud_dock_color = autocvar_hud_dock_color;
4549                         if(hud_dock_color == "shirt") {
4550                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4551                                 color = colormapPaletteColor(floor(f / 16), 0);
4552                         }
4553                         else if(hud_dock_color == "pants") {
4554                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4555                                 color = colormapPaletteColor(f % 16, 1);
4556                         }
4557                         else
4558                                 color = stov(hud_dock_color);
4559                 }
4560
4561                 string pic;
4562                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4563                 if(precache_pic(pic) == "") {
4564                         pic = strcat(hud_skin_path, "/dock_medium");
4565                         if(precache_pic(pic) == "") {
4566                                 pic = "gfx/hud/default/dock_medium";
4567                         }
4568                 }
4569                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4570         }
4571
4572         // cache the panel order into the panel_order array
4573         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4574                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4575                         panel_order[i] = -1;
4576                 string s = "";
4577                 float p_num, warning = false;
4578                 float argc = tokenize_console(autocvar__hud_panelorder);
4579                 if (argc > HUD_PANEL_NUM)
4580                         warning = true;
4581                 //first detect wrong/missing panel numbers
4582                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4583                         p_num = stof(argv(i));
4584                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4585                                 if (panel_order[p_num] == -1) //found for the first time?
4586                                         s = strcat(s, ftos(p_num), " ");
4587                                 panel_order[p_num] = 1; //mark as found
4588                         }
4589                         else
4590                                 warning = true;
4591                 }
4592                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4593                         if (panel_order[i] == -1) {
4594                                 warning = true;
4595                                 s = strcat(s, ftos(i), " "); //add missing panel number
4596                         }
4597                 }
4598                 if (warning)
4599                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4600
4601                 cvar_set("_hud_panelorder", s);
4602                 if(hud_panelorder_prev)
4603                         strunzone(hud_panelorder_prev);
4604                 hud_panelorder_prev = strzone(s);
4605
4606                 //now properly set panel_order
4607                 tokenize_console(s);
4608                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4609                         panel_order[i] = stof(argv(i));
4610                 }
4611         }
4612
4613         hud_draw_maximized = 0;
4614         // draw panels in order specified by panel_order array
4615         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4616                 (panel = hud_panel[panel_order[i]]).panel_draw();
4617
4618         hud_draw_maximized = 1; // panels that may be maximized must check this var
4619         // draw maximized panels on top
4620         if(hud_panel_radar_maximized)
4621                 (panel = HUD_PANEL(RADAR)).panel_draw();
4622         if(autocvar__con_chat_maximized)
4623                 (panel = HUD_PANEL(CHAT)).panel_draw();
4624         if(hud_panel_quickmenu)
4625                 (panel = HUD_PANEL(QUICKMENU)).panel_draw();
4626
4627         HUD_Configure_PostDraw();
4628
4629         hud_configure_prev = autocvar__hud_configure;
4630 }