qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float HUD_GetRowCount(float item_count, vector size, float item_aspect)
 136 {
 137         float aspect = size_y/size_x;
 138         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 139 }
 140
 141 float stringwidth_colors(string s, vector theSize)
 142 {
 143         return stringwidth(s, TRUE, theSize);
 144 }
 145
 146 float stringwidth_nocolors(string s, vector theSize)
 147 {
 148         return stringwidth(s, FALSE, theSize);
 149 }
 150
 151 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x -= 2 / 3 * strlen(text) * theScale_x;
 154         drawstring(position, text, theScale, rgb, theAlpha, flag);
 155 }
 156
 157 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 158 {
 159         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale_x);
 160         drawstring(position, text, theScale, rgb, theAlpha, flag);
 161 }
 162
 163 // return the string of the onscreen race timer
 164 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 165 {
 166         string col;
 167         string timestr;
 168         string cpname;
 169         string lapstr;
 170         lapstr = "";
 171
 172         if(histime == 0) // goal hit
 173         {
 174                 if(mytime > 0)
 175                 {
 176                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 177                         col = "^1";
 178                 }
 179                 else if(mytime == 0)
 180                 {
 181                         timestr = "+0.0";
 182                         col = "^3";
 183                 }
 184                 else
 185                 {
 186                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 187                         col = "^2";
 188                 }
 189
 190                 if(lapdelta > 0)
 191                 {
 192                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 193                         col = "^2";
 194                 }
 195                 else if(lapdelta < 0)
 196                 {
 197                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 198                         col = "^1";
 199                 }
 200         }
 201         else if(histime > 0) // anticipation
 202         {
 203                 if(mytime >= histime)
 204                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 205                 else
 206                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 207                 col = "^3";
 208         }
 209         else
 210         {
 211                 col = "^7";
 212                 timestr = "";
 213         }
 214
 215         if(cp == 254)
 216                 cpname = _("Start line");
 217         else if(cp == 255)
 218                 cpname = _("Finish line");
 219         else if(cp)
 220                 cpname = sprintf(_("Intermediate %d"), cp);
 221         else
 222                 cpname = _("Finish line");
 223
 224         if(histime < 0)
 225                 return strcat(col, cpname);
 226         else if(hisname == "")
 227                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 228         else
 229                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(hisname, col, lapstr)));
 230 }
 231
 232 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 233 float race_CheckName(string net_name) {
 234         float i;
 235         for (i=RANKINGS_CNT-1;i>=0;--i)
 236                 if(grecordholder[i] == net_name)
 237                         return i+1;
 238         return 0;
 239 }
 240
 241 float GetPlayerColorForce(float i)
 242 {
 243         if(!teamplay)
 244                 return 0;
 245         else
 246                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 247 }
 248
 249 float GetPlayerColor(float i)
 250 {
 251         if(!playerslots[i].gotscores) // unconnected
 252                 return NUM_SPECTATOR;
 253         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 254                 return NUM_SPECTATOR;
 255         else
 256                 return GetPlayerColorForce(i);
 257 }
 258
 259 string GetPlayerName(float i)
 260 {
 261         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 262 }
 263
 264
 265 /*
 266 ==================
 267 HUD panels
 268 ==================
 269 */
 270
 271 // draw the background/borders
 272 #define HUD_Panel_DrawBg(theAlpha)\
 273 if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")\
 274         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 275
 276 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 277 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 278 {
 279         if(!length_ratio || !theAlpha)
 280                 return;
 281         if(length_ratio > 1)
 282                 length_ratio = 1;
 283         if (baralign == 3)
 284         {
 285                 if(length_ratio < -1)
 286                         length_ratio = -1;
 287         }
 288         else if(length_ratio < 0)
 289                 return;
 290
 291         vector square;
 292         vector width, height;
 293         if(vertical) {
 294                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 295                 if(precache_pic(pic) == "") {
 296                         pic = "gfx/hud/default/progressbar_vertical";
 297                 }
 298
 299         if (baralign == 1) // bottom align
 300                         theOrigin_y += (1 - length_ratio) * theSize_y;
 301         else if (baralign == 2) // center align
 302             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 303         else if (baralign == 3) // center align, positive values down, negative up
 304                 {
 305                         theSize_y *= 0.5;
 306                         if (length_ratio > 0)
 307                                 theOrigin_y += theSize_y;
 308                         else
 309                         {
 310                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 311                                 length_ratio = -length_ratio;
 312                         }
 313                 }
 314                 theSize_y *= length_ratio;
 315
 316                 vector bH;
 317                 width = eX * theSize_x;
 318                 height = eY * theSize_y;
 319                 if(theSize_y <= theSize_x * 2)
 320                 {
 321                         // button not high enough
 322                         // draw just upper and lower part then
 323                         square = eY * theSize_y * 0.5;
 324                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 325                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 327                 }
 328                 else
 329                 {
 330                         square = eY * theSize_x;
 331                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 332                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 333                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 334                 }
 335         } else {
 336                 pic = strcat(hud_skin_path, "/", pic);
 337                 if(precache_pic(pic) == "") {
 338                         pic = "gfx/hud/default/progressbar";
 339                 }
 340
 341                 if (baralign == 1) // right align
 342                         theOrigin_x += (1 - length_ratio) * theSize_x;
 343         else if (baralign == 2) // center align
 344             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 345         else if (baralign == 3) // center align, positive values on the right, negative on the left
 346                 {
 347                         theSize_x *= 0.5;
 348                         if (length_ratio > 0)
 349                                 theOrigin_x += theSize_x;
 350                         else
 351                         {
 352                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 353                                 length_ratio = -length_ratio;
 354                         }
 355                 }
 356                 theSize_x *= length_ratio;
 357
 358                 vector bW;
 359                 width = eX * theSize_x;
 360                 height = eY * theSize_y;
 361                 if(theSize_x <= theSize_y * 2)
 362                 {
 363                         // button not wide enough
 364                         // draw just left and right part then
 365                         square = eX * theSize_x * 0.5;
 366                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 367                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 369                 }
 370                 else
 371                 {
 372                         square = eX * theSize_y;
 373                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 374                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 375                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 376                 }
 377         }
 378 }
 379
 380 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 381 {
 382         if(!theAlpha)
 383                 return;
 384
 385         string pic;
 386         pic = strcat(hud_skin_path, "/num_leading");
 387         if(precache_pic(pic) == "") {
 388                 pic = "gfx/hud/default/num_leading";
 389         }
 390
 391         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 392         if(mySize_x/mySize_y > 2)
 393                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 394         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 395 }
 396
 397 // Weapon icons (#0)
 398 //
 399 entity weaponorder[WEP_MAXCOUNT];
 400 void weaponorder_swap(float i, float j, entity pass)
 401 {
 402         entity h;
 403         h = weaponorder[i];
 404         weaponorder[i] = weaponorder[j];
 405         weaponorder[j] = h;
 406 }
 407
 408 string weaponorder_cmp_str;
 409 float weaponorder_cmp(float i, float j, entity pass)
 410 {
 411         float ai, aj;
 412         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 413         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 414         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 415 }
 416
 417 void HUD_Weapons(void)
 418 {
 419         // declarations
 420         WepSet weapons_stat = WepSet_GetFromStat();
 421         float i, f, a;
 422         float screen_ar, center_x = 0, center_y;
 423         float weapon_count, weapon_id;
 424         float row, column, rows = 0, columns;
 425         float aspect = autocvar_hud_panel_weapons_aspect;
 426
 427         float timeout = autocvar_hud_panel_weapons_timeout;
 428         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 429         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 430
 431         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 432         vector ammo_color = '1 0 1';
 433         float ammo_alpha = 1;
 434
 435         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 436         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 437
 438         vector weapon_pos, weapon_size = '0 0 0';
 439         vector color;
 440
 441         // check to see if we want to continue
 442         if(hud != HUD_NORMAL) { return; }
 443
 444         if(!autocvar__hud_configure)
 445         {
 446                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 447                         return;
 448                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 449                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 450                 {
 451                         weaponprevtime = time;
 452                         return;
 453                 }
 454         }
 455
 456         // update generic hud functions
 457         HUD_Panel_UpdateCvars();
 458
 459         draw_beginBoldFont();
 460
 461         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 462         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 463         {
 464                 float weapon_cnt;
 465                 if(weaponorder_bypriority)
 466                         strunzone(weaponorder_bypriority);
 467                 if(weaponorder_byimpulse)
 468                         strunzone(weaponorder_byimpulse);
 469
 470                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 471                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 472                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 473
 474                 weapon_cnt = 0;
 475                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 476                 {
 477                         self = get_weaponinfo(i);
 478                         if(self.impulse >= 0)
 479                         {
 480                                 weaponorder[weapon_cnt] = self;
 481                                 ++weapon_cnt;
 482                         }
 483                 }
 484                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 485                         weaponorder[i] = world;
 486                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 487
 488                 weaponorder_cmp_str = string_null;
 489         }
 490
 491         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 492                 complain_weapon = 0;
 493
 494         // determine which weapons are going to be shown
 495         if (autocvar_hud_panel_weapons_onlyowned)
 496         {
 497                 if(autocvar__hud_configure)
 498                 {
 499                         if (!weapons_stat)
 500                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 501                                         weapons_stat |= WepSet_FromWeapon(i);
 502
 503                         if(menu_enabled != 2)
 504                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 505                 }
 506
 507                 // do we own this weapon?
 508                 weapon_count = 0;
 509                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 510                         if(weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon))
 511                                 ++weapon_count;
 512
 513                 // add it anyway if weaponcomplain is shown
 514                 if(complain_weapon)
 515                         ++weapon_count;
 516
 517                 // might as well commit suicide now, no reason to live ;)
 518                 if (weapon_count == 0)
 519                 {
 520                         draw_endBoldFont();
 521                         return;
 522                 }
 523
 524                 vector old_panel_size = panel_size;
 525                 if(panel_bg_padding)
 526                         old_panel_size -= '2 2 0' * panel_bg_padding;
 527
 528                 // NOTE: the goal is to use the all-weapons layout and remove unneeded cells
 529                 // this way weapon icons always have the same size regardless of owned weapon count
 530
 531                 // get the all-weapons layout
 532                 rows = HUD_GetRowCount(WEP_COUNT, old_panel_size, aspect);
 533                 columns = ceil(WEP_COUNT/rows);
 534                 weapon_size_x = old_panel_size_x / columns;
 535                 weapon_size_y = old_panel_size_y / rows;
 536
 537                 // reduce rows and columns as needed
 538                 columns = ceil(weapon_count / rows);
 539                 rows = ceil(weapon_count / columns);
 540
 541                 // NOTE: although weapons should aways look the same even if onlyowned is disabled,
 542                 // we enlarge them a bit when possible to better match the desired aspect ratio
 543                 // as they look much better
 544                 weapon_size_x = min(old_panel_size_x / columns, aspect * weapon_size_y);
 545                 weapon_size_y = min(old_panel_size_y / rows, weapon_size_x / aspect);
 546
 547                 // reduce size of the panel
 548                 panel_size_x = columns * weapon_size_x;
 549                 panel_size_y = rows * weapon_size_y;
 550                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 551                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 552                 if(panel_bg_padding)
 553                         panel_size += '2 2 0' * panel_bg_padding;
 554         }
 555         else
 556                 weapon_count = WEP_COUNT;
 557
 558         // animation for fading in/out the panel respectively when not in use
 559         if(!autocvar__hud_configure)
 560         {
 561                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 562                 {
 563                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 564
 565                         // fade the panel alpha
 566                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 567                         {
 568                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 569                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 570                         }
 571                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 572                         {
 573                                 panel_bg_alpha *= (1 - f);
 574                                 panel_fg_alpha *= (1 - f);
 575                         }
 576
 577                         // move the panel off the screen
 578                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 579                         {
 580                                 f *= f; // for a cooler movement
 581                                 center_x = panel_pos_x + panel_size_x/2;
 582                                 center_y = panel_pos_y + panel_size_y/2;
 583                                 screen_ar = vid_conwidth/vid_conheight;
 584                                 if (center_x/center_y < screen_ar) //bottom left
 585                                 {
 586                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 587                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 588                                         else //left
 589                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 590                                 }
 591                                 else //top right
 592                                 {
 593                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 594                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 595                                         else //top
 596                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 597                                 }
 598                                 if(f == 1)
 599                                         center_x = -1; // mark the panel as off screen
 600                         }
 601                         weaponprevtime = time - (1 - f) * timein_effect_length;
 602                 }
 603                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 604                 {
 605                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 606
 607                         // fade the panel alpha
 608                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 609                         {
 610                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 611                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 612                         }
 613                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 614                         {
 615                                 panel_bg_alpha *= (f);
 616                                 panel_fg_alpha *= (f);
 617                         }
 618
 619                         // move the panel back on screen
 620                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 621                         {
 622                                 f *= f; // for a cooler movement
 623                                 f = 1 - f;
 624                                 center_x = panel_pos_x + panel_size_x/2;
 625                                 center_y = panel_pos_y + panel_size_y/2;
 626                                 screen_ar = vid_conwidth/vid_conheight;
 627                                 if (center_x/center_y < screen_ar) //bottom left
 628                                 {
 629                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 630                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 631                                         else //left
 632                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 633                                 }
 634                                 else //top right
 635                                 {
 636                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 637                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 638                                         else //top
 639                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 640                                 }
 641                         }
 642                 }
 643         }
 644
 645         // draw the background, then change the virtual size of it to better fit other items inside
 646         HUD_Panel_DrawBg(1);
 647
 648         if(center_x == -1)
 649         {
 650                 draw_endBoldFont();
 651                 return;
 652         }
 653
 654         if(panel_bg_padding)
 655         {
 656                 panel_pos += '1 1 0' * panel_bg_padding;
 657                 panel_size -= '2 2 0' * panel_bg_padding;
 658         }
 659
 660         // after the sizing and animations are done, update the other values
 661
 662         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 663         {
 664                 rows = HUD_GetRowCount(weapon_count, panel_size, aspect);
 665                 columns = ceil(weapon_count/rows);
 666                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 667         }
 668
 669         // calculate position/size for visual bar displaying ammount of ammo status
 670         if (autocvar_hud_panel_weapons_ammo)
 671         {
 672                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 673                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 674
 675                 if(weapon_size_x/weapon_size_y > aspect)
 676                 {
 677                         barsize_x = aspect * weapon_size_y;
 678                         barsize_y = weapon_size_y;
 679                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 680                 }
 681                 else
 682                 {
 683                         barsize_y = 1/aspect * weapon_size_x;
 684                         barsize_x = weapon_size_x;
 685                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 686                 }
 687         }
 688         if(autocvar_hud_panel_weapons_accuracy)
 689                 Accuracy_LoadColors();
 690
 691         // draw items
 692         row = column = 0;
 693         vector label_size = '1 1 0' * min(weapon_size_x, weapon_size_y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 694         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 695         {
 696                 // retrieve information about the current weapon to be drawn
 697                 self = weaponorder[i];
 698                 weapon_id = self.impulse;
 699
 700                 // skip if this weapon doesn't exist
 701                 if(!self || weapon_id < 0) { continue; }
 702
 703                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 704                 if(autocvar_hud_panel_weapons_onlyowned)
 705                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 706                         continue;
 707
 708                 // figure out the drawing position of weapon
 709                 weapon_pos = (panel_pos
 710                         + eX * column * weapon_size_x
 711                         + eY * row * weapon_size_y);
 712
 713                 // draw background behind currently selected weapon
 714                 if(self.weapon == switchweapon)
 715                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 716
 717                 // draw the weapon accuracy
 718                 if(autocvar_hud_panel_weapons_accuracy)
 719                 {
 720                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 721                         if(panel_weapon_accuracy >= 0)
 722                         {
 723                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 724                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 725                         }
 726                 }
 727
 728                 // drawing all the weapon items
 729                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 730                 {
 731                         // draw the weapon image
 732                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 733
 734                         // draw weapon label string
 735                         switch(autocvar_hud_panel_weapons_label)
 736                         {
 737                                 case 1: // weapon number
 738                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 739                                         break;
 740
 741                                 case 2: // bind
 742                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 743                                         break;
 744
 745                                 case 3: // weapon name
 746                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 747                                         break;
 748
 749                                 default: // nothing
 750                                         break;
 751                         }
 752
 753                         // draw ammo status bar
 754                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 755                         {
 756                                 float ammo_full;
 757                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 758
 759                                 if(a > 0)
 760                                 {
 761                                         switch(self.ammo_field)
 762                                         {
 763                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 764                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 765                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 766                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 767                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 768                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 769                                                 default: ammo_full = 60;
 770                                         }
 771
 772                                         drawsetcliparea(
 773                                                 weapon_pos_x + baroffset_x,
 774                                                 weapon_pos_y + baroffset_y,
 775                                                 barsize_x * bound(0, a/ammo_full, 1),
 776                                                 barsize_y
 777                                         );
 778
 779                                         drawpic_aspect_skin(
 780                                                 weapon_pos,
 781                                                 "weapon_ammo",
 782                                                 weapon_size,
 783                                                 ammo_color,
 784                                                 ammo_alpha,
 785                                                 DRAWFLAG_NORMAL
 786                                         );
 787
 788                                         drawresetcliparea();
 789                                 }
 790                         }
 791                 }
 792                 else // draw a "ghost weapon icon" if you don't have the weapon
 793                 {
 794                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 795                 }
 796
 797                 // draw the complain message
 798                 if(self.weapon == complain_weapon)
 799                 {
 800                         if(fadetime)
 801                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 802                         else
 803                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 804
 805                         string s;
 806                         if(complain_weapon_type == 0) {
 807                                 s = _("Out of ammo");
 808                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 809                         }
 810                         else if(complain_weapon_type == 1) {
 811                                 s = _("Don't have");
 812                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 813                         }
 814                         else {
 815                                 s = _("Unavailable");
 816                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 817                         }
 818                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 819                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 820                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 821                 }
 822
 823                 // continue with new position for the next weapon
 824                 ++row;
 825                 if(row >= rows)
 826                 {
 827                         row = 0;
 828                         ++column;
 829                 }
 830         }
 831
 832         draw_endBoldFont();
 833 }
 834
 835 // Ammo (#1)
 836 void DrawNadeScoreBar(vector myPos, vector mySize, vector color)
 837 {
 838
 839         HUD_Panel_DrawProgressBar(
 840                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x,
 841                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x,
 842                 autocvar_hud_panel_ammo_progressbar_name,
 843                 getstatf(STAT_NADE_BONUS_SCORE), 0, 0, color,
 844                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 845
 846 }
 847
 848 void DrawAmmoNades(vector myPos, vector mySize, float draw_expanding, float expand_time)
 849 {
 850         float theAlpha = 1, a, b;
 851         vector nade_color, picpos, numpos;
 852
 853         nade_color = Nade_Color(getstati(STAT_NADE_BONUS_TYPE));
 854
 855         a = getstatf(STAT_NADE_BONUS);
 856         b = getstatf(STAT_NADE_BONUS_SCORE);
 857
 858         if(autocvar_hud_panel_ammo_iconalign)
 859         {
 860                 numpos = myPos;
 861                 picpos = myPos + eX * 2 * mySize_y;
 862         }
 863         else
 864         {
 865                 numpos = myPos + eX * mySize_y;
 866                 picpos = myPos;
 867         }
 868
 869         DrawNadeScoreBar(myPos, mySize, nade_color);
 870
 871         if(b > 0 || a > 0)
 872         {
 873                 if(autocvar_hud_panel_ammo_text)
 874                         drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 875
 876                 if(draw_expanding)
 877                         drawpic_aspect_skin_expanding(picpos, "nade_nbg", '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, expand_time);
 878
 879                 drawpic_aspect_skin(picpos, "nade_bg" , '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 880                 drawpic_aspect_skin(picpos, "nade_nbg" , '1 1 0' * mySize_y, nade_color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 881         }
 882 }
 883
 884 void DrawAmmoItem(vector myPos, vector mySize, .float ammoType, float isCurrent, float isInfinite)
 885 {
 886         if(ammoType == ammo_none)
 887                 return;
 888
 889         // Initialize variables
 890
 891         float ammo;
 892         if(autocvar__hud_configure)
 893         {
 894                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
 895                 ammo = 60;
 896         }
 897         else
 898                 ammo = getstati(GetAmmoStat(ammoType));
 899
 900         if(!isCurrent)
 901         {
 902                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
 903                 myPos = myPos + (mySize - mySize * scale) * 0.5;
 904                 mySize = mySize * scale;
 905         }
 906
 907         vector iconPos, textPos;
 908         if(autocvar_hud_panel_ammo_iconalign)
 909         {
 910                 iconPos = myPos + eX * 2 * mySize_y;
 911                 textPos = myPos;
 912         }
 913         else
 914         {
 915                 iconPos = myPos;
 916                 textPos = myPos + eX * mySize_y;
 917         }
 918
 919         float isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
 920
 921         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
 922         vector textColor;
 923         if(isInfinite)
 924                 textColor = '0.2 0.95 0';
 925         else if(isShadowed)
 926                 textColor = '0 0 0';
 927         else if(ammo < 10)
 928                 textColor = '0.8 0.04 0';
 929         else
 930                 textColor = '1 1 1';
 931
 932         float alpha;
 933         if(isCurrent)
 934                 alpha = panel_fg_alpha;
 935         else if(isShadowed)
 936                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
 937         else
 938                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
 939
 940         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
 941
 942         // Draw item
 943
 944         if(isCurrent)
 945                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 946
 947         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
 948                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
 949
 950         if(autocvar_hud_panel_ammo_text)
 951                 drawstring_aspect(textPos, text, eX * (2/3) * mySize_x + eY * mySize_y, textColor, alpha, DRAWFLAG_NORMAL);
 952
 953         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize_y, iconColor, alpha, DRAWFLAG_NORMAL);
 954 }
 955
 956 float nade_prevstatus;
 957 float nade_prevframe;
 958 float nade_statuschange_time;
 959 void HUD_Ammo(void)
 960 {
 961         if(hud != HUD_NORMAL) return;
 962         if(!autocvar__hud_configure)
 963         {
 964                 if(!autocvar_hud_panel_ammo) return;
 965                 if(spectatee_status == -1) return;
 966         }
 967
 968         HUD_Panel_UpdateCvars();
 969
 970         draw_beginBoldFont();
 971
 972         vector pos, mySize;
 973         pos = panel_pos;
 974         mySize = panel_size;
 975
 976         HUD_Panel_DrawBg(1);
 977         if(panel_bg_padding)
 978         {
 979                 pos += '1 1 0' * panel_bg_padding;
 980                 mySize -= '2 2 0' * panel_bg_padding;
 981         }
 982
 983         float rows = 0, columns, row, column;
 984         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
 985         float draw_nades = (nade_cnt > 0 || nade_score > 0), nade_statuschange_elapsedtime;
 986         float total_ammo_count;
 987
 988         vector ammo_size;
 989         if (autocvar_hud_panel_ammo_onlycurrent)
 990                 total_ammo_count = 1;
 991         else
 992                 total_ammo_count = AMMO_COUNT;
 993
 994         if(draw_nades)
 995         {
 996                 ++total_ammo_count;
 997                 if (nade_cnt != nade_prevframe)
 998                 {
 999                         nade_statuschange_time = time;
1000                         nade_prevstatus = nade_prevframe;
1001                         nade_prevframe = nade_cnt;
1002                 }
1003         }
1004         else
1005                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1006
1007         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1008         columns = ceil((total_ammo_count)/rows);
1009         ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
1010
1011         local vector offset = '0 0 0'; // fteqcc sucks
1012         float newSize;
1013         if(ammo_size_x/ammo_size_y > 3)
1014         {
1015                 newSize = 3 * ammo_size_y;
1016                 offset_x = ammo_size_x - newSize;
1017                 pos_x += offset_x/2;
1018                 ammo_size_x = newSize;
1019         }
1020         else
1021         {
1022                 newSize = 1/3 * ammo_size_x;
1023                 offset_y = ammo_size_y - newSize;
1024                 pos_y += offset_y/2;
1025                 ammo_size_y = newSize;
1026         }
1027
1028         float i;
1029         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1030         row = column = 0;
1031         if(autocvar_hud_panel_ammo_onlycurrent)
1032         {
1033                 if(autocvar__hud_configure)
1034                 {
1035                         DrawAmmoItem(pos, ammo_size, ammo_rockets, TRUE, FALSE);
1036                 }
1037                 else
1038                 {
1039                         DrawAmmoItem(
1040                                 pos,
1041                                 ammo_size,
1042                                 (get_weaponinfo(switchweapon)).ammo_field,
1043                                 TRUE,
1044                                 infinite_ammo
1045                         );
1046                 }
1047
1048                 ++row;
1049                 if(row >= rows)
1050                 {
1051                         row = 0;
1052                         column = column + 1;
1053                 }
1054         }
1055         else
1056         {
1057                 .float ammotype;
1058                 row = column = 0;
1059                 for(i = 0; i < AMMO_COUNT; ++i)
1060                 {
1061                         ammotype = GetAmmoFieldFromNum(i);
1062                         DrawAmmoItem(
1063                                 pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y),
1064                                 ammo_size,
1065                                 ammotype,
1066                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1067                                 infinite_ammo
1068                         );
1069
1070                         ++row;
1071                         if(row >= rows)
1072                         {
1073                                 row = 0;
1074                                 column = column + 1;
1075                         }
1076                 }
1077         }
1078
1079         if (draw_nades)
1080         {
1081                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1082
1083                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1084
1085                 DrawAmmoNades(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1086         }
1087
1088         draw_endBoldFont();
1089 }
1090
1091 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1092 {
1093         vector newPos = '0 0 0', newSize = '0 0 0';
1094         vector picpos, numpos;
1095
1096         if (vertical)
1097         {
1098                 if(mySize_y/mySize_x > 2)
1099                 {
1100                         newSize_y = 2 * mySize_x;
1101                         newSize_x = mySize_x;
1102
1103                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1104                         newPos_x = myPos_x;
1105                 }
1106                 else
1107                 {
1108                         newSize_x = 1/2 * mySize_y;
1109                         newSize_y = mySize_y;
1110
1111                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1112                         newPos_y = myPos_y;
1113                 }
1114
1115                 if(icon_right_align)
1116                 {
1117                         numpos = newPos;
1118                         picpos = newPos + eY * newSize_x;
1119                 }
1120                 else
1121                 {
1122                         picpos = newPos;
1123                         numpos = newPos + eY * newSize_x;
1124                 }
1125
1126                 newSize_y /= 2;
1127                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1128                 // make number smaller than icon, it looks better
1129                 // reduce only y to draw numbers with different number of digits with the same y size
1130                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1131                 newSize_y *= 0.7;
1132                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1133                 return;
1134         }
1135
1136         if(mySize_x/mySize_y > 3)
1137         {
1138                 newSize_x = 3 * mySize_y;
1139                 newSize_y = mySize_y;
1140
1141                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1142                 newPos_y = myPos_y;
1143         }
1144         else
1145         {
1146                 newSize_y = 1/3 * mySize_x;
1147                 newSize_x = mySize_x;
1148
1149                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1150                 newPos_x = myPos_x;
1151         }
1152
1153         if(icon_right_align) // right align
1154         {
1155                 numpos = newPos;
1156                 picpos = newPos + eX * 2 * newSize_y;
1157         }
1158         else // left align
1159         {
1160                 numpos = newPos + eX * newSize_y;
1161                 picpos = newPos;
1162         }
1163
1164         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1165         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1166         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1167         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1168 }
1169
1170 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1171 {
1172         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1173 }
1174
1175 // Powerups (#2)
1176 //
1177 void HUD_Powerups(void)
1178 {
1179         float strength_time, shield_time, superweapons_time;
1180         if(!autocvar__hud_configure)
1181         {
1182                 if(!autocvar_hud_panel_powerups) return;
1183                 if(spectatee_status == -1) return;
1184                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1185                 if (getstati(STAT_HEALTH) <= 0) return;
1186
1187                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1188                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1189                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1190
1191                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1192                         superweapons_time = 99; // force max
1193
1194                 // prevent stuff to show up on mismatch that will be fixed next frame
1195                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1196                         superweapons_time = 0;
1197         }
1198         else
1199         {
1200                 strength_time = 15;
1201                 shield_time = 27;
1202                 superweapons_time = 13;
1203         }
1204
1205         HUD_Panel_UpdateCvars();
1206
1207         draw_beginBoldFont();
1208
1209         vector pos, mySize;
1210         pos = panel_pos;
1211         mySize = panel_size;
1212
1213         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1214         if(panel_bg_padding)
1215         {
1216                 pos += '1 1 0' * panel_bg_padding;
1217                 mySize -= '2 2 0' * panel_bg_padding;
1218         }
1219
1220         float panel_ar = mySize_x/mySize_y;
1221         float is_vertical = (panel_ar < 1);
1222         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1223
1224         float superweapons_is = -1;
1225
1226         if(superweapons_time)
1227         {
1228                 if(strength_time)
1229                 {
1230                         if(shield_time)
1231                                 superweapons_is = 0;
1232                         else
1233                                 superweapons_is = 2;
1234                 }
1235                 else
1236                 {
1237                         if(shield_time)
1238                                 superweapons_is = 1;
1239                         else
1240                                 superweapons_is = 2;
1241                 }
1242         }
1243
1244         // FIXME handle superweapons here
1245         if(superweapons_is == 0)
1246         {
1247                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1248                 {
1249                         mySize_x *= (1.0 / 3.0);
1250                         superweapons_offset_x = mySize_x;
1251                         if (autocvar_hud_panel_powerups_flip)
1252                                 shield_offset_x = 2*mySize_x;
1253                         else
1254                                 strength_offset_x = 2*mySize_x;
1255                 }
1256                 else
1257                 {
1258                         mySize_y *= (1.0 / 3.0);
1259                         superweapons_offset_y = mySize_y;
1260                         if (autocvar_hud_panel_powerups_flip)
1261                                 shield_offset_y = 2*mySize_y;
1262                         else
1263                                 strength_offset_y = 2*mySize_y;
1264                 }
1265         }
1266         else
1267         {
1268                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1269                 {
1270                         mySize_x *= 0.5;
1271                         if (autocvar_hud_panel_powerups_flip)
1272                                 shield_offset_x = mySize_x;
1273                         else
1274                                 strength_offset_x = mySize_x;
1275                 }
1276                 else
1277                 {
1278                         mySize_y *= 0.5;
1279                         if (autocvar_hud_panel_powerups_flip)
1280                                 shield_offset_y = mySize_y;
1281                         else
1282                                 strength_offset_y = mySize_y;
1283                 }
1284         }
1285
1286         float shield_baralign, strength_baralign, superweapons_baralign;
1287         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1288
1289         if (autocvar_hud_panel_powerups_flip)
1290         {
1291                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1292                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1293                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1294                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1295         }
1296         else
1297         {
1298                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1299                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1300                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1301                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1302         }
1303
1304         if(superweapons_is == 0)
1305         {
1306                 superweapons_iconalign = strength_iconalign;
1307                 superweapons_baralign = 2;
1308         }
1309         else if(superweapons_is == 1)
1310         {
1311                 superweapons_offset = strength_offset;
1312                 superweapons_iconalign = strength_iconalign;
1313                 superweapons_baralign = strength_baralign;
1314         }
1315         else // if(superweapons_is == 2)
1316         {
1317                 superweapons_offset = shield_offset;
1318                 superweapons_iconalign = shield_iconalign;
1319                 superweapons_baralign = shield_baralign;
1320         }
1321
1322         if(shield_time)
1323         {
1324                 const float maxshield = 30;
1325                 float shield = ceil(shield_time);
1326                 if(autocvar_hud_panel_powerups_progressbar)
1327                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1328                 if(autocvar_hud_panel_powerups_text)
1329                 {
1330                         if(shield > 1)
1331                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1332                         if(shield <= 5)
1333                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1334                 }
1335         }
1336
1337         if(strength_time)
1338         {
1339                 const float maxstrength = 30;
1340                 float strength = ceil(strength_time);
1341                 if(autocvar_hud_panel_powerups_progressbar)
1342                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1343                 if(autocvar_hud_panel_powerups_text)
1344                 {
1345                         if(strength > 1)
1346                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1347                         if(strength <= 5)
1348                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1349                 }
1350         }
1351
1352         if(superweapons_time)
1353         {
1354                 const float maxsuperweapons = 30;
1355                 float superweapons = ceil(superweapons_time);
1356                 if(autocvar_hud_panel_powerups_progressbar)
1357                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1358                 if(autocvar_hud_panel_powerups_text)
1359                 {
1360                         if(superweapons > 1)
1361                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1362                         if(superweapons <= 5)
1363                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1364                 }
1365         }
1366
1367         draw_endBoldFont();
1368 }
1369
1370 // Health/armor (#3)
1371 //
1372
1373 // prev_* vars contain the health/armor at the previous FRAME
1374 // set to -1 when player is dead or was not playing
1375 float prev_health, prev_armor;
1376 float health_damagetime, armor_damagetime;
1377 float health_beforedamage, armor_beforedamage;
1378 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1379 float old_p_health, old_p_armor;
1380 float old_p_healthtime, old_p_armortime;
1381 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1382 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1383 float prev_p_health, prev_p_armor;
1384
1385 void HUD_HealthArmor(void)
1386 {
1387         float armor, health, fuel;
1388         if(!autocvar__hud_configure)
1389         {
1390                 if(!autocvar_hud_panel_healtharmor) return;
1391                 if(hud != HUD_NORMAL) return;
1392                 if(spectatee_status == -1) return;
1393
1394                 health = getstati(STAT_HEALTH);
1395                 if(health <= 0)
1396                 {
1397                         prev_health = -1;
1398                         return;
1399                 }
1400                 armor = getstati(STAT_ARMOR);
1401
1402                 // code to check for spectatee_status changes is in Ent_ClientData()
1403                 // prev_p_health and prev_health can be set to -1 there
1404
1405                 if (prev_p_health == -1)
1406                 {
1407                         // no effect
1408                         health_beforedamage = 0;
1409                         armor_beforedamage = 0;
1410                         health_damagetime = 0;
1411                         armor_damagetime = 0;
1412                         prev_health = health;
1413                         prev_armor = armor;
1414                         old_p_health = health;
1415                         old_p_armor = armor;
1416                         prev_p_health = health;
1417                         prev_p_armor = armor;
1418                 }
1419                 else if (prev_health == -1)
1420                 {
1421                         //start the load effect
1422                         health_damagetime = 0;
1423                         armor_damagetime = 0;
1424                         prev_health = 0;
1425                         prev_armor = 0;
1426                 }
1427                 fuel = getstati(STAT_FUEL);
1428         }
1429         else
1430         {
1431                 health = 150;
1432                 armor = 75;
1433                 fuel = 20;
1434         }
1435
1436         HUD_Panel_UpdateCvars();
1437         vector pos, mySize;
1438         pos = panel_pos;
1439         mySize = panel_size;
1440
1441         HUD_Panel_DrawBg(1);
1442         if(panel_bg_padding)
1443         {
1444                 pos += '1 1 0' * panel_bg_padding;
1445                 mySize -= '2 2 0' * panel_bg_padding;
1446         }
1447
1448         float baralign = autocvar_hud_panel_healtharmor_baralign;
1449         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1450
1451     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1452     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1453         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1454         {
1455                 vector v;
1456                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1457
1458                 float x;
1459                 x = floor(v_x + 1);
1460
1461         float maxtotal = maxhealth + maxarmor;
1462                 string biggercount;
1463                 if(v_z) // NOT fully armored
1464                 {
1465                         biggercount = "health";
1466                         if(autocvar_hud_panel_healtharmor_progressbar)
1467                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1468                         if(armor)
1469             if(autocvar_hud_panel_healtharmor_text)
1470                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1471                 }
1472                 else
1473                 {
1474                         biggercount = "armor";
1475                         if(autocvar_hud_panel_healtharmor_progressbar)
1476                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1477                         if(health)
1478             if(autocvar_hud_panel_healtharmor_text)
1479                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1480                 }
1481         if(autocvar_hud_panel_healtharmor_text)
1482                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1483
1484                 if(fuel)
1485                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1486         }
1487         else
1488         {
1489                 float panel_ar = mySize_x/mySize_y;
1490                 float is_vertical = (panel_ar < 1);
1491                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1492                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1493                 {
1494                         mySize_x *= 0.5;
1495                         if (autocvar_hud_panel_healtharmor_flip)
1496                                 health_offset_x = mySize_x;
1497                         else
1498                                 armor_offset_x = mySize_x;
1499                 }
1500                 else
1501                 {
1502                         mySize_y *= 0.5;
1503                         if (autocvar_hud_panel_healtharmor_flip)
1504                                 health_offset_y = mySize_y;
1505                         else
1506                                 armor_offset_y = mySize_y;
1507                 }
1508
1509                 float health_baralign, armor_baralign, fuel_baralign;
1510                 float health_iconalign, armor_iconalign;
1511                 if (autocvar_hud_panel_healtharmor_flip)
1512                 {
1513                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1514                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1515                         fuel_baralign = health_baralign;
1516                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1517                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1518                 }
1519                 else
1520                 {
1521                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1522                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1523                         fuel_baralign = armor_baralign;
1524                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1525                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1526                 }
1527
1528                 //if(health)
1529                 {
1530                         if(autocvar_hud_panel_healtharmor_progressbar)
1531                         {
1532                                 float p_health, pain_health_alpha;
1533                                 p_health = health;
1534                                 pain_health_alpha = 1;
1535                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1536                                 {
1537                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1538                                         {
1539                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1540                                                 {
1541                                                         if (time - old_p_healthtime < 1)
1542                                                                 old_p_health = prev_p_health;
1543                                                         else
1544                                                                 old_p_health = prev_health;
1545                                                         old_p_healthtime = time;
1546                                                 }
1547                                                 if (time - old_p_healthtime < 1)
1548                                                 {
1549                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1550                                                         prev_p_health = p_health;
1551                                                 }
1552                                         }
1553                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1554                                         {
1555                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1556                                                 {
1557                                                         if (time - health_damagetime >= 1)
1558                                                                 health_beforedamage = prev_health;
1559                                                         health_damagetime = time;
1560                                                 }
1561                                                 if (time - health_damagetime < 1)
1562                                                 {
1563                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1564                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1565                                                 }
1566                                         }
1567                                         prev_health = health;
1568
1569                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1570                                         {
1571                                                 float BLINK_FACTOR = 0.15;
1572                                                 float BLINK_BASE = 0.85;
1573                                                 float BLINK_FREQ = 9;
1574                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1575                                         }
1576                                 }
1577                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1578                         }
1579                         if(autocvar_hud_panel_healtharmor_text)
1580                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1581                 }
1582
1583                 if(armor)
1584                 {
1585                         if(autocvar_hud_panel_healtharmor_progressbar)
1586                         {
1587                                 float p_armor;
1588                                 p_armor = armor;
1589                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1590                                 {
1591                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1592                                         {
1593                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1594                                                 {
1595                                                         if (time - old_p_armortime < 1)
1596                                                                 old_p_armor = prev_p_armor;
1597                                                         else
1598                                                                 old_p_armor = prev_armor;
1599                                                         old_p_armortime = time;
1600                                                 }
1601                                                 if (time - old_p_armortime < 1)
1602                                                 {
1603                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1604                                                         prev_p_armor = p_armor;
1605                                                 }
1606                                         }
1607                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1608                                         {
1609                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1610                                                 {
1611                                                         if (time - armor_damagetime >= 1)
1612                                                                 armor_beforedamage = prev_armor;
1613                                                         armor_damagetime = time;
1614                                                 }
1615                                                 if (time - armor_damagetime < 1)
1616                                                 {
1617                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1618                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1619                                                 }
1620                                         }
1621                                         prev_armor = armor;
1622                                 }
1623                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1624                         }
1625                         if(autocvar_hud_panel_healtharmor_text)
1626                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1627                 }
1628
1629                 if(fuel)
1630                 {
1631                         if (is_vertical)
1632                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1633                         else
1634                                 mySize_y *= 0.2;
1635                         if (panel_ar >= 4)
1636                                 mySize_x *= 2; //restore full panel size
1637                         else if (panel_ar < 1/4)
1638                                 mySize_y *= 2; //restore full panel size
1639                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1640                 }
1641         }
1642 }
1643
1644 // Notification area (#4)
1645 //
1646
1647 void HUD_Notify_Push(string icon, string attacker, string victim)
1648 {
1649         if (icon == "")
1650                 return;
1651
1652         ++notify_count;
1653         --notify_index;
1654
1655         if (notify_index == -1)
1656                 notify_index = NOTIFY_MAX_ENTRIES-1;
1657
1658         // Free old strings
1659         if (notify_attackers[notify_index])
1660                 strunzone(notify_attackers[notify_index]);
1661
1662         if (notify_victims[notify_index])
1663                 strunzone(notify_victims[notify_index]);
1664
1665         if (notify_icons[notify_index])
1666                 strunzone(notify_icons[notify_index]);
1667
1668         // Allocate new strings
1669         if (victim != "")
1670         {
1671                 notify_attackers[notify_index] = strzone(attacker);
1672                 notify_victims[notify_index] = strzone(victim);
1673         }
1674         else
1675         {
1676                 // In case of a notification without a victim, the attacker
1677                 // is displayed on the victim's side. Instead of special
1678                 // treatment later on, we can simply switch them here.
1679                 notify_attackers[notify_index] = string_null;
1680                 notify_victims[notify_index] = strzone(attacker);
1681         }
1682
1683         notify_icons[notify_index] = strzone(icon);
1684         notify_times[notify_index] = time;
1685 }
1686
1687 void HUD_Notify(void)
1688 {
1689         if (!autocvar__hud_configure)
1690                 if (!autocvar_hud_panel_notify)
1691                         return;
1692
1693         HUD_Panel_UpdateCvars();
1694         HUD_Panel_DrawBg(1);
1695
1696         if (!autocvar__hud_configure)
1697                 if (notify_count == 0)
1698                         return;
1699
1700         vector pos, size;
1701         pos  = panel_pos;
1702         size = panel_size;
1703
1704         if (panel_bg_padding)
1705         {
1706                 pos  += '1 1 0' * panel_bg_padding;
1707                 size -= '2 2 0' * panel_bg_padding;
1708         }
1709
1710         float fade_start = max(0, autocvar_hud_panel_notify_time);
1711         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1712         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1713
1714         float entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size_y / size_x), NOTIFY_MAX_ENTRIES);
1715         float entry_height = size_y / entry_count;
1716
1717         float panel_width_half = size_x * 0.5;
1718         float icon_width_half = entry_height * icon_aspect / 2;
1719         float name_maxwidth = panel_width_half - icon_width_half - size_x * NOTIFY_ICON_MARGIN;
1720
1721         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1722         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1723         vector icon_left = eX * (panel_width_half - icon_width_half);
1724         vector attacker_right = eX * name_maxwidth;
1725         vector victim_left = eX * (size_x - name_maxwidth);
1726
1727         vector attacker_pos, victim_pos, icon_pos;
1728         string attacker, victim, icon;
1729         float i, j, count, step, limit, alpha;
1730
1731         if (autocvar_hud_panel_notify_flip)
1732         {
1733                 // Order items from the top down
1734                 i = 0;
1735                 step = +1;
1736                 limit = entry_count;
1737         }
1738         else
1739         {
1740                 // Order items from the bottom up
1741                 i = entry_count - 1;
1742                 step = -1;
1743                 limit = -1;
1744         }
1745
1746         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1747         {
1748                 if(autocvar__hud_configure)
1749                 {
1750                         attacker = sprintf(_("Player %d"), count + 1);
1751                         victim = sprintf(_("Player %d"), count + 2);
1752                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1753                         alpha = bound(0, 1.2 - count / entry_count, 1);
1754                 }
1755                 else
1756                 {
1757                         if (j == NOTIFY_MAX_ENTRIES)
1758                                 j = 0;
1759
1760                         if (notify_times[j] + fade_start > time)
1761                                 alpha = 1;
1762                         else if (fade_time != 0)
1763                         {
1764                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1765                                 if (alpha == 0)
1766                                         break;
1767                         }
1768                         else
1769                                 break;
1770
1771                         attacker = notify_attackers[j];
1772                         victim = notify_victims[j];
1773                         icon = notify_icons[j];
1774                 }
1775
1776                 if (icon != "" && victim != "")
1777                 {
1778                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size_y));
1779
1780                         icon_pos = pos + icon_left + eY * i * entry_height;
1781                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1782
1783                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1784                         victim_pos = pos + victim_left + name_top;
1785                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1786
1787                         if (attacker != "")
1788                         {
1789                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1790                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, TRUE, font_size) + name_top;
1791                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1792                         }
1793                 }
1794         }
1795
1796         notify_count = count;
1797 }
1798
1799 // Timer (#5)
1800 //
1801 // TODO: macro
1802 string seconds_tostring(float sec)
1803 {
1804         float minutes;
1805         minutes = floor(sec / 60);
1806
1807         sec -= minutes * 60;
1808         return sprintf("%d:%02d", minutes, sec);
1809 }
1810
1811 void HUD_Timer(void)
1812 {
1813         if(!autocvar__hud_configure)
1814         {
1815                 if(!autocvar_hud_panel_timer) return;
1816         }
1817
1818         HUD_Panel_UpdateCvars();
1819
1820         draw_beginBoldFont();
1821
1822         vector pos, mySize;
1823         pos = panel_pos;
1824         mySize = panel_size;
1825
1826         HUD_Panel_DrawBg(1);
1827         if(panel_bg_padding)
1828         {
1829                 pos += '1 1 0' * panel_bg_padding;
1830                 mySize -= '2 2 0' * panel_bg_padding;
1831         }
1832
1833         string timer;
1834         float timelimit, elapsedTime, timeleft, minutesLeft;
1835
1836         timelimit = getstatf(STAT_TIMELIMIT);
1837
1838         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1839         timeleft = ceil(timeleft);
1840
1841         minutesLeft = floor(timeleft / 60);
1842
1843         vector timer_color;
1844         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1845                 timer_color = '1 1 1'; //white
1846         else if(minutesLeft >= 1)
1847                 timer_color = '1 1 0'; //yellow
1848         else
1849                 timer_color = '1 0 0'; //red
1850
1851         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1852                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1853                         //while restart is still active, show 00:00
1854                         timer = seconds_tostring(0);
1855                 } else {
1856                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1857                         timer = seconds_tostring(elapsedTime);
1858                 }
1859         } else {
1860                 timer = seconds_tostring(timeleft);
1861         }
1862
1863         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1864
1865         draw_endBoldFont();
1866 }
1867
1868 // Radar (#6)
1869 //
1870 void HUD_Radar(void)
1871 {
1872         if (!autocvar__hud_configure)
1873         {
1874                 if (hud_panel_radar_maximized)
1875                 {
1876                         if (!hud_draw_maximized) return;
1877                 }
1878                 else
1879                 {
1880                         if (autocvar_hud_panel_radar == 0) return;
1881                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1882                         if(radar_panel_modified)
1883                         {
1884                                 panel.update_time = time; // forces reload of panel attributes
1885                                 radar_panel_modified = false;
1886                         }
1887                 }
1888         }
1889
1890         HUD_Panel_UpdateCvars();
1891
1892         float f = 0;
1893
1894         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1895         {
1896                 panel_size = autocvar_hud_panel_radar_maximized_size;
1897                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1898                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1899                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1900                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1901
1902                 string panel_bg;
1903                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1904                 if(precache_pic(panel_bg) == "")
1905                         panel_bg = "gfx/hud/default/border_default"; // fallback
1906                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
1907                         radar_panel_modified = true;
1908                 if(panel.current_panel_bg)
1909                         strunzone(panel.current_panel_bg);
1910                 panel.current_panel_bg = strzone(panel_bg);
1911
1912                 switch(hud_panel_radar_maximized_zoommode)
1913                 {
1914                         default:
1915                         case 0:
1916                                 f = current_zoomfraction;
1917                                 break;
1918                         case 1:
1919                                 f = 1 - current_zoomfraction;
1920                                 break;
1921                         case 2:
1922                                 f = 0;
1923                                 break;
1924                         case 3:
1925                                 f = 1;
1926                                 break;
1927                 }
1928
1929                 switch(hud_panel_radar_maximized_rotation)
1930                 {
1931                         case 0:
1932                                 teamradar_angle = view_angles_y - 90;
1933                                 break;
1934                         default:
1935                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1936                                 break;
1937                 }
1938         }
1939         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1940         {
1941                 switch(hud_panel_radar_zoommode)
1942                 {
1943                         default:
1944                         case 0:
1945                                 f = current_zoomfraction;
1946                                 break;
1947                         case 1:
1948                                 f = 1 - current_zoomfraction;
1949                                 break;
1950                         case 2:
1951                                 f = 0;
1952                                 break;
1953                         case 3:
1954                                 f = 1;
1955                                 break;
1956                 }
1957
1958                 switch(hud_panel_radar_rotation)
1959                 {
1960                         case 0:
1961                                 teamradar_angle = view_angles_y - 90;
1962                                 break;
1963                         default:
1964                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1965                                 break;
1966                 }
1967         }
1968
1969         vector pos, mySize;
1970         pos = panel_pos;
1971         mySize = panel_size;
1972
1973         HUD_Panel_DrawBg(1);
1974         if(panel_bg_padding)
1975         {
1976                 pos += '1 1 0' * panel_bg_padding;
1977                 mySize -= '2 2 0' * panel_bg_padding;
1978         }
1979
1980         float color2;
1981         entity tm;
1982         float scale2d, normalsize, bigsize;
1983
1984         teamradar_origin2d = pos + 0.5 * mySize;
1985         teamradar_size2d = mySize;
1986
1987         if(minimapname == "")
1988                 return;
1989
1990         teamradar_loadcvars();
1991
1992         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1993         teamradar_size2d = mySize;
1994
1995         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1996
1997         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1998         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1999         {
2000                 // max-min distance must fit the radar in any rotation
2001                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2002         }
2003         else
2004         {
2005                 vector c0, c1, c2, c3, span;
2006                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2007                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2008                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
2009                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
2010                 span = '0 0 0';
2011                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2012                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2013
2014                 // max-min distance must fit the radar in x=x, y=y
2015                 bigsize = min(
2016                         teamradar_size2d_x * scale2d / (1.05 * span_x),
2017                         teamradar_size2d_y * scale2d / (1.05 * span_y)
2018                 );
2019         }
2020
2021         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2022         if(bigsize > normalsize)
2023                 normalsize = bigsize;
2024
2025         teamradar_size =
2026                   f * bigsize
2027                 + (1 - f) * normalsize;
2028         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2029                   f * mi_center
2030                 + (1 - f) * view_origin);
2031
2032         drawsetcliparea(
2033                 pos_x,
2034                 pos_y,
2035                 mySize_x,
2036                 mySize_y
2037         );
2038
2039         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2040
2041         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2042                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2043         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2044                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2045         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2046         {
2047                 color2 = GetPlayerColor(tm.sv_entnum);
2048                 //if(color == NUM_SPECTATOR || color == color2)
2049                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2050         }
2051         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2052
2053         drawresetcliparea();
2054 }
2055
2056 // Score (#7)
2057 //
2058 void HUD_UpdatePlayerTeams();
2059 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2060 {
2061         float score;
2062         entity tm = world, pl;
2063 #define SCOREPANEL_MAX_ENTRIES 6
2064 #define SCOREPANEL_ASPECTRATIO 2
2065         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2066         vector fontsize = '1 1 0' * (mySize_y/entries);
2067
2068         vector rgb, score_color;
2069         rgb = '1 1 1';
2070         score_color = '1 1 1';
2071
2072         float name_size = mySize_x*0.75;
2073         float spacing_size = mySize_x*0.04;
2074         const float highlight_alpha = 0.2;
2075         float i = 0, me_printed = 0, first_pl = 0;
2076         string s;
2077         if (autocvar__hud_configure)
2078         {
2079                 float players_per_team = 0;
2080                 if (team_count)
2081                 {
2082                         // show team scores in the first line
2083                         float score_size = mySize_x / team_count;
2084                         players_per_team = max(2, ceil((entries - 1) / team_count));
2085                         for(i=0; i<team_count; ++i) {
2086                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2087                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2088                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2089                         }
2090                         first_pl = 1;
2091                         pos_y += fontsize_y;
2092                 }
2093                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2094                 for (i=first_pl; i<entries; ++i)
2095                 {
2096                         //simulate my score is lower than all displayed players,
2097                         //so that I don't appear at all showing pure rankings.
2098                         //This is to better show the difference between the 2 ranking views
2099                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2100                         {
2101                                 rgb = '1 1 0';
2102                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2103                                 s = GetPlayerName(player_localnum);
2104                                 score = 7;
2105                         }
2106                         else
2107                         {
2108                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2109                                 score -= 3;
2110                         }
2111
2112                         if (team_count)
2113                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2114                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2115                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2116                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2117                         pos_y += fontsize_y;
2118                 }
2119                 return;
2120         }
2121
2122         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2123                 HUD_UpdatePlayerTeams();
2124         if (team_count)
2125         {
2126                 // show team scores in the first line
2127                 float score_size = mySize_x / team_count;
2128                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2129                         if(tm.team == NUM_SPECTATOR)
2130                                 continue;
2131                         if (tm.team == myteam)
2132                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2133                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2134                         ++i;
2135                 }
2136                 first_pl = 1;
2137                 pos_y += fontsize_y;
2138                 tm = teams.sort_next;
2139         }
2140         i = first_pl;
2141
2142         do
2143         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2144         {
2145                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2146                         continue;
2147
2148                 if (i == entries-1 && !me_printed && pl != me)
2149                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2150                 {
2151                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2152                                 if (pl.team != NUM_SPECTATOR)
2153                                         break;
2154
2155                         if (pl)
2156                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2157                         else
2158                                 rgb = '1 0 0'; //last: red
2159                         pl = me;
2160                 }
2161
2162                 if (pl == me)
2163                 {
2164                         if (i == first_pl)
2165                                 rgb = '0 1 0'; //first: green
2166                         me_printed = 1;
2167                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2168                 }
2169                 if (team_count)
2170                         score_color = Team_ColorRGB(pl.team) * 0.8;
2171                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2172                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2173                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2174                 pos_y += fontsize_y;
2175                 ++i;
2176         }
2177         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2178 }
2179
2180 void HUD_Score(void)
2181 {
2182         if(!autocvar__hud_configure)
2183         {
2184                 if(!autocvar_hud_panel_score) return;
2185                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2186         }
2187
2188         HUD_Panel_UpdateCvars();
2189         vector pos, mySize;
2190         pos = panel_pos;
2191         mySize = panel_size;
2192
2193         HUD_Panel_DrawBg(1);
2194         if(panel_bg_padding)
2195         {
2196                 pos += '1 1 0' * panel_bg_padding;
2197                 mySize -= '2 2 0' * panel_bg_padding;
2198         }
2199
2200         float score, distribution = 0;
2201         string sign;
2202         vector distribution_color;
2203         entity tm, pl, me;
2204
2205         me = playerslots[player_localentnum - 1];
2206
2207         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2208                 string timer, distrtimer;
2209
2210                 pl = players.sort_next;
2211                 if(pl == me)
2212                         pl = pl.sort_next;
2213                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2214                         if(pl.scores[ps_primary] == 0)
2215                                 pl = world;
2216
2217                 score = me.(scores[ps_primary]);
2218                 timer = TIME_ENCODED_TOSTRING(score);
2219
2220                 draw_beginBoldFont();
2221                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2222                         // distribution display
2223                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2224
2225                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2226
2227                         if (distribution <= 0) {
2228                                 distribution_color = '0 1 0';
2229                                 sign = "-";
2230                         }
2231                         else {
2232                                 distribution_color = '1 0 0';
2233                                 sign = "+";
2234                         }
2235                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2236                 }
2237                 // race record display
2238                 if (distribution <= 0)
2239                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2240                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2241                 draw_endBoldFont();
2242         } else if (!teamplay) { // non-teamgames
2243                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2244                 {
2245                         HUD_Score_Rankings(pos, mySize, me);
2246                         return;
2247                 }
2248                 // me vector := [team/connected frags id]
2249                 pl = players.sort_next;
2250                 if(pl == me)
2251                         pl = pl.sort_next;
2252
2253                 if(autocvar__hud_configure)
2254                         distribution = 42;
2255                 else if(pl)
2256                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2257                 else
2258                         distribution = 0;
2259
2260                 score = me.(scores[ps_primary]);
2261                 if(autocvar__hud_configure)
2262                         score = 123;
2263
2264                 if(distribution >= 5)
2265                         distribution_color = eY;
2266                 else if(distribution >= 0)
2267                         distribution_color = '1 1 1';
2268                 else if(distribution >= -5)
2269                         distribution_color = '1 1 0';
2270                 else
2271                         distribution_color = eX;
2272
2273                 string distribution_str;
2274                 distribution_str = ftos(distribution);
2275                 draw_beginBoldFont();
2276                 if (distribution >= 0)
2277                 {
2278                         if (distribution > 0)
2279                                 distribution_str = strcat("+", distribution_str);
2280                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2281                 }
2282                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2283                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2284                 draw_endBoldFont();
2285         } else { // teamgames
2286                 float row, column, rows = 0, columns = 0;
2287                 local noref vector offset = '0 0 0';
2288                 vector score_pos, score_size; //for scores other than myteam
2289                 if(autocvar_hud_panel_score_rankings)
2290                 {
2291                         HUD_Score_Rankings(pos, mySize, me);
2292                         return;
2293                 }
2294                 if(spectatee_status == -1)
2295                 {
2296                         rows = HUD_GetRowCount(team_count, mySize, 3);
2297                         columns = ceil(team_count/rows);
2298                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2299
2300                         float newSize;
2301                         if(score_size_x/score_size_y > 3)
2302                         {
2303                                 newSize = 3 * score_size_y;
2304                                 offset_x = score_size_x - newSize;
2305                                 pos_x += offset_x/2;
2306                                 score_size_x = newSize;
2307                         }
2308                         else
2309                         {
2310                                 newSize = 1/3 * score_size_x;
2311                                 offset_y = score_size_y - newSize;
2312                                 pos_y += offset_y/2;
2313                                 score_size_y = newSize;
2314                         }
2315                 }
2316                 else
2317                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2318
2319                 float max_fragcount;
2320                 max_fragcount = -99;
2321                 draw_beginBoldFont();
2322                 row = column = 0;
2323                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2324                         if(tm.team == NUM_SPECTATOR)
2325                                 continue;
2326                         score = tm.(teamscores[ts_primary]);
2327                         if(autocvar__hud_configure)
2328                                 score = 123;
2329
2330                         if (score > max_fragcount)
2331                                 max_fragcount = score;
2332
2333                         if (spectatee_status == -1)
2334                         {
2335                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2336                                 if (max_fragcount == score)
2337                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2338                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2339                                 ++row;
2340                                 if(row >= rows)
2341                                 {
2342                                         row = 0;
2343                                         ++column;
2344                                 }
2345                         }
2346                         else if(tm.team == myteam) {
2347                                 if (max_fragcount == score)
2348                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2349                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2350                         } else {
2351                                 if (max_fragcount == score)
2352                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2353                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2354                                 ++rows;
2355                         }
2356                 }
2357                 draw_endBoldFont();
2358         }
2359 }
2360
2361 // Race timer (#8)
2362 //
2363 void HUD_RaceTimer (void)
2364 {
2365         if(!autocvar__hud_configure)
2366         {
2367                 if(!autocvar_hud_panel_racetimer) return;
2368                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2369                 if(spectatee_status == -1) return;
2370         }
2371
2372         HUD_Panel_UpdateCvars();
2373
2374         draw_beginBoldFont();
2375
2376         vector pos, mySize;
2377         pos = panel_pos;
2378         mySize = panel_size;
2379
2380         HUD_Panel_DrawBg(1);
2381         if(panel_bg_padding)
2382         {
2383                 pos += '1 1 0' * panel_bg_padding;
2384                 mySize -= '2 2 0' * panel_bg_padding;
2385         }
2386
2387         // always force 4:1 aspect
2388         vector newSize = '0 0 0';
2389         if(mySize_x/mySize_y > 4)
2390         {
2391                 newSize_x = 4 * mySize_y;
2392                 newSize_y = mySize_y;
2393
2394                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2395         }
2396         else
2397         {
2398                 newSize_y = 1/4 * mySize_x;
2399                 newSize_x = mySize_x;
2400
2401                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2402         }
2403         mySize = newSize;
2404
2405         float a, t;
2406         string s, forcetime;
2407
2408         if(autocvar__hud_configure)
2409         {
2410                 s = "0:13:37";
2411                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2412                 s = _("^1Intermediate 1 (+15.42)");
2413                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2414                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2415                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2416         }
2417         else if(race_checkpointtime)
2418         {
2419                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2420                 s = "";
2421                 forcetime = "";
2422                 if(a > 0) // just hit a checkpoint?
2423                 {
2424                         if(race_checkpoint != 254)
2425                         {
2426                                 if(race_time && race_previousbesttime)
2427                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2428                                 else
2429                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2430                                 if(race_time)
2431                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2432                         }
2433                 }
2434                 else
2435                 {
2436                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2437                         {
2438                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2439                                 if(a > 0) // next one?
2440                                 {
2441                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2442                                 }
2443                         }
2444                 }
2445
2446                 if(s != "" && a > 0)
2447                 {
2448                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2449                 }
2450
2451                 if(race_penaltytime)
2452                 {
2453                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2454                         if(a > 0)
2455                         {
2456                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2457                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2458                         }
2459                 }
2460
2461                 if(forcetime != "")
2462                 {
2463                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2464                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2465                 }
2466                 else
2467                         a = 1;
2468
2469                 if(race_laptime && race_checkpoint != 255)
2470                 {
2471                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2472                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2473                 }
2474         }
2475         else
2476         {
2477                 if(race_mycheckpointtime)
2478                 {
2479                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2480                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2481                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2482                 }
2483                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2484                 {
2485                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2486                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2487                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2488                 }
2489
2490                 if(race_penaltytime && !race_penaltyaccumulator)
2491                 {
2492                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2493                         a = bound(0, (1 + t - time), 1);
2494                         if(a > 0)
2495                         {
2496                                 if(time < t)
2497                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2498                                 else
2499                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2500                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2501                         }
2502                 }
2503         }
2504
2505         draw_endBoldFont();
2506 }
2507
2508 // Vote window (#9)
2509 //
2510 float vote_yescount;
2511 float vote_nocount;
2512 float vote_needed;
2513 float vote_highlighted; // currently selected vote
2514
2515 float vote_active; // is there an active vote?
2516 float vote_prev; // previous state of vote_active to check for a change
2517 float vote_alpha;
2518 float vote_change; // "time" when vote_active changed
2519
2520 void HUD_Vote(void)
2521 {
2522         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2523         {
2524                 vote_active = 1;
2525                 if (autocvar__hud_configure)
2526                 {
2527                         vote_yescount = 0;
2528                         vote_nocount = 0;
2529                         print(_("^1You must answer before entering hud configure mode\n"));
2530                         cvar_set("_hud_configure", "0");
2531                 }
2532                 if(vote_called_vote)
2533                         strunzone(vote_called_vote);
2534                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2535                 uid2name_dialog = 1;
2536         }
2537
2538         if(!autocvar__hud_configure)
2539         {
2540                 if(!autocvar_hud_panel_vote) return;
2541
2542                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2543                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2544
2545                 if(panel_bg_alpha_str == "") {
2546                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2547                 }
2548                 panel_bg_alpha = stof(panel_bg_alpha_str);
2549         }
2550         else
2551         {
2552                 vote_yescount = 3;
2553                 vote_nocount = 2;
2554                 vote_needed = 4;
2555         }
2556
2557         string s;
2558         float a;
2559         if(vote_active != vote_prev) {
2560                 vote_change = time;
2561                 vote_prev = vote_active;
2562         }
2563
2564         if(vote_active || autocvar__hud_configure)
2565                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2566         else
2567                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2568
2569         if(!vote_alpha)
2570                 return;
2571
2572         HUD_Panel_UpdateCvars();
2573
2574         if(uid2name_dialog)
2575         {
2576                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2577                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2578         }
2579
2580     // these must be below above block
2581         vector pos, mySize;
2582         pos = panel_pos;
2583         mySize = panel_size;
2584
2585         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2586         HUD_Panel_DrawBg(a);
2587         a = panel_fg_alpha * a;
2588
2589         if(panel_bg_padding)
2590         {
2591                 pos += '1 1 0' * panel_bg_padding;
2592                 mySize -= '2 2 0' * panel_bg_padding;
2593         }
2594
2595         // always force 3:1 aspect
2596         vector newSize = '0 0 0';
2597         if(mySize_x/mySize_y > 3)
2598         {
2599                 newSize_x = 3 * mySize_y;
2600                 newSize_y = mySize_y;
2601
2602                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2603         }
2604         else
2605         {
2606                 newSize_y = 1/3 * mySize_x;
2607                 newSize_x = mySize_x;
2608
2609                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2610         }
2611         mySize = newSize;
2612
2613         s = _("A vote has been called for:");
2614         if(uid2name_dialog)
2615                 s = _("Allow servers to store and display your name?");
2616         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2617         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2618         if(autocvar__hud_configure)
2619                 s = _("^1Configure the HUD");
2620         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2621
2622         // print the yes/no counts
2623     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2624         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2625     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2626         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2627
2628         // draw the progress bar backgrounds
2629         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2630
2631         // draw the highlights
2632         if(vote_highlighted == 1) {
2633                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2634                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2635         }
2636         else if(vote_highlighted == -1) {
2637                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2638                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2639         }
2640
2641         // draw the progress bars
2642         if(vote_yescount && vote_needed)
2643         {
2644                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2645                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2646         }
2647
2648         if(vote_nocount && vote_needed)
2649         {
2650                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2651                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2652         }
2653
2654         drawresetcliparea();
2655 }
2656
2657 // Mod icons panel (#10)
2658 //
2659
2660 float mod_active; // is there any active mod icon?
2661
2662 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2663 {
2664         float stat;
2665         string pic;
2666         vector color;
2667 #ifdef GMQCC
2668         stat = -1;
2669         pic = "";
2670         color = '0 0 0';
2671 #endif
2672         switch(i)
2673         {
2674                 case 0:
2675                         stat = getstati(STAT_REDALIVE);
2676                         pic = "player_red.tga";
2677                         color = '1 0 0';
2678                         break;
2679                 case 1:
2680                         stat = getstati(STAT_BLUEALIVE);
2681                         pic = "player_blue.tga";
2682                         color = '0 0 1';
2683                         break;
2684                 case 2:
2685                         stat = getstati(STAT_YELLOWALIVE);
2686                         pic = "player_yellow.tga";
2687                         color = '1 1 0';
2688                         break;
2689                 default:
2690                 case 3:
2691                         stat = getstati(STAT_PINKALIVE);
2692                         pic = "player_pink.tga";
2693                         color = '1 0 1';
2694                         break;
2695         }
2696
2697         if(mySize_x/mySize_y > aspect_ratio)
2698         {
2699                 i = aspect_ratio * mySize_y;
2700                 myPos_x = myPos_x + (mySize_x - i) / 2;
2701                 mySize_x = i;
2702         }
2703         else
2704         {
2705                 i = 1/aspect_ratio * mySize_x;
2706                 myPos_y = myPos_y + (mySize_y - i) / 2;
2707                 mySize_y = i;
2708         }
2709
2710         if(layout)
2711         {
2712                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2713                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2714         }
2715         else
2716                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2717 }
2718
2719 // Clan Arena and Freeze Tag HUD modicons
2720 void HUD_Mod_CA(vector myPos, vector mySize)
2721 {
2722         mod_active = 1; // required in each mod function that always shows something
2723
2724         float layout;
2725         if(gametype == MAPINFO_TYPE_CA)
2726                 layout = autocvar_hud_panel_modicons_ca_layout;
2727         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2728                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2729         float rows, columns, aspect_ratio;
2730         aspect_ratio = (layout) ? 2 : 1;
2731         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2732         columns = ceil(team_count/rows);
2733
2734         int i;
2735         float row = 0, column = 0;
2736         vector pos, itemSize;
2737         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2738         for(i=0; i<team_count; ++i)
2739         {
2740                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2741
2742                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2743
2744                 ++row;
2745                 if(row >= rows)
2746                 {
2747                         row = 0;
2748                         ++column;
2749                 }
2750         }
2751 }
2752
2753 // CTF HUD modicon section
2754 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2755 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2756 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2757
2758 void HUD_Mod_CTF_Reset(void)
2759 {
2760         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2761 }
2762
2763 void HUD_Mod_CTF(vector pos, vector mySize)
2764 {
2765         vector redflag_pos, blueflag_pos;
2766         vector flag_size;
2767         float f; // every function should have that
2768
2769         float redflag, blueflag; // current status
2770         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2771         float stat_items;
2772
2773         stat_items = getstati(STAT_ITEMS, 0, 24);
2774         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2775         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2776
2777         if(redflag || blueflag)
2778                 mod_active = 1;
2779         else
2780                 mod_active = 0;
2781
2782         if(autocvar__hud_configure)
2783         {
2784                 redflag = 1;
2785                 blueflag = 2;
2786         }
2787
2788         // when status CHANGES, set old status into prevstatus and current status into status
2789         if (redflag != redflag_prevframe)
2790         {
2791                 redflag_statuschange_time = time;
2792                 redflag_prevstatus = redflag_prevframe;
2793                 redflag_prevframe = redflag;
2794         }
2795
2796         if (blueflag != blueflag_prevframe)
2797         {
2798                 blueflag_statuschange_time = time;
2799                 blueflag_prevstatus = blueflag_prevframe;
2800                 blueflag_prevframe = blueflag;
2801         }
2802
2803         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2804         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2805
2806         float BLINK_FACTOR = 0.15;
2807         float BLINK_BASE = 0.85;
2808         // note:
2809         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2810         // thus
2811         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2812         // ensure RMS == 1
2813         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2814
2815         string red_icon, red_icon_prevstatus;
2816         float red_alpha, red_alpha_prevstatus;
2817         red_alpha = red_alpha_prevstatus = 1;
2818         switch(redflag) {
2819                 case 1: red_icon = "flag_red_taken"; break;
2820                 case 2: red_icon = "flag_red_lost"; break;
2821                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2822                 default:
2823                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2824                                 red_icon = "flag_red_shielded";
2825                         else
2826                                 red_icon = string_null;
2827                         break;
2828         }
2829         switch(redflag_prevstatus) {
2830                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2831                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2832                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2833                 default:
2834                         if(redflag == 3)
2835                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2836                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2837                                 red_icon_prevstatus = "flag_red_shielded";
2838                         else
2839                                 red_icon_prevstatus = string_null;
2840                         break;
2841         }
2842
2843         string blue_icon, blue_icon_prevstatus;
2844         float blue_alpha, blue_alpha_prevstatus;
2845         blue_alpha = blue_alpha_prevstatus = 1;
2846         switch(blueflag) {
2847                 case 1: blue_icon = "flag_blue_taken"; break;
2848                 case 2: blue_icon = "flag_blue_lost"; break;
2849                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2850                 default:
2851                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2852                                 blue_icon = "flag_blue_shielded";
2853                         else
2854                                 blue_icon = string_null;
2855                         break;
2856         }
2857         switch(blueflag_prevstatus) {
2858                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2859                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2860                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2861                 default:
2862                         if(blueflag == 3)
2863                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2864                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2865                                 blue_icon_prevstatus = "flag_blue_shielded";
2866                         else
2867                                 blue_icon_prevstatus = string_null;
2868                         break;
2869         }
2870
2871         if(mySize_x > mySize_y) {
2872                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2873                         redflag_pos = pos;
2874                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2875                 } else {
2876                         blueflag_pos = pos;
2877                         redflag_pos = pos + eX * 0.5 * mySize_x;
2878                 }
2879                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2880         } else {
2881                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2882                         redflag_pos = pos;
2883                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2884                 } else {
2885                         blueflag_pos = pos;
2886                         redflag_pos = pos + eY * 0.5 * mySize_y;
2887                 }
2888                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2889         }
2890
2891         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2892         if(red_icon_prevstatus && f < 1)
2893                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2894         if(red_icon)
2895                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2896
2897         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2898         if(blue_icon_prevstatus && f < 1)
2899                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2900         if(blue_icon)
2901                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2902 }
2903
2904 // Keyhunt HUD modicon section
2905 vector KH_SLOTS[4];
2906
2907 void HUD_Mod_KH(vector pos, vector mySize)
2908 {
2909         mod_active = 1; // keyhunt should never hide the mod icons panel
2910
2911         // Read current state
2912
2913         float state = getstati(STAT_KH_KEYS);
2914         float i, key_state;
2915         float all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
2916         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
2917
2918         for(i = 0; i < 4; ++i)
2919         {
2920                 key_state = (bitshift(state, i * -5) & 31) - 1;
2921
2922                 if(key_state == -1)
2923                         continue;
2924
2925                 if(key_state == 30)
2926                 {
2927                         ++carrying_keys;
2928                         key_state = myteam;
2929                 }
2930
2931                 switch(key_state)
2932                 {
2933                         case NUM_TEAM_1: ++team1_keys; break;
2934                         case NUM_TEAM_2: ++team2_keys; break;
2935                         case NUM_TEAM_3: ++team3_keys; break;
2936                         case NUM_TEAM_4: ++team4_keys; break;
2937                         case 29: ++dropped_keys; break;
2938                 }
2939
2940                 ++all_keys;
2941         }
2942
2943         // Calculate slot measurements
2944
2945         vector slot_size;
2946
2947         if(all_keys == 4 && mySize_x * 0.5 < mySize_y && mySize_y * 0.5 < mySize_x)
2948         {
2949                 // Quadratic arrangement
2950                 slot_size = eX * mySize_x * 0.5 + eY * mySize_y * 0.5;
2951                 KH_SLOTS[0] = pos;
2952                 KH_SLOTS[1] = pos + eX * slot_size_x;
2953                 KH_SLOTS[2] = pos + eY * slot_size_y;
2954                 KH_SLOTS[3] = pos + eX * slot_size_x + eY * slot_size_y;
2955         }
2956         else
2957         {
2958                 if(mySize_x > mySize_y)
2959                 {
2960                         // Horizontal arrangement
2961                         slot_size = eX * mySize_x / all_keys + eY * mySize_y;
2962                         for(i = 0; i < all_keys; ++i)
2963                                 KH_SLOTS[i] = pos + eX * slot_size_x * i;
2964                 }
2965                 else
2966                 {
2967                         // Vertical arrangement
2968                         slot_size = eX * mySize_x + eY * mySize_y / all_keys;
2969                         for(i = 0; i < all_keys; ++i)
2970                                 KH_SLOTS[i] = pos + eY * slot_size_y * i;
2971                 }
2972         }
2973
2974         // Make icons blink in case of RUN HERE
2975
2976         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
2977         float alpha;
2978         alpha = 1;
2979
2980         if(carrying_keys)
2981                 switch(myteam)
2982                 {
2983                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
2984                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
2985                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
2986                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
2987                 }
2988
2989         // Draw icons
2990
2991         i = 0;
2992
2993         while(team1_keys--)
2994                 if(myteam == NUM_TEAM_1 && carrying_keys)
2995                 {
2996                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
2997                         --carrying_keys;
2998                 }
2999                 else
3000                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3001
3002         while(team2_keys--)
3003                 if(myteam == NUM_TEAM_2 && carrying_keys)
3004                 {
3005                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3006                         --carrying_keys;
3007                 }
3008                 else
3009                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3010
3011         while(team3_keys--)
3012                 if(myteam == NUM_TEAM_3 && carrying_keys)
3013                 {
3014                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3015                         --carrying_keys;
3016                 }
3017                 else
3018                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3019
3020         while(team4_keys--)
3021                 if(myteam == NUM_TEAM_4 && carrying_keys)
3022                 {
3023                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3024                         --carrying_keys;
3025                 }
3026                 else
3027                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3028
3029         while(dropped_keys--)
3030                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3031 }
3032
3033 // Keepaway HUD mod icon
3034 float kaball_prevstatus; // last remembered status
3035 float kaball_statuschange_time; // time when the status changed
3036
3037 // we don't need to reset for keepaway since it immediately
3038 // autocorrects prevstatus as to if the player has the ball or not
3039
3040 void HUD_Mod_Keepaway(vector pos, vector mySize)
3041 {
3042         mod_active = 1; // keepaway should always show the mod HUD
3043
3044         float BLINK_FACTOR = 0.15;
3045         float BLINK_BASE = 0.85;
3046         float BLINK_FREQ = 5;
3047         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3048
3049         float stat_items = getstati(STAT_ITEMS, 0, 24);
3050         float kaball = (stat_items/IT_KEY1) & 1;
3051
3052         if(kaball != kaball_prevstatus)
3053         {
3054                 kaball_statuschange_time = time;
3055                 kaball_prevstatus = kaball;
3056         }
3057
3058         vector kaball_pos, kaball_size;
3059
3060         if(mySize_x > mySize_y) {
3061                 kaball_pos = pos + eX * 0.25 * mySize_x;
3062                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
3063         } else {
3064                 kaball_pos = pos + eY * 0.25 * mySize_y;
3065                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3066         }
3067
3068         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3069         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3070
3071         if(kaball_prevstatus && f < 1)
3072                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3073
3074         if(kaball)
3075                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3076 }
3077
3078
3079 // Nexball HUD mod icon
3080 void HUD_Mod_NexBall(vector pos, vector mySize)
3081 {
3082         float stat_items, nb_pb_starttime, dt, p;
3083
3084         stat_items = getstati(STAT_ITEMS, 0, 24);
3085         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3086
3087         if (stat_items & IT_KEY1)
3088                 mod_active = 1;
3089         else
3090                 mod_active = 0;
3091
3092         //Manage the progress bar if any
3093         if (nb_pb_starttime > 0)
3094         {
3095                 dt = (time - nb_pb_starttime) % nb_pb_period;
3096                 // one period of positive triangle
3097                 p = 2 * dt / nb_pb_period;
3098                 if (p > 1)
3099                         p = 2 - p;
3100
3101                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize_x <= mySize_y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3102         }
3103
3104         if (stat_items & IT_KEY1)
3105                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3106 }
3107
3108 // Race/CTS HUD mod icons
3109 float crecordtime_prev; // last remembered crecordtime
3110 float crecordtime_change_time; // time when crecordtime last changed
3111 float srecordtime_prev; // last remembered srecordtime
3112 float srecordtime_change_time; // time when srecordtime last changed
3113
3114 float race_status_time;
3115 float race_status_prev;
3116 string race_status_name_prev;
3117 void HUD_Mod_Race(vector pos, vector mySize)
3118 {
3119         mod_active = 1; // race should never hide the mod icons panel
3120         entity me;
3121         me = playerslots[player_localnum];
3122         float t, score;
3123         float f; // yet another function has this
3124         score = me.(scores[ps_primary]);
3125
3126         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3127                 return; // no records in the actual race
3128
3129         // clientside personal record
3130         string rr;
3131         if(gametype == MAPINFO_TYPE_CTS)
3132                 rr = CTS_RECORD;
3133         else
3134                 rr = RACE_RECORD;
3135         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3136
3137         if(score && (score < t || !t)) {
3138                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3139                 if(autocvar_cl_autodemo_delete_keeprecords)
3140                 {
3141                         f = autocvar_cl_autodemo_delete;
3142                         f &= ~1;
3143                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3144                 }
3145         }
3146
3147         if(t != crecordtime_prev) {
3148                 crecordtime_prev = t;
3149                 crecordtime_change_time = time;
3150         }
3151
3152         vector textPos, medalPos;
3153         float squareSize;
3154         if(mySize_x > mySize_y) {
3155                 // text on left side
3156                 squareSize = min(mySize_y, mySize_x/2);
3157                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3158                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3159         } else {
3160                 // text on top
3161                 squareSize = min(mySize_x, mySize_y/2);
3162                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3163                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3164         }
3165
3166         f = time - crecordtime_change_time;
3167
3168         if (f > 1) {
3169                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3170                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3171         } else {
3172                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3173                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3174                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3175                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3176         }
3177
3178         // server record
3179         t = race_server_record;
3180         if(t != srecordtime_prev) {
3181                 srecordtime_prev = t;
3182                 srecordtime_change_time = time;
3183         }
3184         f = time - srecordtime_change_time;
3185
3186         if (f > 1) {
3187                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3188                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3189         } else {
3190                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3191                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3192                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3193                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3194         }
3195
3196         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3197                 race_status_time = time + 5;
3198                 race_status_prev = race_status;
3199                 if (race_status_name_prev)
3200                         strunzone(race_status_name_prev);
3201                 race_status_name_prev = strzone(race_status_name);
3202         }
3203
3204         // race "awards"
3205         float a;
3206         a = bound(0, race_status_time - time, 1);
3207
3208         string s;
3209         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3210
3211         float rank;
3212         if(race_status > 0)
3213                 rank = race_CheckName(race_status_name);
3214         else
3215                 rank = 0;
3216         string rankname;
3217         rankname = count_ordinal(rank);
3218
3219         vector namepos;
3220         namepos = medalPos + '0 0.8 0' * squareSize;
3221         vector rankpos;
3222         rankpos = medalPos + '0 0.15 0' * squareSize;
3223
3224         if(race_status == 0)
3225                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3226         else if(race_status == 1) {
3227                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3228                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3229                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3230         } else if(race_status == 2) {
3231                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3232                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3233                 else
3234                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3235                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3236                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3237         } else if(race_status == 3) {
3238                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3239                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3240                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3241         }
3242
3243         if (race_status_time - time <= 0) {
3244                 race_status_prev = -1;
3245                 race_status = -1;
3246                 if(race_status_name)
3247                         strunzone(race_status_name);
3248                 race_status_name = string_null;
3249                 if(race_status_name_prev)
3250                         strunzone(race_status_name_prev);
3251                 race_status_name_prev = string_null;
3252         }
3253 }
3254
3255 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3256 {
3257         float stat, pps_ratio;
3258         string pic;
3259         vector color;
3260 #ifdef GMQCC
3261         stat = -1;
3262         pic = "";
3263         color = '0 0 0';
3264 #endif
3265         switch(i)
3266         {
3267                 case 0:
3268                         stat = getstatf(STAT_DOM_PPS_RED);
3269                         pic = "dom_icon_red";
3270                         color = '1 0 0';
3271                         break;
3272                 case 1:
3273                         stat = getstatf(STAT_DOM_PPS_BLUE);
3274                         pic = "dom_icon_blue";
3275                         color = '0 0 1';
3276                         break;
3277                 case 2:
3278                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3279                         pic = "dom_icon_yellow";
3280                         color = '1 1 0';
3281                         break;
3282                 default:
3283                 case 3:
3284                         stat = getstatf(STAT_DOM_PPS_PINK);
3285                         pic = "dom_icon_pink";
3286                         color = '1 0 1';
3287                         break;
3288         }
3289         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3290
3291         if(mySize_x/mySize_y > aspect_ratio)
3292         {
3293                 i = aspect_ratio * mySize_y;
3294                 myPos_x = myPos_x + (mySize_x - i) / 2;
3295                 mySize_x = i;
3296         }
3297         else
3298         {
3299                 i = 1/aspect_ratio * mySize_x;
3300                 myPos_y = myPos_y + (mySize_y - i) / 2;
3301                 mySize_y = i;
3302         }
3303
3304         if (layout) // show text too
3305         {
3306                 //draw the text
3307                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3308                 if (layout == 2) // average pps
3309                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3310                 else // percentage of average pps
3311                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3312         }
3313
3314         //draw the icon
3315         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3316         if (stat > 0)
3317         {
3318                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3319                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3320                 drawresetcliparea();
3321         }
3322 }
3323
3324 void HUD_Mod_Dom(vector myPos, vector mySize)
3325 {
3326         mod_active = 1; // required in each mod function that always shows something
3327
3328         float layout = autocvar_hud_panel_modicons_dom_layout;
3329         float rows, columns, aspect_ratio;
3330         aspect_ratio = (layout) ? 3 : 1;
3331         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3332         columns = ceil(team_count/rows);
3333
3334         int i;
3335         float row = 0, column = 0;
3336         vector pos, itemSize;
3337         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3338         for(i=0; i<team_count; ++i)
3339         {
3340                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
3341
3342                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3343
3344                 ++row;
3345                 if(row >= rows)
3346                 {
3347                         row = 0;
3348                         ++column;
3349                 }
3350         }
3351 }
3352
3353 void HUD_ModIcons_SetFunc()
3354 {
3355         switch(gametype)
3356         {
3357                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3358                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3359                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3360                 case MAPINFO_TYPE_CTS:
3361                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3362                 case MAPINFO_TYPE_CA:
3363                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3364                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3365                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3366         }
3367 }
3368
3369 float mod_prev; // previous state of mod_active to check for a change
3370 float mod_alpha;
3371 float mod_change; // "time" when mod_active changed
3372
3373 void HUD_ModIcons(void)
3374 {
3375         if(!autocvar__hud_configure)
3376         {
3377                 if(!autocvar_hud_panel_modicons) return;
3378                 if(!HUD_ModIcons_GameType) return;
3379         }
3380
3381         HUD_Panel_UpdateCvars();
3382
3383         draw_beginBoldFont();
3384
3385         if(mod_active != mod_prev) {
3386                 mod_change = time;
3387                 mod_prev = mod_active;
3388         }
3389
3390         if(mod_active || autocvar__hud_configure)
3391                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3392         else
3393                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3394
3395         if(mod_alpha)
3396                 HUD_Panel_DrawBg(mod_alpha);
3397
3398         if(panel_bg_padding)
3399         {
3400                 panel_pos += '1 1 0' * panel_bg_padding;
3401                 panel_size -= '2 2 0' * panel_bg_padding;
3402         }
3403
3404         if(autocvar__hud_configure)
3405                 HUD_Mod_CTF(panel_pos, panel_size);
3406         else
3407                 HUD_ModIcons_GameType(panel_pos, panel_size);
3408
3409         draw_endBoldFont();
3410 }
3411
3412 // Draw pressed keys (#11)
3413 //
3414 void HUD_PressedKeys(void)
3415 {
3416         if(!autocvar__hud_configure)
3417         {
3418                 if(!autocvar_hud_panel_pressedkeys) return;
3419                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3420         }
3421
3422         HUD_Panel_UpdateCvars();
3423         vector pos, mySize;
3424         pos = panel_pos;
3425         mySize = panel_size;
3426
3427         HUD_Panel_DrawBg(1);
3428         if(panel_bg_padding)
3429         {
3430                 pos += '1 1 0' * panel_bg_padding;
3431                 mySize -= '2 2 0' * panel_bg_padding;
3432         }
3433
3434         // force custom aspect
3435         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3436         if(aspect)
3437         {
3438                 vector newSize = '0 0 0';
3439                 if(mySize_x/mySize_y > aspect)
3440                 {
3441                         newSize_x = aspect * mySize_y;
3442                         newSize_y = mySize_y;
3443
3444                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3445                 }
3446                 else
3447                 {
3448                         newSize_y = 1/aspect * mySize_x;
3449                         newSize_x = mySize_x;
3450
3451                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3452                 }
3453                 mySize = newSize;
3454         }
3455
3456         vector keysize;
3457         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3458         float pressedkeys;
3459         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3460
3461         if(autocvar_hud_panel_pressedkeys_attack)
3462         {
3463                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3464                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3465                 pos_y += keysize_y;
3466         }
3467
3468         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3469         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3470         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3471         pos_y += keysize_y;
3472         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3473         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3474         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3475 }
3476
3477 // Handle chat as a panel (#12)
3478 //
3479 void HUD_Chat(void)
3480 {
3481         if(!autocvar__hud_configure)
3482         {
3483                 if (!autocvar_hud_panel_chat)
3484                 {
3485                         if (!autocvar_con_chatrect)
3486                                 cvar_set("con_chatrect", "0");
3487                         return;
3488                 }
3489                 if(autocvar__con_chat_maximized)
3490                 {
3491                         if(!hud_draw_maximized) return;
3492                 }
3493                 else if(chat_panel_modified)
3494                 {
3495                         panel.update_time = time; // forces reload of panel attributes
3496                         chat_panel_modified = false;
3497                 }
3498         }
3499
3500         HUD_Panel_UpdateCvars();
3501
3502         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3503         {
3504                 panel_pos_y = panel_bg_border;
3505                 panel_size_y = vid_conheight - panel_bg_border * 2;
3506                 if(panel.current_panel_bg == "0") // force a border when maximized
3507                 {
3508                         string panel_bg;
3509                         panel_bg = strcat(hud_skin_path, "/border_default");
3510                         if(precache_pic(panel_bg) == "")
3511                                 panel_bg = "gfx/hud/default/border_default";
3512                         if(panel.current_panel_bg)
3513                                 strunzone(panel.current_panel_bg);
3514                         panel.current_panel_bg = strzone(panel_bg);
3515                         chat_panel_modified = true;
3516                 }
3517                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3518         }
3519
3520         vector pos, mySize;
3521         pos = panel_pos;
3522         mySize = panel_size;
3523
3524         HUD_Panel_DrawBg(1);
3525
3526         if(panel_bg_padding)
3527         {
3528                 pos += '1 1 0' * panel_bg_padding;
3529                 mySize -= '2 2 0' * panel_bg_padding;
3530         }
3531
3532         if (!autocvar_con_chatrect)
3533                 cvar_set("con_chatrect", "1");
3534
3535         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3536         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3537
3538         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3539         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3540
3541         if(autocvar__hud_configure)
3542         {
3543                 vector chatsize;
3544                 chatsize = '1 1 0' * autocvar_con_chatsize;
3545                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3546                 float i, a;
3547                 for(i = 0; i < autocvar_con_chat; ++i)
3548                 {
3549                         if(i == autocvar_con_chat - 1)
3550                                 a = panel_fg_alpha;
3551                         else
3552                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3553                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3554                         pos_y += chatsize_y;
3555                 }
3556         }
3557 }
3558
3559 // Engine info panel (#13)
3560 //
3561 float prevfps;
3562 float prevfps_time;
3563 float framecounter;
3564
3565 float frametimeavg;
3566 float frametimeavg1; // 1 frame ago
3567 float frametimeavg2; // 2 frames ago
3568 void HUD_EngineInfo(void)
3569 {
3570         if(!autocvar__hud_configure)
3571         {
3572                 if(!autocvar_hud_panel_engineinfo) return;
3573         }
3574
3575         HUD_Panel_UpdateCvars();
3576         vector pos, mySize;
3577         pos = panel_pos;
3578         mySize = panel_size;
3579
3580         HUD_Panel_DrawBg(1);
3581         if(panel_bg_padding)
3582         {
3583                 pos += '1 1 0' * panel_bg_padding;
3584                 mySize -= '2 2 0' * panel_bg_padding;
3585         }
3586
3587         float currentTime = gettime(GETTIME_REALTIME);
3588         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3589         {
3590                 float currentframetime = currentTime - prevfps_time;
3591                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3592                 frametimeavg2 = frametimeavg1;
3593                 frametimeavg1 = frametimeavg;
3594
3595                 float weight;
3596                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3597                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3598                 {
3599                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3600                                 prevfps = (1/currentframetime);
3601                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3602                 }
3603                 prevfps_time = currentTime;
3604         }
3605         else
3606         {
3607                 framecounter += 1;
3608                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3609                 {
3610                         prevfps = framecounter/(currentTime - prevfps_time);
3611                         framecounter = 0;
3612                         prevfps_time = currentTime;
3613                 }
3614         }
3615
3616         vector color;
3617         color = HUD_Get_Num_Color (prevfps, 100);
3618         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3619 }
3620
3621 // Info messages panel (#14)
3622 //
3623 #define drawInfoMessage(s)\
3624         if(autocvar_hud_panel_infomessages_flip)\
3625                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3626         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3627         o_y += fontsize_y;
3628 void HUD_InfoMessages(void)
3629 {
3630         if(!autocvar__hud_configure)
3631         {
3632                 if(!autocvar_hud_panel_infomessages) return;
3633         }
3634
3635         HUD_Panel_UpdateCvars();
3636         vector pos, mySize;
3637         pos = panel_pos;
3638         mySize = panel_size;
3639
3640         HUD_Panel_DrawBg(1);
3641         if(panel_bg_padding)
3642         {
3643                 pos += '1 1 0' * panel_bg_padding;
3644                 mySize -= '2 2 0' * panel_bg_padding;
3645         }
3646
3647         // always force 5:1 aspect
3648         vector newSize = '0 0 0';
3649         if(mySize_x/mySize_y > 5)
3650         {
3651                 newSize_x = 5 * mySize_y;
3652                 newSize_y = mySize_y;
3653
3654                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3655         }
3656         else
3657         {
3658                 newSize_y = 1/5 * mySize_x;
3659                 newSize_x = mySize_x;
3660
3661                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3662         }
3663
3664         mySize = newSize;
3665         entity tm;
3666         vector o;
3667         o = pos;
3668
3669         vector fontsize;
3670         fontsize = '0.20 0.20 0' * mySize_y;
3671
3672         float a;
3673         a = panel_fg_alpha;
3674
3675         string s;
3676         if(!autocvar__hud_configure)
3677         {
3678                 if(spectatee_status && !intermission)
3679                 {
3680                         a = 1;
3681                         if(spectatee_status == -1)
3682                                 s = _("^1Observing");
3683                         else
3684                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3685                         drawInfoMessage(s)
3686
3687                         if(spectatee_status == -1)
3688                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3689                         else
3690                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3691                         drawInfoMessage(s)
3692
3693                         if(spectatee_status == -1)
3694                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3695                         else
3696                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3697                         drawInfoMessage(s)
3698
3699                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3700                         drawInfoMessage(s)
3701
3702                         if(gametype == MAPINFO_TYPE_LMS)
3703                         {
3704                                 entity sk;
3705                                 sk = playerslots[player_localnum];
3706                                 if(sk.(scores[ps_primary]) >= 666)
3707                                         s = _("^1Match has already begun");
3708                                 else if(sk.(scores[ps_primary]) > 0)
3709                                         s = _("^1You have no more lives left");
3710                                 else
3711                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3712                         }
3713                         else
3714                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3715                         drawInfoMessage(s)
3716
3717                         //show restart countdown:
3718                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3719                                 float countdown;
3720                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3721                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3722                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3723                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3724                                 o_y += fontsize_y;
3725                         }
3726                 }
3727                 if(warmup_stage && !intermission)
3728                 {
3729                         s = _("^2Currently in ^1warmup^2 stage!");
3730                         drawInfoMessage(s)
3731                 }
3732
3733                 string blinkcolor;
3734                 if(time % 1 >= 0.5)
3735                         blinkcolor = "^1";
3736                 else
3737                         blinkcolor = "^3";
3738
3739                 if(ready_waiting && !intermission && !spectatee_status)
3740                 {
3741                         if(ready_waiting_for_me)
3742                         {
3743                                 if(warmup_stage)
3744                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3745                                 else
3746                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3747                         }
3748                         else
3749                         {
3750                                 if(warmup_stage)
3751                                         s = _("^2Waiting for others to ready up to end warmup...");
3752                                 else
3753                                         s = _("^2Waiting for others to ready up...");
3754                         }
3755                         drawInfoMessage(s)
3756                 }
3757                 else if(warmup_stage && !intermission && !spectatee_status)
3758                 {
3759                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3760                         drawInfoMessage(s)
3761                 }
3762
3763                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3764                 {
3765                         float ts_min = 0, ts_max = 0;
3766                         tm = teams.sort_next;
3767                         if (tm)
3768                         {
3769                                 for(; tm.sort_next; tm = tm.sort_next)
3770                                 {
3771                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3772                                                 continue;
3773                                         if(!ts_min) ts_min = tm.team_size;
3774                                         else ts_min = min(ts_min, tm.team_size);
3775                                         if(!ts_max) ts_max = tm.team_size;
3776                                         else ts_max = max(ts_max, tm.team_size);
3777                                 }
3778                                 if ((ts_max - ts_min) > 1)
3779                                 {
3780                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3781                                         tm = GetTeam(myteam, false);
3782                                         if (tm)
3783                                         if (tm.team != NUM_SPECTATOR)
3784                                         if (tm.team_size == ts_max)
3785                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3786                                         drawInfoMessage(s)
3787                                 }
3788                         }
3789                 }
3790         }
3791         else
3792         {
3793                 s = _("^7Press ^3ESC ^7to show HUD options.");
3794                 drawInfoMessage(s)
3795                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3796                 drawInfoMessage(s)
3797                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3798                 drawInfoMessage(s)
3799                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3800                 drawInfoMessage(s)
3801         }
3802 }
3803
3804 // Physics panel (#15)
3805 //
3806 vector acc_prevspeed;
3807 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3808 void HUD_Physics(void)
3809 {
3810         if(!autocvar__hud_configure)
3811         {
3812                 if(!autocvar_hud_panel_physics) return;
3813                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3814                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3815         }
3816
3817         HUD_Panel_UpdateCvars();
3818
3819         draw_beginBoldFont();
3820
3821         HUD_Panel_DrawBg(1);
3822         if(panel_bg_padding)
3823         {
3824                 panel_pos += '1 1 0' * panel_bg_padding;
3825                 panel_size -= '2 2 0' * panel_bg_padding;
3826         }
3827
3828         float acceleration_progressbar_scale = 0;
3829         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3830                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3831
3832         float text_scale;
3833         if (autocvar_hud_panel_physics_text_scale <= 0)
3834                 text_scale = 1;
3835         else
3836                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3837
3838         //compute speed
3839         float speed, conversion_factor;
3840         string unit;
3841
3842         switch(autocvar_hud_panel_physics_speed_unit)
3843         {
3844                 default:
3845                 case 1:
3846                         unit = _(" qu/s");
3847                         conversion_factor = 1.0;
3848                         break;
3849                 case 2:
3850                         unit = _(" m/s");
3851                         conversion_factor = 0.0254;
3852                         break;
3853                 case 3:
3854                         unit = _(" km/h");
3855                         conversion_factor = 0.0254 * 3.6;
3856                         break;
3857                 case 4:
3858                         unit = _(" mph");
3859                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3860                         break;
3861                 case 5:
3862                         unit = _(" knots");
3863                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3864                         break;
3865         }
3866
3867         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3868
3869         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3870         if (autocvar__hud_configure)
3871                 speed = floor( max_speed * 0.65 + 0.5 );
3872         else if(autocvar_hud_panel_physics_speed_vertical)
3873                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3874         else
3875                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3876
3877         //compute acceleration
3878         float acceleration, f;
3879         if (autocvar__hud_configure)
3880                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3881         else
3882         {
3883                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3884                 f = time - acc_prevtime;
3885                 if(autocvar_hud_panel_physics_acceleration_vertical)
3886                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3887                 else
3888                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3889
3890                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3891
3892                 acc_prevspeed = vel;
3893                 acc_prevtime = time;
3894
3895                 f = bound(0, f * 10, 1);
3896                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3897         }
3898
3899         //compute layout
3900         float panel_ar = panel_size_x/panel_size_y;
3901         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3902         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3903         {
3904                 panel_size_x *= 0.5;
3905                 if (autocvar_hud_panel_physics_flip)
3906                         speed_offset_x = panel_size_x;
3907                 else
3908                         acceleration_offset_x = panel_size_x;
3909         }
3910         else
3911         {
3912                 panel_size_y *= 0.5;
3913                 if (autocvar_hud_panel_physics_flip)
3914                         speed_offset_y = panel_size_y;
3915                 else
3916                         acceleration_offset_y = panel_size_y;
3917         }
3918         float speed_baralign, acceleration_baralign;
3919         if (autocvar_hud_panel_physics_baralign == 1)
3920                 acceleration_baralign = speed_baralign = 1;
3921     else if(autocvar_hud_panel_physics_baralign == 4)
3922                 acceleration_baralign = speed_baralign = 2;
3923         else if (autocvar_hud_panel_physics_flip)
3924         {
3925                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3926                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3927         }
3928         else
3929         {
3930                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3931                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3932         }
3933         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3934                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3935
3936         //draw speed
3937         if(speed)
3938         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3939                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3940         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3941         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3942         {
3943                 tmp_size_x = panel_size_x * 0.75;
3944                 tmp_size_y = panel_size_y * text_scale;
3945                 if (speed_baralign)
3946                         tmp_offset_x = panel_size_x - tmp_size_x;
3947                 //else
3948                         //tmp_offset_x = 0;
3949                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3950                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3951
3952                 //draw speed unit
3953                 if (speed_baralign)
3954                         tmp_offset_x = 0;
3955                 else
3956                         tmp_offset_x = tmp_size_x;
3957                 if (autocvar_hud_panel_physics_speed_unit_show)
3958                 {
3959                         //tmp_offset_y = 0;
3960                         tmp_size_x = panel_size_x * (1 - 0.75);
3961                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3962                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3963                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3964                 }
3965         }
3966
3967         //compute and draw top speed
3968         if (autocvar_hud_panel_physics_topspeed)
3969         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3970         {
3971                 if (autocvar__hud_configure)
3972                 {
3973                         top_speed = floor( max_speed * 0.75 + 0.5 );
3974                         f = 1;
3975                 }
3976                 else
3977                 {
3978                         if (speed >= top_speed)
3979                         {
3980                                 top_speed = speed;
3981                                 top_speed_time = time;
3982                         }
3983                         if (top_speed != 0)
3984                         {
3985                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3986                                 // divide by f to make it start from 1
3987                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3988                         }
3989             else //hide top speed 0, it would be stupid
3990                                 f = 0;
3991                 }
3992                 if (f > 0)
3993                 {
3994                         //top speed progressbar peak
3995                         if(speed < top_speed)
3996                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3997                         {
3998                                 float peak_offset_x;
3999                                 vector peak_size = '0 0 0';
4000                                 if (speed_baralign == 0)
4001                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
4002                 else if (speed_baralign == 1)
4003                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
4004                 else // if (speed_baralign == 2)
4005                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
4006                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
4007                 peak_size_y = panel_size_y;
4008                 if (speed_baralign == 2) // draw two peaks, on both sides
4009                 {
4010                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4011                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4012                 }
4013                 else
4014                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4015                         }
4016
4017                         //top speed
4018                         tmp_offset_y = panel_size_y * 0.4;
4019                         tmp_size_x = panel_size_x * (1 - 0.75);
4020                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
4021                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
4022                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4023                 }
4024                 else
4025                         top_speed = 0;
4026         }
4027
4028         //draw acceleration
4029         if(acceleration)
4030         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4031         {
4032                 vector progressbar_color;
4033                 if(acceleration < 0)
4034                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4035                 else
4036                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4037
4038                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4039                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4040                         f = sqrt(f);
4041
4042                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4043                 {
4044                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
4045
4046                         if (acceleration_baralign == 1)
4047                                 tmp_offset_x = panel_size_x - tmp_size_x;
4048                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4049                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
4050                         else
4051                                 tmp_offset_x = 0;
4052                         tmp_offset_y = 0;
4053                 }
4054                 else
4055                 {
4056                         tmp_size = panel_size;
4057                         tmp_offset = '0 0 0';
4058                 }
4059
4060                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4061         }
4062         tmp_size_x = panel_size_x;
4063         tmp_size_y = panel_size_y * text_scale;
4064         tmp_offset_x = 0;
4065         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4066         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4067                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4068
4069         draw_endBoldFont();
4070 }
4071
4072 // CenterPrint (#16)
4073 //
4074 #define CENTERPRINT_MAX_MSGS 10
4075 #define CENTERPRINT_MAX_ENTRIES 50
4076 #define CENTERPRINT_SPACING 0.7
4077 float cpm_index;
4078 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4079 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4080 float centerprint_time[CENTERPRINT_MAX_MSGS];
4081 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4082 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4083 float centerprint_showing;
4084
4085 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4086 {
4087         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4088         float i, j;
4089
4090         if(strMessage == "" && new_id == 0)
4091                 return;
4092
4093         // strip trailing newlines
4094         j = strlen(strMessage) - 1;
4095         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4096                 --j;
4097         if (j < strlen(strMessage) - 1)
4098                 strMessage = substring(strMessage, 0, j + 1);
4099
4100         if(strMessage == "" && new_id == 0)
4101                 return;
4102
4103         // strip leading newlines
4104         j = 0;
4105         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4106                 ++j;
4107         if (j > 0)
4108                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4109
4110         if(strMessage == "" && new_id == 0)
4111                 return;
4112
4113         if (!centerprint_showing)
4114                 centerprint_showing = TRUE;
4115
4116         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4117         {
4118                 if (j == CENTERPRINT_MAX_MSGS)
4119                         j = 0;
4120                 if (new_id && new_id == centerprint_msgID[j])
4121                 {
4122                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4123                         {
4124                                 // fade out the current msg (duration and countdown_num are ignored)
4125                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4126                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4127                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4128                                 return;
4129                         }
4130                         break; // found a msg with the same id, at position j
4131                 }
4132         }
4133
4134         if (i == CENTERPRINT_MAX_MSGS)
4135         {
4136                 // a msg with the same id was not found, add the msg at the next position
4137                 --cpm_index;
4138                 if (cpm_index == -1)
4139                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4140                 j = cpm_index;
4141         }
4142         if(centerprint_messages[j])
4143                 strunzone(centerprint_messages[j]);
4144         centerprint_messages[j] = strzone(strMessage);
4145         centerprint_msgID[j] = new_id;
4146         if (duration < 0)
4147         {
4148                 centerprint_time[j] = -1;
4149                 centerprint_expire_time[j] = time;
4150         }
4151         else
4152         {
4153                 if(duration == 0)
4154                         duration = max(1, autocvar_hud_panel_centerprint_time);
4155                 centerprint_time[j] = duration;
4156                 centerprint_expire_time[j] = time + duration;
4157         }
4158         centerprint_countdown_num[j] = countdown_num;
4159 }
4160
4161 void centerprint_hud(string strMessage)
4162 {
4163         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4164 }
4165
4166 void reset_centerprint_messages(void)
4167 {
4168         float i;
4169         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4170         {
4171                 centerprint_expire_time[i] = 0;
4172                 centerprint_time[i] = 1;
4173                 centerprint_msgID[i] = 0;
4174                 if(centerprint_messages[i])
4175                         strunzone(centerprint_messages[i]);
4176                 centerprint_messages[i] = string_null;
4177         }
4178 }
4179 float hud_configure_cp_generation_time;
4180 void HUD_CenterPrint (void)
4181 {
4182         if(!autocvar__hud_configure)
4183         {
4184                 if(!autocvar_hud_panel_centerprint) return;
4185
4186                 if (hud_configure_prev && hud_configure_prev != -1)
4187                         reset_centerprint_messages();
4188         }
4189         else
4190         {
4191                 if (!hud_configure_prev)
4192                         reset_centerprint_messages();
4193                 if (time > hud_configure_cp_generation_time)
4194                 {
4195                         float r;
4196                         r = random();
4197                         if (r > 0.75)
4198                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4199                         else if (r > 0.5)
4200                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4201                         else
4202                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4203                         hud_configure_cp_generation_time = time + 1 + random()*4;
4204                 }
4205         }
4206
4207         // this panel fades only when the menu does
4208         float hud_fade_alpha_save = 0;
4209         if(scoreboard_fade_alpha)
4210         {
4211                 hud_fade_alpha_save = hud_fade_alpha;
4212                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4213         }
4214         HUD_Panel_UpdateCvars();
4215
4216         if(scoreboard_fade_alpha)
4217         {
4218                 hud_fade_alpha = hud_fade_alpha_save;
4219
4220                 // move the panel below the scoreboard
4221                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4222                         return;
4223                 vector target_pos;
4224
4225                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4226
4227                 if(target_pos_y > panel_pos_y)
4228                 {
4229                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4230                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4231                 }
4232         }
4233
4234         HUD_Panel_DrawBg(1);
4235
4236         if (!centerprint_showing)
4237                 return;
4238
4239         if(panel_bg_padding)
4240         {
4241                 panel_pos += '1 1 0' * panel_bg_padding;
4242                 panel_size -= '2 2 0' * panel_bg_padding;
4243         }
4244
4245         float entries, height;
4246         vector fontsize;
4247         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4248         // height = panel_size_y/entries;
4249         // fontsize = '1 1 0' * height;
4250         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4251         fontsize = '1 1 0' * height;
4252         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4253
4254         float i, j, k, n, g;
4255         float a, sz, align, current_msg_pos_y = 0, msg_size;
4256         vector pos;
4257         string ts;
4258         float all_messages_expired = TRUE;
4259
4260         pos = panel_pos;
4261         if (autocvar_hud_panel_centerprint_flip)
4262                 pos_y += panel_size_y;
4263         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4264         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4265         {
4266                 if (j == CENTERPRINT_MAX_MSGS)
4267                         j = 0;
4268                 if (centerprint_expire_time[j] <= time)
4269                 {
4270                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4271                         {
4272                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4273                                 if (centerprint_countdown_num[j] == 0)
4274                                         continue;
4275                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4276                         }
4277                         else if(centerprint_time[j] != -1)
4278                                 continue;
4279                 }
4280
4281                 all_messages_expired = FALSE;
4282
4283                 // fade the centerprint_hud in/out
4284                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4285                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4286                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4287                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4288                 else // Expiring soon, so fade it out.
4289                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4290
4291                 // while counting down show it anyway in order to hold the current message position
4292                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4293                         continue;
4294                 if (a > 1)
4295                         a = 1;
4296
4297                 // set the size from fading in/out before subsequent fading
4298                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4299
4300                 // also fade it based on positioning
4301                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4302                 {
4303                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4304                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4305                 }
4306                 a *= panel_fg_alpha;
4307
4308                 // finally set the size based on the new theAlpha from subsequent fading
4309                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4310                 drawfontscale = sz * '1 1 0';
4311
4312                 if (centerprint_countdown_num[j])
4313                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4314                 else
4315                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4316
4317                 if (autocvar_hud_panel_centerprint_flip)
4318                 {
4319                         // check if the message can be entirely shown
4320                         for(k = 0; k < n; ++k)
4321                         {
4322                                 getWrappedLine_remaining = argv(k);
4323                                 while(getWrappedLine_remaining)
4324                                 {
4325                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4326                                         if (ts != "")
4327                                                 pos_y -= fontsize_y;
4328                                         else
4329                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4330                                 }
4331                         }
4332                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4333                 }
4334
4335                 msg_size = pos_y;
4336                 for(k = 0; k < n; ++k)
4337                 {
4338                         getWrappedLine_remaining = argv(k);
4339                         while(getWrappedLine_remaining)
4340                         {
4341                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4342                                 if (ts != "")
4343                                 {
4344                                         if (align)
4345                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4346                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4347                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a, DRAWFLAG_NORMAL);
4348                                         pos_y += fontsize_y;
4349                                 }
4350                                 else
4351                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4352                         }
4353                 }
4354
4355                 ++g; // move next position number up
4356
4357                 msg_size = pos_y - msg_size;
4358                 if (autocvar_hud_panel_centerprint_flip)
4359                 {
4360                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4361                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4362                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4363
4364                         if (pos_y < panel_pos_y) // check if the next message can be shown
4365                         {
4366                                 drawfontscale = '1 1 0';
4367                                 return;
4368                         }
4369                 }
4370                 else
4371                 {
4372                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4373                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4374                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4375
4376                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4377                         {
4378                                 drawfontscale = '1 1 0';
4379                                 return;
4380                         }
4381                 }
4382         }
4383         drawfontscale = '1 1 0';
4384         if (all_messages_expired)
4385         {
4386                 centerprint_showing = FALSE;
4387                 reset_centerprint_messages();
4388         }
4389 }
4390
4391 // Buffs (#18)
4392 //
4393 void HUD_Buffs(void)
4394 {
4395         float buffs = getstati(STAT_BUFFS, 0, 24);
4396         if(!autocvar__hud_configure)
4397         {
4398                 if(!autocvar_hud_panel_buffs) return;
4399                 if(spectatee_status == -1) return;
4400                 if(getstati(STAT_HEALTH) <= 0) return;
4401                 if(!buffs) return;
4402         }
4403         else
4404         {
4405                 buffs = Buff_Type_first.items; // force first buff
4406         }
4407
4408         float b = 0; // counter to tell other functions that we have buffs
4409         entity e;
4410         string s = "";
4411         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4412         {
4413                 ++b;
4414                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4415                 if(s == "")
4416                         s = o;
4417                 else
4418                         s = strcat(s, " ", o);
4419         }
4420
4421         HUD_Panel_UpdateCvars();
4422
4423         draw_beginBoldFont();
4424
4425         vector pos, mySize;
4426         pos = panel_pos;
4427         mySize = panel_size;
4428
4429         HUD_Panel_DrawBg(bound(0, b, 1));
4430         if(panel_bg_padding)
4431         {
4432                 pos += '1 1 0' * panel_bg_padding;
4433                 mySize -= '2 2 0' * panel_bg_padding;
4434         }
4435
4436         //float panel_ar = mySize_x/mySize_y;
4437         //float is_vertical = (panel_ar < 1);
4438         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4439         vector buff_offset = '0 0 0';
4440
4441         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4442         {
4443                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4444                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4445         }
4446
4447         draw_endBoldFont();
4448 }
4449
4450
4451 /*
4452 ==================
4453 Main HUD system
4454 ==================
4455 */
4456
4457 void HUD_Reset (void)
4458 {
4459         // reset gametype specific icons
4460         if(gametype == MAPINFO_TYPE_CTF)
4461                 HUD_Mod_CTF_Reset();
4462 }
4463
4464 void HUD_Main (void)
4465 {
4466         float i;
4467         // global hud theAlpha fade
4468         if(menu_enabled == 1)
4469                 hud_fade_alpha = 1;
4470         else
4471                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4472
4473         if(scoreboard_fade_alpha)
4474                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4475
4476         HUD_Configure_Frame();
4477
4478         if(intermission == 2) // no hud during mapvote
4479                 hud_fade_alpha = 0;
4480
4481         // panels that we want to be active together with the scoreboard
4482         // they must fade only when the menu does
4483         if(scoreboard_fade_alpha == 1)
4484         {
4485                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4486                 return;
4487         }
4488
4489         if(!autocvar__hud_configure && !hud_fade_alpha)
4490                 return;
4491
4492         // Drawing stuff
4493         if (hud_skin_prev != autocvar_hud_skin)
4494         {
4495                 if (hud_skin_path)
4496                         strunzone(hud_skin_path);
4497                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4498                 if (hud_skin_prev)
4499                         strunzone(hud_skin_prev);
4500                 hud_skin_prev = strzone(autocvar_hud_skin);
4501         }
4502
4503     current_player = player_localentnum;
4504
4505         // draw the dock
4506         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4507         {
4508                 float f;
4509                 vector color;
4510                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4511                 if((teamplay) && hud_dock_color_team) {
4512                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4513                                 color = '1 0 0' * hud_dock_color_team;
4514                         else
4515                                 color = myteamcolors * hud_dock_color_team;
4516                 }
4517                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4518                         color = '1 0 0' * hud_dock_color_team;
4519                 }
4520                 else
4521                 {
4522                         string hud_dock_color = autocvar_hud_dock_color;
4523                         if(hud_dock_color == "shirt") {
4524                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4525                                 color = colormapPaletteColor(floor(f / 16), 0);
4526                         }
4527                         else if(hud_dock_color == "pants") {
4528                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4529                                 color = colormapPaletteColor(f % 16, 1);
4530                         }
4531                         else
4532                                 color = stov(hud_dock_color);
4533                 }
4534
4535                 string pic;
4536                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4537                 if(precache_pic(pic) == "") {
4538                         pic = strcat(hud_skin_path, "/dock_medium");
4539                         if(precache_pic(pic) == "") {
4540                                 pic = "gfx/hud/default/dock_medium";
4541                         }
4542                 }
4543                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4544         }
4545
4546         // cache the panel order into the panel_order array
4547         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4548                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4549                         panel_order[i] = -1;
4550                 string s = "";
4551                 float p_num, warning = false;
4552                 float argc = tokenize_console(autocvar__hud_panelorder);
4553                 if (argc > HUD_PANEL_NUM)
4554                         warning = true;
4555                 //first detect wrong/missing panel numbers
4556                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4557                         p_num = stof(argv(i));
4558                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4559                                 if (panel_order[p_num] == -1) //found for the first time?
4560                                         s = strcat(s, ftos(p_num), " ");
4561                                 panel_order[p_num] = 1; //mark as found
4562                         }
4563                         else
4564                                 warning = true;
4565                 }
4566                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4567                         if (panel_order[i] == -1) {
4568                                 warning = true;
4569                                 s = strcat(s, ftos(i), " "); //add missing panel number
4570                         }
4571                 }
4572                 if (warning)
4573                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4574
4575                 cvar_set("_hud_panelorder", s);
4576                 if(hud_panelorder_prev)
4577                         strunzone(hud_panelorder_prev);
4578                 hud_panelorder_prev = strzone(s);
4579
4580                 //now properly set panel_order
4581                 tokenize_console(s);
4582                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4583                         panel_order[i] = stof(argv(i));
4584                 }
4585         }
4586
4587         hud_draw_maximized = 0;
4588         // draw panels in order specified by panel_order array
4589         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4590                 (panel = hud_panel[panel_order[i]]).panel_draw();
4591
4592         hud_draw_maximized = 1; // panels that may be maximized must check this var
4593         // draw maximized panels on top
4594         if(hud_panel_radar_maximized)
4595                 (panel = HUD_PANEL(RADAR)).panel_draw();
4596         if(autocvar__con_chat_maximized)
4597                 (panel = HUD_PANEL(CHAT)).panel_draw();
4598
4599         HUD_Configure_PostDraw();
4600
4601         hud_configure_prev = autocvar__hud_configure;
4602 }