qcsrc/client/hud/panel/healtharmor.qc

   1 #include "healtharmor.qh"
   2
   3 #include <client/draw.qh>
   4 #include <common/deathtypes/all.qh>
   5
   6 // Health/armor (#3)
   7
   8 void HUD_HealthArmor_Export(int fh)
   9 {
  10         // allow saving cvars that aesthetically change the panel into hud skin files
  11         HUD_Write_Cvar("hud_panel_healtharmor_combined");
  12         HUD_Write_Cvar("hud_panel_healtharmor_flip");
  13         HUD_Write_Cvar("hud_panel_healtharmor_iconalign");
  14         HUD_Write_Cvar("hud_panel_healtharmor_baralign");
  15         HUD_Write_Cvar("hud_panel_healtharmor_progressbar");
  16         HUD_Write_Cvar("hud_panel_healtharmor_progressbar_health");
  17         HUD_Write_Cvar("hud_panel_healtharmor_progressbar_armor");
  18         HUD_Write_Cvar("hud_panel_healtharmor_progressbar_gfx");
  19         HUD_Write_Cvar("hud_panel_healtharmor_progressbar_gfx_smooth");
  20         HUD_Write_Cvar("hud_panel_healtharmor_text");
  21 }
  22
  23 void HUD_HealthArmor()
  24 {
  25         int armor, health, fuel, air_time;
  26         if(!autocvar__hud_configure)
  27         {
  28                 if((!autocvar_hud_panel_healtharmor) || (spectatee_status == -1))
  29                         return;
  30                 if(hud != HUD_NORMAL) return;
  31
  32                 health = STAT(HEALTH);
  33                 if(health <= 0)
  34                 {
  35                         health = 0;
  36                         prev_health = -1;
  37                         if(autocvar_hud_panel_healtharmor_hide_ondeath)
  38                                 return;
  39                 }
  40                 armor = STAT(ARMOR);
  41
  42                 // code to check for spectatee_status changes is in ENT_CLIENT_CLIENTDATA
  43                 // prev_p_health and prev_health can be set to -1 there
  44
  45                 if (prev_p_health == -1)
  46                 {
  47                         // no effect
  48                         health_beforedamage = 0;
  49                         armor_beforedamage = 0;
  50                         health_damagetime = 0;
  51                         armor_damagetime = 0;
  52                         prev_health = health;
  53                         prev_armor = armor;
  54                         old_p_health = health;
  55                         old_p_armor = armor;
  56                         prev_p_health = health;
  57                         prev_p_armor = armor;
  58                 }
  59                 else if (prev_health == -1)
  60                 {
  61                         //start the load effect
  62                         health_damagetime = 0;
  63                         armor_damagetime = 0;
  64                         prev_health = 0;
  65                         prev_armor = 0;
  66                 }
  67                 fuel = STAT(FUEL);
  68                 air_time = bound(0, STAT(AIR_FINISHED) - time, 10);
  69         }
  70         else
  71         {
  72                 health = 150;
  73                 armor = 75;
  74                 fuel = 20;
  75                 air_time = 6;
  76         }
  77
  78         HUD_Panel_LoadCvars();
  79
  80         draw_beginBoldFont();
  81
  82         vector pos, mySize;
  83         pos = panel_pos;
  84         mySize = panel_size;
  85
  86         if (autocvar_hud_panel_healtharmor_dynamichud)
  87                 HUD_Scale_Enable();
  88         else
  89                 HUD_Scale_Disable();
  90         HUD_Panel_DrawBg();
  91         if(panel_bg_padding)
  92         {
  93                 pos += '1 1 0' * panel_bg_padding;
  94                 mySize -= '2 2 0' * panel_bg_padding;
  95         }
  96
  97         float air_alpha;
  98         if (!STAT(AIR_FINISHED))
  99                 air_alpha = 0;
 100         else if (time > STAT(AIR_FINISHED))
 101         {
 102                 air_alpha = blink_synced(0.5, 0.5, 7, STAT(AIR_FINISHED), -1);
 103                 air_time = 10;
 104         }
 105         else
 106         {
 107                 float fade_time = 10 / 2;
 108                 float start_alpha = autocvar_hud_panel_healtharmor_oxygenbar_startalpha;
 109                 float f = (STAT(AIR_FINISHED) - time - fade_time) / fade_time;
 110                 air_alpha = bound(0, start_alpha + (1 - start_alpha) * (1 - f), 1);
 111         }
 112
 113         int baralign = autocvar_hud_panel_healtharmor_baralign;
 114         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
 115
 116         int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
 117         int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
 118         if(autocvar_hud_panel_healtharmor_combined) // combined health and armor display
 119         {
 120                 vector v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON.m_id);
 121                 float hp = floor(v.x + 1);
 122
 123                 float maxtotal = maxhealth + maxarmor;
 124                 string biggercount;
 125                 if(v.z) // NOT fully armored
 126                 {
 127                         biggercount = "health";
 128                         if(autocvar_hud_panel_healtharmor_progressbar)
 129                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, hp/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 130                         if(armor && autocvar_hud_panel_healtharmor_text)
 131                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
 132                 }
 133                 else
 134                 {
 135                         biggercount = "armor";
 136                         if(autocvar_hud_panel_healtharmor_progressbar)
 137                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, hp/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 138                         if(health && autocvar_hud_panel_healtharmor_text)
 139                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 140                 }
 141                 if(autocvar_hud_panel_healtharmor_text)
 142                         DrawNumIcon(pos, mySize, hp, biggercount, 0, iconalign, HUD_Get_Num_Color(hp, maxtotal, true), 1);
 143
 144                 if(fuel)
 145                         HUD_Panel_DrawProgressBar(pos, vec2(mySize.x, 0.2 * mySize.y), "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 146                 if(air_time)
 147                         HUD_Panel_DrawProgressBar(pos + eY * 0.8 * mySize.y, vec2(mySize.x, 0.2 * mySize.y), "progressbar", air_time / 10, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_oxygen_color, air_alpha * panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 148         }
 149         else
 150         {
 151                 float panel_ar = mySize.x/mySize.y;
 152                 bool is_vertical = (panel_ar < 1);
 153                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
 154                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
 155                 {
 156                         mySize.x *= 0.5;
 157                         if (autocvar_hud_panel_healtharmor_flip)
 158                                 health_offset.x = mySize.x;
 159                         else
 160                                 armor_offset.x = mySize.x;
 161                 }
 162                 else
 163                 {
 164                         mySize.y *= 0.5;
 165                         if (autocvar_hud_panel_healtharmor_flip)
 166                                 health_offset.y = mySize.y;
 167                         else
 168                                 armor_offset.y = mySize.y;
 169                 }
 170
 171                 bool health_baralign, armor_baralign, fuel_baralign, air_align;
 172                 bool health_iconalign, armor_iconalign;
 173                 if (autocvar_hud_panel_healtharmor_flip)
 174                 {
 175                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 176                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 177                         air_align = fuel_baralign = health_baralign;
 178                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 179                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 180                 }
 181                 else
 182                 {
 183                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 184                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 185                         air_align = fuel_baralign = armor_baralign;
 186                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 187                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 188                 }
 189
 190                 //if(health)
 191                 {
 192                         if(autocvar_hud_panel_healtharmor_progressbar)
 193                         {
 194                                 float p_health, pain_health_alpha;
 195                                 p_health = health;
 196                                 pain_health_alpha = 1;
 197                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 198                                 {
 199                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 200                                         {
 201                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 202                                                 {
 203                                                         if (time - old_p_healthtime < 1)
 204                                                                 old_p_health = prev_p_health;
 205                                                         else
 206                                                                 old_p_health = prev_health;
 207                                                         old_p_healthtime = time;
 208                                                 }
 209                                                 if (time - old_p_healthtime < 1)
 210                                                 {
 211                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
 212                                                         prev_p_health = p_health;
 213                                                 }
 214                                         }
 215                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 216                                         {
 217                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 218                                                 {
 219                                                         if (time - health_damagetime >= 1)
 220                                                                 health_beforedamage = prev_health;
 221                                                         health_damagetime = time;
 222                                                 }
 223                                                 if (time - health_damagetime < 1)
 224                                                 {
 225                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
 226                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
 227                                                 }
 228                                         }
 229                                         prev_health = health;
 230
 231                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
 232                                         {
 233                                                 pain_health_alpha = blink(0.85, 0.15, 9);
 234                                         }
 235                                 }
 236                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
 237                         }
 238                         if(autocvar_hud_panel_healtharmor_text)
 239                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth, true), 1);
 240                 }
 241
 242                 //if(armor)
 243                 {
 244                         float p_armor = armor;
 245                         if(autocvar_hud_panel_healtharmor_progressbar)
 246                         {
 247                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 248                                 {
 249                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 250                                         {
 251                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 252                                                 {
 253                                                         if (time - old_p_armortime < 1)
 254                                                                 old_p_armor = prev_p_armor;
 255                                                         else
 256                                                                 old_p_armor = prev_armor;
 257                                                         old_p_armortime = time;
 258                                                 }
 259                                                 if (time - old_p_armortime < 1)
 260                                                 {
 261                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
 262                                                         prev_p_armor = p_armor;
 263                                                 }
 264                                         }
 265                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 266                                         {
 267                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 268                                                 {
 269                                                         if (time - armor_damagetime >= 1)
 270                                                                 armor_beforedamage = prev_armor;
 271                                                         armor_damagetime = time;
 272                                                 }
 273                                                 if (time - armor_damagetime < 1)
 274                                                 {
 275                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
 276                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
 277                                                 }
 278                                         }
 279                                         prev_armor = armor;
 280                                 }
 281                                 if(p_armor)
 282                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 283                         }
 284                         if(!autocvar_hud_panel_healtharmor_progressbar || p_armor)
 285                         if(autocvar_hud_panel_healtharmor_text)
 286                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor, true), 1);
 287                 }
 288
 289                 vector cell_size = mySize;
 290                 if (fuel || air_time)
 291                 {
 292                         if (is_vertical)
 293                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
 294                         else
 295                                 mySize.y *= 0.2;
 296                         if (panel_ar >= 4)
 297                                 mySize.x *= 2; //restore full panel size
 298                         else if (panel_ar < 1/4)
 299                                 mySize.y *= 2; //restore full panel size
 300                         if (fuel)
 301                                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 302                         if (air_time)
 303                         {
 304                                 if (panel_ar > 1 && panel_ar < 4)
 305                                         pos.y += cell_size.y;
 306                                 else if (panel_ar > 1/4 && panel_ar <= 1)
 307                                         pos.x += cell_size.x;
 308                                 if (is_vertical)
 309                                         pos.x += cell_size.x - mySize.x;
 310                                 else
 311                                         pos.y += cell_size.y - mySize.y;
 312                                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", air_time / 10, is_vertical, air_align, autocvar_hud_progressbar_oxygen_color, air_alpha * panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 313                         }
 314                 }
 315         }
 316
 317         draw_endBoldFont();
 318 }