qcsrc/client/hud.qc

   1 #include "hud.qh"
   2 #include "_all.qh"
   3
   4 #include "hud_config.qh"
   5 #include "scoreboard.qh"
   6 #include "sortlist.qh"
   7 #include "teamradar.qh"
   8 #include "t_items.qh"
   9
  10 #include "../common/buffs.qh"
  11 #include "../common/constants.qh"
  12 #include "../common/counting.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16
  17 #include "../server/mutators/gamemode_ctf.qh"
  18
  19 #include "../common/stats.qh"
  20
  21 #include "../csqcmodellib/cl_player.qh"
  22
  23 #include "../warpzonelib/mathlib.qh"
  24
  25 /*
  26 ==================
  27 Misc HUD functions
  28 ==================
  29 */
  30
  31 // a border picture is a texture containing nine parts:
  32 //   1/4 width: left part
  33 //   1/2 width: middle part (stretched)
  34 //   1/4 width: right part
  35 // divided into
  36 //   1/4 height: top part
  37 //   1/2 height: middle part (stretched)
  38 //   1/4 height: bottom part
  39 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  40 {
  41     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  42     {
  43                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  44                 return;
  45     }
  46         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  47         {
  48                 // draw only the central part
  49                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  50                 return;
  51         }
  52
  53         vector dX, dY;
  54         vector width, height;
  55         vector bW, bH;
  56         //pic = draw_UseSkinFor(pic);
  57         width = eX * theSize.x;
  58         height = eY * theSize.y;
  59         if(theSize.x <= theBorderSize.x * 2)
  60         {
  61                 // not wide enough... draw just left and right then
  62                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  63                 if(theSize.y <= theBorderSize.y * 2)
  64                 {
  65                         // not high enough... draw just corners
  66                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  67                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  71                 }
  72                 else
  73                 {
  74                         dY = theBorderSize.x * eY;
  75                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  81                 }
  82         }
  83         else
  84         {
  85                 if(theSize.y <= theBorderSize.y * 2)
  86                 {
  87                         // not high enough... draw just top and bottom then
  88                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  89                         dX = theBorderSize.x * eX;
  90                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  93                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  94                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  95                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  96                 }
  97                 else
  98                 {
  99                         dX = theBorderSize.x * eX;
 100                         dY = theBorderSize.x * eY;
 101                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 102                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
 103                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 104                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 105                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
 106                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 107                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 108                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
 109                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 110                 }
 111         }
 112 }
 113
 114 vector HUD_Get_Num_Color (float x, float maxvalue)
 115 {
 116         float blinkingamt;
 117         vector color;
 118         if(x >= maxvalue) {
 119                 color.x = sin(2*M_PI*time);
 120                 color.y = 1;
 121                 color.z = sin(2*M_PI*time);
 122         }
 123         else if(x > maxvalue * 0.75) {
 124                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 125                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 126                 color.z = 0;
 127         }
 128         else if(x > maxvalue * 0.5) {
 129                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 130                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 131                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 132         }
 133         else if(x > maxvalue * 0.25) {
 134                 color.x = 1;
 135                 color.y = 1;
 136                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 137         }
 138         else if(x > maxvalue * 0.1) {
 139                 color.x = 1;
 140                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 141                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 142         }
 143         else {
 144                 color.x = 1;
 145                 color.y = 0;
 146                 color.z = 0;
 147         }
 148
 149         blinkingamt = (1 - x/maxvalue/0.25);
 150         if(blinkingamt > 0)
 151         {
 152                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 153                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 154                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 155         }
 156         return color;
 157 }
 158
 159 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
 160 {
 161         float aspect = size_y / size_x;
 162         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 163 }
 164
 165 vector HUD_GetTableSize(int item_count, vector psize, float item_aspect)
 166 {
 167         float columns, rows;
 168         float ratio, best_ratio = 0;
 169         float best_columns = 1, best_rows = 1;
 170         bool vertical = (psize.x / psize.y >= item_aspect);
 171         if(vertical)
 172         {
 173                 psize = eX * psize.y + eY * psize.x;
 174                 item_aspect = 1 / item_aspect;
 175         }
 176
 177         rows = ceil(sqrt(item_count));
 178         columns = ceil(item_count/rows);
 179         while(columns >= 1)
 180         {
 181                 ratio = (psize.x/columns) / (psize.y/rows);
 182                 if(ratio > item_aspect)
 183                         ratio = item_aspect * item_aspect / ratio;
 184
 185                 if(ratio <= best_ratio)
 186                         break; // ratio starts decreasing by now, skip next configurations
 187
 188                 best_columns = columns;
 189                 best_rows = rows;
 190                 best_ratio = ratio;
 191
 192                 if(columns == 1)
 193                         break;
 194
 195                 --columns;
 196                 rows = ceil(item_count/columns);
 197         }
 198
 199         if(vertical)
 200                 return eX * best_rows + eY * best_columns;
 201         else
 202                 return eX * best_columns + eY * best_rows;
 203 }
 204
 205 float stringwidth_colors(string s, vector theSize)
 206 {
 207         return stringwidth(s, true, theSize);
 208 }
 209
 210 float stringwidth_nocolors(string s, vector theSize)
 211 {
 212         return stringwidth(s, false, theSize);
 213 }
 214
 215 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 216 {
 217         position.x -= 2 / 3 * strlen(text) * theScale.x;
 218         drawstring(position, text, theScale, rgb, theAlpha, flag);
 219 }
 220
 221 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 222 {
 223         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 224         drawstring(position, text, theScale, rgb, theAlpha, flag);
 225 }
 226
 227 // return the string of the onscreen race timer
 228 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 229 {
 230         string col;
 231         string timestr;
 232         string cpname;
 233         string lapstr;
 234         lapstr = "";
 235
 236         if(theirtime == 0) // goal hit
 237         {
 238                 if(mytime > 0)
 239                 {
 240                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 241                         col = "^1";
 242                 }
 243                 else if(mytime == 0)
 244                 {
 245                         timestr = "+0.0";
 246                         col = "^3";
 247                 }
 248                 else
 249                 {
 250                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 251                         col = "^2";
 252                 }
 253
 254                 if(lapdelta > 0)
 255                 {
 256                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 257                         col = "^2";
 258                 }
 259                 else if(lapdelta < 0)
 260                 {
 261                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 262                         col = "^1";
 263                 }
 264         }
 265         else if(theirtime > 0) // anticipation
 266         {
 267                 if(mytime >= theirtime)
 268                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 269                 else
 270                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 271                 col = "^3";
 272         }
 273         else
 274         {
 275                 col = "^7";
 276                 timestr = "";
 277         }
 278
 279         if(cp == 254)
 280                 cpname = _("Start line");
 281         else if(cp == 255)
 282                 cpname = _("Finish line");
 283         else if(cp)
 284                 cpname = sprintf(_("Intermediate %d"), cp);
 285         else
 286                 cpname = _("Finish line");
 287
 288         if(theirtime < 0)
 289                 return strcat(col, cpname);
 290         else if(theirname == "")
 291                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 292         else
 293                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 294 }
 295
 296 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 297 int race_CheckName(string net_name)
 298 {
 299         int i;
 300         for (i=RANKINGS_CNT-1;i>=0;--i)
 301                 if(grecordholder[i] == net_name)
 302                         return i+1;
 303         return 0;
 304 }
 305
 306 int GetPlayerColorForce(int i)
 307 {
 308         if(!teamplay)
 309                 return 0;
 310         else
 311                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 312 }
 313
 314 int GetPlayerColor(int i)
 315 {
 316         if(!playerslots[i].gotscores) // unconnected
 317                 return NUM_SPECTATOR;
 318         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 319                 return NUM_SPECTATOR;
 320         else
 321                 return GetPlayerColorForce(i);
 322 }
 323
 324 string GetPlayerName(int i)
 325 {
 326         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 327 }
 328
 329
 330 /*
 331 ==================
 332 HUD panels
 333 ==================
 334 */
 335
 336 // draw the background/borders
 337 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 338         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 339                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 340 } while(0)
 341
 342 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 343 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 344 {
 345         if(!length_ratio || !theAlpha)
 346                 return;
 347         if(length_ratio > 1)
 348                 length_ratio = 1;
 349         if (baralign == 3)
 350         {
 351                 if(length_ratio < -1)
 352                         length_ratio = -1;
 353         }
 354         else if(length_ratio < 0)
 355                 return;
 356
 357         vector square;
 358         vector width, height;
 359         if(vertical) {
 360                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 361                 if(precache_pic(pic) == "") {
 362                         pic = "gfx/hud/default/progressbar_vertical";
 363                 }
 364
 365         if (baralign == 1) // bottom align
 366                         theOrigin.y += (1 - length_ratio) * theSize.y;
 367         else if (baralign == 2) // center align
 368             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 369         else if (baralign == 3) // center align, positive values down, negative up
 370                 {
 371                         theSize.y *= 0.5;
 372                         if (length_ratio > 0)
 373                                 theOrigin.y += theSize.y;
 374                         else
 375                         {
 376                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 377                                 length_ratio = -length_ratio;
 378                         }
 379                 }
 380                 theSize.y *= length_ratio;
 381
 382                 vector bH;
 383                 width = eX * theSize.x;
 384                 height = eY * theSize.y;
 385                 if(theSize.y <= theSize.x * 2)
 386                 {
 387                         // button not high enough
 388                         // draw just upper and lower part then
 389                         square = eY * theSize.y * 0.5;
 390                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 391                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 392                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 393                 }
 394                 else
 395                 {
 396                         square = eY * theSize.x;
 397                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 398                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 399                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 400                 }
 401         } else {
 402                 pic = strcat(hud_skin_path, "/", pic);
 403                 if(precache_pic(pic) == "") {
 404                         pic = "gfx/hud/default/progressbar";
 405                 }
 406
 407                 if (baralign == 1) // right align
 408                         theOrigin.x += (1 - length_ratio) * theSize.x;
 409         else if (baralign == 2) // center align
 410             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 411         else if (baralign == 3) // center align, positive values on the right, negative on the left
 412                 {
 413                         theSize.x *= 0.5;
 414                         if (length_ratio > 0)
 415                                 theOrigin.x += theSize.x;
 416                         else
 417                         {
 418                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 419                                 length_ratio = -length_ratio;
 420                         }
 421                 }
 422                 theSize.x *= length_ratio;
 423
 424                 vector bW;
 425                 width = eX * theSize.x;
 426                 height = eY * theSize.y;
 427                 if(theSize.x <= theSize.y * 2)
 428                 {
 429                         // button not wide enough
 430                         // draw just left and right part then
 431                         square = eX * theSize.x * 0.5;
 432                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 433                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 434                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 435                 }
 436                 else
 437                 {
 438                         square = eX * theSize.y;
 439                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 440                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 441                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 442                 }
 443         }
 444 }
 445
 446 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 447 {
 448         if(!theAlpha)
 449                 return;
 450
 451         string pic;
 452         pic = strcat(hud_skin_path, "/num_leading");
 453         if(precache_pic(pic) == "") {
 454                 pic = "gfx/hud/default/num_leading";
 455         }
 456
 457         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 458         if(mySize.x/mySize.y > 2)
 459                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 460         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 461 }
 462
 463 // Weapon icons (#0)
 464 //
 465 entity weaponorder[WEP_MAXCOUNT];
 466 void weaponorder_swap(int i, int j, entity pass)
 467 {
 468         entity h = weaponorder[i];
 469         weaponorder[i] = weaponorder[j];
 470         weaponorder[j] = h;
 471 }
 472
 473 string weaponorder_cmp_str;
 474 int weaponorder_cmp(int i, int j, entity pass)
 475 {
 476         int ai, aj;
 477         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 478         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 479         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 480 }
 481
 482 void HUD_Weapons(void)
 483 {
 484         // declarations
 485         WepSet weapons_stat = WepSet_GetFromStat();
 486         int i;
 487         float f, a;
 488         float screen_ar;
 489         vector center = '0 0 0';
 490         int weapon_count, weapon_id;
 491         int row, column, rows = 0, columns = 0;
 492         bool vertical_order = true;
 493         float aspect = autocvar_hud_panel_weapons_aspect;
 494
 495         float timeout = autocvar_hud_panel_weapons_timeout;
 496         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 497         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 498
 499         vector barsize = '0 0 0', baroffset = '0 0 0';
 500         vector ammo_color = '1 0 1';
 501         float ammo_alpha = 1;
 502
 503         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 504         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 505
 506         vector weapon_pos, weapon_size = '0 0 0';
 507         vector color;
 508
 509         // check to see if we want to continue
 510         if(hud != HUD_NORMAL) { return; }
 511
 512         if(!autocvar__hud_configure)
 513         {
 514                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 515                         return;
 516                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 517                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 518                 {
 519                         weaponprevtime = time;
 520                         return;
 521                 }
 522         }
 523
 524         // update generic hud functions
 525         HUD_Panel_UpdateCvars();
 526
 527         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 528         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 529         {
 530                 int weapon_cnt;
 531                 if(weaponorder_bypriority)
 532                         strunzone(weaponorder_bypriority);
 533                 if(weaponorder_byimpulse)
 534                         strunzone(weaponorder_byimpulse);
 535
 536                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 537                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 538                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 539
 540                 weapon_cnt = 0;
 541                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 542                 {
 543                         self = get_weaponinfo(i);
 544                         if(self.impulse >= 0)
 545                         {
 546                                 weaponorder[weapon_cnt] = self;
 547                                 ++weapon_cnt;
 548                         }
 549                 }
 550                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 551                         weaponorder[i] = world;
 552                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 553
 554                 weaponorder_cmp_str = string_null;
 555         }
 556
 557         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 558                 complain_weapon = 0;
 559
 560         if(autocvar__hud_configure)
 561         {
 562                 if(!weapons_stat)
 563                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 564                                 weapons_stat |= WepSet_FromWeapon(i);
 565
 566                 #if 0
 567                 /// debug code
 568                 if(cvar("wep_add"))
 569                 {
 570                         weapons_stat = '0 0 0';
 571                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
 572                         for(i = WEP_FIRST; i <= countw; ++i)
 573                                 weapons_stat |= WepSet_FromWeapon(i);
 574                 }
 575                 #endif
 576         }
 577
 578         // determine which weapons are going to be shown
 579         if (autocvar_hud_panel_weapons_onlyowned)
 580         {
 581                 if(autocvar__hud_configure)
 582                 {
 583                         if(menu_enabled != 2)
 584                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 585                 }
 586
 587                 // do we own this weapon?
 588                 weapon_count = 0;
 589                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 590                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 591                                 ++weapon_count;
 592
 593
 594                 // might as well commit suicide now, no reason to live ;)
 595                 if (weapon_count == 0)
 596                         return;
 597
 598                 vector old_panel_size = panel_size;
 599                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 600
 601                 // get the all-weapons layout
 602                 vector table_size = HUD_GetTableSize(WEP_COUNT, padded_panel_size, aspect);
 603                 columns = table_size.x;
 604                 rows = table_size.y;
 605                 weapon_size.x = padded_panel_size.x / columns;
 606                 weapon_size.y = padded_panel_size.y / rows;
 607
 608                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 609                 // we enlarge them a bit when possible to better match the desired aspect ratio
 610                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 611                 {
 612                         // maximum number of rows that allows to display items with the desired aspect ratio
 613                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 614                         columns = min(columns, ceil(weapon_count / max_rows));
 615                         rows = ceil(weapon_count / columns);
 616                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 617                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 618                         vertical_order = false;
 619                 }
 620                 else
 621                 {
 622                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 623                         rows = min(rows, ceil(weapon_count / max_columns));
 624                         columns = ceil(weapon_count / rows);
 625                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 626                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 627                         vertical_order = true;
 628                 }
 629
 630                 // reduce size of the panel
 631                 panel_size.x = columns * weapon_size.x;
 632                 panel_size.y = rows * weapon_size.y;
 633                 panel_size += '2 2 0' * panel_bg_padding;
 634
 635                 // center the resized panel, or snap it to the screen edge when close enough
 636                 if(panel_pos.x > vid_conwidth * 0.001)
 637                 {
 638                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 639                                 panel_pos.x += old_panel_size.x - panel_size.x;
 640                         else
 641                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 642                 }
 643                 else if(old_panel_size.x > vid_conwidth * 0.999)
 644                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 645
 646                 if(panel_pos.y > vid_conheight * 0.001)
 647                 {
 648                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 649                                 panel_pos.y += old_panel_size.y - panel_size.y;
 650                         else
 651                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 652                 }
 653                 else if(old_panel_size.y > vid_conheight * 0.999)
 654                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 655         }
 656         else
 657                 weapon_count = WEP_COUNT;
 658
 659         // animation for fading in/out the panel respectively when not in use
 660         if(!autocvar__hud_configure)
 661         {
 662                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 663                 {
 664                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 665
 666                         // fade the panel alpha
 667                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 668                         {
 669                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 670                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 671                         }
 672                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 673                         {
 674                                 panel_bg_alpha *= (1 - f);
 675                                 panel_fg_alpha *= (1 - f);
 676                         }
 677
 678                         // move the panel off the screen
 679                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 680                         {
 681                                 f *= f; // for a cooler movement
 682                                 center.x = panel_pos.x + panel_size.x/2;
 683                                 center.y = panel_pos.y + panel_size.y/2;
 684                                 screen_ar = vid_conwidth/vid_conheight;
 685                                 if (center.x/center.y < screen_ar) //bottom left
 686                                 {
 687                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 688                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 689                                         else //left
 690                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 691                                 }
 692                                 else //top right
 693                                 {
 694                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 695                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 696                                         else //top
 697                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 698                                 }
 699                                 if(f == 1)
 700                                         center.x = -1; // mark the panel as off screen
 701                         }
 702                         weaponprevtime = time - (1 - f) * timein_effect_length;
 703                 }
 704                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 705                 {
 706                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 707
 708                         // fade the panel alpha
 709                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 710                         {
 711                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 712                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 713                         }
 714                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 715                         {
 716                                 panel_bg_alpha *= (f);
 717                                 panel_fg_alpha *= (f);
 718                         }
 719
 720                         // move the panel back on screen
 721                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 722                         {
 723                                 f *= f; // for a cooler movement
 724                                 f = 1 - f;
 725                                 center.x = panel_pos.x + panel_size.x/2;
 726                                 center.y = panel_pos.y + panel_size.y/2;
 727                                 screen_ar = vid_conwidth/vid_conheight;
 728                                 if (center.x/center.y < screen_ar) //bottom left
 729                                 {
 730                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 731                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 732                                         else //left
 733                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 734                                 }
 735                                 else //top right
 736                                 {
 737                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 738                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 739                                         else //top
 740                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 741                                 }
 742                         }
 743                 }
 744         }
 745
 746         // draw the background, then change the virtual size of it to better fit other items inside
 747         HUD_Panel_DrawBg(1);
 748
 749         if(center.x == -1)
 750                 return;
 751
 752         if(panel_bg_padding)
 753         {
 754                 panel_pos += '1 1 0' * panel_bg_padding;
 755                 panel_size -= '2 2 0' * panel_bg_padding;
 756         }
 757
 758         // after the sizing and animations are done, update the other values
 759
 760         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 761         {
 762                 vector table_size = HUD_GetTableSize(WEP_COUNT, panel_size, aspect);
 763                 columns = table_size.x;
 764                 rows = table_size.y;
 765                 weapon_size.x = panel_size.x / columns;
 766                 weapon_size.y = panel_size.y / rows;
 767                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 768         }
 769
 770         // calculate position/size for visual bar displaying ammount of ammo status
 771         if (autocvar_hud_panel_weapons_ammo)
 772         {
 773                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 774                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 775
 776                 if(weapon_size.x/weapon_size.y > aspect)
 777                 {
 778                         barsize.x = aspect * weapon_size.y;
 779                         barsize.y = weapon_size.y;
 780                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 781                 }
 782                 else
 783                 {
 784                         barsize.y = 1/aspect * weapon_size.x;
 785                         barsize.x = weapon_size.x;
 786                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 787                 }
 788         }
 789         if(autocvar_hud_panel_weapons_accuracy)
 790                 Accuracy_LoadColors();
 791
 792         // draw items
 793         row = column = 0;
 794         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 795         vector noncurrent_pos = '0 0 0';
 796         vector noncurrent_size = weapon_size * bound(0, autocvar_hud_panel_weapons_noncurrent_scale, 1);
 797         float noncurrent_alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_weapons_noncurrent_alpha, 1);
 798         bool isCurrent;
 799
 800         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 801         {
 802                 // retrieve information about the current weapon to be drawn
 803                 self = weaponorder[i];
 804                 weapon_id = self.impulse;
 805                 isCurrent = (self.weapon == switchweapon);
 806
 807                 // skip if this weapon doesn't exist
 808                 if(!self || weapon_id < 0) { continue; }
 809
 810                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 811                 if(autocvar_hud_panel_weapons_onlyowned)
 812                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 813                         continue;
 814
 815                 // figure out the drawing position of weapon
 816                 weapon_pos = (panel_pos + eX * column * weapon_size.x + eY * row * weapon_size.y);
 817                 noncurrent_pos.x = weapon_pos.x + (weapon_size.x - noncurrent_size.x) / 2;
 818                 noncurrent_pos.y = weapon_pos.y + (weapon_size.y - noncurrent_size.y) / 2;
 819
 820                 // draw background behind currently selected weapon
 821                 if(isCurrent)
 822                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 823
 824                 // draw the weapon accuracy
 825                 if(autocvar_hud_panel_weapons_accuracy)
 826                 {
 827                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 828                         if(panel_weapon_accuracy >= 0)
 829                         {
 830                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 831                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 832                         }
 833                 }
 834
 835                 // drawing all the weapon items
 836                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 837                 {
 838                         // draw the weapon image
 839                         if(isCurrent)
 840                                 drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 841                         else
 842                                 drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '1 1 1', noncurrent_alpha, DRAWFLAG_NORMAL);
 843
 844                         // draw weapon label string
 845                         switch(autocvar_hud_panel_weapons_label)
 846                         {
 847                                 case 1: // weapon number
 848                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 849                                         break;
 850
 851                                 case 2: // bind
 852                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 853                                         break;
 854
 855                                 case 3: // weapon name
 856                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 857                                         break;
 858
 859                                 default: // nothing
 860                                         break;
 861                         }
 862
 863                         // draw ammo status bar
 864                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 865                         {
 866                                 float ammo_full;
 867                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 868
 869                                 if(a > 0)
 870                                 {
 871                                         switch(self.ammo_field)
 872                                         {
 873                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 874                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 875                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 876                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 877                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 878                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 879                                                 default: ammo_full = 60;
 880                                         }
 881
 882                                         drawsetcliparea(
 883                                                 weapon_pos.x + baroffset.x,
 884                                                 weapon_pos.y + baroffset.y,
 885                                                 barsize.x * bound(0, a/ammo_full, 1),
 886                                                 barsize.y
 887                                         );
 888
 889                                         drawpic_aspect_skin(
 890                                                 weapon_pos,
 891                                                 "weapon_ammo",
 892                                                 weapon_size,
 893                                                 ammo_color,
 894                                                 ammo_alpha,
 895                                                 DRAWFLAG_NORMAL
 896                                         );
 897
 898                                         drawresetcliparea();
 899                                 }
 900                         }
 901                 }
 902                 else // draw a "ghost weapon icon" if you don't have the weapon
 903                 {
 904                         drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '0.2 0.2 0.2', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 905                 }
 906
 907                 // draw the complain message
 908                 if(self.weapon == complain_weapon)
 909                 {
 910                         if(fadetime)
 911                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 912                         else
 913                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 914
 915                         string s;
 916                         if(complain_weapon_type == 0) {
 917                                 s = _("Out of ammo");
 918                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 919                         }
 920                         else if(complain_weapon_type == 1) {
 921                                 s = _("Don't have");
 922                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 923                         }
 924                         else {
 925                                 s = _("Unavailable");
 926                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 927                         }
 928                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 929                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 930                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 931                 }
 932
 933                 #if 0
 934                 /// debug code
 935                 if(!autocvar_hud_panel_weapons_onlyowned)
 936                 {
 937                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 938                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 939                 }
 940                 #endif
 941
 942                 // continue with new position for the next weapon
 943                 if(vertical_order)
 944                 {
 945                         ++column;
 946                         if(column >= columns)
 947                         {
 948                                 column = 0;
 949                                 ++row;
 950                         }
 951                 }
 952                 else
 953                 {
 954                         ++row;
 955                         if(row >= rows)
 956                         {
 957                                 row = 0;
 958                                 ++column;
 959                         }
 960                 }
 961         }
 962 }
 963
 964 // Ammo (#1)
 965 void DrawNadeProgressBar(vector myPos, vector mySize, float progress, vector color)
 966 {
 967         HUD_Panel_DrawProgressBar(
 968                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 969                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 970                 autocvar_hud_panel_ammo_progressbar_name,
 971                 progress, 0, 0, color,
 972                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 973 }
 974
 975 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 976 {
 977         float bonusNades    = getstatf(STAT_NADE_BONUS);
 978         float bonusProgress = getstatf(STAT_NADE_BONUS_SCORE);
 979         float bonusType     = getstati(STAT_NADE_BONUS_TYPE);
 980         vector nadeColor    = Nade_Color(bonusType);
 981         string nadeIcon     = Nade_Icon(bonusType);
 982
 983         vector iconPos, textPos;
 984
 985         if(autocvar_hud_panel_ammo_iconalign)
 986         {
 987                 iconPos = myPos + eX * 2 * mySize.y;
 988                 textPos = myPos;
 989         }
 990         else
 991         {
 992                 iconPos = myPos;
 993                 textPos = myPos + eX * mySize.y;
 994         }
 995
 996         if(bonusNades > 0 || bonusProgress > 0)
 997         {
 998                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 999
1000                 if(autocvar_hud_panel_ammo_text)
1001                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1002
1003                 if(draw_expanding)
1004                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
1005
1006                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1007         }
1008 }
1009
1010 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
1011 {
1012         if(ammoType == ammo_none)
1013                 return;
1014
1015         // Initialize variables
1016
1017         int ammo;
1018         if(autocvar__hud_configure)
1019         {
1020                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1021                 ammo = 60;
1022         }
1023         else
1024                 ammo = getstati(GetAmmoStat(ammoType));
1025
1026         if(!isCurrent)
1027         {
1028                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1029                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1030                 mySize = mySize * scale;
1031         }
1032
1033         vector iconPos, textPos;
1034         if(autocvar_hud_panel_ammo_iconalign)
1035         {
1036                 iconPos = myPos + eX * 2 * mySize.y;
1037                 textPos = myPos;
1038         }
1039         else
1040         {
1041                 iconPos = myPos;
1042                 textPos = myPos + eX * mySize.y;
1043         }
1044
1045         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1046
1047         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1048         vector textColor;
1049         if(isInfinite)
1050                 textColor = '0.2 0.95 0';
1051         else if(isShadowed)
1052                 textColor = '0 0 0';
1053         else if(ammo < 10)
1054                 textColor = '0.8 0.04 0';
1055         else
1056                 textColor = '1 1 1';
1057
1058         float alpha;
1059         if(isCurrent)
1060                 alpha = panel_fg_alpha;
1061         else if(isShadowed)
1062                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1063         else
1064                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1065
1066         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1067
1068         // Draw item
1069
1070         if(isCurrent)
1071                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1072
1073         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1074                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1075
1076         if(autocvar_hud_panel_ammo_text)
1077                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1078
1079         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1080 }
1081
1082 int nade_prevstatus;
1083 int nade_prevframe;
1084 float nade_statuschange_time;
1085 void HUD_Ammo(void)
1086 {
1087         if(hud != HUD_NORMAL) return;
1088         if(!autocvar__hud_configure)
1089         {
1090                 if(!autocvar_hud_panel_ammo) return;
1091                 if(spectatee_status == -1) return;
1092         }
1093
1094         HUD_Panel_UpdateCvars();
1095
1096         draw_beginBoldFont();
1097
1098         vector pos, mySize;
1099         pos = panel_pos;
1100         mySize = panel_size;
1101
1102         HUD_Panel_DrawBg(1);
1103         if(panel_bg_padding)
1104         {
1105                 pos += '1 1 0' * panel_bg_padding;
1106                 mySize -= '2 2 0' * panel_bg_padding;
1107         }
1108
1109         int rows = 0, columns, row, column;
1110         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1111         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
1112         float nade_statuschange_elapsedtime;
1113         int total_ammo_count;
1114
1115         vector ammo_size;
1116         if (autocvar_hud_panel_ammo_onlycurrent)
1117                 total_ammo_count = 1;
1118         else
1119                 total_ammo_count = AMMO_COUNT;
1120
1121         if(draw_nades)
1122         {
1123                 ++total_ammo_count;
1124                 if (nade_cnt != nade_prevframe)
1125                 {
1126                         nade_statuschange_time = time;
1127                         nade_prevstatus = nade_prevframe;
1128                         nade_prevframe = nade_cnt;
1129                 }
1130         }
1131         else
1132                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1133
1134         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1135         columns = ceil((total_ammo_count)/rows);
1136         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1137
1138         vector offset = '0 0 0'; // fteqcc sucks
1139         float newSize;
1140         if(ammo_size.x/ammo_size.y > 3)
1141         {
1142                 newSize = 3 * ammo_size.y;
1143                 offset.x = ammo_size.x - newSize;
1144                 pos.x += offset.x/2;
1145                 ammo_size.x = newSize;
1146         }
1147         else
1148         {
1149                 newSize = 1/3 * ammo_size.x;
1150                 offset.y = ammo_size.y - newSize;
1151                 pos.y += offset.y/2;
1152                 ammo_size.y = newSize;
1153         }
1154
1155         int i;
1156         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1157         row = column = 0;
1158         if(autocvar_hud_panel_ammo_onlycurrent)
1159         {
1160                 if(autocvar__hud_configure)
1161                 {
1162                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1163                 }
1164                 else
1165                 {
1166                         DrawAmmoItem(
1167                                 pos,
1168                                 ammo_size,
1169                                 (get_weaponinfo(switchweapon)).ammo_field,
1170                                 true,
1171                                 infinite_ammo
1172                         );
1173                 }
1174
1175                 ++row;
1176                 if(row >= rows)
1177                 {
1178                         row = 0;
1179                         column = column + 1;
1180                 }
1181         }
1182         else
1183         {
1184                 .int ammotype;
1185                 row = column = 0;
1186                 for(i = 0; i < AMMO_COUNT; ++i)
1187                 {
1188                         ammotype = GetAmmoFieldFromNum(i);
1189                         DrawAmmoItem(
1190                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1191                                 ammo_size,
1192                                 ammotype,
1193                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1194                                 infinite_ammo
1195                         );
1196
1197                         ++row;
1198                         if(row >= rows)
1199                         {
1200                                 row = 0;
1201                                 column = column + 1;
1202                         }
1203                 }
1204         }
1205
1206         if (draw_nades)
1207         {
1208                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1209
1210                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1211
1212                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1213         }
1214
1215         draw_endBoldFont();
1216 }
1217
1218 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1219 {
1220         vector newPos = '0 0 0', newSize = '0 0 0';
1221         vector picpos, numpos;
1222
1223         if (vertical)
1224         {
1225                 if(mySize.y/mySize.x > 2)
1226                 {
1227                         newSize.y = 2 * mySize.x;
1228                         newSize.x = mySize.x;
1229
1230                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1231                         newPos.x = myPos.x;
1232                 }
1233                 else
1234                 {
1235                         newSize.x = 1/2 * mySize.y;
1236                         newSize.y = mySize.y;
1237
1238                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1239                         newPos.y = myPos.y;
1240                 }
1241
1242                 if(icon_right_align)
1243                 {
1244                         numpos = newPos;
1245                         picpos = newPos + eY * newSize.x;
1246                 }
1247                 else
1248                 {
1249                         picpos = newPos;
1250                         numpos = newPos + eY * newSize.x;
1251                 }
1252
1253                 newSize.y /= 2;
1254                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1255                 // make number smaller than icon, it looks better
1256                 // reduce only y to draw numbers with different number of digits with the same y size
1257                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1258                 newSize.y *= 0.7;
1259                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1260                 return;
1261         }
1262
1263         if(mySize.x/mySize.y > 3)
1264         {
1265                 newSize.x = 3 * mySize.y;
1266                 newSize.y = mySize.y;
1267
1268                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1269                 newPos.y = myPos.y;
1270         }
1271         else
1272         {
1273                 newSize.y = 1/3 * mySize.x;
1274                 newSize.x = mySize.x;
1275
1276                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1277                 newPos.x = myPos.x;
1278         }
1279
1280         if(icon_right_align) // right align
1281         {
1282                 numpos = newPos;
1283                 picpos = newPos + eX * 2 * newSize.y;
1284         }
1285         else // left align
1286         {
1287                 numpos = newPos + eX * newSize.y;
1288                 picpos = newPos;
1289         }
1290
1291         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1292         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1293         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1294         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1295 }
1296
1297 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1298 {
1299         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1300 }
1301
1302 // Powerups (#2)
1303 //
1304
1305 // Powerup item fields (reusing existing fields)
1306 .string message;  // Human readable name
1307 .string netname;  // Icon name
1308 .vector colormod; // Color
1309 .float count;     // Time left
1310 .float lifetime;  // Maximum time
1311
1312 entity powerupItems;
1313 int powerupItemsCount;
1314
1315 void resetPowerupItems()
1316 {
1317         entity item;
1318         for(item = powerupItems; item; item = item.chain)
1319                 item.count = 0;
1320
1321         powerupItemsCount = 0;
1322 }
1323
1324 void addPowerupItem(string name, string icon, vector color, float currentTime, float lifeTime)
1325 {
1326         if(!powerupItems)
1327                 powerupItems = spawn();
1328
1329         entity item;
1330         for(item = powerupItems; item.count; item = item.chain)
1331                 if(!item.chain)
1332                         item.chain = spawn();
1333
1334         item.message  = name;
1335         item.netname  = icon;
1336         item.colormod = color;
1337         item.count    = currentTime;
1338         item.lifetime = lifeTime;
1339
1340         ++powerupItemsCount;
1341 }
1342
1343 int getPowerupItemAlign(int align, int column, int row, int columns, int rows, bool isVertical)
1344 {
1345         if(align < 2)
1346                 return align;
1347
1348         bool isTop    =  isVertical && rows > 1 && row == 0;
1349         bool isBottom =  isVertical && rows > 1 && row == rows-1;
1350         bool isLeft   = !isVertical && columns > 1 && column == 0;
1351         bool isRight  = !isVertical && columns > 1 && column == columns-1;
1352
1353         if(isTop    || isLeft)  return (align == 2) ? 1 : 0;
1354         if(isBottom || isRight) return (align == 2) ? 0 : 1;
1355
1356         return 2;
1357 }
1358
1359 void HUD_Powerups(void)
1360 {
1361         int allItems = getstati(STAT_ITEMS, 0, 24);
1362         int allBuffs = getstati(STAT_BUFFS, 0, 24);
1363         int strengthTime, shieldTime, superTime;
1364
1365         // Initialize items
1366         if(!autocvar__hud_configure)
1367         {
1368                 if(!autocvar_hud_panel_powerups) return;
1369                 if(spectatee_status == -1) return;
1370                 if(getstati(STAT_HEALTH) <= 0) return;
1371                 if(!(allItems & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON)) && !allBuffs) return;
1372
1373                 strengthTime = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1374                 shieldTime = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1375                 superTime = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1376
1377                 if(allItems & IT_UNLIMITED_SUPERWEAPONS)
1378                         superTime = 99;
1379
1380                 // Prevent stuff to show up on mismatch that will be fixed next frame
1381                 if(!(allItems & IT_SUPERWEAPON))
1382                         superTime = 0;
1383         }
1384         else
1385         {
1386                 strengthTime = 15;
1387                 shieldTime = 27;
1388                 superTime = 13;
1389                 allBuffs = 0;
1390         }
1391
1392         // Add items to linked list
1393         resetPowerupItems();
1394
1395         if(strengthTime)
1396                 addPowerupItem("Strength", "strength", autocvar_hud_progressbar_strength_color, strengthTime, 30);
1397         if(shieldTime)
1398                 addPowerupItem("Shield", "shield", autocvar_hud_progressbar_shield_color, shieldTime, 30);
1399         if(superTime)
1400                 addPowerupItem("Superweapons", "superweapons", autocvar_hud_progressbar_superweapons_color, superTime, 30);
1401
1402         entity item;
1403         for(item = Buff_Type_first; item; item = item.enemy)
1404                 if(allBuffs & item.items)
1405                         addPowerupItem(item.message, strcat("buff_", item.netname), item.colormod, bound(0, getstatf(STAT_BUFF_TIME) - time, 99), 60);
1406
1407         if(!powerupItemsCount)
1408                 return;
1409
1410         // Draw panel background
1411         HUD_Panel_UpdateCvars();
1412         HUD_Panel_DrawBg(1);
1413
1414         // Set drawing area
1415         vector pos = panel_pos;
1416         vector size = panel_size;
1417         bool isVertical = size.y > size.x;
1418
1419         if(panel_bg_padding)
1420         {
1421                 pos += '1 1 0' * panel_bg_padding;
1422                 size -= '2 2 0' * panel_bg_padding;
1423         }
1424
1425         // Find best partitioning of the drawing area
1426         const float DESIRED_ASPECT = 6;
1427         float aspect = 0, a;
1428         int columns = 0, c;
1429         int rows = 0, r;
1430         int i = 1;
1431
1432         do
1433         {
1434                 c = floor(powerupItemsCount / i);
1435                 r = ceil(powerupItemsCount / c);
1436                 a = isVertical ? (size.y/r) / (size.x/c) : (size.x/c) / (size.y/r);
1437
1438                 if(i == 1 || fabs(DESIRED_ASPECT - a) < fabs(DESIRED_ASPECT - aspect))
1439                 {
1440                         aspect = a;
1441                         columns = c;
1442                         rows = r;
1443                 }
1444         }
1445         while(++i <= powerupItemsCount);
1446
1447         // Prevent single items from getting too wide
1448         if(powerupItemsCount == 1 && aspect > DESIRED_ASPECT)
1449         {
1450                 if(isVertical)
1451                 {
1452                         size.y *= 0.5;
1453                         pos.y += size.y * 0.5;
1454                 }
1455                 else
1456                 {
1457                         size.x *= 0.5;
1458                         pos.x += size.x * 0.5;
1459                 }
1460         }
1461
1462         // Draw items from linked list
1463         vector itemPos = pos;
1464         vector itemSize = eX * (size.x / columns) + eY * (size.y / rows);
1465         vector textColor = '1 1 1';
1466
1467         int fullSeconds = 0;
1468         int align = 0;
1469         int column = 0;
1470         int row = 0;
1471
1472         draw_beginBoldFont();
1473         for(item = powerupItems; item.count; item = item.chain)
1474         {
1475                 itemPos = eX * (pos.x + column * itemSize.x) + eY * (pos.y + row * itemSize.y);
1476
1477                 // Draw progressbar
1478                 if(autocvar_hud_panel_powerups_progressbar)
1479                 {
1480                         align = getPowerupItemAlign(autocvar_hud_panel_powerups_baralign, column, row, columns, rows, isVertical);
1481                         HUD_Panel_DrawProgressBar(itemPos, itemSize, "progressbar", item.count / item.lifetime, isVertical, align, item.colormod, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1482                 }
1483
1484                 // Draw icon and text
1485                 if(autocvar_hud_panel_powerups_text)
1486                 {
1487                         align = getPowerupItemAlign(autocvar_hud_panel_powerups_iconalign, column, row, columns, rows, isVertical);
1488                         fullSeconds = ceil(item.count);
1489                         textColor = '0.6 0.6 0.6' + (item.colormod * 0.4);
1490
1491                         if(item.count > 1)
1492                                 DrawNumIcon(itemPos, itemSize, fullSeconds, item.netname, isVertical, align, textColor, panel_fg_alpha);
1493                         if(item.count <= 5)
1494                                 DrawNumIcon_expanding(itemPos, itemSize, fullSeconds, item.netname, isVertical, align, textColor, panel_fg_alpha, bound(0, (fullSeconds - item.count) / 0.5, 1));
1495                 }
1496
1497                 // Determine next section
1498                 if(isVertical)
1499                 {
1500                         if(++column >= columns)
1501                         {
1502                                 column = 0;
1503                                 ++row;
1504                         }
1505                 }
1506                 else
1507                 {
1508                         if(++row >= rows)
1509                         {
1510                                 row = 0;
1511                                 ++column;
1512                         }
1513                 }
1514         }
1515         draw_endBoldFont();
1516 }
1517
1518 // Health/armor (#3)
1519 //
1520
1521
1522 void HUD_HealthArmor(void)
1523 {
1524         int armor, health, fuel;
1525         if(!autocvar__hud_configure)
1526         {
1527                 if(!autocvar_hud_panel_healtharmor) return;
1528                 if(hud != HUD_NORMAL) return;
1529                 if(spectatee_status == -1) return;
1530
1531                 health = getstati(STAT_HEALTH);
1532                 if(health <= 0)
1533                 {
1534                         prev_health = -1;
1535                         return;
1536                 }
1537                 armor = getstati(STAT_ARMOR);
1538
1539                 // code to check for spectatee_status changes is in Ent_ClientData()
1540                 // prev_p_health and prev_health can be set to -1 there
1541
1542                 if (prev_p_health == -1)
1543                 {
1544                         // no effect
1545                         health_beforedamage = 0;
1546                         armor_beforedamage = 0;
1547                         health_damagetime = 0;
1548                         armor_damagetime = 0;
1549                         prev_health = health;
1550                         prev_armor = armor;
1551                         old_p_health = health;
1552                         old_p_armor = armor;
1553                         prev_p_health = health;
1554                         prev_p_armor = armor;
1555                 }
1556                 else if (prev_health == -1)
1557                 {
1558                         //start the load effect
1559                         health_damagetime = 0;
1560                         armor_damagetime = 0;
1561                         prev_health = 0;
1562                         prev_armor = 0;
1563                 }
1564                 fuel = getstati(STAT_FUEL);
1565         }
1566         else
1567         {
1568                 health = 150;
1569                 armor = 75;
1570                 fuel = 20;
1571         }
1572
1573         HUD_Panel_UpdateCvars();
1574
1575         draw_beginBoldFont();
1576
1577         vector pos, mySize;
1578         pos = panel_pos;
1579         mySize = panel_size;
1580
1581         HUD_Panel_DrawBg(1);
1582         if(panel_bg_padding)
1583         {
1584                 pos += '1 1 0' * panel_bg_padding;
1585                 mySize -= '2 2 0' * panel_bg_padding;
1586         }
1587
1588         int baralign = autocvar_hud_panel_healtharmor_baralign;
1589         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1590
1591     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1592     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1593         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1594         {
1595                 vector v;
1596                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1597
1598                 float x;
1599                 x = floor(v.x + 1);
1600
1601         float maxtotal = maxhealth + maxarmor;
1602                 string biggercount;
1603                 if(v.z) // NOT fully armored
1604                 {
1605                         biggercount = "health";
1606                         if(autocvar_hud_panel_healtharmor_progressbar)
1607                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1608                         if(armor)
1609             if(autocvar_hud_panel_healtharmor_text)
1610                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1611                 }
1612                 else
1613                 {
1614                         biggercount = "armor";
1615                         if(autocvar_hud_panel_healtharmor_progressbar)
1616                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1617                         if(health)
1618             if(autocvar_hud_panel_healtharmor_text)
1619                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1620                 }
1621         if(autocvar_hud_panel_healtharmor_text)
1622                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1623
1624                 if(fuel)
1625                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1626         }
1627         else
1628         {
1629                 float panel_ar = mySize.x/mySize.y;
1630                 bool is_vertical = (panel_ar < 1);
1631                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1632                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1633                 {
1634                         mySize.x *= 0.5;
1635                         if (autocvar_hud_panel_healtharmor_flip)
1636                                 health_offset.x = mySize.x;
1637                         else
1638                                 armor_offset.x = mySize.x;
1639                 }
1640                 else
1641                 {
1642                         mySize.y *= 0.5;
1643                         if (autocvar_hud_panel_healtharmor_flip)
1644                                 health_offset.y = mySize.y;
1645                         else
1646                                 armor_offset.y = mySize.y;
1647                 }
1648
1649                 bool health_baralign, armor_baralign, fuel_baralign;
1650                 bool health_iconalign, armor_iconalign;
1651                 if (autocvar_hud_panel_healtharmor_flip)
1652                 {
1653                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1654                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1655                         fuel_baralign = health_baralign;
1656                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1657                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1658                 }
1659                 else
1660                 {
1661                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1662                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1663                         fuel_baralign = armor_baralign;
1664                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1665                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1666                 }
1667
1668                 //if(health)
1669                 {
1670                         if(autocvar_hud_panel_healtharmor_progressbar)
1671                         {
1672                                 float p_health, pain_health_alpha;
1673                                 p_health = health;
1674                                 pain_health_alpha = 1;
1675                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1676                                 {
1677                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1678                                         {
1679                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1680                                                 {
1681                                                         if (time - old_p_healthtime < 1)
1682                                                                 old_p_health = prev_p_health;
1683                                                         else
1684                                                                 old_p_health = prev_health;
1685                                                         old_p_healthtime = time;
1686                                                 }
1687                                                 if (time - old_p_healthtime < 1)
1688                                                 {
1689                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1690                                                         prev_p_health = p_health;
1691                                                 }
1692                                         }
1693                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1694                                         {
1695                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1696                                                 {
1697                                                         if (time - health_damagetime >= 1)
1698                                                                 health_beforedamage = prev_health;
1699                                                         health_damagetime = time;
1700                                                 }
1701                                                 if (time - health_damagetime < 1)
1702                                                 {
1703                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1704                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1705                                                 }
1706                                         }
1707                                         prev_health = health;
1708
1709                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1710                                         {
1711                                                 float BLINK_FACTOR = 0.15;
1712                                                 float BLINK_BASE = 0.85;
1713                                                 float BLINK_FREQ = 9;
1714                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1715                                         }
1716                                 }
1717                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1718                         }
1719                         if(autocvar_hud_panel_healtharmor_text)
1720                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1721                 }
1722
1723                 if(armor)
1724                 {
1725                         if(autocvar_hud_panel_healtharmor_progressbar)
1726                         {
1727                                 float p_armor;
1728                                 p_armor = armor;
1729                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1730                                 {
1731                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1732                                         {
1733                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1734                                                 {
1735                                                         if (time - old_p_armortime < 1)
1736                                                                 old_p_armor = prev_p_armor;
1737                                                         else
1738                                                                 old_p_armor = prev_armor;
1739                                                         old_p_armortime = time;
1740                                                 }
1741                                                 if (time - old_p_armortime < 1)
1742                                                 {
1743                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1744                                                         prev_p_armor = p_armor;
1745                                                 }
1746                                         }
1747                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1748                                         {
1749                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1750                                                 {
1751                                                         if (time - armor_damagetime >= 1)
1752                                                                 armor_beforedamage = prev_armor;
1753                                                         armor_damagetime = time;
1754                                                 }
1755                                                 if (time - armor_damagetime < 1)
1756                                                 {
1757                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1758                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1759                                                 }
1760                                         }
1761                                         prev_armor = armor;
1762                                 }
1763                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1764                         }
1765                         if(autocvar_hud_panel_healtharmor_text)
1766                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1767                 }
1768
1769                 if(fuel)
1770                 {
1771                         if (is_vertical)
1772                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1773                         else
1774                                 mySize.y *= 0.2;
1775                         if (panel_ar >= 4)
1776                                 mySize.x *= 2; //restore full panel size
1777                         else if (panel_ar < 1/4)
1778                                 mySize.y *= 2; //restore full panel size
1779                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1780                 }
1781         }
1782
1783         draw_endBoldFont();
1784 }
1785
1786 // Notification area (#4)
1787 //
1788
1789 void HUD_Notify_Push(string icon, string attacker, string victim)
1790 {
1791         if (icon == "")
1792                 return;
1793
1794         ++notify_count;
1795         --notify_index;
1796
1797         if (notify_index == -1)
1798                 notify_index = NOTIFY_MAX_ENTRIES-1;
1799
1800         // Free old strings
1801         if (notify_attackers[notify_index])
1802                 strunzone(notify_attackers[notify_index]);
1803
1804         if (notify_victims[notify_index])
1805                 strunzone(notify_victims[notify_index]);
1806
1807         if (notify_icons[notify_index])
1808                 strunzone(notify_icons[notify_index]);
1809
1810         // Allocate new strings
1811         if (victim != "")
1812         {
1813                 notify_attackers[notify_index] = strzone(attacker);
1814                 notify_victims[notify_index] = strzone(victim);
1815         }
1816         else
1817         {
1818                 // In case of a notification without a victim, the attacker
1819                 // is displayed on the victim's side. Instead of special
1820                 // treatment later on, we can simply switch them here.
1821                 notify_attackers[notify_index] = string_null;
1822                 notify_victims[notify_index] = strzone(attacker);
1823         }
1824
1825         notify_icons[notify_index] = strzone(icon);
1826         notify_times[notify_index] = time;
1827 }
1828
1829 void HUD_Notify(void)
1830 {
1831         if (!autocvar__hud_configure)
1832                 if (!autocvar_hud_panel_notify)
1833                         return;
1834
1835         HUD_Panel_UpdateCvars();
1836         HUD_Panel_DrawBg(1);
1837
1838         if (!autocvar__hud_configure)
1839                 if (notify_count == 0)
1840                         return;
1841
1842         vector pos, size;
1843         pos  = panel_pos;
1844         size = panel_size;
1845
1846         if (panel_bg_padding)
1847         {
1848                 pos  += '1 1 0' * panel_bg_padding;
1849                 size -= '2 2 0' * panel_bg_padding;
1850         }
1851
1852         float fade_start = max(0, autocvar_hud_panel_notify_time);
1853         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1854         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1855
1856         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1857         float entry_height = size.y / entry_count;
1858
1859         float panel_width_half = size.x * 0.5;
1860         float icon_width_half = entry_height * icon_aspect / 2;
1861         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1862
1863         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1864         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1865         vector icon_left = eX * (panel_width_half - icon_width_half);
1866         vector attacker_right = eX * name_maxwidth;
1867         vector victim_left = eX * (size.x - name_maxwidth);
1868
1869         vector attacker_pos, victim_pos, icon_pos;
1870         string attacker, victim, icon;
1871         int i, j, count, step, limit;
1872         float alpha;
1873
1874         if (autocvar_hud_panel_notify_flip)
1875         {
1876                 // Order items from the top down
1877                 i = 0;
1878                 step = +1;
1879                 limit = entry_count;
1880         }
1881         else
1882         {
1883                 // Order items from the bottom up
1884                 i = entry_count - 1;
1885                 step = -1;
1886                 limit = -1;
1887         }
1888
1889         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1890         {
1891                 if(autocvar__hud_configure)
1892                 {
1893                         attacker = sprintf(_("Player %d"), count + 1);
1894                         victim = sprintf(_("Player %d"), count + 2);
1895                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1896                         alpha = bound(0, 1.2 - count / entry_count, 1);
1897                 }
1898                 else
1899                 {
1900                         if (j == NOTIFY_MAX_ENTRIES)
1901                                 j = 0;
1902
1903                         if (notify_times[j] + fade_start > time)
1904                                 alpha = 1;
1905                         else if (fade_time != 0)
1906                         {
1907                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1908                                 if (alpha == 0)
1909                                         break;
1910                         }
1911                         else
1912                                 break;
1913
1914                         attacker = notify_attackers[j];
1915                         victim = notify_victims[j];
1916                         icon = notify_icons[j];
1917                 }
1918
1919                 if (icon != "" && victim != "")
1920                 {
1921                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1922
1923                         icon_pos = pos + icon_left + eY * i * entry_height;
1924                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1925
1926                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1927                         victim_pos = pos + victim_left + name_top;
1928                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1929
1930                         if (attacker != "")
1931                         {
1932                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1933                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1934                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1935                         }
1936                 }
1937         }
1938
1939         notify_count = count;
1940 }
1941
1942 // Timer (#5)
1943 //
1944 // TODO: macro
1945 string seconds_tostring(float sec)
1946 {
1947         float minutes;
1948         minutes = floor(sec / 60);
1949
1950         sec -= minutes * 60;
1951         return sprintf("%d:%02d", minutes, sec);
1952 }
1953
1954 void HUD_Timer(void)
1955 {
1956         if(!autocvar__hud_configure)
1957         {
1958                 if(!autocvar_hud_panel_timer) return;
1959         }
1960
1961         HUD_Panel_UpdateCvars();
1962
1963         draw_beginBoldFont();
1964
1965         vector pos, mySize;
1966         pos = panel_pos;
1967         mySize = panel_size;
1968
1969         HUD_Panel_DrawBg(1);
1970         if(panel_bg_padding)
1971         {
1972                 pos += '1 1 0' * panel_bg_padding;
1973                 mySize -= '2 2 0' * panel_bg_padding;
1974         }
1975
1976         string timer;
1977         float timelimit, elapsedTime, timeleft, minutesLeft;
1978
1979         timelimit = getstatf(STAT_TIMELIMIT);
1980
1981         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1982         timeleft = ceil(timeleft);
1983
1984         minutesLeft = floor(timeleft / 60);
1985
1986         vector timer_color;
1987         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1988                 timer_color = '1 1 1'; //white
1989         else if(minutesLeft >= 1)
1990                 timer_color = '1 1 0'; //yellow
1991         else
1992                 timer_color = '1 0 0'; //red
1993
1994         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1995                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1996                         //while restart is still active, show 00:00
1997                         timer = seconds_tostring(0);
1998                 } else {
1999                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
2000                         timer = seconds_tostring(elapsedTime);
2001                 }
2002         } else {
2003                 timer = seconds_tostring(timeleft);
2004         }
2005
2006         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2007
2008         draw_endBoldFont();
2009 }
2010
2011 // Radar (#6)
2012 //
2013 void HUD_Radar(void)
2014 {
2015         if (!autocvar__hud_configure)
2016         {
2017                 if (hud_panel_radar_maximized)
2018                 {
2019                         if (!hud_draw_maximized) return;
2020                 }
2021                 else
2022                 {
2023                         if (autocvar_hud_panel_radar == 0) return;
2024                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
2025                         if(radar_panel_modified)
2026                         {
2027                                 panel.update_time = time; // forces reload of panel attributes
2028                                 radar_panel_modified = false;
2029                         }
2030                 }
2031         }
2032
2033         HUD_Panel_UpdateCvars();
2034
2035         float f = 0;
2036
2037         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2038         {
2039                 panel_size = autocvar_hud_panel_radar_maximized_size;
2040                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2041                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2042                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2043                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2044
2045                 string panel_bg;
2046                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2047                 if(precache_pic(panel_bg) == "")
2048                         panel_bg = "gfx/hud/default/border_default"; // fallback
2049                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2050                         radar_panel_modified = true;
2051                 if(panel.current_panel_bg)
2052                         strunzone(panel.current_panel_bg);
2053                 panel.current_panel_bg = strzone(panel_bg);
2054
2055                 switch(hud_panel_radar_maximized_zoommode)
2056                 {
2057                         default:
2058                         case 0:
2059                                 f = current_zoomfraction;
2060                                 break;
2061                         case 1:
2062                                 f = 1 - current_zoomfraction;
2063                                 break;
2064                         case 2:
2065                                 f = 0;
2066                                 break;
2067                         case 3:
2068                                 f = 1;
2069                                 break;
2070                 }
2071
2072                 switch(hud_panel_radar_maximized_rotation)
2073                 {
2074                         case 0:
2075                                 teamradar_angle = view_angles.y - 90;
2076                                 break;
2077                         default:
2078                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2079                                 break;
2080                 }
2081         }
2082         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2083         {
2084                 switch(hud_panel_radar_zoommode)
2085                 {
2086                         default:
2087                         case 0:
2088                                 f = current_zoomfraction;
2089                                 break;
2090                         case 1:
2091                                 f = 1 - current_zoomfraction;
2092                                 break;
2093                         case 2:
2094                                 f = 0;
2095                                 break;
2096                         case 3:
2097                                 f = 1;
2098                                 break;
2099                 }
2100
2101                 switch(hud_panel_radar_rotation)
2102                 {
2103                         case 0:
2104                                 teamradar_angle = view_angles.y - 90;
2105                                 break;
2106                         default:
2107                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2108                                 break;
2109                 }
2110         }
2111
2112         vector pos, mySize;
2113         pos = panel_pos;
2114         mySize = panel_size;
2115
2116         HUD_Panel_DrawBg(1);
2117         if(panel_bg_padding)
2118         {
2119                 pos += '1 1 0' * panel_bg_padding;
2120                 mySize -= '2 2 0' * panel_bg_padding;
2121         }
2122
2123         int color2;
2124         entity tm;
2125         float scale2d, normalsize, bigsize;
2126
2127         teamradar_origin2d = pos + 0.5 * mySize;
2128         teamradar_size2d = mySize;
2129
2130         if(minimapname == "")
2131                 return;
2132
2133         teamradar_loadcvars();
2134
2135         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2136         teamradar_size2d = mySize;
2137
2138         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2139
2140         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2141         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2142         {
2143                 // max-min distance must fit the radar in any rotation
2144                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2145         }
2146         else
2147         {
2148                 vector c0, c1, c2, c3, span;
2149                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2150                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2151                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2152                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2153                 span = '0 0 0';
2154                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2155                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2156
2157                 // max-min distance must fit the radar in x=x, y=y
2158                 bigsize = min(
2159                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2160                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2161                 );
2162         }
2163
2164         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2165         if(bigsize > normalsize)
2166                 normalsize = bigsize;
2167
2168         teamradar_size =
2169                   f * bigsize
2170                 + (1 - f) * normalsize;
2171         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2172                   f * mi_center
2173                 + (1 - f) * view_origin);
2174
2175         drawsetcliparea(
2176                 pos.x,
2177                 pos.y,
2178                 mySize.x,
2179                 mySize.y
2180         );
2181
2182         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2183
2184         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2185                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2186         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2187                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2188         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2189         {
2190                 color2 = GetPlayerColor(tm.sv_entnum);
2191                 //if(color == NUM_SPECTATOR || color == color2)
2192                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2193         }
2194         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2195
2196         drawresetcliparea();
2197 }
2198
2199 // Score (#7)
2200 //
2201 void HUD_UpdatePlayerTeams();
2202 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2203 {
2204         float score;
2205         entity tm = world, pl;
2206         int SCOREPANEL_MAX_ENTRIES = 6;
2207         float SCOREPANEL_ASPECTRATIO = 2;
2208         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2209         vector fontsize = '1 1 0' * (mySize.y/entries);
2210
2211         vector rgb, score_color;
2212         rgb = '1 1 1';
2213         score_color = '1 1 1';
2214
2215         float name_size = mySize.x*0.75;
2216         float spacing_size = mySize.x*0.04;
2217         const float highlight_alpha = 0.2;
2218         int i = 0, first_pl = 0;
2219         bool me_printed = false;
2220         string s;
2221         if (autocvar__hud_configure)
2222         {
2223                 float players_per_team = 0;
2224                 if (team_count)
2225                 {
2226                         // show team scores in the first line
2227                         float score_size = mySize.x / team_count;
2228                         players_per_team = max(2, ceil((entries - 1) / team_count));
2229                         for(i=0; i<team_count; ++i) {
2230                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2231                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2232                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2233                         }
2234                         first_pl = 1;
2235                         pos.y += fontsize.y;
2236                 }
2237                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2238                 for (i=first_pl; i<entries; ++i)
2239                 {
2240                         //simulate my score is lower than all displayed players,
2241                         //so that I don't appear at all showing pure rankings.
2242                         //This is to better show the difference between the 2 ranking views
2243                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2244                         {
2245                                 rgb = '1 1 0';
2246                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2247                                 s = GetPlayerName(player_localnum);
2248                                 score = 7;
2249                         }
2250                         else
2251                         {
2252                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2253                                 score -= 3;
2254                         }
2255
2256                         if (team_count)
2257                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2258                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2259                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2260                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2261                         pos.y += fontsize.y;
2262                 }
2263                 return;
2264         }
2265
2266         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2267                 HUD_UpdatePlayerTeams();
2268         if (team_count)
2269         {
2270                 // show team scores in the first line
2271                 float score_size = mySize.x / team_count;
2272                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2273                         if(tm.team == NUM_SPECTATOR)
2274                                 continue;
2275                         if (tm.team == myteam)
2276                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2277                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2278                         ++i;
2279                 }
2280                 first_pl = 1;
2281                 pos.y += fontsize.y;
2282                 tm = teams.sort_next;
2283         }
2284         i = first_pl;
2285
2286         do
2287         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2288         {
2289                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2290                         continue;
2291
2292                 if (i == entries-1 && !me_printed && pl != me)
2293                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2294                 {
2295                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2296                                 if (pl.team != NUM_SPECTATOR)
2297                                         break;
2298
2299                         if (pl)
2300                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2301                         else
2302                                 rgb = '1 0 0'; //last: red
2303                         pl = me;
2304                 }
2305
2306                 if (pl == me)
2307                 {
2308                         if (i == first_pl)
2309                                 rgb = '0 1 0'; //first: green
2310                         me_printed = true;
2311                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2312                 }
2313                 if (team_count)
2314                         score_color = Team_ColorRGB(pl.team) * 0.8;
2315                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2316                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2317                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2318                 pos.y += fontsize.y;
2319                 ++i;
2320         }
2321         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2322 }
2323
2324 void HUD_Score(void)
2325 {
2326         if(!autocvar__hud_configure)
2327         {
2328                 if(!autocvar_hud_panel_score) return;
2329                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2330         }
2331
2332         HUD_Panel_UpdateCvars();
2333         vector pos, mySize;
2334         pos = panel_pos;
2335         mySize = panel_size;
2336
2337         HUD_Panel_DrawBg(1);
2338         if(panel_bg_padding)
2339         {
2340                 pos += '1 1 0' * panel_bg_padding;
2341                 mySize -= '2 2 0' * panel_bg_padding;
2342         }
2343
2344         float score, distribution = 0;
2345         string sign;
2346         vector distribution_color;
2347         entity tm, pl, me;
2348
2349         me = playerslots[current_player];
2350
2351         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2352                 string timer, distrtimer;
2353
2354                 pl = players.sort_next;
2355                 if(pl == me)
2356                         pl = pl.sort_next;
2357                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2358                         if(pl.scores[ps_primary] == 0)
2359                                 pl = world;
2360
2361                 score = me.(scores[ps_primary]);
2362                 timer = TIME_ENCODED_TOSTRING(score);
2363
2364                 draw_beginBoldFont();
2365                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2366                         // distribution display
2367                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2368
2369                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2370
2371                         if (distribution <= 0) {
2372                                 distribution_color = '0 1 0';
2373                                 sign = "-";
2374                         }
2375                         else {
2376                                 distribution_color = '1 0 0';
2377                                 sign = "+";
2378                         }
2379                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2380                 }
2381                 // race record display
2382                 if (distribution <= 0)
2383                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2384                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2385                 draw_endBoldFont();
2386         } else if (!teamplay) { // non-teamgames
2387                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2388                 {
2389                         HUD_Score_Rankings(pos, mySize, me);
2390                         return;
2391                 }
2392                 // me vector := [team/connected frags id]
2393                 pl = players.sort_next;
2394                 if(pl == me)
2395                         pl = pl.sort_next;
2396
2397                 if(autocvar__hud_configure)
2398                         distribution = 42;
2399                 else if(pl)
2400                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2401                 else
2402                         distribution = 0;
2403
2404                 score = me.(scores[ps_primary]);
2405                 if(autocvar__hud_configure)
2406                         score = 123;
2407
2408                 if(distribution >= 5)
2409                         distribution_color = eY;
2410                 else if(distribution >= 0)
2411                         distribution_color = '1 1 1';
2412                 else if(distribution >= -5)
2413                         distribution_color = '1 1 0';
2414                 else
2415                         distribution_color = eX;
2416
2417                 string distribution_str;
2418                 distribution_str = ftos(distribution);
2419                 draw_beginBoldFont();
2420                 if (distribution >= 0)
2421                 {
2422                         if (distribution > 0)
2423                                 distribution_str = strcat("+", distribution_str);
2424                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2425                 }
2426                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2427                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2428                 draw_endBoldFont();
2429         } else { // teamgames
2430                 float row, column, rows = 0, columns = 0;
2431                 vector offset = '0 0 0';
2432                 vector score_pos, score_size; //for scores other than myteam
2433                 if(autocvar_hud_panel_score_rankings)
2434                 {
2435                         HUD_Score_Rankings(pos, mySize, me);
2436                         return;
2437                 }
2438                 if(spectatee_status == -1)
2439                 {
2440                         rows = HUD_GetRowCount(team_count, mySize, 3);
2441                         columns = ceil(team_count/rows);
2442                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2443
2444                         float newSize;
2445                         if(score_size.x/score_size.y > 3)
2446                         {
2447                                 newSize = 3 * score_size.y;
2448                                 offset.x = score_size.x - newSize;
2449                                 pos.x += offset.x/2;
2450                                 score_size.x = newSize;
2451                         }
2452                         else
2453                         {
2454                                 newSize = 1/3 * score_size.x;
2455                                 offset.y = score_size.y - newSize;
2456                                 pos.y += offset.y/2;
2457                                 score_size.y = newSize;
2458                         }
2459                 }
2460                 else
2461                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2462
2463                 float max_fragcount;
2464                 max_fragcount = -99;
2465                 draw_beginBoldFont();
2466                 row = column = 0;
2467                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2468                         if(tm.team == NUM_SPECTATOR)
2469                                 continue;
2470                         score = tm.(teamscores[ts_primary]);
2471                         if(autocvar__hud_configure)
2472                                 score = 123;
2473
2474                         if (score > max_fragcount)
2475                                 max_fragcount = score;
2476
2477                         if (spectatee_status == -1)
2478                         {
2479                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2480                                 if (max_fragcount == score)
2481                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2482                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2483                                 ++row;
2484                                 if(row >= rows)
2485                                 {
2486                                         row = 0;
2487                                         ++column;
2488                                 }
2489                         }
2490                         else if(tm.team == myteam) {
2491                                 if (max_fragcount == score)
2492                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2493                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2494                         } else {
2495                                 if (max_fragcount == score)
2496                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2497                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2498                                 ++rows;
2499                         }
2500                 }
2501                 draw_endBoldFont();
2502         }
2503 }
2504
2505 // Race timer (#8)
2506 //
2507 void HUD_RaceTimer (void)
2508 {
2509         if(!autocvar__hud_configure)
2510         {
2511                 if(!autocvar_hud_panel_racetimer) return;
2512                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2513                 if(spectatee_status == -1) return;
2514         }
2515
2516         HUD_Panel_UpdateCvars();
2517
2518         vector pos, mySize;
2519         pos = panel_pos;
2520         mySize = panel_size;
2521
2522         HUD_Panel_DrawBg(1);
2523         if(panel_bg_padding)
2524         {
2525                 pos += '1 1 0' * panel_bg_padding;
2526                 mySize -= '2 2 0' * panel_bg_padding;
2527         }
2528
2529         // always force 4:1 aspect
2530         vector newSize = '0 0 0';
2531         if(mySize.x/mySize.y > 4)
2532         {
2533                 newSize.x = 4 * mySize.y;
2534                 newSize.y = mySize.y;
2535
2536                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2537         }
2538         else
2539         {
2540                 newSize.y = 1/4 * mySize.x;
2541                 newSize.x = mySize.x;
2542
2543                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2544         }
2545         mySize = newSize;
2546
2547         float a, t;
2548         string s, forcetime;
2549
2550         if(autocvar__hud_configure)
2551         {
2552                 s = "0:13:37";
2553                 draw_beginBoldFont();
2554                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2555                 draw_endBoldFont();
2556                 s = _("^1Intermediate 1 (+15.42)");
2557                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2558                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2559                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2560         }
2561         else if(race_checkpointtime)
2562         {
2563                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2564                 s = "";
2565                 forcetime = "";
2566                 if(a > 0) // just hit a checkpoint?
2567                 {
2568                         if(race_checkpoint != 254)
2569                         {
2570                                 if(race_time && race_previousbesttime)
2571                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2572                                 else
2573                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2574                                 if(race_time)
2575                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2576                         }
2577                 }
2578                 else
2579                 {
2580                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2581                         {
2582                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2583                                 if(a > 0) // next one?
2584                                 {
2585                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2586                                 }
2587                         }
2588                 }
2589
2590                 if(s != "" && a > 0)
2591                 {
2592                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2593                 }
2594
2595                 if(race_penaltytime)
2596                 {
2597                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2598                         if(a > 0)
2599                         {
2600                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2601                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2602                         }
2603                 }
2604
2605                 draw_beginBoldFont();
2606
2607                 if(forcetime != "")
2608                 {
2609                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2610                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2611                 }
2612                 else
2613                         a = 1;
2614
2615                 if(race_laptime && race_checkpoint != 255)
2616                 {
2617                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2618                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2619                 }
2620
2621                 draw_endBoldFont();
2622         }
2623         else
2624         {
2625                 if(race_mycheckpointtime)
2626                 {
2627                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2628                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2629                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2630                 }
2631                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2632                 {
2633                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2634                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2635                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2636                 }
2637
2638                 if(race_penaltytime && !race_penaltyaccumulator)
2639                 {
2640                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2641                         a = bound(0, (1 + t - time), 1);
2642                         if(a > 0)
2643                         {
2644                                 if(time < t)
2645                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2646                                 else
2647                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2648                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2649                         }
2650                 }
2651         }
2652 }
2653
2654 // Vote window (#9)
2655 //
2656
2657 void HUD_Vote(void)
2658 {
2659         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2660         {
2661                 vote_active = 1;
2662                 if (autocvar__hud_configure)
2663                 {
2664                         vote_yescount = 0;
2665                         vote_nocount = 0;
2666                         print(_("^1You must answer before entering hud configure mode\n"));
2667                         cvar_set("_hud_configure", "0");
2668                 }
2669                 if(vote_called_vote)
2670                         strunzone(vote_called_vote);
2671                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2672                 uid2name_dialog = 1;
2673         }
2674
2675         if(!autocvar__hud_configure)
2676         {
2677                 if(!autocvar_hud_panel_vote) return;
2678
2679                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2680                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2681
2682                 if(panel_bg_alpha_str == "") {
2683                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2684                 }
2685                 panel_bg_alpha = stof(panel_bg_alpha_str);
2686         }
2687         else
2688         {
2689                 vote_yescount = 3;
2690                 vote_nocount = 2;
2691                 vote_needed = 4;
2692         }
2693
2694         string s;
2695         float a;
2696         if(vote_active != vote_prev) {
2697                 vote_change = time;
2698                 vote_prev = vote_active;
2699         }
2700
2701         if(vote_active || autocvar__hud_configure)
2702                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2703         else
2704                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2705
2706         if(!vote_alpha)
2707                 return;
2708
2709         HUD_Panel_UpdateCvars();
2710
2711         if(uid2name_dialog)
2712         {
2713                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2714                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2715         }
2716
2717     // these must be below above block
2718         vector pos, mySize;
2719         pos = panel_pos;
2720         mySize = panel_size;
2721
2722         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2723         HUD_Panel_DrawBg(a);
2724         a = panel_fg_alpha * a;
2725
2726         if(panel_bg_padding)
2727         {
2728                 pos += '1 1 0' * panel_bg_padding;
2729                 mySize -= '2 2 0' * panel_bg_padding;
2730         }
2731
2732         // always force 3:1 aspect
2733         vector newSize = '0 0 0';
2734         if(mySize.x/mySize.y > 3)
2735         {
2736                 newSize.x = 3 * mySize.y;
2737                 newSize.y = mySize.y;
2738
2739                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2740         }
2741         else
2742         {
2743                 newSize.y = 1/3 * mySize.x;
2744                 newSize.x = mySize.x;
2745
2746                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2747         }
2748         mySize = newSize;
2749
2750         s = _("A vote has been called for:");
2751         if(uid2name_dialog)
2752                 s = _("Allow servers to store and display your name?");
2753         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2754         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2755         if(autocvar__hud_configure)
2756                 s = _("^1Configure the HUD");
2757         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2758
2759         // print the yes/no counts
2760     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2761         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2762     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2763         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2764
2765         // draw the progress bar backgrounds
2766         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2767
2768         // draw the highlights
2769         if(vote_highlighted == 1) {
2770                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2771                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2772         }
2773         else if(vote_highlighted == -1) {
2774                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2775                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2776         }
2777
2778         // draw the progress bars
2779         if(vote_yescount && vote_needed)
2780         {
2781                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2782                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2783         }
2784
2785         if(vote_nocount && vote_needed)
2786         {
2787                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2788                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2789         }
2790
2791         drawresetcliparea();
2792 }
2793
2794 // Mod icons panel (#10)
2795 //
2796
2797 bool mod_active; // is there any active mod icon?
2798
2799 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2800 {
2801         int stat = -1;
2802         string pic = "";
2803         vector color = '0 0 0';
2804         switch(i)
2805         {
2806                 case 0:
2807                         stat = getstati(STAT_REDALIVE);
2808                         pic = "player_red.tga";
2809                         color = '1 0 0';
2810                         break;
2811                 case 1:
2812                         stat = getstati(STAT_BLUEALIVE);
2813                         pic = "player_blue.tga";
2814                         color = '0 0 1';
2815                         break;
2816                 case 2:
2817                         stat = getstati(STAT_YELLOWALIVE);
2818                         pic = "player_yellow.tga";
2819                         color = '1 1 0';
2820                         break;
2821                 default:
2822                 case 3:
2823                         stat = getstati(STAT_PINKALIVE);
2824                         pic = "player_pink.tga";
2825                         color = '1 0 1';
2826                         break;
2827         }
2828
2829         if(mySize.x/mySize.y > aspect_ratio)
2830         {
2831                 i = aspect_ratio * mySize.y;
2832                 myPos.x = myPos.x + (mySize.x - i) / 2;
2833                 mySize.x = i;
2834         }
2835         else
2836         {
2837                 i = 1/aspect_ratio * mySize.x;
2838                 myPos.y = myPos.y + (mySize.y - i) / 2;
2839                 mySize.y = i;
2840         }
2841
2842         if(layout)
2843         {
2844                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2845                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2846         }
2847         else
2848                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2849 }
2850
2851 // Clan Arena and Freeze Tag HUD modicons
2852 void HUD_Mod_CA(vector myPos, vector mySize)
2853 {
2854         mod_active = 1; // required in each mod function that always shows something
2855
2856         int layout;
2857         if(gametype == MAPINFO_TYPE_CA)
2858                 layout = autocvar_hud_panel_modicons_ca_layout;
2859         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2860                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2861         int rows, columns;
2862         float aspect_ratio;
2863         aspect_ratio = (layout) ? 2 : 1;
2864         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2865         columns = ceil(team_count/rows);
2866
2867         int i;
2868         float row = 0, column = 0;
2869         vector pos, itemSize;
2870         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2871         for(i=0; i<team_count; ++i)
2872         {
2873                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2874
2875                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2876
2877                 ++row;
2878                 if(row >= rows)
2879                 {
2880                         row = 0;
2881                         ++column;
2882                 }
2883         }
2884 }
2885
2886 // CTF HUD modicon section
2887 int redflag_prevframe, blueflag_prevframe, yellowflag_prevframe, pinkflag_prevframe, neutralflag_prevframe; // status during previous frame
2888 int redflag_prevstatus, blueflag_prevstatus, yellowflag_prevstatus, pinkflag_prevstatus, neutralflag_prevstatus; // last remembered status
2889 float redflag_statuschange_time, blueflag_statuschange_time, yellowflag_statuschange_time, pinkflag_statuschange_time, neutralflag_statuschange_time; // time when the status changed
2890
2891 void HUD_Mod_CTF_Reset(void)
2892 {
2893         redflag_prevstatus = blueflag_prevstatus = yellowflag_prevstatus = pinkflag_prevstatus = neutralflag_prevstatus = 0;
2894         redflag_prevframe = blueflag_prevframe = yellowflag_prevframe = pinkflag_prevframe = neutralflag_prevframe = 0;
2895         redflag_statuschange_time = blueflag_statuschange_time = yellowflag_statuschange_time = pinkflag_statuschange_time = neutralflag_statuschange_time = 0;
2896 }
2897
2898 void HUD_Mod_CTF(vector pos, vector mySize)
2899 {
2900         vector redflag_pos, blueflag_pos, yellowflag_pos, pinkflag_pos, neutralflag_pos;
2901         vector flag_size;
2902         float f; // every function should have that
2903
2904         int redflag, blueflag, yellowflag, pinkflag, neutralflag; // current status
2905         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime, yellowflag_statuschange_elapsedtime, pinkflag_statuschange_elapsedtime, neutralflag_statuschange_elapsedtime; // time since the status changed
2906         bool ctf_oneflag; // one-flag CTF mode enabled/disabled
2907         int stat_items = getstati(STAT_CTF_FLAGSTATUS, 0, 24);
2908         float fs, fs2, fs3, size1, size2;
2909         vector e1, e2;
2910
2911         redflag = (stat_items/CTF_RED_FLAG_TAKEN) & 3;
2912         blueflag = (stat_items/CTF_BLUE_FLAG_TAKEN) & 3;
2913         yellowflag = (stat_items/CTF_YELLOW_FLAG_TAKEN) & 3;
2914         pinkflag = (stat_items/CTF_PINK_FLAG_TAKEN) & 3;
2915         neutralflag = (stat_items/CTF_NEUTRAL_FLAG_TAKEN) & 3;
2916
2917         ctf_oneflag = (stat_items & CTF_FLAG_NEUTRAL);
2918
2919         mod_active = (redflag || blueflag || yellowflag || pinkflag || neutralflag);
2920
2921         if (autocvar__hud_configure) {
2922                 redflag = 1;
2923                 blueflag = 2;
2924                 if (team_count >= 3)
2925                         yellowflag = 2;
2926                 if (team_count >= 4)
2927                         pinkflag = 3;
2928                 ctf_oneflag = neutralflag = 0; // disable neutral flag in hud editor?
2929         }
2930
2931         // when status CHANGES, set old status into prevstatus and current status into status
2932         #define X(team) do {                                                                                                                    \
2933                 if (team##flag != team##flag_prevframe) {                                                                       \
2934                 team##flag_statuschange_time = time;                                                                    \
2935                 team##flag_prevstatus = team##flag_prevframe;                                                   \
2936                 team##flag_prevframe = team##flag;                                                                              \
2937         }                                                                                                                                                       \
2938         team##flag_statuschange_elapsedtime = time - team##flag_statuschange_time;      \
2939     } while (0)
2940         X(red);
2941         X(blue);
2942         X(yellow);
2943         X(pink);
2944         X(neutral);
2945         #undef X
2946
2947         const float BLINK_FACTOR = 0.15;
2948         const float BLINK_BASE = 0.85;
2949         // note:
2950         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2951         // thus
2952         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2953         // ensure RMS == 1
2954         const float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2955
2956         #define X(team, cond) \
2957         string team##_icon, team##_icon_prevstatus; \
2958         int team##_alpha, team##_alpha_prevstatus; \
2959         team##_alpha = team##_alpha_prevstatus = 1; \
2960         do { \
2961                 switch (team##flag) { \
2962                         case 1: team##_icon = "flag_" #team "_taken"; break; \
2963                         case 2: team##_icon = "flag_" #team "_lost"; break; \
2964                         case 3: team##_icon = "flag_" #team "_carrying"; team##_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2965                         default: \
2966                                 if ((stat_items & CTF_SHIELDED) && (cond)) { \
2967                                         team##_icon = "flag_" #team "_shielded"; \
2968                                 } else { \
2969                                         team##_icon = string_null; \
2970                                 } \
2971                                 break; \
2972                 } \
2973                 switch (team##flag_prevstatus) { \
2974                         case 1: team##_icon_prevstatus = "flag_" #team "_taken"; break; \
2975                         case 2: team##_icon_prevstatus = "flag_" #team "_lost"; break; \
2976                         case 3: team##_icon_prevstatus = "flag_" #team "_carrying"; team##_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2977                         default: \
2978                                 if (team##flag == 3) { \
2979                                         team##_icon_prevstatus = "flag_" #team "_carrying"; /* make it more visible */\
2980                                 } else if((stat_items & CTF_SHIELDED) && (cond)) { \
2981                                         team##_icon_prevstatus = "flag_" #team "_shielded"; \
2982                                 } else { \
2983                                         team##_icon_prevstatus = string_null; \
2984                                 } \
2985                                 break; \
2986                 } \
2987         } while (0)
2988         X(red, myteam != NUM_TEAM_1);
2989         X(blue, myteam != NUM_TEAM_2);
2990         X(yellow, myteam != NUM_TEAM_3);
2991         X(pink, myteam != NUM_TEAM_4);
2992         X(neutral, true);
2993         #undef X
2994
2995         if (ctf_oneflag) {
2996                 // hacky, but these aren't needed
2997                 red_icon = red_icon_prevstatus = blue_icon = blue_icon_prevstatus = yellow_icon = yellow_icon_prevstatus = pink_icon = pink_icon_prevstatus = string_null;
2998                 fs = fs2 = fs3 = 1;
2999         } else switch (team_count) {
3000                 default:
3001                 case 2: fs = 0.5; fs2 = 0.5; fs3 = 0.5; break;
3002                 case 3: fs = 1; fs2 = 0.35; fs3 = 0.35; break;
3003                 case 4: fs = 0.75; fs2 = 0.25; fs3 = 0.5; break;
3004         }
3005
3006         if (mySize_x > mySize_y) {
3007                 size1 = mySize_x;
3008                 size2 = mySize_y;
3009                 e1 = eX;
3010                 e2 = eY;
3011         } else {
3012                 size1 = mySize_y;
3013                 size2 = mySize_x;
3014                 e1 = eY;
3015                 e2 = eX;
3016         }
3017
3018         switch (myteam) {
3019                 default:
3020                 case NUM_TEAM_1: {
3021                         redflag_pos = pos;
3022                         blueflag_pos = pos + eX * fs2 * size1;
3023                         yellowflag_pos = pos - eX * fs2 * size1;
3024                         pinkflag_pos = pos + eX * fs3 * size1;
3025                         break;
3026                 }
3027                 case NUM_TEAM_2: {
3028                         redflag_pos = pos + eX * fs2 * size1;
3029                         blueflag_pos = pos;
3030                         yellowflag_pos = pos - eX * fs2 * size1;
3031                         pinkflag_pos = pos + eX * fs3 * size1;
3032                         break;
3033                 }
3034                 case NUM_TEAM_3: {
3035                         redflag_pos = pos + eX * fs3 * size1;
3036                         blueflag_pos = pos - eX * fs2 * size1;
3037                         yellowflag_pos = pos;
3038                         pinkflag_pos = pos + eX * fs2 * size1;
3039                         break;
3040                 }
3041                 case NUM_TEAM_4: {
3042                         redflag_pos = pos - eX * fs2 * size1;
3043                         blueflag_pos = pos + eX * fs3 * size1;
3044                         yellowflag_pos = pos + eX * fs2 * size1;
3045                         pinkflag_pos = pos;
3046                         break;
3047                 }
3048         }
3049         neutralflag_pos = pos;
3050         flag_size = e1 * fs * size1 + e2 * size2;
3051
3052         #define X(team) do { \
3053                 f = bound(0, team##flag_statuschange_elapsedtime * 2, 1); \
3054                 if (team##_icon_prevstatus && f < 1) \
3055                         drawpic_aspect_skin_expanding(team##flag_pos, team##_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * team##_alpha_prevstatus, DRAWFLAG_NORMAL, f); \
3056                 if (team##_icon) \
3057                         drawpic_aspect_skin(team##flag_pos, team##_icon, flag_size, '1 1 1', panel_fg_alpha * team##_alpha * f, DRAWFLAG_NORMAL); \
3058         } while (0)
3059         X(red);
3060         X(blue);
3061         X(yellow);
3062         X(pink);
3063         X(neutral);
3064         #undef X
3065 }
3066
3067 // Keyhunt HUD modicon section
3068 vector KH_SLOTS[4];
3069
3070 void HUD_Mod_KH(vector pos, vector mySize)
3071 {
3072         mod_active = 1; // keyhunt should never hide the mod icons panel
3073
3074         // Read current state
3075
3076         int state = getstati(STAT_KH_KEYS);
3077         int i, key_state;
3078         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3079         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3080
3081         for(i = 0; i < 4; ++i)
3082         {
3083                 key_state = (bitshift(state, i * -5) & 31) - 1;
3084
3085                 if(key_state == -1)
3086                         continue;
3087
3088                 if(key_state == 30)
3089                 {
3090                         ++carrying_keys;
3091                         key_state = myteam;
3092                 }
3093
3094                 switch(key_state)
3095                 {
3096                         case NUM_TEAM_1: ++team1_keys; break;
3097                         case NUM_TEAM_2: ++team2_keys; break;
3098                         case NUM_TEAM_3: ++team3_keys; break;
3099                         case NUM_TEAM_4: ++team4_keys; break;
3100                         case 29: ++dropped_keys; break;
3101                 }
3102
3103                 ++all_keys;
3104         }
3105
3106         // Calculate slot measurements
3107
3108         vector slot_size;
3109
3110         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3111         {
3112                 // Quadratic arrangement
3113                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3114                 KH_SLOTS[0] = pos;
3115                 KH_SLOTS[1] = pos + eX * slot_size.x;
3116                 KH_SLOTS[2] = pos + eY * slot_size.y;
3117                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3118         }
3119         else
3120         {
3121                 if(mySize.x > mySize.y)
3122                 {
3123                         // Horizontal arrangement
3124                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3125                         for(i = 0; i < all_keys; ++i)
3126                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3127                 }
3128                 else
3129                 {
3130                         // Vertical arrangement
3131                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3132                         for(i = 0; i < all_keys; ++i)
3133                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3134                 }
3135         }
3136
3137         // Make icons blink in case of RUN HERE
3138
3139         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3140         float alpha;
3141         alpha = 1;
3142
3143         if(carrying_keys)
3144                 switch(myteam)
3145                 {
3146                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3147                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3148                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3149                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3150                 }
3151
3152         // Draw icons
3153
3154         i = 0;
3155
3156         while(team1_keys--)
3157                 if(myteam == NUM_TEAM_1 && carrying_keys)
3158                 {
3159                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3160                         --carrying_keys;
3161                 }
3162                 else
3163                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3164
3165         while(team2_keys--)
3166                 if(myteam == NUM_TEAM_2 && carrying_keys)
3167                 {
3168                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3169                         --carrying_keys;
3170                 }
3171                 else
3172                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3173
3174         while(team3_keys--)
3175                 if(myteam == NUM_TEAM_3 && carrying_keys)
3176                 {
3177                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3178                         --carrying_keys;
3179                 }
3180                 else
3181                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3182
3183         while(team4_keys--)
3184                 if(myteam == NUM_TEAM_4 && carrying_keys)
3185                 {
3186                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3187                         --carrying_keys;
3188                 }
3189                 else
3190                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3191
3192         while(dropped_keys--)
3193                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3194 }
3195
3196 // Keepaway HUD mod icon
3197 int kaball_prevstatus; // last remembered status
3198 float kaball_statuschange_time; // time when the status changed
3199
3200 // we don't need to reset for keepaway since it immediately
3201 // autocorrects prevstatus as to if the player has the ball or not
3202
3203 void HUD_Mod_Keepaway(vector pos, vector mySize)
3204 {
3205         mod_active = 1; // keepaway should always show the mod HUD
3206
3207         float BLINK_FACTOR = 0.15;
3208         float BLINK_BASE = 0.85;
3209         float BLINK_FREQ = 5;
3210         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3211
3212         int stat_items = getstati(STAT_ITEMS, 0, 24);
3213         int kaball = (stat_items/IT_KEY1) & 1;
3214
3215         if(kaball != kaball_prevstatus)
3216         {
3217                 kaball_statuschange_time = time;
3218                 kaball_prevstatus = kaball;
3219         }
3220
3221         vector kaball_pos, kaball_size;
3222
3223         if(mySize.x > mySize.y) {
3224                 kaball_pos = pos + eX * 0.25 * mySize.x;
3225                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3226         } else {
3227                 kaball_pos = pos + eY * 0.25 * mySize.y;
3228                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3229         }
3230
3231         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3232         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3233
3234         if(kaball_prevstatus && f < 1)
3235                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3236
3237         if(kaball)
3238                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3239 }
3240
3241
3242 // Nexball HUD mod icon
3243 void HUD_Mod_NexBall(vector pos, vector mySize)
3244 {
3245         float nb_pb_starttime, dt, p;
3246         int stat_items;
3247
3248         stat_items = getstati(STAT_ITEMS, 0, 24);
3249         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3250
3251         if (stat_items & IT_KEY1)
3252                 mod_active = 1;
3253         else
3254                 mod_active = 0;
3255
3256         //Manage the progress bar if any
3257         if (nb_pb_starttime > 0)
3258         {
3259                 dt = (time - nb_pb_starttime) % nb_pb_period;
3260                 // one period of positive triangle
3261                 p = 2 * dt / nb_pb_period;
3262                 if (p > 1)
3263                         p = 2 - p;
3264
3265                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3266         }
3267
3268         if (stat_items & IT_KEY1)
3269                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3270 }
3271
3272 // Race/CTS HUD mod icons
3273 float crecordtime_prev; // last remembered crecordtime
3274 float crecordtime_change_time; // time when crecordtime last changed
3275 float srecordtime_prev; // last remembered srecordtime
3276 float srecordtime_change_time; // time when srecordtime last changed
3277
3278 float race_status_time;
3279 int race_status_prev;
3280 string race_status_name_prev;
3281 void HUD_Mod_Race(vector pos, vector mySize)
3282 {
3283         mod_active = 1; // race should never hide the mod icons panel
3284         entity me;
3285         me = playerslots[player_localnum];
3286         float t, score;
3287         float f; // yet another function has this
3288         score = me.(scores[ps_primary]);
3289
3290         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3291                 return; // no records in the actual race
3292
3293         // clientside personal record
3294         string rr;
3295         if(gametype == MAPINFO_TYPE_CTS)
3296                 rr = CTS_RECORD;
3297         else
3298                 rr = RACE_RECORD;
3299         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3300
3301         if(score && (score < t || !t)) {
3302                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3303                 if(autocvar_cl_autodemo_delete_keeprecords)
3304                 {
3305                         f = autocvar_cl_autodemo_delete;
3306                         f &= ~1;
3307                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3308                 }
3309         }
3310
3311         if(t != crecordtime_prev) {
3312                 crecordtime_prev = t;
3313                 crecordtime_change_time = time;
3314         }
3315
3316         vector textPos, medalPos;
3317         float squareSize;
3318         if(mySize.x > mySize.y) {
3319                 // text on left side
3320                 squareSize = min(mySize.y, mySize.x/2);
3321                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3322                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3323         } else {
3324                 // text on top
3325                 squareSize = min(mySize.x, mySize.y/2);
3326                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3327                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3328         }
3329
3330         f = time - crecordtime_change_time;
3331
3332         if (f > 1) {
3333                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3334                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3335         } else {
3336                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3337                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3338                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3339                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3340         }
3341
3342         // server record
3343         t = race_server_record;
3344         if(t != srecordtime_prev) {
3345                 srecordtime_prev = t;
3346                 srecordtime_change_time = time;
3347         }
3348         f = time - srecordtime_change_time;
3349
3350         if (f > 1) {
3351                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3352                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3353         } else {
3354                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3355                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3356                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3357                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3358         }
3359
3360         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3361                 race_status_time = time + 5;
3362                 race_status_prev = race_status;
3363                 if (race_status_name_prev)
3364                         strunzone(race_status_name_prev);
3365                 race_status_name_prev = strzone(race_status_name);
3366         }
3367
3368         // race "awards"
3369         float a;
3370         a = bound(0, race_status_time - time, 1);
3371
3372         string s;
3373         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3374
3375         float rank;
3376         if(race_status > 0)
3377                 rank = race_CheckName(race_status_name);
3378         else
3379                 rank = 0;
3380         string rankname;
3381         rankname = count_ordinal(rank);
3382
3383         vector namepos;
3384         namepos = medalPos + '0 0.8 0' * squareSize;
3385         vector rankpos;
3386         rankpos = medalPos + '0 0.15 0' * squareSize;
3387
3388         if(race_status == 0)
3389                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3390         else if(race_status == 1) {
3391                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3392                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3393                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3394         } else if(race_status == 2) {
3395                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3396                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3397                 else
3398                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3399                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3400                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3401         } else if(race_status == 3) {
3402                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3403                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3404                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3405         }
3406
3407         if (race_status_time - time <= 0) {
3408                 race_status_prev = -1;
3409                 race_status = -1;
3410                 if(race_status_name)
3411                         strunzone(race_status_name);
3412                 race_status_name = string_null;
3413                 if(race_status_name_prev)
3414                         strunzone(race_status_name_prev);
3415                 race_status_name_prev = string_null;
3416         }
3417 }
3418
3419 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3420 {
3421         float stat = -1;
3422         string pic = "";
3423         vector color = '0 0 0';
3424         switch(i)
3425         {
3426                 case 0:
3427                         stat = getstatf(STAT_DOM_PPS_RED);
3428                         pic = "dom_icon_red";
3429                         color = '1 0 0';
3430                         break;
3431                 case 1:
3432                         stat = getstatf(STAT_DOM_PPS_BLUE);
3433                         pic = "dom_icon_blue";
3434                         color = '0 0 1';
3435                         break;
3436                 case 2:
3437                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3438                         pic = "dom_icon_yellow";
3439                         color = '1 1 0';
3440                         break;
3441                 default:
3442                 case 3:
3443                         stat = getstatf(STAT_DOM_PPS_PINK);
3444                         pic = "dom_icon_pink";
3445                         color = '1 0 1';
3446                         break;
3447         }
3448         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3449
3450         if(mySize.x/mySize.y > aspect_ratio)
3451         {
3452                 i = aspect_ratio * mySize.y;
3453                 myPos.x = myPos.x + (mySize.x - i) / 2;
3454                 mySize.x = i;
3455         }
3456         else
3457         {
3458                 i = 1/aspect_ratio * mySize.x;
3459                 myPos.y = myPos.y + (mySize.y - i) / 2;
3460                 mySize.y = i;
3461         }
3462
3463         if (layout) // show text too
3464         {
3465                 //draw the text
3466                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3467                 if (layout == 2) // average pps
3468                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3469                 else // percentage of average pps
3470                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3471         }
3472
3473         //draw the icon
3474         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3475         if (stat > 0)
3476         {
3477                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3478                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3479                 drawresetcliparea();
3480         }
3481 }
3482
3483 void HUD_Mod_Dom(vector myPos, vector mySize)
3484 {
3485         mod_active = 1; // required in each mod function that always shows something
3486
3487         int layout = autocvar_hud_panel_modicons_dom_layout;
3488         int rows, columns;
3489         float aspect_ratio;
3490         aspect_ratio = (layout) ? 3 : 1;
3491         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3492         columns = ceil(team_count/rows);
3493
3494         int i;
3495         float row = 0, column = 0;
3496         vector pos, itemSize;
3497         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3498         for(i=0; i<team_count; ++i)
3499         {
3500                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3501
3502                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3503
3504                 ++row;
3505                 if(row >= rows)
3506                 {
3507                         row = 0;
3508                         ++column;
3509                 }
3510         }
3511 }
3512
3513 void HUD_ModIcons_SetFunc()
3514 {
3515         switch(gametype)
3516         {
3517                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3518                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3519                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3520                 case MAPINFO_TYPE_CTS:
3521                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3522                 case MAPINFO_TYPE_CA:
3523                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3524                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3525                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3526         }
3527 }
3528
3529 int mod_prev; // previous state of mod_active to check for a change
3530 float mod_alpha;
3531 float mod_change; // "time" when mod_active changed
3532
3533 void HUD_ModIcons(void)
3534 {
3535         if(!autocvar__hud_configure)
3536         {
3537                 if(!autocvar_hud_panel_modicons) return;
3538                 if(!HUD_ModIcons_GameType) return;
3539         }
3540
3541         HUD_Panel_UpdateCvars();
3542
3543         draw_beginBoldFont();
3544
3545         if(mod_active != mod_prev) {
3546                 mod_change = time;
3547                 mod_prev = mod_active;
3548         }
3549
3550         if(mod_active || autocvar__hud_configure)
3551                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3552         else
3553                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3554
3555         if(mod_alpha)
3556                 HUD_Panel_DrawBg(mod_alpha);
3557
3558         if(panel_bg_padding)
3559         {
3560                 panel_pos += '1 1 0' * panel_bg_padding;
3561                 panel_size -= '2 2 0' * panel_bg_padding;
3562         }
3563
3564         if(autocvar__hud_configure)
3565                 HUD_Mod_CTF(panel_pos, panel_size);
3566         else
3567                 HUD_ModIcons_GameType(panel_pos, panel_size);
3568
3569         draw_endBoldFont();
3570 }
3571
3572 // Draw pressed keys (#11)
3573 //
3574 void HUD_PressedKeys(void)
3575 {
3576         if(!autocvar__hud_configure)
3577         {
3578                 if(!autocvar_hud_panel_pressedkeys) return;
3579                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3580         }
3581
3582         HUD_Panel_UpdateCvars();
3583         vector pos, mySize;
3584         pos = panel_pos;
3585         mySize = panel_size;
3586
3587         HUD_Panel_DrawBg(1);
3588         if(panel_bg_padding)
3589         {
3590                 pos += '1 1 0' * panel_bg_padding;
3591                 mySize -= '2 2 0' * panel_bg_padding;
3592         }
3593
3594         // force custom aspect
3595         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3596         if(aspect)
3597         {
3598                 vector newSize = '0 0 0';
3599                 if(mySize.x/mySize.y > aspect)
3600                 {
3601                         newSize.x = aspect * mySize.y;
3602                         newSize.y = mySize.y;
3603
3604                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3605                 }
3606                 else
3607                 {
3608                         newSize.y = 1/aspect * mySize.x;
3609                         newSize.x = mySize.x;
3610
3611                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3612                 }
3613                 mySize = newSize;
3614         }
3615
3616         vector keysize;
3617         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3618         float pressedkeys;
3619         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3620
3621         if(autocvar_hud_panel_pressedkeys_attack)
3622         {
3623                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3624                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3625                 pos.y += keysize.y;
3626         }
3627
3628         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3629         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3630         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3631         pos.y += keysize.y;
3632         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3633         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3634         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3635 }
3636
3637 // Handle chat as a panel (#12)
3638 //
3639 void HUD_Chat(void)
3640 {
3641         if(!autocvar__hud_configure)
3642         {
3643                 if (!autocvar_hud_panel_chat)
3644                 {
3645                         if (!autocvar_con_chatrect)
3646                                 cvar_set("con_chatrect", "0");
3647                         return;
3648                 }
3649                 if(autocvar__con_chat_maximized)
3650                 {
3651                         if(!hud_draw_maximized) return;
3652                 }
3653                 else if(chat_panel_modified)
3654                 {
3655                         panel.update_time = time; // forces reload of panel attributes
3656                         chat_panel_modified = false;
3657                 }
3658         }
3659
3660         HUD_Panel_UpdateCvars();
3661
3662         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3663         {
3664                 panel_pos.y = panel_bg_border;
3665                 panel_size.y = vid_conheight - panel_bg_border * 2;
3666                 if(panel.current_panel_bg == "0") // force a border when maximized
3667                 {
3668                         string panel_bg;
3669                         panel_bg = strcat(hud_skin_path, "/border_default");
3670                         if(precache_pic(panel_bg) == "")
3671                                 panel_bg = "gfx/hud/default/border_default";
3672                         if(panel.current_panel_bg)
3673                                 strunzone(panel.current_panel_bg);
3674                         panel.current_panel_bg = strzone(panel_bg);
3675                         chat_panel_modified = true;
3676                 }
3677                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3678         }
3679
3680         vector pos, mySize;
3681         pos = panel_pos;
3682         mySize = panel_size;
3683
3684         HUD_Panel_DrawBg(1);
3685
3686         if(panel_bg_padding)
3687         {
3688                 pos += '1 1 0' * panel_bg_padding;
3689                 mySize -= '2 2 0' * panel_bg_padding;
3690         }
3691
3692         if (!autocvar_con_chatrect)
3693                 cvar_set("con_chatrect", "1");
3694
3695         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3696         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3697
3698         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3699         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3700
3701         if(autocvar__hud_configure)
3702         {
3703                 vector chatsize;
3704                 chatsize = '1 1 0' * autocvar_con_chatsize;
3705                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3706                 float i, a;
3707                 for(i = 0; i < autocvar_con_chat; ++i)
3708                 {
3709                         if(i == autocvar_con_chat - 1)
3710                                 a = panel_fg_alpha;
3711                         else
3712                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3713                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3714                         pos.y += chatsize.y;
3715                 }
3716         }
3717 }
3718
3719 // Engine info panel (#13)
3720 //
3721 float prevfps;
3722 float prevfps_time;
3723 int framecounter;
3724
3725 float frametimeavg;
3726 float frametimeavg1; // 1 frame ago
3727 float frametimeavg2; // 2 frames ago
3728 void HUD_EngineInfo(void)
3729 {
3730         if(!autocvar__hud_configure)
3731         {
3732                 if(!autocvar_hud_panel_engineinfo) return;
3733         }
3734
3735         HUD_Panel_UpdateCvars();
3736         vector pos, mySize;
3737         pos = panel_pos;
3738         mySize = panel_size;
3739
3740         HUD_Panel_DrawBg(1);
3741         if(panel_bg_padding)
3742         {
3743                 pos += '1 1 0' * panel_bg_padding;
3744                 mySize -= '2 2 0' * panel_bg_padding;
3745         }
3746
3747         float currentTime = gettime(GETTIME_REALTIME);
3748         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3749         {
3750                 float currentframetime = currentTime - prevfps_time;
3751                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3752                 frametimeavg2 = frametimeavg1;
3753                 frametimeavg1 = frametimeavg;
3754
3755                 float weight;
3756                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3757                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3758                 {
3759                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3760                                 prevfps = (1/currentframetime);
3761                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3762                 }
3763                 prevfps_time = currentTime;
3764         }
3765         else
3766         {
3767                 framecounter += 1;
3768                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3769                 {
3770                         prevfps = framecounter/(currentTime - prevfps_time);
3771                         framecounter = 0;
3772                         prevfps_time = currentTime;
3773                 }
3774         }
3775
3776         vector color;
3777         color = HUD_Get_Num_Color (prevfps, 100);
3778         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3779 }
3780
3781 // Info messages panel (#14)
3782 //
3783 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3784         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3785                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3786         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3787         o.y += fontsize.y;                                                                                                                                                                                              \
3788 } while(0)
3789 void HUD_InfoMessages(void)
3790 {
3791         if(!autocvar__hud_configure)
3792         {
3793                 if(!autocvar_hud_panel_infomessages) return;
3794         }
3795
3796         HUD_Panel_UpdateCvars();
3797         vector pos, mySize;
3798         pos = panel_pos;
3799         mySize = panel_size;
3800
3801         HUD_Panel_DrawBg(1);
3802         if(panel_bg_padding)
3803         {
3804                 pos += '1 1 0' * panel_bg_padding;
3805                 mySize -= '2 2 0' * panel_bg_padding;
3806         }
3807
3808         // always force 5:1 aspect
3809         vector newSize = '0 0 0';
3810         if(mySize.x/mySize.y > 5)
3811         {
3812                 newSize.x = 5 * mySize.y;
3813                 newSize.y = mySize.y;
3814
3815                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3816         }
3817         else
3818         {
3819                 newSize.y = 1/5 * mySize.x;
3820                 newSize.x = mySize.x;
3821
3822                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3823         }
3824
3825         mySize = newSize;
3826         entity tm;
3827         vector o;
3828         o = pos;
3829
3830         vector fontsize;
3831         fontsize = '0.20 0.20 0' * mySize.y;
3832
3833         float a;
3834         a = panel_fg_alpha;
3835
3836         string s;
3837         if(!autocvar__hud_configure)
3838         {
3839                 if(spectatee_status && !intermission)
3840                 {
3841                         a = 1;
3842                         if(spectatee_status == -1)
3843                                 s = _("^1Observing");
3844                         else
3845                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(current_player));
3846                         drawInfoMessage(s);
3847
3848                         if(spectatee_status == -1)
3849                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3850                         else
3851                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3852                         drawInfoMessage(s);
3853
3854                         if(spectatee_status == -1)
3855                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3856                         else
3857                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3858                         drawInfoMessage(s);
3859
3860                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3861                         drawInfoMessage(s);
3862
3863                         if(gametype == MAPINFO_TYPE_LMS)
3864                         {
3865                                 entity sk;
3866                                 sk = playerslots[player_localnum];
3867                                 if(sk.(scores[ps_primary]) >= 666)
3868                                         s = _("^1Match has already begun");
3869                                 else if(sk.(scores[ps_primary]) > 0)
3870                                         s = _("^1You have no more lives left");
3871                                 else
3872                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3873                         }
3874                         else
3875                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3876                         drawInfoMessage(s);
3877
3878                         //show restart countdown:
3879                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3880                                 float countdown;
3881                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3882                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3883                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3884                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3885                                 o.y += fontsize.y;
3886                         }
3887                 }
3888                 if(warmup_stage && !intermission)
3889                 {
3890                         s = _("^2Currently in ^1warmup^2 stage!");
3891                         drawInfoMessage(s);
3892                 }
3893
3894                 string blinkcolor;
3895                 if(time % 1 >= 0.5)
3896                         blinkcolor = "^1";
3897                 else
3898                         blinkcolor = "^3";
3899
3900                 if(ready_waiting && !intermission && !spectatee_status)
3901                 {
3902                         if(ready_waiting_for_me)
3903                         {
3904                                 if(warmup_stage)
3905                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3906                                 else
3907                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3908                         }
3909                         else
3910                         {
3911                                 if(warmup_stage)
3912                                         s = _("^2Waiting for others to ready up to end warmup...");
3913                                 else
3914                                         s = _("^2Waiting for others to ready up...");
3915                         }
3916                         drawInfoMessage(s);
3917                 }
3918                 else if(warmup_stage && !intermission && !spectatee_status)
3919                 {
3920                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3921                         drawInfoMessage(s);
3922                 }
3923
3924                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3925                 {
3926                         float ts_min = 0, ts_max = 0;
3927                         tm = teams.sort_next;
3928                         if (tm)
3929                         {
3930                                 for (; tm.sort_next; tm = tm.sort_next)
3931                                 {
3932                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3933                                                 continue;
3934                                         if(!ts_min) ts_min = tm.team_size;
3935                                         else ts_min = min(ts_min, tm.team_size);
3936                                         if(!ts_max) ts_max = tm.team_size;
3937                                         else ts_max = max(ts_max, tm.team_size);
3938                                 }
3939                                 if ((ts_max - ts_min) > 1)
3940                                 {
3941                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3942                                         tm = GetTeam(myteam, false);
3943                                         if (tm)
3944                                         if (tm.team != NUM_SPECTATOR)
3945                                         if (tm.team_size == ts_max)
3946                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3947                                         drawInfoMessage(s);
3948                                 }
3949                         }
3950                 }
3951         }
3952         else
3953         {
3954                 s = _("^7Press ^3ESC ^7to show HUD options.");
3955                 drawInfoMessage(s);
3956                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3957                 drawInfoMessage(s);
3958                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3959                 drawInfoMessage(s);
3960                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3961                 drawInfoMessage(s);
3962         }
3963 }
3964
3965 // Physics panel (#15)
3966 //
3967 vector acc_prevspeed;
3968 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3969 float physics_update_time, discrete_speed, discrete_acceleration;
3970 void HUD_Physics(void)
3971 {
3972         if(!autocvar__hud_configure)
3973         {
3974                 if(!autocvar_hud_panel_physics) return;
3975                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3976                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3977         }
3978
3979         HUD_Panel_UpdateCvars();
3980
3981         draw_beginBoldFont();
3982
3983         HUD_Panel_DrawBg(1);
3984         if(panel_bg_padding)
3985         {
3986                 panel_pos += '1 1 0' * panel_bg_padding;
3987                 panel_size -= '2 2 0' * panel_bg_padding;
3988         }
3989
3990         float acceleration_progressbar_scale = 0;
3991         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3992                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3993
3994         float text_scale;
3995         if (autocvar_hud_panel_physics_text_scale <= 0)
3996                 text_scale = 1;
3997         else
3998                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3999
4000         //compute speed
4001         float speed, conversion_factor;
4002         string unit;
4003
4004         switch(autocvar_hud_panel_physics_speed_unit)
4005         {
4006                 default:
4007                 case 1:
4008                         unit = _(" qu/s");
4009                         conversion_factor = 1.0;
4010                         break;
4011                 case 2:
4012                         unit = _(" m/s");
4013                         conversion_factor = 0.0254;
4014                         break;
4015                 case 3:
4016                         unit = _(" km/h");
4017                         conversion_factor = 0.0254 * 3.6;
4018                         break;
4019                 case 4:
4020                         unit = _(" mph");
4021                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
4022                         break;
4023                 case 5:
4024                         unit = _(" knots");
4025                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
4026                         break;
4027         }
4028
4029         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
4030
4031         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
4032         if (autocvar__hud_configure)
4033                 speed = floor( max_speed * 0.65 + 0.5 );
4034         else if(autocvar_hud_panel_physics_speed_vertical)
4035                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
4036         else
4037                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
4038
4039         //compute acceleration
4040         float acceleration, f;
4041         if (autocvar__hud_configure)
4042                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
4043         else
4044         {
4045                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
4046                 f = time - acc_prevtime;
4047                 if(autocvar_hud_panel_physics_acceleration_vertical)
4048                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
4049                 else
4050                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
4051
4052                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
4053
4054                 acc_prevspeed = vel;
4055                 acc_prevtime = time;
4056
4057                 if(autocvar_hud_panel_physics_acceleration_movingaverage)
4058                 {
4059                         f = bound(0, f * 10, 1);
4060                         acc_avg = acc_avg * (1 - f) + acceleration * f;
4061                         acceleration = acc_avg;
4062                 }
4063         }
4064
4065         int acc_decimals = 2;
4066         if(time > physics_update_time)
4067         {
4068                 // workaround for ftos_decimals returning a negative 0
4069                 if(discrete_acceleration > -1 / pow(10, acc_decimals) && discrete_acceleration < 0)
4070                         discrete_acceleration = 0;
4071                 discrete_acceleration = acceleration;
4072                 discrete_speed = speed;
4073                 physics_update_time += autocvar_hud_panel_physics_update_interval;
4074         }
4075
4076         //compute layout
4077         float panel_ar = panel_size.x/panel_size.y;
4078         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4079         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4080         {
4081                 panel_size.x *= 0.5;
4082                 if (autocvar_hud_panel_physics_flip)
4083                         speed_offset.x = panel_size.x;
4084                 else
4085                         acceleration_offset.x = panel_size.x;
4086         }
4087         else
4088         {
4089                 panel_size.y *= 0.5;
4090                 if (autocvar_hud_panel_physics_flip)
4091                         speed_offset.y = panel_size.y;
4092                 else
4093                         acceleration_offset.y = panel_size.y;
4094         }
4095         int speed_baralign, acceleration_baralign;
4096         if (autocvar_hud_panel_physics_baralign == 1)
4097                 acceleration_baralign = speed_baralign = 1;
4098     else if(autocvar_hud_panel_physics_baralign == 4)
4099                 acceleration_baralign = speed_baralign = 2;
4100         else if (autocvar_hud_panel_physics_flip)
4101         {
4102                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4103                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4104         }
4105         else
4106         {
4107                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4108                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4109         }
4110         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4111                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4112
4113         //draw speed
4114         if(speed)
4115         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4116                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4117         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4118         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4119         {
4120                 tmp_size.x = panel_size.x * 0.75;
4121                 tmp_size.y = panel_size.y * text_scale;
4122                 if (speed_baralign)
4123                         tmp_offset.x = panel_size.x - tmp_size.x;
4124                 //else
4125                         //tmp_offset_x = 0;
4126                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4127                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(discrete_speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4128
4129                 //draw speed unit
4130                 if (speed_baralign)
4131                         tmp_offset.x = 0;
4132                 else
4133                         tmp_offset.x = tmp_size.x;
4134                 if (autocvar_hud_panel_physics_speed_unit_show)
4135                 {
4136                         //tmp_offset_y = 0;
4137                         tmp_size.x = panel_size.x * (1 - 0.75);
4138                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4139                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4140                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4141                 }
4142         }
4143
4144         //compute and draw top speed
4145         if (autocvar_hud_panel_physics_topspeed)
4146         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4147         {
4148                 if (autocvar__hud_configure)
4149                 {
4150                         top_speed = floor( max_speed * 0.75 + 0.5 );
4151                         f = 1;
4152                 }
4153                 else
4154                 {
4155                         if (speed >= top_speed)
4156                         {
4157                                 top_speed = speed;
4158                                 top_speed_time = time;
4159                         }
4160                         if (top_speed != 0)
4161                         {
4162                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4163                                 // divide by f to make it start from 1
4164                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4165                         }
4166             else //hide top speed 0, it would be stupid
4167                                 f = 0;
4168                 }
4169                 if (f > 0)
4170                 {
4171                         //top speed progressbar peak
4172                         if(speed < top_speed)
4173                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4174                         {
4175                                 float peak_offsetX;
4176                                 vector peak_size = '0 0 0';
4177                                 if (speed_baralign == 0)
4178                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4179                 else if (speed_baralign == 1)
4180                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4181                 else // if (speed_baralign == 2)
4182                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4183                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4184                 peak_size.y = panel_size.y;
4185                 if (speed_baralign == 2) // draw two peaks, on both sides
4186                 {
4187                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4188                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4189                 }
4190                 else
4191                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4192                         }
4193
4194                         //top speed
4195                         tmp_offset.y = panel_size.y * 0.4;
4196                         tmp_size.x = panel_size.x * (1 - 0.75);
4197                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4198                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4199                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4200                 }
4201                 else
4202                         top_speed = 0;
4203         }
4204
4205         //draw acceleration
4206         if(acceleration)
4207         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4208         {
4209                 vector progressbar_color;
4210                 if(acceleration < 0)
4211                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4212                 else
4213                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4214
4215                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4216                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4217                         f = (f >= 0 ? sqrt(f) : -sqrt(-f));
4218
4219                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4220                 {
4221                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4222
4223                         if (acceleration_baralign == 1)
4224                                 tmp_offset.x = panel_size.x - tmp_size.x;
4225                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4226                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4227                         else
4228                                 tmp_offset.x = 0;
4229                         tmp_offset.y = 0;
4230                 }
4231                 else
4232                 {
4233                         tmp_size = panel_size;
4234                         tmp_offset = '0 0 0';
4235                 }
4236
4237                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4238         }
4239
4240         if(autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4241         {
4242                 tmp_size.x = panel_size.x;
4243                 tmp_size.y = panel_size.y * text_scale;
4244                 tmp_offset.x = 0;
4245                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4246
4247                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(discrete_acceleration, acc_decimals), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4248         }
4249
4250         draw_endBoldFont();
4251 }
4252
4253 // CenterPrint (#16)
4254 //
4255 const int CENTERPRINT_MAX_MSGS = 10;
4256 const int CENTERPRINT_MAX_ENTRIES = 50;
4257 const float CENTERPRINT_SPACING = 0.7;
4258 int cpm_index;
4259 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4260 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4261 float centerprint_time[CENTERPRINT_MAX_MSGS];
4262 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4263 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4264 bool centerprint_showing;
4265
4266 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4267 {
4268         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4269         int i, j;
4270
4271         if(strMessage == "" && new_id == 0)
4272                 return;
4273
4274         // strip trailing newlines
4275         j = strlen(strMessage) - 1;
4276         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4277                 --j;
4278         if (j < strlen(strMessage) - 1)
4279                 strMessage = substring(strMessage, 0, j + 1);
4280
4281         if(strMessage == "" && new_id == 0)
4282                 return;
4283
4284         // strip leading newlines
4285         j = 0;
4286         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4287                 ++j;
4288         if (j > 0)
4289                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4290
4291         if(strMessage == "" && new_id == 0)
4292                 return;
4293
4294         if (!centerprint_showing)
4295                 centerprint_showing = true;
4296
4297         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4298         {
4299                 if (j == CENTERPRINT_MAX_MSGS)
4300                         j = 0;
4301                 if (new_id && new_id == centerprint_msgID[j])
4302                 {
4303                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4304                         {
4305                                 // fade out the current msg (duration and countdown_num are ignored)
4306                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4307                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4308                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4309                                 return;
4310                         }
4311                         break; // found a msg with the same id, at position j
4312                 }
4313         }
4314
4315         if (i == CENTERPRINT_MAX_MSGS)
4316         {
4317                 // a msg with the same id was not found, add the msg at the next position
4318                 --cpm_index;
4319                 if (cpm_index == -1)
4320                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4321                 j = cpm_index;
4322         }
4323         if(centerprint_messages[j])
4324                 strunzone(centerprint_messages[j]);
4325         centerprint_messages[j] = strzone(strMessage);
4326         centerprint_msgID[j] = new_id;
4327         if (duration < 0)
4328         {
4329                 centerprint_time[j] = -1;
4330                 centerprint_expire_time[j] = time;
4331         }
4332         else
4333         {
4334                 if(duration == 0)
4335                         duration = max(1, autocvar_hud_panel_centerprint_time);
4336                 centerprint_time[j] = duration;
4337                 centerprint_expire_time[j] = time + duration;
4338         }
4339         centerprint_countdown_num[j] = countdown_num;
4340 }
4341
4342 void centerprint_hud(string strMessage)
4343 {
4344         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4345 }
4346
4347 void reset_centerprint_messages(void)
4348 {
4349         int i;
4350         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4351         {
4352                 centerprint_expire_time[i] = 0;
4353                 centerprint_time[i] = 1;
4354                 centerprint_msgID[i] = 0;
4355                 if(centerprint_messages[i])
4356                         strunzone(centerprint_messages[i]);
4357                 centerprint_messages[i] = string_null;
4358         }
4359 }
4360 float hud_configure_cp_generation_time;
4361 void HUD_CenterPrint (void)
4362 {
4363         if(!autocvar__hud_configure)
4364         {
4365                 if(!autocvar_hud_panel_centerprint) return;
4366
4367                 if(hud_configure_prev)
4368                         reset_centerprint_messages();
4369         }
4370         else
4371         {
4372                 if(!hud_configure_prev)
4373                         reset_centerprint_messages();
4374                 if (time > hud_configure_cp_generation_time)
4375                 {
4376                         if(HUD_PANEL(CENTERPRINT) == highlightedPanel)
4377                         {
4378                                 float r;
4379                                 r = random();
4380                                 if (r > 0.8)
4381                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4382                                 else if (r > 0.55)
4383                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4384                                 else
4385                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4386                                 hud_configure_cp_generation_time = time + 1 + random()*4;
4387                         }
4388                         else
4389                         {
4390                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
4391                                 hud_configure_cp_generation_time = time + 10 - random()*3;
4392                         }
4393                 }
4394         }
4395
4396         // this panel fades only when the menu does
4397         float hud_fade_alpha_save = 0;
4398         if(scoreboard_fade_alpha)
4399         {
4400                 hud_fade_alpha_save = hud_fade_alpha;
4401                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4402         }
4403         HUD_Panel_UpdateCvars();
4404
4405         if(scoreboard_fade_alpha)
4406         {
4407                 hud_fade_alpha = hud_fade_alpha_save;
4408
4409                 // move the panel below the scoreboard
4410                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4411                         return;
4412                 vector target_pos;
4413
4414                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4415
4416                 if(target_pos.y > panel_pos.y)
4417                 {
4418                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4419                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4420                 }
4421         }
4422
4423         HUD_Panel_DrawBg(1);
4424
4425         if (!centerprint_showing)
4426                 return;
4427
4428         if(panel_bg_padding)
4429         {
4430                 panel_pos += '1 1 0' * panel_bg_padding;
4431                 panel_size -= '2 2 0' * panel_bg_padding;
4432         }
4433
4434         int entries;
4435         float height;
4436         vector fontsize;
4437         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4438         // height = panel_size_y/entries;
4439         // fontsize = '1 1 0' * height;
4440         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4441         fontsize = '1 1 0' * height;
4442         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4443
4444         int i, j, k, n, g;
4445         float a, sz, align, current_msg_posY = 0, msg_size;
4446         vector pos;
4447         string ts;
4448         bool all_messages_expired = true;
4449
4450         pos = panel_pos;
4451         if (autocvar_hud_panel_centerprint_flip)
4452                 pos.y += panel_size.y;
4453         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4454         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4455         {
4456                 if (j == CENTERPRINT_MAX_MSGS)
4457                         j = 0;
4458                 if (centerprint_expire_time[j] <= time)
4459                 {
4460                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4461                         {
4462                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4463                                 if (centerprint_countdown_num[j] == 0)
4464                                         continue;
4465                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4466                         }
4467                         else if(centerprint_time[j] != -1)
4468                                 continue;
4469                 }
4470
4471                 all_messages_expired = false;
4472
4473                 // fade the centerprint_hud in/out
4474                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4475                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4476                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4477                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4478                 else // Expiring soon, so fade it out.
4479                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4480
4481                 // while counting down show it anyway in order to hold the current message position
4482                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4483                         continue;
4484                 if (a > 1)
4485                         a = 1;
4486
4487                 // set the size from fading in/out before subsequent fading
4488                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4489
4490                 // also fade it based on positioning
4491                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4492                 {
4493                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4494                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4495                 }
4496                 a *= panel_fg_alpha;
4497
4498                 // finally set the size based on the new theAlpha from subsequent fading
4499                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4500                 drawfontscale = sz * '1 1 0';
4501
4502                 if (centerprint_countdown_num[j])
4503                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4504                 else
4505                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4506
4507                 if (autocvar_hud_panel_centerprint_flip)
4508                 {
4509                         // check if the message can be entirely shown
4510                         for(k = 0; k < n; ++k)
4511                         {
4512                                 getWrappedLine_remaining = argv(k);
4513                                 while(getWrappedLine_remaining)
4514                                 {
4515                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4516                                         if (ts != "")
4517                                                 pos.y -= fontsize.y;
4518                                         else
4519                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4520                                 }
4521                         }
4522                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4523                 }
4524
4525                 msg_size = pos.y;
4526                 for(k = 0; k < n; ++k)
4527                 {
4528                         getWrappedLine_remaining = argv(k);
4529                         while(getWrappedLine_remaining)
4530                         {
4531                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4532                                 if (ts != "")
4533                                 {
4534                                         if (align)
4535                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4536                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4537                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4538                                         pos.y += fontsize.y;
4539                                 }
4540                                 else
4541                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4542                         }
4543                 }
4544
4545                 ++g; // move next position number up
4546
4547                 msg_size = pos.y - msg_size;
4548                 if (autocvar_hud_panel_centerprint_flip)
4549                 {
4550                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4551                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4552                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4553
4554                         if (pos.y < panel_pos.y) // check if the next message can be shown
4555                         {
4556                                 drawfontscale = '1 1 0';
4557                                 return;
4558                         }
4559                 }
4560                 else
4561                 {
4562                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4563                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4564                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4565
4566                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4567                         {
4568                                 drawfontscale = '1 1 0';
4569                                 return;
4570                         }
4571                 }
4572         }
4573         drawfontscale = '1 1 0';
4574         if (all_messages_expired)
4575         {
4576                 centerprint_showing = false;
4577                 reset_centerprint_messages();
4578         }
4579 }
4580
4581
4582 /*
4583 ==================
4584 Main HUD system
4585 ==================
4586 */
4587
4588 void HUD_Reset (void)
4589 {
4590         // reset gametype specific icons
4591         if(gametype == MAPINFO_TYPE_CTF)
4592                 HUD_Mod_CTF_Reset();
4593 }
4594
4595 void HUD_Main (void)
4596 {
4597         int i;
4598         // global hud theAlpha fade
4599         if(menu_enabled == 1)
4600                 hud_fade_alpha = 1;
4601         else
4602                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4603
4604         if(scoreboard_fade_alpha)
4605                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4606
4607         HUD_Configure_Frame();
4608
4609         if(intermission == 2) // no hud during mapvote
4610                 hud_fade_alpha = 0;
4611
4612         // panels that we want to be active together with the scoreboard
4613         // they must fade only when the menu does
4614         if(scoreboard_fade_alpha == 1)
4615         {
4616                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4617                 return;
4618         }
4619
4620         if(!autocvar__hud_configure && !hud_fade_alpha)
4621                 return;
4622
4623         // Drawing stuff
4624         if (hud_skin_prev != autocvar_hud_skin)
4625         {
4626                 if (hud_skin_path)
4627                         strunzone(hud_skin_path);
4628                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4629                 if (hud_skin_prev)
4630                         strunzone(hud_skin_prev);
4631                 hud_skin_prev = strzone(autocvar_hud_skin);
4632         }
4633
4634         // draw the dock
4635         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4636         {
4637                 int f;
4638                 vector color;
4639                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4640                 if((teamplay) && hud_dock_color_team) {
4641                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4642                                 color = '1 0 0' * hud_dock_color_team;
4643                         else
4644                                 color = myteamcolors * hud_dock_color_team;
4645                 }
4646                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4647                         color = '1 0 0' * hud_dock_color_team;
4648                 }
4649                 else
4650                 {
4651                         string hud_dock_color = autocvar_hud_dock_color;
4652                         if(hud_dock_color == "shirt") {
4653                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4654                                 color = colormapPaletteColor(floor(f / 16), 0);
4655                         }
4656                         else if(hud_dock_color == "pants") {
4657                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4658                                 color = colormapPaletteColor(f % 16, 1);
4659                         }
4660                         else
4661                                 color = stov(hud_dock_color);
4662                 }
4663
4664                 string pic;
4665                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4666                 if(precache_pic(pic) == "") {
4667                         pic = strcat(hud_skin_path, "/dock_medium");
4668                         if(precache_pic(pic) == "") {
4669                                 pic = "gfx/hud/default/dock_medium";
4670                         }
4671                 }
4672                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4673         }
4674
4675         // cache the panel order into the panel_order array
4676         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4677                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4678                         panel_order[i] = -1;
4679                 string s = "";
4680                 int p_num;
4681                 bool warning = false;
4682                 int argc = tokenize_console(autocvar__hud_panelorder);
4683                 if (argc > HUD_PANEL_NUM)
4684                         warning = true;
4685                 //first detect wrong/missing panel numbers
4686                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4687                         p_num = stoi(argv(i));
4688                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4689                                 if (panel_order[p_num] == -1) //found for the first time?
4690                                         s = strcat(s, ftos(p_num), " ");
4691                                 panel_order[p_num] = 1; //mark as found
4692                         }
4693                         else
4694                                 warning = true;
4695                 }
4696                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4697                         if (panel_order[i] == -1) {
4698                                 warning = true;
4699                                 s = strcat(s, ftos(i), " "); //add missing panel number
4700                         }
4701                 }
4702                 if (warning)
4703                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4704
4705                 cvar_set("_hud_panelorder", s);
4706                 if(hud_panelorder_prev)
4707                         strunzone(hud_panelorder_prev);
4708                 hud_panelorder_prev = strzone(s);
4709
4710                 //now properly set panel_order
4711                 tokenize_console(s);
4712                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4713                         panel_order[i] = stof(argv(i));
4714                 }
4715         }
4716
4717         hud_draw_maximized = 0;
4718         // draw panels in order specified by panel_order array
4719         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4720                 (panel = hud_panel[panel_order[i]]).panel_draw();
4721
4722         hud_draw_maximized = 1; // panels that may be maximized must check this var
4723         // draw maximized panels on top
4724         if(hud_panel_radar_maximized)
4725                 (panel = HUD_PANEL(RADAR)).panel_draw();
4726         if(autocvar__con_chat_maximized)
4727                 (panel = HUD_PANEL(CHAT)).panel_draw();
4728
4729         HUD_Configure_PostDraw();
4730
4731         hud_configure_prev = autocvar__hud_configure;
4732 }