Makefile: use `-I.`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / hud / hud_config.qc
1 #include "hud_config.qh"
2
3 #include "hud.qh"
4
5 #define HUD_Write(s) fputs(fh, s)
6 #define HUD_Write_Cvar(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
7 #define HUD_Write_PanelCvar(cvar_suf) HUD_Write_Cvar(strcat("hud_panel_", panel.panel_name, cvar_suf))
8 // Save the config
9 void HUD_Panel_ExportCfg(string cfgname)
10 {
11         float fh;
12         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
13         fh = fopen(filename, FILE_WRITE);
14         if(fh >= 0)
15         {
16                 HUD_Write("//title \n");
17                 HUD_Write("//author \n");
18                 HUD_Write("\n");
19                 HUD_Write_Cvar("hud_skin");
20                 HUD_Write_Cvar("hud_panel_bg");
21                 HUD_Write_Cvar("hud_panel_bg_color");
22                 HUD_Write_Cvar("hud_panel_bg_color_team");
23                 HUD_Write_Cvar("hud_panel_bg_alpha");
24                 HUD_Write_Cvar("hud_panel_bg_border");
25                 HUD_Write_Cvar("hud_panel_bg_padding");
26                 HUD_Write_Cvar("hud_panel_fg_alpha");
27                 HUD_Write("\n");
28
29                 HUD_Write_Cvar("hud_dock");
30                 HUD_Write_Cvar("hud_dock_color");
31                 HUD_Write_Cvar("hud_dock_color_team");
32                 HUD_Write_Cvar("hud_dock_alpha");
33                 HUD_Write("\n");
34
35                 HUD_Write_Cvar("hud_progressbar_alpha");
36                 HUD_Write_Cvar("hud_progressbar_strength_color");
37                 HUD_Write_Cvar("hud_progressbar_superweapons_color");
38                 HUD_Write_Cvar("hud_progressbar_shield_color");
39                 HUD_Write_Cvar("hud_progressbar_health_color");
40                 HUD_Write_Cvar("hud_progressbar_armor_color");
41                 HUD_Write_Cvar("hud_progressbar_fuel_color");
42                 HUD_Write_Cvar("hud_progressbar_nexball_color");
43                 HUD_Write_Cvar("hud_progressbar_speed_color");
44                 HUD_Write_Cvar("hud_progressbar_acceleration_color");
45                 HUD_Write_Cvar("hud_progressbar_acceleration_neg_color");
46                 HUD_Write_Cvar("hud_progressbar_vehicles_ammo1_color");
47                 HUD_Write_Cvar("hud_progressbar_vehicles_ammo2_color");
48                 HUD_Write("\n");
49
50                 HUD_Write_Cvar("_hud_panelorder");
51                 HUD_Write("\n");
52
53                 HUD_Write_Cvar("hud_configure_grid");
54                 HUD_Write_Cvar("hud_configure_grid_xsize");
55                 HUD_Write_Cvar("hud_configure_grid_ysize");
56                 HUD_Write("\n");
57
58                 // common cvars for all panels
59                 for (int i = 0; i < hud_panels_COUNT; ++i)
60                 {
61                         panel = hud_panels_from(i);
62
63                         HUD_Write_PanelCvar("");
64                         HUD_Write_PanelCvar("_pos");
65                         HUD_Write_PanelCvar("_size");
66                         HUD_Write_PanelCvar("_bg");
67                         HUD_Write_PanelCvar("_bg_color");
68                         HUD_Write_PanelCvar("_bg_color_team");
69                         HUD_Write_PanelCvar("_bg_alpha");
70                         HUD_Write_PanelCvar("_bg_border");
71                         HUD_Write_PanelCvar("_bg_padding");
72                         switch(panel) {
73                                 case HUD_PANEL_WEAPONS:
74                                         HUD_Write_PanelCvar("_accuracy");
75                                         HUD_Write_PanelCvar("_label");
76                                         HUD_Write_PanelCvar("_label_scale");
77                                         HUD_Write_PanelCvar("_complainbubble");
78                                         HUD_Write_PanelCvar("_complainbubble_padding");
79                                         HUD_Write_PanelCvar("_complainbubble_time");
80                                         HUD_Write_PanelCvar("_complainbubble_fadetime");
81                                         HUD_Write_PanelCvar("_complainbubble_color_outofammo");
82                                         HUD_Write_PanelCvar("_complainbubble_color_donthave");
83                                         HUD_Write_PanelCvar("_complainbubble_color_unavailable");
84                                         HUD_Write_PanelCvar("_ammo");
85                                         HUD_Write_PanelCvar("_ammo_color");
86                                         HUD_Write_PanelCvar("_ammo_alpha");
87                                         HUD_Write_PanelCvar("_aspect");
88                                         HUD_Write_PanelCvar("_timeout");
89                                         HUD_Write_PanelCvar("_timeout_effect");
90                                         HUD_Write_PanelCvar("_timeout_fadebgmin");
91                                         HUD_Write_PanelCvar("_timeout_fadefgmin");
92                                         HUD_Write_PanelCvar("_timeout_speed_in");
93                                         HUD_Write_PanelCvar("_timeout_speed_out");
94                                         HUD_Write_PanelCvar("_onlyowned");
95                                         HUD_Write_PanelCvar("_noncurrent_alpha");
96                                         HUD_Write_PanelCvar("_noncurrent_scale");
97                                         break;
98                                 case HUD_PANEL_AMMO:
99                                         HUD_Write_PanelCvar("_onlycurrent");
100                                         HUD_Write_PanelCvar("_noncurrent_alpha");
101                                         HUD_Write_PanelCvar("_noncurrent_scale");
102                                         HUD_Write_PanelCvar("_iconalign");
103                                         HUD_Write_PanelCvar("_progressbar");
104                                         HUD_Write_PanelCvar("_progressbar_name");
105                                         HUD_Write_PanelCvar("_progressbar_xoffset");
106                                         HUD_Write_PanelCvar("_text");
107                                         break;
108                                 case HUD_PANEL_POWERUPS:
109                                         HUD_Write_PanelCvar("_iconalign");
110                                         HUD_Write_PanelCvar("_baralign");
111                                         HUD_Write_PanelCvar("_progressbar");
112                                         HUD_Write_PanelCvar("_text");
113                                         break;
114                                 case HUD_PANEL_HEALTHARMOR:
115                                         HUD_Write_PanelCvar("_flip");
116                                         HUD_Write_PanelCvar("_iconalign");
117                                         HUD_Write_PanelCvar("_baralign");
118                                         HUD_Write_PanelCvar("_progressbar");
119                                         HUD_Write_PanelCvar("_progressbar_health");
120                                         HUD_Write_PanelCvar("_progressbar_armor");
121                                         HUD_Write_PanelCvar("_progressbar_gfx");
122                                         HUD_Write_PanelCvar("_progressbar_gfx_smooth");
123                                         HUD_Write_PanelCvar("_text");
124                                         break;
125                                 case HUD_PANEL_NOTIFY:
126                                         HUD_Write_PanelCvar("_flip");
127                                         HUD_Write_PanelCvar("_fontsize");
128                                         HUD_Write_PanelCvar("_time");
129                                         HUD_Write_PanelCvar("_fadetime");
130                                         HUD_Write_PanelCvar("_icon_aspect");
131                                         break;
132                                 case HUD_PANEL_TIMER:
133                                         break;
134                                 case HUD_PANEL_RADAR:
135                                         HUD_Write_PanelCvar("_foreground_alpha");
136                                         HUD_Write_PanelCvar("_rotation");
137                                         HUD_Write_PanelCvar("_zoommode");
138                                         HUD_Write_PanelCvar("_scale");
139                                         HUD_Write_PanelCvar("_maximized_scale");
140                                         HUD_Write_PanelCvar("_maximized_size");
141                                         HUD_Write_PanelCvar("_maximized_rotation");
142                                         HUD_Write_PanelCvar("_maximized_zoommode");
143                                         break;
144                                 case HUD_PANEL_SCORE:
145                                         HUD_Write_PanelCvar("_rankings");
146                                         break;
147                                 case HUD_PANEL_VOTE:
148                                         HUD_Write_PanelCvar("_alreadyvoted_alpha");
149                                         break;
150                                 case HUD_PANEL_MODICONS:
151                                         HUD_Write_PanelCvar("_ca_layout");
152                                         HUD_Write_PanelCvar("_dom_layout");
153                                         HUD_Write_PanelCvar("_freezetag_layout");
154                                         break;
155                                 case HUD_PANEL_PRESSEDKEYS:
156                                         HUD_Write_PanelCvar("_aspect");
157                                         HUD_Write_PanelCvar("_attack");
158                                         break;
159                                 case HUD_PANEL_ENGINEINFO:
160                                         HUD_Write_PanelCvar("_framecounter_time");
161                                         HUD_Write_PanelCvar("_framecounter_decimals");
162                                         break;
163                                 case HUD_PANEL_INFOMESSAGES:
164                                         HUD_Write_PanelCvar("_flip");
165                                         break;
166                                 case HUD_PANEL_PHYSICS:
167                                         HUD_Write_PanelCvar("_speed_unit_show");
168                                         HUD_Write_PanelCvar("_speed_max");
169                                         HUD_Write_PanelCvar("_speed_vertical");
170                                         HUD_Write_PanelCvar("_topspeed");
171                                         HUD_Write_PanelCvar("_topspeed_time");
172                                         HUD_Write_PanelCvar("_acceleration_max");
173                                         HUD_Write_PanelCvar("_acceleration_vertical");
174                                         HUD_Write_PanelCvar("_flip");
175                                         HUD_Write_PanelCvar("_baralign");
176                                         HUD_Write_PanelCvar("_progressbar");
177                                         HUD_Write_PanelCvar("_acceleration_progressbar_mode");
178                                         HUD_Write_PanelCvar("_acceleration_progressbar_scale");
179                                         HUD_Write_PanelCvar("_acceleration_progressbar_nonlinear");
180                                         HUD_Write_PanelCvar("_text");
181                                         HUD_Write_PanelCvar("_text_scale");
182                                         break;
183                                 case HUD_PANEL_CENTERPRINT:
184                                         HUD_Write_PanelCvar("_align");
185                                         HUD_Write_PanelCvar("_flip");
186                                         HUD_Write_PanelCvar("_fontscale");
187                                         HUD_Write_PanelCvar("_time");
188                                         HUD_Write_PanelCvar("_fade_in");
189                                         HUD_Write_PanelCvar("_fade_out");
190                                         HUD_Write_PanelCvar("_fade_subsequent");
191                                         HUD_Write_PanelCvar("_fade_subsequent_passone");
192                                         HUD_Write_PanelCvar("_fade_subsequent_passone_minalpha");
193                                         HUD_Write_PanelCvar("_fade_subsequent_passtwo");
194                                         HUD_Write_PanelCvar("_fade_subsequent_passtwo_minalpha");
195                                         HUD_Write_PanelCvar("_fade_subsequent_minfontsize");
196                                         HUD_Write_PanelCvar("_fade_minfontsize");
197                                         break;
198                                 case HUD_PANEL_ITEMSTIME:
199                                         HUD_Write_PanelCvar("_iconalign");
200                                         HUD_Write_PanelCvar("_progressbar");
201                                         HUD_Write_PanelCvar("_progressbar_name");
202                                         HUD_Write_PanelCvar("_progressbar_reduced");
203                                         HUD_Write_PanelCvar("_text");
204                                         HUD_Write_PanelCvar("_ratio");
205                                         HUD_Write_PanelCvar("_dynamicsize");
206                                         break;
207                                 case HUD_PANEL_QUICKMENU:
208                                         HUD_Write_PanelCvar("_align");
209                                         break;
210                         }
211                         HUD_Write("\n");
212                 }
213                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
214
215                 LOG_INFOF(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
216                 fclose(fh);
217         }
218         else
219                 LOG_INFOF(_("^1Couldn't write to %s\n"), filename);
220 }
221
222 void HUD_Configure_Exit_Force()
223 {
224         if (menu_enabled)
225         {
226                 menu_enabled = 0;
227                 localcmd("togglemenu\n");
228         }
229         cvar_set("_hud_configure", "0");
230 }
231
232 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
233 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
234 {
235         vector myCenter, targCenter;
236         vector myTarget = myPos;
237         int i;
238         for (i = 0; i < hud_panels_COUNT; ++i) {
239                 panel = hud_panels_from(i);
240                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
241                 if(panel == highlightedPanel) continue;
242                 HUD_Panel_UpdatePosSize();
243                 if(!panel_enabled) continue;
244
245                 panel_pos -= '1 1 0' * panel_bg_border;
246                 panel_size += '2 2 0' * panel_bg_border;
247
248                 if(myPos.y + mySize.y < panel_pos.y)
249                         continue;
250                 if(myPos.y > panel_pos.y + panel_size.y)
251                         continue;
252
253                 if(myPos.x + mySize.x < panel_pos.x)
254                         continue;
255                 if(myPos.x > panel_pos.x + panel_size.x)
256                         continue;
257
258                 // OK, there IS a collision.
259
260                 myCenter.x = myPos.x + 0.5 * mySize.x;
261                 myCenter.y = myPos.y + 0.5 * mySize.y;
262
263                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
264                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
265
266                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
267                 {
268                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
269                                 myTarget.x = panel_pos.x - mySize.x;
270                         else // push it upwards
271                                 myTarget.y = panel_pos.y - mySize.y;
272                 }
273                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
274                 {
275                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
276                                 myTarget.x = panel_pos.x + panel_size.x;
277                         else // push it upwards
278                                 myTarget.y = panel_pos.y - mySize.y;
279                 }
280                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
281                 {
282                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
283                                 myTarget.x = panel_pos.x - mySize.x;
284                         else // push it downwards
285                                 myTarget.y = panel_pos.y + panel_size.y;
286                 }
287                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
288                 {
289                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
290                                 myTarget.x = panel_pos.x + panel_size.x;
291                         else // push it downwards
292                                 myTarget.y = panel_pos.y + panel_size.y;
293                 }
294                 //if(cvar("hud_configure_checkcollisions_debug"))
295                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
296         }
297
298         return myTarget;
299 }
300
301 void HUD_Panel_SetPos(vector pos)
302 {
303         panel = highlightedPanel;
304         HUD_Panel_UpdatePosSize();
305         vector mySize;
306         mySize = panel_size;
307
308         //if(cvar("hud_configure_checkcollisions_debug"))
309                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
310
311         if(autocvar_hud_configure_grid)
312         {
313                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
314                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
315         }
316
317         if(hud_configure_checkcollisions)
318                 pos = HUD_Panel_CheckMove(pos, mySize);
319
320         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
321         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
322
323         string s;
324         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
325
326         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
327 }
328
329 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
330 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
331         vector targEndPos;
332         vector dist;
333         float ratio = mySize.x/mySize.y;
334         int i;
335         for (i = 0; i < hud_panels_COUNT; ++i) {
336                 panel = hud_panels_from(i);
337                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
338                 if(panel == highlightedPanel) continue;
339                 HUD_Panel_UpdatePosSize();
340                 if(!panel_enabled) continue;
341
342                 panel_pos -= '1 1 0' * panel_bg_border;
343                 panel_size += '2 2 0' * panel_bg_border;
344
345                 targEndPos = panel_pos + panel_size;
346
347                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
348                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
349                         continue;
350
351                 if (resizeCorner == 1)
352                 {
353                         // check if this panel is on our way
354                         if (resizeorigin.x <= panel_pos.x)
355                                 continue;
356                         if (resizeorigin.y <= panel_pos.y)
357                                 continue;
358                         if (targEndPos.x <= resizeorigin.x - mySize.x)
359                                 continue;
360                         if (targEndPos.y <= resizeorigin.y - mySize.y)
361                                 continue;
362
363                         // there is a collision:
364                         // detect which side of the panel we are facing is actually limiting the resizing
365                         // (which side the resize direction finds for first) and reduce the size up to there
366                         //
367                         // dist is the distance between resizeorigin and the "analogous" point of the panel
368                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
369                         dist.x = resizeorigin.x - targEndPos.x;
370                         dist.y = resizeorigin.y - targEndPos.y;
371                         if (dist.y <= 0 || dist.x / dist.y > ratio)
372                                 mySize.x = min(mySize.x, dist.x);
373                         else
374                                 mySize.y = min(mySize.y, dist.y);
375                 }
376                 else if (resizeCorner == 2)
377                 {
378                         if (resizeorigin.x >= targEndPos.x)
379                                 continue;
380                         if (resizeorigin.y <= panel_pos.y)
381                                 continue;
382                         if (panel_pos.x >= resizeorigin.x + mySize.x)
383                                 continue;
384                         if (targEndPos.y <= resizeorigin.y - mySize.y)
385                                 continue;
386
387                         dist.x = panel_pos.x - resizeorigin.x;
388                         dist.y = resizeorigin.y - targEndPos.y;
389                         if (dist.y <= 0 || dist.x / dist.y > ratio)
390                                 mySize.x = min(mySize.x, dist.x);
391                         else
392                                 mySize.y = min(mySize.y, dist.y);
393                 }
394                 else if (resizeCorner == 3)
395                 {
396                         if (resizeorigin.x <= panel_pos.x)
397                                 continue;
398                         if (resizeorigin.y >= targEndPos.y)
399                                 continue;
400                         if (targEndPos.x <= resizeorigin.x - mySize.x)
401                                 continue;
402                         if (panel_pos.y >= resizeorigin.y + mySize.y)
403                                 continue;
404
405                         dist.x = resizeorigin.x - targEndPos.x;
406                         dist.y = panel_pos.y - resizeorigin.y;
407                         if (dist.y <= 0 || dist.x / dist.y > ratio)
408                                 mySize.x = min(mySize.x, dist.x);
409                         else
410                                 mySize.y = min(mySize.y, dist.y);
411                 }
412                 else if (resizeCorner == 4)
413                 {
414                         if (resizeorigin.x >= targEndPos.x)
415                                 continue;
416                         if (resizeorigin.y >= targEndPos.y)
417                                 continue;
418                         if (panel_pos.x >= resizeorigin.x + mySize.x)
419                                 continue;
420                         if (panel_pos.y >= resizeorigin.y + mySize.y)
421                                 continue;
422
423                         dist.x = panel_pos.x - resizeorigin.x;
424                         dist.y = panel_pos.y - resizeorigin.y;
425                         if (dist.y <= 0 || dist.x / dist.y > ratio)
426                                 mySize.x = min(mySize.x, dist.x);
427                         else
428                                 mySize.y = min(mySize.y, dist.y);
429                 }
430                 //if(cvar("hud_configure_checkcollisions_debug"))
431                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
432         }
433
434         return mySize;
435 }
436
437 void HUD_Panel_SetPosSize(vector mySize)
438 {
439         panel = highlightedPanel;
440         HUD_Panel_UpdatePosSize();
441         vector resizeorigin = panel_click_resizeorigin;
442         vector myPos;
443
444         // minimum panel size cap
445         mySize.x = max(0.025 * vid_conwidth, mySize.x);
446         mySize.y = max(0.025 * vid_conheight, mySize.y);
447
448         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
449         {
450                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
451                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
452         }
453
454         // collision testing|
455         // -----------------+
456
457         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
458         if(resizeCorner == 1) {
459                 myPos.x = resizeorigin.x - mySize.x;
460                 myPos.y = resizeorigin.y - mySize.y;
461         } else if(resizeCorner == 2) {
462                 myPos.x = resizeorigin.x;
463                 myPos.y = resizeorigin.y - mySize.y;
464         } else if(resizeCorner == 3) {
465                 myPos.x = resizeorigin.x - mySize.x;
466                 myPos.y = resizeorigin.y;
467         } else { // resizeCorner == 4
468                 myPos.x = resizeorigin.x;
469                 myPos.y = resizeorigin.y;
470         }
471
472         // left/top screen edges
473         if(myPos.x < 0)
474                 mySize.x = mySize.x + myPos.x;
475         if(myPos.y < 0)
476                 mySize.y = mySize.y + myPos.y;
477
478         // bottom/right screen edges
479         if(myPos.x + mySize.x > vid_conwidth)
480                 mySize.x = vid_conwidth - myPos.x;
481         if(myPos.y + mySize.y > vid_conheight)
482                 mySize.y = vid_conheight - myPos.y;
483
484         //if(cvar("hud_configure_checkcollisions_debug"))
485                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
486
487         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
488         if(autocvar_hud_configure_grid)
489         {
490                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
491                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
492         }
493
494         if(hud_configure_checkcollisions)
495                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
496
497         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
498         mySize.x = max(0.025 * vid_conwidth, mySize.x);
499         mySize.y = max(0.025 * vid_conheight, mySize.y);
500
501         // do another pos check, as size might have changed by now
502         if(resizeCorner == 1) {
503                 myPos.x = resizeorigin.x - mySize.x;
504                 myPos.y = resizeorigin.y - mySize.y;
505         } else if(resizeCorner == 2) {
506                 myPos.x = resizeorigin.x;
507                 myPos.y = resizeorigin.y - mySize.y;
508         } else if(resizeCorner == 3) {
509                 myPos.x = resizeorigin.x - mySize.x;
510                 myPos.y = resizeorigin.y;
511         } else { // resizeCorner == 4
512                 myPos.x = resizeorigin.x;
513                 myPos.y = resizeorigin.y;
514         }
515
516         //if(cvar("hud_configure_checkcollisions_debug"))
517                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
518
519         string s;
520         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
521         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
522
523         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
524         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
525 }
526
527 float pressed_key_time;
528 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
529 void HUD_Panel_Arrow_Action(float nPrimary)
530 {
531         if(!highlightedPanel)
532                 return;
533
534         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
535
536         float step;
537         if(autocvar_hud_configure_grid)
538         {
539                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
540                 {
541                         if (hudShiftState & S_SHIFT)
542                                 step = hud_configure_realGridSize.y;
543                         else
544                                 step = 2 * hud_configure_realGridSize.y;
545                 }
546                 else
547                 {
548                         if (hudShiftState & S_SHIFT)
549                                 step = hud_configure_realGridSize.x;
550                         else
551                                 step = 2 * hud_configure_realGridSize.x;
552                 }
553         }
554         else
555         {
556                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
557                         step = vid_conheight;
558                 else
559                         step = vid_conwidth;
560                 if (hudShiftState & S_SHIFT)
561                         step = (step / 256); // more precision
562                 else
563                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
564         }
565
566         panel = highlightedPanel;
567         HUD_Panel_UpdatePosSize();
568
569         highlightedPanel_initial_pos = panel_pos;
570         highlightedPanel_initial_size = panel_size;
571
572         if (hudShiftState & S_ALT) // resize
573         {
574                 if(nPrimary == K_UPARROW)
575                         resizeCorner = 1;
576                 else if(nPrimary == K_RIGHTARROW)
577                         resizeCorner = 2;
578                 else if(nPrimary == K_LEFTARROW)
579                         resizeCorner = 3;
580                 else // if(nPrimary == K_DOWNARROW)
581                         resizeCorner = 4;
582
583                 // ctrl+arrow reduces the size, instead of increasing it
584                 // Note that ctrl disables collisions check too, but it's fine
585                 // since we don't collide with anything reducing the size
586                 if (hudShiftState & S_CTRL) {
587                         step = -step;
588                         resizeCorner = 5 - resizeCorner;
589                 }
590
591                 vector mySize;
592                 mySize = panel_size;
593                 panel_click_resizeorigin = panel_pos;
594                 if(resizeCorner == 1) {
595                         panel_click_resizeorigin += mySize;
596                         mySize.y += step;
597                 } else if(resizeCorner == 2) {
598                         panel_click_resizeorigin.y += mySize.y;
599                         mySize.x += step;
600                 } else if(resizeCorner == 3) {
601                         panel_click_resizeorigin.x += mySize.x;
602                         mySize.x += step;
603                 } else { // resizeCorner == 4
604                         mySize.y += step;
605                 }
606                 HUD_Panel_SetPosSize(mySize);
607         }
608         else // move
609         {
610                 vector pos;
611                 pos = panel_pos;
612                 if(nPrimary == K_UPARROW)
613                         pos.y -= step;
614                 else if(nPrimary == K_DOWNARROW)
615                         pos.y += step;
616                 else if(nPrimary == K_LEFTARROW)
617                         pos.x -= step;
618                 else // if(nPrimary == K_RIGHTARROW)
619                         pos.x += step;
620
621                 HUD_Panel_SetPos(pos);
622         }
623
624         panel = highlightedPanel;
625         HUD_Panel_UpdatePosSize();
626
627         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
628         {
629                 // backup!
630                 panel_pos_backup = highlightedPanel_initial_pos;
631                 panel_size_backup = highlightedPanel_initial_size;
632                 highlightedPanel_backup = highlightedPanel;
633         }
634 }
635
636 void HUD_Panel_EnableMenu();
637 entity tab_panels[hud_panels_MAX];
638 entity tab_panel;
639 vector tab_panel_pos;
640 float tab_backward;
641 void HUD_Panel_FirstInDrawQ(float id);
642 void reset_tab_panels()
643 {
644         int i;
645         for(i = 0; i < hud_panels_COUNT; ++i)
646                 tab_panels[i] = world;
647 }
648 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
649 {
650         string s;
651
652         if(bInputType == 2)
653                 return false;
654
655         if(!autocvar__hud_configure)
656                 return false;
657
658         if(bInputType == 3)
659         {
660                 mousepos.x = nPrimary;
661                 mousepos.y = nSecondary;
662                 return true;
663         }
664
665         // block any input while a menu dialog is fading
666         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
667         if(autocvar__menu_alpha)
668         {
669                 hudShiftState = 0;
670                 mouseClicked = 0;
671                 return true;
672         }
673
674         // allow console bind to work
675         string con_keys;
676         float keys;
677         con_keys = findkeysforcommand("toggleconsole", 0);
678         keys = tokenize(con_keys); // findkeysforcommand returns data for this
679
680         bool hit_con_bind = false;
681         int i;
682         for (i = 0; i < keys; ++i)
683         {
684                 if(nPrimary == stof(argv(i)))
685                         hit_con_bind = true;
686         }
687
688         if(bInputType == 0) {
689                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
690                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
691                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
692         }
693         else if(bInputType == 1) {
694                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
695                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
696                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
697         }
698
699         if(nPrimary == K_CTRL)
700         {
701                 if (bInputType == 1) //ctrl has been released
702                 {
703                         if (tab_panel)
704                         {
705                                 //switch to selected panel
706                                 highlightedPanel = tab_panel;
707                                 highlightedAction = 0;
708                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
709                         }
710                         tab_panel = world;
711                         reset_tab_panels();
712                 }
713         }
714
715         if(nPrimary == K_MOUSE1)
716         {
717                 if(bInputType == 0) // key pressed
718                         mouseClicked |= S_MOUSE1;
719                 else if(bInputType == 1) // key released
720                         mouseClicked -= (mouseClicked & S_MOUSE1);
721         }
722         else if(nPrimary == K_MOUSE2)
723         {
724                 if(bInputType == 0) // key pressed
725                         mouseClicked |= S_MOUSE2;
726                 else if(bInputType == 1) // key released
727                         mouseClicked -= (mouseClicked & S_MOUSE2);
728         }
729         else if(nPrimary == K_ESCAPE)
730         {
731                 if (bInputType == 1)
732                         return true;
733                 menu_enabled = 1;
734                 localcmd("menu_showhudexit\n");
735         }
736         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
737         {
738                 if (bInputType == 1)
739                         return true;
740                 if (!menu_enabled)
741                         cvar_set("_hud_configure", "0");
742         }
743         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // switch panel
744         {
745                 if (bInputType == 1 || mouseClicked)
746                         return true;
747
748                 // FIXME minor bug: if a panel is highlighted, has the same pos_x and
749                 // lays in the same level of another panel then the next consecutive
750                 // CTRL TAB presses will reselect once more the highlighted panel
751
752                 entity starting_panel;
753                 entity old_tab_panel = tab_panel;
754                 if (!tab_panel) //first press of TAB
755                 {
756                         if (highlightedPanel)
757                         {
758                                 panel = highlightedPanel;
759                                 HUD_Panel_UpdatePosSize();
760                         }
761                         else
762                                 panel_pos = '0 0 0';
763                         starting_panel = highlightedPanel;
764                         tab_panel_pos = panel_pos; //to compute level
765                 }
766                 else
767                 {
768                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
769                                 reset_tab_panels();
770                         starting_panel = tab_panel;
771                 }
772                 tab_backward = (hudShiftState & S_SHIFT);
773
774                 float k, level = 0, start_posX;
775                 vector candidate_pos = '0 0 0';
776                 const float LEVELS_NUM = 4;
777                 float level_height = vid_conheight / LEVELS_NUM;
778 :find_tab_panel
779                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
780                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
781                 start_posX = tab_panel_pos.x;
782                 tab_panel = world;
783                 k=0;
784                 while(++k)
785                 {
786                         for(i = 0; i < hud_panels_COUNT; ++i)
787                         {
788                                 panel = hud_panels_from(i);
789                                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN))
790                                         continue;
791                                 if (panel == tab_panels[i] || panel == starting_panel)
792                                         continue;
793                                 HUD_Panel_UpdatePosSize();
794                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
795                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
796                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
797                                 {
798                                         tab_panel = panel;
799                                         tab_panel_pos = candidate_pos = panel_pos;
800                                 }
801                         }
802                         if (tab_panel)
803                                 break;
804                         if (k == LEVELS_NUM) //tab_panel not found
805                         {
806                                 reset_tab_panels();
807                                 if (!old_tab_panel)
808                                 {
809                                         tab_panel = world;
810                                         return true;
811                                 }
812                                 starting_panel = old_tab_panel;
813                                 old_tab_panel = world;
814                                 goto find_tab_panel; //u must find tab_panel!
815                         }
816                         if (!tab_backward)
817                         {
818                                 level = (level + level_height) % vid_conheight;
819                                 start_posX = 0;
820                                 candidate_pos.x = vid_conwidth;
821                         }
822                         else
823                         {
824                                 level = (level - level_height) % vid_conheight;
825                                 start_posX = vid_conwidth;
826                                 candidate_pos.x = 0;
827                         }
828                 }
829
830                 tab_panels[tab_panel.panel_id] = tab_panel;
831         }
832         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
833         {
834                 if (bInputType == 1 || mouseClicked)
835                         return true;
836
837                 if (highlightedPanel)
838                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
839                 else
840                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
841         }
842         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
843         {
844                 if (bInputType == 1 || mouseClicked)
845                         return true;
846
847                 if (highlightedPanel)
848                 {
849                         panel = highlightedPanel;
850                         HUD_Panel_UpdatePosSize();
851                         panel_size_copied = panel_size;
852                 }
853         }
854         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
855         {
856                 if (bInputType == 1 || mouseClicked)
857                         return true;
858
859                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
860                         return true;
861
862                 panel = highlightedPanel;
863                 HUD_Panel_UpdatePosSize();
864
865                 // reduce size if it'd go beyond screen boundaries
866                 vector tmp_size = panel_size_copied;
867                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
868                         tmp_size.x = vid_conwidth - panel_pos.x;
869                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
870                         tmp_size.y = vid_conheight - panel_pos.y;
871
872                 if (panel_size == tmp_size)
873                         return true;
874
875                 // backup first!
876                 panel_pos_backup = panel_pos;
877                 panel_size_backup = panel_size;
878                 highlightedPanel_backup = highlightedPanel;
879
880                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
881                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
882         }
883         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
884         {
885                 if (bInputType == 1 || mouseClicked)
886                         return true;
887                 //restore previous values
888                 if (highlightedPanel_backup)
889                 {
890                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
891                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
892                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
893                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
894                         highlightedPanel_backup = world;
895                 }
896         }
897         else if(nPrimary == 's' && hudShiftState & S_CTRL) // save config
898         {
899                 if (bInputType == 1 || mouseClicked)
900                         return true;
901                 localcmd("hud save myconfig\n");
902         }
903         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
904         {
905                 if (bInputType == 1)
906                 {
907                         pressed_key_time = 0;
908                         return true;
909                 }
910                 else if (pressed_key_time == 0)
911                         pressed_key_time = time;
912
913                 if (!mouseClicked)
914                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
915         }
916         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
917         {
918                 if (bInputType == 1)
919                         return true;
920                 if (highlightedPanel)
921                         HUD_Panel_EnableMenu();
922         }
923         else if(hit_con_bind || nPrimary == K_PAUSE)
924                 return false;
925
926         return true;
927 }
928
929 float HUD_Panel_Check_Mouse_Pos(float allow_move)
930 {
931         int i, j = 0;
932         while(j < hud_panels_COUNT)
933         {
934                 i = panel_order[j];
935                 j += 1;
936
937                 panel = hud_panels_from(i);
938                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN)) continue;
939                 HUD_Panel_UpdatePosSize();
940
941                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
942
943                 // move
944                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
945                 {
946                         return 1;
947                 }
948                 // resize from topleft border
949                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
950                 {
951                         return 2;
952                 }
953                 // resize from topright border
954                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
955                 {
956                         return 3;
957                 }
958                 // resize from bottomleft border
959                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
960                 {
961                         return 3;
962                 }
963                 // resize from bottomright border
964                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
965                 {
966                         return 2;
967                 }
968         }
969         return 0;
970 }
971
972 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
973 void HUD_Panel_FirstInDrawQ(float id)
974 {
975         int i;
976         int place = -1;
977         // find out where in the array our current id is, save into place
978         for(i = 0; i < hud_panels_COUNT; ++i)
979         {
980                 if(panel_order[i] == id)
981                 {
982                         place = i;
983                         break;
984                 }
985         }
986         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
987         if(place == -1)
988                 place = hud_panels_COUNT - 1;
989
990         // move all ids up by one step in the array until "place"
991         for(i = place; i > 0; --i)
992         {
993                 panel_order[i] = panel_order[i-1];
994         }
995         // now save the new top id
996         panel_order[0] = id;
997
998         // let's save them into the cvar by some strcat trickery
999         string s = "";
1000         for(i = 0; i < hud_panels_COUNT; ++i)
1001         {
1002                 s = strcat(s, ftos(panel_order[i]), " ");
1003         }
1004         cvar_set("_hud_panelorder", s);
1005         if(hud_panelorder_prev)
1006                 strunzone(hud_panelorder_prev);
1007         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1008 }
1009
1010 void HUD_Panel_Highlight(float allow_move)
1011 {
1012         int i, j = 0;
1013
1014         while(j < hud_panels_COUNT)
1015         {
1016                 i = panel_order[j];
1017                 j += 1;
1018
1019                 panel = hud_panels_from(i);
1020                 if(!(panel.panel_configflags & PANEL_CONFIG_MAIN))
1021                         continue;
1022                 HUD_Panel_UpdatePosSize();
1023
1024                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1025
1026                 // move
1027                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
1028                 {
1029                         highlightedPanel = hud_panels_from(i);
1030                         HUD_Panel_FirstInDrawQ(i);
1031                         highlightedAction = 1;
1032                         panel_click_distance = mousepos - panel_pos;
1033                         return;
1034                 }
1035                 // resize from topleft border
1036                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1037                 {
1038                         highlightedPanel = hud_panels_from(i);
1039                         HUD_Panel_FirstInDrawQ(i);
1040                         highlightedAction = 2;
1041                         resizeCorner = 1;
1042                         panel_click_distance = mousepos - panel_pos;
1043                         panel_click_resizeorigin = panel_pos + panel_size;
1044                         return;
1045                 }
1046                 // resize from topright border
1047                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1048                 {
1049                         highlightedPanel = hud_panels_from(i);
1050                         HUD_Panel_FirstInDrawQ(i);
1051                         highlightedAction = 2;
1052                         resizeCorner = 2;
1053                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
1054                         panel_click_distance.y = mousepos.y - panel_pos.y;
1055                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
1056                         return;
1057                 }
1058                 // resize from bottomleft border
1059                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
1060                 {
1061                         highlightedPanel = hud_panels_from(i);
1062                         HUD_Panel_FirstInDrawQ(i);
1063                         highlightedAction = 2;
1064                         resizeCorner = 3;
1065                         panel_click_distance.x = mousepos.x - panel_pos.x;
1066                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
1067                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
1068                         return;
1069                 }
1070                 // resize from bottomright border
1071                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
1072                 {
1073                         highlightedPanel = hud_panels_from(i);
1074                         HUD_Panel_FirstInDrawQ(i);
1075                         highlightedAction = 2;
1076                         resizeCorner = 4;
1077                         panel_click_distance = panel_size - mousepos + panel_pos;
1078                         panel_click_resizeorigin = panel_pos;
1079                         return;
1080                 }
1081         }
1082         highlightedPanel = world;
1083         highlightedAction = 0;
1084 }
1085
1086 void HUD_Panel_EnableMenu()
1087 {
1088         menu_enabled = 2;
1089         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1090 }
1091 float mouse_over_panel;
1092 void HUD_Panel_Mouse()
1093 {
1094         if(autocvar__menu_alpha == 1)
1095                 return;
1096
1097         if (!autocvar_hud_cursormode)
1098         {
1099                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1100
1101                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
1102                 mousepos.y = bound(0, mousepos.y, vid_conheight);
1103         }
1104
1105         if(mouseClicked)
1106         {
1107                 if(prevMouseClicked == 0)
1108                 {
1109                         if (tab_panel)
1110                         {
1111                                 //stop ctrl-tab selection
1112                                 tab_panel = world;
1113                                 reset_tab_panels();
1114                         }
1115                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1116                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1117                         if (highlightedPanel)
1118                         {
1119                                 highlightedPanel_initial_pos = panel_pos;
1120                                 highlightedPanel_initial_size = panel_size;
1121                         }
1122                         // doubleclick check
1123                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1124                         {
1125                                 mouseClicked = 0; // to prevent spam, I guess.
1126                                 HUD_Panel_EnableMenu();
1127                         }
1128                         else
1129                         {
1130                                 if (mouseClicked & S_MOUSE1)
1131                                 {
1132                                         prevMouseClickedTime = time;
1133                                         prevMouseClickedPos = mousepos;
1134                                 }
1135                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1136                         }
1137                 }
1138                 else
1139                 {
1140                         panel = highlightedPanel;
1141                         HUD_Panel_UpdatePosSize();
1142                 }
1143
1144                 if (highlightedPanel)
1145                 {
1146                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1147                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1148                         {
1149                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1150                                 // backup!
1151                                 panel_pos_backup = highlightedPanel_initial_pos;
1152                                 panel_size_backup = highlightedPanel_initial_size;
1153                                 highlightedPanel_backup = highlightedPanel;
1154                         }
1155                         else
1156                                 // in case the clicked panel is inside another panel and we aren't
1157                                 // moving it, avoid the immediate "fix" of its position/size
1158                                 // (often unwanted and hateful) by disabling collisions check
1159                                 hud_configure_checkcollisions = false;
1160                 }
1161
1162                 if(highlightedAction == 1)
1163                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1164                 else if(highlightedAction == 2)
1165                 {
1166                         vector mySize = '0 0 0';
1167                         if(resizeCorner == 1) {
1168                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1169                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1170                         } else if(resizeCorner == 2) {
1171                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1172                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1173                         } else if(resizeCorner == 3) {
1174                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1175                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1176                         } else { // resizeCorner == 4
1177                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1178                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1179                         }
1180                         HUD_Panel_SetPosSize(mySize);
1181                 }
1182         }
1183         else
1184         {
1185                 if(prevMouseClicked)
1186                         highlightedAction = 0;
1187                 if(menu_enabled == 2)
1188                         mouse_over_panel = 0;
1189                 else
1190                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(true);
1191                 if (mouse_over_panel && !tab_panel)
1192                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1193         }
1194         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1195         const vector cursorsize = '32 32 0';
1196         float cursor_alpha = 1 - autocvar__menu_alpha;
1197
1198         if(!mouse_over_panel)
1199                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1200         else if(mouse_over_panel == 1)
1201                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1202         else if(mouse_over_panel == 2)
1203                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1204         else
1205                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1206
1207         prevMouseClicked = mouseClicked;
1208 }
1209 void HUD_Configure_DrawGrid()
1210 {
1211         float i;
1212         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1213         {
1214                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1215                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1216                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1217                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1218                 vector s;
1219                 // x-axis
1220                 s = eX + eY * vid_conheight;
1221                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1222                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1223                 // y-axis
1224                 s = eY + eX * vid_conwidth;
1225                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1226                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1227         }
1228 }
1229
1230 float _menu_alpha_prev;
1231 void HUD_Configure_Frame()
1232 {
1233         int i;
1234         if(autocvar__hud_configure)
1235         {
1236                 if(isdemo() || intermission == 2)
1237                 {
1238                         HUD_Configure_Exit_Force();
1239                         return;
1240                 }
1241
1242                 if(!hud_configure_prev)
1243                 {
1244                         if(autocvar_hud_cursormode)
1245                                 setcursormode(1);
1246                         hudShiftState = 0;
1247                         for(i = hud_panels_COUNT - 1; i >= 0; --i)
1248                                 hud_panels_from(panel_order[i]).update_time = time;
1249                 }
1250
1251                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1252                 if(autocvar__menu_alpha != _menu_alpha_prev)
1253                 {
1254                         if(autocvar__menu_alpha == 0)
1255                                 menu_enabled = 0;
1256                         _menu_alpha_prev = autocvar__menu_alpha;
1257                 }
1258
1259                 HUD_Configure_DrawGrid();
1260         }
1261         else if(hud_configure_prev)
1262         {
1263                 if(menu_enabled)
1264                         menu_enabled = 0;
1265                 if(autocvar_hud_cursormode)
1266                         setcursormode(0);
1267         }
1268 }
1269
1270 const float hlBorderSize = 2;
1271 const string hlBorder = "gfx/hud/default/border_highlighted";
1272 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1273 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1274 {
1275         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1276         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1277         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1278         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1279         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1280 }
1281
1282 void HUD_Configure_PostDraw()
1283 {
1284         if(autocvar__hud_configure)
1285         {
1286                 if(tab_panel)
1287                 {
1288                         panel = tab_panel;
1289                         HUD_Panel_UpdatePosSize();
1290                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1291                 }
1292                 if(highlightedPanel)
1293                 {
1294                         panel = highlightedPanel;
1295                         HUD_Panel_UpdatePosSize();
1296                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1297                 }
1298         }
1299 }