qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * scale_x;
 148         drawstring(position, text, scale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
 154         drawstring(position, text, scale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
 222         else
 223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if not(playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel_bg != "0")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 float GetAmmoStat(float i)
 412 {
 413         switch(i)
 414         {
 415                 case 0: return STAT_SHELLS;
 416                 case 1: return STAT_NAILS;
 417                 case 2: return STAT_ROCKETS;
 418                 case 3: return STAT_CELLS;
 419                 case 4: return STAT_FUEL;
 420                 default: return -1;
 421         }
 422 }
 423
 424 float GetAmmoTypeForWep(float i)
 425 {
 426         switch(i)
 427         {
 428                 case WEP_SHOTGUN: return 0;
 429                 case WEP_UZI: return 1;
 430                 case WEP_GRENADE_LAUNCHER: return 2;
 431                 case WEP_MINE_LAYER: return 2;
 432                 case WEP_ELECTRO: return 3;
 433                 case WEP_CRYLINK: return 3;
 434                 case WEP_HLAC: return 3;
 435                 case WEP_MINSTANEX: return 3;
 436                 case WEP_NEX: return 3;
 437                 case WEP_RIFLE: return 1;
 438                 case WEP_HAGAR: return 2;
 439                 case WEP_ROCKET_LAUNCHER: return 2;
 440                 case WEP_SEEKER: return 2;
 441                 case WEP_FIREBALL: return 4;
 442                 case WEP_HOOK: return 3;
 443                 default: return -1;
 444         }
 445 }
 446
 447 void HUD_Weapons(void)
 448 {
 449         // declarations
 450         WEPSET_DECLARE_A(weapons_stat);
 451         WEPSET_COPY_AS(weapons_stat);
 452         float i, f, a;
 453         float screen_ar, center_x = 0, center_y;
 454         float weapon_count, weapon_id;
 455         float row, column, rows = 0, columns;
 456         float aspect = autocvar_hud_panel_weapons_aspect;
 457
 458         float panel_weapon_accuracy;
 459
 460         float timeout = autocvar_hud_panel_weapons_timeout;
 461         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 462         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 463
 464         float ammo_type, ammo_full;
 465         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 466         vector ammo_color = '1 0 1';
 467         float ammo_alpha = 1;
 468
 469         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 470         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 471
 472         vector weapon_pos, weapon_size = '0 0 0';
 473         local noref vector old_panel_size; // fteqcc sucks
 474         vector color;
 475
 476         // check to see if we want to continue
 477         if(hud != HUD_NORMAL) { return; }
 478
 479         if(!autocvar__hud_configure)
 480         {
 481                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 482                         return;
 483                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 484                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 485                 {
 486                         weaponprevtime = time;
 487                         return;
 488                 }
 489         }
 490         else
 491                 hud_configure_active_panel = HUD_PANEL_WEAPONS;
 492
 493         // update generic hud functions
 494         HUD_Panel_UpdateCvars(weapons);
 495         HUD_Panel_ApplyFadeAlpha();
 496
 497         draw_beginBoldFont();
 498
 499         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 500         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 501         {
 502                 float weapon_cnt;
 503                 if(weaponorder_bypriority)
 504                         strunzone(weaponorder_bypriority);
 505                 if(weaponorder_byimpulse)
 506                         strunzone(weaponorder_byimpulse);
 507
 508                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 509                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 510                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 511
 512                 weapon_cnt = 0;
 513                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 514                 {
 515                         self = get_weaponinfo(i);
 516                         if(self.impulse >= 0)
 517                         {
 518                                 weaponorder[weapon_cnt] = self;
 519                                 ++weapon_cnt;
 520                         }
 521                 }
 522                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 523                         weaponorder[i] = world;
 524                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 525
 526                 weaponorder_cmp_str = string_null;
 527         }
 528
 529         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 530                 complain_weapon = 0;
 531
 532         // determine which weapons are going to be shown
 533         if (autocvar_hud_panel_weapons_onlyowned)
 534         {
 535                 if(autocvar__hud_configure)
 536                 {
 537                         if (WEPSET_EMPTY_A(weapons_stat))
 538                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 539                                         WEPSET_OR_AW(weapons_stat, i);
 540
 541                         if(menu_enabled != 2)
 542                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 543                 }
 544
 545                 // do we own this weapon?
 546                 weapon_count = 0;
 547                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 548                         if(WEPSET_CONTAINS_AW(weapons_stat, weaponorder[i].weapon))
 549                                 ++weapon_count;
 550
 551                 // add it anyway if weaponcomplain is shown
 552                 if(complain_weapon)
 553                         ++weapon_count;
 554
 555                 // might as well commit suicide now, no reason to live ;)
 556                 if (weapon_count == 0)
 557                 {
 558                         draw_endBoldFont();
 559                         return;
 560                 }
 561
 562                 old_panel_size = panel_size;
 563                 if(panel_bg_padding)
 564                         old_panel_size -= '2 2 0' * panel_bg_padding;
 565
 566                 // first find values for the standard table (with all the weapons)
 567                 rows = old_panel_size_y/old_panel_size_x;
 568                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 569                 columns = ceil(WEP_COUNT/rows);
 570                 weapon_size_x = old_panel_size_x / columns;
 571                 weapon_size_y = old_panel_size_y / rows;
 572
 573                 // change table values to include only the owned weapons
 574                 // weapon_size won't be changed
 575                 if(weapon_count <= rows)
 576                 {
 577                         rows = weapon_count;
 578                         columns = 1;
 579                 }
 580                 else
 581                         columns = ceil(weapon_count / rows);
 582
 583                 // reduce size of the panel
 584                 panel_size_x = columns * weapon_size_x;
 585                 panel_size_y = rows * weapon_size_y;
 586                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 587                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 588                 if(panel_bg_padding)
 589                         panel_size += '2 2 0' * panel_bg_padding;
 590         }
 591         else
 592                 weapon_count = WEP_COUNT;
 593
 594         // animation for fading in/out the panel respectively when not in use
 595         if(!autocvar__hud_configure)
 596         {
 597                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 598                 {
 599                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 600
 601                         // fade the panel alpha
 602                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 603                         {
 604                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 605                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 606                         }
 607                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 608                         {
 609                                 panel_bg_alpha *= (1 - f);
 610                                 panel_fg_alpha *= (1 - f);
 611                         }
 612
 613                         // move the panel off the screen
 614                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 615                         {
 616                                 f *= f; // for a cooler movement
 617                                 center_x = panel_pos_x + panel_size_x/2;
 618                                 center_y = panel_pos_y + panel_size_y/2;
 619                                 screen_ar = vid_conwidth/vid_conheight;
 620                                 if (center_x/center_y < screen_ar) //bottom left
 621                                 {
 622                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 623                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 624                                         else //left
 625                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 626                                 }
 627                                 else //top right
 628                                 {
 629                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 630                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 631                                         else //top
 632                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 633                                 }
 634                                 if(f == 1)
 635                                         center_x = -1; // mark the panel as off screen
 636                         }
 637                         weaponprevtime = time - (1 - f) * timein_effect_length;
 638                 }
 639                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 640                 {
 641                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 642
 643                         // fade the panel alpha
 644                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 645                         {
 646                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 647                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 648                         }
 649                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 650                         {
 651                                 panel_bg_alpha *= (f);
 652                                 panel_fg_alpha *= (f);
 653                         }
 654
 655                         // move the panel back on screen
 656                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 657                         {
 658                                 f *= f; // for a cooler movement
 659                                 f = 1 - f;
 660                                 center_x = panel_pos_x + panel_size_x/2;
 661                                 center_y = panel_pos_y + panel_size_y/2;
 662                                 screen_ar = vid_conwidth/vid_conheight;
 663                                 if (center_x/center_y < screen_ar) //bottom left
 664                                 {
 665                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 666                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 667                                         else //left
 668                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 669                                 }
 670                                 else //top right
 671                                 {
 672                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 673                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 674                                         else //top
 675                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 676                                 }
 677                         }
 678                 }
 679         }
 680
 681         // draw the background, then change the virtual size of it to better fit other items inside
 682         HUD_Panel_DrawBg(1);
 683
 684         if(center_x == -1)
 685         {
 686                 draw_endBoldFont();
 687                 return;
 688         }
 689
 690         if(panel_bg_padding)
 691         {
 692                 panel_pos += '1 1 0' * panel_bg_padding;
 693                 panel_size -= '2 2 0' * panel_bg_padding;
 694         }
 695
 696         // after the sizing and animations are done, update the other values
 697
 698         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 699         {
 700                 rows = panel_size_y/panel_size_x;
 701                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 702                 columns = ceil(weapon_count/rows);
 703                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 704         }
 705
 706         // calculate position/size for visual bar displaying ammount of ammo status
 707         if (autocvar_hud_panel_weapons_ammo)
 708         {
 709                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 710                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 711
 712                 if(weapon_size_x/weapon_size_y > aspect)
 713                 {
 714                         barsize_x = aspect * weapon_size_y;
 715                         barsize_y = weapon_size_y;
 716                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 717                 }
 718                 else
 719                 {
 720                         barsize_y = 1/aspect * weapon_size_x;
 721                         barsize_x = weapon_size_x;
 722                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 723                 }
 724         }
 725         if(autocvar_hud_panel_weapons_accuracy)
 726                 Accuracy_LoadColors();
 727
 728         row = column = 0;
 729         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 730         {
 731                 // retrieve information about the current weapon to be drawn
 732                 self = weaponorder[i];
 733                 weapon_id = self.impulse;
 734
 735                 // skip if this weapon doesn't exist
 736                 if(!self || weapon_id < 0) { continue; }
 737
 738                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 739                 if(autocvar_hud_panel_weapons_onlyowned)
 740                 if not(WEPSET_CONTAINS_AW(weapons_stat, self.weapon) || (self.weapon == complain_weapon))
 741                         continue;
 742
 743                 // figure out the drawing position of weapon
 744                 weapon_pos = (panel_pos
 745                         + eX * column * weapon_size_x
 746                         + eY * row * weapon_size_y);
 747
 748                 // draw background behind currently selected weapon
 749                 if(self.weapon == switchweapon)
 750                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 751
 752                 // draw the weapon accuracy
 753                 if(autocvar_hud_panel_weapons_accuracy)
 754                 {
 755                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 756                         if(panel_weapon_accuracy >= 0)
 757                         {
 758                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 759                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 760                         }
 761                 }
 762
 763                 // drawing all the weapon items
 764                 if(WEPSET_CONTAINS_AW(weapons_stat, self.weapon))
 765                 {
 766                         // draw the weapon image
 767                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 768
 769                         // draw weapon label string
 770                         switch(autocvar_hud_panel_weapons_label)
 771                         {
 772                                 case 1: // weapon number
 773                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 774                                         break;
 775
 776                                 case 2: // bind
 777                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 778                                         break;
 779
 780                                 case 3: // weapon name
 781                                         drawstring(weapon_pos, self.netname, '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 782                                         break;
 783
 784                                 default: // nothing
 785                                         break;
 786                         }
 787
 788                         // draw ammo status bar
 789                         if(autocvar_hud_panel_weapons_ammo && self.weapon != WEP_TUBA && self.weapon != WEP_LASER && self.weapon != WEP_PORTO)
 790                         {
 791                                 a = 0;
 792                                 ammo_type = GetAmmoTypeForWep(self.weapon);
 793                                 if(ammo_type != -1)
 794                                         a = getstati(GetAmmoStat(ammo_type)); // how much ammo do we have?
 795
 796                                 if(a > 0)
 797                                 {
 798                                         switch(ammo_type) {
 799                                                 case 0: ammo_full = autocvar_hud_panel_weapons_ammo_full_shells; break;
 800                                                 case 1: ammo_full = autocvar_hud_panel_weapons_ammo_full_nails; break;
 801                                                 case 2: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 802                                                 case 3: ammo_full = autocvar_hud_panel_weapons_ammo_full_cells; break;
 803                                                 case 4: ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel; break;
 804                                                 default: ammo_full = 60;
 805                                         }
 806
 807                                         drawsetcliparea(
 808                                                 weapon_pos_x + baroffset_x,
 809                                                 weapon_pos_y + baroffset_y,
 810                                                 barsize_x * bound(0, a/ammo_full, 1),
 811                                                 barsize_y);
 812                                         drawpic_aspect_skin(weapon_pos, "weapon_ammo", weapon_size, ammo_color, ammo_alpha, DRAWFLAG_NORMAL);
 813                                         drawresetcliparea();
 814                                 }
 815                         }
 816                 }
 817                 else // draw a "ghost weapon icon" if you don't have the weapon
 818                 {
 819                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 820                 }
 821
 822                 // draw the complain message
 823                 if(self.weapon == complain_weapon)
 824                 {
 825                         if(fadetime)
 826                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 827                         else
 828                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 829
 830                         string s;
 831                         if(complain_weapon_type == 0) {
 832                                 s = _("Out of ammo");
 833                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 834                         }
 835                         else if(complain_weapon_type == 1) {
 836                                 s = _("Don't have");
 837                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 838                         }
 839                         else {
 840                                 s = _("Unavailable");
 841                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 842                         }
 843                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 844                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 845                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 846                 }
 847
 848                 // continue with new position for the next weapon
 849                 ++row;
 850                 if(row >= rows)
 851                 {
 852                         row = 0;
 853                         ++column;
 854                 }
 855         }
 856
 857         draw_endBoldFont();
 858 }
 859
 860 // Ammo (#1)
 861 //
 862 // TODO: macro
 863 float GetAmmoItemCode(float i)
 864 {
 865         switch(i)
 866         {
 867                 case 0: return IT_SHELLS;
 868                 case 1: return IT_NAILS;
 869                 case 2: return IT_ROCKETS;
 870                 case 3: return IT_CELLS;
 871                 case 4: return IT_FUEL;
 872                 default: return -1;
 873         }
 874 }
 875
 876 string GetAmmoPicture(float i)
 877 {
 878         switch(i)
 879         {
 880                 case 0: return "ammo_shells";
 881                 case 1: return "ammo_bullets";
 882                 case 2: return "ammo_rockets";
 883                 case 3: return "ammo_cells";
 884                 case 4: return "ammo_fuel";
 885                 default: return "";
 886         }
 887 }
 888
 889 void DrawAmmoItem(vector myPos, vector mySize, float itemcode, float currently_selected, float infinite_ammo)
 890 {
 891         float a;
 892         if(autocvar__hud_configure)
 893         {
 894                 currently_selected = (itemcode == 2); //rockets always selected
 895                 a = 31 + mod(itemcode*93, 128);
 896         }
 897         else
 898                 a = getstati(GetAmmoStat(itemcode)); // how much ammo do we have of type itemcode?
 899
 900         vector color;
 901         if(infinite_ammo)
 902                 color = '0 0.5 0.75';
 903         else if(a < 10)
 904                 color = '0.7 0 0';
 905         else
 906                 color = '1 1 1';
 907
 908         float theAlpha;
 909         if(currently_selected)
 910                 theAlpha = 1;
 911         else
 912                 theAlpha = 0.7;
 913
 914         vector picpos, numpos;
 915         if(autocvar_hud_panel_ammo_iconalign)
 916         {
 917                 numpos = myPos;
 918                 picpos = myPos + eX * 2 * mySize_y;
 919         }
 920         else
 921         {
 922                 numpos = myPos + eX * mySize_y;
 923                 picpos = myPos;
 924         }
 925
 926         if (currently_selected)
 927                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 928
 929     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
 930         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 931
 932     if(autocvar_hud_panel_ammo_text)
 933     {
 934         if(a > 0 || infinite_ammo)
 935             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 936         else // "ghost" ammo count
 937             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 938     }
 939         if(a > 0 || infinite_ammo)
 940                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 941         else // "ghost" ammo icon
 942                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 943 }
 944
 945 void HUD_Ammo(void)
 946 {
 947     if(hud != HUD_NORMAL) return;
 948         if(!autocvar__hud_configure)
 949         {
 950                 if(!autocvar_hud_panel_ammo) return;
 951                 if(spectatee_status == -1) return;
 952         }
 953         else
 954                 hud_configure_active_panel = HUD_PANEL_AMMO;
 955
 956         HUD_Panel_UpdateCvars(ammo);
 957         HUD_Panel_ApplyFadeAlpha();
 958
 959         draw_beginBoldFont();
 960
 961         vector pos, mySize;
 962         pos = panel_pos;
 963         mySize = panel_size;
 964
 965         HUD_Panel_DrawBg(1);
 966         if(panel_bg_padding)
 967         {
 968                 pos += '1 1 0' * panel_bg_padding;
 969                 mySize -= '2 2 0' * panel_bg_padding;
 970         }
 971
 972         float rows = 0, columns, row, column;
 973         vector ammo_size;
 974         if (autocvar_hud_panel_ammo_onlycurrent)
 975                 ammo_size = mySize;
 976         else
 977         {
 978                 rows = mySize_y/mySize_x;
 979                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
 980                 //                               ^^^ ammo item aspect goes here
 981
 982                 columns = ceil(AMMO_COUNT/rows);
 983
 984                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
 985         }
 986
 987         local vector offset = '0 0 0'; // fteqcc sucks
 988         float newSize;
 989         if(ammo_size_x/ammo_size_y > 3)
 990         {
 991                 newSize = 3 * ammo_size_y;
 992                 offset_x = ammo_size_x - newSize;
 993                 pos_x += offset_x/2;
 994                 ammo_size_x = newSize;
 995         }
 996         else
 997         {
 998                 newSize = 1/3 * ammo_size_x;
 999                 offset_y = ammo_size_y - newSize;
1000                 pos_y += offset_y/2;
1001                 ammo_size_y = newSize;
1002         }
1003
1004         float i, stat_items, currently_selected, infinite_ammo;
1005         infinite_ammo = FALSE;
1006         if (autocvar_hud_panel_ammo_onlycurrent)
1007         {
1008                 if(autocvar__hud_configure)
1009                 {
1010                         DrawAmmoItem(pos, ammo_size, 2, true, FALSE); //show rockets
1011                 }
1012                 else
1013                 {
1014                         stat_items = getstati(STAT_ITEMS, 0, 24);
1015                         if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1016                                 infinite_ammo = TRUE;
1017                         for (i = 0; i < AMMO_COUNT; ++i) {
1018                                 currently_selected = stat_items & GetAmmoItemCode(i);
1019                                 if (currently_selected)
1020                                 {
1021                                         DrawAmmoItem(pos, ammo_size, i, true, infinite_ammo);
1022                                         break;
1023                                 }
1024                         }
1025                 }
1026         }
1027         else
1028         {
1029                 stat_items = getstati(STAT_ITEMS, 0, 24);
1030                 if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1031                         infinite_ammo = TRUE;
1032                 row = column = 0;
1033                 for (i = 0; i < AMMO_COUNT; ++i) {
1034                         currently_selected = stat_items & GetAmmoItemCode(i);
1035                         DrawAmmoItem(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, i, currently_selected, infinite_ammo);
1036                         ++row;
1037                         if(row >= rows)
1038                         {
1039                                 row = 0;
1040                                 column = column + 1;
1041                         }
1042                 }
1043         }
1044
1045         draw_endBoldFont();
1046 }
1047
1048 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1049 {
1050         vector newPos = '0 0 0', newSize = '0 0 0';
1051         vector picpos, numpos;
1052
1053         if (vertical)
1054         {
1055                 if(mySize_y/mySize_x > 2)
1056                 {
1057                         newSize_y = 2 * mySize_x;
1058                         newSize_x = mySize_x;
1059
1060                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1061                         newPos_x = myPos_x;
1062                 }
1063                 else
1064                 {
1065                         newSize_x = 1/2 * mySize_y;
1066                         newSize_y = mySize_y;
1067
1068                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1069                         newPos_y = myPos_y;
1070                 }
1071
1072                 if(icon_right_align)
1073                 {
1074                         numpos = newPos;
1075                         picpos = newPos + eY * newSize_x;
1076                 }
1077                 else
1078                 {
1079                         picpos = newPos;
1080                         numpos = newPos + eY * newSize_x;
1081                 }
1082
1083                 newSize_y /= 2;
1084                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1085                 // make number smaller than icon, it looks better
1086                 // reduce only y to draw numbers with different number of digits with the same y size
1087                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1088                 newSize_y *= 0.7;
1089                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1090                 return;
1091         }
1092
1093         if(mySize_x/mySize_y > 3)
1094         {
1095                 newSize_x = 3 * mySize_y;
1096                 newSize_y = mySize_y;
1097
1098                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1099                 newPos_y = myPos_y;
1100         }
1101         else
1102         {
1103                 newSize_y = 1/3 * mySize_x;
1104                 newSize_x = mySize_x;
1105
1106                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1107                 newPos_x = myPos_x;
1108         }
1109
1110         if(icon_right_align) // right align
1111         {
1112                 numpos = newPos;
1113                 picpos = newPos + eX * 2 * newSize_y;
1114         }
1115         else // left align
1116         {
1117                 numpos = newPos + eX * newSize_y;
1118                 picpos = newPos;
1119         }
1120
1121         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1122         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1123         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1124         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1125 }
1126
1127 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1128 {
1129         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1130 }
1131
1132 // Powerups (#2)
1133 //
1134 void HUD_Powerups(void)
1135 {
1136         float strength_time, shield_time, superweapons_time;
1137         if(!autocvar__hud_configure)
1138         {
1139                 if(!autocvar_hud_panel_powerups) return;
1140                 if(spectatee_status == -1) return;
1141                 if not(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON)) return;
1142                 if (getstati(STAT_HEALTH) <= 0) return;
1143
1144                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1145                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1146                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1147
1148                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1149                         superweapons_time = 99; // force max
1150
1151                 // prevent stuff to show up on mismatch that will be fixed next frame
1152                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1153                         superweapons_time = 0;
1154         }
1155         else
1156         {
1157                 hud_configure_active_panel = HUD_PANEL_POWERUPS;
1158
1159                 strength_time = 15;
1160                 shield_time = 27;
1161                 superweapons_time = 13;
1162         }
1163
1164         HUD_Panel_UpdateCvars(powerups);
1165         HUD_Panel_ApplyFadeAlpha();
1166
1167         draw_beginBoldFont();
1168
1169         vector pos, mySize;
1170         pos = panel_pos;
1171         mySize = panel_size;
1172
1173         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1174         if(panel_bg_padding)
1175         {
1176                 pos += '1 1 0' * panel_bg_padding;
1177                 mySize -= '2 2 0' * panel_bg_padding;
1178         }
1179
1180         float panel_ar = mySize_x/mySize_y;
1181         float is_vertical = (panel_ar < 1);
1182         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1183
1184         float superweapons_is = -1;
1185
1186         if(superweapons_time)
1187         {
1188                 if(strength_time)
1189                 {
1190                         if(shield_time)
1191                                 superweapons_is = 0;
1192                         else
1193                                 superweapons_is = 2;
1194                 }
1195                 else
1196                 {
1197                         if(shield_time)
1198                                 superweapons_is = 1;
1199                         else
1200                                 superweapons_is = 2;
1201                 }
1202         }
1203
1204         // FIXME handle superweapons here
1205         if(superweapons_is == 0)
1206         {
1207                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1208                 {
1209                         mySize_x *= (1.0 / 3.0);
1210                         superweapons_offset_x = mySize_x;
1211                         if (autocvar_hud_panel_powerups_flip)
1212                                 shield_offset_x = 2*mySize_x;
1213                         else
1214                                 strength_offset_x = 2*mySize_x;
1215                 }
1216                 else
1217                 {
1218                         mySize_y *= (1.0 / 3.0);
1219                         superweapons_offset_y = mySize_y;
1220                         if (autocvar_hud_panel_powerups_flip)
1221                                 shield_offset_y = 2*mySize_y;
1222                         else
1223                                 strength_offset_y = 2*mySize_y;
1224                 }
1225         }
1226         else
1227         {
1228                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1229                 {
1230                         mySize_x *= 0.5;
1231                         if (autocvar_hud_panel_powerups_flip)
1232                                 shield_offset_x = mySize_x;
1233                         else
1234                                 strength_offset_x = mySize_x;
1235                 }
1236                 else
1237                 {
1238                         mySize_y *= 0.5;
1239                         if (autocvar_hud_panel_powerups_flip)
1240                                 shield_offset_y = mySize_y;
1241                         else
1242                                 strength_offset_y = mySize_y;
1243                 }
1244         }
1245
1246         float shield_baralign, strength_baralign, superweapons_baralign;
1247         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1248
1249         if (autocvar_hud_panel_powerups_flip)
1250         {
1251                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1252                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1253                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1254                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1255         }
1256         else
1257         {
1258                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1259                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1260                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1261                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1262         }
1263
1264         if(superweapons_is == 0)
1265         {
1266                 superweapons_iconalign = strength_iconalign;
1267                 superweapons_baralign = 2;
1268         }
1269         else if(superweapons_is == 1)
1270         {
1271                 superweapons_offset = strength_offset;
1272                 superweapons_iconalign = strength_iconalign;
1273                 superweapons_baralign = strength_baralign;
1274         }
1275         else // if(superweapons_is == 2)
1276         {
1277                 superweapons_offset = shield_offset;
1278                 superweapons_iconalign = shield_iconalign;
1279                 superweapons_baralign = shield_baralign;
1280         }
1281
1282         if(shield_time)
1283         {
1284                 const float maxshield = 30;
1285                 float shield = ceil(shield_time);
1286                 if(autocvar_hud_panel_powerups_progressbar)
1287                 {
1288                         HUD_Panel_GetProgressBarColor(shield);
1289                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1290                 }
1291                 if(autocvar_hud_panel_powerups_text)
1292                 {
1293                         if(shield > 1)
1294                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1295                         if(shield <= 5)
1296                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1297                 }
1298         }
1299
1300         if(strength_time)
1301         {
1302                 const float maxstrength = 30;
1303                 float strength = ceil(strength_time);
1304                 if(autocvar_hud_panel_powerups_progressbar)
1305                 {
1306                         HUD_Panel_GetProgressBarColor(strength);
1307                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1308                 }
1309                 if(autocvar_hud_panel_powerups_text)
1310                 {
1311                         if(strength > 1)
1312                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1313                         if(strength <= 5)
1314                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1315                 }
1316         }
1317
1318         if(superweapons_time)
1319         {
1320                 const float maxsuperweapons = 30;
1321                 float superweapons = ceil(superweapons_time);
1322                 if(autocvar_hud_panel_powerups_progressbar)
1323                 {
1324                         HUD_Panel_GetProgressBarColor(superweapons);
1325                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1326                 }
1327                 if(autocvar_hud_panel_powerups_text)
1328                 {
1329                         if(superweapons > 1)
1330                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1331                         if(superweapons <= 5)
1332                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1333                 }
1334         }
1335
1336         draw_endBoldFont();
1337 }
1338
1339 // Health/armor (#3)
1340 //
1341
1342 // prev_* vars contain the health/armor at the previous FRAME
1343 // set to -1 when player is dead or was not playing
1344 float prev_health, prev_armor;
1345 float health_damagetime, armor_damagetime;
1346 float health_beforedamage, armor_beforedamage;
1347 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1348 float old_p_health, old_p_armor;
1349 float old_p_healthtime, old_p_armortime;
1350 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1351 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1352 float prev_p_health, prev_p_armor;
1353
1354 void HUD_HealthArmor(void)
1355 {
1356         float armor, health, fuel;
1357         if(!autocvar__hud_configure)
1358         {
1359                 if(!autocvar_hud_panel_healtharmor) return;
1360                 if(hud != HUD_NORMAL) return;
1361                 if(spectatee_status == -1) return;
1362
1363                 health = getstati(STAT_HEALTH);
1364                 if(health <= 0)
1365                 {
1366                         prev_health = -1;
1367                         return;
1368                 }
1369                 armor = getstati(STAT_ARMOR);
1370
1371                 // code to check for spectatee_status changes is in Ent_ClientData()
1372                 // prev_p_health and prev_health can be set to -1 there
1373
1374                 if (prev_p_health == -1)
1375                 {
1376                         // no effect
1377                         health_beforedamage = 0;
1378                         armor_beforedamage = 0;
1379                         health_damagetime = 0;
1380                         armor_damagetime = 0;
1381                         prev_health = health;
1382                         prev_armor = armor;
1383                         old_p_health = health;
1384                         old_p_armor = armor;
1385                         prev_p_health = health;
1386                         prev_p_armor = armor;
1387                 }
1388                 else if (prev_health == -1)
1389                 {
1390                         //start the load effect
1391                         health_damagetime = 0;
1392                         armor_damagetime = 0;
1393                         prev_health = 0;
1394                         prev_armor = 0;
1395                 }
1396                 fuel = getstati(STAT_FUEL);
1397         }
1398         else
1399         {
1400                 hud_configure_active_panel = HUD_PANEL_HEALTHARMOR;
1401
1402                 health = 150;
1403                 armor = 75;
1404                 fuel = 20;
1405         }
1406
1407         HUD_Panel_UpdateCvars(healtharmor);
1408         HUD_Panel_ApplyFadeAlpha();
1409         vector pos, mySize;
1410         pos = panel_pos;
1411         mySize = panel_size;
1412
1413         HUD_Panel_DrawBg(1);
1414         if(panel_bg_padding)
1415         {
1416                 pos += '1 1 0' * panel_bg_padding;
1417                 mySize -= '2 2 0' * panel_bg_padding;
1418         }
1419
1420         float baralign = autocvar_hud_panel_healtharmor_baralign;
1421         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1422
1423     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1424     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1425         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1426         {
1427                 vector v;
1428                 v = healtharmor_maxdamage(health, armor, armorblockpercent);
1429
1430                 float x;
1431                 x = floor(v_x + 1);
1432
1433         float maxtotal = maxhealth + maxarmor;
1434                 string biggercount;
1435                 if(v_z) // NOT fully armored
1436                 {
1437                         biggercount = "health";
1438                         if(autocvar_hud_panel_healtharmor_progressbar)
1439                         {
1440                                 HUD_Panel_GetProgressBarColor(health);
1441                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1442                         }
1443                         if(armor)
1444             if(autocvar_hud_panel_healtharmor_text)
1445                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1446                 }
1447                 else
1448                 {
1449                         biggercount = "armor";
1450                         if(autocvar_hud_panel_healtharmor_progressbar)
1451                         {
1452                                 HUD_Panel_GetProgressBarColor(armor);
1453                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1454                         }
1455                         if(health)
1456             if(autocvar_hud_panel_healtharmor_text)
1457                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1458                 }
1459         if(autocvar_hud_panel_healtharmor_text)
1460                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1461
1462                 if(fuel)
1463                 {
1464                         HUD_Panel_GetProgressBarColor(fuel);
1465                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), progressbar_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1466                 }
1467         }
1468         else
1469         {
1470                 float panel_ar = mySize_x/mySize_y;
1471                 float is_vertical = (panel_ar < 1);
1472                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1473                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1474                 {
1475                         mySize_x *= 0.5;
1476                         if (autocvar_hud_panel_healtharmor_flip)
1477                                 health_offset_x = mySize_x;
1478                         else
1479                                 armor_offset_x = mySize_x;
1480                 }
1481                 else
1482                 {
1483                         mySize_y *= 0.5;
1484                         if (autocvar_hud_panel_healtharmor_flip)
1485                                 health_offset_y = mySize_y;
1486                         else
1487                                 armor_offset_y = mySize_y;
1488                 }
1489
1490                 float health_baralign, armor_baralign, fuel_baralign;
1491                 float health_iconalign, armor_iconalign;
1492                 if (autocvar_hud_panel_healtharmor_flip)
1493                 {
1494                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1495                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1496                         fuel_baralign = health_baralign;
1497                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1498                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1499                 }
1500                 else
1501                 {
1502                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1503                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1504                         fuel_baralign = armor_baralign;
1505                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1506                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1507                 }
1508
1509                 //if(health)
1510                 {
1511                         if(autocvar_hud_panel_healtharmor_progressbar)
1512                         {
1513                                 HUD_Panel_GetProgressBarColor(health);
1514                                 float p_health, pain_health_alpha;
1515                                 p_health = health;
1516                                 pain_health_alpha = 1;
1517                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1518                                 {
1519                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1520                                         {
1521                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1522                                                 {
1523                                                         if (time - old_p_healthtime < 1)
1524                                                                 old_p_health = prev_p_health;
1525                                                         else
1526                                                                 old_p_health = prev_health;
1527                                                         old_p_healthtime = time;
1528                                                 }
1529                                                 if (time - old_p_healthtime < 1)
1530                                                 {
1531                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1532                                                         prev_p_health = p_health;
1533                                                 }
1534                                         }
1535                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1536                                         {
1537                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1538                                                 {
1539                                                         if (time - health_damagetime >= 1)
1540                                                                 health_beforedamage = prev_health;
1541                                                         health_damagetime = time;
1542                                                 }
1543                                                 if (time - health_damagetime < 1)
1544                                                 {
1545                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1546                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1547                                                 }
1548                                         }
1549                                         prev_health = health;
1550
1551                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1552                                         {
1553                                                 float BLINK_FACTOR = 0.15;
1554                                                 float BLINK_BASE = 0.85;
1555                                                 float BLINK_FREQ = 9;
1556                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1557                                         }
1558                                 }
1559                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1560                         }
1561                         if(autocvar_hud_panel_healtharmor_text)
1562                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1563                 }
1564
1565                 if(armor)
1566                 {
1567                         if(autocvar_hud_panel_healtharmor_progressbar)
1568                         {
1569                                 HUD_Panel_GetProgressBarColor(armor);
1570                                 float p_armor;
1571                                 p_armor = armor;
1572                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1573                                 {
1574                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1575                                         {
1576                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1577                                                 {
1578                                                         if (time - old_p_armortime < 1)
1579                                                                 old_p_armor = prev_p_armor;
1580                                                         else
1581                                                                 old_p_armor = prev_armor;
1582                                                         old_p_armortime = time;
1583                                                 }
1584                                                 if (time - old_p_armortime < 1)
1585                                                 {
1586                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1587                                                         prev_p_armor = p_armor;
1588                                                 }
1589                                         }
1590                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1591                                         {
1592                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1593                                                 {
1594                                                         if (time - armor_damagetime >= 1)
1595                                                                 armor_beforedamage = prev_armor;
1596                                                         armor_damagetime = time;
1597                                                 }
1598                                                 if (time - armor_damagetime < 1)
1599                                                 {
1600                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1601                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1602                                                 }
1603                                         }
1604                                         prev_armor = armor;
1605                                 }
1606                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1607                         }
1608                         if(autocvar_hud_panel_healtharmor_text)
1609                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1610                 }
1611
1612                 if(fuel)
1613                 {
1614                         if (is_vertical)
1615                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1616                         else
1617                                 mySize_y *= 0.2;
1618                         if (panel_ar >= 4)
1619                                 mySize_x *= 2; //restore full panel size
1620                         else if (panel_ar < 1/4)
1621                                 mySize_y *= 2; //restore full panel size
1622                         HUD_Panel_GetProgressBarColor(fuel);
1623                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, progressbar_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1624                 }
1625         }
1626 }
1627
1628 // Notification area (#4)
1629 //
1630
1631 void HUD_Notify_Push(string icon, string attacker, string victim)
1632 {
1633         if(icon != "")
1634         {
1635                 --kn_index;
1636                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
1637                 notify_times[kn_index] = time;
1638
1639                 // icon
1640                 if(notify_icon[kn_index]) { strunzone(notify_icon[kn_index]); }
1641                 notify_icon[kn_index] = strzone(icon);
1642
1643                 // attacker
1644                 if(notify_attackers[kn_index]) { strunzone(notify_attackers[kn_index]); }
1645                 notify_attackers[kn_index] = strzone(attacker);
1646
1647                 // victim
1648                 if(notify_victims[kn_index]) { strunzone(notify_victims[kn_index]); }
1649                 notify_victims[kn_index] = strzone(victim);
1650         }
1651 }
1652
1653 void HUD_Notify(void)
1654 {
1655         if(!autocvar__hud_configure)
1656         {
1657                 if(!autocvar_hud_panel_notify) return;
1658         }
1659         else
1660                 hud_configure_active_panel = HUD_PANEL_NOTIFY;
1661
1662         HUD_Panel_UpdateCvars(notify);
1663         HUD_Panel_ApplyFadeAlpha();
1664         vector pos, mySize;
1665         pos = panel_pos;
1666         mySize = panel_size;
1667
1668         HUD_Panel_DrawBg(1);
1669         if(panel_bg_padding)
1670         {
1671                 pos += '1 1 0' * panel_bg_padding;
1672                 mySize -= '2 2 0' * panel_bg_padding;
1673         }
1674
1675         float entries, height;
1676         entries = bound(1, floor(KN_MAX_ENTRIES * mySize_y/mySize_x), KN_MAX_ENTRIES);
1677         height = mySize_y/entries;
1678
1679         vector fontsize;
1680         float fontheight = height * autocvar_hud_panel_notify_fontsize;
1681         fontsize = '0.5 0.5 0' * fontheight;
1682
1683         float a;
1684         float when;
1685         when = autocvar_hud_panel_notify_time;
1686         float fadetime;
1687         fadetime = autocvar_hud_panel_notify_fadetime;
1688
1689         vector pos_attacker, pos_victim, pos_icon;
1690         float width_attacker;
1691         string attacker, victim, icon;
1692
1693         float i, j, step, limit;
1694         if(autocvar_hud_panel_notify_flip) //order items from the top down
1695         {
1696                 i = 0;
1697                 step = +1;
1698                 limit = entries;
1699         }
1700         else //order items from the bottom up
1701         {
1702                 i = entries - 1;
1703                 step = -1;
1704                 limit = -1;
1705         }
1706
1707         for(j = kn_index;  i != limit;  i += step, ++j)
1708         {
1709                 if(autocvar__hud_configure)
1710                 {
1711                         if (step == +1)
1712                                 a = i;
1713                         else // inverse order
1714                                 a = entries - 1 - i;
1715                         attacker = textShortenToWidth(sprintf(_("Player %d"), a+1), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1716                         victim = textShortenToWidth(sprintf(_("Player %d"), a+2), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1717                         icon = strcat("weapon", get_weaponinfo(WEP_FIRST + mod(floor(a*2.4), WEP_LAST)).netname);
1718                         a = bound(0, (when - a) / 4, 1);
1719                         goto hud_config_notifyprint;
1720                 }
1721                 else
1722                 {
1723                         if (j == KN_MAX_ENTRIES)
1724                                 j = 0;
1725
1726                         if(notify_times[j] + when > time)
1727                                 a = 1;
1728                         else if(fadetime)
1729                         {
1730                                 a = bound(0, (notify_times[j] + when + fadetime - time) / fadetime, 1);
1731                                 if(!a)
1732                                 {
1733                                         break;
1734                                 }
1735                         }
1736                         else
1737                         {
1738                                 break;
1739                         }
1740
1741                         attacker = notify_attackers[j];
1742                         victim = notify_victims[j];
1743                         icon = notify_icon[j];
1744                 }
1745
1746                 //type = notify_deathtype[j];
1747                 //w = DEATH_WEAPONOF(type);
1748
1749                 if(icon != "")
1750                 {
1751                         if((attacker != "") && (victim == ""))
1752                         {
1753                                 // Y [used by] X
1754                                 attacker = textShortenToWidth(attacker, 0.73 * mySize_x - height, fontsize, stringwidth_colors);
1755                                 pos_attacker = pos + eX * (0.27 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1756                                 pos_icon = pos + eX * 0.25 * mySize_x - eX * height + eY * i * height;
1757
1758                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1759                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1760                         }
1761                         else if((attacker != "") && (victim != ""))
1762                         {
1763                                 // X [did action to] Y
1764                                 attacker = textShortenToWidth(attacker, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1765                                 victim = textShortenToWidth(victim, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1766 :hud_config_notifyprint
1767                                 width_attacker = stringwidth(attacker, TRUE, fontsize);
1768                                 pos_attacker = pos + eX * (0.48 * mySize_x - height - width_attacker) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1769                                 pos_victim = pos + eX * (0.52 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1770                                 pos_icon = pos + eX * 0.5 * mySize_x - eX * height + eY * i * height;
1771
1772                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1773                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1774                                 drawcolorcodedstring(pos_victim, victim, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1775                         }
1776                 }
1777         }
1778 }
1779
1780 // Timer (#5)
1781 //
1782 // TODO: macro
1783 string seconds_tostring(float sec)
1784 {
1785         float minutes;
1786         minutes = floor(sec / 60);
1787
1788         sec -= minutes * 60;
1789         return sprintf("%d:%02d", minutes, sec);
1790 }
1791
1792 void HUD_Timer(void)
1793 {
1794         if(!autocvar__hud_configure)
1795         {
1796                 if(!autocvar_hud_panel_timer) return;
1797         }
1798         else
1799                 hud_configure_active_panel = HUD_PANEL_TIMER;
1800
1801         HUD_Panel_UpdateCvars(timer);
1802         HUD_Panel_ApplyFadeAlpha();
1803
1804         draw_beginBoldFont();
1805
1806         vector pos, mySize;
1807         pos = panel_pos;
1808         mySize = panel_size;
1809
1810         HUD_Panel_DrawBg(1);
1811         if(panel_bg_padding)
1812         {
1813                 pos += '1 1 0' * panel_bg_padding;
1814                 mySize -= '2 2 0' * panel_bg_padding;
1815         }
1816
1817         string timer;
1818         float timelimit, elapsedTime, timeleft, minutesLeft;
1819
1820         timelimit = getstatf(STAT_TIMELIMIT);
1821
1822         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1823         timeleft = ceil(timeleft);
1824
1825         minutesLeft = floor(timeleft / 60);
1826
1827         vector timer_color;
1828         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1829                 timer_color = '1 1 1'; //white
1830         else if(minutesLeft >= 1)
1831                 timer_color = '1 1 0'; //yellow
1832         else
1833                 timer_color = '1 0 0'; //red
1834
1835         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1836                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1837                         //while restart is still active, show 00:00
1838                         timer = seconds_tostring(0);
1839                 } else {
1840                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1841                         timer = seconds_tostring(elapsedTime);
1842                 }
1843         } else {
1844                 timer = seconds_tostring(timeleft);
1845         }
1846
1847         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1848
1849         draw_endBoldFont();
1850 }
1851
1852 // Radar (#6)
1853 //
1854 void HUD_Radar(void)
1855 {
1856         if (!autocvar__hud_configure)
1857         {
1858                 if (hud_panel_radar_maximized)
1859                 {
1860                         if (!hud_draw_maximized) return;
1861                 }
1862                 else
1863                 {
1864                         if (autocvar_hud_panel_radar == 0) return;
1865                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1866                 }
1867         }
1868         else
1869                 hud_configure_active_panel = HUD_PANEL_RADAR;
1870
1871         HUD_Panel_UpdateCvars(radar);
1872         HUD_Panel_ApplyFadeAlpha();
1873
1874         float f = 0;
1875
1876         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1877         {
1878                 panel_size = autocvar_hud_panel_radar_maximized_size;
1879                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1880                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1881                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1882                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1883
1884                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1885                 if(precache_pic(panel_bg) == "") { panel_bg = "gfx/hud/default/border_default"; } // fallback
1886
1887                 switch(hud_panel_radar_maximized_zoommode)
1888                 {
1889                         default:
1890                         case 0:
1891                                 f = current_zoomfraction;
1892                                 break;
1893                         case 1:
1894                                 f = 1 - current_zoomfraction;
1895                                 break;
1896                         case 2:
1897                                 f = 0;
1898                                 break;
1899                         case 3:
1900                                 f = 1;
1901                                 break;
1902                 }
1903
1904                 switch(hud_panel_radar_maximized_rotation)
1905                 {
1906                         case 0:
1907                                 teamradar_angle = view_angles_y - 90;
1908                                 break;
1909                         default:
1910                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1911                                 break;
1912                 }
1913         }
1914         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1915         {
1916                 switch(hud_panel_radar_zoommode)
1917                 {
1918                         default:
1919                         case 0:
1920                                 f = current_zoomfraction;
1921                                 break;
1922                         case 1:
1923                                 f = 1 - current_zoomfraction;
1924                                 break;
1925                         case 2:
1926                                 f = 0;
1927                                 break;
1928                         case 3:
1929                                 f = 1;
1930                                 break;
1931                 }
1932
1933                 switch(hud_panel_radar_rotation)
1934                 {
1935                         case 0:
1936                                 teamradar_angle = view_angles_y - 90;
1937                                 break;
1938                         default:
1939                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1940                                 break;
1941                 }
1942         }
1943
1944         vector pos, mySize;
1945         pos = panel_pos;
1946         mySize = panel_size;
1947
1948         HUD_Panel_DrawBg(1);
1949         if(panel_bg_padding)
1950         {
1951                 pos += '1 1 0' * panel_bg_padding;
1952                 mySize -= '2 2 0' * panel_bg_padding;
1953         }
1954
1955         float color2;
1956         entity tm;
1957         float scale2d, normalsize, bigsize;
1958
1959         teamradar_origin2d = pos + 0.5 * mySize;
1960         teamradar_size2d = mySize;
1961
1962         if(minimapname == "")
1963                 return;
1964
1965         teamradar_loadcvars();
1966
1967         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1968         teamradar_size2d = mySize;
1969
1970         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1971
1972         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1973         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1974         {
1975                 // max-min distance must fit the radar in any rotation
1976                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1977         }
1978         else
1979         {
1980                 vector c0, c1, c2, c3, span;
1981                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1982                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1983                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1984                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1985                 span = '0 0 0';
1986                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1987                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1988
1989                 // max-min distance must fit the radar in x=x, y=y
1990                 bigsize = min(
1991                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1992                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1993                 );
1994         }
1995
1996         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1997         if(bigsize > normalsize)
1998                 normalsize = bigsize;
1999
2000         teamradar_size =
2001                   f * bigsize
2002                 + (1 - f) * normalsize;
2003         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2004                   f * mi_center
2005                 + (1 - f) * view_origin);
2006
2007         drawsetcliparea(
2008                 pos_x,
2009                 pos_y,
2010                 mySize_x,
2011                 mySize_y
2012         );
2013
2014         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2015
2016         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2017                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2018         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2019                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2020         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2021         {
2022                 color2 = GetPlayerColor(tm.sv_entnum);
2023                 //if(color == NUM_SPECTATOR || color == color2)
2024                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2025         }
2026         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2027
2028         drawresetcliparea();
2029 }
2030
2031 // Score (#7)
2032 //
2033 void HUD_UpdatePlayerTeams();
2034 void HUD_Score_Rankings(vector pos, vector mySize, entity me, float team_count)
2035 {
2036         float score;
2037         entity tm = world, pl;
2038 #define SCOREPANEL_MAX_ENTRIES 6
2039 #define SCOREPANEL_ASPECTRATIO 2
2040         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2041         vector fontsize = '1 1 0' * (mySize_y/entries);
2042
2043         vector rgb, score_color;
2044         rgb = '1 1 1';
2045         score_color = '1 1 1';
2046
2047         float name_size = mySize_x*0.75;
2048         float spacing_size = mySize_x*0.04;
2049         const float highlight_alpha = 0.2;
2050         float i = 0, me_printed = 0, first_pl = 0;
2051         string s;
2052         if (autocvar__hud_configure)
2053         {
2054                 float players_per_team = 0;
2055                 if (team_count)
2056                 {
2057                         // show team scores in the first line
2058                         float score_size = mySize_x / team_count;
2059                         players_per_team = max(2, ceil((entries - 1) / team_count));
2060                         for(i=0; i<team_count; ++i) {
2061                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2062                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2063                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2064                         }
2065                         first_pl = 1;
2066                         pos_y += fontsize_y;
2067                 }
2068                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2069                 for (i=first_pl; i<entries; ++i)
2070                 {
2071                         //simulate my score is lower than all displayed players,
2072                         //so that I don't appear at all showing pure rankings.
2073                         //This is to better show the difference between the 2 ranking views
2074                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2075                         {
2076                                 rgb = '1 1 0';
2077                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2078                                 s = GetPlayerName(player_localnum);
2079                                 score = 7;
2080                         }
2081                         else
2082                         {
2083                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2084                                 score -= 3;
2085                         }
2086
2087                         if (team_count)
2088                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2089                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2090                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2091                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2092                         pos_y += fontsize_y;
2093                 }
2094                 return;
2095         }
2096
2097         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2098                 HUD_UpdatePlayerTeams();
2099         if (team_count)
2100         {
2101                 // show team scores in the first line
2102                 float score_size = mySize_x / team_count;
2103                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2104                         if(tm.team == NUM_SPECTATOR)
2105                                 continue;
2106                         if (tm.team == myteam)
2107                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2108                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2109                         ++i;
2110                 }
2111                 first_pl = 1;
2112                 pos_y += fontsize_y;
2113                 tm = teams.sort_next;
2114         }
2115         i = first_pl;
2116
2117         do
2118         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2119         {
2120                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2121                         continue;
2122
2123                 if (i == entries-1 && !me_printed && pl != me)
2124                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2125                 {
2126                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2127                                 if (pl.team != NUM_SPECTATOR)
2128                                         break;
2129
2130                         if (pl)
2131                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2132                         else
2133                                 rgb = '1 0 0'; //last: red
2134                         pl = me;
2135                 }
2136
2137                 if (pl == me)
2138                 {
2139                         if (i == first_pl)
2140                                 rgb = '0 1 0'; //first: green
2141                         me_printed = 1;
2142                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2143                 }
2144                 if (team_count)
2145                         score_color = Team_ColorRGB(pl.team) * 0.8;
2146                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2147                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2148                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2149                 pos_y += fontsize_y;
2150                 ++i;
2151         }
2152         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2153 }
2154
2155 void HUD_Score(void)
2156 {
2157         if(!autocvar__hud_configure)
2158         {
2159                 if(!autocvar_hud_panel_score) return;
2160                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2161         }
2162         else
2163                 hud_configure_active_panel = HUD_PANEL_SCORE;
2164
2165         HUD_Panel_UpdateCvars(score);
2166         HUD_Panel_ApplyFadeAlpha();
2167         vector pos, mySize;
2168         pos = panel_pos;
2169         mySize = panel_size;
2170
2171         HUD_Panel_DrawBg(1);
2172         if(panel_bg_padding)
2173         {
2174                 pos += '1 1 0' * panel_bg_padding;
2175                 mySize -= '2 2 0' * panel_bg_padding;
2176         }
2177
2178         float score, distribution = 0;
2179         string sign;
2180         vector distribution_color;
2181         entity tm, pl, me;
2182
2183 #ifdef COMPAT_XON050_ENGINE
2184         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2185 #else
2186         me = playerslots[player_localentnum - 1];
2187 #endif
2188
2189         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2190                 string timer, distrtimer;
2191
2192                 pl = players.sort_next;
2193                 if(pl == me)
2194                         pl = pl.sort_next;
2195                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2196                         if(pl.scores[ps_primary] == 0)
2197                                 pl = world;
2198
2199                 score = me.(scores[ps_primary]);
2200                 timer = TIME_ENCODED_TOSTRING(score);
2201
2202                 draw_beginBoldFont();
2203                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2204                         // distribution display
2205                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2206
2207                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2208
2209                         if (distribution <= 0) {
2210                                 distribution_color = '0 1 0';
2211                                 sign = "-";
2212                         }
2213                         else {
2214                                 distribution_color = '1 0 0';
2215                                 sign = "+";
2216                         }
2217                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2218                 }
2219                 // race record display
2220                 if (distribution <= 0)
2221                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2222                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2223                 draw_endBoldFont();
2224         } else if (!teamplay) { // non-teamgames
2225                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2226                 {
2227                         HUD_Score_Rankings(pos, mySize, me, 0);
2228                         return;
2229                 }
2230                 // me vector := [team/connected frags id]
2231                 pl = players.sort_next;
2232                 if(pl == me)
2233                         pl = pl.sort_next;
2234
2235                 if(autocvar__hud_configure)
2236                         distribution = 42;
2237                 else if(pl)
2238                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2239                 else
2240                         distribution = 0;
2241
2242                 score = me.(scores[ps_primary]);
2243                 if(autocvar__hud_configure)
2244                         score = 123;
2245
2246                 if(distribution >= 5)
2247                         distribution_color = eY;
2248                 else if(distribution >= 0)
2249                         distribution_color = '1 1 1';
2250                 else if(distribution >= -5)
2251                         distribution_color = '1 1 0';
2252                 else
2253                         distribution_color = eX;
2254
2255                 string distribution_str;
2256                 distribution_str = ftos(distribution);
2257                 draw_beginBoldFont();
2258                 if (distribution >= 0)
2259                 {
2260                         if (distribution > 0)
2261                                 distribution_str = strcat("+", distribution_str);
2262                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2263                 }
2264                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2265                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2266                 draw_endBoldFont();
2267         } else { // teamgames
2268                 float scores_count = 0, row, column, rows = 0, columns = 0;
2269                 local noref vector offset = '0 0 0';
2270                 vector score_pos, score_size; //for scores other than myteam
2271                 if (spectatee_status == -1 || autocvar_hud_panel_score_rankings)
2272                 {
2273                         for(tm = teams.sort_next; tm, tm.team != NUM_SPECTATOR; tm = tm.sort_next)
2274                                 ++scores_count;
2275                         if (autocvar_hud_panel_score_rankings)
2276                         {
2277                                 HUD_Score_Rankings(pos, mySize, me, scores_count);
2278                                 return;
2279                         }
2280                         rows = mySize_y/mySize_x;
2281                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * scores_count + rows * rows) + rows + 0.5) / 2), scores_count);
2282                         //                               ^^^ ammo item aspect goes here
2283
2284                         columns = ceil(scores_count/rows);
2285
2286                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2287
2288                         float newSize;
2289                         if(score_size_x/score_size_y > 3)
2290                         {
2291                                 newSize = 3 * score_size_y;
2292                                 offset_x = score_size_x - newSize;
2293                                 pos_x += offset_x/2;
2294                                 score_size_x = newSize;
2295                         }
2296                         else
2297                         {
2298                                 newSize = 1/3 * score_size_x;
2299                                 offset_y = score_size_y - newSize;
2300                                 pos_y += offset_y/2;
2301                                 score_size_y = newSize;
2302                         }
2303                 }
2304                 else
2305                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2306
2307                 float max_fragcount;
2308                 max_fragcount = -99;
2309                 draw_beginBoldFont();
2310                 row = column = 0;
2311                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2312                         if(tm.team == NUM_SPECTATOR)
2313                                 continue;
2314                         score = tm.(teamscores[ts_primary]);
2315                         if(autocvar__hud_configure)
2316                                 score = 123;
2317
2318                         if (score > max_fragcount)
2319                                 max_fragcount = score;
2320
2321                         if (spectatee_status == -1)
2322                         {
2323                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2324                                 if (max_fragcount == score)
2325                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2326                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2327                                 ++row;
2328                                 if(row >= rows)
2329                                 {
2330                                         row = 0;
2331                                         ++column;
2332                                 }
2333                         }
2334                         else if(tm.team == myteam) {
2335                                 if (max_fragcount == score)
2336                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2337                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2338                         } else {
2339                                 if (max_fragcount == score)
2340                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2341                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2342                                 ++rows;
2343                         }
2344                 }
2345                 draw_endBoldFont();
2346         }
2347 }
2348
2349 // Race timer (#8)
2350 //
2351 void HUD_RaceTimer (void)
2352 {
2353         if(!autocvar__hud_configure)
2354         {
2355                 if(!autocvar_hud_panel_racetimer) return;
2356                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2357                 if(spectatee_status == -1) return;
2358         }
2359         else
2360                 hud_configure_active_panel = HUD_PANEL_RACETIMER;
2361
2362         HUD_Panel_UpdateCvars(racetimer);
2363         HUD_Panel_ApplyFadeAlpha();
2364
2365         draw_beginBoldFont();
2366
2367         vector pos, mySize;
2368         pos = panel_pos;
2369         mySize = panel_size;
2370
2371         HUD_Panel_DrawBg(1);
2372         if(panel_bg_padding)
2373         {
2374                 pos += '1 1 0' * panel_bg_padding;
2375                 mySize -= '2 2 0' * panel_bg_padding;
2376         }
2377
2378         // always force 4:1 aspect
2379         vector newSize = '0 0 0';
2380         if(mySize_x/mySize_y > 4)
2381         {
2382                 newSize_x = 4 * mySize_y;
2383                 newSize_y = mySize_y;
2384
2385                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2386         }
2387         else
2388         {
2389                 newSize_y = 1/4 * mySize_x;
2390                 newSize_x = mySize_x;
2391
2392                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2393         }
2394         mySize = newSize;
2395
2396         float a, t;
2397         string s, forcetime;
2398
2399         if(autocvar__hud_configure)
2400         {
2401                 s = "0:13:37";
2402                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2403                 s = _("^1Intermediate 1 (+15.42)");
2404                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2405                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2406                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2407         }
2408         else if(race_checkpointtime)
2409         {
2410                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2411                 s = "";
2412                 forcetime = "";
2413                 if(a > 0) // just hit a checkpoint?
2414                 {
2415                         if(race_checkpoint != 254)
2416                         {
2417                                 if(race_time && race_previousbesttime)
2418                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2419                                 else
2420                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2421                                 if(race_time)
2422                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2423                         }
2424                 }
2425                 else
2426                 {
2427                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2428                         {
2429                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2430                                 if(a > 0) // next one?
2431                                 {
2432                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2433                                 }
2434                         }
2435                 }
2436
2437                 if(s != "" && a > 0)
2438                 {
2439                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2440                 }
2441
2442                 if(race_penaltytime)
2443                 {
2444                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2445                         if(a > 0)
2446                         {
2447                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2448                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2449                         }
2450                 }
2451
2452                 if(forcetime != "")
2453                 {
2454                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2455                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2456                 }
2457                 else
2458                         a = 1;
2459
2460                 if(race_laptime && race_checkpoint != 255)
2461                 {
2462                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2463                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2464                 }
2465         }
2466         else
2467         {
2468                 if(race_mycheckpointtime)
2469                 {
2470                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2471                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2472                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2473                 }
2474                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2475                 {
2476                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2477                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2478                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2479                 }
2480
2481                 if(race_penaltytime && !race_penaltyaccumulator)
2482                 {
2483                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2484                         a = bound(0, (1 + t - time), 1);
2485                         if(a > 0)
2486                         {
2487                                 if(time < t)
2488                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2489                                 else
2490                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2491                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2492                         }
2493                 }
2494         }
2495
2496         draw_endBoldFont();
2497 }
2498
2499 // Vote window (#9)
2500 //
2501 float vote_yescount;
2502 float vote_nocount;
2503 float vote_needed;
2504 float vote_highlighted; // currently selected vote
2505
2506 float vote_active; // is there an active vote?
2507 float vote_prev; // previous state of vote_active to check for a change
2508 float vote_alpha;
2509 float vote_change; // "time" when vote_active changed
2510
2511 void HUD_VoteWindow(void)
2512 {
2513         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2514         {
2515                 vote_active = 1;
2516                 if (autocvar__hud_configure)
2517                 {
2518                         vote_yescount = 0;
2519                         vote_nocount = 0;
2520                         print(_("^1You must answer before entering hud configure mode\n"));
2521                         cvar_set("_hud_configure", "0");
2522                 }
2523                 if(vote_called_vote)
2524                         strunzone(vote_called_vote);
2525                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2526                 uid2name_dialog = 1;
2527         }
2528
2529         if(!autocvar__hud_configure)
2530         {
2531                 if(!autocvar_hud_panel_vote) return;
2532
2533                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2534                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2535
2536                 if(panel_bg_alpha_str == "") {
2537                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2538                 }
2539                 panel_bg_alpha = stof(panel_bg_alpha_str);
2540         }
2541         else
2542         {
2543                 hud_configure_active_panel = HUD_PANEL_VOTE;
2544
2545                 vote_yescount = 3;
2546                 vote_nocount = 2;
2547                 vote_needed = 4;
2548         }
2549
2550         string s;
2551         float a;
2552         if(vote_active != vote_prev) {
2553                 vote_change = time;
2554                 vote_prev = vote_active;
2555         }
2556
2557         if(vote_active || autocvar__hud_configure)
2558                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2559         else
2560                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2561
2562         if(!vote_alpha)
2563                 return;
2564
2565         HUD_Panel_UpdateCvars(vote);
2566         HUD_Panel_ApplyFadeAlpha();
2567
2568         if(uid2name_dialog)
2569         {
2570                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2571                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2572         }
2573
2574     // these must be below above block
2575         vector pos, mySize;
2576         pos = panel_pos;
2577         mySize = panel_size;
2578
2579         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2580         HUD_Panel_DrawBg(a);
2581         a = panel_fg_alpha * a;
2582
2583         if(panel_bg_padding)
2584         {
2585                 pos += '1 1 0' * panel_bg_padding;
2586                 mySize -= '2 2 0' * panel_bg_padding;
2587         }
2588
2589         // always force 3:1 aspect
2590         vector newSize = '0 0 0';
2591         if(mySize_x/mySize_y > 3)
2592         {
2593                 newSize_x = 3 * mySize_y;
2594                 newSize_y = mySize_y;
2595
2596                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2597         }
2598         else
2599         {
2600                 newSize_y = 1/3 * mySize_x;
2601                 newSize_x = mySize_x;
2602
2603                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2604         }
2605         mySize = newSize;
2606
2607         s = _("A vote has been called for:");
2608         if(uid2name_dialog)
2609                 s = _("Allow servers to store and display your name?");
2610         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2611         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2612         if(autocvar__hud_configure)
2613                 s = _("^1Configure the HUD");
2614         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2615
2616         // print the yes/no counts
2617     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2618         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2619     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2620         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2621
2622         // draw the progress bar backgrounds
2623         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2624
2625         // draw the highlights
2626         if(vote_highlighted == 1) {
2627                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2628                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2629         }
2630         else if(vote_highlighted == -1) {
2631                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2632                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2633         }
2634
2635         // draw the progress bars
2636         if(vote_yescount && vote_needed)
2637         {
2638                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2639                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2640         }
2641
2642         if(vote_nocount && vote_needed)
2643         {
2644                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2645                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2646         }
2647
2648         drawresetcliparea();
2649 }
2650
2651 // Mod icons panel (#10)
2652 //
2653
2654 float mod_active; // is there any active mod icon?
2655
2656 // Clan Arena HUD modicons
2657 void HUD_Mod_CA(vector pos, vector mySize)
2658 {
2659         mod_active = 1; // CA should never hide the mod icons panel
2660         float redalive, bluealive;
2661         redalive = getstati(STAT_REDALIVE);
2662         bluealive = getstati(STAT_BLUEALIVE);
2663
2664         vector redpos, bluepos;
2665         if(mySize_x > mySize_y)
2666         {
2667                 redpos = pos;
2668                 bluepos = pos + eY * 0.5 * mySize_y;
2669                 drawpic_aspect_skin(redpos, "player_red.tga", 0.5 * mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2670                 drawstring_aspect(redpos + eX * 0.5 * mySize_x, ftos(redalive), 0.5 * mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2671                 drawpic_aspect_skin(bluepos, "player_blue.tga", 0.5 * mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2672                 drawstring_aspect(bluepos + eX * 0.5 * mySize_x, ftos(bluealive), 0.5 * mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2673         }
2674         else
2675         {
2676                 redpos = pos;
2677                 bluepos = pos + eY * 0.5 * mySize_y;
2678                 drawpic_aspect_skin(redpos, "player_red.tga", eX * mySize_x + eY * 0.3 * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2679                 drawstring_aspect(redpos + eY * 0.3 * mySize_y, ftos(redalive), eX * mySize_x + eY * 0.2 * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2680                 drawpic_aspect_skin(bluepos, "player_blue.tga", eX * mySize_x + eY * 0.3 * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2681                 drawstring_aspect(bluepos + eY * 0.3 * mySize_y, ftos(bluealive), eX * mySize_x + eY * 0.2 * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2682         }
2683 }
2684
2685 // CTF HUD modicon section
2686 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2687 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2688 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2689
2690 void HUD_Mod_CTF_Reset(void)
2691 {
2692         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2693 }
2694
2695 void HUD_Mod_CTF(vector pos, vector mySize)
2696 {
2697         vector redflag_pos, blueflag_pos;
2698         vector flag_size;
2699         float f; // every function should have that
2700
2701         float redflag, blueflag; // current status
2702         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2703         float stat_items;
2704
2705         stat_items = getstati(STAT_ITEMS, 0, 24);
2706         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2707         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2708
2709         if(redflag || blueflag)
2710                 mod_active = 1;
2711         else
2712                 mod_active = 0;
2713
2714         if(autocvar__hud_configure)
2715         {
2716                 redflag = 1;
2717                 blueflag = 2;
2718         }
2719
2720         // when status CHANGES, set old status into prevstatus and current status into status
2721         if (redflag != redflag_prevframe)
2722         {
2723                 redflag_statuschange_time = time;
2724                 redflag_prevstatus = redflag_prevframe;
2725                 redflag_prevframe = redflag;
2726         }
2727
2728         if (blueflag != blueflag_prevframe)
2729         {
2730                 blueflag_statuschange_time = time;
2731                 blueflag_prevstatus = blueflag_prevframe;
2732                 blueflag_prevframe = blueflag;
2733         }
2734
2735         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2736         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2737
2738         float BLINK_FACTOR = 0.15;
2739         float BLINK_BASE = 0.85;
2740         // note:
2741         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2742         // thus
2743         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2744         // ensure RMS == 1
2745         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2746
2747         string red_icon, red_icon_prevstatus;
2748         float red_alpha, red_alpha_prevstatus;
2749         red_alpha = red_alpha_prevstatus = 1;
2750         switch(redflag) {
2751                 case 1: red_icon = "flag_red_taken"; break;
2752                 case 2: red_icon = "flag_red_lost"; break;
2753                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2754                 default:
2755                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2756                                 red_icon = "flag_red_shielded";
2757                         else
2758                                 red_icon = string_null;
2759                         break;
2760         }
2761         switch(redflag_prevstatus) {
2762                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2763                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2764                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2765                 default:
2766                         if(redflag == 3)
2767                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2768                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2769                                 red_icon_prevstatus = "flag_red_shielded";
2770                         else
2771                                 red_icon_prevstatus = string_null;
2772                         break;
2773         }
2774
2775         string blue_icon, blue_icon_prevstatus;
2776         float blue_alpha, blue_alpha_prevstatus;
2777         blue_alpha = blue_alpha_prevstatus = 1;
2778         switch(blueflag) {
2779                 case 1: blue_icon = "flag_blue_taken"; break;
2780                 case 2: blue_icon = "flag_blue_lost"; break;
2781                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2782                 default:
2783                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2784                                 blue_icon = "flag_blue_shielded";
2785                         else
2786                                 blue_icon = string_null;
2787                         break;
2788         }
2789         switch(blueflag_prevstatus) {
2790                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2791                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2792                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2793                 default:
2794                         if(blueflag == 3)
2795                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2796                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2797                                 blue_icon_prevstatus = "flag_blue_shielded";
2798                         else
2799                                 blue_icon_prevstatus = string_null;
2800                         break;
2801         }
2802
2803         if(mySize_x > mySize_y) {
2804                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2805                         redflag_pos = pos;
2806                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2807                 } else {
2808                         blueflag_pos = pos;
2809                         redflag_pos = pos + eX * 0.5 * mySize_x;
2810                 }
2811                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2812         } else {
2813                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2814                         redflag_pos = pos;
2815                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2816                 } else {
2817                         blueflag_pos = pos;
2818                         redflag_pos = pos + eY * 0.5 * mySize_y;
2819                 }
2820                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2821         }
2822
2823         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2824         if(red_icon_prevstatus && f < 1)
2825                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2826         if(red_icon)
2827                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2828
2829         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2830         if(blue_icon_prevstatus && f < 1)
2831                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2832         if(blue_icon)
2833                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2834 }
2835
2836 // Keyhunt HUD modicon section
2837 float kh_runheretime;
2838
2839 void HUD_Mod_KH_Reset(void)
2840 {
2841         kh_runheretime = 0;
2842 }
2843
2844 void HUD_Mod_KH(vector pos, vector mySize)
2845 {
2846         mod_active = 1; // keyhunt should never hide the mod icons panel
2847         float kh_keys;
2848         float keyteam;
2849         float a, aa;
2850         vector p = '0 0 0', pa, kh_size = '0 0 0', kh_asize = '0 0 0';
2851
2852         kh_keys = getstati(STAT_KH_KEYS);
2853
2854         p_x = pos_x;
2855         if(mySize_x > mySize_y)
2856         {
2857                 p_y = pos_y + 0.25 * mySize_y;
2858                 pa = p - eY * 0.25 * mySize_y;
2859
2860                 kh_size_x = mySize_x * 0.25;
2861                 kh_size_y = 0.75 * mySize_y;
2862                 kh_asize_x = mySize_x * 0.25;
2863                 kh_asize_y = mySize_y * 0.25;
2864         }
2865         else
2866         {
2867                 p_y = pos_y + 0.125 * mySize_y;
2868                 pa = p - eY * 0.125 * mySize_y;
2869
2870                 kh_size_x = mySize_x * 0.5;
2871                 kh_size_y = 0.375 * mySize_y;
2872                 kh_asize_x = mySize_x * 0.5;
2873                 kh_asize_y = mySize_y * 0.125;
2874         }
2875
2876         float i, key;
2877
2878         float keycount;
2879         keycount = 0;
2880         for(i = 0; i < 4; ++i)
2881         {
2882                 key = floor(kh_keys / pow(32, i)) & 31;
2883                 keyteam = key - 1;
2884                 if(keyteam == 30 && keycount <= 4)
2885                         keycount += 4;
2886                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2887                         keycount += 1;
2888         }
2889
2890         // this yields 8 exactly if "RUN HERE" shows
2891
2892         if(keycount == 8)
2893         {
2894                 if(!kh_runheretime)
2895                         kh_runheretime = time;
2896                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
2897         }
2898         else
2899                 kh_runheretime = 0;
2900
2901         for(i = 0; i < 4; ++i)
2902         {
2903                 key = floor(kh_keys / pow(32, i)) & 31;
2904                 keyteam = key - 1;
2905                 switch(keyteam)
2906                 {
2907                         case 30: // my key
2908                                 keyteam = myteam;
2909                                 a = 1;
2910                                 aa = 1;
2911                                 break;
2912                         case -1: // no key
2913                                 a = 0;
2914                                 aa = 0;
2915                                 break;
2916                         default: // owned or dropped
2917                                 a = 0.2;
2918                                 aa = 0.5;
2919                                 break;
2920                 }
2921                 a = a * panel_fg_alpha;
2922                 aa = aa * panel_fg_alpha;
2923                 if(a > 0)
2924                 {
2925                         switch(keyteam)
2926                         {
2927                                 case NUM_TEAM_1:
2928                                         drawpic_aspect_skin(pa, "kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2929                                         break;
2930                                 case NUM_TEAM_2:
2931                                         drawpic_aspect_skin(pa, "kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2932                                         break;
2933                                 case NUM_TEAM_3:
2934                                         drawpic_aspect_skin(pa, "kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2935                                         break;
2936                                 case NUM_TEAM_4:
2937                                         drawpic_aspect_skin(pa, "kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2938                                         break;
2939                                 default:
2940                                         break;
2941                         }
2942                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
2943                         {
2944                                 case 0:
2945                                         drawpic_aspect_skin(p, "kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2946                                         break;
2947                                 case 1:
2948                                         drawpic_aspect_skin(p, "kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2949                                         break;
2950                                 case 2:
2951                                         drawpic_aspect_skin(p, "kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2952                                         break;
2953                                 case 3:
2954                                         drawpic_aspect_skin(p, "kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2955                                         break;
2956                         }
2957                 }
2958                 if(mySize_x > mySize_y)
2959                 {
2960                         p_x += 0.25 * mySize_x;
2961                         pa_x += 0.25 * mySize_x;
2962                 }
2963                 else
2964                 {
2965                         if(i == 1)
2966                         {
2967                                 p_y = pos_y + 0.625 * mySize_y;
2968                                 pa_y = pos_y + 0.5 * mySize_y;
2969                                 p_x = pos_x;
2970                                 pa_x = pos_x;
2971                         }
2972                         else
2973                         {
2974                                 p_x += 0.5 * mySize_x;
2975                                 pa_x += 0.5 * mySize_x;
2976                         }
2977                 }
2978         }
2979 }
2980
2981 // Keepaway HUD mod icon
2982 float kaball_prevstatus; // last remembered status
2983 float kaball_statuschange_time; // time when the status changed
2984
2985 // we don't need to reset for keepaway since it immediately
2986 // autocorrects prevstatus as to if the player has the ball or not
2987
2988 void HUD_Mod_Keepaway(vector pos, vector mySize)
2989 {
2990         mod_active = 1; // keepaway should always show the mod HUD
2991
2992         float BLINK_FACTOR = 0.15;
2993         float BLINK_BASE = 0.85;
2994         float BLINK_FREQ = 5;
2995         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
2996
2997         float stat_items = getstati(STAT_ITEMS, 0, 24);
2998         float kaball = (stat_items/IT_KEY1) & 1;
2999
3000         if(kaball != kaball_prevstatus)
3001         {
3002                 kaball_statuschange_time = time;
3003                 kaball_prevstatus = kaball;
3004         }
3005
3006         vector kaball_pos, kaball_size;
3007
3008         if(mySize_x > mySize_y) {
3009                 kaball_pos = pos + eX * 0.25 * mySize_x;
3010                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
3011         } else {
3012                 kaball_pos = pos + eY * 0.25 * mySize_y;
3013                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3014         }
3015
3016         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3017         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3018
3019         if(kaball_prevstatus && f < 1)
3020                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3021
3022         if(kaball)
3023                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3024 }
3025
3026
3027 // Nexball HUD mod icon
3028 void HUD_Mod_NexBall(vector pos, vector mySize)
3029 {
3030         float stat_items, nb_pb_starttime, dt, p;
3031
3032         stat_items = getstati(STAT_ITEMS, 0, 24);
3033         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3034
3035         if (stat_items & IT_KEY1)
3036                 mod_active = 1;
3037         else
3038                 mod_active = 0;
3039
3040         //Manage the progress bar if any
3041         if (nb_pb_starttime > 0)
3042         {
3043                 dt = mod(time - nb_pb_starttime, nb_pb_period);
3044                 // one period of positive triangle
3045                 p = 2 * dt / nb_pb_period;
3046                 if (p > 1)
3047                         p = 2 - p;
3048
3049                 //Draw the filling
3050                 HUD_Panel_GetProgressBarColor(nexball);
3051                 if(mySize_x > mySize_y)
3052                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, 0, 0, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3053                 else
3054                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, 1, 0, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3055         }
3056
3057         if (stat_items & IT_KEY1)
3058                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3059 }
3060
3061 // Race/CTS HUD mod icons
3062 float crecordtime_prev; // last remembered crecordtime
3063 float crecordtime_change_time; // time when crecordtime last changed
3064 float srecordtime_prev; // last remembered srecordtime
3065 float srecordtime_change_time; // time when srecordtime last changed
3066
3067 float race_status_time;
3068 float race_status_prev;
3069 string race_status_name_prev;
3070 void HUD_Mod_Race(vector pos, vector mySize)
3071 {
3072         mod_active = 1; // race should never hide the mod icons panel
3073         entity me;
3074         me = playerslots[player_localnum];
3075         float t, score;
3076         float f; // yet another function has this
3077         score = me.(scores[ps_primary]);
3078
3079         if not((scores_flags[ps_primary] & SFL_TIME) && !teamplay) // race/cts record display on HUD
3080                 return; // no records in the actual race
3081
3082         // clientside personal record
3083         string rr;
3084         if(gametype == MAPINFO_TYPE_CTS)
3085                 rr = CTS_RECORD;
3086         else
3087                 rr = RACE_RECORD;
3088         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3089
3090         if(score && (score < t || !t)) {
3091                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3092                 if(autocvar_cl_autodemo_delete_keeprecords)
3093                 {
3094                         f = autocvar_cl_autodemo_delete;
3095                         f &~= 1;
3096                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3097                 }
3098         }
3099
3100         if(t != crecordtime_prev) {
3101                 crecordtime_prev = t;
3102                 crecordtime_change_time = time;
3103         }
3104
3105         vector textPos, medalPos;
3106         float squareSize;
3107         if(mySize_x > mySize_y) {
3108                 // text on left side
3109                 squareSize = min(mySize_y, mySize_x/2);
3110                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3111                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3112         } else {
3113                 // text on top
3114                 squareSize = min(mySize_x, mySize_y/2);
3115                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3116                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3117         }
3118
3119         f = time - crecordtime_change_time;
3120
3121         if (f > 1) {
3122                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3123                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3124         } else {
3125                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3126                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3127                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3128                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3129         }
3130
3131         // server record
3132         t = race_server_record;
3133         if(t != srecordtime_prev) {
3134                 srecordtime_prev = t;
3135                 srecordtime_change_time = time;
3136         }
3137         f = time - srecordtime_change_time;
3138
3139         if (f > 1) {
3140                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3141                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3142         } else {
3143                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3144                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3145                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3146                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3147         }
3148
3149         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3150                 race_status_time = time + 5;
3151                 race_status_prev = race_status;
3152                 if (race_status_name_prev)
3153                         strunzone(race_status_name_prev);
3154                 race_status_name_prev = strzone(race_status_name);
3155         }
3156
3157         // race "awards"
3158         float a;
3159         a = bound(0, race_status_time - time, 1);
3160
3161         string s;
3162         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3163
3164         float rank;
3165         if(race_status > 0)
3166                 rank = race_CheckName(race_status_name);
3167         else
3168                 rank = 0;
3169         string rankname;
3170         rankname = count_ordinal(rank);
3171
3172         vector namepos;
3173         namepos = medalPos + '0 0.8 0' * squareSize;
3174         vector rankpos;
3175         rankpos = medalPos + '0 0.15 0' * squareSize;
3176
3177         if(race_status == 0)
3178                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3179         else if(race_status == 1) {
3180                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3181                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3182                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3183         } else if(race_status == 2) {
3184                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3185                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3186                 else
3187                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3188                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3189                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3190         } else if(race_status == 3) {
3191                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3192                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3193                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3194         }
3195
3196         if (race_status_time - time <= 0) {
3197                 race_status_prev = -1;
3198                 race_status = -1;
3199                 if(race_status_name)
3200                         strunzone(race_status_name);
3201                 race_status_name = string_null;
3202                 if(race_status_name_prev)
3203                         strunzone(race_status_name_prev);
3204                 race_status_name_prev = string_null;
3205         }
3206 }
3207
3208 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3209 {
3210         float stat, pps_ratio;
3211         string pic;
3212         vector color;
3213 #ifdef GMQCC
3214         stat = -1;
3215         pic = "";
3216         color = '0 0 0';
3217 #endif
3218         switch(i)
3219         {
3220                 case 0:
3221                         stat = getstatf(STAT_DOM_PPS_RED);
3222                         pic = "dom_icon_red";
3223                         color = '1 0 0';
3224                         break;
3225                 case 1:
3226                         stat = getstatf(STAT_DOM_PPS_BLUE);
3227                         pic = "dom_icon_blue";
3228                         color = '0 0 1';
3229                         break;
3230                 case 2:
3231                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3232                         pic = "dom_icon_yellow";
3233                         color = '1 1 0';
3234                         break;
3235                 default:
3236                 case 3:
3237                         stat = getstatf(STAT_DOM_PPS_PINK);
3238                         pic = "dom_icon_pink";
3239                         color = '1 0 1';
3240                         break;
3241         }
3242         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3243
3244         if(mySize_x/mySize_y > aspect_ratio)
3245         {
3246                 i = aspect_ratio * mySize_y;
3247                 myPos_x = myPos_x + (mySize_x - i) / 2;
3248                 mySize_x = i;
3249         }
3250         else
3251         {
3252                 i = 1/aspect_ratio * mySize_x;
3253                 myPos_y = myPos_y + (mySize_y - i) / 2;
3254                 mySize_y = i;
3255         }
3256
3257         if (layout) // show text too
3258         {
3259                 //draw the text
3260                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3261                 if (layout == 2) // average pps
3262                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3263                 else // percentage of average pps
3264                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3265         }
3266
3267         //draw the icon
3268         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3269         if (stat > 0)
3270         {
3271                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3272                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3273                 drawresetcliparea();
3274         }
3275 }
3276
3277 void HUD_Mod_Dom(vector myPos, vector mySize)
3278 {
3279         mod_active = 1; // required in each mod function that always shows something
3280         entity tm;
3281         float teams_count = 0;
3282         for(tm = teams.sort_next; tm; tm = tm.sort_next)
3283                 if(tm.team != NUM_SPECTATOR)
3284                         ++teams_count;
3285
3286         float layout = autocvar_hud_panel_modicons_dom_layout;
3287         float rows, columns, aspect_ratio;
3288         rows = mySize_y/mySize_x;
3289         aspect_ratio = (layout) ? 3 : 1;
3290         rows = bound(1, floor((sqrt((4 * aspect_ratio * teams_count + rows) * rows) + rows + 0.5) / 2), teams_count);
3291         columns = ceil(teams_count/rows);
3292
3293         int i;
3294         float row = 0, column = 0;
3295         for(i=0; i<teams_count; ++i)
3296         {
3297                 vector pos, itemSize;
3298                 pos = myPos + eX * column * mySize_x*(1/columns) + eY * row * mySize_y*(1/rows);
3299                 itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3300
3301                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3302
3303                 ++row;
3304                 if(row >= rows)
3305                 {
3306                         row = 0;
3307                         ++column;
3308                 }
3309         }
3310 }
3311
3312 float mod_prev; // previous state of mod_active to check for a change
3313 float mod_alpha;
3314 float mod_change; // "time" when mod_active changed
3315
3316 void HUD_ModIcons(void)
3317 {
3318         if(!autocvar__hud_configure)
3319         {
3320                 if(!autocvar_hud_panel_modicons) return;
3321                 if (gametype != MAPINFO_TYPE_CTF && gametype != MAPINFO_TYPE_KEYHUNT && gametype != MAPINFO_TYPE_NEXBALL && gametype != MAPINFO_TYPE_CTS && gametype != MAPINFO_TYPE_RACE && gametype != MAPINFO_TYPE_CA && gametype != MAPINFO_TYPE_FREEZETAG && gametype != MAPINFO_TYPE_KEEPAWAY && gametype != MAPINFO_TYPE_DOMINATION) return;
3322         }
3323         else
3324                 hud_configure_active_panel = HUD_PANEL_MODICONS;
3325
3326         HUD_Panel_UpdateCvars(modicons);
3327         HUD_Panel_ApplyFadeAlpha();
3328
3329         draw_beginBoldFont();
3330
3331         vector pos, mySize;
3332         pos = panel_pos;
3333         mySize = panel_size;
3334
3335         if(mod_active != mod_prev) {
3336                 mod_change = time;
3337                 mod_prev = mod_active;
3338         }
3339
3340         if(mod_active || autocvar__hud_configure)
3341                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3342         else
3343                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3344
3345         if(mod_alpha)
3346                 HUD_Panel_DrawBg(mod_alpha);
3347
3348         if(panel_bg_padding)
3349         {
3350                 pos += '1 1 0' * panel_bg_padding;
3351                 mySize -= '2 2 0' * panel_bg_padding;
3352         }
3353
3354         // these MUST be ran in order to update mod_active
3355         if(gametype == MAPINFO_TYPE_KEYHUNT)
3356                 HUD_Mod_KH(pos, mySize);
3357         else if(gametype == MAPINFO_TYPE_CTF || autocvar__hud_configure)
3358                 HUD_Mod_CTF(pos, mySize); // forcealpha only needed for ctf icons, as only they are shown in config mode
3359         else if(gametype == MAPINFO_TYPE_NEXBALL)
3360                 HUD_Mod_NexBall(pos, mySize);
3361         else if(gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE)
3362                 HUD_Mod_Race(pos, mySize);
3363         else if(gametype == MAPINFO_TYPE_CA || gametype == MAPINFO_TYPE_FREEZETAG)
3364                 HUD_Mod_CA(pos, mySize);
3365         else if(gametype == MAPINFO_TYPE_DOMINATION)
3366                 HUD_Mod_Dom(pos, mySize);
3367         else if(gametype == MAPINFO_TYPE_KEEPAWAY)
3368                 HUD_Mod_Keepaway(pos, mySize);
3369
3370         draw_endBoldFont();
3371 }
3372
3373 // Draw pressed keys (#11)
3374 //
3375 void HUD_DrawPressedKeys(void)
3376 {
3377         if(!autocvar__hud_configure)
3378         {
3379                 if(!autocvar_hud_panel_pressedkeys) return;
3380                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3381         }
3382         else
3383                 hud_configure_active_panel = HUD_PANEL_PRESSEDKEYS;
3384
3385
3386         HUD_Panel_UpdateCvars(pressedkeys);
3387         HUD_Panel_ApplyFadeAlpha();
3388         vector pos, mySize;
3389         pos = panel_pos;
3390         mySize = panel_size;
3391
3392         HUD_Panel_DrawBg(1);
3393         if(panel_bg_padding)
3394         {
3395                 pos += '1 1 0' * panel_bg_padding;
3396                 mySize -= '2 2 0' * panel_bg_padding;
3397         }
3398
3399         // force custom aspect
3400         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3401         if(aspect)
3402         {
3403                 vector newSize = '0 0 0';
3404                 if(mySize_x/mySize_y > aspect)
3405                 {
3406                         newSize_x = aspect * mySize_y;
3407                         newSize_y = mySize_y;
3408
3409                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3410                 }
3411                 else
3412                 {
3413                         newSize_y = 1/aspect * mySize_x;
3414                         newSize_x = mySize_x;
3415
3416                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3417                 }
3418                 mySize = newSize;
3419         }
3420
3421         vector keysize;
3422         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3423         float pressedkeys;
3424         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3425
3426         if(autocvar_hud_panel_pressedkeys_attack)
3427         {
3428                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3429                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3430                 pos_y += keysize_y;
3431         }
3432
3433         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3434         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3435         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3436         pos_y += keysize_y;
3437         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3438         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3439         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3440 }
3441
3442 // Handle chat as a panel (#12)
3443 //
3444 void HUD_Chat(void)
3445 {
3446         if(!autocvar__hud_configure)
3447         {
3448                 if (!autocvar_hud_panel_chat)
3449                 {
3450                         if (!autocvar_con_chatrect)
3451                                 cvar_set("con_chatrect", "0");
3452                         return;
3453                 }
3454                 if(autocvar__con_chat_maximized)
3455                         if(!hud_draw_maximized) return;
3456         }
3457         else
3458                 hud_configure_active_panel = HUD_PANEL_CHAT;
3459
3460         HUD_Panel_UpdateCvars(chat);
3461         HUD_Panel_ApplyFadeAlpha();
3462
3463         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3464         {
3465                 panel_pos_y = panel_bg_border;
3466                 panel_size_y = vid_conheight - panel_bg_border * 2;
3467                 if(panel_bg == "0") // force a border when maximized
3468                 {
3469                         if(precache_pic(panel_bg) == "") {
3470                                 panel_bg = strcat(hud_skin_path, "/border_default");
3471                                 if(precache_pic(panel_bg) == "") {
3472                                         panel_bg = "gfx/hud/default/border_default";
3473                                 }
3474                         }
3475                 }
3476                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3477         }
3478
3479         vector pos, mySize;
3480         pos = panel_pos;
3481         mySize = panel_size;
3482
3483         HUD_Panel_DrawBg(1);
3484
3485         if(panel_bg_padding)
3486         {
3487                 pos += '1 1 0' * panel_bg_padding;
3488                 mySize -= '2 2 0' * panel_bg_padding;
3489         }
3490
3491         if (!autocvar_con_chatrect)
3492                 cvar_set("con_chatrect", "1");
3493
3494         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3495         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3496
3497         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3498         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3499
3500         if(autocvar__hud_configure)
3501         {
3502                 vector chatsize;
3503                 chatsize = '1 1 0' * autocvar_con_chatsize;
3504                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3505                 float i, a;
3506                 for(i = 0; i < autocvar_con_chat; ++i)
3507                 {
3508                         if(i == autocvar_con_chat - 1)
3509                                 a = panel_fg_alpha;
3510                         else
3511                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3512                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3513                         pos_y += chatsize_y;
3514                 }
3515         }
3516 }
3517
3518 // Engine info panel (#13)
3519 //
3520 float prevfps;
3521 float prevfps_time;
3522 float framecounter;
3523
3524 float frametimeavg;
3525 float frametimeavg1; // 1 frame ago
3526 float frametimeavg2; // 2 frames ago
3527 void HUD_EngineInfo(void)
3528 {
3529         if(!autocvar__hud_configure)
3530         {
3531                 if(!autocvar_hud_panel_engineinfo) return;
3532         }
3533         else
3534                 hud_configure_active_panel = HUD_PANEL_ENGINEINFO;
3535
3536         HUD_Panel_UpdateCvars(engineinfo);
3537         HUD_Panel_ApplyFadeAlpha();
3538         vector pos, mySize;
3539         pos = panel_pos;
3540         mySize = panel_size;
3541
3542         HUD_Panel_DrawBg(1);
3543         if(panel_bg_padding)
3544         {
3545                 pos += '1 1 0' * panel_bg_padding;
3546                 mySize -= '2 2 0' * panel_bg_padding;
3547         }
3548
3549         float currentTime = gettime(GETTIME_REALTIME);
3550         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3551         {
3552                 float currentframetime = currentTime - prevfps_time;
3553                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3554                 frametimeavg2 = frametimeavg1;
3555                 frametimeavg1 = frametimeavg;
3556
3557                 float weight;
3558                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3559                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3560                 {
3561                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3562                                 prevfps = (1/currentframetime);
3563                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3564                 }
3565                 prevfps_time = currentTime;
3566         }
3567         else
3568         {
3569                 framecounter += 1;
3570                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3571                 {
3572                         prevfps = framecounter/(currentTime - prevfps_time);
3573                         framecounter = 0;
3574                         prevfps_time = currentTime;
3575                 }
3576         }
3577
3578         vector color;
3579         color = HUD_Get_Num_Color (prevfps, 100);
3580         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3581 }
3582
3583 // Info messages panel (#14)
3584 //
3585 #define drawInfoMessage(s)\
3586         if(autocvar_hud_panel_infomessages_flip)\
3587                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3588         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3589         o_y += fontsize_y;
3590 void HUD_InfoMessages(void)
3591 {
3592         if(!autocvar__hud_configure)
3593         {
3594                 if(!autocvar_hud_panel_infomessages) return;
3595         }
3596         else
3597                 hud_configure_active_panel = HUD_PANEL_INFOMESSAGES;
3598
3599         HUD_Panel_UpdateCvars(infomessages);
3600         HUD_Panel_ApplyFadeAlpha();
3601         vector pos, mySize;
3602         pos = panel_pos;
3603         mySize = panel_size;
3604
3605         HUD_Panel_DrawBg(1);
3606         if(panel_bg_padding)
3607         {
3608                 pos += '1 1 0' * panel_bg_padding;
3609                 mySize -= '2 2 0' * panel_bg_padding;
3610         }
3611
3612         // always force 5:1 aspect
3613         vector newSize = '0 0 0';
3614         if(mySize_x/mySize_y > 5)
3615         {
3616                 newSize_x = 5 * mySize_y;
3617                 newSize_y = mySize_y;
3618
3619                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3620         }
3621         else
3622         {
3623                 newSize_y = 1/5 * mySize_x;
3624                 newSize_x = mySize_x;
3625
3626                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3627         }
3628
3629         mySize = newSize;
3630         entity tm;
3631         vector o;
3632         o = pos;
3633
3634         vector fontsize;
3635         fontsize = '0.20 0.20 0' * mySize_y;
3636
3637         float a;
3638         a = panel_fg_alpha;
3639
3640         string s;
3641         if(!autocvar__hud_configure)
3642         {
3643                 if(spectatee_status && !intermission)
3644                 {
3645                         a = 1;
3646                         if(spectatee_status == -1)
3647                                 s = _("^1Observing");
3648                         else
3649 #ifdef COMPAT_XON050_ENGINE
3650                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(spectatee_status - 1));
3651 #else
3652                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3653 #endif
3654                         drawInfoMessage(s)
3655
3656                         if(spectatee_status == -1)
3657                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3658                         else
3659                                 s = sprintf(_("^1Press ^3%s^1 for another player"), getcommandkey("primary fire", "+fire"));
3660                         drawInfoMessage(s)
3661
3662                         if(spectatee_status == -1)
3663                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3664                         else
3665                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3666                         drawInfoMessage(s)
3667
3668                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3669                         drawInfoMessage(s)
3670
3671                         if(gametype == MAPINFO_TYPE_ARENA)
3672                                 s = _("^1Wait for your turn to join");
3673                         else if(gametype == MAPINFO_TYPE_LMS)
3674                         {
3675                                 entity sk;
3676                                 sk = playerslots[player_localnum];
3677                                 if(sk.(scores[ps_primary]) >= 666)
3678                                         s = _("^1Match has already begun");
3679                                 else if(sk.(scores[ps_primary]) > 0)
3680                                         s = _("^1You have no more lives left");
3681                                 else
3682                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3683                         }
3684                         else
3685                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3686                         drawInfoMessage(s)
3687
3688                         //show restart countdown:
3689                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3690                                 float countdown;
3691                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3692                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3693                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3694                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3695                                 o_y += fontsize_y;
3696                         }
3697                 }
3698                 if(warmup_stage && !intermission)
3699                 {
3700                         s = _("^2Currently in ^1warmup^2 stage!");
3701                         drawInfoMessage(s)
3702                 }
3703
3704                 string blinkcolor;
3705                 if(mod(time, 1) >= 0.5)
3706                         blinkcolor = "^1";
3707                 else
3708                         blinkcolor = "^3";
3709
3710                 if(ready_waiting && !intermission && !spectatee_status)
3711                 {
3712                         if(ready_waiting_for_me)
3713                         {
3714                                 if(warmup_stage)
3715                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3716                                 else
3717                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3718                         }
3719                         else
3720                         {
3721                                 if(warmup_stage)
3722                                         s = _("^2Waiting for others to ready up to end warmup...");
3723                                 else
3724                                         s = _("^2Waiting for others to ready up...");
3725                         }
3726                         drawInfoMessage(s)
3727                 }
3728                 else if(warmup_stage && !intermission && !spectatee_status)
3729                 {
3730                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3731                         drawInfoMessage(s)
3732                 }
3733
3734                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3735                 {
3736                         float ts_min = 0, ts_max = 0;
3737                         tm = teams.sort_next;
3738                         if (tm)
3739                         {
3740                                 for(; tm.sort_next; tm = tm.sort_next)
3741                                 {
3742                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3743                                                 continue;
3744                                         if(!ts_min) ts_min = tm.team_size;
3745                                         else ts_min = min(ts_min, tm.team_size);
3746                                         if(!ts_max) ts_max = tm.team_size;
3747                                         else ts_max = max(ts_max, tm.team_size);
3748                                 }
3749                                 if ((ts_max - ts_min) > 1)
3750                                 {
3751                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3752                                         tm = GetTeam(myteam, false);
3753                                         if (tm)
3754                                         if (tm.team != NUM_SPECTATOR)
3755                                         if (tm.team_size == ts_max)
3756                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3757                                         drawInfoMessage(s)
3758                                 }
3759                         }
3760                 }
3761         }
3762         else
3763         {
3764                 s = _("^7Press ^3ESC ^7to show HUD options.");
3765                 drawInfoMessage(s)
3766                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3767                 drawInfoMessage(s)
3768                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3769                 drawInfoMessage(s)
3770                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3771                 drawInfoMessage(s)
3772         }
3773 }
3774
3775 // Physics panel (#15)
3776 //
3777 vector acc_prevspeed;
3778 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3779 void HUD_Physics(void)
3780 {
3781         if(!autocvar__hud_configure)
3782         {
3783                 if(!autocvar_hud_panel_physics) return;
3784                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3785                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3786         }
3787         else
3788                 hud_configure_active_panel = HUD_PANEL_PHYSICS;
3789
3790         HUD_Panel_UpdateCvars(physics);
3791         HUD_Panel_ApplyFadeAlpha();
3792
3793         draw_beginBoldFont();
3794
3795         HUD_Panel_DrawBg(1);
3796         if(panel_bg_padding)
3797         {
3798                 panel_pos += '1 1 0' * panel_bg_padding;
3799                 panel_size -= '2 2 0' * panel_bg_padding;
3800         }
3801
3802         float acceleration_progressbar_scale = 0;
3803         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3804                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3805
3806         float text_scale;
3807         if (autocvar_hud_panel_physics_text_scale <= 0)
3808                 text_scale = 1;
3809         else
3810                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3811
3812         //compute speed
3813         float speed, conversion_factor;
3814         string unit;
3815
3816         switch(autocvar_hud_panel_physics_speed_unit)
3817         {
3818                 default:
3819                 case 1:
3820                         unit = _(" qu/s");
3821                         conversion_factor = 1.0;
3822                         break;
3823                 case 2:
3824                         unit = _(" m/s");
3825                         conversion_factor = 0.0254;
3826                         break;
3827                 case 3:
3828                         unit = _(" km/h");
3829                         conversion_factor = 0.0254 * 3.6;
3830                         break;
3831                 case 4:
3832                         unit = _(" mph");
3833                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3834                         break;
3835                 case 5:
3836                         unit = _(" knots");
3837                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3838                         break;
3839         }
3840
3841         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3842
3843         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3844         if (autocvar__hud_configure)
3845                 speed = floor( max_speed * 0.65 + 0.5 );
3846         else if(autocvar_hud_panel_physics_speed_vertical)
3847                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3848         else
3849                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3850
3851         //compute acceleration
3852         float acceleration, f;
3853         if (autocvar__hud_configure)
3854                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3855         else
3856         {
3857                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3858                 f = time - acc_prevtime;
3859                 if(autocvar_hud_panel_physics_acceleration_vertical)
3860                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3861                 else
3862                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3863
3864                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3865
3866                 acc_prevspeed = vel;
3867                 acc_prevtime = time;
3868
3869                 f = bound(0, f * 10, 1);
3870                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3871         }
3872
3873         //compute layout
3874         float panel_ar = panel_size_x/panel_size_y;
3875         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3876         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3877         {
3878                 panel_size_x *= 0.5;
3879                 if (autocvar_hud_panel_physics_flip)
3880                         speed_offset_x = panel_size_x;
3881                 else
3882                         acceleration_offset_x = panel_size_x;
3883         }
3884         else
3885         {
3886                 panel_size_y *= 0.5;
3887                 if (autocvar_hud_panel_physics_flip)
3888                         speed_offset_y = panel_size_y;
3889                 else
3890                         acceleration_offset_y = panel_size_y;
3891         }
3892         float speed_baralign, acceleration_baralign;
3893         if (autocvar_hud_panel_physics_baralign == 1)
3894                 acceleration_baralign = speed_baralign = 1;
3895     else if(autocvar_hud_panel_physics_baralign == 4)
3896                 acceleration_baralign = speed_baralign = 2;
3897         else if (autocvar_hud_panel_physics_flip)
3898         {
3899                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3900                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3901         }
3902         else
3903         {
3904                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3905                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3906         }
3907         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3908                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3909
3910         //draw speed
3911         if(speed)
3912         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3913         {
3914                 HUD_Panel_GetProgressBarColor(speed);
3915                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3916         }
3917         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3918         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3919         {
3920                 tmp_size_x = panel_size_x * 0.75;
3921                 tmp_size_y = panel_size_y * text_scale;
3922                 if (speed_baralign)
3923                         tmp_offset_x = panel_size_x - tmp_size_x;
3924                 //else
3925                         //tmp_offset_x = 0;
3926                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3927                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3928
3929                 //draw speed unit
3930                 if (speed_baralign)
3931                         tmp_offset_x = 0;
3932                 else
3933                         tmp_offset_x = tmp_size_x;
3934                 if (autocvar_hud_panel_physics_speed_unit_show)
3935                 {
3936                         //tmp_offset_y = 0;
3937                         tmp_size_x = panel_size_x * (1 - 0.75);
3938                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3939                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3940                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3941                 }
3942         }
3943
3944         //compute and draw top speed
3945         if (autocvar_hud_panel_physics_topspeed)
3946         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3947         {
3948                 if (autocvar__hud_configure)
3949                 {
3950                         top_speed = floor( max_speed * 0.75 + 0.5 );
3951                         f = 1;
3952                 }
3953                 else
3954                 {
3955                         if (speed >= top_speed)
3956                         {
3957                                 top_speed = speed;
3958                                 top_speed_time = time;
3959                         }
3960                         if (top_speed != 0)
3961                         {
3962                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3963                                 // divide by f to make it start from 1
3964                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3965                         }
3966             else //hide top speed 0, it would be stupid
3967                                 f = 0;
3968                 }
3969                 if (f > 0)
3970                 {
3971                         //top speed progressbar peak
3972                         if(speed < top_speed)
3973                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3974                         {
3975                                 float peak_offset_x;
3976                                 vector peak_size = '0 0 0';
3977                                 if (speed_baralign == 0)
3978                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
3979                 else if (speed_baralign == 1)
3980                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
3981                 else // if (speed_baralign == 2)
3982                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
3983                                 //if speed is not 0 the speed progressbar already fetched the color
3984                                 if (speed == 0)
3985                                         HUD_Panel_GetProgressBarColor(speed);
3986                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
3987                 peak_size_y = panel_size_y;
3988                 if (speed_baralign == 2) // draw two peaks, on both sides
3989                 {
3990                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, progressbar_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3991                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, progressbar_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3992                 }
3993                 else
3994                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, progressbar_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3995                         }
3996
3997                         //top speed
3998                         tmp_offset_y = panel_size_y * 0.4;
3999                         tmp_size_x = panel_size_x * (1 - 0.75);
4000                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
4001                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
4002                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4003                 }
4004                 else
4005                         top_speed = 0;
4006         }
4007
4008         //draw acceleration
4009         if(acceleration)
4010         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4011         {
4012                 if (acceleration < 0)
4013                         HUD_Panel_GetProgressBarColor(acceleration_neg);
4014                 else
4015                         HUD_Panel_GetProgressBarColor(acceleration);
4016
4017                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4018                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4019                         f = sqrt(f);
4020
4021                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4022                 {
4023                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
4024
4025                         if (acceleration_baralign == 1)
4026                                 tmp_offset_x = panel_size_x - tmp_size_x;
4027                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4028                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
4029                         else
4030                                 tmp_offset_x = 0;
4031                         tmp_offset_y = 0;
4032                 }
4033                 else
4034                 {
4035                         tmp_size = panel_size;
4036                         tmp_offset = '0 0 0';
4037                 }
4038
4039                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4040         }
4041         tmp_size_x = panel_size_x;
4042         tmp_size_y = panel_size_y * text_scale;
4043         tmp_offset_x = 0;
4044         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4045         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4046                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4047
4048         draw_endBoldFont();
4049 }
4050
4051 // CenterPrint (#16)
4052 //
4053 #define CENTERPRINT_MAX_MSGS 10
4054 #define CENTERPRINT_MAX_ENTRIES 50
4055 #define CENTERPRINT_SPACING 0.7
4056 float cpm_index;
4057 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4058 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4059 float centerprint_time[CENTERPRINT_MAX_MSGS];
4060 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4061 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4062 float centerprint_showing;
4063
4064 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4065 {
4066         //print(sprintf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num));
4067         float i, j;
4068
4069         if(strMessage == "" && new_id == 0)
4070                 return;
4071
4072         // strip trailing newlines
4073         j = strlen(strMessage) - 1;
4074         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4075                 --j;
4076         if (j < strlen(strMessage) - 1)
4077                 strMessage = substring(strMessage, 0, j + 1);
4078
4079         if(strMessage == "" && new_id == 0)
4080                 return;
4081
4082         // strip leading newlines
4083         j = 0;
4084         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4085                 ++j;
4086         if (j > 0)
4087                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4088
4089         if(strMessage == "" && new_id == 0)
4090                 return;
4091
4092         if (!centerprint_showing)
4093                 centerprint_showing = TRUE;
4094
4095         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4096         {
4097                 if (j == CENTERPRINT_MAX_MSGS)
4098                         j = 0;
4099                 if (new_id && new_id == centerprint_msgID[j])
4100                 {
4101                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4102                         {
4103                                 // fade out the current msg (duration and countdown_num are ignored)
4104                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4105                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4106                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4107                                 return;
4108                         }
4109                         break; // found a msg with the same id, at position j
4110                 }
4111         }
4112
4113         if (i == CENTERPRINT_MAX_MSGS)
4114         {
4115                 // a msg with the same id was not found, add the msg at the next position
4116                 --cpm_index;
4117                 if (cpm_index == -1)
4118                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4119                 j = cpm_index;
4120         }
4121         if(centerprint_messages[j])
4122                 strunzone(centerprint_messages[j]);
4123         centerprint_messages[j] = strzone(strMessage);
4124         centerprint_msgID[j] = new_id;
4125         if (duration < 0)
4126         {
4127                 centerprint_time[j] = -1;
4128                 centerprint_expire_time[j] = time;
4129         }
4130         else
4131         {
4132                 if(duration == 0)
4133                         duration = max(1, autocvar_hud_panel_centerprint_time);
4134                 centerprint_time[j] = duration;
4135                 centerprint_expire_time[j] = time + duration;
4136         }
4137         centerprint_countdown_num[j] = countdown_num;
4138 }
4139
4140 void centerprint_hud(string strMessage)
4141 {
4142         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4143 }
4144
4145 void reset_centerprint_messages(void)
4146 {
4147         float i;
4148         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4149         {
4150                 centerprint_expire_time[i] = 0;
4151                 centerprint_time[i] = 1;
4152                 centerprint_msgID[i] = 0;
4153                 if(centerprint_messages[i])
4154                         strunzone(centerprint_messages[i]);
4155                 centerprint_messages[i] = string_null;
4156         }
4157 }
4158 float hud_configure_cp_generation_time;
4159 void HUD_CenterPrint (void)
4160 {
4161         if(!autocvar__hud_configure)
4162         {
4163                 if(!autocvar_hud_panel_centerprint) return;
4164
4165                 if (hud_configure_prev && hud_configure_prev != -1)
4166                         reset_centerprint_messages();
4167         }
4168         else
4169         {
4170                 hud_configure_active_panel = HUD_PANEL_CENTERPRINT;
4171
4172                 if (!hud_configure_prev)
4173                         reset_centerprint_messages();
4174                 if (time > hud_configure_cp_generation_time)
4175                 {
4176                         float r;
4177                         r = random();
4178                         if (r > 0.9)
4179                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: %d"), 1, 10);
4180                         else if (r > 0.8)
4181                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4182                         else
4183                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4184                         hud_configure_cp_generation_time = time + 1 + random()*4;
4185                 }
4186         }
4187
4188         HUD_Panel_UpdateCvars(centerprint);
4189
4190         // this panel doesn't fade when showing the scoreboard
4191         if(autocvar__menu_alpha)
4192                 HUD_Panel_ApplyFadeAlpha();
4193
4194         if(scoreboard_fade_alpha)
4195         {
4196                 // move the panel below the scoreboard
4197                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4198                         return;
4199                 vector target_pos;
4200
4201                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4202
4203                 if(target_pos_y > panel_pos_y)
4204                 {
4205                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4206                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4207                 }
4208         }
4209
4210         HUD_Panel_DrawBg(1);
4211
4212         if (!centerprint_showing)
4213                 return;
4214
4215         if(panel_bg_padding)
4216         {
4217                 panel_pos += '1 1 0' * panel_bg_padding;
4218                 panel_size -= '2 2 0' * panel_bg_padding;
4219         }
4220
4221         float entries, height;
4222         vector fontsize;
4223         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4224         // height = panel_size_y/entries;
4225         // fontsize = '1 1 0' * height;
4226         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4227         fontsize = '1 1 0' * height;
4228         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4229
4230         float i, j, k, n, g;
4231         float a, sz, align, current_msg_pos_y = 0, msg_size;
4232         vector pos;
4233         string ts;
4234
4235         n = -1; // if no msg will be displayed, n stays -1
4236
4237         pos = panel_pos;
4238         if (autocvar_hud_panel_centerprint_flip)
4239                 pos_y += panel_size_y;
4240         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4241         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4242         {
4243                 if (j == CENTERPRINT_MAX_MSGS)
4244                         j = 0;
4245                 if (centerprint_expire_time[j] <= time)
4246                 {
4247                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4248                         {
4249                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4250                                 if (centerprint_countdown_num[j] == 0)
4251                                         continue;
4252                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4253                         }
4254                         else if(centerprint_time[j] != -1)
4255                                 continue;
4256                 }
4257
4258
4259                 // fade the centerprint_hud in/out
4260                 if(centerprint_time[j] < 0)
4261                         a = bound(0, (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in), 1);
4262                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)
4263                         a = bound(0, (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in), 1);
4264                 else if(centerprint_expire_time[j] > time)
4265                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4266                 else
4267                         a = 0;
4268
4269                 // set the size from fading in/out before subsequent fading
4270                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4271
4272                 // also fade it based on positioning
4273                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4274                 {
4275                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4276                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4277                 }
4278
4279                 // finally set the size based on the new theAlpha from subsequent fading
4280                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4281                 drawfontscale = sz * '1 1 0';
4282
4283                 if (centerprint_countdown_num[j])
4284                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4285                 else
4286                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4287
4288                 if (autocvar_hud_panel_centerprint_flip)
4289                 {
4290                         // check if the message can be entirely shown
4291                         for(k = 0; k < n; ++k)
4292                         {
4293                                 getWrappedLine_remaining = argv(k);
4294                                 while(getWrappedLine_remaining)
4295                                 {
4296                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4297                                         if (ts != "")
4298                                                 pos_y -= fontsize_y;
4299                                         else
4300                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4301                                 }
4302                         }
4303                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4304                 }
4305
4306                 msg_size = pos_y;
4307                 for(k = 0; k < n; ++k)
4308                 {
4309                         getWrappedLine_remaining = argv(k);
4310                         while(getWrappedLine_remaining)
4311                         {
4312                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4313                                 if (ts != "")
4314                                 {
4315                                         if (align)
4316                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4317                                         drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a * panel_fg_alpha, DRAWFLAG_NORMAL);
4318                                         pos_y += fontsize_y;
4319                                 }
4320                                 else
4321                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4322                         }
4323                 }
4324
4325                 ++g; // move next position number up
4326
4327                 msg_size = pos_y - msg_size;
4328                 if (autocvar_hud_panel_centerprint_flip)
4329                 {
4330                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4331                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4332                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4333
4334                         if (pos_y < panel_pos_y) // check if the next message can be shown
4335                         {
4336                                 drawfontscale = '1 1 0';
4337                                 return;
4338                         }
4339                 }
4340                 else
4341                 {
4342                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4343                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4344                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4345
4346                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4347                         {
4348                                 drawfontscale = '1 1 0';
4349                                 return;
4350                         }
4351                 }
4352         }
4353         drawfontscale = '1 1 0';
4354         if (n == -1)
4355         {
4356                 centerprint_showing = FALSE;
4357                 reset_centerprint_messages();
4358         }
4359 }
4360
4361 /*
4362 ==================
4363 Main HUD system
4364 ==================
4365 */
4366
4367 void HUD_Reset (void)
4368 {
4369         // reset gametype specific icons
4370         if(gametype == MAPINFO_TYPE_KEYHUNT)
4371                 HUD_Mod_KH_Reset();
4372         else if(gametype == MAPINFO_TYPE_CTF)
4373                 HUD_Mod_CTF_Reset();
4374 }
4375
4376 #define HUD_DrawPanel(id)\
4377 switch (id) {\
4378         case (HUD_PANEL_RADAR):\
4379                 HUD_Radar(); break;\
4380         case (HUD_PANEL_WEAPONS):\
4381                 HUD_Weapons(); break;\
4382         case (HUD_PANEL_AMMO):\
4383                 HUD_Ammo(); break;\
4384         case (HUD_PANEL_POWERUPS):\
4385                 HUD_Powerups(); break;\
4386         case (HUD_PANEL_HEALTHARMOR):\
4387                 HUD_HealthArmor(); break;\
4388         case (HUD_PANEL_NOTIFY):\
4389                 HUD_Notify(); break;\
4390         case (HUD_PANEL_TIMER):\
4391                 HUD_Timer(); break;\
4392         case (HUD_PANEL_SCORE):\
4393                 HUD_Score(); break;\
4394         case (HUD_PANEL_RACETIMER):\
4395                 HUD_RaceTimer(); break;\
4396         case (HUD_PANEL_VOTE):\
4397                 HUD_VoteWindow(); break;\
4398         case (HUD_PANEL_MODICONS):\
4399                 HUD_ModIcons(); break;\
4400         case (HUD_PANEL_PRESSEDKEYS):\
4401                 HUD_DrawPressedKeys(); break;\
4402         case (HUD_PANEL_CHAT):\
4403                 HUD_Chat(); break;\
4404         case (HUD_PANEL_ENGINEINFO):\
4405                 HUD_EngineInfo(); break;\
4406         case (HUD_PANEL_INFOMESSAGES):\
4407                 HUD_InfoMessages(); break;\
4408         case (HUD_PANEL_PHYSICS):\
4409                 HUD_Physics(); break;\
4410         case (HUD_PANEL_CENTERPRINT):\
4411                 HUD_CenterPrint(); break;\
4412 } ENDS_WITH_CURLY_BRACE
4413
4414 void HUD_Main (void)
4415 {
4416         float i;
4417         // global hud theAlpha fade
4418         if(menu_enabled == 1)
4419                 hud_fade_alpha = 1;
4420         else
4421                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4422
4423         if(scoreboard_fade_alpha)
4424                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4425
4426         if(autocvar__hud_configure)
4427                 if(isdemo())
4428                         HUD_Configure_Exit_Force();
4429
4430         if(intermission == 2) // no hud during mapvote
4431         {
4432                 if (autocvar__hud_configure)
4433                         HUD_Configure_Exit_Force();
4434                 hud_fade_alpha = 0;
4435         }
4436         else if(autocvar__menu_alpha == 0 && scoreboard_fade_alpha == 0)
4437                 hud_fade_alpha = 1;
4438
4439         // panels that we want to be active together with the scoreboard
4440         // they must call HUD_Panel_ApplyFadeAlpha(); only when showing the menu
4441         if(scoreboard_fade_alpha == 1)
4442         {
4443                 HUD_CenterPrint();
4444                 return;
4445         }
4446
4447         if(!autocvar__hud_configure && !hud_fade_alpha)
4448                 return;
4449
4450         // Drawing stuff
4451         if (hud_skin_prev != autocvar_hud_skin)
4452         {
4453                 if (hud_skin_path)
4454                         strunzone(hud_skin_path);
4455                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4456                 if (hud_skin_prev)
4457                         strunzone(hud_skin_prev);
4458                 hud_skin_prev = strzone(autocvar_hud_skin);
4459         }
4460
4461         // HUD configure visible grid
4462         if(autocvar__hud_configure && autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
4463         {
4464                 hud_configure_gridSize_x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
4465                 hud_configure_gridSize_y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
4466                 hud_configure_realGridSize_x = hud_configure_gridSize_x * vid_conwidth;
4467                 hud_configure_realGridSize_y = hud_configure_gridSize_y * vid_conheight;
4468                 vector s;
4469                 // x-axis
4470                 s = eX + eY * vid_conheight;
4471                 for(i = 1; i < 1/hud_configure_gridSize_x; ++i)
4472                         drawfill(eX * i * hud_configure_realGridSize_x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
4473                 // y-axis
4474                 s = eY + eX * vid_conwidth;
4475                 for(i = 1; i < 1/hud_configure_gridSize_y; ++i)
4476                         drawfill(eY * i * hud_configure_realGridSize_y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
4477         }
4478
4479 #ifdef COMPAT_XON050_ENGINE
4480     current_player = (spectatee_status > 0) ? spectatee_status : player_localentnum;
4481 #else
4482     current_player = player_localentnum;
4483 #endif
4484
4485         // draw the dock
4486         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4487         {
4488                 float f;
4489                 vector color;
4490                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4491                 if((teamplay) && hud_dock_color_team) {
4492                         color = colormapPaletteColor(myteam, 1) * hud_dock_color_team;
4493                 }
4494                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4495                         color = '1 0 0' * hud_dock_color_team;
4496                 }
4497                 else
4498                 {
4499                         string hud_dock_color = autocvar_hud_dock_color;
4500                         if(hud_dock_color == "shirt") {
4501                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4502                                 color = colormapPaletteColor(floor(f / 16), 0);
4503                         }
4504                         else if(hud_dock_color == "pants") {
4505                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4506                                 color = colormapPaletteColor(mod(f, 16), 1);
4507                         }
4508                         else
4509                                 color = stov(hud_dock_color);
4510                 }
4511
4512                 string pic;
4513                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4514                 if(precache_pic(pic) == "") {
4515                         pic = strcat(hud_skin_path, "/dock_medium");
4516                         if(precache_pic(pic) == "") {
4517                                 pic = "gfx/hud/default/dock_medium";
4518                         }
4519                 }
4520                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4521         }
4522
4523         // cache the panel order into the panel_order array
4524         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4525                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4526                         panel_order[i] = -1;
4527                 string s = "";
4528                 float p_num, warning = false;
4529                 float argc = tokenize_console(autocvar__hud_panelorder);
4530                 if (argc > HUD_PANEL_NUM)
4531                         warning = true;
4532                 //first detect wrong/missing panel numbers
4533                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4534                         p_num = stof(argv(i));
4535                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4536                                 if (panel_order[p_num] == -1) //found for the first time?
4537                                         s = strcat(s, ftos(p_num), " ");
4538                                 panel_order[p_num] = 1; //mark as found
4539                         }
4540                         else
4541                                 warning = true;
4542                 }
4543                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4544                         if (panel_order[i] == -1) {
4545                                 warning = true;
4546                                 s = strcat(s, ftos(i), " "); //add missing panel number
4547                         }
4548                 }
4549                 if (warning)
4550                         print(_("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n"));
4551
4552                 cvar_set("_hud_panelorder", s);
4553                 if(hud_panelorder_prev)
4554                         strunzone(hud_panelorder_prev);
4555                 hud_panelorder_prev = strzone(s);
4556
4557                 //now properly set panel_order
4558                 tokenize_console(s);
4559                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4560                         panel_order[i] = stof(argv(i));
4561                 }
4562         }
4563
4564         hud_draw_maximized = 0;
4565         // draw panels in order specified by panel_order array
4566         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4567                 HUD_DrawPanel(panel_order[i]);
4568
4569         hud_draw_maximized = 1; // panels that may be maximized must check this var
4570         // draw maximized panels on top
4571         if(hud_panel_radar_maximized)
4572                 HUD_Radar();
4573         if(autocvar__con_chat_maximized)
4574                 HUD_Chat();
4575
4576         if(autocvar__hud_configure)
4577         {
4578                 if(tab_panel != -1)
4579                 {
4580                         HUD_Panel_UpdatePosSizeForId(tab_panel)
4581                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
4582                 }
4583                 if(highlightedPanel != -1)
4584                 {
4585                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
4586                         HUD_Panel_HlBorder(panel_bg_border + 1.5 * hlBorderSize, '0 0.5 1', 0.25 * (1 - autocvar__menu_alpha));
4587                 }
4588                 if(!hud_configure_prev || hud_configure_prev == -1)
4589                 {
4590                         if(autocvar_hud_cursormode) { setcursormode(1); }
4591                         hudShiftState = 0;
4592                 }
4593         }
4594         else if (hud_configure_prev && autocvar_hud_cursormode)
4595                 setcursormode(0);
4596
4597         hud_configure_prev = autocvar__hud_configure;
4598
4599         if (!autocvar__hud_configure) // hud config mode disabled, enable normal theAlpha stuff again
4600                 if (menu_enabled)
4601                         menu_enabled = 0;
4602 }