qcsrc/client/hud/panel/healtharmor.qc

   1 #include "healtharmor.qh"
   2
   3 #include <common/deathtypes/all.qh>
   4
   5 // Health/armor (#3)
   6
   7 void HUD_HealthArmor()
   8 {
   9         int armor, health, fuel;
  10         if(!autocvar__hud_configure)
  11         {
  12                 if((!autocvar_hud_panel_healtharmor) || (spectatee_status == -1))
  13                         return;
  14                 if(hud != HUD_NORMAL) return;
  15
  16                 health = STAT(HEALTH);
  17                 if(health <= 0)
  18                 {
  19                         health = 0;
  20                         prev_health = -1;
  21                         if(autocvar_hud_panel_healtharmor_hide_ondeath)
  22                                 return;
  23                 }
  24                 armor = STAT(ARMOR);
  25
  26                 // code to check for spectatee_status changes is in ENT_CLIENT_CLIENTDATA
  27                 // prev_p_health and prev_health can be set to -1 there
  28
  29                 if (prev_p_health == -1)
  30                 {
  31                         // no effect
  32                         health_beforedamage = 0;
  33                         armor_beforedamage = 0;
  34                         health_damagetime = 0;
  35                         armor_damagetime = 0;
  36                         prev_health = health;
  37                         prev_armor = armor;
  38                         old_p_health = health;
  39                         old_p_armor = armor;
  40                         prev_p_health = health;
  41                         prev_p_armor = armor;
  42                 }
  43                 else if (prev_health == -1)
  44                 {
  45                         //start the load effect
  46                         health_damagetime = 0;
  47                         armor_damagetime = 0;
  48                         prev_health = 0;
  49                         prev_armor = 0;
  50                 }
  51                 fuel = STAT(FUEL);
  52         }
  53         else
  54         {
  55                 health = 150;
  56                 armor = 75;
  57                 fuel = 20;
  58         }
  59
  60         HUD_Panel_LoadCvars();
  61
  62         draw_beginBoldFont();
  63
  64         vector pos, mySize;
  65         pos = panel_pos;
  66         mySize = panel_size;
  67
  68         if (autocvar_hud_panel_healtharmor_dynamichud)
  69                 HUD_Scale_Enable();
  70         else
  71                 HUD_Scale_Disable();
  72         HUD_Panel_DrawBg();
  73         if(panel_bg_padding)
  74         {
  75                 pos += '1 1 0' * panel_bg_padding;
  76                 mySize -= '2 2 0' * panel_bg_padding;
  77         }
  78
  79         int baralign = autocvar_hud_panel_healtharmor_baralign;
  80         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
  81
  82     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
  83     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
  84         if(autocvar_hud_panel_healtharmor_combined) // combined health and armor display
  85         {
  86                 vector v;
  87                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON.m_id);
  88
  89                 float x;
  90                 x = floor(v.x + 1);
  91
  92         float maxtotal = maxhealth + maxarmor;
  93                 string biggercount;
  94                 if(v.z) // NOT fully armored
  95                 {
  96                         biggercount = "health";
  97                         if(autocvar_hud_panel_healtharmor_progressbar)
  98                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
  99                         if(armor)
 100             if(autocvar_hud_panel_healtharmor_text)
 101                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
 102                 }
 103                 else
 104                 {
 105                         biggercount = "armor";
 106                         if(autocvar_hud_panel_healtharmor_progressbar)
 107                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 108                         if(health)
 109             if(autocvar_hud_panel_healtharmor_text)
 110                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 111                 }
 112         if(autocvar_hud_panel_healtharmor_text)
 113                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
 114
 115                 if(fuel)
 116                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 117         }
 118         else
 119         {
 120                 float panel_ar = mySize.x/mySize.y;
 121                 bool is_vertical = (panel_ar < 1);
 122                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
 123                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
 124                 {
 125                         mySize.x *= 0.5;
 126                         if (autocvar_hud_panel_healtharmor_flip)
 127                                 health_offset.x = mySize.x;
 128                         else
 129                                 armor_offset.x = mySize.x;
 130                 }
 131                 else
 132                 {
 133                         mySize.y *= 0.5;
 134                         if (autocvar_hud_panel_healtharmor_flip)
 135                                 health_offset.y = mySize.y;
 136                         else
 137                                 armor_offset.y = mySize.y;
 138                 }
 139
 140                 bool health_baralign, armor_baralign, fuel_baralign;
 141                 bool health_iconalign, armor_iconalign;
 142                 if (autocvar_hud_panel_healtharmor_flip)
 143                 {
 144                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 145                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 146                         fuel_baralign = health_baralign;
 147                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 148                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 149                 }
 150                 else
 151                 {
 152                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 153                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 154                         fuel_baralign = armor_baralign;
 155                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 156                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 157                 }
 158
 159                 //if(health)
 160                 {
 161                         if(autocvar_hud_panel_healtharmor_progressbar)
 162                         {
 163                                 float p_health, pain_health_alpha;
 164                                 p_health = health;
 165                                 pain_health_alpha = 1;
 166                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 167                                 {
 168                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 169                                         {
 170                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 171                                                 {
 172                                                         if (time - old_p_healthtime < 1)
 173                                                                 old_p_health = prev_p_health;
 174                                                         else
 175                                                                 old_p_health = prev_health;
 176                                                         old_p_healthtime = time;
 177                                                 }
 178                                                 if (time - old_p_healthtime < 1)
 179                                                 {
 180                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
 181                                                         prev_p_health = p_health;
 182                                                 }
 183                                         }
 184                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 185                                         {
 186                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 187                                                 {
 188                                                         if (time - health_damagetime >= 1)
 189                                                                 health_beforedamage = prev_health;
 190                                                         health_damagetime = time;
 191                                                 }
 192                                                 if (time - health_damagetime < 1)
 193                                                 {
 194                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
 195                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
 196                                                 }
 197                                         }
 198                                         prev_health = health;
 199
 200                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
 201                                         {
 202                                                 float BLINK_FACTOR = 0.15;
 203                                                 float BLINK_BASE = 0.85;
 204                                                 float BLINK_FREQ = 9;
 205                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 206                                         }
 207                                 }
 208                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
 209                         }
 210                         if(autocvar_hud_panel_healtharmor_text)
 211                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
 212                 }
 213
 214                 if(armor)
 215                 {
 216                         if(autocvar_hud_panel_healtharmor_progressbar)
 217                         {
 218                                 float p_armor;
 219                                 p_armor = armor;
 220                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 221                                 {
 222                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 223                                         {
 224                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 225                                                 {
 226                                                         if (time - old_p_armortime < 1)
 227                                                                 old_p_armor = prev_p_armor;
 228                                                         else
 229                                                                 old_p_armor = prev_armor;
 230                                                         old_p_armortime = time;
 231                                                 }
 232                                                 if (time - old_p_armortime < 1)
 233                                                 {
 234                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
 235                                                         prev_p_armor = p_armor;
 236                                                 }
 237                                         }
 238                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 239                                         {
 240                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 241                                                 {
 242                                                         if (time - armor_damagetime >= 1)
 243                                                                 armor_beforedamage = prev_armor;
 244                                                         armor_damagetime = time;
 245                                                 }
 246                                                 if (time - armor_damagetime < 1)
 247                                                 {
 248                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
 249                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
 250                                                 }
 251                                         }
 252                                         prev_armor = armor;
 253                                 }
 254                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 255                         }
 256                         if(autocvar_hud_panel_healtharmor_text)
 257                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
 258                 }
 259
 260                 if(fuel)
 261                 {
 262                         if (is_vertical)
 263                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
 264                         else
 265                                 mySize.y *= 0.2;
 266                         if (panel_ar >= 4)
 267                                 mySize.x *= 2; //restore full panel size
 268                         else if (panel_ar < 1/4)
 269                                 mySize.y *= 2; //restore full panel size
 270                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 271                 }
 272         }
 273
 274         draw_endBoldFont();
 275 }