qcsrc/client/hud.qh

   1 #define HUD_PANEL_MAX 24
   2 entity hud_panel[HUD_PANEL_MAX];
   3 #define HUD_PANEL_FIRST 0
   4 float HUD_PANEL_NUM;
   5 float HUD_PANEL_LAST;
   6
   7 float panel_order[HUD_PANEL_MAX];
   8 string hud_panelorder_prev;
   9
  10 float hud_draw_maximized;
  11 float hud_panel_radar_maximized;
  12 float hud_panel_quickmenu;
  13
  14 vector mousepos;
  15 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  16 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  17 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  18 entity highlightedPanel;
  19 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  20
  21 const float BORDER_MULTIPLIER = 0.25;
  22 float scoreboard_bottom;
  23 float weapon_accuracy[WEP_MAXCOUNT];
  24
  25 float complain_weapon;
  26 string complain_weapon_name;
  27 float complain_weapon_type;
  28 float complain_weapon_time;
  29
  30 float ps_primary, ps_secondary;
  31 float ts_primary, ts_secondary;
  32
  33 float last_switchweapon;
  34 float last_activeweapon;
  35 float weapontime;
  36 float weaponprevtime;
  37
  38 float teamnagger;
  39
  40 float hud_configure_checkcollisions;
  41 float hud_configure_prev;
  42 noref vector hud_configure_gridSize; // fteqcc sucks
  43 noref vector hud_configure_realGridSize; // fteqcc sucks
  44
  45 float hudShiftState;
  46 const float S_SHIFT = 1;
  47 const float S_CTRL = 2;
  48 const float S_ALT = 4;
  49
  50 float menu_enabled; // 1 showing the entire HUD, 2 showing only the clicked panel
  51 float menu_enabled_time;
  52
  53 float hud_fade_alpha;
  54
  55 string hud_skin_path;
  56 string hud_skin_prev;
  57
  58 vector myteamcolors;
  59
  60 var vector progressbar_color;
  61
  62 entity highlightedPanel_backup;
  63 var vector panel_pos_backup;
  64 var vector panel_size_backup;
  65
  66 var vector panel_size_copied;
  67
  68 entity panel;
  69 .string panel_name;
  70 .float panel_id;
  71 .vector current_panel_pos;
  72 .vector current_panel_size;
  73 .string current_panel_bg;
  74 .float current_panel_bg_alpha;
  75 .float current_panel_bg_border;
  76 .vector current_panel_bg_color;
  77 .float current_panel_bg_color_team;
  78 .float current_panel_bg_padding;
  79 .float current_panel_fg_alpha;
  80 .float update_time;
  81 var float panel_enabled;
  82 var vector panel_pos;
  83 var vector panel_size;
  84 var string panel_bg;
  85 var string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
  86 var vector panel_bg_color;
  87 var string panel_bg_color_str;
  88 var float panel_bg_color_team;
  89 var string panel_bg_color_team_str;
  90 var float panel_fg_alpha;
  91 var float panel_bg_alpha;
  92 var string panel_bg_alpha_str;
  93 var float panel_bg_border;
  94 var string panel_bg_border_str;
  95 var float panel_bg_padding;
  96 var string panel_bg_padding_str;
  97
  98 .void() panel_draw;
  99
 100 float current_player;
 101
 102 float mv_active;
 103
 104
 105 #define HUD_PANELS \
 106         HUD_PANEL(WEAPONS      , HUD_Weapons      , weapons) \
 107         HUD_PANEL(AMMO         , HUD_Ammo         , ammo) \
 108         HUD_PANEL(POWERUPS     , HUD_Powerups     , powerups) \
 109         HUD_PANEL(HEALTHARMOR  , HUD_HealthArmor  , healtharmor) \
 110         HUD_PANEL(NOTIFY       , HUD_Notify       , notify) \
 111         HUD_PANEL(TIMER        , HUD_Timer        , timer) \
 112         HUD_PANEL(RADAR        , HUD_Radar        , radar) \
 113         HUD_PANEL(SCORE        , HUD_Score        , score) \
 114         HUD_PANEL(RACETIMER    , HUD_RaceTimer    , racetimer) \
 115         HUD_PANEL(VOTE         , HUD_Vote         , vote) \
 116         HUD_PANEL(MODICONS     , HUD_ModIcons     , modicons) \
 117         HUD_PANEL(PRESSEDKEYS  , HUD_PressedKeys  , pressedkeys) \
 118         HUD_PANEL(CHAT         , HUD_Chat         , chat) \
 119         HUD_PANEL(ENGINEINFO   , HUD_EngineInfo   , engineinfo) \
 120         HUD_PANEL(INFOMESSAGES , HUD_InfoMessages , infomessages) \
 121         HUD_PANEL(PHYSICS      , HUD_Physics      , physics) \
 122         HUD_PANEL(CENTERPRINT  , HUD_CenterPrint  , centerprint) \
 123         HUD_PANEL(QUICKMENU    , HUD_QuickMenu    , quickmenu)
 124
 125 #define HUD_PANEL(NAME,draw_func,name) \
 126         float HUD_PANEL_##NAME; \
 127         void ##draw_func(void); \
 128         void RegisterHUD_Panel_##NAME() \
 129         { \
 130                 HUD_PANEL_LAST = HUD_PANEL_##NAME = HUD_PANEL_NUM; \
 131                 entity hud_panelent = spawn(); \
 132                 hud_panel[HUD_PANEL_##NAME] = hud_panelent; \
 133                 hud_panelent.classname = "hud_panel"; \
 134                 hud_panelent.panel_name = #name; \
 135                 hud_panelent.panel_id = HUD_PANEL_##NAME; \
 136                 hud_panelent.panel_draw = ##draw_func; \
 137                 ++HUD_PANEL_NUM; \
 138         } \
 139         ACCUMULATE_FUNCTION(RegisterHUD_Panels, RegisterHUD_Panel_##NAME);
 140
 141 HUD_PANELS
 142 #undef HUD_PANEL
 143
 144 #define HUD_PANEL(NAME) hud_panel[HUD_PANEL_##NAME]
 145
 146
 147 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
 148 // ----------------------
 149 // MACRO HELL STARTS HERE
 150 // ----------------------
 151 // Little help for the poor people who have to make sense of this: Start from the bottom ;)
 152
 153 #define HUD_Panel_GetProgressBarColor(item) \
 154                 progressbar_color = stov(cvar_string("hud_progressbar_" #item "_color"))
 155 #define HUD_Panel_GetProgressBarColorForString(item) \
 156 switch(item) {\
 157         case "health": HUD_Panel_GetProgressBarColor(health); break;\
 158         case "armor": HUD_Panel_GetProgressBarColor(armor); break;\
 159         case "strength": HUD_Panel_GetProgressBarColor(strength); break;\
 160         case "shield": HUD_Panel_GetProgressBarColor(shield); break;\
 161         case "fuel": HUD_Panel_GetProgressBarColor(fuel); break;\
 162         case "nexball": HUD_Panel_GetProgressBarColor(nexball); break;\
 163         case "speed": HUD_Panel_GetProgressBarColor(speed); break;\
 164         case "acceleration": HUD_Panel_GetProgressBarColor(acceleration); break;\
 165         case "acceleration_neg": HUD_Panel_GetProgressBarColor(acceleration_neg); break;\
 166 } ENDS_WITH_CURLY_BRACE
 167
 168 // Get value for panel_bg: if "" fetch default, else use panel_bg_str
 169 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 170 #define HUD_Panel_GetBg()\
 171 if(!autocvar__hud_configure && panel_bg_str == "0") {\
 172         panel_bg = "0";\
 173 } else {\
 174         if(panel_bg_str == "") {\
 175                 panel_bg_str = autocvar_hud_panel_bg;\
 176         }\
 177         if(panel_bg_str == "0" && !autocvar__hud_configure) {\
 178                         panel_bg = "0";\
 179         } else {\
 180                 if (panel_bg_str == "0" && autocvar__hud_configure)\
 181                         panel_bg_alpha_str = "0";\
 182                 panel_bg = strcat(hud_skin_path, "/", panel_bg_str);\
 183                 if(precache_pic(panel_bg) == "") {\
 184                         panel_bg = strcat(hud_skin_path, "/", "border_default");\
 185                         if(precache_pic(panel_bg) == "") {\
 186                                 panel_bg = strcat("gfx/hud/default/", "border_default");\
 187                         }\
 188                 }\
 189         }\
 190 }
 191
 192 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 193 #define HUD_Panel_GetColor()\
 194 if((teamplay) && panel_bg_color_team) {\
 195         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)\
 196                 panel_bg_color = '1 0 0' * panel_bg_color_team;\
 197         else\
 198                 panel_bg_color = myteamcolors * panel_bg_color_team;\
 199 } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {\
 200         panel_bg_color = '1 0 0' * panel_bg_color_team;\
 201 } else {\
 202         if(panel_bg_color_str == "") {\
 203                 panel_bg_color = autocvar_hud_panel_bg_color;\
 204         } else {\
 205                 if(panel_bg_color_str == "shirt") {\
 206                         panel_bg_color = colormapPaletteColor(floor(stof(getplayerkeyvalue(current_player - 1, "colors")) / 16), 0);\
 207                 } else if(panel_bg_color_str == "pants") {\
 208                         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkeyvalue(current_player - 1, "colors")), 16), 1);\
 209                 } else {\
 210                         panel_bg_color = stov(panel_bg_color_str);\
 211                 }\
 212         }\
 213 }
 214
 215 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 216 #define HUD_Panel_GetColorTeam()\
 217 if(panel_bg_color_team_str == "") {\
 218         panel_bg_color_team = autocvar_hud_panel_bg_color_team;\
 219 } else {\
 220         panel_bg_color_team = stof(panel_bg_color_team_str);\
 221 }
 222
 223 // the check doesn't allow to fade this panel when showing the panel-specific menu dialog
 224 #define HUD_Panel_ApplyFadeAlpha()\
 225 if(!(menu_enabled == 2 && panel == highlightedPanel))\
 226 {\
 227         panel_bg_alpha *= hud_fade_alpha;\
 228         panel_fg_alpha *= hud_fade_alpha;\
 229 } ENDS_WITH_CURLY_BRACE
 230
 231 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 232 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 233 #define HUD_Panel_GetBgAlpha()\
 234 if(panel_bg_alpha_str == "") {\
 235         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);\
 236 }\
 237 panel_bg_alpha = stof(panel_bg_alpha_str);\
 238 if(autocvar__hud_configure) {\
 239         if(!panel_enabled)\
 240                 panel_bg_alpha = 0.25;\
 241         else if(menu_enabled == 2 && panel == highlightedPanel)\
 242                 panel_bg_alpha = (1 - autocvar__menu_alpha) * max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 243         else\
 244                 panel_bg_alpha = max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha);\
 245 }
 246
 247 // Get value for panel_fg_alpha. Also do various minalpha checks
 248 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 249 #define HUD_Panel_GetFgAlpha()\
 250 panel_fg_alpha = autocvar_hud_panel_fg_alpha;\
 251 if(autocvar__hud_configure && !panel_enabled)\
 252         panel_fg_alpha = 0.25;\
 253
 254 // Get border. See comments above, it's similar.
 255 #define HUD_Panel_GetBorder()\
 256 if(panel_bg_border_str == "") {\
 257         panel_bg_border = autocvar_hud_panel_bg_border;\
 258 } else {\
 259         panel_bg_border = stof(panel_bg_border_str);\
 260 } ENDS_WITH_CURLY_BRACE
 261
 262 // Scale the pos and size vectors to absolute coordinates
 263 #define HUD_Panel_GetScaledVectors()\
 264 panel_pos_x *= vid_conwidth;\
 265 panel_pos_y *= vid_conheight;\
 266 panel_size_x *= vid_conwidth;\
 267 panel_size_y *= vid_conheight;
 268
 269 // Get padding. See comments above, it's similar.
 270 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 271 #define HUD_Panel_GetPadding()\
 272 if(panel_bg_padding_str == "") {\
 273         panel_bg_padding = autocvar_hud_panel_bg_padding;\
 274 } else {\
 275         panel_bg_padding = stof(panel_bg_padding_str);\
 276 }\
 277 panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);
 278
 279 // Point to the macros above (stupid max macro length)
 280 #define HUD_Panel_GetStringVars()\
 281 HUD_Panel_GetBg()\
 282 if (panel_bg != "0") {\
 283         HUD_Panel_GetColorTeam()\
 284         HUD_Panel_GetColor()\
 285         HUD_Panel_GetBgAlpha()\
 286         HUD_Panel_GetBorder()\
 287 }\
 288 HUD_Panel_GetFgAlpha()\
 289 HUD_Panel_GetScaledVectors()\
 290 HUD_Panel_GetPadding()
 291
 292 // return smoothly faded pos of given panel when a dialog is active
 293 var vector menu_enable_panelpos;
 294 #define HUD_Panel_GetMenuPos() \
 295 if(panel_size_x > panel_size_y)\
 296         menu_enable_panelpos = eX * 0.5 * vid_conwidth - eX * 0.5 * panel_size_x + eY * 0.82 * vid_conheight;\
 297 else\
 298         menu_enable_panelpos = eY * 0.5 * vid_conheight - eY * 0.5 * panel_size_y + eX * 0.7 * vid_conwidth;\
 299 panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_panelpos;
 300
 301 // return smoothly faded size of given panel when a dialog is active
 302 //var vector menu_enable_maxsize;
 303 var float menu_enable_maxsize_x;
 304 var float menu_enable_maxsize_y;
 305 var vector menu_enable_size;
 306 #define HUD_Panel_GetMenuSize()\
 307 menu_enable_maxsize_x = 0.3 * vid_conwidth;\
 308 menu_enable_maxsize_y = 0.18 * vid_conheight;\
 309 if(panel_size_x > panel_size_y)\
 310 {\
 311         if(panel_size_y > menu_enable_maxsize_y)\
 312         {\
 313                 menu_enable_size_y = menu_enable_maxsize_y;\
 314                 menu_enable_size_x = panel_size_x * (menu_enable_maxsize_y/panel_size_y);\
 315                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 316         }\
 317 }\
 318 else\
 319 {\
 320         if(panel_size_x > menu_enable_maxsize_x)\
 321         {\
 322                 menu_enable_size_x = menu_enable_maxsize_x;\
 323                 menu_enable_size_y = panel_size_y * (menu_enable_maxsize_x/panel_size_x);\
 324                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 325         }\
 326 }
 327
 328 // NOTE: in hud_configure mode cvars must be reloaded every frame
 329 #define HUD_Panel_UpdateCvars() \
 330 if(panel.update_time <= time) { \
 331         if(autocvar__hud_configure) panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 332         panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 333         panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 334         panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg")); \
 335         panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color")); \
 336         panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team")); \
 337         panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha")); \
 338         panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 339         panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding")); \
 340         HUD_Panel_GetStringVars()\
 341         if(menu_enabled == 2 && panel == highlightedPanel) {\
 342                 HUD_Panel_GetMenuSize()\
 343                 HUD_Panel_GetMenuPos()\
 344         } \
 345         panel.current_panel_pos = panel_pos; \
 346         panel.current_panel_size = panel_size; \
 347         if(panel.current_panel_bg) \
 348                 strunzone(panel.current_panel_bg); \
 349         if(panel_bg == "")\
 350         {\
 351                 /*printf("^xf08 %s panel: panel_bg is empty\n", panel.panel_name);*/\
 352                 panel_bg = "0";\
 353         }\
 354         panel.current_panel_bg = strzone(panel_bg); \
 355         panel.current_panel_bg_alpha = panel_bg_alpha; \
 356         panel.current_panel_bg_border = panel_bg_border; \
 357         panel.current_panel_bg_color = panel_bg_color; \
 358         panel.current_panel_bg_color_team = panel_bg_color_team; \
 359         panel.current_panel_bg_padding = panel_bg_padding; \
 360         panel.current_panel_fg_alpha = panel_fg_alpha; \
 361         panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval; \
 362 } else { \
 363         panel_pos = panel.current_panel_pos; \
 364         panel_size = panel.current_panel_size; \
 365         panel_bg = panel.current_panel_bg; \
 366         if(panel.current_panel_bg == "")\
 367         {\
 368                 /*printf("^xf08 %s panel: panel.current_panel_bg is empty\n", panel.panel_name);*/\
 369                 panel_bg = "0";\
 370         }\
 371         panel_bg_alpha = panel.current_panel_bg_alpha; \
 372         panel_bg_border = panel.current_panel_bg_border; \
 373         panel_bg_color = panel.current_panel_bg_color; \
 374         panel_bg_color_team = panel.current_panel_bg_color_team; \
 375         panel_bg_padding = panel.current_panel_bg_padding; \
 376         panel_fg_alpha = panel.current_panel_fg_alpha; \
 377 } ENDS_WITH_CURLY_BRACE
 378
 379 #define HUD_Panel_UpdatePosSize() {\
 380 panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 381 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 382 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 383 HUD_Panel_GetScaledVectors()\
 384 if(menu_enabled == 2 && panel == highlightedPanel) {\
 385         HUD_Panel_GetMenuSize()\
 386         HUD_Panel_GetMenuPos()\
 387 }\
 388 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 389 HUD_Panel_GetBorder() \
 390 } ENDS_WITH_CURLY_BRACE
 391
 392
 393 #define KN_MAX_ENTRIES 10
 394
 395 float kn_index;
 396 float notify_times[KN_MAX_ENTRIES];
 397 string notify_icon[KN_MAX_ENTRIES];
 398 string notify_attackers[KN_MAX_ENTRIES];
 399 string notify_victims[KN_MAX_ENTRIES];
 400 void HUD_Notify_Push(string icon, string attacker, string victim);