qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * theScale_x;
 148         drawstring(position, text, theScale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale_x);
 154         drawstring(position, text, theScale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 222         else
 223                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if(!playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 void HUD_Weapons(void)
 412 {
 413         // declarations
 414         WepSet weapons_stat = WepSet_GetFromStat();
 415         float i, f, a;
 416         float screen_ar, center_x = 0, center_y;
 417         float weapon_count, weapon_id;
 418         float row, column, rows = 0, columns;
 419         float aspect = autocvar_hud_panel_weapons_aspect;
 420
 421         float panel_weapon_accuracy;
 422
 423         float timeout = autocvar_hud_panel_weapons_timeout;
 424         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 425         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 426
 427         float ammo_full;
 428         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 429         vector ammo_color = '1 0 1';
 430         float ammo_alpha = 1;
 431
 432         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 433         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 434
 435         vector weapon_pos, weapon_size = '0 0 0';
 436         local noref vector old_panel_size; // fteqcc sucks
 437         vector color;
 438
 439         // check to see if we want to continue
 440         if(hud != HUD_NORMAL) { return; }
 441
 442         if(!autocvar__hud_configure)
 443         {
 444                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 445                         return;
 446                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 447                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 448                 {
 449                         weaponprevtime = time;
 450                         return;
 451                 }
 452         }
 453
 454         // update generic hud functions
 455         HUD_Panel_UpdateCvars();
 456
 457         draw_beginBoldFont();
 458
 459         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 460         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 461         {
 462                 float weapon_cnt;
 463                 if(weaponorder_bypriority)
 464                         strunzone(weaponorder_bypriority);
 465                 if(weaponorder_byimpulse)
 466                         strunzone(weaponorder_byimpulse);
 467
 468                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 469                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 470                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 471
 472                 weapon_cnt = 0;
 473                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 474                 {
 475                         self = get_weaponinfo(i);
 476                         if(self.impulse >= 0)
 477                         {
 478                                 weaponorder[weapon_cnt] = self;
 479                                 ++weapon_cnt;
 480                         }
 481                 }
 482                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 483                         weaponorder[i] = world;
 484                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 485
 486                 weaponorder_cmp_str = string_null;
 487         }
 488
 489         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 490                 complain_weapon = 0;
 491
 492         // determine which weapons are going to be shown
 493         if (autocvar_hud_panel_weapons_onlyowned)
 494         {
 495                 if(autocvar__hud_configure)
 496                 {
 497                         if (!weapons_stat)
 498                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 499                                         weapons_stat |= WepSet_FromWeapon(i);
 500
 501                         if(menu_enabled != 2)
 502                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 503                 }
 504
 505                 // do we own this weapon?
 506                 weapon_count = 0;
 507                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 508                         if(weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon))
 509                                 ++weapon_count;
 510
 511                 // add it anyway if weaponcomplain is shown
 512                 if(complain_weapon)
 513                         ++weapon_count;
 514
 515                 // might as well commit suicide now, no reason to live ;)
 516                 if (weapon_count == 0)
 517                 {
 518                         draw_endBoldFont();
 519                         return;
 520                 }
 521
 522                 old_panel_size = panel_size;
 523                 if(panel_bg_padding)
 524                         old_panel_size -= '2 2 0' * panel_bg_padding;
 525
 526                 // first find values for the standard table (with all the weapons)
 527                 rows = old_panel_size_y/old_panel_size_x;
 528                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 529                 columns = ceil(WEP_COUNT/rows);
 530                 weapon_size_x = old_panel_size_x / columns;
 531                 weapon_size_y = old_panel_size_y / rows;
 532
 533                 // change table values to include only the owned weapons
 534                 float columns_save = columns;
 535                 if(weapon_count <= rows)
 536                 {
 537                         rows = weapon_count;
 538                         columns = 1;
 539                 }
 540                 else
 541                         columns = ceil(weapon_count / rows);
 542
 543                 // enlarge weapon_size to match desired aspect ratio in order to capitalize on panel space
 544                 if(columns < columns_save)
 545                         weapon_size_x = min(old_panel_size_x / columns, aspect * weapon_size_y);
 546
 547                 // reduce size of the panel
 548                 panel_size_x = columns * weapon_size_x;
 549                 panel_size_y = rows * weapon_size_y;
 550                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 551                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 552                 if(panel_bg_padding)
 553                         panel_size += '2 2 0' * panel_bg_padding;
 554         }
 555         else
 556                 weapon_count = WEP_COUNT;
 557
 558         // animation for fading in/out the panel respectively when not in use
 559         if(!autocvar__hud_configure)
 560         {
 561                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 562                 {
 563                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 564
 565                         // fade the panel alpha
 566                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 567                         {
 568                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 569                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 570                         }
 571                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 572                         {
 573                                 panel_bg_alpha *= (1 - f);
 574                                 panel_fg_alpha *= (1 - f);
 575                         }
 576
 577                         // move the panel off the screen
 578                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 579                         {
 580                                 f *= f; // for a cooler movement
 581                                 center_x = panel_pos_x + panel_size_x/2;
 582                                 center_y = panel_pos_y + panel_size_y/2;
 583                                 screen_ar = vid_conwidth/vid_conheight;
 584                                 if (center_x/center_y < screen_ar) //bottom left
 585                                 {
 586                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 587                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 588                                         else //left
 589                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 590                                 }
 591                                 else //top right
 592                                 {
 593                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 594                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 595                                         else //top
 596                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 597                                 }
 598                                 if(f == 1)
 599                                         center_x = -1; // mark the panel as off screen
 600                         }
 601                         weaponprevtime = time - (1 - f) * timein_effect_length;
 602                 }
 603                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 604                 {
 605                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 606
 607                         // fade the panel alpha
 608                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 609                         {
 610                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 611                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 612                         }
 613                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 614                         {
 615                                 panel_bg_alpha *= (f);
 616                                 panel_fg_alpha *= (f);
 617                         }
 618
 619                         // move the panel back on screen
 620                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 621                         {
 622                                 f *= f; // for a cooler movement
 623                                 f = 1 - f;
 624                                 center_x = panel_pos_x + panel_size_x/2;
 625                                 center_y = panel_pos_y + panel_size_y/2;
 626                                 screen_ar = vid_conwidth/vid_conheight;
 627                                 if (center_x/center_y < screen_ar) //bottom left
 628                                 {
 629                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 630                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 631                                         else //left
 632                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 633                                 }
 634                                 else //top right
 635                                 {
 636                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 637                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 638                                         else //top
 639                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 640                                 }
 641                         }
 642                 }
 643         }
 644
 645         // draw the background, then change the virtual size of it to better fit other items inside
 646         HUD_Panel_DrawBg(1);
 647
 648         if(center_x == -1)
 649         {
 650                 draw_endBoldFont();
 651                 return;
 652         }
 653
 654         if(panel_bg_padding)
 655         {
 656                 panel_pos += '1 1 0' * panel_bg_padding;
 657                 panel_size -= '2 2 0' * panel_bg_padding;
 658         }
 659
 660         // after the sizing and animations are done, update the other values
 661
 662         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 663         {
 664                 rows = panel_size_y/panel_size_x;
 665                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 666                 columns = ceil(weapon_count/rows);
 667                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 668         }
 669
 670         // calculate position/size for visual bar displaying ammount of ammo status
 671         if (autocvar_hud_panel_weapons_ammo)
 672         {
 673                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 674                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 675
 676                 if(weapon_size_x/weapon_size_y > aspect)
 677                 {
 678                         barsize_x = aspect * weapon_size_y;
 679                         barsize_y = weapon_size_y;
 680                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 681                 }
 682                 else
 683                 {
 684                         barsize_y = 1/aspect * weapon_size_x;
 685                         barsize_x = weapon_size_x;
 686                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 687                 }
 688         }
 689         if(autocvar_hud_panel_weapons_accuracy)
 690                 Accuracy_LoadColors();
 691
 692         row = column = 0;
 693         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 694         {
 695                 // retrieve information about the current weapon to be drawn
 696                 self = weaponorder[i];
 697                 weapon_id = self.impulse;
 698
 699                 // skip if this weapon doesn't exist
 700                 if(!self || weapon_id < 0) { continue; }
 701
 702                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 703                 if(autocvar_hud_panel_weapons_onlyowned)
 704                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 705                         continue;
 706
 707                 // figure out the drawing position of weapon
 708                 weapon_pos = (panel_pos
 709                         + eX * column * weapon_size_x
 710                         + eY * row * weapon_size_y);
 711
 712                 // draw background behind currently selected weapon
 713                 if(self.weapon == switchweapon)
 714                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 715
 716                 // draw the weapon accuracy
 717                 if(autocvar_hud_panel_weapons_accuracy)
 718                 {
 719                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 720                         if(panel_weapon_accuracy >= 0)
 721                         {
 722                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 723                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 724                         }
 725                 }
 726
 727                 // drawing all the weapon items
 728                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 729                 {
 730                         // draw the weapon image
 731                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 732
 733                         // draw weapon label string
 734                         switch(autocvar_hud_panel_weapons_label)
 735                         {
 736                                 case 1: // weapon number
 737                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 738                                         break;
 739
 740                                 case 2: // bind
 741                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 742                                         break;
 743
 744                                 case 3: // weapon name
 745                                         drawstring(weapon_pos, strtolower(self.message), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 746                                         break;
 747
 748                                 default: // nothing
 749                                         break;
 750                         }
 751
 752                         // draw ammo status bar
 753                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 754                         {
 755                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 756
 757                                 if(a > 0)
 758                                 {
 759                                         switch(self.ammo_field)
 760                                         {
 761                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 762                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 763                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 764                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 765                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 766                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 767                                                 default: ammo_full = 60;
 768                                         }
 769
 770                                         drawsetcliparea(
 771                                                 weapon_pos_x + baroffset_x,
 772                                                 weapon_pos_y + baroffset_y,
 773                                                 barsize_x * bound(0, a/ammo_full, 1),
 774                                                 barsize_y
 775                                         );
 776
 777                                         drawpic_aspect_skin(
 778                                                 weapon_pos,
 779                                                 "weapon_ammo",
 780                                                 weapon_size,
 781                                                 ammo_color,
 782                                                 ammo_alpha,
 783                                                 DRAWFLAG_NORMAL
 784                                         );
 785
 786                                         drawresetcliparea();
 787                                 }
 788                         }
 789                 }
 790                 else // draw a "ghost weapon icon" if you don't have the weapon
 791                 {
 792                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 793                 }
 794
 795                 // draw the complain message
 796                 if(self.weapon == complain_weapon)
 797                 {
 798                         if(fadetime)
 799                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 800                         else
 801                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 802
 803                         string s;
 804                         if(complain_weapon_type == 0) {
 805                                 s = _("Out of ammo");
 806                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 807                         }
 808                         else if(complain_weapon_type == 1) {
 809                                 s = _("Don't have");
 810                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 811                         }
 812                         else {
 813                                 s = _("Unavailable");
 814                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 815                         }
 816                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 817                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 818                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 819                 }
 820
 821                 // continue with new position for the next weapon
 822                 ++row;
 823                 if(row >= rows)
 824                 {
 825                         row = 0;
 826                         ++column;
 827                 }
 828         }
 829
 830         draw_endBoldFont();
 831 }
 832
 833 // Ammo (#1)
 834 void DrawNadeScoreBar(vector myPos, vector mySize, vector color)
 835 {
 836
 837         HUD_Panel_DrawProgressBar(
 838                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x,
 839                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x,
 840                 autocvar_hud_panel_ammo_progressbar_name,
 841                 getstatf(STAT_NADE_BONUS_SCORE), 0, 0, color,
 842                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 843
 844 }
 845
 846 void DrawAmmoNades(vector myPos, vector mySize, float draw_expanding, float expand_time)
 847 {
 848         float theAlpha = 1, a, b;
 849         vector nade_color, picpos, numpos;
 850
 851         nade_color = Nade_Color(getstati(STAT_NADE_BONUS_TYPE));
 852
 853         a = getstatf(STAT_NADE_BONUS);
 854         b = getstatf(STAT_NADE_BONUS_SCORE);
 855
 856         if(autocvar_hud_panel_ammo_iconalign)
 857         {
 858                 numpos = myPos;
 859                 picpos = myPos + eX * 2 * mySize_y;
 860         }
 861         else
 862         {
 863                 numpos = myPos + eX * mySize_y;
 864                 picpos = myPos;
 865         }
 866
 867         DrawNadeScoreBar(myPos, mySize, nade_color);
 868
 869         if(b > 0 || a > 0)
 870         {
 871                 if(autocvar_hud_panel_ammo_text)
 872                         drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 873
 874                 if(draw_expanding)
 875                         drawpic_aspect_skin_expanding(picpos, "nade_nbg", '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, expand_time);
 876
 877                 drawpic_aspect_skin(picpos, "nade_bg" , '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 878                 drawpic_aspect_skin(picpos, "nade_nbg" , '1 1 0' * mySize_y, nade_color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 879         }
 880 }
 881
 882 void DrawAmmoItem(vector myPos, vector mySize, .float ammoType, float isCurrent, float isInfinite)
 883 {
 884         if(ammoType == ammo_none)
 885                 return;
 886
 887         // Initialize variables
 888
 889         float ammo;
 890         if(autocvar__hud_configure)
 891         {
 892                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
 893                 ammo = 60;
 894         }
 895         else
 896                 ammo = getstati(GetAmmoStat(ammoType));
 897
 898         if(!isCurrent)
 899         {
 900                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
 901                 myPos = myPos + (mySize - mySize * scale) * 0.5;
 902                 mySize = mySize * scale;
 903         }
 904
 905         vector iconPos, textPos;
 906         if(autocvar_hud_panel_ammo_iconalign)
 907         {
 908                 iconPos = myPos + eX * 2 * mySize_y;
 909                 textPos = myPos;
 910         }
 911         else
 912         {
 913                 iconPos = myPos;
 914                 textPos = myPos + eX * mySize_y;
 915         }
 916
 917         float isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
 918
 919         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
 920         vector textColor;
 921         if(isInfinite)
 922                 textColor = '0.2 0.95 0';
 923         else if(isShadowed)
 924                 textColor = '0 0 0';
 925         else if(ammo < 10)
 926                 textColor = '0.8 0.04 0';
 927         else
 928                 textColor = '1 1 1';
 929
 930         float alpha;
 931         if(isCurrent)
 932                 alpha = panel_fg_alpha;
 933         else if(isShadowed)
 934                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
 935         else
 936                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
 937
 938         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
 939
 940         // Draw item
 941
 942         if(isCurrent)
 943                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 944
 945         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
 946                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
 947
 948         if(autocvar_hud_panel_ammo_text)
 949                 drawstring_aspect(textPos, text, eX * (2/3) * mySize_x + eY * mySize_y, textColor, alpha, DRAWFLAG_NORMAL);
 950
 951         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize_y, iconColor, alpha, DRAWFLAG_NORMAL);
 952 }
 953
 954 float nade_prevstatus;
 955 float nade_prevframe;
 956 float nade_statuschange_time;
 957 void HUD_Ammo(void)
 958 {
 959         if(hud != HUD_NORMAL) return;
 960         if(!autocvar__hud_configure)
 961         {
 962                 if(!autocvar_hud_panel_ammo) return;
 963                 if(spectatee_status == -1) return;
 964         }
 965
 966         HUD_Panel_UpdateCvars();
 967
 968         draw_beginBoldFont();
 969
 970         vector pos, mySize;
 971         pos = panel_pos;
 972         mySize = panel_size;
 973
 974         HUD_Panel_DrawBg(1);
 975         if(panel_bg_padding)
 976         {
 977                 pos += '1 1 0' * panel_bg_padding;
 978                 mySize -= '2 2 0' * panel_bg_padding;
 979         }
 980
 981         float rows = 0, columns, row, column;
 982         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
 983         float draw_nades = (nade_cnt > 0 || nade_score > 0), nade_statuschange_elapsedtime;
 984         float total_ammo_count;
 985
 986         vector ammo_size;
 987         if (autocvar_hud_panel_ammo_onlycurrent)
 988                 total_ammo_count = 1;
 989         else
 990                 total_ammo_count = AMMO_COUNT;
 991
 992         if(draw_nades)
 993         {
 994                 ++total_ammo_count;
 995                 if (nade_cnt != nade_prevframe)
 996                 {
 997                         nade_statuschange_time = time;
 998                         nade_prevstatus = nade_prevframe;
 999                         nade_prevframe = nade_cnt;
1000                 }
1001         }
1002         else
1003                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1004
1005         rows = mySize_y/mySize_x;
1006         rows = bound(1, floor((sqrt(4 * (3/1) * rows * (total_ammo_count) + rows * rows) + rows + 0.5) / 2), (total_ammo_count));
1007         //                               ^^^ ammo item aspect goes here
1008
1009         columns = ceil((total_ammo_count)/rows);
1010
1011         ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
1012
1013
1014         local vector offset = '0 0 0'; // fteqcc sucks
1015         float newSize;
1016         if(ammo_size_x/ammo_size_y > 3)
1017         {
1018                 newSize = 3 * ammo_size_y;
1019                 offset_x = ammo_size_x - newSize;
1020                 pos_x += offset_x/2;
1021                 ammo_size_x = newSize;
1022         }
1023         else
1024         {
1025                 newSize = 1/3 * ammo_size_x;
1026                 offset_y = ammo_size_y - newSize;
1027                 pos_y += offset_y/2;
1028                 ammo_size_y = newSize;
1029         }
1030
1031         float i;
1032         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1033         row = column = 0;
1034         if(autocvar_hud_panel_ammo_onlycurrent)
1035         {
1036                 if(autocvar__hud_configure)
1037                 {
1038                         DrawAmmoItem(pos, ammo_size, ammo_rockets, TRUE, FALSE);
1039                 }
1040                 else
1041                 {
1042                         DrawAmmoItem(
1043                                 pos,
1044                                 ammo_size,
1045                                 (get_weaponinfo(switchweapon)).ammo_field,
1046                                 TRUE,
1047                                 infinite_ammo
1048                         );
1049                 }
1050
1051                 ++row;
1052                 if(row >= rows)
1053                 {
1054                         row = 0;
1055                         column = column + 1;
1056                 }
1057         }
1058         else
1059         {
1060                 .float ammotype;
1061                 row = column = 0;
1062                 for(i = 0; i < AMMO_COUNT; ++i)
1063                 {
1064                         ammotype = GetAmmoFieldFromNum(i);
1065                         DrawAmmoItem(
1066                                 pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y),
1067                                 ammo_size,
1068                                 ammotype,
1069                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1070                                 infinite_ammo
1071                         );
1072
1073                         ++row;
1074                         if(row >= rows)
1075                         {
1076                                 row = 0;
1077                                 column = column + 1;
1078                         }
1079                 }
1080         }
1081
1082         if (draw_nades)
1083         {
1084                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1085
1086                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1087
1088                 DrawAmmoNades(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1089         }
1090
1091         draw_endBoldFont();
1092 }
1093
1094 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1095 {
1096         vector newPos = '0 0 0', newSize = '0 0 0';
1097         vector picpos, numpos;
1098
1099         if (vertical)
1100         {
1101                 if(mySize_y/mySize_x > 2)
1102                 {
1103                         newSize_y = 2 * mySize_x;
1104                         newSize_x = mySize_x;
1105
1106                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1107                         newPos_x = myPos_x;
1108                 }
1109                 else
1110                 {
1111                         newSize_x = 1/2 * mySize_y;
1112                         newSize_y = mySize_y;
1113
1114                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1115                         newPos_y = myPos_y;
1116                 }
1117
1118                 if(icon_right_align)
1119                 {
1120                         numpos = newPos;
1121                         picpos = newPos + eY * newSize_x;
1122                 }
1123                 else
1124                 {
1125                         picpos = newPos;
1126                         numpos = newPos + eY * newSize_x;
1127                 }
1128
1129                 newSize_y /= 2;
1130                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1131                 // make number smaller than icon, it looks better
1132                 // reduce only y to draw numbers with different number of digits with the same y size
1133                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1134                 newSize_y *= 0.7;
1135                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1136                 return;
1137         }
1138
1139         if(mySize_x/mySize_y > 3)
1140         {
1141                 newSize_x = 3 * mySize_y;
1142                 newSize_y = mySize_y;
1143
1144                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1145                 newPos_y = myPos_y;
1146         }
1147         else
1148         {
1149                 newSize_y = 1/3 * mySize_x;
1150                 newSize_x = mySize_x;
1151
1152                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1153                 newPos_x = myPos_x;
1154         }
1155
1156         if(icon_right_align) // right align
1157         {
1158                 numpos = newPos;
1159                 picpos = newPos + eX * 2 * newSize_y;
1160         }
1161         else // left align
1162         {
1163                 numpos = newPos + eX * newSize_y;
1164                 picpos = newPos;
1165         }
1166
1167         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1168         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1169         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1170         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1171 }
1172
1173 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1174 {
1175         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1176 }
1177
1178 // Powerups (#2)
1179 //
1180 void HUD_Powerups(void)
1181 {
1182         float strength_time, shield_time, superweapons_time;
1183         if(!autocvar__hud_configure)
1184         {
1185                 if(!autocvar_hud_panel_powerups) return;
1186                 if(spectatee_status == -1) return;
1187                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1188                 if (getstati(STAT_HEALTH) <= 0) return;
1189
1190                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1191                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1192                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1193
1194                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1195                         superweapons_time = 99; // force max
1196
1197                 // prevent stuff to show up on mismatch that will be fixed next frame
1198                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1199                         superweapons_time = 0;
1200         }
1201         else
1202         {
1203                 strength_time = 15;
1204                 shield_time = 27;
1205                 superweapons_time = 13;
1206         }
1207
1208         HUD_Panel_UpdateCvars();
1209
1210         draw_beginBoldFont();
1211
1212         vector pos, mySize;
1213         pos = panel_pos;
1214         mySize = panel_size;
1215
1216         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1217         if(panel_bg_padding)
1218         {
1219                 pos += '1 1 0' * panel_bg_padding;
1220                 mySize -= '2 2 0' * panel_bg_padding;
1221         }
1222
1223         float panel_ar = mySize_x/mySize_y;
1224         float is_vertical = (panel_ar < 1);
1225         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1226
1227         float superweapons_is = -1;
1228
1229         if(superweapons_time)
1230         {
1231                 if(strength_time)
1232                 {
1233                         if(shield_time)
1234                                 superweapons_is = 0;
1235                         else
1236                                 superweapons_is = 2;
1237                 }
1238                 else
1239                 {
1240                         if(shield_time)
1241                                 superweapons_is = 1;
1242                         else
1243                                 superweapons_is = 2;
1244                 }
1245         }
1246
1247         // FIXME handle superweapons here
1248         if(superweapons_is == 0)
1249         {
1250                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1251                 {
1252                         mySize_x *= (1.0 / 3.0);
1253                         superweapons_offset_x = mySize_x;
1254                         if (autocvar_hud_panel_powerups_flip)
1255                                 shield_offset_x = 2*mySize_x;
1256                         else
1257                                 strength_offset_x = 2*mySize_x;
1258                 }
1259                 else
1260                 {
1261                         mySize_y *= (1.0 / 3.0);
1262                         superweapons_offset_y = mySize_y;
1263                         if (autocvar_hud_panel_powerups_flip)
1264                                 shield_offset_y = 2*mySize_y;
1265                         else
1266                                 strength_offset_y = 2*mySize_y;
1267                 }
1268         }
1269         else
1270         {
1271                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1272                 {
1273                         mySize_x *= 0.5;
1274                         if (autocvar_hud_panel_powerups_flip)
1275                                 shield_offset_x = mySize_x;
1276                         else
1277                                 strength_offset_x = mySize_x;
1278                 }
1279                 else
1280                 {
1281                         mySize_y *= 0.5;
1282                         if (autocvar_hud_panel_powerups_flip)
1283                                 shield_offset_y = mySize_y;
1284                         else
1285                                 strength_offset_y = mySize_y;
1286                 }
1287         }
1288
1289         float shield_baralign, strength_baralign, superweapons_baralign;
1290         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1291
1292         if (autocvar_hud_panel_powerups_flip)
1293         {
1294                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1295                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1296                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1297                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1298         }
1299         else
1300         {
1301                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1302                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1303                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1304                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1305         }
1306
1307         if(superweapons_is == 0)
1308         {
1309                 superweapons_iconalign = strength_iconalign;
1310                 superweapons_baralign = 2;
1311         }
1312         else if(superweapons_is == 1)
1313         {
1314                 superweapons_offset = strength_offset;
1315                 superweapons_iconalign = strength_iconalign;
1316                 superweapons_baralign = strength_baralign;
1317         }
1318         else // if(superweapons_is == 2)
1319         {
1320                 superweapons_offset = shield_offset;
1321                 superweapons_iconalign = shield_iconalign;
1322                 superweapons_baralign = shield_baralign;
1323         }
1324
1325         if(shield_time)
1326         {
1327                 const float maxshield = 30;
1328                 float shield = ceil(shield_time);
1329                 if(autocvar_hud_panel_powerups_progressbar)
1330                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1331                 if(autocvar_hud_panel_powerups_text)
1332                 {
1333                         if(shield > 1)
1334                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1335                         if(shield <= 5)
1336                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1337                 }
1338         }
1339
1340         if(strength_time)
1341         {
1342                 const float maxstrength = 30;
1343                 float strength = ceil(strength_time);
1344                 if(autocvar_hud_panel_powerups_progressbar)
1345                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1346                 if(autocvar_hud_panel_powerups_text)
1347                 {
1348                         if(strength > 1)
1349                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1350                         if(strength <= 5)
1351                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1352                 }
1353         }
1354
1355         if(superweapons_time)
1356         {
1357                 const float maxsuperweapons = 30;
1358                 float superweapons = ceil(superweapons_time);
1359                 if(autocvar_hud_panel_powerups_progressbar)
1360                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1361                 if(autocvar_hud_panel_powerups_text)
1362                 {
1363                         if(superweapons > 1)
1364                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1365                         if(superweapons <= 5)
1366                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1367                 }
1368         }
1369
1370         draw_endBoldFont();
1371 }
1372
1373 // Health/armor (#3)
1374 //
1375
1376 // prev_* vars contain the health/armor at the previous FRAME
1377 // set to -1 when player is dead or was not playing
1378 float prev_health, prev_armor;
1379 float health_damagetime, armor_damagetime;
1380 float health_beforedamage, armor_beforedamage;
1381 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1382 float old_p_health, old_p_armor;
1383 float old_p_healthtime, old_p_armortime;
1384 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1385 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1386 float prev_p_health, prev_p_armor;
1387
1388 void HUD_HealthArmor(void)
1389 {
1390         float armor, health, fuel;
1391         if(!autocvar__hud_configure)
1392         {
1393                 if(!autocvar_hud_panel_healtharmor) return;
1394                 if(hud != HUD_NORMAL) return;
1395                 if(spectatee_status == -1) return;
1396
1397                 health = getstati(STAT_HEALTH);
1398                 if(health <= 0)
1399                 {
1400                         prev_health = -1;
1401                         return;
1402                 }
1403                 armor = getstati(STAT_ARMOR);
1404
1405                 // code to check for spectatee_status changes is in Ent_ClientData()
1406                 // prev_p_health and prev_health can be set to -1 there
1407
1408                 if (prev_p_health == -1)
1409                 {
1410                         // no effect
1411                         health_beforedamage = 0;
1412                         armor_beforedamage = 0;
1413                         health_damagetime = 0;
1414                         armor_damagetime = 0;
1415                         prev_health = health;
1416                         prev_armor = armor;
1417                         old_p_health = health;
1418                         old_p_armor = armor;
1419                         prev_p_health = health;
1420                         prev_p_armor = armor;
1421                 }
1422                 else if (prev_health == -1)
1423                 {
1424                         //start the load effect
1425                         health_damagetime = 0;
1426                         armor_damagetime = 0;
1427                         prev_health = 0;
1428                         prev_armor = 0;
1429                 }
1430                 fuel = getstati(STAT_FUEL);
1431         }
1432         else
1433         {
1434                 health = 150;
1435                 armor = 75;
1436                 fuel = 20;
1437         }
1438
1439         HUD_Panel_UpdateCvars();
1440         vector pos, mySize;
1441         pos = panel_pos;
1442         mySize = panel_size;
1443
1444         HUD_Panel_DrawBg(1);
1445         if(panel_bg_padding)
1446         {
1447                 pos += '1 1 0' * panel_bg_padding;
1448                 mySize -= '2 2 0' * panel_bg_padding;
1449         }
1450
1451         float baralign = autocvar_hud_panel_healtharmor_baralign;
1452         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1453
1454     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1455     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1456         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1457         {
1458                 vector v;
1459                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1460
1461                 float x;
1462                 x = floor(v_x + 1);
1463
1464         float maxtotal = maxhealth + maxarmor;
1465                 string biggercount;
1466                 if(v_z) // NOT fully armored
1467                 {
1468                         biggercount = "health";
1469                         if(autocvar_hud_panel_healtharmor_progressbar)
1470                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1471                         if(armor)
1472             if(autocvar_hud_panel_healtharmor_text)
1473                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1474                 }
1475                 else
1476                 {
1477                         biggercount = "armor";
1478                         if(autocvar_hud_panel_healtharmor_progressbar)
1479                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1480                         if(health)
1481             if(autocvar_hud_panel_healtharmor_text)
1482                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1483                 }
1484         if(autocvar_hud_panel_healtharmor_text)
1485                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1486
1487                 if(fuel)
1488                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1489         }
1490         else
1491         {
1492                 float panel_ar = mySize_x/mySize_y;
1493                 float is_vertical = (panel_ar < 1);
1494                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1495                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1496                 {
1497                         mySize_x *= 0.5;
1498                         if (autocvar_hud_panel_healtharmor_flip)
1499                                 health_offset_x = mySize_x;
1500                         else
1501                                 armor_offset_x = mySize_x;
1502                 }
1503                 else
1504                 {
1505                         mySize_y *= 0.5;
1506                         if (autocvar_hud_panel_healtharmor_flip)
1507                                 health_offset_y = mySize_y;
1508                         else
1509                                 armor_offset_y = mySize_y;
1510                 }
1511
1512                 float health_baralign, armor_baralign, fuel_baralign;
1513                 float health_iconalign, armor_iconalign;
1514                 if (autocvar_hud_panel_healtharmor_flip)
1515                 {
1516                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1517                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1518                         fuel_baralign = health_baralign;
1519                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1520                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1521                 }
1522                 else
1523                 {
1524                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1525                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1526                         fuel_baralign = armor_baralign;
1527                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1528                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1529                 }
1530
1531                 //if(health)
1532                 {
1533                         if(autocvar_hud_panel_healtharmor_progressbar)
1534                         {
1535                                 float p_health, pain_health_alpha;
1536                                 p_health = health;
1537                                 pain_health_alpha = 1;
1538                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1539                                 {
1540                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1541                                         {
1542                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1543                                                 {
1544                                                         if (time - old_p_healthtime < 1)
1545                                                                 old_p_health = prev_p_health;
1546                                                         else
1547                                                                 old_p_health = prev_health;
1548                                                         old_p_healthtime = time;
1549                                                 }
1550                                                 if (time - old_p_healthtime < 1)
1551                                                 {
1552                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1553                                                         prev_p_health = p_health;
1554                                                 }
1555                                         }
1556                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1557                                         {
1558                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1559                                                 {
1560                                                         if (time - health_damagetime >= 1)
1561                                                                 health_beforedamage = prev_health;
1562                                                         health_damagetime = time;
1563                                                 }
1564                                                 if (time - health_damagetime < 1)
1565                                                 {
1566                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1567                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1568                                                 }
1569                                         }
1570                                         prev_health = health;
1571
1572                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1573                                         {
1574                                                 float BLINK_FACTOR = 0.15;
1575                                                 float BLINK_BASE = 0.85;
1576                                                 float BLINK_FREQ = 9;
1577                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1578                                         }
1579                                 }
1580                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1581                         }
1582                         if(autocvar_hud_panel_healtharmor_text)
1583                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1584                 }
1585
1586                 if(armor)
1587                 {
1588                         if(autocvar_hud_panel_healtharmor_progressbar)
1589                         {
1590                                 float p_armor;
1591                                 p_armor = armor;
1592                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1593                                 {
1594                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1595                                         {
1596                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1597                                                 {
1598                                                         if (time - old_p_armortime < 1)
1599                                                                 old_p_armor = prev_p_armor;
1600                                                         else
1601                                                                 old_p_armor = prev_armor;
1602                                                         old_p_armortime = time;
1603                                                 }
1604                                                 if (time - old_p_armortime < 1)
1605                                                 {
1606                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1607                                                         prev_p_armor = p_armor;
1608                                                 }
1609                                         }
1610                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1611                                         {
1612                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1613                                                 {
1614                                                         if (time - armor_damagetime >= 1)
1615                                                                 armor_beforedamage = prev_armor;
1616                                                         armor_damagetime = time;
1617                                                 }
1618                                                 if (time - armor_damagetime < 1)
1619                                                 {
1620                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1621                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1622                                                 }
1623                                         }
1624                                         prev_armor = armor;
1625                                 }
1626                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1627                         }
1628                         if(autocvar_hud_panel_healtharmor_text)
1629                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1630                 }
1631
1632                 if(fuel)
1633                 {
1634                         if (is_vertical)
1635                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1636                         else
1637                                 mySize_y *= 0.2;
1638                         if (panel_ar >= 4)
1639                                 mySize_x *= 2; //restore full panel size
1640                         else if (panel_ar < 1/4)
1641                                 mySize_y *= 2; //restore full panel size
1642                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1643                 }
1644         }
1645 }
1646
1647 // Notification area (#4)
1648 //
1649
1650 void HUD_Notify_Push(string icon, string attacker, string victim)
1651 {
1652         if (icon == "")
1653                 return;
1654
1655         ++notify_count;
1656         --notify_index;
1657
1658         if (notify_index == -1)
1659                 notify_index = NOTIFY_MAX_ENTRIES-1;
1660
1661         // Free old strings
1662         if (notify_attackers[notify_index])
1663                 strunzone(notify_attackers[notify_index]);
1664
1665         if (notify_victims[notify_index])
1666                 strunzone(notify_victims[notify_index]);
1667
1668         if (notify_icons[notify_index])
1669                 strunzone(notify_icons[notify_index]);
1670
1671         // Allocate new strings
1672         if (victim != "")
1673         {
1674                 notify_attackers[notify_index] = strzone(attacker);
1675                 notify_victims[notify_index] = strzone(victim);
1676         }
1677         else
1678         {
1679                 // In case of a notification without a victim, the attacker
1680                 // is displayed on the victim's side. Instead of special
1681                 // treatment later on, we can simply switch them here.
1682                 notify_attackers[notify_index] = string_null;
1683                 notify_victims[notify_index] = strzone(attacker);
1684         }
1685
1686         notify_icons[notify_index] = strzone(icon);
1687         notify_times[notify_index] = time;
1688 }
1689
1690 void HUD_Notify(void)
1691 {
1692         if (!autocvar__hud_configure)
1693                 if (!autocvar_hud_panel_notify)
1694                         return;
1695
1696         HUD_Panel_UpdateCvars();
1697         HUD_Panel_DrawBg(1);
1698
1699         if (!autocvar__hud_configure)
1700                 if (notify_count == 0)
1701                         return;
1702
1703         vector pos, size;
1704         pos  = panel_pos;
1705         size = panel_size;
1706
1707         if (panel_bg_padding)
1708         {
1709                 pos  += '1 1 0' * panel_bg_padding;
1710                 size -= '2 2 0' * panel_bg_padding;
1711         }
1712
1713         float fade_start = max(0, autocvar_hud_panel_notify_time);
1714         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1715         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1716
1717         float entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size_y / size_x), NOTIFY_MAX_ENTRIES);
1718         float entry_height = size_y / entry_count;
1719
1720         float panel_width_half = size_x * 0.5;
1721         float icon_width_half = entry_height * icon_aspect / 2;
1722         float name_maxwidth = panel_width_half - icon_width_half - size_x * NOTIFY_ICON_MARGIN;
1723
1724         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1725         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1726         vector icon_left = eX * (panel_width_half - icon_width_half);
1727         vector attacker_right = eX * name_maxwidth;
1728         vector victim_left = eX * (size_x - name_maxwidth);
1729
1730         vector attacker_pos, victim_pos, icon_pos;
1731         string attacker, victim, icon;
1732         float i, j, count, step, limit, alpha;
1733
1734         if (autocvar_hud_panel_notify_flip)
1735         {
1736                 // Order items from the top down
1737                 i = 0;
1738                 step = +1;
1739                 limit = entry_count;
1740         }
1741         else
1742         {
1743                 // Order items from the bottom up
1744                 i = entry_count - 1;
1745                 step = -1;
1746                 limit = -1;
1747         }
1748
1749         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1750         {
1751                 if(autocvar__hud_configure)
1752                 {
1753                         attacker = sprintf(_("Player %d"), count + 1);
1754                         victim = sprintf(_("Player %d"), count + 2);
1755                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1756                         alpha = bound(0, 1.2 - count / entry_count, 1);
1757                 }
1758                 else
1759                 {
1760                         if (j == NOTIFY_MAX_ENTRIES)
1761                                 j = 0;
1762
1763                         if (notify_times[j] + fade_start > time)
1764                                 alpha = 1;
1765                         else if (fade_time != 0)
1766                         {
1767                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1768                                 if (alpha == 0)
1769                                         break;
1770                         }
1771                         else
1772                                 break;
1773
1774                         attacker = notify_attackers[j];
1775                         victim = notify_victims[j];
1776                         icon = notify_icons[j];
1777                 }
1778
1779                 if (icon != "" && victim != "")
1780                 {
1781                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size_y));
1782
1783                         icon_pos = pos + icon_left + eY * i * entry_height;
1784                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1785
1786                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1787                         victim_pos = pos + victim_left + name_top;
1788                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1789
1790                         if (attacker != "")
1791                         {
1792                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1793                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, TRUE, font_size) + name_top;
1794                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1795                         }
1796                 }
1797         }
1798
1799         notify_count = count;
1800 }
1801
1802 // Timer (#5)
1803 //
1804 // TODO: macro
1805 string seconds_tostring(float sec)
1806 {
1807         float minutes;
1808         minutes = floor(sec / 60);
1809
1810         sec -= minutes * 60;
1811         return sprintf("%d:%02d", minutes, sec);
1812 }
1813
1814 void HUD_Timer(void)
1815 {
1816         if(!autocvar__hud_configure)
1817         {
1818                 if(!autocvar_hud_panel_timer) return;
1819         }
1820
1821         HUD_Panel_UpdateCvars();
1822
1823         draw_beginBoldFont();
1824
1825         vector pos, mySize;
1826         pos = panel_pos;
1827         mySize = panel_size;
1828
1829         HUD_Panel_DrawBg(1);
1830         if(panel_bg_padding)
1831         {
1832                 pos += '1 1 0' * panel_bg_padding;
1833                 mySize -= '2 2 0' * panel_bg_padding;
1834         }
1835
1836         string timer;
1837         float timelimit, elapsedTime, timeleft, minutesLeft;
1838
1839         timelimit = getstatf(STAT_TIMELIMIT);
1840
1841         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1842         timeleft = ceil(timeleft);
1843
1844         minutesLeft = floor(timeleft / 60);
1845
1846         vector timer_color;
1847         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1848                 timer_color = '1 1 1'; //white
1849         else if(minutesLeft >= 1)
1850                 timer_color = '1 1 0'; //yellow
1851         else
1852                 timer_color = '1 0 0'; //red
1853
1854         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1855                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1856                         //while restart is still active, show 00:00
1857                         timer = seconds_tostring(0);
1858                 } else {
1859                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1860                         timer = seconds_tostring(elapsedTime);
1861                 }
1862         } else {
1863                 timer = seconds_tostring(timeleft);
1864         }
1865
1866         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1867
1868         draw_endBoldFont();
1869 }
1870
1871 // Radar (#6)
1872 //
1873 void HUD_Radar(void)
1874 {
1875         if (!autocvar__hud_configure)
1876         {
1877                 if (hud_panel_radar_maximized)
1878                 {
1879                         if (!hud_draw_maximized) return;
1880                 }
1881                 else
1882                 {
1883                         if (autocvar_hud_panel_radar == 0) return;
1884                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1885                         if(radar_panel_modified)
1886                         {
1887                                 panel.update_time = time; // forces reload of panel attributes
1888                                 radar_panel_modified = false;
1889                         }
1890                 }
1891         }
1892
1893         HUD_Panel_UpdateCvars();
1894
1895         float f = 0;
1896
1897         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1898         {
1899                 panel_size = autocvar_hud_panel_radar_maximized_size;
1900                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1901                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1902                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1903                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1904
1905                 string panel_bg;
1906                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1907                 if(precache_pic(panel_bg) == "")
1908                         panel_bg = "gfx/hud/default/border_default"; // fallback
1909                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
1910                         radar_panel_modified = true;
1911                 if(panel.current_panel_bg)
1912                         strunzone(panel.current_panel_bg);
1913                 panel.current_panel_bg = strzone(panel_bg);
1914
1915                 switch(hud_panel_radar_maximized_zoommode)
1916                 {
1917                         default:
1918                         case 0:
1919                                 f = current_zoomfraction;
1920                                 break;
1921                         case 1:
1922                                 f = 1 - current_zoomfraction;
1923                                 break;
1924                         case 2:
1925                                 f = 0;
1926                                 break;
1927                         case 3:
1928                                 f = 1;
1929                                 break;
1930                 }
1931
1932                 switch(hud_panel_radar_maximized_rotation)
1933                 {
1934                         case 0:
1935                                 teamradar_angle = view_angles_y - 90;
1936                                 break;
1937                         default:
1938                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1939                                 break;
1940                 }
1941         }
1942         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1943         {
1944                 switch(hud_panel_radar_zoommode)
1945                 {
1946                         default:
1947                         case 0:
1948                                 f = current_zoomfraction;
1949                                 break;
1950                         case 1:
1951                                 f = 1 - current_zoomfraction;
1952                                 break;
1953                         case 2:
1954                                 f = 0;
1955                                 break;
1956                         case 3:
1957                                 f = 1;
1958                                 break;
1959                 }
1960
1961                 switch(hud_panel_radar_rotation)
1962                 {
1963                         case 0:
1964                                 teamradar_angle = view_angles_y - 90;
1965                                 break;
1966                         default:
1967                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1968                                 break;
1969                 }
1970         }
1971
1972         vector pos, mySize;
1973         pos = panel_pos;
1974         mySize = panel_size;
1975
1976         HUD_Panel_DrawBg(1);
1977         if(panel_bg_padding)
1978         {
1979                 pos += '1 1 0' * panel_bg_padding;
1980                 mySize -= '2 2 0' * panel_bg_padding;
1981         }
1982
1983         float color2;
1984         entity tm;
1985         float scale2d, normalsize, bigsize;
1986
1987         teamradar_origin2d = pos + 0.5 * mySize;
1988         teamradar_size2d = mySize;
1989
1990         if(minimapname == "")
1991                 return;
1992
1993         teamradar_loadcvars();
1994
1995         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1996         teamradar_size2d = mySize;
1997
1998         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1999
2000         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2001         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2002         {
2003                 // max-min distance must fit the radar in any rotation
2004                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2005         }
2006         else
2007         {
2008                 vector c0, c1, c2, c3, span;
2009                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2010                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2011                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
2012                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
2013                 span = '0 0 0';
2014                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2015                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2016
2017                 // max-min distance must fit the radar in x=x, y=y
2018                 bigsize = min(
2019                         teamradar_size2d_x * scale2d / (1.05 * span_x),
2020                         teamradar_size2d_y * scale2d / (1.05 * span_y)
2021                 );
2022         }
2023
2024         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2025         if(bigsize > normalsize)
2026                 normalsize = bigsize;
2027
2028         teamradar_size =
2029                   f * bigsize
2030                 + (1 - f) * normalsize;
2031         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2032                   f * mi_center
2033                 + (1 - f) * view_origin);
2034
2035         drawsetcliparea(
2036                 pos_x,
2037                 pos_y,
2038                 mySize_x,
2039                 mySize_y
2040         );
2041
2042         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2043
2044         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2045                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2046         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2047                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2048         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2049         {
2050                 color2 = GetPlayerColor(tm.sv_entnum);
2051                 //if(color == NUM_SPECTATOR || color == color2)
2052                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2053         }
2054         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2055
2056         drawresetcliparea();
2057 }
2058
2059 // Score (#7)
2060 //
2061 void HUD_UpdatePlayerTeams();
2062 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2063 {
2064         float score;
2065         entity tm = world, pl;
2066 #define SCOREPANEL_MAX_ENTRIES 6
2067 #define SCOREPANEL_ASPECTRATIO 2
2068         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2069         vector fontsize = '1 1 0' * (mySize_y/entries);
2070
2071         vector rgb, score_color;
2072         rgb = '1 1 1';
2073         score_color = '1 1 1';
2074
2075         float name_size = mySize_x*0.75;
2076         float spacing_size = mySize_x*0.04;
2077         const float highlight_alpha = 0.2;
2078         float i = 0, me_printed = 0, first_pl = 0;
2079         string s;
2080         if (autocvar__hud_configure)
2081         {
2082                 float players_per_team = 0;
2083                 if (team_count)
2084                 {
2085                         // show team scores in the first line
2086                         float score_size = mySize_x / team_count;
2087                         players_per_team = max(2, ceil((entries - 1) / team_count));
2088                         for(i=0; i<team_count; ++i) {
2089                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2090                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2091                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2092                         }
2093                         first_pl = 1;
2094                         pos_y += fontsize_y;
2095                 }
2096                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2097                 for (i=first_pl; i<entries; ++i)
2098                 {
2099                         //simulate my score is lower than all displayed players,
2100                         //so that I don't appear at all showing pure rankings.
2101                         //This is to better show the difference between the 2 ranking views
2102                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2103                         {
2104                                 rgb = '1 1 0';
2105                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2106                                 s = GetPlayerName(player_localnum);
2107                                 score = 7;
2108                         }
2109                         else
2110                         {
2111                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2112                                 score -= 3;
2113                         }
2114
2115                         if (team_count)
2116                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2117                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2118                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2119                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2120                         pos_y += fontsize_y;
2121                 }
2122                 return;
2123         }
2124
2125         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2126                 HUD_UpdatePlayerTeams();
2127         if (team_count)
2128         {
2129                 // show team scores in the first line
2130                 float score_size = mySize_x / team_count;
2131                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2132                         if(tm.team == NUM_SPECTATOR)
2133                                 continue;
2134                         if (tm.team == myteam)
2135                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2136                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2137                         ++i;
2138                 }
2139                 first_pl = 1;
2140                 pos_y += fontsize_y;
2141                 tm = teams.sort_next;
2142         }
2143         i = first_pl;
2144
2145         do
2146         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2147         {
2148                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2149                         continue;
2150
2151                 if (i == entries-1 && !me_printed && pl != me)
2152                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2153                 {
2154                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2155                                 if (pl.team != NUM_SPECTATOR)
2156                                         break;
2157
2158                         if (pl)
2159                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2160                         else
2161                                 rgb = '1 0 0'; //last: red
2162                         pl = me;
2163                 }
2164
2165                 if (pl == me)
2166                 {
2167                         if (i == first_pl)
2168                                 rgb = '0 1 0'; //first: green
2169                         me_printed = 1;
2170                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2171                 }
2172                 if (team_count)
2173                         score_color = Team_ColorRGB(pl.team) * 0.8;
2174                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2175                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2176                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2177                 pos_y += fontsize_y;
2178                 ++i;
2179         }
2180         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2181 }
2182
2183 void HUD_Score(void)
2184 {
2185         if(!autocvar__hud_configure)
2186         {
2187                 if(!autocvar_hud_panel_score) return;
2188                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2189         }
2190
2191         HUD_Panel_UpdateCvars();
2192         vector pos, mySize;
2193         pos = panel_pos;
2194         mySize = panel_size;
2195
2196         HUD_Panel_DrawBg(1);
2197         if(panel_bg_padding)
2198         {
2199                 pos += '1 1 0' * panel_bg_padding;
2200                 mySize -= '2 2 0' * panel_bg_padding;
2201         }
2202
2203         float score, distribution = 0;
2204         string sign;
2205         vector distribution_color;
2206         entity tm, pl, me;
2207
2208         me = playerslots[player_localentnum - 1];
2209
2210         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2211                 string timer, distrtimer;
2212
2213                 pl = players.sort_next;
2214                 if(pl == me)
2215                         pl = pl.sort_next;
2216                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2217                         if(pl.scores[ps_primary] == 0)
2218                                 pl = world;
2219
2220                 score = me.(scores[ps_primary]);
2221                 timer = TIME_ENCODED_TOSTRING(score);
2222
2223                 draw_beginBoldFont();
2224                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2225                         // distribution display
2226                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2227
2228                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2229
2230                         if (distribution <= 0) {
2231                                 distribution_color = '0 1 0';
2232                                 sign = "-";
2233                         }
2234                         else {
2235                                 distribution_color = '1 0 0';
2236                                 sign = "+";
2237                         }
2238                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2239                 }
2240                 // race record display
2241                 if (distribution <= 0)
2242                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2243                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2244                 draw_endBoldFont();
2245         } else if (!teamplay) { // non-teamgames
2246                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2247                 {
2248                         HUD_Score_Rankings(pos, mySize, me);
2249                         return;
2250                 }
2251                 // me vector := [team/connected frags id]
2252                 pl = players.sort_next;
2253                 if(pl == me)
2254                         pl = pl.sort_next;
2255
2256                 if(autocvar__hud_configure)
2257                         distribution = 42;
2258                 else if(pl)
2259                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2260                 else
2261                         distribution = 0;
2262
2263                 score = me.(scores[ps_primary]);
2264                 if(autocvar__hud_configure)
2265                         score = 123;
2266
2267                 if(distribution >= 5)
2268                         distribution_color = eY;
2269                 else if(distribution >= 0)
2270                         distribution_color = '1 1 1';
2271                 else if(distribution >= -5)
2272                         distribution_color = '1 1 0';
2273                 else
2274                         distribution_color = eX;
2275
2276                 string distribution_str;
2277                 distribution_str = ftos(distribution);
2278                 draw_beginBoldFont();
2279                 if (distribution >= 0)
2280                 {
2281                         if (distribution > 0)
2282                                 distribution_str = strcat("+", distribution_str);
2283                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2284                 }
2285                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2286                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2287                 draw_endBoldFont();
2288         } else { // teamgames
2289                 float row, column, rows = 0, columns = 0;
2290                 local noref vector offset = '0 0 0';
2291                 vector score_pos, score_size; //for scores other than myteam
2292                 if(autocvar_hud_panel_score_rankings)
2293                 {
2294                         HUD_Score_Rankings(pos, mySize, me);
2295                         return;
2296                 }
2297                 if(spectatee_status == -1)
2298                 {
2299                         rows = mySize_y/mySize_x;
2300                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * team_count + rows * rows) + rows + 0.5) / 2), team_count);
2301                         //                               ^^^ ammo item aspect goes here
2302
2303                         columns = ceil(team_count/rows);
2304
2305                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2306
2307                         float newSize;
2308                         if(score_size_x/score_size_y > 3)
2309                         {
2310                                 newSize = 3 * score_size_y;
2311                                 offset_x = score_size_x - newSize;
2312                                 pos_x += offset_x/2;
2313                                 score_size_x = newSize;
2314                         }
2315                         else
2316                         {
2317                                 newSize = 1/3 * score_size_x;
2318                                 offset_y = score_size_y - newSize;
2319                                 pos_y += offset_y/2;
2320                                 score_size_y = newSize;
2321                         }
2322                 }
2323                 else
2324                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2325
2326                 float max_fragcount;
2327                 max_fragcount = -99;
2328                 draw_beginBoldFont();
2329                 row = column = 0;
2330                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2331                         if(tm.team == NUM_SPECTATOR)
2332                                 continue;
2333                         score = tm.(teamscores[ts_primary]);
2334                         if(autocvar__hud_configure)
2335                                 score = 123;
2336
2337                         if (score > max_fragcount)
2338                                 max_fragcount = score;
2339
2340                         if (spectatee_status == -1)
2341                         {
2342                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2343                                 if (max_fragcount == score)
2344                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2345                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2346                                 ++row;
2347                                 if(row >= rows)
2348                                 {
2349                                         row = 0;
2350                                         ++column;
2351                                 }
2352                         }
2353                         else if(tm.team == myteam) {
2354                                 if (max_fragcount == score)
2355                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2356                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2357                         } else {
2358                                 if (max_fragcount == score)
2359                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2360                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2361                                 ++rows;
2362                         }
2363                 }
2364                 draw_endBoldFont();
2365         }
2366 }
2367
2368 // Race timer (#8)
2369 //
2370 void HUD_RaceTimer (void)
2371 {
2372         if(!autocvar__hud_configure)
2373         {
2374                 if(!autocvar_hud_panel_racetimer) return;
2375                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2376                 if(spectatee_status == -1) return;
2377         }
2378
2379         HUD_Panel_UpdateCvars();
2380
2381         draw_beginBoldFont();
2382
2383         vector pos, mySize;
2384         pos = panel_pos;
2385         mySize = panel_size;
2386
2387         HUD_Panel_DrawBg(1);
2388         if(panel_bg_padding)
2389         {
2390                 pos += '1 1 0' * panel_bg_padding;
2391                 mySize -= '2 2 0' * panel_bg_padding;
2392         }
2393
2394         // always force 4:1 aspect
2395         vector newSize = '0 0 0';
2396         if(mySize_x/mySize_y > 4)
2397         {
2398                 newSize_x = 4 * mySize_y;
2399                 newSize_y = mySize_y;
2400
2401                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2402         }
2403         else
2404         {
2405                 newSize_y = 1/4 * mySize_x;
2406                 newSize_x = mySize_x;
2407
2408                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2409         }
2410         mySize = newSize;
2411
2412         float a, t;
2413         string s, forcetime;
2414
2415         if(autocvar__hud_configure)
2416         {
2417                 s = "0:13:37";
2418                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2419                 s = _("^1Intermediate 1 (+15.42)");
2420                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2421                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2422                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2423         }
2424         else if(race_checkpointtime)
2425         {
2426                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2427                 s = "";
2428                 forcetime = "";
2429                 if(a > 0) // just hit a checkpoint?
2430                 {
2431                         if(race_checkpoint != 254)
2432                         {
2433                                 if(race_time && race_previousbesttime)
2434                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2435                                 else
2436                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2437                                 if(race_time)
2438                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2439                         }
2440                 }
2441                 else
2442                 {
2443                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2444                         {
2445                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2446                                 if(a > 0) // next one?
2447                                 {
2448                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2449                                 }
2450                         }
2451                 }
2452
2453                 if(s != "" && a > 0)
2454                 {
2455                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2456                 }
2457
2458                 if(race_penaltytime)
2459                 {
2460                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2461                         if(a > 0)
2462                         {
2463                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2464                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2465                         }
2466                 }
2467
2468                 if(forcetime != "")
2469                 {
2470                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2471                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2472                 }
2473                 else
2474                         a = 1;
2475
2476                 if(race_laptime && race_checkpoint != 255)
2477                 {
2478                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2479                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2480                 }
2481         }
2482         else
2483         {
2484                 if(race_mycheckpointtime)
2485                 {
2486                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2487                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2488                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2489                 }
2490                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2491                 {
2492                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2493                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2494                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2495                 }
2496
2497                 if(race_penaltytime && !race_penaltyaccumulator)
2498                 {
2499                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2500                         a = bound(0, (1 + t - time), 1);
2501                         if(a > 0)
2502                         {
2503                                 if(time < t)
2504                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2505                                 else
2506                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2507                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2508                         }
2509                 }
2510         }
2511
2512         draw_endBoldFont();
2513 }
2514
2515 // Vote window (#9)
2516 //
2517 float vote_yescount;
2518 float vote_nocount;
2519 float vote_needed;
2520 float vote_highlighted; // currently selected vote
2521
2522 float vote_active; // is there an active vote?
2523 float vote_prev; // previous state of vote_active to check for a change
2524 float vote_alpha;
2525 float vote_change; // "time" when vote_active changed
2526
2527 void HUD_Vote(void)
2528 {
2529         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2530         {
2531                 vote_active = 1;
2532                 if (autocvar__hud_configure)
2533                 {
2534                         vote_yescount = 0;
2535                         vote_nocount = 0;
2536                         print(_("^1You must answer before entering hud configure mode\n"));
2537                         cvar_set("_hud_configure", "0");
2538                 }
2539                 if(vote_called_vote)
2540                         strunzone(vote_called_vote);
2541                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2542                 uid2name_dialog = 1;
2543         }
2544
2545         if(!autocvar__hud_configure)
2546         {
2547                 if(!autocvar_hud_panel_vote) return;
2548
2549                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2550                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2551
2552                 if(panel_bg_alpha_str == "") {
2553                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2554                 }
2555                 panel_bg_alpha = stof(panel_bg_alpha_str);
2556         }
2557         else
2558         {
2559                 vote_yescount = 3;
2560                 vote_nocount = 2;
2561                 vote_needed = 4;
2562         }
2563
2564         string s;
2565         float a;
2566         if(vote_active != vote_prev) {
2567                 vote_change = time;
2568                 vote_prev = vote_active;
2569         }
2570
2571         if(vote_active || autocvar__hud_configure)
2572                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2573         else
2574                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2575
2576         if(!vote_alpha)
2577                 return;
2578
2579         HUD_Panel_UpdateCvars();
2580
2581         if(uid2name_dialog)
2582         {
2583                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2584                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2585         }
2586
2587     // these must be below above block
2588         vector pos, mySize;
2589         pos = panel_pos;
2590         mySize = panel_size;
2591
2592         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2593         HUD_Panel_DrawBg(a);
2594         a = panel_fg_alpha * a;
2595
2596         if(panel_bg_padding)
2597         {
2598                 pos += '1 1 0' * panel_bg_padding;
2599                 mySize -= '2 2 0' * panel_bg_padding;
2600         }
2601
2602         // always force 3:1 aspect
2603         vector newSize = '0 0 0';
2604         if(mySize_x/mySize_y > 3)
2605         {
2606                 newSize_x = 3 * mySize_y;
2607                 newSize_y = mySize_y;
2608
2609                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2610         }
2611         else
2612         {
2613                 newSize_y = 1/3 * mySize_x;
2614                 newSize_x = mySize_x;
2615
2616                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2617         }
2618         mySize = newSize;
2619
2620         s = _("A vote has been called for:");
2621         if(uid2name_dialog)
2622                 s = _("Allow servers to store and display your name?");
2623         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2624         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2625         if(autocvar__hud_configure)
2626                 s = _("^1Configure the HUD");
2627         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2628
2629         // print the yes/no counts
2630     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2631         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2632     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2633         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2634
2635         // draw the progress bar backgrounds
2636         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2637
2638         // draw the highlights
2639         if(vote_highlighted == 1) {
2640                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2641                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2642         }
2643         else if(vote_highlighted == -1) {
2644                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2645                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2646         }
2647
2648         // draw the progress bars
2649         if(vote_yescount && vote_needed)
2650         {
2651                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2652                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2653         }
2654
2655         if(vote_nocount && vote_needed)
2656         {
2657                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2658                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2659         }
2660
2661         drawresetcliparea();
2662 }
2663
2664 // Mod icons panel (#10)
2665 //
2666
2667 float mod_active; // is there any active mod icon?
2668
2669 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2670 {
2671         float stat;
2672         string pic;
2673         vector color;
2674 #ifdef GMQCC
2675         stat = -1;
2676         pic = "";
2677         color = '0 0 0';
2678 #endif
2679         switch(i)
2680         {
2681                 case 0:
2682                         stat = getstati(STAT_REDALIVE);
2683                         pic = "player_red.tga";
2684                         color = '1 0 0';
2685                         break;
2686                 case 1:
2687                         stat = getstati(STAT_BLUEALIVE);
2688                         pic = "player_blue.tga";
2689                         color = '0 0 1';
2690                         break;
2691                 case 2:
2692                         stat = getstati(STAT_YELLOWALIVE);
2693                         pic = "player_yellow.tga";
2694                         color = '1 1 0';
2695                         break;
2696                 default:
2697                 case 3:
2698                         stat = getstati(STAT_PINKALIVE);
2699                         pic = "player_pink.tga";
2700                         color = '1 0 1';
2701                         break;
2702         }
2703
2704         if(mySize_x/mySize_y > aspect_ratio)
2705         {
2706                 i = aspect_ratio * mySize_y;
2707                 myPos_x = myPos_x + (mySize_x - i) / 2;
2708                 mySize_x = i;
2709         }
2710         else
2711         {
2712                 i = 1/aspect_ratio * mySize_x;
2713                 myPos_y = myPos_y + (mySize_y - i) / 2;
2714                 mySize_y = i;
2715         }
2716
2717         if(layout)
2718         {
2719                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2720                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2721         }
2722         else
2723                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2724 }
2725
2726 // Clan Arena and Freeze Tag HUD modicons
2727 void HUD_Mod_CA(vector myPos, vector mySize)
2728 {
2729         mod_active = 1; // required in each mod function that always shows something
2730
2731         float layout;
2732         if(gametype == MAPINFO_TYPE_CA)
2733                 layout = autocvar_hud_panel_modicons_ca_layout;
2734         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2735                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2736         float rows, columns, aspect_ratio;
2737         rows = mySize_y/mySize_x;
2738         aspect_ratio = (layout) ? 2 : 1;
2739         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
2740         columns = ceil(team_count/rows);
2741
2742         int i;
2743         float row = 0, column = 0;
2744         vector pos, itemSize;
2745         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2746         for(i=0; i<team_count; ++i)
2747         {
2748                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2749
2750                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2751
2752                 ++row;
2753                 if(row >= rows)
2754                 {
2755                         row = 0;
2756                         ++column;
2757                 }
2758         }
2759 }
2760
2761 // CTF HUD modicon section
2762 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2763 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2764 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2765
2766 void HUD_Mod_CTF_Reset(void)
2767 {
2768         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2769 }
2770
2771 void HUD_Mod_CTF(vector pos, vector mySize)
2772 {
2773         vector redflag_pos, blueflag_pos;
2774         vector flag_size;
2775         float f; // every function should have that
2776
2777         float redflag, blueflag; // current status
2778         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2779         float stat_items;
2780
2781         stat_items = getstati(STAT_ITEMS, 0, 24);
2782         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2783         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2784
2785         if(redflag || blueflag)
2786                 mod_active = 1;
2787         else
2788                 mod_active = 0;
2789
2790         if(autocvar__hud_configure)
2791         {
2792                 redflag = 1;
2793                 blueflag = 2;
2794         }
2795
2796         // when status CHANGES, set old status into prevstatus and current status into status
2797         if (redflag != redflag_prevframe)
2798         {
2799                 redflag_statuschange_time = time;
2800                 redflag_prevstatus = redflag_prevframe;
2801                 redflag_prevframe = redflag;
2802         }
2803
2804         if (blueflag != blueflag_prevframe)
2805         {
2806                 blueflag_statuschange_time = time;
2807                 blueflag_prevstatus = blueflag_prevframe;
2808                 blueflag_prevframe = blueflag;
2809         }
2810
2811         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2812         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2813
2814         float BLINK_FACTOR = 0.15;
2815         float BLINK_BASE = 0.85;
2816         // note:
2817         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2818         // thus
2819         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2820         // ensure RMS == 1
2821         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2822
2823         string red_icon, red_icon_prevstatus;
2824         float red_alpha, red_alpha_prevstatus;
2825         red_alpha = red_alpha_prevstatus = 1;
2826         switch(redflag) {
2827                 case 1: red_icon = "flag_red_taken"; break;
2828                 case 2: red_icon = "flag_red_lost"; break;
2829                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2830                 default:
2831                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2832                                 red_icon = "flag_red_shielded";
2833                         else
2834                                 red_icon = string_null;
2835                         break;
2836         }
2837         switch(redflag_prevstatus) {
2838                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2839                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2840                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2841                 default:
2842                         if(redflag == 3)
2843                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2844                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2845                                 red_icon_prevstatus = "flag_red_shielded";
2846                         else
2847                                 red_icon_prevstatus = string_null;
2848                         break;
2849         }
2850
2851         string blue_icon, blue_icon_prevstatus;
2852         float blue_alpha, blue_alpha_prevstatus;
2853         blue_alpha = blue_alpha_prevstatus = 1;
2854         switch(blueflag) {
2855                 case 1: blue_icon = "flag_blue_taken"; break;
2856                 case 2: blue_icon = "flag_blue_lost"; break;
2857                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2858                 default:
2859                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2860                                 blue_icon = "flag_blue_shielded";
2861                         else
2862                                 blue_icon = string_null;
2863                         break;
2864         }
2865         switch(blueflag_prevstatus) {
2866                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2867                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2868                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2869                 default:
2870                         if(blueflag == 3)
2871                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2872                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2873                                 blue_icon_prevstatus = "flag_blue_shielded";
2874                         else
2875                                 blue_icon_prevstatus = string_null;
2876                         break;
2877         }
2878
2879         if(mySize_x > mySize_y) {
2880                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2881                         redflag_pos = pos;
2882                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2883                 } else {
2884                         blueflag_pos = pos;
2885                         redflag_pos = pos + eX * 0.5 * mySize_x;
2886                 }
2887                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2888         } else {
2889                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2890                         redflag_pos = pos;
2891                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2892                 } else {
2893                         blueflag_pos = pos;
2894                         redflag_pos = pos + eY * 0.5 * mySize_y;
2895                 }
2896                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2897         }
2898
2899         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2900         if(red_icon_prevstatus && f < 1)
2901                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2902         if(red_icon)
2903                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2904
2905         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2906         if(blue_icon_prevstatus && f < 1)
2907                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2908         if(blue_icon)
2909                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2910 }
2911
2912 // Keyhunt HUD modicon section
2913 vector KH_SLOTS[4];
2914
2915 void HUD_Mod_KH(vector pos, vector mySize)
2916 {
2917         mod_active = 1; // keyhunt should never hide the mod icons panel
2918
2919         // Read current state
2920
2921         float state = getstati(STAT_KH_KEYS);
2922         float i, key_state;
2923         float all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
2924         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
2925
2926         for(i = 0; i < 4; ++i)
2927         {
2928                 key_state = (bitshift(state, i * -5) & 31) - 1;
2929
2930                 if(key_state == -1)
2931                         continue;
2932
2933                 if(key_state == 30)
2934                 {
2935                         ++carrying_keys;
2936                         key_state = myteam;
2937                 }
2938
2939                 switch(key_state)
2940                 {
2941                         case NUM_TEAM_1: ++team1_keys; break;
2942                         case NUM_TEAM_2: ++team2_keys; break;
2943                         case NUM_TEAM_3: ++team3_keys; break;
2944                         case NUM_TEAM_4: ++team4_keys; break;
2945                         case 29: ++dropped_keys; break;
2946                 }
2947
2948                 ++all_keys;
2949         }
2950
2951         // Calculate slot measurements
2952
2953         vector slot_size;
2954
2955         if(all_keys == 4 && mySize_x * 0.5 < mySize_y && mySize_y * 0.5 < mySize_x)
2956         {
2957                 // Quadratic arrangement
2958                 slot_size = eX * mySize_x * 0.5 + eY * mySize_y * 0.5;
2959                 KH_SLOTS[0] = pos;
2960                 KH_SLOTS[1] = pos + eX * slot_size_x;
2961                 KH_SLOTS[2] = pos + eY * slot_size_y;
2962                 KH_SLOTS[3] = pos + eX * slot_size_x + eY * slot_size_y;
2963         }
2964         else
2965         {
2966                 if(mySize_x > mySize_y)
2967                 {
2968                         // Horizontal arrangement
2969                         slot_size = eX * mySize_x / all_keys + eY * mySize_y;
2970                         for(i = 0; i < all_keys; ++i)
2971                                 KH_SLOTS[i] = pos + eX * slot_size_x * i;
2972                 }
2973                 else
2974                 {
2975                         // Vertical arrangement
2976                         slot_size = eX * mySize_x + eY * mySize_y / all_keys;
2977                         for(i = 0; i < all_keys; ++i)
2978                                 KH_SLOTS[i] = pos + eY * slot_size_y * i;
2979                 }
2980         }
2981
2982         // Make icons blink in case of RUN HERE
2983
2984         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
2985         float alpha;
2986         alpha = 1;
2987
2988         if(carrying_keys)
2989                 switch(myteam)
2990                 {
2991                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
2992                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
2993                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
2994                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
2995                 }
2996
2997         // Draw icons
2998
2999         i = 0;
3000
3001         while(team1_keys--)
3002                 if(myteam == NUM_TEAM_1 && carrying_keys)
3003                 {
3004                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3005                         --carrying_keys;
3006                 }
3007                 else
3008                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3009
3010         while(team2_keys--)
3011                 if(myteam == NUM_TEAM_2 && carrying_keys)
3012                 {
3013                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3014                         --carrying_keys;
3015                 }
3016                 else
3017                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3018
3019         while(team3_keys--)
3020                 if(myteam == NUM_TEAM_3 && carrying_keys)
3021                 {
3022                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3023                         --carrying_keys;
3024                 }
3025                 else
3026                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3027
3028         while(team4_keys--)
3029                 if(myteam == NUM_TEAM_4 && carrying_keys)
3030                 {
3031                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3032                         --carrying_keys;
3033                 }
3034                 else
3035                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3036
3037         while(dropped_keys--)
3038                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3039 }
3040
3041 // Keepaway HUD mod icon
3042 float kaball_prevstatus; // last remembered status
3043 float kaball_statuschange_time; // time when the status changed
3044
3045 // we don't need to reset for keepaway since it immediately
3046 // autocorrects prevstatus as to if the player has the ball or not
3047
3048 void HUD_Mod_Keepaway(vector pos, vector mySize)
3049 {
3050         mod_active = 1; // keepaway should always show the mod HUD
3051
3052         float BLINK_FACTOR = 0.15;
3053         float BLINK_BASE = 0.85;
3054         float BLINK_FREQ = 5;
3055         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3056
3057         float stat_items = getstati(STAT_ITEMS, 0, 24);
3058         float kaball = (stat_items/IT_KEY1) & 1;
3059
3060         if(kaball != kaball_prevstatus)
3061         {
3062                 kaball_statuschange_time = time;
3063                 kaball_prevstatus = kaball;
3064         }
3065
3066         vector kaball_pos, kaball_size;
3067
3068         if(mySize_x > mySize_y) {
3069                 kaball_pos = pos + eX * 0.25 * mySize_x;
3070                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
3071         } else {
3072                 kaball_pos = pos + eY * 0.25 * mySize_y;
3073                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3074         }
3075
3076         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3077         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3078
3079         if(kaball_prevstatus && f < 1)
3080                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3081
3082         if(kaball)
3083                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3084 }
3085
3086
3087 // Nexball HUD mod icon
3088 void HUD_Mod_NexBall(vector pos, vector mySize)
3089 {
3090         float stat_items, nb_pb_starttime, dt, p;
3091
3092         stat_items = getstati(STAT_ITEMS, 0, 24);
3093         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3094
3095         if (stat_items & IT_KEY1)
3096                 mod_active = 1;
3097         else
3098                 mod_active = 0;
3099
3100         //Manage the progress bar if any
3101         if (nb_pb_starttime > 0)
3102         {
3103                 dt = (time - nb_pb_starttime) % nb_pb_period;
3104                 // one period of positive triangle
3105                 p = 2 * dt / nb_pb_period;
3106                 if (p > 1)
3107                         p = 2 - p;
3108
3109                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize_x <= mySize_y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3110         }
3111
3112         if (stat_items & IT_KEY1)
3113                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3114 }
3115
3116 // Race/CTS HUD mod icons
3117 float crecordtime_prev; // last remembered crecordtime
3118 float crecordtime_change_time; // time when crecordtime last changed
3119 float srecordtime_prev; // last remembered srecordtime
3120 float srecordtime_change_time; // time when srecordtime last changed
3121
3122 float race_status_time;
3123 float race_status_prev;
3124 string race_status_name_prev;
3125 void HUD_Mod_Race(vector pos, vector mySize)
3126 {
3127         mod_active = 1; // race should never hide the mod icons panel
3128         entity me;
3129         me = playerslots[player_localnum];
3130         float t, score;
3131         float f; // yet another function has this
3132         score = me.(scores[ps_primary]);
3133
3134         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3135                 return; // no records in the actual race
3136
3137         // clientside personal record
3138         string rr;
3139         if(gametype == MAPINFO_TYPE_CTS)
3140                 rr = CTS_RECORD;
3141         else
3142                 rr = RACE_RECORD;
3143         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3144
3145         if(score && (score < t || !t)) {
3146                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3147                 if(autocvar_cl_autodemo_delete_keeprecords)
3148                 {
3149                         f = autocvar_cl_autodemo_delete;
3150                         f &= ~1;
3151                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3152                 }
3153         }
3154
3155         if(t != crecordtime_prev) {
3156                 crecordtime_prev = t;
3157                 crecordtime_change_time = time;
3158         }
3159
3160         vector textPos, medalPos;
3161         float squareSize;
3162         if(mySize_x > mySize_y) {
3163                 // text on left side
3164                 squareSize = min(mySize_y, mySize_x/2);
3165                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3166                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3167         } else {
3168                 // text on top
3169                 squareSize = min(mySize_x, mySize_y/2);
3170                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3171                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3172         }
3173
3174         f = time - crecordtime_change_time;
3175
3176         if (f > 1) {
3177                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3178                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3179         } else {
3180                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3181                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3182                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3183                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3184         }
3185
3186         // server record
3187         t = race_server_record;
3188         if(t != srecordtime_prev) {
3189                 srecordtime_prev = t;
3190                 srecordtime_change_time = time;
3191         }
3192         f = time - srecordtime_change_time;
3193
3194         if (f > 1) {
3195                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3196                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3197         } else {
3198                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3199                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3200                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3201                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3202         }
3203
3204         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3205                 race_status_time = time + 5;
3206                 race_status_prev = race_status;
3207                 if (race_status_name_prev)
3208                         strunzone(race_status_name_prev);
3209                 race_status_name_prev = strzone(race_status_name);
3210         }
3211
3212         // race "awards"
3213         float a;
3214         a = bound(0, race_status_time - time, 1);
3215
3216         string s;
3217         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3218
3219         float rank;
3220         if(race_status > 0)
3221                 rank = race_CheckName(race_status_name);
3222         else
3223                 rank = 0;
3224         string rankname;
3225         rankname = count_ordinal(rank);
3226
3227         vector namepos;
3228         namepos = medalPos + '0 0.8 0' * squareSize;
3229         vector rankpos;
3230         rankpos = medalPos + '0 0.15 0' * squareSize;
3231
3232         if(race_status == 0)
3233                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3234         else if(race_status == 1) {
3235                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3236                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3237                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3238         } else if(race_status == 2) {
3239                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3240                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3241                 else
3242                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3243                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3244                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3245         } else if(race_status == 3) {
3246                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3247                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3248                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3249         }
3250
3251         if (race_status_time - time <= 0) {
3252                 race_status_prev = -1;
3253                 race_status = -1;
3254                 if(race_status_name)
3255                         strunzone(race_status_name);
3256                 race_status_name = string_null;
3257                 if(race_status_name_prev)
3258                         strunzone(race_status_name_prev);
3259                 race_status_name_prev = string_null;
3260         }
3261 }
3262
3263 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3264 {
3265         float stat, pps_ratio;
3266         string pic;
3267         vector color;
3268 #ifdef GMQCC
3269         stat = -1;
3270         pic = "";
3271         color = '0 0 0';
3272 #endif
3273         switch(i)
3274         {
3275                 case 0:
3276                         stat = getstatf(STAT_DOM_PPS_RED);
3277                         pic = "dom_icon_red";
3278                         color = '1 0 0';
3279                         break;
3280                 case 1:
3281                         stat = getstatf(STAT_DOM_PPS_BLUE);
3282                         pic = "dom_icon_blue";
3283                         color = '0 0 1';
3284                         break;
3285                 case 2:
3286                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3287                         pic = "dom_icon_yellow";
3288                         color = '1 1 0';
3289                         break;
3290                 default:
3291                 case 3:
3292                         stat = getstatf(STAT_DOM_PPS_PINK);
3293                         pic = "dom_icon_pink";
3294                         color = '1 0 1';
3295                         break;
3296         }
3297         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3298
3299         if(mySize_x/mySize_y > aspect_ratio)
3300         {
3301                 i = aspect_ratio * mySize_y;
3302                 myPos_x = myPos_x + (mySize_x - i) / 2;
3303                 mySize_x = i;
3304         }
3305         else
3306         {
3307                 i = 1/aspect_ratio * mySize_x;
3308                 myPos_y = myPos_y + (mySize_y - i) / 2;
3309                 mySize_y = i;
3310         }
3311
3312         if (layout) // show text too
3313         {
3314                 //draw the text
3315                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3316                 if (layout == 2) // average pps
3317                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3318                 else // percentage of average pps
3319                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3320         }
3321
3322         //draw the icon
3323         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3324         if (stat > 0)
3325         {
3326                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3327                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3328                 drawresetcliparea();
3329         }
3330 }
3331
3332 void HUD_Mod_Dom(vector myPos, vector mySize)
3333 {
3334         mod_active = 1; // required in each mod function that always shows something
3335
3336         float layout = autocvar_hud_panel_modicons_dom_layout;
3337         float rows, columns, aspect_ratio;
3338         rows = mySize_y/mySize_x;
3339         aspect_ratio = (layout) ? 3 : 1;
3340         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
3341         columns = ceil(team_count/rows);
3342
3343         int i;
3344         float row = 0, column = 0;
3345         vector pos, itemSize;
3346         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3347         for(i=0; i<team_count; ++i)
3348         {
3349                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
3350
3351                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3352
3353                 ++row;
3354                 if(row >= rows)
3355                 {
3356                         row = 0;
3357                         ++column;
3358                 }
3359         }
3360 }
3361
3362 void HUD_ModIcons_SetFunc()
3363 {
3364         switch(gametype)
3365         {
3366                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3367                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3368                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3369                 case MAPINFO_TYPE_CTS:
3370                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3371                 case MAPINFO_TYPE_CA:
3372                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3373                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3374                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3375         }
3376 }
3377
3378 float mod_prev; // previous state of mod_active to check for a change
3379 float mod_alpha;
3380 float mod_change; // "time" when mod_active changed
3381
3382 void HUD_ModIcons(void)
3383 {
3384         if(!autocvar__hud_configure)
3385         {
3386                 if(!autocvar_hud_panel_modicons) return;
3387                 if(!HUD_ModIcons_GameType) return;
3388         }
3389
3390         HUD_Panel_UpdateCvars();
3391
3392         draw_beginBoldFont();
3393
3394         if(mod_active != mod_prev) {
3395                 mod_change = time;
3396                 mod_prev = mod_active;
3397         }
3398
3399         if(mod_active || autocvar__hud_configure)
3400                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3401         else
3402                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3403
3404         if(mod_alpha)
3405                 HUD_Panel_DrawBg(mod_alpha);
3406
3407         if(panel_bg_padding)
3408         {
3409                 panel_pos += '1 1 0' * panel_bg_padding;
3410                 panel_size -= '2 2 0' * panel_bg_padding;
3411         }
3412
3413         if(autocvar__hud_configure)
3414                 HUD_Mod_CTF(panel_pos, panel_size);
3415         else
3416                 HUD_ModIcons_GameType(panel_pos, panel_size);
3417
3418         draw_endBoldFont();
3419 }
3420
3421 // Draw pressed keys (#11)
3422 //
3423 void HUD_PressedKeys(void)
3424 {
3425         if(!autocvar__hud_configure)
3426         {
3427                 if(!autocvar_hud_panel_pressedkeys) return;
3428                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3429         }
3430
3431         HUD_Panel_UpdateCvars();
3432         vector pos, mySize;
3433         pos = panel_pos;
3434         mySize = panel_size;
3435
3436         HUD_Panel_DrawBg(1);
3437         if(panel_bg_padding)
3438         {
3439                 pos += '1 1 0' * panel_bg_padding;
3440                 mySize -= '2 2 0' * panel_bg_padding;
3441         }
3442
3443         // force custom aspect
3444         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3445         if(aspect)
3446         {
3447                 vector newSize = '0 0 0';
3448                 if(mySize_x/mySize_y > aspect)
3449                 {
3450                         newSize_x = aspect * mySize_y;
3451                         newSize_y = mySize_y;
3452
3453                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3454                 }
3455                 else
3456                 {
3457                         newSize_y = 1/aspect * mySize_x;
3458                         newSize_x = mySize_x;
3459
3460                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3461                 }
3462                 mySize = newSize;
3463         }
3464
3465         vector keysize;
3466         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3467         float pressedkeys;
3468         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3469
3470         if(autocvar_hud_panel_pressedkeys_attack)
3471         {
3472                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3473                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3474                 pos_y += keysize_y;
3475         }
3476
3477         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3478         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3479         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3480         pos_y += keysize_y;
3481         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3482         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3483         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3484 }
3485
3486 // Handle chat as a panel (#12)
3487 //
3488 void HUD_Chat(void)
3489 {
3490         if(!autocvar__hud_configure)
3491         {
3492                 if (!autocvar_hud_panel_chat)
3493                 {
3494                         if (!autocvar_con_chatrect)
3495                                 cvar_set("con_chatrect", "0");
3496                         return;
3497                 }
3498                 if(autocvar__con_chat_maximized)
3499                 {
3500                         if(!hud_draw_maximized) return;
3501                 }
3502                 else if(chat_panel_modified)
3503                 {
3504                         panel.update_time = time; // forces reload of panel attributes
3505                         chat_panel_modified = false;
3506                 }
3507         }
3508
3509         HUD_Panel_UpdateCvars();
3510
3511         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3512         {
3513                 panel_pos_y = panel_bg_border;
3514                 panel_size_y = vid_conheight - panel_bg_border * 2;
3515                 if(panel.current_panel_bg == "0") // force a border when maximized
3516                 {
3517                         string panel_bg;
3518                         panel_bg = strcat(hud_skin_path, "/border_default");
3519                         if(precache_pic(panel_bg) == "")
3520                                 panel_bg = "gfx/hud/default/border_default";
3521                         if(panel.current_panel_bg)
3522                                 strunzone(panel.current_panel_bg);
3523                         panel.current_panel_bg = strzone(panel_bg);
3524                         chat_panel_modified = true;
3525                 }
3526                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3527         }
3528
3529         vector pos, mySize;
3530         pos = panel_pos;
3531         mySize = panel_size;
3532
3533         HUD_Panel_DrawBg(1);
3534
3535         if(panel_bg_padding)
3536         {
3537                 pos += '1 1 0' * panel_bg_padding;
3538                 mySize -= '2 2 0' * panel_bg_padding;
3539         }
3540
3541         if (!autocvar_con_chatrect)
3542                 cvar_set("con_chatrect", "1");
3543
3544         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3545         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3546
3547         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3548         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3549
3550         if(autocvar__hud_configure)
3551         {
3552                 vector chatsize;
3553                 chatsize = '1 1 0' * autocvar_con_chatsize;
3554                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3555                 float i, a;
3556                 for(i = 0; i < autocvar_con_chat; ++i)
3557                 {
3558                         if(i == autocvar_con_chat - 1)
3559                                 a = panel_fg_alpha;
3560                         else
3561                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3562                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3563                         pos_y += chatsize_y;
3564                 }
3565         }
3566 }
3567
3568 // Engine info panel (#13)
3569 //
3570 float prevfps;
3571 float prevfps_time;
3572 float framecounter;
3573
3574 float frametimeavg;
3575 float frametimeavg1; // 1 frame ago
3576 float frametimeavg2; // 2 frames ago
3577 void HUD_EngineInfo(void)
3578 {
3579         if(!autocvar__hud_configure)
3580         {
3581                 if(!autocvar_hud_panel_engineinfo) return;
3582         }
3583
3584         HUD_Panel_UpdateCvars();
3585         vector pos, mySize;
3586         pos = panel_pos;
3587         mySize = panel_size;
3588
3589         HUD_Panel_DrawBg(1);
3590         if(panel_bg_padding)
3591         {
3592                 pos += '1 1 0' * panel_bg_padding;
3593                 mySize -= '2 2 0' * panel_bg_padding;
3594         }
3595
3596         float currentTime = gettime(GETTIME_REALTIME);
3597         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3598         {
3599                 float currentframetime = currentTime - prevfps_time;
3600                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3601                 frametimeavg2 = frametimeavg1;
3602                 frametimeavg1 = frametimeavg;
3603
3604                 float weight;
3605                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3606                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3607                 {
3608                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3609                                 prevfps = (1/currentframetime);
3610                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3611                 }
3612                 prevfps_time = currentTime;
3613         }
3614         else
3615         {
3616                 framecounter += 1;
3617                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3618                 {
3619                         prevfps = framecounter/(currentTime - prevfps_time);
3620                         framecounter = 0;
3621                         prevfps_time = currentTime;
3622                 }
3623         }
3624
3625         vector color;
3626         color = HUD_Get_Num_Color (prevfps, 100);
3627         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3628 }
3629
3630 // Info messages panel (#14)
3631 //
3632 #define drawInfoMessage(s)\
3633         if(autocvar_hud_panel_infomessages_flip)\
3634                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3635         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3636         o_y += fontsize_y;
3637 void HUD_InfoMessages(void)
3638 {
3639         if(!autocvar__hud_configure)
3640         {
3641                 if(!autocvar_hud_panel_infomessages) return;
3642         }
3643
3644         HUD_Panel_UpdateCvars();
3645         vector pos, mySize;
3646         pos = panel_pos;
3647         mySize = panel_size;
3648
3649         HUD_Panel_DrawBg(1);
3650         if(panel_bg_padding)
3651         {
3652                 pos += '1 1 0' * panel_bg_padding;
3653                 mySize -= '2 2 0' * panel_bg_padding;
3654         }
3655
3656         // always force 5:1 aspect
3657         vector newSize = '0 0 0';
3658         if(mySize_x/mySize_y > 5)
3659         {
3660                 newSize_x = 5 * mySize_y;
3661                 newSize_y = mySize_y;
3662
3663                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3664         }
3665         else
3666         {
3667                 newSize_y = 1/5 * mySize_x;
3668                 newSize_x = mySize_x;
3669
3670                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3671         }
3672
3673         mySize = newSize;
3674         entity tm;
3675         vector o;
3676         o = pos;
3677
3678         vector fontsize;
3679         fontsize = '0.20 0.20 0' * mySize_y;
3680
3681         float a;
3682         a = panel_fg_alpha;
3683
3684         string s;
3685         if(!autocvar__hud_configure)
3686         {
3687                 if(spectatee_status && !intermission)
3688                 {
3689                         a = 1;
3690                         if(spectatee_status == -1)
3691                                 s = _("^1Observing");
3692                         else
3693                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3694                         drawInfoMessage(s)
3695
3696                         if(spectatee_status == -1)
3697                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3698                         else
3699                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3700                         drawInfoMessage(s)
3701
3702                         if(spectatee_status == -1)
3703                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3704                         else
3705                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3706                         drawInfoMessage(s)
3707
3708                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3709                         drawInfoMessage(s)
3710
3711                         if(gametype == MAPINFO_TYPE_LMS)
3712                         {
3713                                 entity sk;
3714                                 sk = playerslots[player_localnum];
3715                                 if(sk.(scores[ps_primary]) >= 666)
3716                                         s = _("^1Match has already begun");
3717                                 else if(sk.(scores[ps_primary]) > 0)
3718                                         s = _("^1You have no more lives left");
3719                                 else
3720                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3721                         }
3722                         else
3723                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3724                         drawInfoMessage(s)
3725
3726                         //show restart countdown:
3727                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3728                                 float countdown;
3729                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3730                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3731                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3732                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3733                                 o_y += fontsize_y;
3734                         }
3735                 }
3736                 if(warmup_stage && !intermission)
3737                 {
3738                         s = _("^2Currently in ^1warmup^2 stage!");
3739                         drawInfoMessage(s)
3740                 }
3741
3742                 string blinkcolor;
3743                 if(time % 1 >= 0.5)
3744                         blinkcolor = "^1";
3745                 else
3746                         blinkcolor = "^3";
3747
3748                 if(ready_waiting && !intermission && !spectatee_status)
3749                 {
3750                         if(ready_waiting_for_me)
3751                         {
3752                                 if(warmup_stage)
3753                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3754                                 else
3755                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3756                         }
3757                         else
3758                         {
3759                                 if(warmup_stage)
3760                                         s = _("^2Waiting for others to ready up to end warmup...");
3761                                 else
3762                                         s = _("^2Waiting for others to ready up...");
3763                         }
3764                         drawInfoMessage(s)
3765                 }
3766                 else if(warmup_stage && !intermission && !spectatee_status)
3767                 {
3768                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3769                         drawInfoMessage(s)
3770                 }
3771
3772                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3773                 {
3774                         float ts_min = 0, ts_max = 0;
3775                         tm = teams.sort_next;
3776                         if (tm)
3777                         {
3778                                 for(; tm.sort_next; tm = tm.sort_next)
3779                                 {
3780                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3781                                                 continue;
3782                                         if(!ts_min) ts_min = tm.team_size;
3783                                         else ts_min = min(ts_min, tm.team_size);
3784                                         if(!ts_max) ts_max = tm.team_size;
3785                                         else ts_max = max(ts_max, tm.team_size);
3786                                 }
3787                                 if ((ts_max - ts_min) > 1)
3788                                 {
3789                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3790                                         tm = GetTeam(myteam, false);
3791                                         if (tm)
3792                                         if (tm.team != NUM_SPECTATOR)
3793                                         if (tm.team_size == ts_max)
3794                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3795                                         drawInfoMessage(s)
3796                                 }
3797                         }
3798                 }
3799         }
3800         else
3801         {
3802                 s = _("^7Press ^3ESC ^7to show HUD options.");
3803                 drawInfoMessage(s)
3804                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3805                 drawInfoMessage(s)
3806                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3807                 drawInfoMessage(s)
3808                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3809                 drawInfoMessage(s)
3810         }
3811 }
3812
3813 // Physics panel (#15)
3814 //
3815 vector acc_prevspeed;
3816 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3817 void HUD_Physics(void)
3818 {
3819         if(!autocvar__hud_configure)
3820         {
3821                 if(!autocvar_hud_panel_physics) return;
3822                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3823                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3824         }
3825
3826         HUD_Panel_UpdateCvars();
3827
3828         draw_beginBoldFont();
3829
3830         HUD_Panel_DrawBg(1);
3831         if(panel_bg_padding)
3832         {
3833                 panel_pos += '1 1 0' * panel_bg_padding;
3834                 panel_size -= '2 2 0' * panel_bg_padding;
3835         }
3836
3837         float acceleration_progressbar_scale = 0;
3838         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3839                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3840
3841         float text_scale;
3842         if (autocvar_hud_panel_physics_text_scale <= 0)
3843                 text_scale = 1;
3844         else
3845                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3846
3847         //compute speed
3848         float speed, conversion_factor;
3849         string unit;
3850
3851         switch(autocvar_hud_panel_physics_speed_unit)
3852         {
3853                 default:
3854                 case 1:
3855                         unit = _(" qu/s");
3856                         conversion_factor = 1.0;
3857                         break;
3858                 case 2:
3859                         unit = _(" m/s");
3860                         conversion_factor = 0.0254;
3861                         break;
3862                 case 3:
3863                         unit = _(" km/h");
3864                         conversion_factor = 0.0254 * 3.6;
3865                         break;
3866                 case 4:
3867                         unit = _(" mph");
3868                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3869                         break;
3870                 case 5:
3871                         unit = _(" knots");
3872                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3873                         break;
3874         }
3875
3876         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3877
3878         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3879         if (autocvar__hud_configure)
3880                 speed = floor( max_speed * 0.65 + 0.5 );
3881         else if(autocvar_hud_panel_physics_speed_vertical)
3882                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3883         else
3884                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3885
3886         //compute acceleration
3887         float acceleration, f;
3888         if (autocvar__hud_configure)
3889                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3890         else
3891         {
3892                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3893                 f = time - acc_prevtime;
3894                 if(autocvar_hud_panel_physics_acceleration_vertical)
3895                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3896                 else
3897                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3898
3899                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3900
3901                 acc_prevspeed = vel;
3902                 acc_prevtime = time;
3903
3904                 f = bound(0, f * 10, 1);
3905                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3906         }
3907
3908         //compute layout
3909         float panel_ar = panel_size_x/panel_size_y;
3910         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3911         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3912         {
3913                 panel_size_x *= 0.5;
3914                 if (autocvar_hud_panel_physics_flip)
3915                         speed_offset_x = panel_size_x;
3916                 else
3917                         acceleration_offset_x = panel_size_x;
3918         }
3919         else
3920         {
3921                 panel_size_y *= 0.5;
3922                 if (autocvar_hud_panel_physics_flip)
3923                         speed_offset_y = panel_size_y;
3924                 else
3925                         acceleration_offset_y = panel_size_y;
3926         }
3927         float speed_baralign, acceleration_baralign;
3928         if (autocvar_hud_panel_physics_baralign == 1)
3929                 acceleration_baralign = speed_baralign = 1;
3930     else if(autocvar_hud_panel_physics_baralign == 4)
3931                 acceleration_baralign = speed_baralign = 2;
3932         else if (autocvar_hud_panel_physics_flip)
3933         {
3934                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3935                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3936         }
3937         else
3938         {
3939                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3940                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3941         }
3942         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3943                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3944
3945         //draw speed
3946         if(speed)
3947         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3948                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3949         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3950         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3951         {
3952                 tmp_size_x = panel_size_x * 0.75;
3953                 tmp_size_y = panel_size_y * text_scale;
3954                 if (speed_baralign)
3955                         tmp_offset_x = panel_size_x - tmp_size_x;
3956                 //else
3957                         //tmp_offset_x = 0;
3958                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3959                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3960
3961                 //draw speed unit
3962                 if (speed_baralign)
3963                         tmp_offset_x = 0;
3964                 else
3965                         tmp_offset_x = tmp_size_x;
3966                 if (autocvar_hud_panel_physics_speed_unit_show)
3967                 {
3968                         //tmp_offset_y = 0;
3969                         tmp_size_x = panel_size_x * (1 - 0.75);
3970                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3971                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3972                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3973                 }
3974         }
3975
3976         //compute and draw top speed
3977         if (autocvar_hud_panel_physics_topspeed)
3978         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3979         {
3980                 if (autocvar__hud_configure)
3981                 {
3982                         top_speed = floor( max_speed * 0.75 + 0.5 );
3983                         f = 1;
3984                 }
3985                 else
3986                 {
3987                         if (speed >= top_speed)
3988                         {
3989                                 top_speed = speed;
3990                                 top_speed_time = time;
3991                         }
3992                         if (top_speed != 0)
3993                         {
3994                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3995                                 // divide by f to make it start from 1
3996                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3997                         }
3998             else //hide top speed 0, it would be stupid
3999                                 f = 0;
4000                 }
4001                 if (f > 0)
4002                 {
4003                         //top speed progressbar peak
4004                         if(speed < top_speed)
4005                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4006                         {
4007                                 float peak_offset_x;
4008                                 vector peak_size = '0 0 0';
4009                                 if (speed_baralign == 0)
4010                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
4011                 else if (speed_baralign == 1)
4012                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
4013                 else // if (speed_baralign == 2)
4014                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
4015                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
4016                 peak_size_y = panel_size_y;
4017                 if (speed_baralign == 2) // draw two peaks, on both sides
4018                 {
4019                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4020                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4021                 }
4022                 else
4023                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4024                         }
4025
4026                         //top speed
4027                         tmp_offset_y = panel_size_y * 0.4;
4028                         tmp_size_x = panel_size_x * (1 - 0.75);
4029                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
4030                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
4031                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4032                 }
4033                 else
4034                         top_speed = 0;
4035         }
4036
4037         //draw acceleration
4038         if(acceleration)
4039         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4040         {
4041                 vector progressbar_color;
4042                 if(acceleration < 0)
4043                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4044                 else
4045                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4046
4047                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4048                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4049                         f = sqrt(f);
4050
4051                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4052                 {
4053                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
4054
4055                         if (acceleration_baralign == 1)
4056                                 tmp_offset_x = panel_size_x - tmp_size_x;
4057                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4058                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
4059                         else
4060                                 tmp_offset_x = 0;
4061                         tmp_offset_y = 0;
4062                 }
4063                 else
4064                 {
4065                         tmp_size = panel_size;
4066                         tmp_offset = '0 0 0';
4067                 }
4068
4069                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4070         }
4071         tmp_size_x = panel_size_x;
4072         tmp_size_y = panel_size_y * text_scale;
4073         tmp_offset_x = 0;
4074         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4075         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4076                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4077
4078         draw_endBoldFont();
4079 }
4080
4081 // CenterPrint (#16)
4082 //
4083 #define CENTERPRINT_MAX_MSGS 10
4084 #define CENTERPRINT_MAX_ENTRIES 50
4085 #define CENTERPRINT_SPACING 0.7
4086 float cpm_index;
4087 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4088 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4089 float centerprint_time[CENTERPRINT_MAX_MSGS];
4090 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4091 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4092 float centerprint_showing;
4093
4094 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4095 {
4096         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4097         float i, j;
4098
4099         if(strMessage == "" && new_id == 0)
4100                 return;
4101
4102         // strip trailing newlines
4103         j = strlen(strMessage) - 1;
4104         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4105                 --j;
4106         if (j < strlen(strMessage) - 1)
4107                 strMessage = substring(strMessage, 0, j + 1);
4108
4109         if(strMessage == "" && new_id == 0)
4110                 return;
4111
4112         // strip leading newlines
4113         j = 0;
4114         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4115                 ++j;
4116         if (j > 0)
4117                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4118
4119         if(strMessage == "" && new_id == 0)
4120                 return;
4121
4122         if (!centerprint_showing)
4123                 centerprint_showing = TRUE;
4124
4125         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4126         {
4127                 if (j == CENTERPRINT_MAX_MSGS)
4128                         j = 0;
4129                 if (new_id && new_id == centerprint_msgID[j])
4130                 {
4131                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4132                         {
4133                                 // fade out the current msg (duration and countdown_num are ignored)
4134                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4135                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4136                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4137                                 return;
4138                         }
4139                         break; // found a msg with the same id, at position j
4140                 }
4141         }
4142
4143         if (i == CENTERPRINT_MAX_MSGS)
4144         {
4145                 // a msg with the same id was not found, add the msg at the next position
4146                 --cpm_index;
4147                 if (cpm_index == -1)
4148                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4149                 j = cpm_index;
4150         }
4151         if(centerprint_messages[j])
4152                 strunzone(centerprint_messages[j]);
4153         centerprint_messages[j] = strzone(strMessage);
4154         centerprint_msgID[j] = new_id;
4155         if (duration < 0)
4156         {
4157                 centerprint_time[j] = -1;
4158                 centerprint_expire_time[j] = time;
4159         }
4160         else
4161         {
4162                 if(duration == 0)
4163                         duration = max(1, autocvar_hud_panel_centerprint_time);
4164                 centerprint_time[j] = duration;
4165                 centerprint_expire_time[j] = time + duration;
4166         }
4167         centerprint_countdown_num[j] = countdown_num;
4168 }
4169
4170 void centerprint_hud(string strMessage)
4171 {
4172         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4173 }
4174
4175 void reset_centerprint_messages(void)
4176 {
4177         float i;
4178         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4179         {
4180                 centerprint_expire_time[i] = 0;
4181                 centerprint_time[i] = 1;
4182                 centerprint_msgID[i] = 0;
4183                 if(centerprint_messages[i])
4184                         strunzone(centerprint_messages[i]);
4185                 centerprint_messages[i] = string_null;
4186         }
4187 }
4188 float hud_configure_cp_generation_time;
4189 void HUD_CenterPrint (void)
4190 {
4191         if(!autocvar__hud_configure)
4192         {
4193                 if(!autocvar_hud_panel_centerprint) return;
4194
4195                 if (hud_configure_prev && hud_configure_prev != -1)
4196                         reset_centerprint_messages();
4197         }
4198         else
4199         {
4200                 if (!hud_configure_prev)
4201                         reset_centerprint_messages();
4202                 if (time > hud_configure_cp_generation_time)
4203                 {
4204                         float r;
4205                         r = random();
4206                         if (r > 0.75)
4207                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4208                         else if (r > 0.5)
4209                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4210                         else
4211                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4212                         hud_configure_cp_generation_time = time + 1 + random()*4;
4213                 }
4214         }
4215
4216         // this panel fades only when the menu does
4217         float hud_fade_alpha_save = 0;
4218         if(scoreboard_fade_alpha)
4219         {
4220                 hud_fade_alpha_save = hud_fade_alpha;
4221                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4222         }
4223         HUD_Panel_UpdateCvars();
4224
4225         if(scoreboard_fade_alpha)
4226         {
4227                 hud_fade_alpha = hud_fade_alpha_save;
4228
4229                 // move the panel below the scoreboard
4230                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4231                         return;
4232                 vector target_pos;
4233
4234                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4235
4236                 if(target_pos_y > panel_pos_y)
4237                 {
4238                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4239                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4240                 }
4241         }
4242
4243         HUD_Panel_DrawBg(1);
4244
4245         if (!centerprint_showing)
4246                 return;
4247
4248         if(panel_bg_padding)
4249         {
4250                 panel_pos += '1 1 0' * panel_bg_padding;
4251                 panel_size -= '2 2 0' * panel_bg_padding;
4252         }
4253
4254         float entries, height;
4255         vector fontsize;
4256         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4257         // height = panel_size_y/entries;
4258         // fontsize = '1 1 0' * height;
4259         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4260         fontsize = '1 1 0' * height;
4261         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4262
4263         float i, j, k, n, g;
4264         float a, sz, align, current_msg_pos_y = 0, msg_size;
4265         vector pos;
4266         string ts;
4267         float all_messages_expired = TRUE;
4268
4269         pos = panel_pos;
4270         if (autocvar_hud_panel_centerprint_flip)
4271                 pos_y += panel_size_y;
4272         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4273         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4274         {
4275                 if (j == CENTERPRINT_MAX_MSGS)
4276                         j = 0;
4277                 if (centerprint_expire_time[j] <= time)
4278                 {
4279                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4280                         {
4281                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4282                                 if (centerprint_countdown_num[j] == 0)
4283                                         continue;
4284                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4285                         }
4286                         else if(centerprint_time[j] != -1)
4287                                 continue;
4288                 }
4289
4290                 all_messages_expired = FALSE;
4291
4292                 // fade the centerprint_hud in/out
4293                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4294                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4295                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4296                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4297                 else // Expiring soon, so fade it out.
4298                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4299
4300                 // while counting down show it anyway in order to hold the current message position
4301                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4302                         continue;
4303                 if (a > 1)
4304                         a = 1;
4305
4306                 // set the size from fading in/out before subsequent fading
4307                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4308
4309                 // also fade it based on positioning
4310                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4311                 {
4312                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4313                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4314                 }
4315                 a *= panel_fg_alpha;
4316
4317                 // finally set the size based on the new theAlpha from subsequent fading
4318                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4319                 drawfontscale = sz * '1 1 0';
4320
4321                 if (centerprint_countdown_num[j])
4322                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4323                 else
4324                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4325
4326                 if (autocvar_hud_panel_centerprint_flip)
4327                 {
4328                         // check if the message can be entirely shown
4329                         for(k = 0; k < n; ++k)
4330                         {
4331                                 getWrappedLine_remaining = argv(k);
4332                                 while(getWrappedLine_remaining)
4333                                 {
4334                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4335                                         if (ts != "")
4336                                                 pos_y -= fontsize_y;
4337                                         else
4338                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4339                                 }
4340                         }
4341                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4342                 }
4343
4344                 msg_size = pos_y;
4345                 for(k = 0; k < n; ++k)
4346                 {
4347                         getWrappedLine_remaining = argv(k);
4348                         while(getWrappedLine_remaining)
4349                         {
4350                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4351                                 if (ts != "")
4352                                 {
4353                                         if (align)
4354                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4355                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4356                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a, DRAWFLAG_NORMAL);
4357                                         pos_y += fontsize_y;
4358                                 }
4359                                 else
4360                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4361                         }
4362                 }
4363
4364                 ++g; // move next position number up
4365
4366                 msg_size = pos_y - msg_size;
4367                 if (autocvar_hud_panel_centerprint_flip)
4368                 {
4369                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4370                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4371                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4372
4373                         if (pos_y < panel_pos_y) // check if the next message can be shown
4374                         {
4375                                 drawfontscale = '1 1 0';
4376                                 return;
4377                         }
4378                 }
4379                 else
4380                 {
4381                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4382                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4383                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4384
4385                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4386                         {
4387                                 drawfontscale = '1 1 0';
4388                                 return;
4389                         }
4390                 }
4391         }
4392         drawfontscale = '1 1 0';
4393         if (all_messages_expired)
4394         {
4395                 centerprint_showing = FALSE;
4396                 reset_centerprint_messages();
4397         }
4398 }
4399
4400 // Buffs (#18)
4401 //
4402 void HUD_Buffs(void)
4403 {
4404         float buffs = getstati(STAT_BUFFS, 0, 24);
4405         if(!autocvar__hud_configure)
4406         {
4407                 if(!autocvar_hud_panel_buffs) return;
4408                 if(spectatee_status == -1) return;
4409                 if(getstati(STAT_HEALTH) <= 0) return;
4410                 if(!buffs) return;
4411         }
4412         else
4413         {
4414                 buffs = Buff_Type_first.items; // force first buff
4415         }
4416
4417         float b = 0; // counter to tell other functions that we have buffs
4418         entity e;
4419         string s = "";
4420         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4421         {
4422                 ++b;
4423                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4424                 if(s == "")
4425                         s = o;
4426                 else
4427                         s = strcat(s, " ", o);
4428         }
4429
4430         HUD_Panel_UpdateCvars();
4431
4432         draw_beginBoldFont();
4433
4434         vector pos, mySize;
4435         pos = panel_pos;
4436         mySize = panel_size;
4437
4438         HUD_Panel_DrawBg(bound(0, b, 1));
4439         if(panel_bg_padding)
4440         {
4441                 pos += '1 1 0' * panel_bg_padding;
4442                 mySize -= '2 2 0' * panel_bg_padding;
4443         }
4444
4445         //float panel_ar = mySize_x/mySize_y;
4446         //float is_vertical = (panel_ar < 1);
4447         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4448         vector buff_offset = '0 0 0';
4449
4450         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4451         {
4452                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4453                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4454         }
4455
4456         draw_endBoldFont();
4457 }
4458
4459
4460 /*
4461 ==================
4462 Main HUD system
4463 ==================
4464 */
4465
4466 void HUD_Reset (void)
4467 {
4468         // reset gametype specific icons
4469         if(gametype == MAPINFO_TYPE_CTF)
4470                 HUD_Mod_CTF_Reset();
4471 }
4472
4473 void HUD_Main (void)
4474 {
4475         float i;
4476         // global hud theAlpha fade
4477         if(menu_enabled == 1)
4478                 hud_fade_alpha = 1;
4479         else
4480                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4481
4482         if(scoreboard_fade_alpha)
4483                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4484
4485         HUD_Configure_Frame();
4486
4487         if(intermission == 2) // no hud during mapvote
4488                 hud_fade_alpha = 0;
4489
4490         // panels that we want to be active together with the scoreboard
4491         // they must fade only when the menu does
4492         if(scoreboard_fade_alpha == 1)
4493         {
4494                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4495                 return;
4496         }
4497
4498         if(!autocvar__hud_configure && !hud_fade_alpha)
4499                 return;
4500
4501         // Drawing stuff
4502         if (hud_skin_prev != autocvar_hud_skin)
4503         {
4504                 if (hud_skin_path)
4505                         strunzone(hud_skin_path);
4506                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4507                 if (hud_skin_prev)
4508                         strunzone(hud_skin_prev);
4509                 hud_skin_prev = strzone(autocvar_hud_skin);
4510         }
4511
4512     current_player = player_localentnum;
4513
4514         // draw the dock
4515         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4516         {
4517                 float f;
4518                 vector color;
4519                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4520                 if((teamplay) && hud_dock_color_team) {
4521                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4522                                 color = '1 0 0' * hud_dock_color_team;
4523                         else
4524                                 color = myteamcolors * hud_dock_color_team;
4525                 }
4526                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4527                         color = '1 0 0' * hud_dock_color_team;
4528                 }
4529                 else
4530                 {
4531                         string hud_dock_color = autocvar_hud_dock_color;
4532                         if(hud_dock_color == "shirt") {
4533                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4534                                 color = colormapPaletteColor(floor(f / 16), 0);
4535                         }
4536                         else if(hud_dock_color == "pants") {
4537                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4538                                 color = colormapPaletteColor(f % 16, 1);
4539                         }
4540                         else
4541                                 color = stov(hud_dock_color);
4542                 }
4543
4544                 string pic;
4545                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4546                 if(precache_pic(pic) == "") {
4547                         pic = strcat(hud_skin_path, "/dock_medium");
4548                         if(precache_pic(pic) == "") {
4549                                 pic = "gfx/hud/default/dock_medium";
4550                         }
4551                 }
4552                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4553         }
4554
4555         // cache the panel order into the panel_order array
4556         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4557                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4558                         panel_order[i] = -1;
4559                 string s = "";
4560                 float p_num, warning = false;
4561                 float argc = tokenize_console(autocvar__hud_panelorder);
4562                 if (argc > HUD_PANEL_NUM)
4563                         warning = true;
4564                 //first detect wrong/missing panel numbers
4565                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4566                         p_num = stof(argv(i));
4567                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4568                                 if (panel_order[p_num] == -1) //found for the first time?
4569                                         s = strcat(s, ftos(p_num), " ");
4570                                 panel_order[p_num] = 1; //mark as found
4571                         }
4572                         else
4573                                 warning = true;
4574                 }
4575                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4576                         if (panel_order[i] == -1) {
4577                                 warning = true;
4578                                 s = strcat(s, ftos(i), " "); //add missing panel number
4579                         }
4580                 }
4581                 if (warning)
4582                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4583
4584                 cvar_set("_hud_panelorder", s);
4585                 if(hud_panelorder_prev)
4586                         strunzone(hud_panelorder_prev);
4587                 hud_panelorder_prev = strzone(s);
4588
4589                 //now properly set panel_order
4590                 tokenize_console(s);
4591                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4592                         panel_order[i] = stof(argv(i));
4593                 }
4594         }
4595
4596         hud_draw_maximized = 0;
4597         // draw panels in order specified by panel_order array
4598         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4599                 (panel = hud_panel[panel_order[i]]).panel_draw();
4600
4601         hud_draw_maximized = 1; // panels that may be maximized must check this var
4602         // draw maximized panels on top
4603         if(hud_panel_radar_maximized)
4604                 (panel = HUD_PANEL(RADAR)).panel_draw();
4605         if(autocvar__con_chat_maximized)
4606                 (panel = HUD_PANEL(CHAT)).panel_draw();
4607
4608         HUD_Configure_PostDraw();
4609
4610         hud_configure_prev = autocvar__hud_configure;
4611 }