Make the scoreboard a panel
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / hud / panel / centerprint.qc
1 #include "centerprint.qh"
2
3 #include <client/scoreboard.qh>
4
5 // CenterPrint (#16)
6
7 const int CENTERPRINT_MAX_MSGS = 10;
8 const int CENTERPRINT_MAX_ENTRIES = 50;
9 const float CENTERPRINT_SPACING = 0.7;
10 int cpm_index;
11 string centerprint_messages[CENTERPRINT_MAX_MSGS];
12 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
13 float centerprint_time[CENTERPRINT_MAX_MSGS];
14 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
15 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
16 bool centerprint_showing;
17
18 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
19 {
20     TC(int, new_id); TC(int, countdown_num);
21         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
22         int i, j;
23
24         if(strMessage == "" && new_id == 0)
25                 return;
26
27         // strip trailing newlines
28         j = strlen(strMessage) - 1;
29         while(substring(strMessage, j, 1) == "\n" && j >= 0)
30                 --j;
31         if (j < strlen(strMessage) - 1)
32                 strMessage = substring(strMessage, 0, j + 1);
33
34         if(strMessage == "" && new_id == 0)
35                 return;
36
37         // strip leading newlines
38         j = 0;
39         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
40                 ++j;
41         if (j > 0)
42                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
43
44         if(strMessage == "" && new_id == 0)
45                 return;
46
47         if (!centerprint_showing)
48                 centerprint_showing = true;
49
50         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
51         {
52                 if (j == CENTERPRINT_MAX_MSGS)
53                         j = 0;
54                 if (new_id && new_id == centerprint_msgID[j])
55                 {
56                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
57                         {
58                                 // fade out the current msg (duration and countdown_num are ignored)
59                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
60                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
61                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
62                                 return;
63                         }
64                         break; // found a msg with the same id, at position j
65                 }
66         }
67
68         if (i == CENTERPRINT_MAX_MSGS)
69         {
70                 // a msg with the same id was not found, add the msg at the next position
71                 --cpm_index;
72                 if (cpm_index == -1)
73                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
74                 j = cpm_index;
75         }
76         if(centerprint_messages[j])
77                 strunzone(centerprint_messages[j]);
78         centerprint_messages[j] = strzone(strMessage);
79         centerprint_msgID[j] = new_id;
80         if (duration < 0)
81         {
82                 centerprint_time[j] = -1;
83                 centerprint_expire_time[j] = time;
84         }
85         else
86         {
87                 if(duration == 0)
88                         duration = max(1, autocvar_hud_panel_centerprint_time);
89                 centerprint_time[j] = duration;
90                 centerprint_expire_time[j] = time + duration;
91         }
92         centerprint_countdown_num[j] = countdown_num;
93 }
94
95 void centerprint_kill(int id)
96 {
97     TC(int, id);
98         centerprint_generic(id, "", 0, 0);
99 }
100
101 void centerprint_hud(string strMessage)
102 {
103         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
104 }
105
106 void reset_centerprint_messages()
107 {
108         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
109         {
110                 centerprint_expire_time[i] = 0;
111                 centerprint_time[i] = 1;
112                 centerprint_msgID[i] = 0;
113                 if(centerprint_messages[i])
114                         strunzone(centerprint_messages[i]);
115                 centerprint_messages[i] = string_null;
116         }
117 }
118 float hud_configure_cp_generation_time;
119 void HUD_CenterPrint ()
120 {
121         if(!autocvar__hud_configure)
122         {
123                 if(!autocvar_hud_panel_centerprint) return;
124
125                 if(hud_configure_prev)
126                         reset_centerprint_messages();
127         }
128         else
129         {
130                 if(!hud_configure_prev)
131                 {
132                         reset_centerprint_messages();
133                         hud_configure_cp_generation_time = time; // show a message immediately
134                 }
135                 if (time > hud_configure_cp_generation_time)
136                 {
137                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
138                         {
139                                 float r;
140                                 r = random();
141                                 if (r > 0.8)
142                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
143                                 else if (r > 0.55)
144                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
145                                 else
146                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
147                                 hud_configure_cp_generation_time = time + 1 + random()*4;
148                         }
149                         else
150                         {
151                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
152                                 hud_configure_cp_generation_time = time + 10 - random()*3;
153                         }
154                 }
155         }
156
157         // this panel fades only when the menu does
158         float hud_fade_alpha_save = hud_fade_alpha;
159         if(menu_enabled == 1)
160                 hud_fade_alpha = 1;
161         else
162                 hud_fade_alpha = 1 - autocvar__menu_alpha;
163
164         HUD_Panel_UpdateCvars();
165         hud_fade_alpha = hud_fade_alpha_save;
166
167         if ( HUD_Radar_Clickable() )
168         {
169                 if (hud_panel_radar_bottom >= 0.96 * vid_conheight)
170                         return;
171
172                 panel_pos = eY * hud_panel_radar_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
173                 panel_size_y = min(panel_size_y, vid_conheight - hud_panel_radar_bottom);
174         }
175         else if(!autocvar__hud_configure && scoreboard_fade_alpha)
176         {
177                 // move the panel below the scoreboard
178                 if (scoreboard_bottom >= 0.96 * vid_conheight)
179                         return;
180                 vector target_pos;
181                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
182                 if(target_pos.y > panel_pos.y)
183                 {
184                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
185                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
186                 }
187         }
188
189         if (autocvar_hud_panel_centerprint_dynamichud)
190                 HUD_Scale_Enable();
191         else
192                 HUD_Scale_Disable();
193         HUD_Panel_DrawBg(1);
194
195         if (!centerprint_showing)
196                 return;
197
198         if(panel_bg_padding)
199         {
200                 panel_pos += '1 1 0' * panel_bg_padding;
201                 panel_size -= '2 2 0' * panel_bg_padding;
202         }
203
204         int entries;
205         float height;
206         vector fontsize;
207         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
208         // height = panel_size_y/entries;
209         // fontsize = '1 1 0' * height;
210         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
211         fontsize = '1 1 0' * height;
212         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
213
214         int i, j, k, n, g;
215         float a, sz, align, current_msg_posY = 0, msg_size;
216         vector pos;
217         string ts;
218         bool all_messages_expired = true;
219
220         pos = panel_pos;
221         if (autocvar_hud_panel_centerprint_flip)
222                 pos.y += panel_size.y;
223         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
224         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
225         {
226                 if (j == CENTERPRINT_MAX_MSGS)
227                         j = 0;
228                 if (centerprint_expire_time[j] <= time)
229                 {
230                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
231                         {
232                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
233                                 if (centerprint_countdown_num[j] == 0)
234                                         continue;
235                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
236                         }
237                         else if(centerprint_time[j] != -1)
238                                 continue;
239                 }
240
241                 all_messages_expired = false;
242
243                 // fade the centerprint_hud in/out
244                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
245                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
246                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
247                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
248                 else // Expiring soon, so fade it out.
249                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
250
251                 // while counting down show it anyway in order to hold the current message position
252                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
253                         continue;
254                 if (a > 1)
255                         a = 1;
256
257                 // set the size from fading in/out before subsequent fading
258                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
259
260                 // also fade it based on positioning
261                 if(autocvar_hud_panel_centerprint_fade_subsequent)
262                 {
263                         // pass one: all messages after the first have half alpha
264                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
265                         // pass two: after that, gradually lower alpha even more for each message
266                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
267                 }
268                 a *= panel_fg_alpha;
269
270                 // finally set the size based on the new alpha from subsequent fading
271                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
272                 drawfontscale = hud_scale * sz;
273
274                 if (centerprint_countdown_num[j])
275                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
276                 else
277                         n = tokenizebyseparator(centerprint_messages[j], "\n");
278
279                 if (autocvar_hud_panel_centerprint_flip)
280                 {
281                         // check if the message can be entirely shown
282                         for(k = 0; k < n; ++k)
283                         {
284                                 getWrappedLine_remaining = argv(k);
285                                 while(getWrappedLine_remaining)
286                                 {
287                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
288                                         if (ts != "")
289                                                 pos.y -= fontsize.y;
290                                         else
291                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
292                                 }
293                         }
294                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
295                 }
296
297                 msg_size = pos.y;
298                 for(k = 0; k < n; ++k)
299                 {
300                         getWrappedLine_remaining = argv(k);
301                         while(getWrappedLine_remaining)
302                         {
303                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
304                                 if (ts != "")
305                                 {
306                                         if (align)
307                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
308                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
309                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
310                                         pos.y += fontsize.y;
311                                 }
312                                 else
313                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
314                         }
315                 }
316
317                 ++g; // move next position number up
318
319                 msg_size = pos.y - msg_size;
320                 if (autocvar_hud_panel_centerprint_flip)
321                 {
322                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
323                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
324                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
325
326                         if (pos.y < panel_pos.y) // check if the next message can be shown
327                         {
328                                 drawfontscale = hud_scale;
329                                 return;
330                         }
331                 }
332                 else
333                 {
334                         pos.y += CENTERPRINT_SPACING * fontsize.y;
335                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
336                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
337
338                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
339                         {
340                                 drawfontscale = hud_scale;
341                                 return;
342                         }
343                 }
344         }
345         drawfontscale = hud_scale;
346         if (all_messages_expired)
347         {
348                 centerprint_showing = false;
349                 reset_centerprint_messages();
350         }
351 }