qcsrc/client/hud/hud.qc

   1 #include "hud.qh"
   2
   3 #include "panel/scoreboard.qh"
   4 #include "hud_config.qh"
   5 #include "../mapvoting.qh"
   6 #include "../teamradar.qh"
   7 #include <common/t_items.qh>
   8 #include <common/deathtypes/all.qh>
   9 #include <common/items/_mod.qh>
  10 #include <common/mapinfo.qh>
  11 #include <common/vehicles/all.qh>
  12 #include <common/mutators/mutator/waypoints/all.qh>
  13 #include <common/stats.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15 #include <server/mutators/mutator/gamemode_ctf.qh> // TODO: remove
  16
  17
  18 /*
  19 ==================
  20 Misc HUD functions
  21 ==================
  22 */
  23
  24 vector HUD_Get_Num_Color (float x, float maxvalue)
  25 {
  26         float blinkingamt;
  27         vector color;
  28         if(x >= maxvalue) {
  29                 color.x = sin(2*M_PI*time);
  30                 color.y = 1;
  31                 color.z = sin(2*M_PI*time);
  32         }
  33         else if(x > maxvalue * 0.75) {
  34                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
  35                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
  36                 color.z = 0;
  37         }
  38         else if(x > maxvalue * 0.5) {
  39                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
  40                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
  41                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
  42         }
  43         else if(x > maxvalue * 0.25) {
  44                 color.x = 1;
  45                 color.y = 1;
  46                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
  47         }
  48         else if(x > maxvalue * 0.1) {
  49                 color.x = 1;
  50                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
  51                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
  52         }
  53         else {
  54                 color.x = 1;
  55                 color.y = 0;
  56                 color.z = 0;
  57         }
  58
  59         blinkingamt = (1 - x/maxvalue/0.25);
  60         if(blinkingamt > 0)
  61         {
  62                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
  63                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
  64                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
  65         }
  66         return color;
  67 }
  68
  69 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
  70 {
  71     TC(int, item_count);
  72         float aspect = size_y / size_x;
  73         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
  74 }
  75
  76 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect)
  77 {
  78     TC(int, item_count);
  79         float columns, rows;
  80         float ratio, best_ratio = 0;
  81         float best_columns = 1, best_rows = 1;
  82         bool vertical = (psize.x / psize.y >= item_aspect);
  83         if(vertical)
  84         {
  85                 psize = eX * psize.y + eY * psize.x;
  86                 item_aspect = 1 / item_aspect;
  87         }
  88
  89         rows = ceil(sqrt(item_count));
  90         columns = ceil(item_count/rows);
  91         while(columns >= 1)
  92         {
  93                 ratio = (psize.x/columns) / (psize.y/rows);
  94                 if(ratio > item_aspect)
  95                         ratio = item_aspect * item_aspect / ratio;
  96
  97                 if(ratio <= best_ratio)
  98                         break; // ratio starts decreasing by now, skip next configurations
  99
 100                 best_columns = columns;
 101                 best_rows = rows;
 102                 best_ratio = ratio;
 103
 104                 if(columns == 1)
 105                         break;
 106
 107                 --columns;
 108                 rows = ceil(item_count/columns);
 109         }
 110
 111         if(vertical)
 112                 return eX * best_rows + eY * best_columns;
 113         else
 114                 return eX * best_columns + eY * best_rows;
 115 }
 116
 117 /*
 118 ==================
 119 HUD panels
 120 ==================
 121 */
 122
 123 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 124 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 125 {
 126     TC(bool, vertical); TC(int, drawflag);
 127         if(!length_ratio || !theAlpha)
 128                 return;
 129         if(length_ratio > 1)
 130                 length_ratio = 1;
 131         if (baralign == 3)
 132         {
 133                 if(length_ratio < -1)
 134                         length_ratio = -1;
 135         }
 136         else if(length_ratio < 0)
 137                 return;
 138
 139         theOrigin = HUD_Shift(theOrigin);
 140         theSize = HUD_Scale(theSize);
 141
 142         vector square;
 143         vector width, height;
 144         if(vertical) {
 145                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 146                 if(precache_pic(pic) == "") {
 147                         pic = "gfx/hud/default/progressbar_vertical";
 148                 }
 149
 150         if (baralign == 1) // bottom align
 151                         theOrigin.y += (1 - length_ratio) * theSize.y;
 152         else if (baralign == 2) // center align
 153             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 154         else if (baralign == 3) // center align, positive values down, negative up
 155                 {
 156                         theSize.y *= 0.5;
 157                         if (length_ratio > 0)
 158                                 theOrigin.y += theSize.y;
 159                         else
 160                         {
 161                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 162                                 length_ratio = -length_ratio;
 163                         }
 164                 }
 165                 theSize.y *= length_ratio;
 166
 167                 vector bH;
 168                 width = eX * theSize.x;
 169                 height = eY * theSize.y;
 170                 if(theSize.y <= theSize.x * 2)
 171                 {
 172                         // button not high enough
 173                         // draw just upper and lower part then
 174                         square = eY * theSize.y * 0.5;
 175                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 176                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 177                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 178                 }
 179                 else
 180                 {
 181                         square = eY * theSize.x;
 182                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 183                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 184                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 185                 }
 186         } else {
 187                 pic = strcat(hud_skin_path, "/", pic);
 188                 if(precache_pic(pic) == "") {
 189                         pic = "gfx/hud/default/progressbar";
 190                 }
 191
 192                 if (baralign == 1) // right align
 193                         theOrigin.x += (1 - length_ratio) * theSize.x;
 194         else if (baralign == 2) // center align
 195             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 196         else if (baralign == 3) // center align, positive values on the right, negative on the left
 197                 {
 198                         theSize.x *= 0.5;
 199                         if (length_ratio > 0)
 200                                 theOrigin.x += theSize.x;
 201                         else
 202                         {
 203                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 204                                 length_ratio = -length_ratio;
 205                         }
 206                 }
 207                 theSize.x *= length_ratio;
 208
 209                 vector bW;
 210                 width = eX * theSize.x;
 211                 height = eY * theSize.y;
 212                 if(theSize.x <= theSize.y * 2)
 213                 {
 214                         // button not wide enough
 215                         // draw just left and right part then
 216                         square = eX * theSize.x * 0.5;
 217                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 218                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 219                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 220                 }
 221                 else
 222                 {
 223                         square = eX * theSize.y;
 224                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 225                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 226                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 227                 }
 228         }
 229 }
 230
 231 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 232 {
 233     TC(int, drawflag);
 234         if(!theAlpha)
 235                 return;
 236
 237         pos = HUD_Shift(pos);
 238         mySize = HUD_Scale(mySize);
 239
 240         string pic;
 241         pic = strcat(hud_skin_path, "/num_leading");
 242         if(precache_pic(pic) == "") {
 243                 pic = "gfx/hud/default/num_leading";
 244         }
 245
 246         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 247         if(mySize.x/mySize.y > 2)
 248                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 249         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 250 }
 251
 252 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, int icon_right_align, vector color, float theAlpha, float fadelerp)
 253 {
 254     TC(bool, vertical); TC(int, icon_right_align);
 255         vector newPos = '0 0 0', newSize = '0 0 0';
 256         vector picpos, numpos;
 257
 258         if (vertical)
 259         {
 260                 if(mySize.y/mySize.x > 2)
 261                 {
 262                         newSize.y = 2 * mySize.x;
 263                         newSize.x = mySize.x;
 264
 265                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
 266                         newPos.x = myPos.x;
 267                 }
 268                 else
 269                 {
 270                         newSize.x = 1/2 * mySize.y;
 271                         newSize.y = mySize.y;
 272
 273                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
 274                         newPos.y = myPos.y;
 275                 }
 276
 277                 if(icon_right_align)
 278                 {
 279                         numpos = newPos;
 280                         picpos = newPos + eY * newSize.x;
 281                 }
 282                 else
 283                 {
 284                         picpos = newPos;
 285                         numpos = newPos + eY * newSize.x;
 286                 }
 287
 288                 newSize.y /= 2;
 289                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 290                 // make number smaller than icon, it looks better
 291                 // reduce only y to draw numbers with different number of digits with the same y size
 292                 numpos.y += newSize.y * ((1 - 0.7) / 2);
 293                 newSize.y *= 0.7;
 294                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 295                 return;
 296         }
 297
 298         if(mySize.x/mySize.y > 3)
 299         {
 300                 newSize.x = 3 * mySize.y;
 301                 newSize.y = mySize.y;
 302
 303                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
 304                 newPos.y = myPos.y;
 305         }
 306         else
 307         {
 308                 newSize.y = 1/3 * mySize.x;
 309                 newSize.x = mySize.x;
 310
 311                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
 312                 newPos.x = myPos.x;
 313         }
 314
 315         if(icon_right_align) // right align
 316         {
 317                 numpos = newPos;
 318                 picpos = newPos + eX * 2 * newSize.y;
 319         }
 320         else // left align
 321         {
 322                 numpos = newPos + eX * newSize.y;
 323                 picpos = newPos;
 324         }
 325
 326         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
 327         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
 328         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
 329         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
 330 }
 331
 332 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, int icon_right_align, vector color, float theAlpha)
 333 {
 334     TC(bool, vertical); TC(int, icon_right_align);
 335         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
 336 }
 337
 338 /*
 339 ==================
 340 Main HUD system
 341 ==================
 342 */
 343
 344 void CSQC_BUMBLE_GUN_HUD();
 345
 346 void HUD_Vehicle()
 347 {
 348         if(autocvar__hud_configure) return;
 349         if(intermission == 2) return;
 350
 351         if(hud == HUD_BUMBLEBEE_GUN)
 352                 CSQC_BUMBLE_GUN_HUD();
 353         else {
 354                 Vehicle info = Vehicles_from(hud);
 355                 info.vr_hud(info);
 356         }
 357 }
 358
 359 bool HUD_Minigame_Showpanels();
 360
 361 void HUD_Panel_Draw(entity panent)
 362 {
 363         panel = panent;
 364         if (autocvar__hud_configure)
 365         {
 366                 if (!(panel.panel_configflags & PANEL_CONFIG_MAIN))
 367                         return;
 368                 panel_fade_alpha = 1;
 369                 Hud_Panel_GetPanelEnabled();
 370                 panel.panel_draw();
 371                 return;
 372         }
 373
 374         bool draw_allowed = false;
 375         if (HUD_Minigame_Showpanels())
 376         {
 377                 if (panel.panel_showflags & PANEL_SHOW_MINIGAME)
 378                         draw_allowed = true;
 379         }
 380         else if(intermission == 2)
 381         {
 382                 if(panel.panel_showflags & PANEL_SHOW_MAPVOTE)
 383                         draw_allowed = true;
 384         }
 385         else if (panel.panel_showflags & PANEL_SHOW_MAINGAME)
 386                 draw_allowed = true;
 387
 388         if (draw_allowed)
 389         {
 390                 if (panel.panel_showflags & PANEL_SHOW_WITH_SB)
 391                         panel_fade_alpha = 1;
 392                 else
 393                 {
 394                         panel_fade_alpha = 1 - scoreboard_fade_alpha;
 395                         if(!panel_fade_alpha)
 396                                 return;
 397                 }
 398                 panel.panel_draw();
 399         }
 400 }
 401
 402 void HUD_Reset()
 403 {
 404         // reset gametype specific icons
 405         if(gametype.m_modicons_reset)
 406                 gametype.m_modicons_reset();
 407 }
 408
 409 float autocvar_hud_dynamic_shake = 1;
 410 float autocvar_hud_dynamic_shake_damage_max = 130;
 411 float autocvar_hud_dynamic_shake_damage_min = 10;
 412 float autocvar_hud_dynamic_shake_scale = 0.2;
 413 float hud_dynamic_shake_x[10] = {0,    1, -0.7,  0.5, -0.3,  0.2, -0.1,  0.1,  0.0, 0};
 414 float hud_dynamic_shake_y[10] = {0,  0.4,  0.8, -0.2, -0.6,  0.0,  0.3,  0.1, -0.1, 0};
 415 bool Hud_Shake_Update()
 416 {
 417         if(time - hud_dynamic_shake_time < 0)
 418                 return false;
 419
 420         float anim_speed = 17 + 9 * hud_dynamic_shake_factor;
 421         float elapsed_time = (time - hud_dynamic_shake_time) * anim_speed;
 422         int i = floor(elapsed_time);
 423         if(i >= 9)
 424                 return false;
 425
 426         float f = elapsed_time - i;
 427         hud_dynamic_shake_realofs.x = (1 - f) * hud_dynamic_shake_x[i] + f * hud_dynamic_shake_x[i+1];
 428         hud_dynamic_shake_realofs.y = (1 - f) * hud_dynamic_shake_y[i] + f * hud_dynamic_shake_y[i+1];
 429         hud_dynamic_shake_realofs.z = 0;
 430         hud_dynamic_shake_realofs *= hud_dynamic_shake_factor * autocvar_hud_dynamic_shake_scale;
 431         hud_dynamic_shake_realofs.x = bound(-0.1, hud_dynamic_shake_realofs.x, 0.1) * vid_conwidth;
 432         hud_dynamic_shake_realofs.y = bound(-0.1, hud_dynamic_shake_realofs.y, 0.1) * vid_conheight;
 433         return true;
 434 }
 435
 436 entity CSQCModel_server2csqc(int i);
 437 void calc_followmodel_ofs(entity view);
 438 void Hud_Dynamic_Frame()
 439 {
 440         vector ofs = '0 0 0';
 441         hud_scale = '1 1 0';
 442         hud_shift = '0 0 0';
 443         if (autocvar_hud_dynamic_follow)
 444         {
 445                 entity view = CSQCModel_server2csqc(player_localentnum - 1);
 446                 calc_followmodel_ofs(view);
 447                 ofs = -cl_followmodel_ofs * autocvar_hud_dynamic_follow_scale;
 448                 ofs.x *= autocvar_hud_dynamic_follow_scale_xyz.z;
 449                 ofs.y *= autocvar_hud_dynamic_follow_scale_xyz.x;
 450                 ofs.z *= autocvar_hud_dynamic_follow_scale_xyz.y;
 451
 452                 if (fabs(ofs.x) < 0.001) ofs.x = 0;
 453                 if (fabs(ofs.y) < 0.001) ofs.y = 0;
 454                 if (fabs(ofs.z) < 0.001) ofs.z = 0;
 455                 ofs.x = bound(-0.1, ofs.x, 0.1);
 456                 ofs.y = bound(-0.1, ofs.y, 0.1);
 457                 ofs.z = bound(-0.1, ofs.z, 0.1);
 458
 459                 hud_shift.x = ofs.y * vid_conwidth;
 460                 hud_shift.y = ofs.z * vid_conheight;
 461                 hud_shift.z = ofs.x;
 462
 463                 hud_scale.x = (1 + hud_shift.z);
 464                 hud_scale.y = hud_scale.x;
 465         }
 466
 467         if(autocvar_hud_dynamic_shake > 0)
 468         {
 469                 static float old_health = 0;
 470                 float health = max(-1, STAT(HEALTH));
 471                 if(hud_dynamic_shake_factor == -1) // don't allow the effect for this frame
 472                 {
 473                         hud_dynamic_shake_factor = 0;
 474                         old_health = health;
 475                 }
 476                 else
 477                 {
 478                         float new_hud_dynamic_shake_factor = 0;
 479                         if (old_health - health >= autocvar_hud_dynamic_shake_damage_min
 480                                 && autocvar_hud_dynamic_shake_damage_max > autocvar_hud_dynamic_shake_damage_min
 481                                 && old_health > 0 && !intermission)
 482                         {
 483                                 float m = max(autocvar_hud_dynamic_shake_damage_min, 1);
 484                                 new_hud_dynamic_shake_factor = (old_health - health - m) / (autocvar_hud_dynamic_shake_damage_max - m);
 485                                 if(new_hud_dynamic_shake_factor >= 1)
 486                                         new_hud_dynamic_shake_factor = 1;
 487                                 if(new_hud_dynamic_shake_factor >= hud_dynamic_shake_factor)
 488                                 {
 489                                         hud_dynamic_shake_factor = new_hud_dynamic_shake_factor;
 490                                         hud_dynamic_shake_time = time;
 491                                 }
 492                         }
 493                         old_health = health;
 494                         if(hud_dynamic_shake_factor)
 495                                 if(!Hud_Shake_Update())
 496                                         hud_dynamic_shake_factor = 0;
 497                 }
 498
 499                 if(hud_dynamic_shake_factor > 0)
 500                 {
 501                         hud_shift.x += hud_dynamic_shake_realofs.x;
 502                         hud_shift.y += hud_dynamic_shake_realofs.y;
 503                 }
 504         }
 505
 506         hud_scale_center.x = 0.5 * vid_conwidth;
 507         hud_scale_center.y = 0.5 * vid_conheight;
 508
 509         hud_scale_current = hud_scale;
 510         hud_shift_current = hud_shift;
 511 }
 512
 513 void HUD_Main()
 514 {
 515         int i;
 516         if(hud_configure_menu_open == 1)
 517                 hud_fade_alpha = 1;
 518         else
 519                 hud_fade_alpha = 1 - autocvar__menu_alpha;
 520
 521         HUD_Configure_Frame();
 522
 523         Hud_Dynamic_Frame();
 524
 525         if(scoreboard_fade_alpha == 1)
 526                 if(autocvar__menu_alpha == 1)
 527                         return;
 528
 529         // Drawing stuff
 530         if (hud_skin_prev != autocvar_hud_skin)
 531         {
 532                 if (hud_skin_path)
 533                         strunzone(hud_skin_path);
 534                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 535                 if (hud_skin_prev)
 536                         strunzone(hud_skin_prev);
 537                 hud_skin_prev = strzone(autocvar_hud_skin);
 538         }
 539
 540         // draw the dock
 541         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
 542         {
 543                 int f;
 544                 vector color;
 545                 float hud_dock_color_team = autocvar_hud_dock_color_team;
 546                 if((teamplay) && hud_dock_color_team) {
 547                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
 548                                 color = '1 0 0' * hud_dock_color_team;
 549                         else
 550                                 color = myteamcolors * hud_dock_color_team;
 551                 }
 552                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
 553                         color = '1 0 0' * hud_dock_color_team;
 554                 }
 555                 else
 556                 {
 557                         string hud_dock_color = autocvar_hud_dock_color;
 558                         if(hud_dock_color == "shirt") {
 559                                 f = entcs_GetClientColors(current_player);
 560                                 color = colormapPaletteColor(floor(f / 16), 0);
 561                         }
 562                         else if(hud_dock_color == "pants") {
 563                                 f = entcs_GetClientColors(current_player);
 564                                 color = colormapPaletteColor(f % 16, 1);
 565                         }
 566                         else
 567                                 color = stov(hud_dock_color);
 568                 }
 569
 570                 string pic;
 571                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
 572                 if(precache_pic(pic) == "") {
 573                         pic = strcat(hud_skin_path, "/dock_medium");
 574                         if(precache_pic(pic) == "") {
 575                                 pic = "gfx/hud/default/dock_medium";
 576                         }
 577                 }
 578                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
 579         }
 580
 581         // cache the panel order into the panel_order array
 582         if(autocvar__hud_panelorder != hud_panelorder_prev) {
 583                 for(i = 0; i < hud_panels_COUNT; ++i)
 584                         panel_order[i] = -1;
 585                 string s = "";
 586                 int p_num;
 587                 bool warning = false;
 588                 int argc = tokenize_console(autocvar__hud_panelorder);
 589                 if (argc > hud_panels_COUNT)
 590                         warning = true;
 591                 //first detect wrong/missing panel numbers
 592                 for(i = 0; i < hud_panels_COUNT; ++i) {
 593                         p_num = stoi(argv(i));
 594                         if (p_num >= 0 && p_num < hud_panels_COUNT) { //correct panel number?
 595                                 if (panel_order[p_num] == -1) //found for the first time?
 596                                         s = strcat(s, ftos(p_num), " ");
 597                                 panel_order[p_num] = 1; //mark as found
 598                         }
 599                         else
 600                                 warning = true;
 601                 }
 602                 for(i = 0; i < hud_panels_COUNT; ++i) {
 603                         if (panel_order[i] == -1) {
 604                                 warning = true;
 605                                 s = strcat(s, ftos(i), " "); //add missing panel number
 606                         }
 607                 }
 608                 if (warning)
 609                         LOG_TRACE("Automatically fixed wrong/missing panel numbers in _hud_panelorder");
 610
 611                 cvar_set("_hud_panelorder", s);
 612                 if(hud_panelorder_prev)
 613                         strunzone(hud_panelorder_prev);
 614                 hud_panelorder_prev = strzone(s);
 615
 616                 //now properly set panel_order
 617                 tokenize_console(s);
 618                 for(i = 0; i < hud_panels_COUNT; ++i) {
 619                         panel_order[i] = stof(argv(i));
 620                 }
 621         }
 622
 623         hud_draw_maximized = 0;
 624         // draw panels in the order specified by panel_order array
 625         for(i = hud_panels_COUNT - 1; i >= 0; --i)
 626                 HUD_Panel_Draw(hud_panels_from(panel_order[i]));
 627
 628         HUD_Vehicle();
 629
 630         hud_draw_maximized = 1; // panels that may be maximized must check this var
 631         // draw maximized panels on top
 632         if(hud_panel_radar_maximized)
 633                 HUD_Panel_Draw(HUD_PANEL(RADAR));
 634         if(autocvar__con_chat_maximized)
 635                 HUD_Panel_Draw(HUD_PANEL(CHAT));
 636         if(hud_panel_quickmenu)
 637                 HUD_Panel_Draw(HUD_PANEL(QUICKMENU));
 638         HUD_Panel_Draw(HUD_PANEL(SCOREBOARD));
 639
 640         if (intermission == 2)
 641                 HUD_Reset();
 642
 643         HUD_Configure_PostDraw();
 644
 645         hud_configure_prev = autocvar__hud_configure;
 646 }