qcsrc/client/hud/hud.qc

   1 #include "hud.qh"
   2
   3 #include <client/defs.qh>
   4 #include <client/miscfunctions.qh>
   5 #include "panel/scoreboard.qh"
   6 #include "hud_config.qh"
   7 #include "../mapvoting.qh"
   8 #include "../teamradar.qh"
   9 #include <common/minigames/cl_minigames.qh>
  10 #include <common/t_items.qh>
  11 #include <common/deathtypes/all.qh>
  12 #include <common/ent_cs.qh>
  13 #include <common/items/_mod.qh>
  14 #include <common/mapinfo.qh>
  15 #include <common/vehicles/all.qh>
  16 #include <common/mutators/mutator/waypoints/all.qh>
  17 #include <common/stats.qh>
  18 #include <lib/csqcmodel/cl_player.qh>
  19 #include <server/mutators/mutator/gamemode_ctf.qh> // TODO: remove
  20
  21
  22 /*
  23 ==================
  24 Misc HUD functions
  25 ==================
  26 */
  27
  28 vector HUD_Get_Num_Color (float hp, float maxvalue)
  29 {
  30         float blinkingamt;
  31         vector color;
  32         if(hp >= maxvalue) {
  33                 color.x = sin(2*M_PI*time);
  34                 color.y = 1;
  35                 color.z = sin(2*M_PI*time);
  36         }
  37         else if(hp > maxvalue * 0.75) {
  38                 color.x = 0.4 - (hp-150)*0.02 * 0.4; //red value between 0.4 -> 0
  39                 color.y = 0.9 + (hp-150)*0.02 * 0.1; // green value between 0.9 -> 1
  40                 color.z = 0;
  41         }
  42         else if(hp > maxvalue * 0.5) {
  43                 color.x = 1 - (hp-100)*0.02 * 0.6; //red value between 1 -> 0.4
  44                 color.y = 1 - (hp-100)*0.02 * 0.1; // green value between 1 -> 0.9
  45                 color.z = 1 - (hp-100)*0.02; // blue value between 1 -> 0
  46         }
  47         else if(hp > maxvalue * 0.25) {
  48                 color.x = 1;
  49                 color.y = 1;
  50                 color.z = 0.2 + (hp-50)*0.02 * 0.8; // blue value between 0.2 -> 1
  51         }
  52         else if(hp > maxvalue * 0.1) {
  53                 color.x = 1;
  54                 color.y = (hp-20)*90/27/100; // green value between 0 -> 1
  55                 color.z = (hp-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
  56         }
  57         else {
  58                 color.x = 1;
  59                 color.y = 0;
  60                 color.z = 0;
  61         }
  62
  63         blinkingamt = (1 - hp/maxvalue/0.25);
  64         if(blinkingamt > 0)
  65         {
  66                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
  67                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
  68                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
  69         }
  70         return color;
  71 }
  72
  73 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
  74 {
  75     TC(int, item_count);
  76         float aspect = size_y / size_x;
  77         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
  78 }
  79
  80 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect)
  81 {
  82     TC(int, item_count);
  83         float columns, rows;
  84         float ratio, best_ratio = 0;
  85         float best_columns = 1, best_rows = 1;
  86         bool vertical = (psize.x / psize.y >= item_aspect);
  87         if(vertical)
  88         {
  89                 psize = eX * psize.y + eY * psize.x;
  90                 item_aspect = 1 / item_aspect;
  91         }
  92
  93         rows = ceil(sqrt(item_count));
  94         columns = ceil(item_count/rows);
  95         while(columns >= 1)
  96         {
  97                 ratio = (psize.x/columns) / (psize.y/rows);
  98                 if(ratio > item_aspect)
  99                         ratio = item_aspect * item_aspect / ratio;
 100
 101                 if(ratio <= best_ratio)
 102                         break; // ratio starts decreasing by now, skip next configurations
 103
 104                 best_columns = columns;
 105                 best_rows = rows;
 106                 best_ratio = ratio;
 107
 108                 if(columns == 1)
 109                         break;
 110
 111                 --columns;
 112                 rows = ceil(item_count/columns);
 113         }
 114
 115         return (vertical) ? vec2(best_rows, best_columns) : vec2(best_columns, best_rows);
 116 }
 117
 118 /*
 119 ==================
 120 HUD panels
 121 ==================
 122 */
 123
 124 void HUD_Panel_LoadCvars()
 125 {
 126         // NOTE: in hud_configure mode cvars must be reloaded every frame
 127         if (panel.update_time <= time)
 128         {
 129                 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos")));
 130                 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size")));
 131                 HUD_Panel_ScalePosSize();
 132                 panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg"));
 133                 panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color"));
 134                 panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team"));
 135                 panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha"));
 136                 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border"));
 137                 panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding"));
 138                 HUD_Panel_GetBg();
 139                 if (panel.current_panel_bg != "0")
 140                 {
 141                         HUD_Panel_GetBgAlpha();
 142                         HUD_Panel_GetBorder();
 143                 }
 144                 HUD_Panel_GetColorTeam();
 145                 HUD_Panel_GetColor();
 146                 HUD_Panel_GetFgAlpha();
 147                 HUD_Panel_GetPadding();
 148                 panel.current_panel_bg_alpha = panel_bg_alpha;
 149                 panel.current_panel_fg_alpha = panel_fg_alpha;
 150                 if (hud_configure_menu_open == 2 && panel == highlightedPanel)
 151                         HUD_Panel_UpdatePosSize_ForMenu();
 152                 else
 153                 {
 154                         panel_bg_alpha *= hud_fade_alpha * panel_fade_alpha;
 155                         panel_fg_alpha *= hud_fade_alpha * panel_fade_alpha;
 156                 }
 157                 panel.current_panel_pos = panel_pos;
 158                 panel.current_panel_size = panel_size;
 159                 panel.current_panel_bg_border = panel_bg_border;
 160                 panel.current_panel_bg_color = panel_bg_color;
 161                 panel.current_panel_bg_color_team = panel_bg_color_team;
 162                 panel.current_panel_bg_padding = panel_bg_padding;
 163                 panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval;
 164                 return;
 165         }
 166
 167         panel_pos = panel.current_panel_pos;
 168         panel_size = panel.current_panel_size;
 169         panel_bg_alpha = panel.current_panel_bg_alpha * hud_fade_alpha * panel_fade_alpha;
 170         panel_bg_border = panel.current_panel_bg_border;
 171         panel_bg_color = panel.current_panel_bg_color;
 172         panel_bg_color_team = panel.current_panel_bg_color_team;
 173         panel_bg_padding = panel.current_panel_bg_padding;
 174         panel_fg_alpha = panel.current_panel_fg_alpha * hud_fade_alpha * panel_fade_alpha;
 175 }
 176
 177 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 178 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 179 {
 180     TC(bool, vertical); TC(int, drawflag);
 181         if(!length_ratio || !theAlpha)
 182                 return;
 183         if(length_ratio > 1)
 184                 length_ratio = 1;
 185         if (baralign == 3)
 186         {
 187                 if(length_ratio < -1)
 188                         length_ratio = -1;
 189         }
 190         else if(length_ratio < 0)
 191                 return;
 192
 193         theOrigin = HUD_Shift(theOrigin);
 194         theSize = HUD_Scale(theSize);
 195
 196         vector square;
 197         vector width, height;
 198         if(vertical) {
 199                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 200                 if(precache_pic(pic) == "") {
 201                         pic = "gfx/hud/default/progressbar_vertical";
 202                 }
 203
 204         if (baralign == 1) // bottom align
 205                         theOrigin.y += (1 - length_ratio) * theSize.y;
 206         else if (baralign == 2) // center align
 207             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 208         else if (baralign == 3) // center align, positive values down, negative up
 209                 {
 210                         theSize.y *= 0.5;
 211                         if (length_ratio > 0)
 212                                 theOrigin.y += theSize.y;
 213                         else
 214                         {
 215                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 216                                 length_ratio = -length_ratio;
 217                         }
 218                 }
 219                 theSize.y *= length_ratio;
 220
 221                 vector bH;
 222                 width = eX * theSize.x;
 223                 height = eY * theSize.y;
 224                 if(theSize.y <= theSize.x * 2)
 225                 {
 226                         // button not high enough
 227                         // draw just upper and lower part then
 228                         square = eY * theSize.y * 0.5;
 229                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 230                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 231                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 232                 }
 233                 else
 234                 {
 235                         square = eY * theSize.x;
 236                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 237                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 238                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 239                 }
 240         } else {
 241                 pic = strcat(hud_skin_path, "/", pic);
 242                 if(precache_pic(pic) == "") {
 243                         pic = "gfx/hud/default/progressbar";
 244                 }
 245
 246                 if (baralign == 1) // right align
 247                         theOrigin.x += (1 - length_ratio) * theSize.x;
 248         else if (baralign == 2) // center align
 249             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 250         else if (baralign == 3) // center align, positive values on the right, negative on the left
 251                 {
 252                         theSize.x *= 0.5;
 253                         if (length_ratio > 0)
 254                                 theOrigin.x += theSize.x;
 255                         else
 256                         {
 257                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 258                                 length_ratio = -length_ratio;
 259                         }
 260                 }
 261                 theSize.x *= length_ratio;
 262
 263                 vector bW;
 264                 width = eX * theSize.x;
 265                 height = eY * theSize.y;
 266                 if(theSize.x <= theSize.y * 2)
 267                 {
 268                         // button not wide enough
 269                         // draw just left and right part then
 270                         square = eX * theSize.x * 0.5;
 271                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 272                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 273                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 274                 }
 275                 else
 276                 {
 277                         square = eX * theSize.y;
 278                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 279                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 280                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 281                 }
 282         }
 283 }
 284
 285 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 286 {
 287     TC(int, drawflag);
 288         if(!theAlpha)
 289                 return;
 290
 291         pos = HUD_Shift(pos);
 292         mySize = HUD_Scale(mySize);
 293
 294         string pic;
 295         pic = strcat(hud_skin_path, "/num_leading");
 296         if(precache_pic(pic) == "") {
 297                 pic = "gfx/hud/default/num_leading";
 298         }
 299
 300         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 301         if(mySize.x/mySize.y > 2)
 302                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 303         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 304 }
 305
 306 void DrawNumIcon_expanding(vector myPos, vector mySize, float theTime, string icon, bool vertical, int icon_right_align, vector color, float theAlpha, float fadelerp)
 307 {
 308     TC(bool, vertical); TC(int, icon_right_align);
 309         vector newPos = '0 0 0', newSize = '0 0 0';
 310         vector picpos, numpos;
 311
 312         if (vertical)
 313         {
 314                 if(mySize.y/mySize.x > 2)
 315                 {
 316                         newSize.y = 2 * mySize.x;
 317                         newSize.x = mySize.x;
 318
 319                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
 320                         newPos.x = myPos.x;
 321                 }
 322                 else
 323                 {
 324                         newSize.x = 1/2 * mySize.y;
 325                         newSize.y = mySize.y;
 326
 327                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
 328                         newPos.y = myPos.y;
 329                 }
 330
 331                 if(icon_right_align)
 332                 {
 333                         numpos = newPos;
 334                         picpos = newPos + eY * newSize.x;
 335                 }
 336                 else
 337                 {
 338                         picpos = newPos;
 339                         numpos = newPos + eY * newSize.x;
 340                 }
 341
 342                 newSize.y /= 2;
 343                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 344                 // make number smaller than icon, it looks better
 345                 // reduce only y to draw numbers with different number of digits with the same y size
 346                 numpos.y += newSize.y * ((1 - 0.7) / 2);
 347                 newSize.y *= 0.7;
 348                 drawstring_aspect(numpos, ftos(theTime), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 349                 return;
 350         }
 351
 352         if(mySize.x/mySize.y > 3)
 353         {
 354                 newSize.x = 3 * mySize.y;
 355                 newSize.y = mySize.y;
 356
 357                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
 358                 newPos.y = myPos.y;
 359         }
 360         else
 361         {
 362                 newSize.y = 1/3 * mySize.x;
 363                 newSize.x = mySize.x;
 364
 365                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
 366                 newPos.x = myPos.x;
 367         }
 368
 369         if(icon_right_align) // right align
 370         {
 371                 numpos = newPos;
 372                 picpos = newPos + eX * 2 * newSize.y;
 373         }
 374         else // left align
 375         {
 376                 numpos = newPos + eX * newSize.y;
 377                 picpos = newPos;
 378         }
 379
 380         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
 381         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
 382         drawstring_aspect_expanding(numpos, ftos(theTime), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
 383         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
 384 }
 385
 386 void DrawNumIcon(vector myPos, vector mySize, float theTime, string icon, bool vertical, int icon_right_align, vector color, float theAlpha)
 387 {
 388     TC(bool, vertical); TC(int, icon_right_align);
 389         DrawNumIcon_expanding(myPos, mySize, theTime, icon, vertical, icon_right_align, color, theAlpha, 0);
 390 }
 391
 392 /*
 393 ==================
 394 Main HUD system
 395 ==================
 396 */
 397
 398 void CSQC_BUMBLE_GUN_HUD();
 399
 400 void HUD_Vehicle()
 401 {
 402         if(autocvar__hud_configure) return;
 403         if(intermission == 2) return;
 404
 405         if(hud == HUD_BUMBLEBEE_GUN)
 406                 CSQC_BUMBLE_GUN_HUD();
 407         else {
 408                 Vehicle info = Vehicles_from(hud);
 409                 info.vr_hud(info);
 410         }
 411 }
 412
 413 void HUD_Panel_Draw(entity panent)
 414 {
 415         panel = panent;
 416         if (autocvar__hud_configure)
 417         {
 418                 if (!(panel.panel_configflags & PANEL_CONFIG_MAIN))
 419                         return;
 420                 panel_fade_alpha = 1;
 421                 Hud_Panel_GetPanelEnabled();
 422                 panel.panel_draw();
 423                 return;
 424         }
 425
 426         bool draw_allowed = false;
 427         if (active_minigame && HUD_MinigameMenu_IsOpened())
 428         {
 429                 if (panel.panel_showflags & PANEL_SHOW_MINIGAME)
 430                         draw_allowed = true;
 431         }
 432         else if(intermission == 2)
 433         {
 434                 if(panel.panel_showflags & PANEL_SHOW_MAPVOTE)
 435                         draw_allowed = true;
 436         }
 437         else if (panel.panel_showflags & PANEL_SHOW_MAINGAME)
 438                 draw_allowed = true;
 439
 440         if (draw_allowed)
 441         {
 442                 if (panel.panel_showflags & PANEL_SHOW_WITH_SB)
 443                         panel_fade_alpha = 1;
 444                 else
 445                 {
 446                         panel_fade_alpha = 1 - scoreboard_fade_alpha;
 447                         if(!panel_fade_alpha)
 448                                 return;
 449                 }
 450                 panel.panel_draw();
 451         }
 452 }
 453
 454 void HUD_Reset()
 455 {
 456         // reset gametype specific icons
 457         if(gametype.m_modicons_reset)
 458                 gametype.m_modicons_reset();
 459 }
 460
 461 float autocvar_hud_dynamic_shake = 1;
 462 float autocvar_hud_dynamic_shake_damage_max = 130;
 463 float autocvar_hud_dynamic_shake_damage_min = 10;
 464 float autocvar_hud_dynamic_shake_scale = 0.2;
 465 float hud_dynamic_shake_x[10] = {0,    1, -0.7,  0.5, -0.3,  0.2, -0.1,  0.1,  0.0, 0};
 466 float hud_dynamic_shake_y[10] = {0,  0.4,  0.8, -0.2, -0.6,  0.0,  0.3,  0.1, -0.1, 0};
 467 bool Hud_Shake_Update()
 468 {
 469         if(time - hud_dynamic_shake_time < 0)
 470                 return false;
 471
 472         float anim_speed = 17 + 9 * hud_dynamic_shake_factor;
 473         float elapsed_time = (time - hud_dynamic_shake_time) * anim_speed;
 474         int i = floor(elapsed_time);
 475         if(i >= 9)
 476                 return false;
 477
 478         float f = elapsed_time - i;
 479         hud_dynamic_shake_realofs.x = (1 - f) * hud_dynamic_shake_x[i] + f * hud_dynamic_shake_x[i+1];
 480         hud_dynamic_shake_realofs.y = (1 - f) * hud_dynamic_shake_y[i] + f * hud_dynamic_shake_y[i+1];
 481         hud_dynamic_shake_realofs.z = 0;
 482         hud_dynamic_shake_realofs *= hud_dynamic_shake_factor * autocvar_hud_dynamic_shake_scale;
 483         hud_dynamic_shake_realofs.x = bound(-0.1, hud_dynamic_shake_realofs.x, 0.1) * vid_conwidth;
 484         hud_dynamic_shake_realofs.y = bound(-0.1, hud_dynamic_shake_realofs.y, 0.1) * vid_conheight;
 485         return true;
 486 }
 487
 488 entity CSQCModel_server2csqc(int i);
 489 void calc_followmodel_ofs(entity view);
 490 void Hud_Dynamic_Frame()
 491 {
 492         vector ofs = '0 0 0';
 493         hud_scale_current = '1 1 0';
 494         hud_shift_current = '0 0 0';
 495
 496         if (autocvar_hud_dynamic_follow)
 497         {
 498                 entity view = CSQCModel_server2csqc(player_localentnum - 1);
 499                 calc_followmodel_ofs(view);
 500                 ofs = -cl_followmodel_ofs * autocvar_hud_dynamic_follow_scale;
 501                 ofs.x *= autocvar_hud_dynamic_follow_scale_xyz.z;
 502                 ofs.y *= autocvar_hud_dynamic_follow_scale_xyz.x;
 503                 ofs.z *= autocvar_hud_dynamic_follow_scale_xyz.y;
 504
 505                 if (fabs(ofs.x) < 0.001) ofs.x = 0;
 506                 if (fabs(ofs.y) < 0.001) ofs.y = 0;
 507                 if (fabs(ofs.z) < 0.001) ofs.z = 0;
 508                 ofs.x = bound(-0.1, ofs.x, 0.1);
 509                 ofs.y = bound(-0.1, ofs.y, 0.1);
 510                 ofs.z = bound(-0.1, ofs.z, 0.1);
 511
 512                 hud_shift_current.x = ofs.y * vid_conwidth;
 513                 hud_shift_current.y = ofs.z * vid_conheight;
 514                 hud_shift_current.z = ofs.x;
 515
 516                 hud_scale_current.x = (1 + hud_shift_current.z);
 517                 hud_scale_current.y = hud_scale_current.x;
 518         }
 519
 520         if(autocvar_hud_dynamic_shake > 0)
 521         {
 522                 static float old_health = 0;
 523                 float health = max(-1, STAT(HEALTH));
 524                 if(hud_dynamic_shake_factor == -1) // don't allow the effect for this frame
 525                 {
 526                         hud_dynamic_shake_factor = 0;
 527                         old_health = health;
 528                 }
 529                 else
 530                 {
 531                         float new_hud_dynamic_shake_factor = 0;
 532                         if (old_health - health >= autocvar_hud_dynamic_shake_damage_min
 533                                 && autocvar_hud_dynamic_shake_damage_max > autocvar_hud_dynamic_shake_damage_min
 534                                 && old_health > 0 && !intermission)
 535                         {
 536                                 float m = max(autocvar_hud_dynamic_shake_damage_min, 1);
 537                                 new_hud_dynamic_shake_factor = (old_health - health - m) / (autocvar_hud_dynamic_shake_damage_max - m);
 538                                 if(new_hud_dynamic_shake_factor >= 1)
 539                                         new_hud_dynamic_shake_factor = 1;
 540                                 if(new_hud_dynamic_shake_factor >= hud_dynamic_shake_factor)
 541                                 {
 542                                         hud_dynamic_shake_factor = new_hud_dynamic_shake_factor;
 543                                         hud_dynamic_shake_time = time;
 544                                 }
 545                         }
 546                         old_health = health;
 547                         if(hud_dynamic_shake_factor)
 548                                 if(!Hud_Shake_Update())
 549                                         hud_dynamic_shake_factor = 0;
 550                 }
 551
 552                 if(hud_dynamic_shake_factor > 0)
 553                 {
 554                         hud_shift_current.x += hud_dynamic_shake_realofs.x;
 555                         hud_shift_current.y += hud_dynamic_shake_realofs.y;
 556                 }
 557         }
 558
 559         hud_scale_center.x = 0.5 * vid_conwidth;
 560         hud_scale_center.y = 0.5 * vid_conheight;
 561
 562         HUD_Scale_Disable();
 563 }
 564
 565 void HUD_Main()
 566 {
 567         int i;
 568         if(hud_configure_menu_open == 1)
 569                 hud_fade_alpha = 1;
 570         else
 571                 hud_fade_alpha = 1 - autocvar__menu_alpha;
 572
 573         HUD_Configure_Frame();
 574
 575         if(scoreboard_fade_alpha == 1)
 576                 if(autocvar__menu_alpha == 1)
 577                         return;
 578
 579         // Drawing stuff
 580         if (hud_skin_prev != autocvar_hud_skin)
 581         {
 582                 if (hud_skin_path)
 583                         strunzone(hud_skin_path);
 584                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 585                 if (hud_skin_prev)
 586                         strunzone(hud_skin_prev);
 587                 hud_skin_prev = strzone(autocvar_hud_skin);
 588         }
 589
 590         // draw the dock
 591         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
 592         {
 593                 int f;
 594                 vector color;
 595                 float hud_dock_color_team = autocvar_hud_dock_color_team;
 596                 if((teamplay) && hud_dock_color_team) {
 597                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
 598                                 color = '1 0 0' * hud_dock_color_team;
 599                         else
 600                                 color = myteamcolors * hud_dock_color_team;
 601                 }
 602                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
 603                         color = '1 0 0' * hud_dock_color_team;
 604                 }
 605                 else
 606                 {
 607                         string hud_dock_color = autocvar_hud_dock_color;
 608                         if(hud_dock_color == "shirt") {
 609                                 f = entcs_GetClientColors(current_player);
 610                                 color = colormapPaletteColor(floor(f / 16), 0);
 611                         }
 612                         else if(hud_dock_color == "pants") {
 613                                 f = entcs_GetClientColors(current_player);
 614                                 color = colormapPaletteColor(f % 16, 1);
 615                         }
 616                         else
 617                                 color = stov(hud_dock_color);
 618                 }
 619
 620                 string pic;
 621                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
 622                 if(precache_pic(pic) == "") {
 623                         pic = strcat(hud_skin_path, "/dock_medium");
 624                         if(precache_pic(pic) == "") {
 625                                 pic = "gfx/hud/default/dock_medium";
 626                         }
 627                 }
 628                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
 629         }
 630
 631         // cache the panel order into the panel_order array
 632         if(autocvar__hud_panelorder != hud_panelorder_prev) {
 633                 for(i = 0; i < hud_panels_COUNT; ++i)
 634                         panel_order[i] = -1;
 635                 string s = "";
 636                 int p_num;
 637                 bool warning = false;
 638                 int argc = tokenize_console(autocvar__hud_panelorder);
 639                 if (argc > hud_panels_COUNT)
 640                         warning = true;
 641                 //first detect wrong/missing panel numbers
 642                 for(i = 0; i < hud_panels_COUNT; ++i) {
 643                         p_num = stoi(argv(i));
 644                         if (p_num >= 0 && p_num < hud_panels_COUNT) { //correct panel number?
 645                                 if (panel_order[p_num] == -1) //found for the first time?
 646                                         s = strcat(s, ftos(p_num), " ");
 647                                 panel_order[p_num] = 1; //mark as found
 648                         }
 649                         else
 650                                 warning = true;
 651                 }
 652                 for(i = 0; i < hud_panels_COUNT; ++i) {
 653                         if (panel_order[i] == -1) {
 654                                 warning = true;
 655                                 s = strcat(s, ftos(i), " "); //add missing panel number
 656                         }
 657                 }
 658                 if (warning)
 659                         LOG_TRACE("Automatically fixed wrong/missing panel numbers in _hud_panelorder");
 660
 661                 cvar_set("_hud_panelorder", s);
 662                 if(hud_panelorder_prev)
 663                         strunzone(hud_panelorder_prev);
 664                 hud_panelorder_prev = strzone(s);
 665
 666                 //now properly set panel_order
 667                 tokenize_console(s);
 668                 for(i = 0; i < hud_panels_COUNT; ++i) {
 669                         panel_order[i] = stof(argv(i));
 670                 }
 671         }
 672
 673         hud_draw_maximized = 0;
 674         // draw panels in the order specified by panel_order array
 675         for(i = hud_panels_COUNT - 1; i >= 0; --i)
 676                 HUD_Panel_Draw(hud_panels_from(panel_order[i]));
 677
 678         HUD_Vehicle();
 679
 680         hud_draw_maximized = 1; // panels that may be maximized must check this var
 681         // draw maximized panels on top
 682         if(hud_panel_radar_maximized)
 683                 HUD_Panel_Draw(HUD_PANEL(RADAR));
 684         if(autocvar__con_chat_maximized)
 685                 HUD_Panel_Draw(HUD_PANEL(CHAT));
 686         if(hud_panel_quickmenu)
 687                 HUD_Panel_Draw(HUD_PANEL(QUICKMENU));
 688         HUD_Panel_Draw(HUD_PANEL(SCOREBOARD));
 689
 690         if (intermission == 2)
 691                 HUD_Reset();
 692
 693         HUD_Configure_PostDraw();
 694
 695         hud_configure_prev = autocvar__hud_configure;
 696 }