qcsrc/client/hud/panel/centerprint.qc

   1 #include "centerprint.qh"
   2
   3 #include "scoreboard.qh"
   4 #include <common/notifications/all.qh>
   5 #include <client/miscfunctions.qh>
   6
   7 // CenterPrint (#16)
   8
   9 void HUD_CenterPrint_Export(int fh)
  10 {
  11         // allow saving cvars that aesthetically change the panel into hud skin files
  12         HUD_Write_Cvar("hud_panel_centerprint_align");
  13         HUD_Write_Cvar("hud_panel_centerprint_flip");
  14         HUD_Write_Cvar("hud_panel_centerprint_fontscale");
  15         HUD_Write_Cvar("hud_panel_centerprint_fontscale_bold");
  16         HUD_Write_Cvar("hud_panel_centerprint_time");
  17         HUD_Write_Cvar("hud_panel_centerprint_fade_in");
  18         HUD_Write_Cvar("hud_panel_centerprint_fade_out");
  19         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent");
  20         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone");
  21         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone_minalpha");
  22         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo");
  23         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo_minalpha");
  24         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_minfontsize");
  25         HUD_Write_Cvar("hud_panel_centerprint_fade_minfontsize");
  26 }
  27
  28 // These are the functions that draw the text at the center of the screen (e.g. frag messages and server MOTD).
  29 // centerprint_Add parses a message and puts it in the circular buffer centerprint_messages
  30 // centerprint_Add is usually called by Local_Notification_centerprint_Add, which is called
  31 // by Local_Notification.
  32 // HUD_CenterPrint draws all the messages on screen
  33
  34 const int CENTERPRINT_MAX_MSGS = 10;
  35 const int CENTERPRINT_MAX_ENTRIES = 50;
  36 const float CENTERPRINT_SPACING = 0.7;
  37 int cpm_index;
  38 string centerprint_messages[CENTERPRINT_MAX_MSGS];
  39 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
  40 bool centerprint_bold[CENTERPRINT_MAX_MSGS];
  41 float centerprint_time[CENTERPRINT_MAX_MSGS];
  42 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
  43 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
  44 bool centerprint_showing;
  45
  46 void centerprint_Add(int new_id, string strMessage, float duration, int countdown_num)
  47 {
  48         TC(int, new_id); TC(int, countdown_num);
  49         //LOG_INFOF("centerprint_Add: ^2id: %d ^3dur: %d ^5countdown: %d\n'%s'", new_id, duration, countdown_num, strreplace("\n", "^7\\n^7", strMessage));
  50         int i, j;
  51
  52         if(strMessage == "" && new_id == 0)
  53                 return;
  54
  55         // strip BOLD_OPERATOR
  56         bool is_bold = (substring(strMessage, 0, 5) == BOLD_OPERATOR);
  57         if (is_bold)
  58                 strMessage = substring(strMessage, 5, -1);
  59
  60         // strip trailing newlines
  61         j = strlen(strMessage) - 1;
  62         while(substring(strMessage, j, 1) == "\n" && j >= 0)
  63                 --j;
  64         if (j < strlen(strMessage) - 1)
  65                 strMessage = substring(strMessage, 0, j + 1);
  66
  67         if(strMessage == "" && new_id == 0)
  68                 return;
  69
  70         // strip leading newlines
  71         j = 0;
  72         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
  73                 ++j;
  74         if (j > 0)
  75                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
  76
  77         if(strMessage == "" && new_id == 0)
  78                 return;
  79
  80         if (!centerprint_showing)
  81                 centerprint_showing = true;
  82
  83         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
  84         {
  85                 if (j == CENTERPRINT_MAX_MSGS)
  86                         j = 0;
  87                 if (new_id && new_id == centerprint_msgID[j])
  88                 {
  89                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
  90                         {
  91                                 // fade out the current msg (duration and countdown_num are ignored)
  92                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
  93                                 centerprint_expire_time[j] = -1; // don't use the variable time here!
  94                                 return;
  95                         }
  96                         break; // found a msg with the same id, at position j
  97                 }
  98         }
  99
 100         if (i == CENTERPRINT_MAX_MSGS)
 101         {
 102                 // a msg with the same id was not found, add the msg at the next position
 103                 --cpm_index;
 104                 if (cpm_index == -1)
 105                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
 106                 j = cpm_index;
 107         }
 108         strcpy(centerprint_messages[j], strMessage);
 109         centerprint_bold[j] = is_bold;
 110         centerprint_msgID[j] = new_id;
 111         if (duration < 0)
 112         {
 113                 centerprint_time[j] = -1;
 114                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 115         }
 116         else
 117         {
 118                 if(duration == 0)
 119                         duration = max(1, autocvar_hud_panel_centerprint_time);
 120                 centerprint_time[j] = duration;
 121                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 122         }
 123         centerprint_countdown_num[j] = countdown_num;
 124 }
 125
 126 void centerprint_Kill(int id)
 127 {
 128         TC(int, id);
 129         centerprint_Add(id, "", 0, 0);
 130 }
 131
 132 void centerprint_AddStandard(string strMessage)
 133 {
 134         centerprint_Add(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
 135 }
 136
 137 void centerprint_KillAll()
 138 {
 139         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
 140         {
 141                 centerprint_expire_time[i] = 0;
 142                 centerprint_time[i] = 1;
 143                 centerprint_msgID[i] = 0;
 144                 centerprint_bold[i] = false;
 145                 strfree(centerprint_messages[i]);
 146         }
 147 }
 148
 149 float hud_configure_cp_generation_time;
 150 void HUD_CenterPrint()
 151 {
 152         if(!autocvar__hud_configure)
 153         {
 154                 if(!autocvar_hud_panel_centerprint) return;
 155
 156                 if(hud_configure_prev)
 157                         centerprint_KillAll();
 158         }
 159         else
 160         {
 161                 if(!hud_configure_prev)
 162                 {
 163                         centerprint_KillAll();
 164                         hud_configure_cp_generation_time = time; // show a message immediately
 165                 }
 166                 if (time > hud_configure_cp_generation_time)
 167                 {
 168                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
 169                         {
 170                                 float r;
 171                                 r = random();
 172                                 if (r > 0.8)
 173                                         centerprint_Add(floor(r*1000), sprintf(_("^3Countdown message at time %s, seconds left: ^COUNT"), seconds_tostring(time)), 1, 10);
 174                                 else if (r > 0.55)
 175                                         centerprint_Add(0, sprintf(_("^1Multiline message at time %s that\n^1lasts longer than normal"), seconds_tostring(time)), 20, 0);
 176                                 else
 177                                         centerprint_AddStandard(sprintf(_("Message at time %s"), seconds_tostring(time)));
 178                                 hud_configure_cp_generation_time = time + 1 + random()*4;
 179                         }
 180                         else
 181                         {
 182                                 centerprint_Add(0, _("Generic message"), 10, 0);
 183                                 hud_configure_cp_generation_time = time + 10 - random()*3;
 184                         }
 185                 }
 186         }
 187
 188         HUD_Panel_LoadCvars();
 189
 190         if ( HUD_Radar_Clickable() )
 191         {
 192                 if (hud_panel_radar_bottom >= 0.96 * vid_conheight)
 193                         return;
 194
 195                 panel_pos.x = 0.5 * (vid_conwidth - panel_size.x);
 196                 panel_pos.y = hud_panel_radar_bottom;
 197                 panel_size.y = min(panel_size.y, vid_conheight - hud_panel_radar_bottom);
 198         }
 199         else if(!autocvar__hud_configure && scoreboard_fade_alpha)
 200         {
 201                 // move the panel below the scoreboard
 202                 if (scoreboard_bottom >= 0.96 * vid_conheight)
 203                         return;
 204                 vector target_pos = vec2(0.5 * (vid_conwidth - panel_size.x), scoreboard_bottom);
 205                 if(target_pos.y > panel_pos.y)
 206                 {
 207                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
 208                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
 209                 }
 210         }
 211
 212         if (autocvar_hud_panel_centerprint_dynamichud)
 213                 HUD_Scale_Enable();
 214         else
 215                 HUD_Scale_Disable();
 216         HUD_Panel_DrawBg();
 217
 218         if (!centerprint_showing)
 219                 return;
 220
 221         if(panel_bg_padding)
 222         {
 223                 panel_pos += '1 1 0' * panel_bg_padding;
 224                 panel_size -= '2 2 0' * panel_bg_padding;
 225         }
 226
 227         int entries;
 228         float height;
 229         vector fontsize;
 230
 231         int i, j, k, n, g;
 232         float a, sz, align, current_msg_posY = 0, msg_size;
 233         vector pos;
 234         string ts;
 235         bool all_messages_expired = true;
 236
 237         pos = panel_pos;
 238         if (autocvar_hud_panel_centerprint_flip)
 239                 pos.y += panel_size.y;
 240         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
 241         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
 242         {
 243                 bool is_bold = centerprint_bold[j];
 244
 245                 // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
 246                 // height = panel_size_y/entries;
 247                 // fontsize = '1 1 0' * height;
 248                 height = (is_bold) ? vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale_bold : vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
 249                 fontsize = '1 1 0' * height;
 250                 entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
 251
 252                 if (j == CENTERPRINT_MAX_MSGS)
 253                         j = 0;
 254                 if (centerprint_expire_time[j] == -1)
 255                 {
 256                         // here we are sure the time variable is not altered by CSQC_Ent_Update
 257                         centerprint_expire_time[j] = time;
 258                         if (centerprint_time[j] > 0)
 259                                 centerprint_expire_time[j] += centerprint_time[j];
 260                 }
 261                 if (centerprint_expire_time[j] <= time)
 262                 {
 263                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
 264                         {
 265                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
 266                                 if (centerprint_countdown_num[j] == 0)
 267                                         continue;
 268                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
 269                         }
 270                         else if(centerprint_time[j] != -1)
 271                                 continue;
 272                 }
 273
 274                 all_messages_expired = false;
 275
 276                 // fade
 277                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
 278                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
 279                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
 280                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
 281                 else // Expiring soon, so fade it out.
 282                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
 283
 284                 if(centerprint_msgID[j] == CPID_TIMEIN)
 285                         a = 1;
 286
 287                 // while counting down show it anyway in order to hold the current message position
 288                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
 289                         continue;
 290                 if (a > 1)
 291                         a = 1;
 292
 293                 // set the size from fading in/out before subsequent fading
 294                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
 295
 296                 // also fade it based on positioning
 297                 if(autocvar_hud_panel_centerprint_fade_subsequent)
 298                 {
 299                         // pass one: all messages after the first have half alpha
 300                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
 301                         // pass two: after that, gradually lower alpha even more for each message
 302                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
 303                 }
 304                 a *= panel_fg_alpha;
 305
 306                 // finally set the size based on the new alpha from subsequent fading
 307                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
 308                 drawfontscale = hud_scale * sz;
 309
 310                 if (centerprint_countdown_num[j])
 311                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
 312                 else
 313                         n = tokenizebyseparator(centerprint_messages[j], "\n");
 314
 315                 if (autocvar_hud_panel_centerprint_flip)
 316                 {
 317                         // check if the message can be entirely shown
 318                         for(k = 0; k < n; ++k)
 319                         {
 320                                 getWrappedLine_remaining = argv(k);
 321                                 while(getWrappedLine_remaining)
 322                                 {
 323                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 324                                         if (ts != "")
 325                                                 pos.y -= fontsize.y;
 326                                         else
 327                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
 328                                 }
 329                         }
 330                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
 331                 }
 332
 333                 msg_size = pos.y;
 334                 for(k = 0; k < n; ++k)
 335                 {
 336                         getWrappedLine_remaining = argv(k);
 337                         while(getWrappedLine_remaining)
 338                         {
 339                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 340                                 if (ts != "")
 341                                 {
 342                                         if (align)
 343                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
 344                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
 345                                                 if (is_bold) draw_beginBoldFont();
 346                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
 347                                                 if (is_bold) draw_endBoldFont();
 348                                         pos.y += fontsize.y;
 349                                 }
 350                                 else
 351                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
 352                         }
 353                 }
 354
 355                 ++g; // move next position number up
 356
 357                 msg_size = pos.y - msg_size;
 358                 if (autocvar_hud_panel_centerprint_flip)
 359                 {
 360                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
 361                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 362                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
 363
 364                         if (pos.y < panel_pos.y) // check if the next message can be shown
 365                         {
 366                                 drawfontscale = hud_scale;
 367                                 return;
 368                         }
 369                 }
 370                 else
 371                 {
 372                         pos.y += CENTERPRINT_SPACING * fontsize.y;
 373                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 374                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
 375
 376                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
 377                         {
 378                                 drawfontscale = hud_scale;
 379                                 return;
 380                         }
 381                 }
 382         }
 383
 384         drawfontscale = hud_scale;
 385         if (all_messages_expired)
 386         {
 387                 centerprint_showing = false;
 388                 centerprint_KillAll();
 389         }
 390 }