qcsrc/client/hud/hud.qc

   1 #include "hud.qh"
   2
   3 #include "panel/scoreboard.qh"
   4 #include "hud_config.qh"
   5 #include "../mapvoting.qh"
   6 #include "../teamradar.qh"
   7 #include <common/minigames/cl_minigames.qh>
   8 #include <common/t_items.qh>
   9 #include <common/deathtypes/all.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/vehicles/all.qh>
  13 #include <common/mutators/mutator/waypoints/all.qh>
  14 #include <common/stats.qh>
  15 #include <lib/csqcmodel/cl_player.qh>
  16 #include <server/mutators/mutator/gamemode_ctf.qh> // TODO: remove
  17
  18
  19 /*
  20 ==================
  21 Misc HUD functions
  22 ==================
  23 */
  24
  25 vector HUD_Get_Num_Color (float hp, float maxvalue)
  26 {
  27         float blinkingamt;
  28         vector color;
  29         if(hp >= maxvalue) {
  30                 color.x = sin(2*M_PI*time);
  31                 color.y = 1;
  32                 color.z = sin(2*M_PI*time);
  33         }
  34         else if(hp > maxvalue * 0.75) {
  35                 color.x = 0.4 - (hp-150)*0.02 * 0.4; //red value between 0.4 -> 0
  36                 color.y = 0.9 + (hp-150)*0.02 * 0.1; // green value between 0.9 -> 1
  37                 color.z = 0;
  38         }
  39         else if(hp > maxvalue * 0.5) {
  40                 color.x = 1 - (hp-100)*0.02 * 0.6; //red value between 1 -> 0.4
  41                 color.y = 1 - (hp-100)*0.02 * 0.1; // green value between 1 -> 0.9
  42                 color.z = 1 - (hp-100)*0.02; // blue value between 1 -> 0
  43         }
  44         else if(hp > maxvalue * 0.25) {
  45                 color.x = 1;
  46                 color.y = 1;
  47                 color.z = 0.2 + (hp-50)*0.02 * 0.8; // blue value between 0.2 -> 1
  48         }
  49         else if(hp > maxvalue * 0.1) {
  50                 color.x = 1;
  51                 color.y = (hp-20)*90/27/100; // green value between 0 -> 1
  52                 color.z = (hp-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
  53         }
  54         else {
  55                 color.x = 1;
  56                 color.y = 0;
  57                 color.z = 0;
  58         }
  59
  60         blinkingamt = (1 - hp/maxvalue/0.25);
  61         if(blinkingamt > 0)
  62         {
  63                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
  64                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
  65                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
  66         }
  67         return color;
  68 }
  69
  70 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
  71 {
  72     TC(int, item_count);
  73         float aspect = size_y / size_x;
  74         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
  75 }
  76
  77 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect)
  78 {
  79     TC(int, item_count);
  80         float columns, rows;
  81         float ratio, best_ratio = 0;
  82         float best_columns = 1, best_rows = 1;
  83         bool vertical = (psize.x / psize.y >= item_aspect);
  84         if(vertical)
  85         {
  86                 psize = eX * psize.y + eY * psize.x;
  87                 item_aspect = 1 / item_aspect;
  88         }
  89
  90         rows = ceil(sqrt(item_count));
  91         columns = ceil(item_count/rows);
  92         while(columns >= 1)
  93         {
  94                 ratio = (psize.x/columns) / (psize.y/rows);
  95                 if(ratio > item_aspect)
  96                         ratio = item_aspect * item_aspect / ratio;
  97
  98                 if(ratio <= best_ratio)
  99                         break; // ratio starts decreasing by now, skip next configurations
 100
 101                 best_columns = columns;
 102                 best_rows = rows;
 103                 best_ratio = ratio;
 104
 105                 if(columns == 1)
 106                         break;
 107
 108                 --columns;
 109                 rows = ceil(item_count/columns);
 110         }
 111
 112         if(vertical)
 113                 return eX * best_rows + eY * best_columns;
 114         else
 115                 return eX * best_columns + eY * best_rows;
 116 }
 117
 118 /*
 119 ==================
 120 HUD panels
 121 ==================
 122 */
 123
 124 void HUD_Panel_LoadCvars()
 125 {
 126         // NOTE: in hud_configure mode cvars must be reloaded every frame
 127         if (panel.update_time <= time)
 128         {
 129                 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos")));
 130                 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size")));
 131                 HUD_Panel_ScalePosSize();
 132                 panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg"));
 133                 panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color"));
 134                 panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team"));
 135                 panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha"));
 136                 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border"));
 137                 panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding"));
 138                 HUD_Panel_GetBg();
 139                 if (panel.current_panel_bg != "0")
 140                 {
 141                         HUD_Panel_GetBgAlpha();
 142                         HUD_Panel_GetBorder();
 143                 }
 144                 HUD_Panel_GetColorTeam();
 145                 HUD_Panel_GetColor();
 146                 HUD_Panel_GetFgAlpha();
 147                 HUD_Panel_GetPadding();
 148                 panel.current_panel_bg_alpha = panel_bg_alpha;
 149                 panel.current_panel_fg_alpha = panel_fg_alpha;
 150                 if (hud_configure_menu_open == 2 && panel == highlightedPanel)
 151                         HUD_Panel_UpdatePosSize_ForMenu();
 152                 else
 153                 {
 154                         panel_bg_alpha *= hud_fade_alpha * panel_fade_alpha;
 155                         panel_fg_alpha *= hud_fade_alpha * panel_fade_alpha;
 156                 }
 157                 panel.current_panel_pos = panel_pos;
 158                 panel.current_panel_size = panel_size;
 159                 panel.current_panel_bg_border = panel_bg_border;
 160                 panel.current_panel_bg_color = panel_bg_color;
 161                 panel.current_panel_bg_color_team = panel_bg_color_team;
 162                 panel.current_panel_bg_padding = panel_bg_padding;
 163                 panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval;
 164                 return;
 165         }
 166
 167         panel_pos = panel.current_panel_pos;
 168         panel_size = panel.current_panel_size;
 169         panel_bg_alpha = panel.current_panel_bg_alpha * hud_fade_alpha * panel_fade_alpha;
 170         panel_bg_border = panel.current_panel_bg_border;
 171         panel_bg_color = panel.current_panel_bg_color;
 172         panel_bg_color_team = panel.current_panel_bg_color_team;
 173         panel_bg_padding = panel.current_panel_bg_padding;
 174         panel_fg_alpha = panel.current_panel_fg_alpha * hud_fade_alpha * panel_fade_alpha;
 175 }
 176
 177 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 178 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 179 {
 180     TC(bool, vertical); TC(int, drawflag);
 181         if(!length_ratio || !theAlpha)
 182                 return;
 183         if(length_ratio > 1)
 184                 length_ratio = 1;
 185         if (baralign == 3)
 186         {
 187                 if(length_ratio < -1)
 188                         length_ratio = -1;
 189         }
 190         else if(length_ratio < 0)
 191                 return;
 192
 193         theOrigin = HUD_Shift(theOrigin);
 194         theSize = HUD_Scale(theSize);
 195
 196         vector square;
 197         vector width, height;
 198         if(vertical) {
 199                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 200                 if(precache_pic(pic) == "") {
 201                         pic = "gfx/hud/default/progressbar_vertical";
 202                 }
 203
 204         if (baralign == 1) // bottom align
 205                         theOrigin.y += (1 - length_ratio) * theSize.y;
 206         else if (baralign == 2) // center align
 207             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 208         else if (baralign == 3) // center align, positive values down, negative up
 209                 {
 210                         theSize.y *= 0.5;
 211                         if (length_ratio > 0)
 212                                 theOrigin.y += theSize.y;
 213                         else
 214                         {
 215                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 216                                 length_ratio = -length_ratio;
 217                         }
 218                 }
 219                 theSize.y *= length_ratio;
 220
 221                 vector bH;
 222                 width = eX * theSize.x;
 223                 height = eY * theSize.y;
 224                 if(theSize.y <= theSize.x * 2)
 225                 {
 226                         // button not high enough
 227                         // draw just upper and lower part then
 228                         square = eY * theSize.y * 0.5;
 229                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 230                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 231                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 232                 }
 233                 else
 234                 {
 235                         square = eY * theSize.x;
 236                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 237                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 238                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 239                 }
 240         } else {
 241                 pic = strcat(hud_skin_path, "/", pic);
 242                 if(precache_pic(pic) == "") {
 243                         pic = "gfx/hud/default/progressbar";
 244                 }
 245
 246                 if (baralign == 1) // right align
 247                         theOrigin.x += (1 - length_ratio) * theSize.x;
 248         else if (baralign == 2) // center align
 249             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 250         else if (baralign == 3) // center align, positive values on the right, negative on the left
 251                 {
 252                         theSize.x *= 0.5;
 253                         if (length_ratio > 0)
 254                                 theOrigin.x += theSize.x;
 255                         else
 256                         {
 257                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 258                                 length_ratio = -length_ratio;
 259                         }
 260                 }
 261                 theSize.x *= length_ratio;
 262
 263                 vector bW;
 264                 width = eX * theSize.x;
 265                 height = eY * theSize.y;
 266                 if(theSize.x <= theSize.y * 2)
 267                 {
 268                         // button not wide enough
 269                         // draw just left and right part then
 270                         square = eX * theSize.x * 0.5;
 271                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 272                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 273                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 274                 }
 275                 else
 276                 {
 277                         square = eX * theSize.y;
 278                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 279                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 280                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 281                 }
 282         }
 283 }
 284
 285 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 286 {
 287     TC(int, drawflag);
 288         if(!theAlpha)
 289                 return;
 290
 291         pos = HUD_Shift(pos);
 292         mySize = HUD_Scale(mySize);
 293
 294         string pic;
 295         pic = strcat(hud_skin_path, "/num_leading");
 296         if(precache_pic(pic) == "") {
 297                 pic = "gfx/hud/default/num_leading";
 298         }
 299
 300         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 301         if(mySize.x/mySize.y > 2)
 302                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 303         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 304 }
 305
 306 void DrawNumIcon_expanding(vector myPos, vector mySize, float theTime, string icon, bool vertical, int icon_right_align, vector color, float theAlpha, float fadelerp)
 307 {
 308     TC(bool, vertical); TC(int, icon_right_align);
 309         vector newPos = '0 0 0', newSize = '0 0 0';
 310         vector picpos, numpos;
 311
 312         if (vertical)
 313         {
 314                 if(mySize.y/mySize.x > 2)
 315                 {
 316                         newSize.y = 2 * mySize.x;
 317                         newSize.x = mySize.x;
 318
 319                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
 320                         newPos.x = myPos.x;
 321                 }
 322                 else
 323                 {
 324                         newSize.x = 1/2 * mySize.y;
 325                         newSize.y = mySize.y;
 326
 327                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
 328                         newPos.y = myPos.y;
 329                 }
 330
 331                 if(icon_right_align)
 332                 {
 333                         numpos = newPos;
 334                         picpos = newPos + eY * newSize.x;
 335                 }
 336                 else
 337                 {
 338                         picpos = newPos;
 339                         numpos = newPos + eY * newSize.x;
 340                 }
 341
 342                 newSize.y /= 2;
 343                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 344                 // make number smaller than icon, it looks better
 345                 // reduce only y to draw numbers with different number of digits with the same y size
 346                 numpos.y += newSize.y * ((1 - 0.7) / 2);
 347                 newSize.y *= 0.7;
 348                 drawstring_aspect(numpos, ftos(theTime), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 349                 return;
 350         }
 351
 352         if(mySize.x/mySize.y > 3)
 353         {
 354                 newSize.x = 3 * mySize.y;
 355                 newSize.y = mySize.y;
 356
 357                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
 358                 newPos.y = myPos.y;
 359         }
 360         else
 361         {
 362                 newSize.y = 1/3 * mySize.x;
 363                 newSize.x = mySize.x;
 364
 365                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
 366                 newPos.x = myPos.x;
 367         }
 368
 369         if(icon_right_align) // right align
 370         {
 371                 numpos = newPos;
 372                 picpos = newPos + eX * 2 * newSize.y;
 373         }
 374         else // left align
 375         {
 376                 numpos = newPos + eX * newSize.y;
 377                 picpos = newPos;
 378         }
 379
 380         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
 381         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
 382         drawstring_aspect_expanding(numpos, ftos(theTime), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
 383         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
 384 }
 385
 386 void DrawNumIcon(vector myPos, vector mySize, float theTime, string icon, bool vertical, int icon_right_align, vector color, float theAlpha)
 387 {
 388     TC(bool, vertical); TC(int, icon_right_align);
 389         DrawNumIcon_expanding(myPos, mySize, theTime, icon, vertical, icon_right_align, color, theAlpha, 0);
 390 }
 391
 392 /*
 393 ==================
 394 Main HUD system
 395 ==================
 396 */
 397
 398 void CSQC_BUMBLE_GUN_HUD();
 399
 400 void HUD_Vehicle()
 401 {
 402         if(autocvar__hud_configure) return;
 403         if(intermission == 2) return;
 404
 405         if(hud == HUD_BUMBLEBEE_GUN)
 406                 CSQC_BUMBLE_GUN_HUD();
 407         else {
 408                 Vehicle info = Vehicles_from(hud);
 409                 info.vr_hud(info);
 410         }
 411 }
 412
 413 void HUD_Panel_Draw(entity panent)
 414 {
 415         panel = panent;
 416         if (autocvar__hud_configure)
 417         {
 418                 if (!(panel.panel_configflags & PANEL_CONFIG_MAIN))
 419                         return;
 420                 panel_fade_alpha = 1;
 421                 Hud_Panel_GetPanelEnabled();
 422                 panel.panel_draw();
 423                 return;
 424         }
 425
 426         bool draw_allowed = false;
 427         if (active_minigame && HUD_MinigameMenu_IsOpened())
 428         {
 429                 if (panel.panel_showflags & PANEL_SHOW_MINIGAME)
 430                         draw_allowed = true;
 431         }
 432         else if(intermission == 2)
 433         {
 434                 if(panel.panel_showflags & PANEL_SHOW_MAPVOTE)
 435                         draw_allowed = true;
 436         }
 437         else if (panel.panel_showflags & PANEL_SHOW_MAINGAME)
 438                 draw_allowed = true;
 439
 440         if (draw_allowed)
 441         {
 442                 if (panel.panel_showflags & PANEL_SHOW_WITH_SB)
 443                         panel_fade_alpha = 1;
 444                 else
 445                 {
 446                         panel_fade_alpha = 1 - scoreboard_fade_alpha;
 447                         if(!panel_fade_alpha)
 448                                 return;
 449                 }
 450                 panel.panel_draw();
 451         }
 452 }
 453
 454 void HUD_Reset()
 455 {
 456         // reset gametype specific icons
 457         if(gametype.m_modicons_reset)
 458                 gametype.m_modicons_reset();
 459 }
 460
 461 float autocvar_hud_dynamic_shake = 1;
 462 float autocvar_hud_dynamic_shake_damage_max = 130;
 463 float autocvar_hud_dynamic_shake_damage_min = 10;
 464 float autocvar_hud_dynamic_shake_scale = 0.2;
 465 float hud_dynamic_shake_x[10] = {0,    1, -0.7,  0.5, -0.3,  0.2, -0.1,  0.1,  0.0, 0};
 466 float hud_dynamic_shake_y[10] = {0,  0.4,  0.8, -0.2, -0.6,  0.0,  0.3,  0.1, -0.1, 0};
 467 bool Hud_Shake_Update()
 468 {
 469         if(time - hud_dynamic_shake_time < 0)
 470                 return false;
 471
 472         float anim_speed = 17 + 9 * hud_dynamic_shake_factor;
 473         float elapsed_time = (time - hud_dynamic_shake_time) * anim_speed;
 474         int i = floor(elapsed_time);
 475         if(i >= 9)
 476                 return false;
 477
 478         float f = elapsed_time - i;
 479         hud_dynamic_shake_realofs.x = (1 - f) * hud_dynamic_shake_x[i] + f * hud_dynamic_shake_x[i+1];
 480         hud_dynamic_shake_realofs.y = (1 - f) * hud_dynamic_shake_y[i] + f * hud_dynamic_shake_y[i+1];
 481         hud_dynamic_shake_realofs.z = 0;
 482         hud_dynamic_shake_realofs *= hud_dynamic_shake_factor * autocvar_hud_dynamic_shake_scale;
 483         hud_dynamic_shake_realofs.x = bound(-0.1, hud_dynamic_shake_realofs.x, 0.1) * vid_conwidth;
 484         hud_dynamic_shake_realofs.y = bound(-0.1, hud_dynamic_shake_realofs.y, 0.1) * vid_conheight;
 485         return true;
 486 }
 487
 488 entity CSQCModel_server2csqc(int i);
 489 void calc_followmodel_ofs(entity view);
 490 void Hud_Dynamic_Frame()
 491 {
 492         vector ofs = '0 0 0';
 493         hud_scale = '1 1 0';
 494         hud_shift = '0 0 0';
 495         if (autocvar_hud_dynamic_follow)
 496         {
 497                 entity view = CSQCModel_server2csqc(player_localentnum - 1);
 498                 calc_followmodel_ofs(view);
 499                 ofs = -cl_followmodel_ofs * autocvar_hud_dynamic_follow_scale;
 500                 ofs.x *= autocvar_hud_dynamic_follow_scale_xyz.z;
 501                 ofs.y *= autocvar_hud_dynamic_follow_scale_xyz.x;
 502                 ofs.z *= autocvar_hud_dynamic_follow_scale_xyz.y;
 503
 504                 if (fabs(ofs.x) < 0.001) ofs.x = 0;
 505                 if (fabs(ofs.y) < 0.001) ofs.y = 0;
 506                 if (fabs(ofs.z) < 0.001) ofs.z = 0;
 507                 ofs.x = bound(-0.1, ofs.x, 0.1);
 508                 ofs.y = bound(-0.1, ofs.y, 0.1);
 509                 ofs.z = bound(-0.1, ofs.z, 0.1);
 510
 511                 hud_shift.x = ofs.y * vid_conwidth;
 512                 hud_shift.y = ofs.z * vid_conheight;
 513                 hud_shift.z = ofs.x;
 514
 515                 hud_scale.x = (1 + hud_shift.z);
 516                 hud_scale.y = hud_scale.x;
 517         }
 518
 519         if(autocvar_hud_dynamic_shake > 0)
 520         {
 521                 static float old_health = 0;
 522                 float health = max(-1, STAT(HEALTH));
 523                 if(hud_dynamic_shake_factor == -1) // don't allow the effect for this frame
 524                 {
 525                         hud_dynamic_shake_factor = 0;
 526                         old_health = health;
 527                 }
 528                 else
 529                 {
 530                         float new_hud_dynamic_shake_factor = 0;
 531                         if (old_health - health >= autocvar_hud_dynamic_shake_damage_min
 532                                 && autocvar_hud_dynamic_shake_damage_max > autocvar_hud_dynamic_shake_damage_min
 533                                 && old_health > 0 && !intermission)
 534                         {
 535                                 float m = max(autocvar_hud_dynamic_shake_damage_min, 1);
 536                                 new_hud_dynamic_shake_factor = (old_health - health - m) / (autocvar_hud_dynamic_shake_damage_max - m);
 537                                 if(new_hud_dynamic_shake_factor >= 1)
 538                                         new_hud_dynamic_shake_factor = 1;
 539                                 if(new_hud_dynamic_shake_factor >= hud_dynamic_shake_factor)
 540                                 {
 541                                         hud_dynamic_shake_factor = new_hud_dynamic_shake_factor;
 542                                         hud_dynamic_shake_time = time;
 543                                 }
 544                         }
 545                         old_health = health;
 546                         if(hud_dynamic_shake_factor)
 547                                 if(!Hud_Shake_Update())
 548                                         hud_dynamic_shake_factor = 0;
 549                 }
 550
 551                 if(hud_dynamic_shake_factor > 0)
 552                 {
 553                         hud_shift.x += hud_dynamic_shake_realofs.x;
 554                         hud_shift.y += hud_dynamic_shake_realofs.y;
 555                 }
 556         }
 557
 558         hud_scale_center.x = 0.5 * vid_conwidth;
 559         hud_scale_center.y = 0.5 * vid_conheight;
 560
 561         hud_scale_current = hud_scale;
 562         hud_shift_current = hud_shift;
 563 }
 564
 565 void HUD_Main()
 566 {
 567         int i;
 568         if(hud_configure_menu_open == 1)
 569                 hud_fade_alpha = 1;
 570         else
 571                 hud_fade_alpha = 1 - autocvar__menu_alpha;
 572
 573         HUD_Configure_Frame();
 574
 575         Hud_Dynamic_Frame();
 576
 577         if(scoreboard_fade_alpha == 1)
 578                 if(autocvar__menu_alpha == 1)
 579                         return;
 580
 581         // Drawing stuff
 582         if (hud_skin_prev != autocvar_hud_skin)
 583         {
 584                 if (hud_skin_path)
 585                         strunzone(hud_skin_path);
 586                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 587                 if (hud_skin_prev)
 588                         strunzone(hud_skin_prev);
 589                 hud_skin_prev = strzone(autocvar_hud_skin);
 590         }
 591
 592         // draw the dock
 593         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
 594         {
 595                 int f;
 596                 vector color;
 597                 float hud_dock_color_team = autocvar_hud_dock_color_team;
 598                 if((teamplay) && hud_dock_color_team) {
 599                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
 600                                 color = '1 0 0' * hud_dock_color_team;
 601                         else
 602                                 color = myteamcolors * hud_dock_color_team;
 603                 }
 604                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
 605                         color = '1 0 0' * hud_dock_color_team;
 606                 }
 607                 else
 608                 {
 609                         string hud_dock_color = autocvar_hud_dock_color;
 610                         if(hud_dock_color == "shirt") {
 611                                 f = entcs_GetClientColors(current_player);
 612                                 color = colormapPaletteColor(floor(f / 16), 0);
 613                         }
 614                         else if(hud_dock_color == "pants") {
 615                                 f = entcs_GetClientColors(current_player);
 616                                 color = colormapPaletteColor(f % 16, 1);
 617                         }
 618                         else
 619                                 color = stov(hud_dock_color);
 620                 }
 621
 622                 string pic;
 623                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
 624                 if(precache_pic(pic) == "") {
 625                         pic = strcat(hud_skin_path, "/dock_medium");
 626                         if(precache_pic(pic) == "") {
 627                                 pic = "gfx/hud/default/dock_medium";
 628                         }
 629                 }
 630                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
 631         }
 632
 633         // cache the panel order into the panel_order array
 634         if(autocvar__hud_panelorder != hud_panelorder_prev) {
 635                 for(i = 0; i < hud_panels_COUNT; ++i)
 636                         panel_order[i] = -1;
 637                 string s = "";
 638                 int p_num;
 639                 bool warning = false;
 640                 int argc = tokenize_console(autocvar__hud_panelorder);
 641                 if (argc > hud_panels_COUNT)
 642                         warning = true;
 643                 //first detect wrong/missing panel numbers
 644                 for(i = 0; i < hud_panels_COUNT; ++i) {
 645                         p_num = stoi(argv(i));
 646                         if (p_num >= 0 && p_num < hud_panels_COUNT) { //correct panel number?
 647                                 if (panel_order[p_num] == -1) //found for the first time?
 648                                         s = strcat(s, ftos(p_num), " ");
 649                                 panel_order[p_num] = 1; //mark as found
 650                         }
 651                         else
 652                                 warning = true;
 653                 }
 654                 for(i = 0; i < hud_panels_COUNT; ++i) {
 655                         if (panel_order[i] == -1) {
 656                                 warning = true;
 657                                 s = strcat(s, ftos(i), " "); //add missing panel number
 658                         }
 659                 }
 660                 if (warning)
 661                         LOG_TRACE("Automatically fixed wrong/missing panel numbers in _hud_panelorder");
 662
 663                 cvar_set("_hud_panelorder", s);
 664                 if(hud_panelorder_prev)
 665                         strunzone(hud_panelorder_prev);
 666                 hud_panelorder_prev = strzone(s);
 667
 668                 //now properly set panel_order
 669                 tokenize_console(s);
 670                 for(i = 0; i < hud_panels_COUNT; ++i) {
 671                         panel_order[i] = stof(argv(i));
 672                 }
 673         }
 674
 675         hud_draw_maximized = 0;
 676         // draw panels in the order specified by panel_order array
 677         for(i = hud_panels_COUNT - 1; i >= 0; --i)
 678                 HUD_Panel_Draw(hud_panels_from(panel_order[i]));
 679
 680         HUD_Vehicle();
 681
 682         hud_draw_maximized = 1; // panels that may be maximized must check this var
 683         // draw maximized panels on top
 684         if(hud_panel_radar_maximized)
 685                 HUD_Panel_Draw(HUD_PANEL(RADAR));
 686         if(autocvar__con_chat_maximized)
 687                 HUD_Panel_Draw(HUD_PANEL(CHAT));
 688         if(hud_panel_quickmenu)
 689                 HUD_Panel_Draw(HUD_PANEL(QUICKMENU));
 690         HUD_Panel_Draw(HUD_PANEL(SCOREBOARD));
 691
 692         if (intermission == 2)
 693                 HUD_Reset();
 694
 695         HUD_Configure_PostDraw();
 696
 697         hud_configure_prev = autocvar__hud_configure;
 698 }