qcsrc/client/hud.qh

   1 #define HUD_PANEL_MAX 24
   2 entity hud_panel[HUD_PANEL_MAX];
   3 #define HUD_PANEL_FIRST 0
   4 float HUD_PANEL_NUM;
   5 float HUD_PANEL_LAST;
   6
   7 float panel_order[HUD_PANEL_MAX];
   8 string hud_panelorder_prev;
   9
  10 float hud_draw_maximized;
  11 float hud_panel_radar_maximized;
  12
  13 vector mousepos;
  14 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  15 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  16 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  17 entity highlightedPanel;
  18 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  19
  20 const float BORDER_MULTIPLIER = 0.25;
  21 float scoreboard_bottom;
  22 float weapon_accuracy[WEP_MAXCOUNT];
  23
  24 float complain_weapon;
  25 string complain_weapon_name;
  26 float complain_weapon_type;
  27 float complain_weapon_time;
  28
  29 float ps_primary, ps_secondary;
  30 float ts_primary, ts_secondary;
  31
  32 float last_switchweapon;
  33 float last_activeweapon;
  34 float weapontime;
  35 float weaponprevtime;
  36
  37 float teamnagger;
  38
  39 float hud_configure_checkcollisions;
  40 float hud_configure_prev;
  41 noref vector hud_configure_gridSize; // fteqcc sucks
  42 noref vector hud_configure_realGridSize; // fteqcc sucks
  43
  44 float hudShiftState;
  45 const float S_SHIFT = 1;
  46 const float S_CTRL = 2;
  47 const float S_ALT = 4;
  48
  49 float menu_enabled; // 1 showing the entire HUD, 2 showing only the clicked panel
  50
  51 float hud_fade_alpha;
  52
  53 string hud_skin_path;
  54 string hud_skin_prev;
  55
  56 vector myteamcolors;
  57
  58 entity highlightedPanel_backup;
  59 var vector panel_pos_backup;
  60 var vector panel_size_backup;
  61
  62 var vector panel_size_copied;
  63
  64 entity panel;
  65 .string panel_name;
  66 .float panel_id;
  67 .vector current_panel_pos;
  68 .vector current_panel_size;
  69 .string current_panel_bg;
  70 .float current_panel_bg_alpha;
  71 .float current_panel_bg_border;
  72 .vector current_panel_bg_color;
  73 .float current_panel_bg_color_team;
  74 .float current_panel_bg_padding;
  75 .float current_panel_fg_alpha;
  76 .float update_time;
  77 var float panel_enabled;
  78 var vector panel_pos;
  79 var vector panel_size;
  80 var string panel_bg;
  81 var string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
  82 var vector panel_bg_color;
  83 var string panel_bg_color_str;
  84 var float panel_bg_color_team;
  85 var string panel_bg_color_team_str;
  86 var float panel_fg_alpha;
  87 var float panel_bg_alpha;
  88 var string panel_bg_alpha_str;
  89 var float panel_bg_border;
  90 var string panel_bg_border_str;
  91 var float panel_bg_padding;
  92 var string panel_bg_padding_str;
  93
  94 .void() panel_draw;
  95
  96 float current_player;
  97
  98
  99 #define HUD_PANELS \
 100         HUD_PANEL(WEAPONS      , HUD_Weapons      , weapons) \
 101         HUD_PANEL(AMMO         , HUD_Ammo         , ammo) \
 102         HUD_PANEL(POWERUPS     , HUD_Powerups     , powerups) \
 103         HUD_PANEL(HEALTHARMOR  , HUD_HealthArmor  , healtharmor) \
 104         HUD_PANEL(NOTIFY       , HUD_Notify       , notify) \
 105         HUD_PANEL(TIMER        , HUD_Timer        , timer) \
 106         HUD_PANEL(RADAR        , HUD_Radar        , radar) \
 107         HUD_PANEL(SCORE        , HUD_Score        , score) \
 108         HUD_PANEL(RACETIMER    , HUD_RaceTimer    , racetimer) \
 109         HUD_PANEL(VOTE         , HUD_Vote         , vote) \
 110         HUD_PANEL(MODICONS     , HUD_ModIcons     , modicons) \
 111         HUD_PANEL(PRESSEDKEYS  , HUD_PressedKeys  , pressedkeys) \
 112         HUD_PANEL(CHAT         , HUD_Chat         , chat) \
 113         HUD_PANEL(ENGINEINFO   , HUD_EngineInfo   , engineinfo) \
 114         HUD_PANEL(INFOMESSAGES , HUD_InfoMessages , infomessages) \
 115         HUD_PANEL(PHYSICS      , HUD_Physics      , physics) \
 116         HUD_PANEL(CENTERPRINT  , HUD_CenterPrint  , centerprint)
 117
 118 #define HUD_PANEL(NAME,draw_func,name) \
 119         float HUD_PANEL_##NAME; \
 120         void ##draw_func(void); \
 121         void RegisterHUD_Panel_##NAME() \
 122         { \
 123                 HUD_PANEL_LAST = HUD_PANEL_##NAME = HUD_PANEL_NUM; \
 124                 entity hud_panelent = spawn(); \
 125                 hud_panel[HUD_PANEL_##NAME] = hud_panelent; \
 126                 hud_panelent.classname = "hud_panel"; \
 127                 hud_panelent.panel_name = #name; \
 128                 hud_panelent.panel_id = HUD_PANEL_##NAME; \
 129                 hud_panelent.panel_draw = ##draw_func; \
 130                 ++HUD_PANEL_NUM; \
 131         } \
 132         ACCUMULATE_FUNCTION(RegisterHUD_Panels, RegisterHUD_Panel_##NAME)
 133
 134 HUD_PANELS
 135 #undef HUD_PANEL
 136
 137 #define HUD_PANEL(NAME) hud_panel[HUD_PANEL_##NAME]
 138
 139
 140 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
 141 // ----------------------
 142 // MACRO HELL STARTS HERE
 143 // ----------------------
 144 // Little help for the poor people who have to make sense of this: Start from the bottom ;)
 145
 146 // Get value for panel_bg: if "" fetch default, else use panel_bg_str
 147 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 148 #define HUD_Panel_GetBg()\
 149 if(!autocvar__hud_configure && panel_bg_str == "0") {\
 150         panel_bg = "0";\
 151 } else {\
 152         if(panel_bg_str == "") {\
 153                 panel_bg_str = autocvar_hud_panel_bg;\
 154         }\
 155         if(panel_bg_str == "0" && !autocvar__hud_configure) {\
 156                         panel_bg = "0";\
 157         } else {\
 158                 if (panel_bg_str == "0" && autocvar__hud_configure)\
 159                         panel_bg_alpha_str = "0";\
 160                 panel_bg = strcat(hud_skin_path, "/", panel_bg_str);\
 161                 if(precache_pic(panel_bg) == "") {\
 162                         panel_bg = strcat(hud_skin_path, "/", "border_default");\
 163                         if(precache_pic(panel_bg) == "") {\
 164                                 panel_bg = strcat("gfx/hud/default/", "border_default");\
 165                         }\
 166                 }\
 167         }\
 168 }
 169
 170 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 171 #define HUD_Panel_GetColor()\
 172 if((teamplay) && panel_bg_color_team) {\
 173         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)\
 174                 panel_bg_color = '1 0 0' * panel_bg_color_team;\
 175         else\
 176                 panel_bg_color = myteamcolors * panel_bg_color_team;\
 177 } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {\
 178         panel_bg_color = '1 0 0' * panel_bg_color_team;\
 179 } else {\
 180         if(panel_bg_color_str == "") {\
 181                 panel_bg_color = autocvar_hud_panel_bg_color;\
 182         } else {\
 183                 if(panel_bg_color_str == "shirt") {\
 184                         panel_bg_color = colormapPaletteColor(floor(stof(getplayerkeyvalue(current_player - 1, "colors")) / 16), 0);\
 185                 } else if(panel_bg_color_str == "pants") {\
 186                         panel_bg_color = colormapPaletteColor(mod(stof(getplayerkeyvalue(current_player - 1, "colors")), 16), 1);\
 187                 } else {\
 188                         panel_bg_color = stov(panel_bg_color_str);\
 189                 }\
 190         }\
 191 }
 192
 193 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 194 #define HUD_Panel_GetColorTeam()\
 195 if(panel_bg_color_team_str == "") {\
 196         panel_bg_color_team = autocvar_hud_panel_bg_color_team;\
 197 } else {\
 198         panel_bg_color_team = stof(panel_bg_color_team_str);\
 199 }
 200
 201 // the check doesn't allow to fade this panel when showing the panel-specific menu dialog
 202 #define HUD_Panel_ApplyFadeAlpha()\
 203 if(!(menu_enabled == 2 && panel == highlightedPanel))\
 204 {\
 205         panel_bg_alpha *= hud_fade_alpha;\
 206         panel_fg_alpha *= hud_fade_alpha;\
 207 } ENDS_WITH_CURLY_BRACE
 208
 209 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 210 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 211 #define HUD_Panel_GetBgAlpha()\
 212 if(panel_bg_alpha_str == "") {\
 213         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);\
 214 }\
 215 panel_bg_alpha = stof(panel_bg_alpha_str);\
 216 if(autocvar__hud_configure) {\
 217         if(!panel_enabled)\
 218                 panel_bg_alpha = 0.25;\
 219         else if(menu_enabled == 2 && panel == highlightedPanel)\
 220                 panel_bg_alpha = (1 - autocvar__menu_alpha) * max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 221         else\
 222                 panel_bg_alpha = max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha);\
 223 }
 224
 225 // Get value for panel_fg_alpha. Also do various minalpha checks
 226 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 227 #define HUD_Panel_GetFgAlpha()\
 228 panel_fg_alpha = autocvar_hud_panel_fg_alpha;\
 229 if(autocvar__hud_configure && !panel_enabled)\
 230         panel_fg_alpha = 0.25;\
 231
 232 // Get border. See comments above, it's similar.
 233 #define HUD_Panel_GetBorder()\
 234 if(panel_bg_border_str == "") {\
 235         panel_bg_border = autocvar_hud_panel_bg_border;\
 236 } else {\
 237         panel_bg_border = stof(panel_bg_border_str);\
 238 } ENDS_WITH_CURLY_BRACE
 239
 240 // Get padding. See comments above, it's similar.
 241 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 242 #define HUD_Panel_GetPadding()\
 243 if(panel_bg_padding_str == "") {\
 244         panel_bg_padding = autocvar_hud_panel_bg_padding;\
 245 } else {\
 246         panel_bg_padding = stof(panel_bg_padding_str);\
 247 }\
 248 panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);
 249
 250 // return smoothly faded pos and size of given panel when a dialog is active
 251 #define HUD_Panel_UpdatePosSize_ForMenu()\
 252 vector menu_enable_pos;\
 253 vector menu_enable_size = '0 0 0';\
 254 float menu_enable_maxsize_x = 0.3 * vid_conwidth;\
 255 float menu_enable_maxsize_y = 0.18 * vid_conheight;\
 256 if(panel_size_x > panel_size_y)\
 257 {\
 258         if(panel_size_y > menu_enable_maxsize_y)\
 259         {\
 260                 menu_enable_size_y = menu_enable_maxsize_y;\
 261                 menu_enable_size_x = panel_size_x * (menu_enable_maxsize_y/panel_size_y);\
 262                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 263         }\
 264 }\
 265 else\
 266 {\
 267         if(panel_size_x > menu_enable_maxsize_x)\
 268         {\
 269                 menu_enable_size_x = menu_enable_maxsize_x;\
 270                 menu_enable_size_y = panel_size_y * (menu_enable_maxsize_x/panel_size_x);\
 271                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 272         }\
 273 }\
 274 if(panel_size_x > panel_size_y)\
 275         menu_enable_pos = eX * 0.5 * vid_conwidth - eX * 0.5 * panel_size_x + eY * (vid_conheight - menu_enable_maxsize_y);\
 276 else\
 277         menu_enable_pos = eY * 0.5 * vid_conheight - eY * 0.5 * panel_size_y + eX * (vid_conwidth - menu_enable_maxsize_x);\
 278 panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_pos;
 279
 280 // Scale the pos and size vectors to absolute coordinates
 281 #define HUD_Panel_ScalePosSize()\
 282 panel_pos_x *= vid_conwidth; panel_pos_y *= vid_conheight;\
 283 panel_size_x *= vid_conwidth; panel_size_y *= vid_conheight;
 284
 285 // NOTE: in hud_configure mode cvars must be reloaded every frame
 286 #define HUD_Panel_UpdateCvars() \
 287 if(panel.update_time <= time) { \
 288         if(autocvar__hud_configure) panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 289         panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 290         panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 291         HUD_Panel_ScalePosSize() \
 292         panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg")); \
 293         panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color")); \
 294         panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team")); \
 295         panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha")); \
 296         panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 297         panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding")); \
 298         HUD_Panel_GetBg()\
 299         if (panel_bg != "0") {\
 300                 HUD_Panel_GetColorTeam()\
 301                 HUD_Panel_GetColor()\
 302                 HUD_Panel_GetBgAlpha()\
 303                 HUD_Panel_GetBorder()\
 304         }\
 305         HUD_Panel_GetFgAlpha()\
 306         HUD_Panel_GetPadding()\
 307         if(menu_enabled == 2 && panel == highlightedPanel) {\
 308                 HUD_Panel_UpdatePosSize_ForMenu()\
 309         } \
 310         panel.current_panel_pos = panel_pos; \
 311         panel.current_panel_size = panel_size; \
 312         if(panel.current_panel_bg != "") \
 313                 strunzone(panel.current_panel_bg); \
 314         panel.current_panel_bg = strzone(panel_bg); \
 315         panel.current_panel_bg_alpha = panel_bg_alpha; \
 316         panel.current_panel_bg_border = panel_bg_border; \
 317         panel.current_panel_bg_color = panel_bg_color; \
 318         panel.current_panel_bg_color_team = panel_bg_color_team; \
 319         panel.current_panel_bg_padding = panel_bg_padding; \
 320         panel.current_panel_fg_alpha = panel_fg_alpha; \
 321         panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval; \
 322 } else { \
 323         panel_pos = panel.current_panel_pos; \
 324         panel_size = panel.current_panel_size; \
 325         panel_bg = panel.current_panel_bg; \
 326         panel_bg_alpha = panel.current_panel_bg_alpha; \
 327         panel_bg_border = panel.current_panel_bg_border; \
 328         panel_bg_color = panel.current_panel_bg_color; \
 329         panel_bg_color_team = panel.current_panel_bg_color_team; \
 330         panel_bg_padding = panel.current_panel_bg_padding; \
 331         panel_fg_alpha = panel.current_panel_fg_alpha; \
 332 } ENDS_WITH_CURLY_BRACE
 333
 334 #define HUD_Panel_UpdatePosSize() {\
 335 panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 336 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 337 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 338 HUD_Panel_ScalePosSize()\
 339 if(menu_enabled == 2 && panel == highlightedPanel) {\
 340         HUD_Panel_UpdatePosSize_ForMenu()\
 341 }\
 342 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 343 HUD_Panel_GetBorder() \
 344 } ENDS_WITH_CURLY_BRACE
 345
 346
 347 #define KN_MAX_ENTRIES 10
 348
 349 float kn_index;
 350 float notify_times[KN_MAX_ENTRIES];
 351 string notify_icon[KN_MAX_ENTRIES];
 352 string notify_attackers[KN_MAX_ENTRIES];
 353 string notify_victims[KN_MAX_ENTRIES];
 354 void HUD_Notify_Push(string icon, string attacker, string victim);
 355
 356 var void HUD_ModIcons_GameType(vector pos, vector size);
 357 void HUD_ModIcons_SetFunc();