qcsrc/client/hud.qh

   1 #define HUD_PANEL_MAX 24
   2 entity hud_panel[HUD_PANEL_MAX];
   3 #define HUD_PANEL_FIRST 0
   4 float HUD_PANEL_NUM;
   5 float HUD_PANEL_LAST;
   6
   7 float panel_order[HUD_PANEL_MAX];
   8 string hud_panelorder_prev;
   9
  10 float hud_draw_maximized;
  11 float hud_panel_radar_maximized;
  12
  13 vector mousepos;
  14 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  15 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  16 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  17 entity highlightedPanel;
  18 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  19
  20 const float BORDER_MULTIPLIER = 0.25;
  21 float scoreboard_bottom;
  22 float weapon_accuracy[WEP_MAXCOUNT];
  23
  24 float complain_weapon;
  25 string complain_weapon_name;
  26 float complain_weapon_type;
  27 float complain_weapon_time;
  28
  29 float ps_primary, ps_secondary;
  30 float ts_primary, ts_secondary;
  31
  32 float last_switchweapon;
  33 float last_activeweapon;
  34 float weapontime;
  35 float weaponprevtime;
  36
  37 float teamnagger;
  38
  39 float hud_configure_checkcollisions;
  40 float hud_configure_prev;
  41 noref vector hud_configure_gridSize; // fteqcc sucks
  42 noref vector hud_configure_realGridSize; // fteqcc sucks
  43
  44 float hudShiftState;
  45 const float S_SHIFT = 1;
  46 const float S_CTRL = 2;
  47 const float S_ALT = 4;
  48
  49 float menu_enabled; // 1 showing the entire HUD, 2 showing only the clicked panel
  50
  51 float hud_fade_alpha;
  52
  53 string hud_skin_path;
  54 string hud_skin_prev;
  55
  56 vector myteamcolors;
  57
  58 entity highlightedPanel_backup;
  59 var vector panel_pos_backup;
  60 var vector panel_size_backup;
  61
  62 var vector panel_size_copied;
  63
  64 entity panel;
  65 .string panel_name;
  66 .float panel_id;
  67 .vector current_panel_pos;
  68 .vector current_panel_size;
  69 .string current_panel_bg;
  70 .float current_panel_bg_alpha;
  71 .float current_panel_bg_border;
  72 .vector current_panel_bg_color;
  73 .float current_panel_bg_color_team;
  74 .float current_panel_bg_padding;
  75 .float current_panel_fg_alpha;
  76 .float update_time;
  77 var float panel_enabled;
  78 var vector panel_pos;
  79 var vector panel_size;
  80 var string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
  81 var vector panel_bg_color;
  82 var string panel_bg_color_str;
  83 var float panel_bg_color_team;
  84 var string panel_bg_color_team_str;
  85 var float panel_fg_alpha;
  86 var float panel_bg_alpha;
  87 var string panel_bg_alpha_str;
  88 var float panel_bg_border;
  89 var string panel_bg_border_str;
  90 var float panel_bg_padding;
  91 var string panel_bg_padding_str;
  92
  93 .void() panel_draw;
  94
  95 float current_player;
  96
  97
  98 #define HUD_PANELS \
  99         HUD_PANEL(WEAPONS      , HUD_Weapons      , weapons) \
 100         HUD_PANEL(AMMO         , HUD_Ammo         , ammo) \
 101         HUD_PANEL(POWERUPS     , HUD_Powerups     , powerups) \
 102         HUD_PANEL(HEALTHARMOR  , HUD_HealthArmor  , healtharmor) \
 103         HUD_PANEL(NOTIFY       , HUD_Notify       , notify) \
 104         HUD_PANEL(TIMER        , HUD_Timer        , timer) \
 105         HUD_PANEL(RADAR        , HUD_Radar        , radar) \
 106         HUD_PANEL(SCORE        , HUD_Score        , score) \
 107         HUD_PANEL(RACETIMER    , HUD_RaceTimer    , racetimer) \
 108         HUD_PANEL(VOTE         , HUD_Vote         , vote) \
 109         HUD_PANEL(MODICONS     , HUD_ModIcons     , modicons) \
 110         HUD_PANEL(PRESSEDKEYS  , HUD_PressedKeys  , pressedkeys) \
 111         HUD_PANEL(CHAT         , HUD_Chat         , chat) \
 112         HUD_PANEL(ENGINEINFO   , HUD_EngineInfo   , engineinfo) \
 113         HUD_PANEL(INFOMESSAGES , HUD_InfoMessages , infomessages) \
 114         HUD_PANEL(PHYSICS      , HUD_Physics      , physics) \
 115         HUD_PANEL(CENTERPRINT  , HUD_CenterPrint  , centerprint)
 116
 117 #define HUD_PANEL(NAME,draw_func,name) \
 118         float HUD_PANEL_##NAME; \
 119         void ##draw_func(void); \
 120         void RegisterHUD_Panel_##NAME() \
 121         { \
 122                 HUD_PANEL_LAST = HUD_PANEL_##NAME = HUD_PANEL_NUM; \
 123                 entity hud_panelent = spawn(); \
 124                 hud_panel[HUD_PANEL_##NAME] = hud_panelent; \
 125                 hud_panelent.classname = "hud_panel"; \
 126                 hud_panelent.panel_name = #name; \
 127                 hud_panelent.panel_id = HUD_PANEL_##NAME; \
 128                 hud_panelent.panel_draw = ##draw_func; \
 129                 ++HUD_PANEL_NUM; \
 130         } \
 131         ACCUMULATE_FUNCTION(RegisterHUD_Panels, RegisterHUD_Panel_##NAME)
 132
 133 HUD_PANELS
 134 #undef HUD_PANEL
 135
 136 #define HUD_PANEL(NAME) hud_panel[HUD_PANEL_##NAME]
 137
 138
 139 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
 140 // ----------------------
 141 // MACRO HELL STARTS HERE
 142 // ----------------------
 143 // Little help for the poor people who have to make sense of this: Start from the bottom ;)
 144
 145 // Get value for panel.current_panel_bg: if "" fetch default, else use panel_bg_str
 146 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 147 #define HUD_Panel_GetBg()\
 148 string panel_bg;\
 149 if(!autocvar__hud_configure && panel_bg_str == "0") {\
 150         panel_bg = "0";\
 151 } else {\
 152         if(panel_bg_str == "") {\
 153                 panel_bg_str = autocvar_hud_panel_bg;\
 154         }\
 155         if(panel_bg_str == "0" && !autocvar__hud_configure) {\
 156                         panel_bg = "0";\
 157         } else {\
 158                 if (panel_bg_str == "0" && autocvar__hud_configure)\
 159                         panel_bg_alpha_str = "0";\
 160                 panel_bg = strcat(hud_skin_path, "/", panel_bg_str);\
 161                 if(precache_pic(panel_bg) == "") {\
 162                         panel_bg = strcat(hud_skin_path, "/", "border_default");\
 163                         if(precache_pic(panel_bg) == "") {\
 164                                 panel_bg = strcat("gfx/hud/default/", "border_default");\
 165                         }\
 166                 }\
 167         }\
 168 }\
 169 if(panel.current_panel_bg)\
 170         strunzone(panel.current_panel_bg);\
 171 panel.current_panel_bg = strzone(panel_bg);
 172
 173 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 174 #define HUD_Panel_GetColor()\
 175 if((teamplay) && panel_bg_color_team) {\
 176         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)\
 177                 panel_bg_color = '1 0 0' * panel_bg_color_team;\
 178         else\
 179                 panel_bg_color = myteamcolors * panel_bg_color_team;\
 180 } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {\
 181         panel_bg_color = '1 0 0' * panel_bg_color_team;\
 182 } else {\
 183         if(panel_bg_color_str == "") {\
 184                 panel_bg_color = autocvar_hud_panel_bg_color;\
 185         } else {\
 186                 if(panel_bg_color_str == "shirt") {\
 187                         panel_bg_color = colormapPaletteColor(floor(stof(getplayerkeyvalue(current_player - 1, "colors")) / 16), 0);\
 188                 } else if(panel_bg_color_str == "pants") {\
 189                         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkeyvalue(current_player - 1, "colors")), 16), 1);\
 190                 } else {\
 191                         panel_bg_color = stov(panel_bg_color_str);\
 192                 }\
 193         }\
 194 }
 195
 196 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 197 #define HUD_Panel_GetColorTeam()\
 198 if(panel_bg_color_team_str == "") {\
 199         panel_bg_color_team = autocvar_hud_panel_bg_color_team;\
 200 } else {\
 201         panel_bg_color_team = stof(panel_bg_color_team_str);\
 202 }
 203
 204 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 205 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 206 #define HUD_Panel_GetBgAlpha()\
 207 if(panel_bg_alpha_str == "") {\
 208         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);\
 209 }\
 210 panel_bg_alpha = stof(panel_bg_alpha_str);\
 211 if(autocvar__hud_configure) {\
 212         if(!panel_enabled)\
 213                 panel_bg_alpha = 0.25;\
 214         else if(menu_enabled == 2 && panel == highlightedPanel)\
 215                 panel_bg_alpha = (1 - autocvar__menu_alpha) * max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 216         else\
 217                 panel_bg_alpha = max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha);\
 218 }
 219
 220 // Get value for panel_fg_alpha. Also do various minalpha checks
 221 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 222 #define HUD_Panel_GetFgAlpha()\
 223 panel_fg_alpha = autocvar_hud_panel_fg_alpha;\
 224 if(autocvar__hud_configure && !panel_enabled)\
 225         panel_fg_alpha = 0.25;\
 226
 227 // Get border. See comments above, it's similar.
 228 #define HUD_Panel_GetBorder()\
 229 if(panel_bg_border_str == "") {\
 230         panel_bg_border = autocvar_hud_panel_bg_border;\
 231 } else {\
 232         panel_bg_border = stof(panel_bg_border_str);\
 233 } ENDS_WITH_CURLY_BRACE
 234
 235 // Get padding. See comments above, it's similar.
 236 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 237 #define HUD_Panel_GetPadding()\
 238 if(panel_bg_padding_str == "") {\
 239         panel_bg_padding = autocvar_hud_panel_bg_padding;\
 240 } else {\
 241         panel_bg_padding = stof(panel_bg_padding_str);\
 242 }\
 243 panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);
 244
 245 // return smoothly faded pos and size of given panel when a dialog is active
 246 #define HUD_Panel_UpdatePosSize_ForMenu()\
 247 vector menu_enable_pos;\
 248 vector menu_enable_size = '0 0 0';\
 249 float menu_enable_maxsize_x = 0.3 * vid_conwidth;\
 250 float menu_enable_maxsize_y = 0.18 * vid_conheight;\
 251 if(panel_size_x > panel_size_y)\
 252 {\
 253         if(panel_size_y > menu_enable_maxsize_y)\
 254         {\
 255                 menu_enable_size_y = menu_enable_maxsize_y;\
 256                 menu_enable_size_x = panel_size_x * (menu_enable_maxsize_y/panel_size_y);\
 257                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 258         }\
 259         menu_enable_pos = eX * 0.5 * vid_conwidth - eX * 0.5 * panel_size_x + eY * (vid_conheight - menu_enable_maxsize_y);\
 260 }\
 261 else\
 262 {\
 263         if(panel_size_x > menu_enable_maxsize_x)\
 264         {\
 265                 menu_enable_size_x = menu_enable_maxsize_x;\
 266                 menu_enable_size_y = panel_size_y * (menu_enable_maxsize_x/panel_size_x);\
 267                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 268         }\
 269         menu_enable_pos = eY * 0.5 * vid_conheight - eY * 0.5 * panel_size_y + eX * (vid_conwidth - menu_enable_maxsize_x);\
 270 }\
 271 panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_pos;
 272
 273 // Scale the pos and size vectors to absolute coordinates
 274 #define HUD_Panel_ScalePosSize()\
 275 panel_pos_x *= vid_conwidth; panel_pos_y *= vid_conheight;\
 276 panel_size_x *= vid_conwidth; panel_size_y *= vid_conheight;
 277
 278 // NOTE: in hud_configure mode cvars must be reloaded every frame
 279 #define HUD_Panel_UpdateCvars() \
 280 if(panel.update_time <= time) { \
 281         if(autocvar__hud_configure) panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 282         panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 283         panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 284         HUD_Panel_ScalePosSize() \
 285         panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg")); \
 286         panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color")); \
 287         panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team")); \
 288         panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha")); \
 289         panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 290         panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding")); \
 291         HUD_Panel_GetBg()\
 292         if (panel.current_panel_bg != "0") {\
 293                 HUD_Panel_GetColorTeam()\
 294                 HUD_Panel_GetColor()\
 295                 HUD_Panel_GetBgAlpha()\
 296                 HUD_Panel_GetBorder()\
 297         }\
 298         HUD_Panel_GetFgAlpha()\
 299         HUD_Panel_GetPadding()\
 300         panel.current_panel_bg_alpha = panel_bg_alpha; \
 301         panel.current_panel_fg_alpha = panel_fg_alpha; \
 302         if(menu_enabled == 2 && panel == highlightedPanel) {\
 303                 HUD_Panel_UpdatePosSize_ForMenu()\
 304         } else {\
 305                 panel_bg_alpha *= hud_fade_alpha;\
 306                 panel_fg_alpha *= hud_fade_alpha;\
 307         }\
 308         panel.current_panel_pos = panel_pos; \
 309         panel.current_panel_size = panel_size; \
 310         panel.current_panel_bg_border = panel_bg_border; \
 311         panel.current_panel_bg_color = panel_bg_color; \
 312         panel.current_panel_bg_color_team = panel_bg_color_team; \
 313         panel.current_panel_bg_padding = panel_bg_padding; \
 314         panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval; \
 315 } else { \
 316         panel_pos = panel.current_panel_pos; \
 317         panel_size = panel.current_panel_size; \
 318         panel_bg_alpha = panel.current_panel_bg_alpha * hud_fade_alpha; \
 319         panel_bg_border = panel.current_panel_bg_border; \
 320         panel_bg_color = panel.current_panel_bg_color; \
 321         panel_bg_color_team = panel.current_panel_bg_color_team; \
 322         panel_bg_padding = panel.current_panel_bg_padding; \
 323         panel_fg_alpha = panel.current_panel_fg_alpha * hud_fade_alpha; \
 324 } ENDS_WITH_CURLY_BRACE
 325
 326 #define HUD_Panel_UpdatePosSize() {\
 327 panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 328 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 329 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 330 HUD_Panel_ScalePosSize()\
 331 if(menu_enabled == 2 && panel == highlightedPanel) {\
 332         HUD_Panel_UpdatePosSize_ForMenu()\
 333 }\
 334 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 335 HUD_Panel_GetBorder() \
 336 } ENDS_WITH_CURLY_BRACE
 337
 338
 339 #define KN_MAX_ENTRIES 10
 340
 341 float kn_index;
 342 float notify_times[KN_MAX_ENTRIES];
 343 string notify_icon[KN_MAX_ENTRIES];
 344 string notify_attackers[KN_MAX_ENTRIES];
 345 string notify_victims[KN_MAX_ENTRIES];
 346 void HUD_Notify_Push(string icon, string attacker, string victim);
 347
 348 var void HUD_ModIcons_GameType(vector pos, vector size);
 349 void HUD_ModIcons_SetFunc();