qcsrc/client/hud/panel/healtharmor.qc

   1 #include "healtharmor.qh"
   2
   3 #include <common/deathtypes/all.qh>
   4
   5 // Health/armor (#3)
   6
   7 void HUD_HealthArmor()
   8 {
   9         int armor, health, fuel;
  10         if(!autocvar__hud_configure)
  11         {
  12                 if((!autocvar_hud_panel_healtharmor) || (spectatee_status == -1))
  13                         return;
  14                 if(hud != HUD_NORMAL) return;
  15
  16                 health = STAT(HEALTH);
  17                 if(health <= 0)
  18                 {
  19                         health = 0;
  20                         prev_health = -1;
  21                         if(autocvar_hud_panel_healtharmor_hide_ondeath)
  22                                 return;
  23                 }
  24                 armor = STAT(ARMOR);
  25
  26                 // code to check for spectatee_status changes is in ENT_CLIENT_CLIENTDATA
  27                 // prev_p_health and prev_health can be set to -1 there
  28
  29                 if (prev_p_health == -1)
  30                 {
  31                         // no effect
  32                         health_beforedamage = 0;
  33                         armor_beforedamage = 0;
  34                         health_damagetime = 0;
  35                         armor_damagetime = 0;
  36                         prev_health = health;
  37                         prev_armor = armor;
  38                         old_p_health = health;
  39                         old_p_armor = armor;
  40                         prev_p_health = health;
  41                         prev_p_armor = armor;
  42                 }
  43                 else if (prev_health == -1)
  44                 {
  45                         //start the load effect
  46                         health_damagetime = 0;
  47                         armor_damagetime = 0;
  48                         prev_health = 0;
  49                         prev_armor = 0;
  50                 }
  51                 fuel = STAT(FUEL);
  52         }
  53         else
  54         {
  55                 health = 150;
  56                 armor = 75;
  57                 fuel = 20;
  58         }
  59
  60         HUD_Panel_LoadCvars();
  61
  62         draw_beginBoldFont();
  63
  64         vector pos, mySize;
  65         pos = panel_pos;
  66         mySize = panel_size;
  67
  68         if (autocvar_hud_panel_healtharmor_dynamichud)
  69                 HUD_Scale_Enable();
  70         else
  71                 HUD_Scale_Disable();
  72         HUD_Panel_DrawBg();
  73         if(panel_bg_padding)
  74         {
  75                 pos += '1 1 0' * panel_bg_padding;
  76                 mySize -= '2 2 0' * panel_bg_padding;
  77         }
  78
  79         int baralign = autocvar_hud_panel_healtharmor_baralign;
  80         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
  81
  82         int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
  83         int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
  84         if(autocvar_hud_panel_healtharmor_combined) // combined health and armor display
  85         {
  86                 vector v;
  87                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON.m_id);
  88
  89                 float hp = floor(v.x + 1);
  90
  91                 float maxtotal = maxhealth + maxarmor;
  92                 string biggercount;
  93                 if(v.z) // NOT fully armored
  94                 {
  95                         biggercount = "health";
  96                         if(autocvar_hud_panel_healtharmor_progressbar)
  97                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, hp/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
  98                         if(armor && autocvar_hud_panel_healtharmor_text)
  99                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
 100                 }
 101                 else
 102                 {
 103                         biggercount = "armor";
 104                         if(autocvar_hud_panel_healtharmor_progressbar)
 105                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, hp/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 106                         if(health && autocvar_hud_panel_healtharmor_text)
 107                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 108                 }
 109                 if(autocvar_hud_panel_healtharmor_text)
 110                         DrawNumIcon(pos, mySize, hp, biggercount, 0, iconalign, HUD_Get_Num_Color(hp, maxtotal), 1);
 111
 112                 if(fuel)
 113                         HUD_Panel_DrawProgressBar(pos, vec2(mySize.x, 0.2 * mySize.y), "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 114         }
 115         else
 116         {
 117                 float panel_ar = mySize.x/mySize.y;
 118                 bool is_vertical = (panel_ar < 1);
 119                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
 120                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
 121                 {
 122                         mySize.x *= 0.5;
 123                         if (autocvar_hud_panel_healtharmor_flip)
 124                                 health_offset.x = mySize.x;
 125                         else
 126                                 armor_offset.x = mySize.x;
 127                 }
 128                 else
 129                 {
 130                         mySize.y *= 0.5;
 131                         if (autocvar_hud_panel_healtharmor_flip)
 132                                 health_offset.y = mySize.y;
 133                         else
 134                                 armor_offset.y = mySize.y;
 135                 }
 136
 137                 bool health_baralign, armor_baralign, fuel_baralign;
 138                 bool health_iconalign, armor_iconalign;
 139                 if (autocvar_hud_panel_healtharmor_flip)
 140                 {
 141                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 142                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 143                         fuel_baralign = health_baralign;
 144                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 145                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 146                 }
 147                 else
 148                 {
 149                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 150                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 151                         fuel_baralign = armor_baralign;
 152                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 153                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 154                 }
 155
 156                 //if(health)
 157                 {
 158                         if(autocvar_hud_panel_healtharmor_progressbar)
 159                         {
 160                                 float p_health, pain_health_alpha;
 161                                 p_health = health;
 162                                 pain_health_alpha = 1;
 163                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 164                                 {
 165                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 166                                         {
 167                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 168                                                 {
 169                                                         if (time - old_p_healthtime < 1)
 170                                                                 old_p_health = prev_p_health;
 171                                                         else
 172                                                                 old_p_health = prev_health;
 173                                                         old_p_healthtime = time;
 174                                                 }
 175                                                 if (time - old_p_healthtime < 1)
 176                                                 {
 177                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
 178                                                         prev_p_health = p_health;
 179                                                 }
 180                                         }
 181                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 182                                         {
 183                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 184                                                 {
 185                                                         if (time - health_damagetime >= 1)
 186                                                                 health_beforedamage = prev_health;
 187                                                         health_damagetime = time;
 188                                                 }
 189                                                 if (time - health_damagetime < 1)
 190                                                 {
 191                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
 192                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
 193                                                 }
 194                                         }
 195                                         prev_health = health;
 196
 197                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
 198                                         {
 199                                                 float BLINK_FACTOR = 0.15;
 200                                                 float BLINK_BASE = 0.85;
 201                                                 float BLINK_FREQ = 9;
 202                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 203                                         }
 204                                 }
 205                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
 206                         }
 207                         if(autocvar_hud_panel_healtharmor_text)
 208                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
 209                 }
 210
 211                 //if(armor)
 212                 {
 213                         float p_armor = armor;
 214                         if(autocvar_hud_panel_healtharmor_progressbar)
 215                         {
 216                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 217                                 {
 218                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 219                                         {
 220                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 221                                                 {
 222                                                         if (time - old_p_armortime < 1)
 223                                                                 old_p_armor = prev_p_armor;
 224                                                         else
 225                                                                 old_p_armor = prev_armor;
 226                                                         old_p_armortime = time;
 227                                                 }
 228                                                 if (time - old_p_armortime < 1)
 229                                                 {
 230                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
 231                                                         prev_p_armor = p_armor;
 232                                                 }
 233                                         }
 234                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 235                                         {
 236                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 237                                                 {
 238                                                         if (time - armor_damagetime >= 1)
 239                                                                 armor_beforedamage = prev_armor;
 240                                                         armor_damagetime = time;
 241                                                 }
 242                                                 if (time - armor_damagetime < 1)
 243                                                 {
 244                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
 245                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
 246                                                 }
 247                                         }
 248                                         prev_armor = armor;
 249                                 }
 250                                 if(p_armor)
 251                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 252                         }
 253                         if(!autocvar_hud_panel_healtharmor_progressbar || p_armor)
 254                         if(autocvar_hud_panel_healtharmor_text)
 255                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
 256                 }
 257
 258                 if(fuel)
 259                 {
 260                         if (is_vertical)
 261                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
 262                         else
 263                                 mySize.y *= 0.2;
 264                         if (panel_ar >= 4)
 265                                 mySize.x *= 2; //restore full panel size
 266                         else if (panel_ar < 1/4)
 267                                 mySize.y *= 2; //restore full panel size
 268                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 269                 }
 270         }
 271
 272         draw_endBoldFont();
 273 }