qcsrc/client/hud/panel/centerprint.qc

   1 #include "centerprint.qh"
   2
   3 #include <client/scoreboard.qh>
   4
   5 // CenterPrint (#16)
   6
   7 const int CENTERPRINT_MAX_MSGS = 10;
   8 const int CENTERPRINT_MAX_ENTRIES = 50;
   9 const float CENTERPRINT_SPACING = 0.7;
  10 int cpm_index;
  11 string centerprint_messages[CENTERPRINT_MAX_MSGS];
  12 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
  13 float centerprint_time[CENTERPRINT_MAX_MSGS];
  14 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
  15 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
  16 bool centerprint_showing;
  17
  18 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
  19 {
  20     TC(int, new_id); TC(int, countdown_num);
  21         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
  22         int i, j;
  23
  24         if(strMessage == "" && new_id == 0)
  25                 return;
  26
  27         // strip trailing newlines
  28         j = strlen(strMessage) - 1;
  29         while(substring(strMessage, j, 1) == "\n" && j >= 0)
  30                 --j;
  31         if (j < strlen(strMessage) - 1)
  32                 strMessage = substring(strMessage, 0, j + 1);
  33
  34         if(strMessage == "" && new_id == 0)
  35                 return;
  36
  37         // strip leading newlines
  38         j = 0;
  39         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
  40                 ++j;
  41         if (j > 0)
  42                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
  43
  44         if(strMessage == "" && new_id == 0)
  45                 return;
  46
  47         if (!centerprint_showing)
  48                 centerprint_showing = true;
  49
  50         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
  51         {
  52                 if (j == CENTERPRINT_MAX_MSGS)
  53                         j = 0;
  54                 if (new_id && new_id == centerprint_msgID[j])
  55                 {
  56                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
  57                         {
  58                                 // fade out the current msg (duration and countdown_num are ignored)
  59                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
  60                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
  61                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
  62                                 return;
  63                         }
  64                         break; // found a msg with the same id, at position j
  65                 }
  66         }
  67
  68         if (i == CENTERPRINT_MAX_MSGS)
  69         {
  70                 // a msg with the same id was not found, add the msg at the next position
  71                 --cpm_index;
  72                 if (cpm_index == -1)
  73                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
  74                 j = cpm_index;
  75         }
  76         if(centerprint_messages[j])
  77                 strunzone(centerprint_messages[j]);
  78         centerprint_messages[j] = strzone(strMessage);
  79         centerprint_msgID[j] = new_id;
  80         if (duration < 0)
  81         {
  82                 centerprint_time[j] = -1;
  83                 centerprint_expire_time[j] = time;
  84         }
  85         else
  86         {
  87                 if(duration == 0)
  88                         duration = max(1, autocvar_hud_panel_centerprint_time);
  89                 centerprint_time[j] = duration;
  90                 centerprint_expire_time[j] = time + duration;
  91         }
  92         centerprint_countdown_num[j] = countdown_num;
  93 }
  94
  95 void centerprint_kill(int id)
  96 {
  97     TC(int, id);
  98         centerprint_generic(id, "", 0, 0);
  99 }
 100
 101 void centerprint_hud(string strMessage)
 102 {
 103         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
 104 }
 105
 106 void reset_centerprint_messages()
 107 {
 108         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
 109         {
 110                 centerprint_expire_time[i] = 0;
 111                 centerprint_time[i] = 1;
 112                 centerprint_msgID[i] = 0;
 113                 if(centerprint_messages[i])
 114                         strunzone(centerprint_messages[i]);
 115                 centerprint_messages[i] = string_null;
 116         }
 117 }
 118 float hud_configure_cp_generation_time;
 119 void HUD_CenterPrint ()
 120 {
 121         if(!autocvar__hud_configure)
 122         {
 123                 if(!autocvar_hud_panel_centerprint) return;
 124
 125                 if(hud_configure_prev)
 126                         reset_centerprint_messages();
 127         }
 128         else
 129         {
 130                 if(!hud_configure_prev)
 131                 {
 132                         reset_centerprint_messages();
 133                         hud_configure_cp_generation_time = time; // show a message immediately
 134                 }
 135                 if (time > hud_configure_cp_generation_time)
 136                 {
 137                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
 138                         {
 139                                 float r;
 140                                 r = random();
 141                                 if (r > 0.8)
 142                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
 143                                 else if (r > 0.55)
 144                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
 145                                 else
 146                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
 147                                 hud_configure_cp_generation_time = time + 1 + random()*4;
 148                         }
 149                         else
 150                         {
 151                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
 152                                 hud_configure_cp_generation_time = time + 10 - random()*3;
 153                         }
 154                 }
 155         }
 156
 157         // this panel fades only when the menu does
 158         float hud_fade_alpha_save = 0;
 159         if(scoreboard_fade_alpha)
 160         {
 161                 hud_fade_alpha_save = hud_fade_alpha;
 162                 hud_fade_alpha = 1 - autocvar__menu_alpha;
 163         }
 164         HUD_Panel_UpdateCvars();
 165
 166         if ( HUD_Radar_Clickable() )
 167         {
 168                 if (hud_panel_radar_bottom >= 0.96 * vid_conheight)
 169                         return;
 170
 171                 panel_pos = eY * hud_panel_radar_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
 172                 panel_size_y = min(panel_size_y, vid_conheight - hud_panel_radar_bottom);
 173         }
 174         else if(scoreboard_fade_alpha)
 175         {
 176                 hud_fade_alpha = hud_fade_alpha_save;
 177
 178                 // move the panel below the scoreboard
 179                 if (scoreboard_bottom >= 0.96 * vid_conheight)
 180                         return;
 181                 vector target_pos;
 182
 183                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
 184
 185                 if(target_pos.y > panel_pos.y)
 186                 {
 187                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
 188                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
 189                 }
 190         }
 191
 192         if (autocvar_hud_panel_centerprint_dynamichud)
 193                 HUD_Scale_Enable();
 194         else
 195                 HUD_Scale_Disable();
 196         HUD_Panel_DrawBg(1);
 197
 198         if (!centerprint_showing)
 199                 return;
 200
 201         if(panel_bg_padding)
 202         {
 203                 panel_pos += '1 1 0' * panel_bg_padding;
 204                 panel_size -= '2 2 0' * panel_bg_padding;
 205         }
 206
 207         int entries;
 208         float height;
 209         vector fontsize;
 210         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
 211         // height = panel_size_y/entries;
 212         // fontsize = '1 1 0' * height;
 213         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
 214         fontsize = '1 1 0' * height;
 215         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
 216
 217         int i, j, k, n, g;
 218         float a, sz, align, current_msg_posY = 0, msg_size;
 219         vector pos;
 220         string ts;
 221         bool all_messages_expired = true;
 222
 223         pos = panel_pos;
 224         if (autocvar_hud_panel_centerprint_flip)
 225                 pos.y += panel_size.y;
 226         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
 227         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
 228         {
 229                 if (j == CENTERPRINT_MAX_MSGS)
 230                         j = 0;
 231                 if (centerprint_expire_time[j] <= time)
 232                 {
 233                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
 234                         {
 235                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
 236                                 if (centerprint_countdown_num[j] == 0)
 237                                         continue;
 238                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
 239                         }
 240                         else if(centerprint_time[j] != -1)
 241                                 continue;
 242                 }
 243
 244                 all_messages_expired = false;
 245
 246                 // fade the centerprint_hud in/out
 247                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
 248                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
 249                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
 250                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
 251                 else // Expiring soon, so fade it out.
 252                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
 253
 254                 // while counting down show it anyway in order to hold the current message position
 255                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
 256                         continue;
 257                 if (a > 1)
 258                         a = 1;
 259
 260                 // set the size from fading in/out before subsequent fading
 261                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
 262
 263                 // also fade it based on positioning
 264                 if(autocvar_hud_panel_centerprint_fade_subsequent)
 265                 {
 266                         // pass one: all messages after the first have half alpha
 267                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
 268                         // pass two: after that, gradually lower alpha even more for each message
 269                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
 270                 }
 271                 a *= panel_fg_alpha;
 272
 273                 // finally set the size based on the new alpha from subsequent fading
 274                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
 275                 drawfontscale = hud_scale * sz;
 276
 277                 if (centerprint_countdown_num[j])
 278                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
 279                 else
 280                         n = tokenizebyseparator(centerprint_messages[j], "\n");
 281
 282                 if (autocvar_hud_panel_centerprint_flip)
 283                 {
 284                         // check if the message can be entirely shown
 285                         for(k = 0; k < n; ++k)
 286                         {
 287                                 getWrappedLine_remaining = argv(k);
 288                                 while(getWrappedLine_remaining)
 289                                 {
 290                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 291                                         if (ts != "")
 292                                                 pos.y -= fontsize.y;
 293                                         else
 294                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
 295                                 }
 296                         }
 297                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
 298                 }
 299
 300                 msg_size = pos.y;
 301                 for(k = 0; k < n; ++k)
 302                 {
 303                         getWrappedLine_remaining = argv(k);
 304                         while(getWrappedLine_remaining)
 305                         {
 306                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 307                                 if (ts != "")
 308                                 {
 309                                         if (align)
 310                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
 311                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
 312                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
 313                                         pos.y += fontsize.y;
 314                                 }
 315                                 else
 316                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
 317                         }
 318                 }
 319
 320                 ++g; // move next position number up
 321
 322                 msg_size = pos.y - msg_size;
 323                 if (autocvar_hud_panel_centerprint_flip)
 324                 {
 325                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
 326                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 327                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
 328
 329                         if (pos.y < panel_pos.y) // check if the next message can be shown
 330                         {
 331                                 drawfontscale = hud_scale;
 332                                 return;
 333                         }
 334                 }
 335                 else
 336                 {
 337                         pos.y += CENTERPRINT_SPACING * fontsize.y;
 338                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 339                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
 340
 341                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
 342                         {
 343                                 drawfontscale = hud_scale;
 344                                 return;
 345                         }
 346                 }
 347         }
 348         drawfontscale = hud_scale;
 349         if (all_messages_expired)
 350         {
 351                 centerprint_showing = false;
 352                 reset_centerprint_messages();
 353         }
 354 }